granicus.if.org Git - clang/blob - runtime/CMakeLists.txt

   1 # TODO: Set the install directory.
   2
   3 include(ExternalProject)
   4
   5 set(known_subdirs
   6   "libcxx"
   7   )
   8
   9 foreach (dir ${known_subdirs})
  10   if (EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/${dir}/CMakeLists.txt)
  11     add_subdirectory(${CMAKE_CURRENT_SOURCE_DIR}/${dir})
  12   endif()
  13 endforeach()
  14
  15 function(get_ext_project_build_command out_var target)
  16   if (CMAKE_GENERATOR MATCHES "Make")
  17     # Use special command for Makefiles to support parallelism.
  18     set(${out_var} "$(MAKE)" "${target}" PARENT_SCOPE)
  19   else()
  20     set(${out_var} ${CMAKE_COMMAND} --build . --target ${target}
  21                                     --config $<CONFIGURATION> PARENT_SCOPE)
  22   endif()
  23 endfunction()
  24
  25 set(COMPILER_RT_SRC_ROOT ${LLVM_MAIN_SRC_DIR}/projects/compiler-rt)
  26 # Fallback to the external path, if the other one isn't available.
  27 # This is the same behavior (try "internal", then check the LLVM_EXTERNAL_...
  28 # variable) as in add_llvm_external_project
  29 if(NOT EXISTS ${COMPILER_RT_SRC_ROOT})
  30   # We don't want to set it if LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR is ""
  31   if(${LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR})
  32     set(COMPILER_RT_SRC_ROOT ${LLVM_EXTERNAL_COMPILER_RT_SOURCE_DIR})
  33   endif()
  34 endif()
  35
  36 if(LLVM_BUILD_EXTERNAL_COMPILER_RT AND EXISTS ${COMPILER_RT_SRC_ROOT}/)
  37   if(CMAKE_VERSION VERSION_GREATER 3.3.20150708)
  38     set(cmake_3_4_USES_TERMINAL_OPTIONS
  39       USES_TERMINAL_CONFIGURE 1
  40       USES_TERMINAL_BUILD 1
  41       USES_TERMINAL_INSTALL 1
  42       )
  43   endif()
  44
  45   # Add compiler-rt as an external project.
  46   set(COMPILER_RT_PREFIX ${CMAKE_BINARY_DIR}/projects/compiler-rt)
  47
  48   set(STAMP_DIR ${CMAKE_CURRENT_BINARY_DIR}/compiler-rt-stamps/)
  49   set(BINARY_DIR ${CMAKE_CURRENT_BINARY_DIR}/compiler-rt-bins/)
  50
  51   add_custom_target(compiler-rt-clear
  52     COMMAND ${CMAKE_COMMAND} -E remove_directory ${BINARY_DIR}
  53     COMMAND ${CMAKE_COMMAND} -E remove_directory ${STAMP_DIR}
  54     COMMENT "Clobberring compiler-rt build and stamp directories"
  55     )
  56
  57   # Find all variables that start with COMPILER_RT and populate a variable with
  58   # them.
  59   get_cmake_property(variableNames VARIABLES)
  60   foreach(variableName ${variableNames})
  61     if(variableName MATCHES "^COMPILER_RT")
  62       string(REPLACE ";" "\;" value "${${variableName}}")
  63       list(APPEND COMPILER_RT_PASSTHROUGH_VARIABLES
  64         -D${variableName}=${value})
  65     endif()
  66   endforeach()
  67
  68   ExternalProject_Add(compiler-rt
  69     DEPENDS llvm-config clang
  70     PREFIX ${COMPILER_RT_PREFIX}
  71     SOURCE_DIR ${COMPILER_RT_SRC_ROOT}
  72     STAMP_DIR ${STAMP_DIR}
  73     BINARY_DIR ${BINARY_DIR}
  74     CMAKE_ARGS ${CLANG_COMPILER_RT_CMAKE_ARGS}
  75                -DCMAKE_C_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang
  76                -DCMAKE_CXX_COMPILER=${LLVM_RUNTIME_OUTPUT_INTDIR}/clang++
  77                -DCMAKE_BUILD_TYPE=${CMAKE_BUILD_TYPE}
  78                -DCMAKE_MAKE_PROGRAM=${CMAKE_MAKE_PROGRAM}
  79                -DLLVM_CONFIG_PATH=${LLVM_RUNTIME_OUTPUT_INTDIR}/llvm-config
  80                -DCOMPILER_RT_OUTPUT_DIR=${LLVM_LIBRARY_OUTPUT_INTDIR}/clang/${CLANG_VERSION}
  81                -DCOMPILER_RT_EXEC_OUTPUT_DIR=${LLVM_RUNTIME_OUTPUT_INTDIR}
  82                -DCOMPILER_RT_INSTALL_PATH:STRING=lib${LLVM_LIBDIR_SUFFIX}/clang/${CLANG_VERSION}
  83                -DCOMPILER_RT_INCLUDE_TESTS=${LLVM_INCLUDE_TESTS}
  84                -DCMAKE_INSTALL_PREFIX=${CMAKE_INSTALL_PREFIX}
  85                -LLVM_LIBDIR_SUFFIX=${LLVM_LIBDIR_SUFFIX}
  86                -Dcmake_3_2_USES_TERMINAL=${cmake_3_2_USES_TERMINAL}
  87                ${COMPILER_RT_PASSTHROUGH_VARIABLES}
  88     INSTALL_COMMAND ""
  89     STEP_TARGETS configure build
  90     ${cmake_3_4_USES_TERMINAL_OPTIONS}
  91     )
  92
  93   get_ext_project_build_command(run_clean_compiler_rt clean)
  94   ExternalProject_Add_Step(compiler-rt clean
  95     COMMAND ${run_clean_compiler_rt}
  96     COMMENT "Cleaning compiler-rt..."
  97     DEPENDEES configure
  98     DEPENDERS build
  99     DEPENDS clang
 100     WORKING_DIRECTORY ${BINARY_DIR}
 101     )
 102
 103   install(CODE "execute_process\(COMMAND \${CMAKE_COMMAND} -DCMAKE_INSTALL_PREFIX=\${CMAKE_INSTALL_PREFIX} -P ${BINARY_DIR}/cmake_install.cmake \)"
 104     COMPONENT compiler-rt)
 105
 106   add_custom_target(install-compiler-rt
 107                     DEPENDS compiler-rt
 108                     COMMAND "${CMAKE_COMMAND}"
 109                              -DCMAKE_INSTALL_COMPONENT=compiler-rt
 110                              -P "${CMAKE_BINARY_DIR}/cmake_install.cmake")
 111
 112   # Add top-level targets that build specific compiler-rt runtimes.
 113   set(COMPILER_RT_RUNTIMES asan builtins dfsan lsan msan profile tsan ubsan)
 114   foreach(runtime ${COMPILER_RT_RUNTIMES})
 115     get_ext_project_build_command(build_runtime_cmd ${runtime})
 116     add_custom_target(${runtime}
 117       COMMAND ${build_runtime_cmd}
 118       DEPENDS compiler-rt-configure
 119       WORKING_DIRECTORY ${BINARY_DIR}
 120       VERBATIM)
 121   endforeach()
 122
 123   if(LLVM_INCLUDE_TESTS)
 124     # Add binaries that compiler-rt tests depend on.
 125     set(COMPILER_RT_TEST_DEPENDENCIES
 126       FileCheck count not llvm-nm llvm-objdump llvm-symbolizer)
 127
 128     # Add top-level targets for various compiler-rt test suites.
 129     set(COMPILER_RT_TEST_SUITES check-asan check-asan-dynamic check-dfsan
 130       check-lsan check-msan check-sanitizer check-tsan check-ubsan
 131       check-profile check-cfi check-cfi-and-supported check-safestack)
 132     foreach(test_suite ${COMPILER_RT_TEST_SUITES})
 133       get_ext_project_build_command(run_test_suite ${test_suite})
 134       add_custom_target(${test_suite}
 135         COMMAND ${run_test_suite}
 136         DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
 137         WORKING_DIRECTORY ${BINARY_DIR}
 138         VERBATIM
 139         ${cmake_3_2_USES_TERMINAL}
 140         )
 141     endforeach()
 142
 143     # Add special target to run all compiler-rt test suites.
 144     get_ext_project_build_command(run_check_compiler_rt check-all)
 145     add_custom_target(check-compiler-rt
 146       COMMAND ${run_check_compiler_rt}
 147       DEPENDS compiler-rt-build ${COMPILER_RT_TEST_DEPENDENCIES}
 148       WORKING_DIRECTORY ${BINARY_DIR}
 149       VERBATIM)
 150   endif()
 151 endif()