+dnl Same as APACHE_MODPATH_INIT/FINISH but for MPMs
+dnl APACHE_MPMPATH_INIT(mpmpath)
+AC_DEFUN(APACHE_MPMPATH_INIT,[
+ current_dir=$1
+ modpath_current=server/mpm/$1
+ modpath_static=
+ modpath_shared=
+ for var in mod_buildvars; do
+ eval MOD_$var=
+ done
+ test -d $1 || $srcdir/build/mkdir.sh $modpath_current
+ > $modpath_current/modules.mk
+])dnl
+dnl
+AC_DEFUN(APACHE_MPMPATH_FINISH,[
+ for var in mod_buildvars; do
+ if eval val=\"\$MOD_$var\"; test -n "$val"; then
+ echo "MOD_$var = $val" >> $modpath_current/modules.mk
+ fi
+ done
+])dnl
+
+dnl
+dnl APACHE_MPM_MODULE(name[, shared[, objects[, config[, path[, libs]]]]])
+dnl
+dnl Provide information for building the MPM. (Enablement is handled using
+dnl --with-mpm/--enable-mpms-shared.)
+dnl
+dnl name -- name of MPM, same as MPM directory name
+dnl shared -- "shared" to indicate shared module build, empty string otherwise
+dnl objects -- one or more .lo files to link into the MPM module (default: mpmname.lo)
+dnl config -- configuration logic to run if the MPM is enabled
+dnl path -- relative path to MPM (default: server/mpm/mpmname)
+dnl libs -- libs needed by this MPM
+dnl
+AC_DEFUN(APACHE_MPM_MODULE,[
+ if ap_mpm_is_enabled $1; then
+ if test -z "$3"; then
+ objects="$1.lo"
+ else
+ objects="$3"
+ fi
+
+ if test -z "$5"; then
+ mpmpath="server/mpm/$1"
+ else
+ mpmpath=$5
+ fi
+
+ dnl VPATH support
+ test -d $mpmpath || $srcdir/build/mkdir.sh $mpmpath
+
+ APACHE_FAST_OUTPUT($mpmpath/Makefile)
+
+ if test -z "$2"; then
+ APR_ADDTO(AP_LIBS, [$6])
+ libname="lib$1.la"
+ cat >>$mpmpath/modules.mk<<EOF
+$libname: $objects
+ \$(MOD_LINK) $objects
+DISTCLEAN_TARGETS = modules.mk
+static = $libname
+shared =
+EOF
+ else
+ apache_need_shared=yes
+ libname="mod_mpm_$1.la"
+ shobjects=`echo $objects | sed 's/\.lo/.slo/g'`
+ cat >>$mpmpath/modules.mk<<EOF
+$libname: $shobjects
+ \$(SH_LINK) -rpath \$(libexecdir) -module -avoid-version $objects $6
+DISTCLEAN_TARGETS = modules.mk
+static =
+shared = $libname
+EOF
+ DSO_MODULES="$DSO_MODULES mpm_$1"
+ # add default MPM to LoadModule list
+ if test $1 = $default_mpm; then
+ ENABLED_DSO_MODULES="${ENABLED_DSO_MODULES},mpm_$1"
+ fi
+ fi
+ $4
+ fi
+])dnl