granicus.if.org Git - icinga2/blob - tools/mkunity/CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2018 Icinga Development Team (https://www.icinga.com/)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 define_property(
  19   SOURCE
  20   PROPERTY EXCLUDE_UNITY_BUILD
  21   BRIEF_DOCS "Whether to exclude the source file from unity builds"
  22   FULL_DOCS "Specified whether a source file should be excluded from unity builds and should be built separately"
  23 )
  24
  25 if(ICINGA2_UNITY_BUILD)
  26     set(mkunity_SOURCES
  27       mkunity.c
  28     )
  29
  30     add_executable(mkunity ${mkunity_SOURCES})
  31
  32     set_target_properties (
  33       mkunity PROPERTIES
  34       FOLDER Bin
  35     )
  36
  37     function(MKUNITY_TARGET Target Prefix UnityInputRef)
  38         set(UnityInput ${${UnityInputRef}})
  39         set(UnityOutput ${CMAKE_CURRENT_BINARY_DIR}/${Target}_unity.cpp)
  40         set(RealSources "")
  41         set(UnitySources "")
  42         foreach(UnitySource ${UnityInput})
  43             get_property(SourceExcluded SOURCE ${UnitySource} PROPERTY EXCLUDE_UNITY_BUILD)
  44             if(SourceExcluded MATCHES TRUE OR NOT ${UnitySource} MATCHES "\\.(cpp|cxx|cc)\$")
  45                 list(APPEND RealSources ${UnitySource})
  46             else()
  47                 list(APPEND UnitySources ${UnitySource})
  48             endif()
  49         endforeach()
  50         add_custom_command(
  51             OUTPUT ${UnityOutput}
  52             COMMAND mkunity
  53             ARGS ${Prefix} ${UnitySources} > ${UnityOutput}.tmp
  54             COMMAND ${CMAKE_COMMAND}
  55             ARGS -E copy ${UnityOutput}.tmp ${UnityOutput}
  56             WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
  57             DEPENDS mkunity ${UnityInput}
  58         )
  59         list(APPEND RealSources ${UnityOutput})
  60         set(${UnityInputRef} ${RealSources} PARENT_SCOPE)
  61     endfunction()
  62 endif()