granicus.if.org Git - strace/blob - m4/st_libdw.m4

   1 #!/usr/bin/m4
   2 #
   3 # Copyright (c) 2018 The strace developers.
   4 # All rights reserved.
   5 #
   6 # Redistribution and use in source and binary forms, with or without
   7 # modification, are permitted provided that the following conditions
   8 # are met:
   9 # 1. Redistributions of source code must retain the above copyright
  10 #    notice, this list of conditions and the following disclaimer.
  11 # 2. Redistributions in binary form must reproduce the above copyright
  12 #    notice, this list of conditions and the following disclaimer in the
  13 #    documentation and/or other materials provided with the distribution.
  14 # 3. The name of the author may not be used to endorse or promote products
  15 #    derived from this software without specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  18 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  19 # OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  20 # IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  21 # INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  22 # NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  23 # DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  24 # THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  25 # (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  26 # THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  27
  28 AC_DEFUN([st_ARG_LIBDW], [dnl
  29
  30 : ${libdw_CPPFLAGS=}
  31 : ${libdw_CFLAGS=}
  32 : ${libdw_LDFLAGS=}
  33 : ${libdw_LIBS=}
  34
  35 AC_ARG_WITH([libdw],
  36             [AS_HELP_STRING([--with-libdw],
  37                             [use libdw to implement stack tracing support]
  38                            )
  39             ],
  40             [case "${withval}" in
  41              yes|no|check) ;;
  42              *) libdw_CPPFLAGS="-I${withval}/include"
  43                 libdw_LDFLAGS="-L${withval}/lib"
  44                 with_libdw=yes ;;
  45              esac
  46             ],
  47             [with_libdw=check]
  48            )
  49
  50 ])
  51
  52 AC_DEFUN([st_LIBDW], [dnl
  53
  54 have_libdw=
  55
  56 AS_IF([test "x$with_libdw" != xno && test "x$use_unwinder" = x],
  57       [saved_CPPFLAGS="$CPPFLAGS"
  58        saved_CFLAGS="$CFLAGS"
  59        CPPFLAGS="$CPPFLAGS $libdw_CPPFLAGS"
  60        CFLAGS="$CFLAGS $libdw_CFLAGS"
  61
  62        AC_CHECK_HEADERS([elfutils/libdwfl.h],
  63                         [AC_CHECK_LIB([dw], [dwfl_linux_proc_attach],
  64                                       [libdw_LIBS="-ldw $libdw_LIBS"
  65                                        AC_CACHE_CHECK([for elfutils version],
  66                                                       [st_cv_ELFUTILS_VERSION],
  67                                                       [[st_cv_ELFUTILS_VERSION="$(echo _ELFUTILS_VERSION |
  68                                                                                   $CPP $CPPFLAGS -P -imacros elfutils/version.h - |
  69                                                                                   grep '^[0-9]')"
  70                                                         test -n "$st_cv_ELFUTILS_VERSION" ||
  71                                                                 st_cv_ELFUTILS_VERSION=0
  72                                                       ]]
  73                                                      )
  74                                        AS_IF([test "$st_cv_ELFUTILS_VERSION" -ge 164],
  75                                              [have_libdw=yes],
  76                                              [AS_IF([test "x$with_libdw" = xyes],
  77                                                     [AC_MSG_ERROR([elfutils version >= 164 is required for stack tracing support])],
  78                                                     [AC_MSG_WARN([elfutils version >= 164 is required for stack tracing support])]
  79                                                    )
  80                                              ]
  81                                             )
  82                                       ],
  83                                       [AS_IF([test "x$with_libdw" = xyes],
  84                                              [AC_MSG_FAILURE([failed to find dwfl_linux_proc_attach in libdw])],
  85                                             )
  86                                       ],
  87                                       [$libdw_LDFLAGS $libdw_LIBS]
  88                                      )
  89                         ],
  90                         [AS_IF([test "x$with_libdw" = xyes],
  91                                [AC_MSG_FAILURE([failed to find elfutils/libdwfl.h])]
  92                               )
  93                         ]
  94                        )
  95
  96        CFLAGS="$saved_CFLAGS"
  97        CPPFLAGS="$saved_CPPFLAGS"
  98       ]
  99 )
 100
 101 AS_IF([test "x$have_libdw" = xyes],
 102       [use_unwinder=libdw
 103        AC_DEFINE([USE_LIBDW], 1,
 104                  [Whether to use libdw for stack tracing]
 105                 )
 106        AC_SUBST(libdw_CPPFLAGS)
 107        AC_SUBST(libdw_CFLAGS)
 108        AC_SUBST(libdw_LDFLAGS)
 109        AC_SUBST(libdw_LIBS)
 110       ]
 111      )
 112
 113 ])