granicus.if.org Git - apache/blob - server/mpm/config.m4

   1 AC_MSG_CHECKING(which MPM to use)
   2 AC_ARG_WITH(mpm,
   3 [  --with-mpm=MPM          Choose the process model for Apache to use.
   4                           MPM={dexter,mpmt_beos,mpmt_pthread,prefork,spmt_os2}],[
   5   APACHE_MPM=$withval
   6 ],[
   7   APACHE_MPM=mpmt_pthread
   8   case "`uname -sr`" in
   9     "BeOS"*)
  10       APACHE_MPM=mpmt_beos;;
  11     "OS/2"*)
  12       APACHE_MPM=spmt_os2;;
  13   esac
  14 ])
  15 AC_MSG_RESULT($APACHE_MPM)
  16
  17 apache_cv_mpm=$APACHE_MPM
  18
  19 if test "$apache_cv_mpm" = "mpmt_pthread" -o "$apache_cv_mpm" = "dexter"; then
  20   PTHREADS_CHECK
  21   AC_MSG_CHECKING([for which threading library to use])
  22   AC_MSG_RESULT($threads_result)
  23
  24   if test "$apache_threads_working" = "no"; then
  25     AC_MSG_RESULT(The currently selected MPM requires pthreads which your system seems to lack)
  26     AC_MSG_CHECKING(checking for replacement)
  27     AC_MSG_RESULT(prefork selected)
  28     apache_cv_mpm=prefork
  29   fi
  30 fi
  31
  32 APACHE_CHECK_SIGWAIT_ONE_ARG
  33 APACHE_CHECK_SHM_RW
  34
  35 APACHE_FAST_OUTPUT(modules/mpm/Makefile)
  36 MPM_NAME=$apache_cv_mpm
  37 MPM_DIR=modules/mpm/$MPM_NAME
  38 MPM_LIB=$MPM_DIR/lib${MPM_NAME}.la
  39
  40 APACHE_SUBST(MPM_NAME)
  41 MODLIST="$MODLIST mpm_${MPM_NAME}"
  42
  43 dnl All the unix MPMs use shared memory; save a little duplication
  44 AC_DEFUN(APACHE_MPM_CHECK_SHMEM, [
  45     AC_CHECK_FUNCS(shmget)
  46     AC_FUNC_MMAP
  47
  48     AC_MSG_CHECKING(which shared memory mechanism to use)
  49     if test "$ac_cv_func_shmget" = "yes" ; then
  50         AC_DEFINE(USE_SHMGET_SCOREBOARD,,
  51             [Define if MPMs should use shmget to implement their shared memory])
  52         AC_MSG_RESULT(shmget)
  53     elif test "$ac_cv_func_mmap" = "yes" ; then
  54         AC_DEFINE(USE_MMAP_SCOREBOARD,,
  55             [Define if MPMs should use mmap to implement their shared memory])
  56         AC_MSG_RESULT(mmap)
  57     else
  58         AC_MSG_ERROR(No known shared memory system)
  59     fi
  60 ])
  61
  62 dnl Check for pthreads and attempt to support it
  63 AC_DEFUN(APACHE_MPM_PTHREAD, [
  64
  65 dnl XXX - We should be checking for the proper flags to use on a particular
  66 dnl platform. This will cover a couple of them, anyway
  67
  68     AC_CHECK_HEADER(pthread.h, [ ],[
  69         AC_MSG_ERROR(This MPM requires pthreads. Try --with-mpm=prefork.)
  70     ])
  71     AC_CHECK_FUNC(pthread_create, [ ],[
  72         AC_MSG_ERROR(Can't compile pthread code.)
  73     ])
  74
  75     dnl User threads libraries need pthread.h included everywhere
  76     AC_DEFINE(PTHREAD_EVERYWHERE,,
  77         [Define if all code should have #include <pthread.h>])
  78 ])