granicus.if.org Git - apache/blob - support/apxs.in

   1 #!@perlbin@ -w
   2 #
   3 # Licensed to the Apache Software Foundation (ASF) under one or more
   4 # contributor license agreements.  See the NOTICE file distributed with
   5 # this work for additional information regarding copyright ownership.
   6 # The ASF licenses this file to You under the Apache License, Version 2.0
   7 # (the "License"); you may not use this file except in compliance with
   8 # the License.  You may obtain a copy of the License at
   9 #
  10 #     http://www.apache.org/licenses/LICENSE-2.0
  11 #
  12 # Unless required by applicable law or agreed to in writing, software
  13 # distributed under the License is distributed on an "AS IS" BASIS,
  14 # WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
  15 # See the License for the specific language governing permissions and
  16 # limitations under the License.
  17
  18 require 5.004;
  19 use strict;
  20 package apxs;
  21
  22 ##
  23 ##  Configuration
  24 ##
  25
  26 my %config_vars = ();
  27
  28 my $installbuilddir = "@exp_installbuilddir@";
  29 get_config_vars("$installbuilddir/config_vars.mk",\%config_vars);
  30
  31 # read the configuration variables once
  32
  33 my $prefix         = get_vars("prefix");
  34 my $CFG_PREFIX     = $prefix;
  35 my $exec_prefix    = get_vars("exec_prefix");
  36 my $datadir        = get_vars("datadir");
  37 my $localstatedir  = get_vars("localstatedir");
  38 my $CFG_TARGET     = get_vars("progname");
  39 my $CFG_SYSCONFDIR = get_vars("sysconfdir");
  40 my $CFG_CFLAGS     = join ' ', map { get_vars($_) }
  41   qw(SHLTCFLAGS CFLAGS NOTEST_CPPFLAGS EXTRA_CPPFLAGS EXTRA_CFLAGS);
  42 my $includedir     = get_vars("includedir");
  43 my $CFG_INCLUDEDIR = eval qq("$includedir");
  44 my $CFG_CC         = get_vars("CC");
  45 my $libexecdir     = get_vars("libexecdir");
  46 my $CFG_LIBEXECDIR = eval qq("$libexecdir");
  47 my $sbindir        = get_vars("sbindir");
  48 my $CFG_SBINDIR    = eval qq("$sbindir");
  49 my $ltflags        = $ENV{'LTFLAGS'};
  50 $ltflags or $ltflags = "--silent";
  51
  52 my %internal_vars = map {$_ => 1}
  53     qw(TARGET CC CFLAGS CFLAGS_SHLIB LD_SHLIB LDFLAGS_SHLIB LIBS_SHLIB
  54        PREFIX SBINDIR INCLUDEDIR LIBEXECDIR SYSCONFDIR);
  55
  56 ##
  57 ##  parse argument line
  58 ##
  59
  60 #   defaults for parameters
  61 my $opt_n = '';
  62 my $opt_g = '';
  63 my $opt_c = 0;
  64 my $opt_o = '';
  65 my @opt_D = ();
  66 my @opt_I = ();
  67 my @opt_L = ();
  68 my @opt_l = ();
  69 my @opt_W = ();
  70 my @opt_S = ();
  71 my $opt_e = 0;
  72 my $opt_i = 0;
  73 my $opt_a = 0;
  74 my $opt_A = 0;
  75 my $opt_q = 0;
  76 my $opt_h = 0;
  77 my $opt_p = 0;
  78 my $opt_v = 0;
  79
  80 #   this subroutine is derived from Perl's getopts.pl with the enhancement of
  81 #   the "+" metacharacter at the format string to allow a list to be built by
  82 #   subsequent occurrences of the same option.
  83 sub Getopts {
  84     my ($argumentative, @ARGV) = @_;
  85     my $errs = 0;
  86     local $_;
  87
  88     my @args = split / */, $argumentative;
  89     while (@ARGV && ($_ = $ARGV[0]) =~ /^-(.)(.*)/) {
  90         my ($first, $rest) = ($1,$2);
  91         if ($_ =~ m|^--$|) {
  92             shift @ARGV;
  93             last;
  94         }
  95         my $pos = index($argumentative,$first);
  96         if ($pos >= 0) {
  97             if ($pos < $#args && $args[$pos+1] eq ':') {
  98                 shift @ARGV;
  99                 if ($rest eq '') {
 100                     unless (@ARGV) {
 101                         error("Incomplete option: $first (needs an argument)");
 102                         $errs++;
 103                     }
 104                     $rest = shift(@ARGV);
 105                 }
 106                 eval "\$opt_$first = \$rest;";
 107             }
 108             elsif ($pos < $#args && $args[$pos+1] eq '+') {
 109                 shift @ARGV;
 110                 if ($rest eq '') {
 111                     unless (@ARGV) {
 112                         error("Incomplete option: $first (needs an argument)");
 113                         $errs++;
 114                     }
 115                     $rest = shift(@ARGV);
 116                 }
 117                 eval "push(\@opt_$first, \$rest);";
 118             }
 119             else {
 120                 eval "\$opt_$first = 1";
 121                 if ($rest eq '') {
 122                     shift(@ARGV);
 123                 }
 124                 else {
 125                     $ARGV[0] = "-$rest";
 126                 }
 127             }
 128         }
 129         else {
 130             error("Unknown option: $first");
 131             $errs++;
 132             if ($rest ne '') {
 133                 $ARGV[0] = "-$rest";
 134             }
 135             else {
 136                 shift(@ARGV);
 137             }
 138         }
 139     }
 140     return ($errs == 0, @ARGV);
 141 }
 142
 143 sub usage {
 144     print STDERR "Usage: apxs -g [-S <var>=<val>] -n <modname>\n";
 145     print STDERR "       apxs -q [-v] [-S <var>=<val>] [<query> ...]\n";
 146     print STDERR "       apxs -c [-S <var>=<val>] [-o <dsofile>] [-D <name>[=<value>]]\n";
 147     print STDERR "               [-I <incdir>] [-L <libdir>] [-l <libname>] [-Wc,<flags>]\n";
 148     print STDERR "               [-Wl,<flags>] [-p] <files> ...\n";
 149     print STDERR "       apxs -i [-S <var>=<val>] [-a] [-A] [-n <modname>] <dsofile> ...\n";
 150     print STDERR "       apxs -e [-S <var>=<val>] [-a] [-A] [-n <modname>] <dsofile> ...\n";
 151     exit(1);
 152 }
 153
 154 #   option handling
 155 my $rc;
 156 ($rc, @ARGV) = &Getopts("qn:gco:I+D+L+l+W+S+eiaApv", @ARGV);
 157 &usage if ($rc == 0);
 158 &usage if ($#ARGV == -1 and not $opt_g and not $opt_q);
 159 &usage if (not $opt_q and not ($opt_g and $opt_n) and not $opt_i and not $opt_c and not $opt_e);
 160
 161 #   argument handling
 162 my @args = @ARGV;
 163 my $name = 'unknown';
 164 $name = $opt_n if ($opt_n ne '');
 165
 166 if (@opt_S) {
 167     my ($opt_S);
 168     foreach $opt_S (@opt_S) {
 169         if ($opt_S =~ m/^([^=]+)=(.*)$/) {
 170             my ($var) = $1;
 171             my ($val) = $2;
 172             my $oldval = eval "\$CFG_$var";
 173
 174             unless ($var and $oldval) {
 175                 print STDERR "apxs:Error: no config variable $var\n";
 176                 &usage;
 177             }
 178
 179             eval "\$CFG_${var}=\"${val}\"";
 180         } else {
 181             print STDERR "apxs:Error: malformatted -S option\n";
 182             &usage;
 183         }
 184     }
 185 }
 186
 187 ##
 188 ##  Initial shared object support check
 189 ##
 190 unless ("@MOD_SO_ENABLED@" eq "yes") {
 191     error("Sorry, no shared object support for Apache");
 192     error("available under your platform. Make sure");
 193     error("the Apache module mod_so is compiled into");
 194     error("the server binary.");
 195     exit 1;
 196 }
 197
 198 sub get_config_vars{
 199     my ($file, $rh_config) = @_;
 200
 201     open IN, $file or die "cannot open $file: $!";
 202     while (<IN>){
 203         if (/^\s*(.*?)\s*=\s*(.*)$/){
 204             $rh_config->{$1} = $2;
 205         }
 206     }
 207     close IN;
 208 }
 209
 210 sub get_vars {
 211     my $result = '';
 212     my $ok = 0;
 213     my $arg;
 214     foreach $arg (@_) {
 215         if (exists $config_vars{$arg} or exists $config_vars{lc $arg}) {
 216             my $val = exists $config_vars{$arg}
 217                 ? $config_vars{$arg}
 218                 : $config_vars{lc $arg};
 219             $val =~ s/[()]//g;
 220             $result .= eval "qq($val)" if defined $val;
 221             $result .= ";;";
 222             $ok = 1;
 223         }
 224         if (not $ok) {
 225             if (exists $internal_vars{$arg} or exists $internal_vars{lc $arg}) {
 226                 my $val = exists $internal_vars{$arg} ? $arg : lc $arg;
 227                 $val = eval "\$CFG_$val";
 228                 $result .= eval "qq($val)" if defined $val;
 229                 $result .= ";;";
 230                 $ok = 1;
 231             }
 232             if (not $ok) {
 233                 error("Invalid query string `$arg'");
 234                 exit(1);
 235             }
 236         }
 237     }
 238     $result =~ s|;;$||;
 239     return $result;
 240 }
 241
 242 ##
 243 ##  Operation
 244 ##
 245
 246 #   helper function for executing a list of
 247 #   system command with return code checks
 248 sub execute_cmds {
 249     my (@cmds) = @_;
 250     my ($cmd, $rc);
 251
 252     foreach $cmd (@cmds) {
 253         notice($cmd);
 254         $rc = system $cmd;
 255         if ($rc) {
 256             error(sprintf "Command failed with rc=%d\n", $rc << 8);
 257             exit 1 ;
 258         }
 259     }
 260 }
 261
 262 if ($opt_g) {
 263     ##
 264     ##  SAMPLE MODULE SOURCE GENERATION
 265     ##
 266
 267     if (-d $name) {
 268         error("Directory `$name' already exists. Remove first");
 269         exit(1);
 270     }
 271
 272     my $data = join('', <DATA>);
 273     $data =~ s|%NAME%|$name|sg;
 274     $data =~ s|%TARGET%|$CFG_TARGET|sg;
 275     $data =~ s|%PREFIX%|$prefix|sg;
 276     $data =~ s|%INSTALLBUILDDIR%|$installbuilddir|sg;
 277
 278     my ($mkf, $mods, $src) = ($data =~ m|^(.+)-=#=-\n(.+)-=#=-\n(.+)|s);
 279
 280     notice("Creating [DIR]  $name");
 281     system("mkdir $name");
 282     notice("Creating [FILE] $name/Makefile");
 283     open(FP, ">${name}/Makefile") || die;
 284     print FP $mkf;
 285     close(FP);
 286     notice("Creating [FILE] $name/modules.mk");
 287     open(FP, ">${name}/modules.mk") || die;
 288     print FP $mods;
 289     close(FP);
 290     notice("Creating [FILE] $name/mod_$name.c");
 291     open(FP, ">${name}/mod_${name}.c") || die;
 292     print FP $src;
 293     close(FP);
 294     notice("Creating [FILE] $name/.deps");
 295     system("touch ${name}/.deps");
 296
 297     exit(0);
 298 }
 299
 300
 301 if ($opt_q) {
 302     ##
 303     ##  QUERY INFORMATION
 304     ##
 305     my $result;
 306     if ($#args >= 0) {
 307         $result = get_vars(@args);
 308         print "$result\n";
 309     } else {
 310         # -q without var name prints all variables and their values
 311
 312         # Additional -v pretty-prints output
 313         if ($opt_v) {
 314             # Variable names in alphabetic order
 315             my @vars = sort {uc($a) cmp uc($b)} keys %config_vars;
 316
 317             # Make the left column as wide as the longest variable name
 318             my $width = 0;
 319             foreach (@vars) {
 320                 my $l = length $_;
 321                 $width = $l unless ($l <= $width);
 322             }
 323
 324             foreach (@vars) {
 325                 printf "%-${width}s = %s\n", $_, $config_vars{$_};
 326             }
 327         } else {
 328             # Unprettified name=value list
 329             foreach (keys %config_vars) {
 330                 print "$_=$config_vars{$_}\n";
 331             }
 332         }
 333     }
 334 }
 335
 336 my $apr_config = get_vars("APR_CONFIG");
 337
 338 if (! -x "$apr_config") {
 339     error("$apr_config not found!");
 340     exit(1);
 341 }
 342
 343 my $apr_major_version = (split /\./, `$apr_config --version`)[0];
 344
 345 my $apu_config = "";
 346 if ($apr_major_version < 2) {
 347     $apu_config = get_vars("APU_CONFIG");
 348
 349     if (! -x "$apu_config") {
 350         error("$apu_config not found!");
 351         exit(1);
 352     }
 353 }
 354
 355 my $libtool = `$apr_config --apr-libtool`;
 356 chomp($libtool);
 357
 358 my $apr_includedir = `$apr_config --includes`;
 359 chomp($apr_includedir);
 360 my $apu_includedir = "";
 361 if ($apr_major_version < 2) {
 362     $apu_includedir = `$apu_config --includes`;
 363     chomp($apu_includedir);
 364 }
 365
 366 if ($opt_c) {
 367     ##
 368     ##  SHARED OBJECT COMPILATION
 369     ##
 370
 371     #   split files into sources and objects
 372     my @srcs = ();
 373     my @objs = ();
 374     my $f;
 375     foreach $f (@args) {
 376         if ($f =~ m|\.c$|) {
 377             push(@srcs, $f);
 378         }
 379         else {
 380             push(@objs, $f);
 381         }
 382     }
 383
 384     #   determine output file
 385     my $dso_file;
 386     if ($opt_o eq '') {
 387         if ($#srcs > -1) {
 388             $dso_file = $srcs[0];
 389             $dso_file =~ s|\.[^.]+$|.la|;
 390         }
 391         elsif ($#objs > -1) {
 392             $dso_file = $objs[0];
 393             $dso_file =~ s|\.[^.]+$|.la|;
 394         }
 395         else {
 396             $dso_file = "mod_unknown.la";
 397         }
 398     }
 399     else {
 400         $dso_file = $opt_o;
 401         $dso_file =~ s|\.[^.]+$|.la|;
 402     }
 403
 404     #   create compilation commands
 405     my @cmds = ();
 406     my $opt = '';
 407     my ($opt_Wc, $opt_I, $opt_D);
 408     foreach $opt_Wc (@opt_W) {
 409         $opt .= "$1 " if ($opt_Wc =~ m|^\s*c,(.*)$|);
 410     }
 411     foreach $opt_I (@opt_I) {
 412         $opt .= "-I$opt_I ";
 413     }
 414     foreach $opt_D (@opt_D) {
 415         $opt .= "-D$opt_D ";
 416     }
 417     my $cflags = "$CFG_CFLAGS";
 418     my $s;
 419     my $mod;
 420     foreach $s (@srcs) {
 421         my $slo = $s;
 422         $slo =~ s|\.c$|.slo|;
 423         my $lo = $s;
 424         $lo =~ s|\.c$|.lo|;
 425         my $la = $s;
 426         $la =~ s|\.c$|.la|;
 427         my $o = $s;
 428         $o =~ s|\.c$|.o|;
 429         push(@cmds, "$libtool $ltflags --mode=compile $CFG_CC $cflags -I$CFG_INCLUDEDIR $apr_includedir $apu_includedir $opt -c -o $lo $s && touch $slo");
 430         unshift(@objs, $lo);
 431     }
 432
 433     #   create link command
 434     my $o;
 435     my $lo;
 436     foreach $o (@objs) {
 437         $lo .= " $o";
 438     }
 439     my ($opt_Wl, $opt_L, $opt_l);
 440     $opt = '';
 441     foreach $opt_Wl (@opt_W) {
 442         $opt .= "$1 " if ($opt_Wl =~ m|^\s*l,(.*)$|);
 443     }
 444     foreach $opt_L (@opt_L) {
 445         $opt .= " -L$opt_L";
 446     }
 447     foreach $opt_l (@opt_l) {
 448         $opt .= " -l$opt_l";
 449     }
 450
 451     if ($opt_p == 1) {
 452
 453         my $apr_libs=`$apr_config --cflags --ldflags --link-libtool --libs`;
 454         chomp($apr_libs);
 455         my $apu_libs="";
 456         if ($apr_major_version < 2) {
 457             $apu_libs=`$apu_config --ldflags --link-libtool --libs`;
 458             chomp($apu_libs);
 459         }
 460
 461         $opt .= " ".$apu_libs." ".$apr_libs;
 462     }
 463     else {
 464         my $apr_ldflags=`$apr_config --ldflags`;
 465         chomp($apr_ldflags);
 466         $opt .= " -rpath $CFG_LIBEXECDIR -module -avoid-version $apr_ldflags";
 467     }
 468
 469     push(@cmds, "$libtool $ltflags --mode=link $CFG_CC -o $dso_file $opt $lo");
 470
 471     #   execute the commands
 472     &execute_cmds(@cmds);
 473
 474     #   allow one-step compilation and installation
 475     if ($opt_i or $opt_e) {
 476         @args = ( $dso_file );
 477     }
 478 }
 479
 480 if ($opt_i or $opt_e) {
 481     ##
 482     ##  SHARED OBJECT INSTALLATION
 483     ##
 484
 485     #   determine installation commands
 486     #   and corresponding LoadModule directive
 487     my @lmd = ();
 488     my @cmds = ();
 489     my $f;
 490     foreach $f (@args) {
 491         #  ack all potential gcc, hp/ux, win32+os2+aix and os/x extensions
 492         if ($f !~ m#(\.so$|\.la$|\.sl$|\.dll$|\.dylib$|)#) {
 493             error("file $f is not a shared object");
 494             exit(1);
 495         }
 496         my $t = $f;
 497         $t =~ s|^.+/([^/]+)$|$1|;
 498         #  use .so unambigiously for installed shared library modules
 499         $t =~ s|\.[^./\\]+$|\.so|;
 500         if ($opt_i) {
 501             push(@cmds, "$installbuilddir/instdso.sh SH_LIBTOOL='" .
 502                  "$libtool' $f $CFG_LIBEXECDIR");
 503             push(@cmds, "chmod 755 $CFG_LIBEXECDIR/$t");
 504         }
 505
 506         #   determine module symbolname and filename
 507         my $filename = '';
 508         if ($name eq 'unknown') {
 509             $name = '';
 510             my $base = $f;
 511             $base =~ s|\.[^.]+$||;
 512             if (-f "$base.c") {
 513                 open(FP, "<$base.c");
 514                 my $content = join('', <FP>);
 515                 close(FP);
 516                 if ($content =~ m|.*AP_DECLARE_MODULE\s*\(\s*([a-zA-Z0-9_]+)\s*\)\s*=.*|s || $content =~ m|.*module\s+(?:AP_MODULE_DECLARE_DATA\s+)?([a-zA-Z0-9_]+)_module\s*=\s*.*|s) {
 517                     $name = "$1";
 518                     $filename = "$base.c";
 519                     $filename =~ s|^[^/]+/||;
 520                 }
 521             }
 522             if ($name eq '') {
 523                 if ($base =~ m|.*mod_([a-zA-Z0-9_]+)\..+|) {
 524                     $name = "$1";
 525                     $filename = $base;
 526                     $filename =~ s|^[^/]+/||;
 527                 }
 528             }
 529             if ($name eq '') {
 530                 error("Sorry, cannot determine bootstrap symbol name");
 531                 error("Please specify one with option `-n'");
 532                 exit(1);
 533             }
 534         }
 535         if ($filename eq '') {
 536             $filename = "mod_${name}.c";
 537         }
 538         my $dir = $CFG_LIBEXECDIR;
 539         $dir =~ s|^$CFG_PREFIX/?||;
 540         $dir =~ s|(.)$|$1/|;
 541         $t =~ s|\.la$|.so|;
 542         push(@lmd, sprintf("LoadModule %-18s %s", "${name}_module", "$dir$t"));
 543     }
 544
 545     #   execute the commands
 546     &execute_cmds(@cmds);
 547
 548     #   activate module via LoadModule/AddModule directive
 549     if ($opt_a or $opt_A) {
 550         if (not -f "$CFG_SYSCONFDIR/$CFG_TARGET.conf") {
 551             error("Config file $CFG_SYSCONFDIR/$CFG_TARGET.conf not found");
 552             exit(1);
 553         }
 554
 555         open(FP, "<$CFG_SYSCONFDIR/$CFG_TARGET.conf") || die;
 556         my $content = join('', <FP>);
 557         close(FP);
 558
 559         if ($content !~ m|\n#?\s*LoadModule\s+|) {
 560             error("Activation failed for custom $CFG_SYSCONFDIR/$CFG_TARGET.conf file.");
 561             error("At least one `LoadModule' directive already has to exist.");
 562             exit(1);
 563         }
 564
 565         my $lmd;
 566         my $c = '';
 567         $c = '#' if ($opt_A);
 568         foreach $lmd (@lmd) {
 569             my $what = $opt_A ? "preparing" : "activating";
 570             my $lmd_re = $lmd;
 571             $lmd_re =~ s/\s+/\\s+/g;
 572
 573             if ($content !~ m|\n#?\s*$lmd_re|) {
 574                 # check for open <containers>, so that the new LoadModule
 575                 # directive always appears *outside* of an <container>.
 576
 577                 my $before = ($content =~ m|^(.*\n)#?\s*LoadModule\s+[^\n]+\n|s)[0];
 578
 579                 # the '()=' trick forces list context and the scalar
 580                 # assignment counts the number of list members (aka number
 581                 # of matches) then
 582                 my $cntopen = () = ($before =~ m|^\s*<[^/].*$|mg);
 583                 my $cntclose = () = ($before =~ m|^\s*</.*$|mg);
 584
 585                 if ($cntopen == $cntclose) {
 586                     # fine. Last LoadModule is contextless.
 587                     $content =~ s|^(.*\n#?\s*LoadModule\s+[^\n]+\n)|$1$c$lmd\n|s;
 588                 }
 589                 elsif ($cntopen < $cntclose) {
 590                     error('Configuration file is not valid. There are sections'
 591                           . ' closed before opened.');
 592                     exit(1);
 593                 }
 594                 else {
 595                     # put our cmd after the section containing the last
 596                     # LoadModule.
 597                     my $found =
 598                     $content =~ s!\A (               # string and capture start
 599                                   (?:(?:
 600                                     ^\s*             # start of conf line with a
 601                                     (?:[^<]|<[^/])   # directive which does not
 602                                                      # start with '</'
 603
 604                                     .*(?:$)\n        # rest of the line.
 605                                                      # the '$' is in parentheses
 606                                                      # to avoid misinterpreting
 607                                                      # the string "$\" as
 608                                                      # perl variable.
 609
 610                                     )*               # catch as much as possible
 611                                                      # of such lines. (including
 612                                                      # zero)
 613
 614                                     ^\s*</.*(?:$)\n? # after the above, we
 615                                                      # expect a config line with
 616                                                      # a closing container (</)
 617
 618                                   ) {$cntopen}       # the whole pattern (bunch
 619                                                      # of lines that end up with
 620                                                      # a closing directive) must
 621                                                      # be repeated $cntopen
 622                                                      # times. That's it.
 623                                                      # Simple, eh? ;-)
 624
 625                                   )                  # capture end
 626                                  !$1$c$lmd\n!mx;
 627
 628                     unless ($found) {
 629                         error('Configuration file is not valid. There are '
 630                               . 'sections opened and not closed.');
 631                         exit(1);
 632                     }
 633                 }
 634             } else {
 635                 # replace already existing LoadModule line
 636                 $content =~ s|^(.*\n)#?\s*$lmd_re[^\n]*\n|$1$c$lmd\n|s;
 637             }
 638             $lmd =~ m|LoadModule\s+(.+?)_module.*|;
 639             notice("[$what module `$1' in $CFG_SYSCONFDIR/$CFG_TARGET.conf]");
 640         }
 641         if (@lmd) {
 642             if (open(FP, ">$CFG_SYSCONFDIR/$CFG_TARGET.conf.new")) {
 643                 print FP $content;
 644                 close(FP);
 645                 system("cp $CFG_SYSCONFDIR/$CFG_TARGET.conf $CFG_SYSCONFDIR/$CFG_TARGET.conf.bak && " .
 646                        "cp $CFG_SYSCONFDIR/$CFG_TARGET.conf.new $CFG_SYSCONFDIR/$CFG_TARGET.conf && " .
 647                        "rm $CFG_SYSCONFDIR/$CFG_TARGET.conf.new");
 648             } else {
 649                 notice("unable to open configuration file");
 650             }
 651         }
 652     }
 653 }
 654
 655 sub error{
 656     print STDERR "apxs:Error: $_[0].\n";
 657 }
 658
 659 sub notice{
 660     print STDERR "$_[0]\n";
 661 }
 662
 663 ##EOF##
 664 __DATA__
 665 ##
 666 ##  Makefile -- Build procedure for sample %NAME% Apache module
 667 ##  Autogenerated via ``apxs -n %NAME% -g''.
 668 ##
 669
 670 builddir=.
 671 top_srcdir=%PREFIX%
 672 top_builddir=%PREFIX%
 673 include %INSTALLBUILDDIR%/special.mk
 674
 675 #   the used tools
 676 APXS=apxs
 677 APACHECTL=apachectl
 678
 679 #   additional defines, includes and libraries
 680 #DEFS=-Dmy_define=my_value
 681 #INCLUDES=-Imy/include/dir
 682 #LIBS=-Lmy/lib/dir -lmylib
 683
 684 #   the default target
 685 all: local-shared-build
 686
 687 #   install the shared object file into Apache
 688 install: install-modules-yes
 689
 690 #   cleanup
 691 clean:
 692         -rm -f mod_%NAME%.o mod_%NAME%.lo mod_%NAME%.slo mod_%NAME%.la
 693
 694 #   simple test
 695 test: reload
 696         lynx -mime_header http://localhost/%NAME%
 697
 698 #   install and activate shared object by reloading Apache to
 699 #   force a reload of the shared object file
 700 reload: install restart
 701
 702 #   the general Apache start/restart/stop
 703 #   procedures
 704 start:
 705         $(APACHECTL) start
 706 restart:
 707         $(APACHECTL) restart
 708 stop:
 709         $(APACHECTL) stop
 710
 711 -=#=-
 712 mod_%NAME%.la: mod_%NAME%.slo
 713         $(SH_LINK) -rpath $(libexecdir) -module -avoid-version  mod_%NAME%.lo
 714 DISTCLEAN_TARGETS = modules.mk
 715 shared =  mod_%NAME%.la
 716 -=#=-
 717 /*
 718 **  mod_%NAME%.c -- Apache sample %NAME% module
 719 **  [Autogenerated via ``apxs -n %NAME% -g'']
 720 **
 721 **  To play with this sample module first compile it into a
 722 **  DSO file and install it into Apache's modules directory
 723 **  by running:
 724 **
 725 **    $ apxs -c -i mod_%NAME%.c
 726 **
 727 **  Then activate it in Apache's %TARGET%.conf file for instance
 728 **  for the URL /%NAME% in as follows:
 729 **
 730 **    #   %TARGET%.conf
 731 **    LoadModule %NAME%_module modules/mod_%NAME%.so
 732 **    <Location /%NAME%>
 733 **    SetHandler %NAME%
 734 **    </Location>
 735 **
 736 **  Then after restarting Apache via
 737 **
 738 **    $ apachectl restart
 739 **
 740 **  you immediately can request the URL /%NAME% and watch for the
 741 **  output of this module. This can be achieved for instance via:
 742 **
 743 **    $ lynx -mime_header http://localhost/%NAME%
 744 **
 745 **  The output should be similar to the following one:
 746 **
 747 **    HTTP/1.1 200 OK
 748 **    Date: Tue, 31 Mar 1998 14:42:22 GMT
 749 **    Server: Apache/1.3.4 (Unix)
 750 **    Connection: close
 751 **    Content-Type: text/html
 752 **
 753 **    The sample page from mod_%NAME%.c
 754 */
 755
 756 #include "httpd.h"
 757 #include "http_config.h"
 758 #include "http_protocol.h"
 759 #include "ap_config.h"
 760
 761 /* The sample content handler */
 762 static int %NAME%_handler(request_rec *r)
 763 {
 764     if (strcmp(r->handler, "%NAME%")) {
 765         return DECLINED;
 766     }
 767     r->content_type = "text/html";
 768
 769     if (!r->header_only)
 770         ap_rputs("The sample page from mod_%NAME%.c\n", r);
 771     return OK;
 772 }
 773
 774 static void %NAME%_register_hooks(apr_pool_t *p)
 775 {
 776     ap_hook_handler(%NAME%_handler, NULL, NULL, APR_HOOK_MIDDLE);
 777 }
 778
 779 /* Dispatch list for API hooks */
 780 module AP_MODULE_DECLARE_DATA %NAME%_module = {
 781     STANDARD20_MODULE_STUFF,
 782     NULL,                  /* create per-dir    config structures */
 783     NULL,                  /* merge  per-dir    config structures */
 784     NULL,                  /* create per-server config structures */
 785     NULL,                  /* merge  per-server config structures */
 786     NULL,                  /* table of config file commands       */
 787     %NAME%_register_hooks  /* register hooks                      */
 788 };
 789