added use of AX_CHECK_COMPILE_FLAG Autoconf macro

diff --git a/expat/acinclude.m4 b/expat/acinclude.m4
index be1d5037349a302dc6037c4214041d7069dce59c..9dabcb95e0ba2fd04b5c64637e44f653047a69a3 100644 (file)
--- a/expat/acinclude.m4
+++ b/expat/acinclude.m4
@@ -1,7 +1,7 @@
 # acinclude.m4 --
 #
 
-dnl m4_include(meta/autoconf/ax-check-compile-flag.m4)
-dnl m4_include(meta/autoconf/ax-gcc-version.m4)
+m4_include(conftools/ax-check-compile-flag.m4)
+dnl m4_include(conftools/ax-gcc-version.m4)
 
 ### end of file

diff --git a/expat/configure.ac b/expat/configure.ac
index 3d167dffcfdbcde1f165a46ac46593f8aa804099..fb9973a893d2360760f9f6cbbb4ae122b2be8381 100644 (file)
--- a/expat/configure.ac
+++ b/expat/configure.ac
@@ -69,25 +69,22 @@ AC_SUBST(LIBAGE)
 AC_PROG_CC_C99
 AC_PROG_CXX
 
-AS_IF([test "$GCC" = yes],[
-    dnl
-    dnl Be careful about adding the -fexceptions option; some versions of
-    dnl GCC don't support it and it causes extra warnings that are only
-    dnl distracting; avoid.
-    dnl
-    OLDCFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wstrict-prototypes"
-    CFLAGS="$OLDCFLAGS -fexceptions"
-    AC_MSG_CHECKING(whether $CC accepts -fexceptions)
-    AC_TRY_LINK( , ,
-                   AC_MSG_RESULT(yes),
-                   AC_MSG_RESULT(no); CFLAGS="$OLDCFLAGS")
-    AS_IF([test "x$CXXFLAGS" = x],
-      [CXXFLAGS=`echo "$CFLAGS" | sed 's/ -Wmissing-prototypes -Wstrict-prototypes//'`])
-
-    CFLAGS="${CFLAGS} -fno-strict-aliasing"
-    CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
-    LDFLAGS="${LDFLAGS} -fno-strict-aliasing"
-])
+AS_IF([test "$GCC" = yes],
+  [AS_VAR_APPEND(CFLAGS," -Wall -Wmissing-prototypes -Wstrict-prototypes")
+
+   dnl Be careful about adding the -fexceptions option; some versions of
+   dnl GCC don't support it and it causes extra warnings that are only
+   dnl distracting; avoid.
+   AX_CHECK_COMPILE_FLAG([-fexceptions],
+     [AS_VAR_APPEND(CFLAGS," -fexceptions")],
+     [AC_MSG_WARN([The GCC compiler does not support -fexceptions.])])
+
+   AS_IF([test "x$CXXFLAGS" = x],
+     [CXXFLAGS=`echo "$CFLAGS" | sed 's/ -Wmissing-prototypes -Wstrict-prototypes//'`])
+
+   AS_VAR_APPEND(CFLAGS,   " -fno-strict-aliasing")
+   AS_VAR_APPEND(CXXFLAGS, " -fno-strict-aliasing")
+   AS_VAR_APPEND(LDFLAGS,  " -fno-strict-aliasing")])
 
 AC_MSG_CHECKING(whether compiler supports visibility)
 AS_VAR_SET(OLDCFLAGS,$CFLAGS)

diff --git a/expat/conftools/ax-check-compile-flag.m4 b/expat/conftools/ax-check-compile-flag.m4
new file mode 100644 (file)
index 0000000..ca36397
--- /dev/null
+++ b/expat/conftools/ax-check-compile-flag.m4
@@ -0,0 +1,74 @@
+# ===========================================================================
+#   http://www.gnu.org/software/autoconf-archive/ax_check_compile_flag.html
+# ===========================================================================
+#
+# SYNOPSIS
+#
+#   AX_CHECK_COMPILE_FLAG(FLAG, [ACTION-SUCCESS], [ACTION-FAILURE], [EXTRA-FLAGS], [INPUT])
+#
+# DESCRIPTION
+#
+#   Check whether the given FLAG works with the current language's compiler
+#   or gives an error.  (Warnings, however, are ignored)
+#
+#   ACTION-SUCCESS/ACTION-FAILURE are shell commands to execute on
+#   success/failure.
+#
+#   If EXTRA-FLAGS is defined, it is added to the current language's default
+#   flags (e.g. CFLAGS) when the check is done.  The check is thus made with
+#   the flags: "CFLAGS EXTRA-FLAGS FLAG".  This can for example be used to
+#   force the compiler to issue an error when a bad flag is given.
+#
+#   INPUT gives an alternative input source to AC_COMPILE_IFELSE.
+#
+#   NOTE: Implementation based on AX_CFLAGS_GCC_OPTION. Please keep this
+#   macro in sync with AX_CHECK_{PREPROC,LINK}_FLAG.
+#
+# LICENSE
+#
+#   Copyright (c) 2008 Guido U. Draheim <guidod@gmx.de>
+#   Copyright (c) 2011 Maarten Bosmans <mkbosmans@gmail.com>
+#
+#   This program is free software: you can redistribute it and/or modify it
+#   under the terms of the GNU General Public License as published by the
+#   Free Software Foundation, either version 3 of the License, or (at your
+#   option) any later version.
+#
+#   This program is distributed in the hope that it will be useful, but
+#   WITHOUT ANY WARRANTY; without even the implied warranty of
+#   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General
+#   Public License for more details.
+#
+#   You should have received a copy of the GNU General Public License along
+#   with this program. If not, see <http://www.gnu.org/licenses/>.
+#
+#   As a special exception, the respective Autoconf Macro's copyright owner
+#   gives unlimited permission to copy, distribute and modify the configure
+#   scripts that are the output of Autoconf when processing the Macro. You
+#   need not follow the terms of the GNU General Public License when using
+#   or distributing such scripts, even though portions of the text of the
+#   Macro appear in them. The GNU General Public License (GPL) does govern
+#   all other use of the material that constitutes the Autoconf Macro.
+#
+#   This special exception to the GPL applies to versions of the Autoconf
+#   Macro released by the Autoconf Archive. When you make and distribute a
+#   modified version of the Autoconf Macro, you may extend this special
+#   exception to the GPL to apply to your modified version as well.
+
+#serial 4
+
+AC_DEFUN([AX_CHECK_COMPILE_FLAG],
+[AC_PREREQ(2.64)dnl for _AC_LANG_PREFIX and AS_VAR_IF
+AS_VAR_PUSHDEF([CACHEVAR],[ax_cv_check_[]_AC_LANG_ABBREV[]flags_$4_$1])dnl
+AC_CACHE_CHECK([whether _AC_LANG compiler accepts $1], CACHEVAR, [
+  ax_check_save_flags=$[]_AC_LANG_PREFIX[]FLAGS
+  _AC_LANG_PREFIX[]FLAGS="$[]_AC_LANG_PREFIX[]FLAGS $4 $1"
+  AC_COMPILE_IFELSE([m4_default([$5],[AC_LANG_PROGRAM()])],
+    [AS_VAR_SET(CACHEVAR,[yes])],
+    [AS_VAR_SET(CACHEVAR,[no])])
+  _AC_LANG_PREFIX[]FLAGS=$ax_check_save_flags])
+AS_VAR_IF(CACHEVAR,yes,
+  [m4_default([$2], :)],
+  [m4_default([$3], :)])
+AS_VAR_POPDEF([CACHEVAR])dnl
+])dnl AX_CHECK_COMPILE_FLAGS