Add wombat to build system.

git-svn-id: https://svn.apache.org/repos/asf/httpd/httpd/branches/wombat-integration@723618 13f79535-47bb-0310-9956-ffa450edef68

diff --git a/modules/wombat/Makefile.in b/modules/wombat/Makefile.in
new file mode 100644 (file)
index 0000000..7c5c149
--- /dev/null
+++ b/modules/wombat/Makefile.in
@@ -0,0 +1,3 @@
+# a modules Makefile has no explicit targets -- they will be defined by
+# whatever modules are enabled. just grab special.mk to deal with this.
+include $(top_srcdir)/build/special.mk

diff --git a/modules/wombat/config.m4 b/modules/wombat/config.m4
new file mode 100644 (file)
index 0000000..7f46f33
--- /dev/null
+++ b/modules/wombat/config.m4
@@ -0,0 +1,104 @@
+
+APACHE_MODPATH_INIT(wombat)
+
+dnl Check for Lua 5.1 Libraries
+dnl CHECK_LUA(ACTION-IF-FOUND [, ACTION-IF-NOT-FOUND])
+dnl Sets:
+dnl  LUA_CFLAGS
+dnl  LUA_LIBS
+AC_DEFUN([CHECK_LUA],
+[dnl
+
+AC_ARG_WITH(
+    lua,
+    [AC_HELP_STRING([--with-lua=PATH],[Path to the Lua 5.1 prefix])],
+    lua_path="$withval",
+    :)
+
+dnl # Determine lua lib directory
+if test -z $lua_path; then
+    test_paths="/usr/local /usr"
+else
+    test_paths="${lua_path}"
+fi
+
+AC_CHECK_LIB([m], [pow], lib_m=" -lm")
+for x in $test_paths ; do
+    AC_MSG_CHECKING([for lua.h in ${x}/include/lua5.1])
+    if test -f ${x}/include/lua5.1/lua.h; then
+        AC_MSG_RESULT([yes])
+        save_CFLAGS=$CFLAGS
+        save_LDFLAGS=$LDFLAGS
+        CFLAGS="$CFLAGS"
+        LDFLAGS="-L$x/lib $LDFLAGS $lib_m"
+        AC_CHECK_LIB(lua5.1, luaL_newstate,
+            [
+            LUA_LIBS="-L$x/lib -llua5.1"
+            LUA_CFLAGS="-I$x/include/lua5.1"
+            ])
+        CFLAGS=$save_CFLAGS
+        LDFLAGS=$save_LDFLAGS
+        break
+    else
+        AC_MSG_RESULT([no])
+    fi
+    AC_MSG_CHECKING([for lua.h in ${x}/include/lua51])
+    if test -f ${x}/include/lua51/lua.h; then
+        AC_MSG_RESULT([yes])
+        save_CFLAGS=$CFLAGS
+        save_LDFLAGS=$LDFLAGS
+        CFLAGS="$CFLAGS"
+        LDFLAGS="-L$x/lib/lua51 $LDFLAGS $lib_m"
+        AC_CHECK_LIB(lua, luaL_newstate,
+            [
+            LUA_LIBS="-L$x/lib/lua51 -llua"
+            LUA_CFLAGS="-I$x/include/lua51"
+            ])
+        CFLAGS=$save_CFLAGS
+        LDFLAGS=$save_LDFLAGS
+        break
+    else
+        AC_MSG_RESULT([no])
+    fi
+    AC_MSG_CHECKING([for lua.h in ${x}/include])
+    if test -f ${x}/include/lua.h; then
+        AC_MSG_RESULT([yes])
+        save_CFLAGS=$CFLAGS
+        save_LDFLAGS=$LDFLAGS
+        CFLAGS="$CFLAGS"
+        LDFLAGS="-L$x/lib $LDFLAGS $lib_m"
+        AC_CHECK_LIB(lua, luaL_newstate,
+            [
+            LUA_LIBS="-L$x/lib -llua"
+            LUA_CFLAGS="-I$x/include"
+            ])
+        CFLAGS=$save_CFLAGS
+        LDFLAGS=$save_LDFLAGS
+        break
+    else
+        AC_MSG_RESULT([no])
+    fi
+done
+
+AC_SUBST(LUA_LIBS)
+AC_SUBST(LUA_CFLAGS)
+
+if test -z "${LUA_LIBS}"; then
+  AC_MSG_NOTICE([*** Lua 5.1 library not found.])
+  ifelse([$2], , AC_MSG_ERROR([Lua 5.1 library is required]), $2)
+else
+  AC_MSG_NOTICE([using '${LUA_LIBS}' for Lua Library])
+  ifelse([$1], , , $1) 
+fi 
+])
+
+wombat_objects="apr_lua.lo config.lo mod_wombat.lo request.lo vmprep.lo"
+
+APACHE_MODULE(wombat, Apache Lua Framework, , , yes,
+[
+CHECK_LUA()
+APR_ADDTO(LIBS, ["$LUA_LIBS"])
+APR_ADDTO(INCLUDES, ["$LUA_CFLAGS"])
+])
+
+APACHE_MODPATH_FINISH