granicus.if.org Git - icinga2/blob - tools/mkunity/CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2017 Icinga Development Team (https://www.icinga.com/)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 define_property(
  19   SOURCE
  20   PROPERTY EXCLUDE_UNITY_BUILD
  21   BRIEF_DOCS "Whether to exclude the source file from unity builds"
  22   FULL_DOCS "Specified whether a source file should be excluded from unity builds and should be built separately"
  23 )
  24
  25 if(ICINGA2_UNITY_BUILD)
  26     add_executable(mkunity mkunity.c)
  27
  28     set_target_properties (
  29       mkunity PROPERTIES
  30       FOLDER Bin
  31     )
  32
  33     function(MKUNITY_TARGET Target Prefix UnityInputRef)
  34         set(UnityInput ${${UnityInputRef}})
  35         set(UnityOutput ${CMAKE_CURRENT_BINARY_DIR}/${Target}_unity.cpp)
  36         set(RealSources "")
  37         set(UnitySources "")
  38         foreach(UnitySource ${UnityInput})
  39             get_property(SourceExcluded SOURCE ${UnitySource} PROPERTY EXCLUDE_UNITY_BUILD)
  40             if(SourceExcluded MATCHES TRUE OR NOT ${UnitySource} MATCHES "\\.(cpp|cxx|cc)\$")
  41                 list(APPEND RealSources ${UnitySource})
  42             else()
  43                 list(APPEND UnitySources ${UnitySource})
  44             endif()
  45         endforeach()
  46         add_custom_command(
  47             OUTPUT ${UnityOutput}
  48             COMMAND mkunity
  49             ARGS ${Prefix} ${UnitySources} > ${UnityOutput}.tmp
  50             COMMAND ${CMAKE_COMMAND}
  51             ARGS -E copy ${UnityOutput}.tmp ${UnityOutput}
  52             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  53             DEPENDS mkunity ${UnityInput}
  54         )
  55         list(APPEND RealSources ${UnityOutput})
  56         set(${UnityInputRef} ${RealSources} PARENT_SCOPE)
  57     endfunction()
  58 endif()