granicus.if.org Git - strace/blob - m4/ax_valgrind_check.m4

   1 # ===========================================================================
   2 #     http://www.gnu.org/software/autoconf-archive/ax_valgrind_check.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_VALGRIND_DFLT(memcheck|helgrind|drd|sgcheck, on|off)
   8 #   AX_VALGRIND_CHECK()
   9 #
  10 # DESCRIPTION
  11 #
  12 #   AX_VALGRIND_CHECK checks whether Valgrind is present and, if so, allows
  13 #   running `make check` under a variety of Valgrind tools to check for
  14 #   memory and threading errors.
  15 #
  16 #   Defines VALGRIND_CHECK_RULES which should be substituted in your
  17 #   Makefile; and $enable_valgrind which can be used in subsequent configure
  18 #   output. VALGRIND_ENABLED is defined and substituted, and corresponds to
  19 #   the value of the --enable-valgrind option, which defaults to being
  20 #   enabled if Valgrind is installed and disabled otherwise. Individual
  21 #   Valgrind tools can be disabled via --disable-valgrind-<tool>, the
  22 #   default is configurable via the AX_VALGRIND_DFLT command or is to use
  23 #   all commands not disabled via AX_VALGRIND_DFLT. All AX_VALGRIND_DFLT
  24 #   calls must be made before the call to AX_VALGRIND_CHECK.
  25 #
  26 #   If unit tests are written using a shell script and automake's
  27 #   LOG_COMPILER system, the $(VALGRIND) variable can be used within the
  28 #   shell scripts to enable Valgrind, as described here:
  29 #
  30 #     https://www.gnu.org/software/gnulib/manual/html_node/Running-self_002dtests-under-valgrind.html
  31 #
  32 #   Usage example:
  33 #
  34 #   configure.ac:
  35 #
  36 #     AX_VALGRIND_DFLT([sgcheck], [off])
  37 #     AX_VALGRIND_CHECK
  38 #
  39 #   Makefile.am:
  40 #
  41 #     @VALGRIND_CHECK_RULES@
  42 #     VALGRIND_SUPPRESSIONS_FILES = my-project.supp
  43 #     EXTRA_DIST = my-project.supp
  44 #
  45 #   This results in a "check-valgrind" rule being added to any Makefile.am
  46 #   which includes "@VALGRIND_CHECK_RULES@" (assuming the module has been
  47 #   configured with --enable-valgrind). Running `make check-valgrind` in
  48 #   that directory will run the module's test suite (`make check`) once for
  49 #   each of the available Valgrind tools (out of memcheck, helgrind and drd)
  50 #   while the sgcheck will be skipped unless enabled again on the
  51 #   commandline with --enable-valgrind-sgcheck. The results for each check
  52 #   will be output to test-suite-$toolname.log. The target will succeed if
  53 #   there are zero errors and fail otherwise.
  54 #
  55 #   Alternatively, a "check-valgrind-$TOOL" rule will be added, for $TOOL in
  56 #   memcheck, helgrind, drd and sgcheck. These are useful because often only
  57 #   some of those tools can be ran cleanly on a codebase.
  58 #
  59 #   The macro supports running with and without libtool.
  60 #
  61 # LICENSE
  62 #
  63 #   Copyright (c) 2014, 2015, 2016 Philip Withnall <philip.withnall@collabora.co.uk>
  64 #
  65 #   Copying and distribution of this file, with or without modification, are
  66 #   permitted in any medium without royalty provided the copyright notice
  67 #   and this notice are preserved.  This file is offered as-is, without any
  68 #   warranty.
  69
  70 #serial 13
  71 #modified for strace project
  72
  73 dnl Configured tools
  74 m4_define([valgrind_tool_list], [[memcheck], [helgrind], [drd], [sgcheck]])
  75 m4_set_add_all([valgrind_exp_tool_set], [sgcheck])
  76 m4_foreach([vgtool], [valgrind_tool_list],
  77            [m4_define([en_dflt_valgrind_]vgtool, [on])])
  78
  79 AC_DEFUN([AX_VALGRIND_DFLT],[
  80         m4_define([en_dflt_valgrind_$1], [$2])
  81 ])dnl
  82
  83 AC_DEFUN([AX_VALGRIND_CHECK],[
  84         dnl Check for --enable-valgrind
  85         AC_ARG_ENABLE([valgrind],
  86                       [AS_HELP_STRING([--enable-valgrind], [Whether to enable Valgrind on the unit tests])],
  87                       [enable_valgrind=$enableval],[enable_valgrind=])
  88
  89         AS_IF([test "$enable_valgrind" != "no"],[
  90                 # Check for Valgrind.
  91                 AC_CHECK_PROG([VALGRIND],[valgrind],[valgrind])
  92                 AS_IF([test "$VALGRIND" = ""],[
  93                         AS_IF([test "$enable_valgrind" = "yes"],[
  94                                 AC_MSG_ERROR([Could not find valgrind; either install it or reconfigure with --disable-valgrind])
  95                         ],[
  96                                 enable_valgrind=no
  97                         ])
  98                 ],[
  99                         enable_valgrind=yes
 100                 ])
 101         ])
 102
 103         AM_CONDITIONAL([VALGRIND_ENABLED],[test "$enable_valgrind" = "yes"])
 104         AC_SUBST([VALGRIND_ENABLED],[$enable_valgrind])
 105
 106         # Check for Valgrind tools we care about.
 107         [valgrind_enabled_tools=]
 108         m4_foreach([vgtool],[valgrind_tool_list],[
 109                 AC_ARG_ENABLE([valgrind-]vgtool,
 110                     m4_if(m4_defn([en_dflt_valgrind_]vgtool),[off],dnl
 111 [AS_HELP_STRING([--enable-valgrind-]vgtool, [Whether to use ]vgtool[ during the Valgrind tests])],dnl
 112 [AS_HELP_STRING([--disable-valgrind-]vgtool, [Whether to skip ]vgtool[ during the Valgrind tests])]),
 113                               [enable_valgrind_]vgtool[=$enableval],
 114                               [enable_valgrind_]vgtool[=])
 115                 AS_IF([test "$enable_valgrind" = "no"],[
 116                         enable_valgrind_]vgtool[=no],
 117                       [test "$enable_valgrind_]vgtool[" ]dnl
 118 m4_if(m4_defn([en_dflt_valgrind_]vgtool), [off], [= "yes"], [!= "no"]),[
 119                         AC_CACHE_CHECK([for Valgrind tool ]vgtool,
 120                                        [ax_cv_valgrind_tool_]vgtool,[
 121                                 ax_cv_valgrind_tool_]vgtool[=no
 122                                 m4_set_contains([valgrind_exp_tool_set],vgtool,
 123                                     [m4_define([vgtoolx],[exp-]vgtool)],
 124                                     [m4_define([vgtoolx],vgtool)])
 125                                 AS_IF([`$VALGRIND --tool=]vgtoolx[ --help >/dev/null 2>&1`],[
 126                                         ax_cv_valgrind_tool_]vgtool[=yes
 127                                 ])
 128                         ])
 129                         AS_IF([test "$ax_cv_valgrind_tool_]vgtool[" = "no"],[
 130                                 AS_IF([test "$enable_valgrind_]vgtool[" = "yes"],[
 131                                         AC_MSG_ERROR([Valgrind does not support ]vgtool[; reconfigure with --disable-valgrind-]vgtool)
 132                                 ],[
 133                                         enable_valgrind_]vgtool[=no
 134                                 ])
 135                         ],[
 136                                 enable_valgrind_]vgtool[=yes
 137                         ])
 138                 ])
 139                 AS_IF([test "$enable_valgrind_]vgtool[" = "yes"],[
 140                         valgrind_enabled_tools="$valgrind_enabled_tools ]m4_bpatsubst(vgtool,[^exp-])["
 141                 ])
 142                 AC_SUBST([ENABLE_VALGRIND_]vgtool,[$enable_valgrind_]vgtool)
 143         ])
 144         AC_SUBST([valgrind_tools],["]m4_join([ ], valgrind_tool_list)["])
 145         AC_SUBST([valgrind_enabled_tools],[$valgrind_enabled_tools])
 146
 147 [VALGRIND_CHECK_RULES='
 148 # Valgrind check
 149 #
 150 # Optional:
 151 #  - VALGRIND_SUPPRESSIONS_FILES: Space-separated list of Valgrind suppressions
 152 #    files to load. (Default: empty)
 153 #  - VALGRIND_FLAGS: General flags to pass to all Valgrind tools.
 154 #    (Default: --num-callers=30)
 155 #  - VALGRIND_$toolname_FLAGS: Flags to pass to Valgrind $toolname (one of:
 156 #    memcheck, helgrind, drd, sgcheck). (Default: various)
 157
 158 # Optional variables
 159 VALGRIND_SUPPRESSIONS ?= $(addprefix --suppressions=,$(VALGRIND_SUPPRESSIONS_FILES))
 160 VALGRIND_FLAGS ?= --num-callers=30
 161 VALGRIND_memcheck_FLAGS ?= --leak-check=full --show-reachable=no
 162 VALGRIND_helgrind_FLAGS ?= --history-level=approx
 163 VALGRIND_drd_FLAGS ?=
 164 VALGRIND_sgcheck_FLAGS ?=
 165
 166 # Internal use
 167 valgrind_log_files = $(addprefix test-suite-,$(addsuffix .log,$(valgrind_tools)))
 168
 169 valgrind_memcheck_flags = --tool=memcheck $(VALGRIND_memcheck_FLAGS)
 170 valgrind_helgrind_flags = --tool=helgrind $(VALGRIND_helgrind_FLAGS)
 171 valgrind_drd_flags = --tool=drd $(VALGRIND_drd_FLAGS)
 172 valgrind_sgcheck_flags = --tool=exp-sgcheck $(VALGRIND_sgcheck_FLAGS)
 173
 174 valgrind_quiet = $(valgrind_quiet_$(V))
 175 valgrind_quiet_ = $(valgrind_quiet_$(AM_DEFAULT_VERBOSITY))
 176 valgrind_quiet_0 = --quiet
 177 valgrind_v_use   = $(valgrind_v_use_$(V))
 178 valgrind_v_use_  = $(valgrind_v_use_$(AM_DEFAULT_VERBOSITY))
 179 valgrind_v_use_0 = @echo "  USE   " $(patsubst check-valgrind-%,%,$''@):;
 180
 181 # Support running with and without libtool.
 182 ifneq ($(LIBTOOL),)
 183 valgrind_lt = $(LIBTOOL) $(AM_LIBTOOLFLAGS) $(LIBTOOLFLAGS) --mode=execute
 184 else
 185 valgrind_lt =
 186 endif
 187
 188 # Use recursive makes in order to ignore errors during check
 189 check-valgrind:
 190 ifeq ($(VALGRIND_ENABLED),yes)
 191         -$(A''M_V_at)$(foreach tool,$(valgrind_enabled_tools), \
 192                 $(MAKE) $(AM_MAKEFLAGS) -k check-valgrind-$(tool); \
 193         )
 194 else
 195         @echo "Need to reconfigure with --enable-valgrind"
 196 endif
 197
 198 # Valgrind running
 199 VALGRIND_TESTS_ENVIRONMENT = \
 200         $(TESTS_ENVIRONMENT) \
 201         env VALGRIND=$(VALGRIND) \
 202         G_SLICE=always-malloc,debug-blocks \
 203         G_DEBUG=fatal-warnings,fatal-criticals,gc-friendly
 204
 205 VALGRIND_LOG_COMPILER = \
 206         $(valgrind_lt) \
 207         $(VALGRIND) $(VALGRIND_SUPPRESSIONS) --error-exitcode=1 $(VALGRIND_FLAGS)
 208
 209 define valgrind_tool_rule =
 210 check-valgrind-$(1): $$(BUILT_SOURCES)
 211 ifeq ($$(VALGRIND_ENABLED)-$$(ENABLE_VALGRIND_$(1)),yes-yes)
 212         $$(valgrind_v_use)$$(MAKE) $$(AM_MAKEFLAGS) check-am \
 213                 TESTS_ENVIRONMENT="$$(VALGRIND_TESTS_ENVIRONMENT)" \
 214                 LOG_COMPILER="$$(VALGRIND_LOG_COMPILER)" \
 215                 LOG_FLAGS="$$(valgrind_$(1)_flags)" \
 216                 TEST_SUITE_LOG=test-suite-$(1).log
 217 else ifeq ($$(VALGRIND_ENABLED),yes)
 218         @echo "Need to reconfigure with --enable-valgrind-$(1)"
 219 else
 220         @echo "Need to reconfigure with --enable-valgrind"
 221 endif
 222 endef
 223
 224 $(foreach tool,$(valgrind_tools),$(eval $(call valgrind_tool_rule,$(tool))))
 225
 226 A''M_DISTCHECK_CONFIGURE_FLAGS ?=
 227 A''M_DISTCHECK_CONFIGURE_FLAGS += --disable-valgrind
 228
 229 MOSTLYCLEANFILES ?=
 230 MOSTLYCLEANFILES += $(valgrind_log_files)
 231
 232 .PHONY: check-valgrind $(add-prefix check-valgrind-,$(valgrind_tools))
 233 ']
 234
 235         AC_SUBST([VALGRIND_CHECK_RULES])
 236         m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([VALGRIND_CHECK_RULES])])
 237 ])