granicus.if.org Git - apache/blob - modules/proxy/config.m4

   1 dnl modules enabled in this directory by default
   2
   3 APACHE_MODPATH_INIT(proxy)
   4
   5 if test "$enable_proxy" = "shared"; then
   6   proxy_mods_enable=shared
   7 elif test "$enable_proxy" = "yes"; then
   8   proxy_mods_enable=yes
   9 else
  10   proxy_mods_enable=most
  11 fi
  12
  13 if test "$proxy_mods_enable" = "no"; then
  14   enable_proxy_hcheck=no
  15 fi
  16
  17 proxy_objs="mod_proxy.lo proxy_util.lo"
  18 APACHE_MODULE(proxy, Apache proxy module, $proxy_objs, , $proxy_mods_enable)
  19
  20 proxy_connect_objs="mod_proxy_connect.lo"
  21 proxy_ftp_objs="mod_proxy_ftp.lo"
  22 proxy_http_objs="mod_proxy_http.lo"
  23 proxy_fcgi_objs="mod_proxy_fcgi.lo"
  24 proxy_scgi_objs="mod_proxy_scgi.lo"
  25 proxy_fdpass_objs="mod_proxy_fdpass.lo"
  26 proxy_ajp_objs="mod_proxy_ajp.lo ajp_header.lo ajp_link.lo ajp_msg.lo ajp_utils.lo"
  27 proxy_wstunnel_objs="mod_proxy_wstunnel.lo"
  28 proxy_balancer_objs="mod_proxy_balancer.lo"
  29
  30 case "$host" in
  31   *os2*)
  32     # OS/2 DLLs must resolve all symbols at build time and
  33     # these sub-modules need some from the main proxy module
  34     proxy_connect_objs="$proxy_connect_objs mod_proxy.la"
  35     proxy_ftp_objs="$proxy_ftp_objs mod_proxy.la"
  36     proxy_http_objs="$proxy_http_objs mod_proxy.la"
  37     proxy_fcgi_objs="$proxy_fcgi_objs mod_proxy.la"
  38     proxy_scgi_objs="$proxy_scgi_objs mod_proxy.la"
  39     proxy_fdpass_objs="$proxy_fdpass_objs mod_proxy.la"
  40     proxy_ajp_objs="$proxy_ajp_objs mod_proxy.la"
  41     proxy_wstunnel_objs="$proxy_wstunnel_objs mod_proxy.la"
  42     proxy_balancer_objs="$proxy_balancer_objs mod_proxy.la"
  43     ;;
  44 esac
  45
  46 APACHE_MODULE(proxy_connect, Apache proxy CONNECT module.  Requires and is enabled by --enable-proxy., $proxy_connect_objs, , $proxy_mods_enable,, proxy)
  47 APACHE_MODULE(proxy_ftp, Apache proxy FTP module.  Requires and is enabled by --enable-proxy., $proxy_ftp_objs, , $proxy_mods_enable,, proxy)
  48 APACHE_MODULE(proxy_http, Apache proxy HTTP module.  Requires and is enabled by --enable-proxy., $proxy_http_objs, , $proxy_mods_enable,, proxy)
  49 APACHE_MODULE(proxy_fcgi, Apache proxy FastCGI module.  Requires and is enabled by --enable-proxy., $proxy_fcgi_objs, , $proxy_mods_enable,, proxy)
  50 APACHE_MODULE(proxy_scgi, Apache proxy SCGI module.  Requires and is enabled by --enable-proxy., $proxy_scgi_objs, , $proxy_mods_enable,, proxy)
  51 APACHE_MODULE(proxy_fdpass, Apache proxy to Unix Daemon Socket module.  Requires --enable-proxy., $proxy_fdpass_objs, , , [
  52   AC_CHECK_DECL(CMSG_DATA,,, [
  53     #include <sys/types.h>
  54     #include <sys/socket.h>
  55   ])
  56   if test $ac_cv_have_decl_CMSG_DATA = "no"; then
  57     AC_MSG_WARN([Your system does not support CMSG_DATA.])
  58     enable_proxy_fdpass=no
  59   fi
  60 ],proxy)
  61 APACHE_MODULE(proxy_wstunnel, Apache proxy Websocket Tunnel module.  Requires and is enabled by --enable-proxy., $proxy_wstunnel_objs, , $proxy_mods_enable,, proxy)
  62 APACHE_MODULE(proxy_ajp, Apache proxy AJP module.  Requires and is enabled by --enable-proxy., $proxy_ajp_objs, , $proxy_mods_enable,, proxy)
  63 APACHE_MODULE(proxy_balancer, Apache proxy BALANCER module.  Requires and is enabled by --enable-proxy., $proxy_balancer_objs, , $proxy_mods_enable,, proxy)
  64
  65 APACHE_MODULE(serf, [Reverse proxy module using Serf], , , no, [
  66     APACHE_CHECK_SERF
  67     if test "$ac_cv_serf" = "yes" ; then
  68       APR_ADDTO(MOD_SERF_LDADD, [\$(SERF_LIBS)])
  69     else
  70       enable_serf=no
  71     fi
  72 ])
  73
  74 APACHE_MODULE(proxy_express, mass reverse-proxy module. Requires --enable-proxy., , , $proxy_mods_enable,, proxy)
  75 APACHE_MODULE(proxy_hcheck, reverse-proxy health-check module. Requires --enable-proxy and --enable-watchdog., , , $enable_proxy_hcheck,, watchdog)
  76
  77 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/$modpath_current])
  78
  79 APACHE_MODPATH_FINISH
  80