granicus.if.org Git - apache/blob - modules/proxy/config.m4

   1 dnl modules enabled in this directory by default
   2
   3 APACHE_MODPATH_INIT(proxy)
   4
   5 if test "$enable_proxy" = "shared"; then
   6   proxy_mods_enable=shared
   7 elif test "$enable_proxy" = "yes"; then
   8   proxy_mods_enable=yes
   9 else
  10   proxy_mods_enable=no
  11 fi
  12
  13 proxy_objs="mod_proxy.lo proxy_util.lo"
  14 APACHE_MODULE(proxy, Apache proxy module, $proxy_objs, , $proxy_mods_enable)
  15
  16 proxy_connect_objs="mod_proxy_connect.lo"
  17 proxy_ftp_objs="mod_proxy_ftp.lo"
  18 proxy_http_objs="mod_proxy_http.lo"
  19 proxy_fcgi_objs="mod_proxy_fcgi.lo"
  20 proxy_fdpass_objs="mod_proxy_fdpass.lo"
  21 proxy_ajp_objs="mod_proxy_ajp.lo ajp_header.lo ajp_link.lo ajp_msg.lo ajp_utils.lo"
  22 proxy_balancer_objs="mod_proxy_balancer.lo"
  23
  24 case "$host" in
  25   *os2*)
  26     # OS/2 DLLs must resolve all symbols at build time and
  27     # these sub-modules need some from the main proxy module
  28     proxy_connect_objs="$proxy_connect_objs mod_proxy.la"
  29     proxy_ftp_objs="$proxy_ftp_objs mod_proxy.la"
  30     proxy_http_objs="$proxy_http_objs mod_proxy.la"
  31     proxy_fcgi_objs="$proxy_fcgi_objs mod_proxy.la"
  32     proxy_fdpass_objs="$proxy_fdpass_objs mod_proxy.la"
  33     proxy_ajp_objs="$proxy_ajp_objs mod_proxy.la"
  34     proxy_balancer_objs="$proxy_balancer_objs mod_proxy.la"
  35     ;;
  36 esac
  37
  38 APACHE_MODULE(proxy_connect, Apache proxy CONNECT module, $proxy_connect_objs, , $proxy_mods_enable)
  39 APACHE_MODULE(proxy_ftp, Apache proxy FTP module, $proxy_ftp_objs, , $proxy_mods_enable)
  40 APACHE_MODULE(proxy_http, Apache proxy HTTP module, $proxy_http_objs, , $proxy_mods_enable)
  41 APACHE_MODULE(proxy_fcgi, Apache proxy FastCGI module, $proxy_fcgi_objs, , $proxy_mods_enable)
  42 APACHE_MODULE(proxy_fdpass, Apache proxy to Unix Daemon Socket module, $proxy_fdpass_objs, , $proxy_mods_enable)
  43 APACHE_MODULE(proxy_ajp, Apache proxy AJP module, $proxy_ajp_objs, , $proxy_mods_enable)
  44 APACHE_MODULE(proxy_balancer, Apache proxy BALANCER module, $proxy_balancer_objs, , $proxy_mods_enable)
  45
  46
  47 AC_DEFUN([CHECK_SERF], [
  48   AC_MSG_CHECKING(for serf)
  49   serf_found="no"
  50   AC_ARG_WITH(serf, APACHE_HELP_STRING([--with-serf=PREFIX],
  51                                   [Serf client library]),
  52   [
  53     if test "$withval" = "yes" ; then
  54       AC_MSG_ERROR([--with-serf requires an argument.])
  55     else
  56       AC_MSG_NOTICE([serf library configuration])
  57       serf_prefix=$withval
  58       save_cppflags="$CPPFLAGS"
  59       CPPFLAGS="$CPPFLAGS $APR_INCLUDES $APU_INCLUDES -I$serf_prefix/include/serf-0"
  60       AC_CHECK_HEADERS(serf.h,[
  61         save_ldflags="$LDFLAGS"
  62         LDFLAGS="$LDFLAGS -L$serf_prefix/lib"
  63         AC_CHECK_LIB(serf-0, serf_context_create,[serf_found="yes"])
  64         LDFLAGS="$save_ldflags"])
  65       CPPFLAGS="$save_cppflags"
  66     fi
  67   ])
  68
  69   if test "$serf_found" = "yes"; then
  70     APR_ADDTO(LDFLAGS, ["-L$serf_prefix/lib"])
  71     APR_ADDTO(LIBS, ["-lserf-0"])
  72     APR_ADDTO(INCLUDES, ["-I$serf_prefix/include/serf-0"])
  73   else
  74     AC_MSG_ERROR(unable to find serf)
  75   fi
  76 ])
  77
  78 serf_objects="mod_serf.lo"
  79 APACHE_MODULE(serf, [Reverse proxy module using Serf], $serf_objects, , no, [
  80     CHECK_SERF
  81 ])
  82
  83 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/$modpath_current/../generators])
  84 APACHE_MODPATH_FINISH
  85