granicus.if.org Git - apache/blob - modules/core/config.m4

   1 dnl modules enabled in this directory by default
   2
   3 dnl APACHE_MODULE(name, helptext[, objects[, structname[, default[, config]]]])
   4
   5 APACHE_MODPATH_INIT(core)
   6
   7 APR_CHECK_APR_DEFINE(APR_HAS_DSO)
   8
   9 case "x$enable_so" in
  10     "xyes")
  11         if test $ac_cv_define_APR_HAS_DSO = "no"; then
  12             AC_MSG_ERROR([mod_so has been requested but cannot be built on your system])
  13         fi
  14         ;;
  15     "xshared")
  16         AC_MSG_ERROR([mod_so can not be built as a shared DSO])
  17         ;;
  18     "xno")
  19         ;;
  20     "x")
  21         enable_so=$ac_cv_define_APR_HAS_DSO
  22         ;;
  23 esac
  24
  25 dnl mod_so can only be built statically. Override the default here.
  26 if test "x$enable_so" = "xyes"; then
  27     enable_so="static"
  28 fi
  29
  30 if test "x$enable_so" = "xstatic"; then
  31     APR_ADDTO(HTTPD_LDFLAGS, [-export-dynamic])
  32     INSTALL_DSO=yes
  33 else
  34     INSTALL_DSO=no
  35 fi
  36 APACHE_SUBST(INSTALL_DSO)
  37
  38 if test "$sharedobjs" = "yes"; then
  39     if test $ac_cv_define_APR_HAS_DSO = "no"; then
  40         AC_MSG_ERROR([shared objects have been requested but cannot be built since mod_so cannot be built])
  41     elif test $enable_so = "no"; then
  42         AC_MSG_ERROR([shared objects have been requested but cannot be built since mod_so was disabled])
  43     fi
  44 fi
  45
  46 APACHE_MODULE(so, DSO capability.  This module will be automatically enabled unless you build all modules statically., , , $enable_so)
  47
  48 APACHE_MODULE(watchdog, Watchdog module, , , most, [
  49     APR_CHECK_APR_DEFINE(APR_HAS_THREADS)
  50     if test $ac_cv_define_APR_HAS_THREADS = "no"; then
  51         AC_MSG_WARN([mod_watchdog requires apr to be built with --enable-threads])
  52         enable_watchdog=no
  53     fi
  54 ])
  55
  56 APACHE_MODULE(macro, Define and use macros in configuration files, , , most)
  57
  58 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/$modpath_current])
  59
  60 APACHE_MODPATH_FINISH