granicus.if.org Git - strace/blob - mpers.awk

   1 function compare_indices(i1, v1, i2, v2) {
   2         c1 = strtonum(sprintf("%s", i1))
   3         c2 = strtonum(sprintf("%s", i2))
   4         if (c1 < c2)
   5                 return -1
   6         return (c1 != c2)
   7 }
   8 function array_get(array_idx, array_member, array_return)
   9 {
  10         array_return = array[array_idx][array_member]
  11         if ("" == array_return) {
  12                 printf("%s: index [%s] without %s\n",
  13                        FILENAME, array_idx, array_member) > "/dev/stderr"
  14                 exit 1
  15         }
  16         return array_return
  17 }
  18 function what_is(what_idx, type_idx, special, item, \
  19                  location, prev_location, prev_returned_size)
  20 {
  21         special = array_get(what_idx, "special")
  22         switch (special) {
  23         case "base_type":
  24                 switch (array_get(what_idx, "encoding")) {
  25                 case 5: # signed
  26                         printf("%s ", "int" \
  27                         8 * array_get(what_idx, "byte_size") "_t")
  28                         break
  29                 case 7: # unsigned
  30                         printf("%s ", "uint" \
  31                         8 * array_get(what_idx, "byte_size") "_t")
  32                         break
  33                 default: # float, signed/unsigned char
  34                         printf("%s ", array_get(what_idx, "name"))
  35                         break
  36                 }
  37                 returned_size = array_get(what_idx, "byte_size")
  38                 break
  39         case "enumeration_type":
  40                 type_idx = array_get(what_idx, "type")
  41                 returned_size = array_get(what_idx, "byte_size")
  42                 printf("%s ", "uint" 8 * returned_size "_t")
  43                 break
  44         case "pointer_type":
  45                 printf("%s", "mpers_ptr_t ")
  46                 returned_size = array_get(what_idx, "byte_size")
  47                 break
  48         case "array_type":
  49                 type_idx = array_get(what_idx, "type")
  50                 what_is(type_idx)
  51                 to_return = array[what_idx]["upper_bound"]
  52                 returned_size = to_return * returned_size
  53                 if ("" == to_return)
  54                         to_return = "00"
  55                 return to_return
  56                 break
  57         case "structure_type":
  58                 print "struct {"
  59                 prev_location = 0
  60                 location = 0
  61                 returned_size = 0
  62                 prev_returned_size = 0
  63                 for (item in array) {
  64                         if ("parent" in array[item] && \
  65                                 array_get(item, "parent") == what_idx) {
  66                                 location = array_get(item, "location")
  67                                 loc_diff = location - prev_location - \
  68                                         prev_returned_size
  69                                 if (loc_diff != 0) {
  70                                         printf("%s", \
  71                                                 "unsigned char mpers_filler_" \
  72                                                 item "[" loc_diff "];\n")
  73                                 }
  74                                 prev_location = location
  75                                 returned = what_is(item)
  76                                 prev_returned_size = returned_size
  77                                 printf("%s", array[item]["name"])
  78                                 if (returned) {
  79                                         printf("[%s]", returned)
  80                                 }
  81                                 print ";"
  82                         }
  83                 }
  84                 returned_size = array_get(what_idx, "byte_size")
  85                 loc_diff = returned_size - prev_location - prev_returned_size
  86                 if (loc_diff != 0) {
  87                         printf("%s", "unsigned char mpers_end_filler_" \
  88                                 item "[" loc_diff "];\n")
  89                 }
  90                 printf("%s", "} ATTRIBUTE_PACKED ")
  91                 break
  92         case "union_type":
  93                 print "union {"
  94                 for (item in array) {
  95                         if ("parent" in array[item] && \
  96                                 array_get(item, "parent") == what_idx) {
  97                                 returned = what_is(item)
  98                                 printf("%s", array_get(item, "name"))
  99                                 if (returned) {
 100                                         printf("[%s]", returned)
 101                                 }
 102                                 print ";"
 103                         }
 104                 }
 105                 printf("%s", "} ")
 106                 returned_size = array_get(what_idx, "byte_size")
 107                 break
 108         case "typedef":
 109                 type_idx = array_get(what_idx, "type")
 110                 return what_is(type_idx)
 111                 break
 112         case "member":
 113                 type_idx = array_get(what_idx, "type")
 114                 return what_is(type_idx)
 115                 break
 116         default:
 117                 type_idx = array_get(what_idx, "type")
 118                 what_is(type_idx)
 119                 break
 120         }
 121         return 0
 122 }
 123 BEGIN {
 124         print "#include <inttypes.h>"
 125 }
 126 /^<[[:xdigit:]]+>/ {
 127         match($0, /([[:alnum:]]+)><([[:alnum:]]+)/, matches)
 128         level = matches[1]
 129         idx = "0x" matches[2]
 130         array[idx]["idx"] = idx
 131         parent[level] = idx
 132         if (level > 1) {
 133                 array[idx]["parent"] = parent[level-1]
 134         }
 135 }
 136 /^DW_AT_data_member_location/ {
 137         match($0, /[[:digit:]]+/, temparray)
 138         array[idx]["location"] = temparray[0]
 139 }
 140 /^DW_AT_name/ {
 141         match($0, /:[[:space:]]+([[:alpha:]_][[:alnum:]_[:space:]]*)/, \
 142                 temparray)
 143         array[idx]["name"] = temparray[1]
 144 }
 145 /^DW_AT_byte_size/ {
 146         match($0, /[[:digit:]]+/, temparray)
 147         array[idx]["byte_size"] = temparray[0]
 148 }
 149 /^DW_AT_encoding/ {
 150         match($0, /[[:digit:]]+/, temparray)
 151         array[idx]["encoding"] = temparray[0]
 152 }
 153 /^DW_AT_type/ {
 154         match($0, /:[[:space:]]+<(0x[[:xdigit:]]*)>$/, temparray)
 155         array[idx]["type"] = temparray[1]
 156 }
 157 /^DW_AT_upper_bound/ {
 158         match($0, /[[:digit:]]+/, temparray)
 159         array[parent[level-1]]["upper_bound"] = temparray[0] + 1
 160 }
 161 /^Abbrev Number:[^(]+\(DW_TAG_/ {
 162         if (match($0, /typedef|union_type|structure_type|pointer_type\
 163 |enumeration_type|array_type|base_type|member/, temparray)) {
 164                 array[idx]["special"] = temparray[0]
 165         }
 166 }
 167 END {
 168         PROCINFO["sorted_in"] = "compare_indices"
 169         for (item in array) {
 170                 if (array[item]["special"] == "pointer_type") {
 171                         print "typedef uint" \
 172                                 8 * array_get(item, "byte_size") "_t mpers_ptr_t;"
 173                         break
 174                 }
 175         }
 176         for (item in array) {
 177                 if (array[item]["name"] == VAR_NAME) {
 178                         type = array_get(item, "type")
 179                         print "typedef"
 180                         what_is(type)
 181                         name = array_get(type, "name")
 182                         print ARCH_FLAG "_" name ";"
 183                         print "#define MPERS_" \
 184                                 ARCH_FLAG "_" name " " \
 185                                 ARCH_FLAG "_" name
 186                         break
 187                 }
 188         }
 189 }