[gn] Support for building libcxxabi

This change introduces support for building libcxxabi. The library
build should be complete, but not all CMake options have been
replicated in GN. We also don't support tests yet.

We only support two stage build at the moment.

Differential Revision: https://reviews.llvm.org/D60372

git-svn-id: https://llvm.org/svn/llvm-project/llvm/trunk@359805 91177308-0d34-0410-b5e6-96231b3b80d8

diff --git a/utils/gn/secondary/BUILD.gn b/utils/gn/secondary/BUILD.gn
index af0c85711c46a9a58064efb9bc4806364db7d209..faefc371ffeff8787f9cd473a9ceefffcdd1a73a 100644 (file)
--- a/utils/gn/secondary/BUILD.gn
+++ b/utils/gn/secondary/BUILD.gn
@@ -13,6 +13,7 @@ group("default") {
   if (current_os == "linux") {
     deps += [
       "//compiler-rt",
+      "//libcxxabi",
       "//libunwind",
     ]
   }

diff --git a/utils/gn/secondary/libcxxabi/BUILD.gn b/utils/gn/secondary/libcxxabi/BUILD.gn
new file mode 100644 (file)
index 0000000..7f1e15f
--- /dev/null
+++ b/utils/gn/secondary/libcxxabi/BUILD.gn
@@ -0,0 +1,5 @@
+group("libcxxabi") {
+  deps = [
+    "//libcxxabi/src(//llvm/utils/gn/build/toolchain:stage2_unix)",
+  ]
+}

diff --git a/utils/gn/secondary/libcxxabi/src/BUILD.gn b/utils/gn/secondary/libcxxabi/src/BUILD.gn
new file mode 100644 (file)
index 0000000..3175bef
--- /dev/null
+++ b/utils/gn/secondary/libcxxabi/src/BUILD.gn
@@ -0,0 +1,145 @@
+import("//clang/runtimes.gni")
+
+declare_args() {
+  # Use exceptions.
+  libcxxabi_enable_exceptions = true
+
+  # Build libc++abi with definitions for operator new/delete.
+  libcxxabi_enable_new_delete_definitions = true
+
+  # Build libcxxabi as a shared library.
+  libcxxabi_enable_shared = true
+
+  # Build libcxxabi as a static library.
+  libcxxabi_enable_static = true
+
+  # Do not export any symbols from the static library.
+  libcxxabi_hermetic_static_library = true
+}
+
+cxxabi_headers = [
+  # This comment prevents `gn format` from putting the file on the same line
+  # as `sources +=`, for sync_source_lists_from_cmake.py.
+  "../include/cxxabi.h",
+]
+
+cxxabi_sources = [
+  # C++ABI files
+  "cxa_aux_runtime.cpp",
+  "cxa_default_handlers.cpp",
+  "cxa_demangle.cpp",
+  "cxa_exception_storage.cpp",
+  "cxa_guard.cpp",
+  "cxa_handlers.cpp",
+  "cxa_unexpected.cpp",
+  "cxa_vector.cpp",
+  "cxa_virtual.cpp",
+
+  # C++ STL files
+  "stdlib_exception.cpp",
+  "stdlib_stdexcept.cpp",
+  "stdlib_typeinfo.cpp",
+
+  # Internal files
+  "abort_message.cpp",
+  "fallback_malloc.cpp",
+  "private_typeinfo.cpp",
+]
+if (libcxxabi_enable_new_delete_definitions) {
+  cxxabi_sources += [ "stdlib_new_delete.cpp" ]
+}
+if (libcxxabi_enable_exceptions) {
+  cxxabi_sources += [
+    "cxa_exception.cpp",
+    "cxa_personality.cpp",
+  ]
+} else {
+  cxxabi_sources += [
+    # This comment prevents `gn format` from putting the file on the same line
+    # as `sources +=`, for sync_source_lists_from_cmake.py.
+    "cxa_noexception.cpp",
+  ]
+}
+if (target_os == "linux" || target_os == "fuchsia") {
+  cxxabi_sources += [
+    # This comment prevents `gn format` from putting the file on the same line
+    # as `sources +=`, for sync_source_lists_from_cmake.py.
+    "cxa_thread_atexit.cpp"
+  ]
+}
+
+config("cxxabi_config") {
+  include_dirs = [
+    "//libcxxabi/include",
+    "//libcxx/include",
+  ]
+  cflags_cc = [ "-nostdinc++" ]
+  defines = [ "_LIBCXXABI_BUILDING_LIBRARY" ]
+  if (target_os == "win") {
+    defines += [ "_LIBCXXABI_DISABLE_VISIBILITY_ANNOTATIONS" ]
+  }
+}
+
+if (libcxxabi_enable_shared) {
+  shared_library("cxxabi_shared") {
+    output_dir = runtimes_dir
+    output_name = "c++abi"
+    if (target_os == "linux" || target_os == "mac") {
+      cflags = [ "-fPIC" ]
+      ldflags = [ "-nostdlib++" ]
+      libs = [
+        "dl",
+        "pthread",
+      ]
+    }
+    sources = cxxabi_sources
+    public = cxxabi_headers
+    deps = [
+      "//compiler-rt/lib/builtins",
+      "//libunwind/src:unwind_shared",
+    ]
+    configs += [ ":cxxabi_config" ]
+    configs -= [
+      "//llvm/utils/gn/build:no_exceptions",
+      "//llvm/utils/gn/build:no_rtti",
+    ]
+  }
+}
+
+if (libcxxabi_enable_static) {
+  static_library("cxxabi_static") {
+    output_dir = runtimes_dir
+    output_name = "c++abi"
+    complete_static_lib = true
+    configs -= [ "//llvm/utils/gn/build:thin_archive" ]
+    sources = cxxabi_sources
+    public = cxxabi_headers
+    if (libcxxabi_hermetic_static_library) {
+      cflags = [ "-fvisibility=hidden" ]
+      cflags_cc = [ "-fvisibility-global-new-delete-hidden" ]
+      defines = [
+        "_LIBCXXABI_DISABLE_VISIBILITY_ANNOTATIONS",
+        "_LIBCPP_DISABLE_VISIBILITY_ANNOTATIONS",
+      ]
+    }
+    deps = [
+      "//compiler-rt/lib/builtins",
+      "//libunwind/src:unwind_static",
+    ]
+    configs += [ ":cxxabi_config" ]
+    configs -= [
+      "//llvm/utils/gn/build:no_exceptions",
+      "//llvm/utils/gn/build:no_rtti",
+    ]
+  }
+}
+
+group("src") {
+  deps = []
+  if (libcxxabi_enable_shared) {
+    deps += [ ":cxxabi_shared" ]
+  }
+  if (libcxxabi_enable_static) {
+    deps += [ ":cxxabi_static" ]
+  }
+}