granicus.if.org Git - apache/blob - modules/proxy/config.m4

   1 dnl modules enabled in this directory by default
   2
   3 APACHE_MODPATH_INIT(proxy)
   4
   5 if test "$enable_proxy" = "shared"; then
   6   proxy_mods_enable=shared
   7 elif test "$enable_proxy" = "yes"; then
   8   proxy_mods_enable=yes
   9 else
  10   proxy_mods_enable=no
  11 fi
  12
  13 proxy_objs="mod_proxy.lo proxy_util.lo"
  14 APACHE_MODULE(proxy, Apache proxy module, $proxy_objs, , $proxy_mods_enable)
  15
  16 proxy_connect_objs="mod_proxy_connect.lo"
  17 proxy_ftp_objs="mod_proxy_ftp.lo"
  18 proxy_http_objs="mod_proxy_http.lo"
  19 proxy_fcgi_objs="mod_proxy_fcgi.lo"
  20 proxy_scgi_objs="mod_proxy_scgi.lo"
  21 proxy_fdpass_objs="mod_proxy_fdpass.lo"
  22 proxy_ajp_objs="mod_proxy_ajp.lo ajp_header.lo ajp_link.lo ajp_msg.lo ajp_utils.lo"
  23 proxy_balancer_objs="mod_proxy_balancer.lo"
  24
  25 case "$host" in
  26   *os2*)
  27     # OS/2 DLLs must resolve all symbols at build time and
  28     # these sub-modules need some from the main proxy module
  29     proxy_connect_objs="$proxy_connect_objs mod_proxy.la"
  30     proxy_ftp_objs="$proxy_ftp_objs mod_proxy.la"
  31     proxy_http_objs="$proxy_http_objs mod_proxy.la"
  32     proxy_fcgi_objs="$proxy_fcgi_objs mod_proxy.la"
  33     proxy_scgi_objs="$proxy_scgi_objs mod_proxy.la"
  34     proxy_fdpass_objs="$proxy_fdpass_objs mod_proxy.la"
  35     proxy_ajp_objs="$proxy_ajp_objs mod_proxy.la"
  36     proxy_balancer_objs="$proxy_balancer_objs mod_proxy.la"
  37     ;;
  38 esac
  39
  40 APACHE_MODULE(proxy_connect, Apache proxy CONNECT module, $proxy_connect_objs, , $proxy_mods_enable)
  41 APACHE_MODULE(proxy_ftp, Apache proxy FTP module, $proxy_ftp_objs, , $proxy_mods_enable)
  42 APACHE_MODULE(proxy_http, Apache proxy HTTP module, $proxy_http_objs, , $proxy_mods_enable)
  43 APACHE_MODULE(proxy_fcgi, Apache proxy FastCGI module, $proxy_fcgi_objs, , $proxy_mods_enable)
  44 APACHE_MODULE(proxy_scgi, Apache proxy SCGI module, $proxy_scgi_objs, , $proxy_mods_enable)
  45 APACHE_MODULE(proxy_fdpass, Apache proxy to Unix Daemon Socket module, $proxy_fdpass_objs, , $proxy_mods_enable, [
  46   AC_CHECK_DECLS(CMSG_DATA, [ap_HAVE_DECL_CMSG_DATA="yes"], [ap_HAVE_DECL_CMSG_DATA="no"], [[#include <sys/socket.h>]])
  47   if test $ap_HAVE_DECL_CMSG_DATA = "no"; then
  48     AC_MSG_WARN([Your system does not support CMSG_DATA.])
  49     enable_proxy_fdpass="no"
  50     _apmod_error_fatal="no"
  51   fi
  52 ])
  53 APACHE_MODULE(proxy_ajp, Apache proxy AJP module, $proxy_ajp_objs, , $proxy_mods_enable)
  54 APACHE_MODULE(proxy_balancer, Apache proxy BALANCER module, $proxy_balancer_objs, , $proxy_mods_enable)
  55
  56
  57 AC_DEFUN([CHECK_SERF], [
  58   AC_MSG_CHECKING(for serf)
  59   serf_found="no"
  60   AC_ARG_WITH(serf, APACHE_HELP_STRING([--with-serf=PREFIX],
  61                                   [Serf client library]),
  62   [
  63     if test "$withval" = "yes" ; then
  64       AC_MSG_ERROR([--with-serf requires an argument.])
  65     else
  66       AC_MSG_NOTICE([serf library configuration])
  67       serf_prefix=$withval
  68       save_cppflags="$CPPFLAGS"
  69       CPPFLAGS="$CPPFLAGS $APR_INCLUDES $APU_INCLUDES -I$serf_prefix/include/serf-0"
  70       AC_CHECK_HEADERS(serf.h,[
  71         save_ldflags="$LDFLAGS"
  72         LDFLAGS="$LDFLAGS -L$serf_prefix/lib"
  73         AC_CHECK_LIB(serf-0, serf_context_create,[serf_found="yes"])
  74         LDFLAGS="$save_ldflags"])
  75       CPPFLAGS="$save_cppflags"
  76     fi
  77   ])
  78
  79   if test "$serf_found" = "yes"; then
  80     APR_ADDTO(LDFLAGS, ["-L$serf_prefix/lib"])
  81     APR_ADDTO(LIBS, ["-lserf-0"])
  82     APR_ADDTO(INCLUDES, ["-I$serf_prefix/include/serf-0"])
  83   else
  84     AC_MSG_ERROR(unable to find serf)
  85   fi
  86 ])
  87
  88 APACHE_MODULE(serf, [Reverse proxy module using Serf], , , no, [
  89     CHECK_SERF
  90 ])
  91
  92 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/$modpath_current/../generators])
  93 APACHE_MODPATH_FINISH
  94