granicus.if.org Git - libass/blob - configure.ac

   1 AC_INIT(libass, 0.14.0)
   2 AM_INIT_AUTOMAKE
   3 AC_CONFIG_MACRO_DIR([m4])
   4 # Disable Fortran checks
   5 define([AC_LIBTOOL_LANG_F77_CONFIG], [:])
   6 LT_INIT
   7 AC_CONFIG_SRCDIR([libass/ass.c])
   8 AC_CONFIG_HEADER([config.h])
   9
  10 # Checks for programs.
  11 AC_PROG_CC
  12 AC_PROG_CPP
  13 AM_PROG_CC_C_O
  14 AM_PROG_AS
  15
  16 # Checks for header files.
  17 AC_HEADER_STDC
  18 AC_HEADER_STDBOOL
  19 AC_CHECK_HEADERS([stdint.h iconv.h])
  20
  21 # Checks for library functions.
  22 AC_CHECK_FUNCS([strdup strndup])
  23
  24 # Checks for libraries.
  25 # Add them to pkg-config for static linking.
  26 OLDLIBS="$LIBS"
  27 LIBS=
  28 use_libiconv=false
  29 AC_SEARCH_LIBS([libiconv_open], [iconv], use_libiconv=true)
  30 AC_SEARCH_LIBS([iconv_open], [iconv], use_libiconv=true)
  31 AC_CHECK_LIB([m], [fabs])
  32 pkg_libs="$LIBS"
  33 LIBS="$OLDLIBS $LIBS"
  34
  35 # Check for libraries via pkg-config
  36 AC_ARG_ENABLE([test], AS_HELP_STRING([--enable-test],
  37     [enable test program (requires libpng) @<:@default=no@:>@]))
  38 AC_ARG_ENABLE([profile], AS_HELP_STRING([--enable-profile],
  39     [enable profiling program @<:@default=no@:>@]))
  40 AC_ARG_ENABLE([fontconfig], AS_HELP_STRING([--disable-fontconfig],
  41     [disable fontconfig support @<:@default=enabled@:>@]))
  42 AC_ARG_ENABLE([directwrite], AS_HELP_STRING([--disable-directwrite],
  43     [disable DirectWrite support (win32 only) @<:@default=check@:>@]))
  44 AC_ARG_ENABLE([coretext], AS_HELP_STRING([--disable-coretext],
  45     [disable CoreText support (OSX only) @<:@default=check@:>@]))
  46 AC_ARG_ENABLE([require-system-font-provider], AS_HELP_STRING([--disable-require-system-font-provider],
  47     [allow compilation even if no system font provider was found @<:@default=enabled:>@]))
  48 AC_ARG_ENABLE([harfbuzz], AS_HELP_STRING([--disable-harfbuzz],
  49     [disable HarfBuzz support @<:@default=check@:>@]))
  50 AC_ARG_ENABLE([asm], AS_HELP_STRING([--disable-asm],
  51     [disable compiling with ASM @<:@default=check@:>@]))
  52 AC_ARG_ENABLE([large-tiles], AS_HELP_STRING([--enable-large-tiles],
  53     [use larger tiles in the rasterizer (better performance, slightly worse quality) @<:@default=disabled@:>@]))
  54
  55 AS_IF([test x$enable_asm != xno], [
  56     AS_CASE([$host],
  57         [i?86-*], [
  58             INTEL=true
  59             AS=nasm
  60             X86=true
  61             BITS=32
  62             BITTYPE=32
  63             ASFLAGS="$ASFLAGS -DARCH_X86_64=0" ],
  64         [x86_64-*-gnux32|amd64-*-gnux32], [
  65             AS=nasm
  66             INTEL=true
  67             X64=true
  68             BITS=64
  69             BITTYPE=x32
  70             ASFLAGS="$ASFLAGS -DARCH_X86_64=1 -DPIC" ],
  71         [x86_64-*|amd64-*], [
  72             AS=nasm
  73             INTEL=true
  74             X64=true
  75             BITS=64
  76             BITTYPE=64
  77             ASFLAGS="$ASFLAGS -DARCH_X86_64=1 -DPIC" ],
  78         )
  79     AS_IF([test x$INTEL = xtrue], [
  80         AC_CHECK_PROG([nasm_check], [$AS], [yes])
  81         AS_IF([test x$nasm_check != xyes], [
  82             AC_MSG_WARN(nasm was not found; ASM functions are disabled.)
  83             AC_MSG_WARN(Install nasm for a significantly faster libass build.)
  84             enable_asm=no
  85         ], [
  86             AS_CASE([$host],
  87                 [*darwin*], [
  88                     ASFLAGS="$ASFLAGS -f macho$BITTYPE -DPREFIX -DHAVE_ALIGNED_STACK=1" ],
  89                 [*linux*|*dragonfly*|*bsd*|*solaris*], [
  90                     ASFLAGS="$ASFLAGS -f elf$BITTYPE -DHAVE_ALIGNED_STACK=1" ],
  91                 [*cygwin*|*mingw*], [
  92                     ASFLAGS="$ASFLAGS -f win$BITTYPE"
  93                     AS_IF([test x$BITS = x64], [
  94                         ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=1"
  95                     ], [
  96                         ASFLAGS="$ASFLAGS -DHAVE_ALIGNED_STACK=0 -DPREFIX"
  97                     ])
  98                 ])
  99             ASFLAGS="$ASFLAGS -DHAVE_CPUNOP=0 -Dprivate_prefix=ass"
 100             AC_MSG_CHECKING([if $AS supports vpmovzxwd])
 101             echo "vpmovzxwd ymm0, xmm0" > conftest.asm
 102             AS_IF([$AS conftest.asm $ASFLAGS -o conftest.o >conftest.log 2>&1], [
 103                 AC_MSG_RESULT([yes])
 104             ], [
 105                 AC_MSG_RESULT([no])
 106                 VER=`($AS --version || echo no assembler) 2>/dev/null | head -n 1`
 107                 AC_MSG_WARN([nasm is too old (found $VER); ASM functions are disabled.])
 108                 AC_MSG_WARN([Install nasm-2.10 or later for a significantly faster libass build.])
 109                 enable_asm=no
 110             ])
 111             rm conftest.asm conftest.o > /dev/null 2>&1
 112         ])
 113     ])
 114 ])
 115
 116 AC_SUBST([ASFLAGS], ["$ASFLAGS"])
 117 AC_SUBST([AS], ["$AS"])
 118
 119 AM_CONDITIONAL([ASM], [test x$enable_asm != xno])
 120 AM_CONDITIONAL([INTEL], [test x$INTEL = xtrue])
 121 AM_CONDITIONAL([X86], [test x$X86 = xtrue])
 122 AM_CONDITIONAL([X64], [test x$X64 = xtrue])
 123
 124 AM_COND_IF([ASM],
 125     [AC_DEFINE(CONFIG_ASM, 1, [ASM enabled])],
 126     [AC_DEFINE(CONFIG_ASM, 0, [ASM enabled])]
 127     )
 128
 129 AM_CONDITIONAL([ENABLE_LARGE_TILES], [test x$enable_large_tiles = xyes])
 130
 131 AM_COND_IF([ENABLE_LARGE_TILES],
 132     [AC_DEFINE(CONFIG_LARGE_TILES, 1, [use large tiles])]
 133     [AC_DEFINE(CONFIG_LARGE_TILES, 0, [use small tiles])],
 134     )
 135
 136 PKG_CHECK_MODULES([FREETYPE], freetype2 >= 9.10.3, [
 137     CFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 138     CXXFLAGS="$CFLAGS $FREETYPE_CFLAGS"
 139     LIBS="$LIBS $FREETYPE_LIBS"
 140     AC_DEFINE(CONFIG_FREETYPE, 1, [found freetype2 via pkg-config])
 141     ])
 142
 143 PKG_CHECK_MODULES([FRIBIDI], fribidi >= 0.19.0, [
 144     CFLAGS="$CFLAGS $FRIBIDI_CFLAGS"
 145     LIBS="$LIBS $FRIBIDI_LIBS"
 146     AC_DEFINE(CONFIG_FRIBIDI, 1, [found fribidi via pkg-config])
 147     ])
 148
 149 if test x$enable_fontconfig != xno; then
 150 PKG_CHECK_MODULES([FONTCONFIG], fontconfig >= 2.10.92, [
 151     CFLAGS="$CFLAGS $FONTCONFIG_CFLAGS"
 152     LIBS="$LIBS $FONTCONFIG_LIBS"
 153     AC_DEFINE(CONFIG_FONTCONFIG, 1, [found fontconfig via pkg-config])
 154         fontconfig=true
 155     ], [fontconfig=false])
 156 fi
 157 AM_CONDITIONAL([FONTCONFIG], [test x$fontconfig = xtrue])
 158
 159 if test x$enable_coretext != xno; then
 160 # Linking to CoreText directly only works from Mountain Lion and iOS.
 161 # In earlier OS X releases CoreText was part of the ApplicationServices
 162 # umbrella framework.
 163 AC_MSG_CHECKING([for CORETEXT])
 164 AC_COMPILE_IFELSE([
 165   AC_LANG_PROGRAM(
 166     [[#include <ApplicationServices/ApplicationServices.h>]],
 167     [[CTFontDescriptorCopyAttribute(NULL, kCTFontURLAttribute);]])
 168   ], [
 169     LIBS="$LIBS -framework ApplicationServices -framework CoreFoundation"
 170     AC_DEFINE(CONFIG_CORETEXT, 1, [found CoreText in ApplicationServices framework])
 171     coretext=true
 172     AC_MSG_RESULT([yes])
 173   ], [
 174     AC_COMPILE_IFELSE([
 175       AC_LANG_PROGRAM(
 176         [[#include <CoreText/CoreText.h>]],
 177         [[CTFontDescriptorCopyAttribute(NULL, kCTFontURLAttribute);]])
 178       ], [
 179         LIBS="$LIBS -framework CoreText -framework CoreFoundation"
 180         AC_DEFINE(CONFIG_CORETEXT, 1, [found CoreText framework])
 181         coretext=true
 182         AC_MSG_RESULT([yes])
 183       ], [
 184         coretext=false
 185         AC_MSG_RESULT([no])
 186       ])
 187   ])
 188 fi
 189 AM_CONDITIONAL([CORETEXT], [test x$coretext = xtrue])
 190
 191
 192
 193 if test x$enable_directwrite != xno; then
 194 # Linking to DirectWrite directly only works from Windows
 195 AC_MSG_CHECKING([for DIRECTWRITE])
 196 AC_LINK_IFELSE([
 197   AC_LANG_PROGRAM(
 198     [[#include <windows.h>]],
 199     [[;]],)
 200   ], [
 201     AC_DEFINE(CONFIG_DIRECTWRITE, 1, [found DirectWrite])
 202     directwrite=true
 203     AC_MSG_RESULT([yes])
 204   ], [
 205     directwrite=false
 206     AC_MSG_RESULT([no])
 207   ])
 208 fi
 209 AM_CONDITIONAL([DIRECTWRITE], [test x$directwrite = xtrue])
 210
 211 if test x$enable_harfbuzz != xno; then
 212 PKG_CHECK_MODULES([HARFBUZZ], harfbuzz >= 0.9.5, [
 213     CFLAGS="$CFLAGS $HARFBUZZ_CFLAGS"
 214     LIBS="$LIBS $HARFBUZZ_LIBS"
 215     AC_DEFINE(CONFIG_HARFBUZZ, 1, [found harfbuzz-ng via pkg-config])
 216         harfbuzz=true
 217     ], [harfbuzz=false])
 218 fi
 219
 220 libpng=false
 221 if test x$enable_test = xyes; then
 222 PKG_CHECK_MODULES([LIBPNG], libpng >= 1.2.0, [
 223     CFLAGS="$CFLAGS $LIBPNG_CFLAGS"
 224     AC_DEFINE(CONFIG_LIBPNG, 1, [found libpng via pkg-config])
 225     libpng=true])
 226 fi
 227
 228 AM_CONDITIONAL([HAVE_LIBPNG], [test x$libpng = xtrue])
 229
 230 AM_CONDITIONAL([ENABLE_PROFILE], [test x$enable_profile = xyes])
 231
 232 # add packages to pkg-config for static linking
 233 if test "$use_libiconv" = true; then
 234     AC_DEFINE(CONFIG_ICONV, 1, [use iconv])
 235     if test x"$ac_cv_search_libiconv_open" != x"none required" &&
 236        test x"$ac_cv_search_iconv_open" != x"none required"; then
 237         pkg_libs="${pkg_libs} -liconv"
 238     fi
 239 fi
 240 pkg_requires="freetype2 >= 9.10.3"
 241 pkg_requires="fribidi >= 0.19.0, ${pkg_requires}"
 242 if test x$fontconfig = xtrue; then
 243     pkg_requires="fontconfig >= 2.10.92, ${pkg_requires}"
 244 fi
 245 if test x$harfbuzz = xtrue; then
 246     pkg_requires="harfbuzz >= 0.9.5, ${pkg_requires}"
 247 fi
 248
 249 if test x$enable_require_system_font_provider != xno &&
 250    test x$fontconfig != xtrue &&
 251    test x$directwrite != xtrue &&
 252    test x$coretext != xtrue
 253 then
 254     AC_MSG_ERROR([\
 255 Either DirectWrite (on Windows), CoreText (on OSX), or Fontconfig \
 256 (Linux, other) is required. If you really want to compile without \
 257 a system font provider, add --disable-require-system-font-provider])
 258 fi
 259
 260 AC_SUBST([PKG_LIBS_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_libs})])
 261 AC_SUBST([PKG_REQUIRES_DEFAULT], [$(test x$enable_shared = xno && echo ${pkg_requires})])
 262 AC_SUBST([PKG_LIBS_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_libs})])
 263 AC_SUBST([PKG_REQUIRES_PRIVATE], [$(test x$enable_shared = xno || echo ${pkg_requires})])
 264
 265 # Setup output beautifier.
 266 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
 267
 268 AC_CONFIG_FILES([Makefile libass/Makefile test/Makefile profile/Makefile libass.pc])
 269 AC_OUTPUT