From 6409d7cd59611974e882c1e6bc0cae82ff4b2bf7 Mon Sep 17 00:00:00 2001
From: Matthew Fernandez <matthew.fernandez@gmail.com>
Date: Fri, 18 Jun 2021 08:07:27 -0700
Subject: [PATCH] only enable -Wtrampolines and -Wlogical-op for compilers that
 support them

This fixes an issue where these flags were enabled for Clang, despite it not
supporting them. This did not fail the build, but produced a lot of noisy
warning output about unsupported flags. Closes #2066.
---
 CHANGELOG.md                |  1 +
 configure.ac                |  8 +++++-
 m4/README                   |  4 +++
 m4/ax_check_compile_flag.m4 | 53 +++++++++++++++++++++++++++++++++++++
 4 files changed, 65 insertions(+), 1 deletion(-)
 create mode 100644 m4/ax_check_compile_flag.m4

diff --git a/CHANGELOG.md b/CHANGELOG.md
index 31ae52447..12bccb3a3 100644
--- a/CHANGELOG.md
+++ b/CHANGELOG.md
@@ -14,6 +14,7 @@ and this project adheres to [Semantic Versioning](https://semver.org/spec/v2.0.0
 ### Fixed
 
 - ortho's eqEndSeg incorrectly modifies its arguments #2047
+- Autotools enables -Wtrampolines and -Wlogical-op for Clang #2066
 
 ## [2.47.3] - 2021-06-19
 
diff --git a/configure.ac b/configure.ac
index 92a6da271..7f6d3e555 100644
--- a/configure.ac
+++ b/configure.ac
@@ -329,7 +329,13 @@ then
   CFLAGS="${CFLAGS} -Wmissing-include-dirs -Wswitch-default -Wfloat-equal -Wundef -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wconversion -Wstrict-prototypes -Wmissing-prototypes -Wnested-externs"
 
   # Enable additional C99 warnings
-  CFLAGS="${CFLAGS} -Wtrampolines -Wlogical-op"
+  save_CFLAGS="${CFLAGS}"
+  CFLAGS=""
+  AX_CHECK_COMPILE_FLAG([-Wtrampolines],
+    [save_CFLAGS="${save_CFLAGS} -Wtrampolines"],[],[-Werror])
+  AX_CHECK_COMPILE_FLAG([-Wlogical-op],
+    [save_CFLAGS="${save_CFLAGS} -Wlogical-op"],[],[-Werror])
+  CFLAGS="${save_CFLAGS}"
 # if [test "${ac_cv_prog_cc_c99}" != "no"]
 # then
     # FIXME - not available on centos[56]: gcc-4.1.2, gcc-4.4.7
diff --git a/m4/README b/m4/README
index caac3e379..5cf02a9bd 100644
--- a/m4/README
+++ b/m4/README
@@ -5,6 +5,10 @@ The file: glib-gettext.m4 was obtained from glib2-devel (go figure!)
 
 They are used in graphviz to avoid requiring gettext be installed.
 
+The file ax_check_compile_flag.m4 was obtained from commit
+0fbee2a29b67cc7867cfe19d473e9fb1f729f771 of
+    https://git.savannah.gnu.org/git/autoconf-archive.git
+
 The files ax_cxx_compile_stdcxx.m4 and ax_cxx_compile_stdcxx_11.m4 were obtained
 from commit efa6f204a6124e882abbbc6e056c91edfdc30555 of
     https://git.savannah.gnu.org/git/autoconf-archive.git
diff --git a/m4/ax_check_compile_flag.m4 b/m4/ax_check_compile_flag.m4
new file mode 100644
index 000000000..bd753b34d
--- /dev/null
+++ b/m4/ax_check_compile_flag.m4
@@ -0,0 +1,53 @@
+# ===========================================================================
+#  https://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
+#
+# DESCRIPTION
+#
+#   Check whether the given FLAG works with the current language's compiler
+#   or gives an error.  (Warnings, however, are ignored)
+#
+#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
+#   success/failure.
+#
+#   If EXTRA-FLAGS is defined, it is added to the current language's default
+#   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
+#   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
+#   force the compiler to issue an error when a bad flag is given.
+#
+#   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
+#
+#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
+#   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
+#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
+#
+#   Copying and distribution of this file, with or without modification, are
+#   permitted in any medium without royalty provided the copyright notice
+#   and this notice are preserved.  This file is offered as-is, without any
+#   warranty.
+
+#serial 6
+
+AC_DEFUN([AX_CHECK_COMPILE_FLAG],
+[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
+AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
+AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
+  ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
+  _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
+  AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
+    [AS_VAR_SET(CACHEVAR,[yes])],
+    [AS_VAR_SET(CACHEVAR,[no])])
+  _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
+AS_VAR_IF(CACHEVAR,yes,
+  [m4_default([$2], :)],
+  [m4_default([$3], :)])
+AS_VAR_POPDEF([CACHEVAR])dnl
+])dnl AX_CHECK_COMPILE_FLAGS
-- 
2.40.0