granicus.if.org Git - strace/blob - m4/ax_valgrind_check.m4

   1 # ===========================================================================
   2 #    https://www.gnu.org/software/autoconf-archive/ax_valgrind_check.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_VALGRIND_DFLT(memcheck|helgrind|drd|sgcheck, on|off)
   8 #   AX_VALGRIND_CHECK()
   9 #
  10 # DESCRIPTION
  11 #
  12 #   AX_VALGRIND_CHECK checks whether Valgrind is present and, if so, allows
  13 #   running `make check` under a variety of Valgrind tools to check for
  14 #   memory and threading errors.
  15 #
  16 #   Defines VALGRIND_CHECK_RULES which should be substituted in your
  17 #   Makefile; and $enable_valgrind which can be used in subsequent configure
  18 #   output. VALGRIND_ENABLED is defined and substituted, and corresponds to
  19 #   the value of the --enable-valgrind option, which defaults to being
  20 #   enabled if Valgrind is installed and disabled otherwise. Individual
  21 #   Valgrind tools can be disabled via --disable-valgrind-<tool>, the
  22 #   default is configurable via the AX_VALGRIND_DFLT command or is to use
  23 #   all commands not disabled via AX_VALGRIND_DFLT. All AX_VALGRIND_DFLT
  24 #   calls must be made before the call to AX_VALGRIND_CHECK.
  25 #
  26 #   If unit tests are written using a shell script and automake's
  27 #   LOG_COMPILER system, the $(VALGRIND) variable can be used within the
  28 #   shell scripts to enable Valgrind, as described here:
  29 #
  30 #     https://www.gnu.org/software/gnulib/manual/html_node/Running-self_002dtests-under-valgrind.html
  31 #
  32 #   Usage example:
  33 #
  34 #   configure.ac:
  35 #
  36 #     AX_VALGRIND_DFLT([sgcheck], [off])
  37 #     AX_VALGRIND_CHECK
  38 #
  39 #   Makefile.am:
  40 #
  41 #     @VALGRIND_CHECK_RULES@
  42 #     VALGRIND_SUPPRESSIONS_FILES = my-project.supp
  43 #     EXTRA_DIST = my-project.supp
  44 #
  45 #   This results in a "check-valgrind" rule being added to any Makefile.am
  46 #   which includes "@VALGRIND_CHECK_RULES@" (assuming the module has been
  47 #   configured with --enable-valgrind). Running `make check-valgrind` in
  48 #   that directory will run the module's test suite (`make check`) once for
  49 #   each of the available Valgrind tools (out of memcheck, helgrind and drd)
  50 #   while the sgcheck will be skipped unless enabled again on the
  51 #   commandline with --enable-valgrind-sgcheck. The results for each check
  52 #   will be output to test-suite-$toolname.log. The target will succeed if
  53 #   there are zero errors and fail otherwise.
  54 #
  55 #   Alternatively, a "check-valgrind-$TOOL" rule will be added, for $TOOL in
  56 #   memcheck, helgrind, drd and sgcheck. These are useful because often only
  57 #   some of those tools can be ran cleanly on a codebase.
  58 #
  59 #   The macro supports running with and without libtool.
  60 #
  61 # LICENSE
  62 #
  63 #   Copyright (c) 2014, 2015, 2016 Philip Withnall <philip.withnall@collabora.co.uk>
  64 #   Copyright (c) 2016-2017 The strace developers.
  65 #
  66 #   Copying and distribution of this file, with or without modification, are
  67 #   permitted in any medium without royalty provided the copyright notice
  68 #   and this notice are preserved.  This file is offered as-is, without any
  69 #   warranty.
  70
  71 #serial 15
  72 #modified for strace project
  73
  74 dnl Configured tools
  75 m4_define([valgrind_tool_list], [[memcheck], [helgrind], [drd], [sgcheck]])
  76 m4_set_add_all([valgrind_exp_tool_set], [sgcheck])
  77 m4_foreach([vgtool], [valgrind_tool_list],
  78            [m4_define([en_dflt_valgrind_]vgtool, [on])])
  79
  80 AC_DEFUN([AX_VALGRIND_DFLT],[
  81         m4_define([en_dflt_valgrind_$1], [$2])
  82 ])dnl
  83
  84 AC_DEFUN([AX_VALGRIND_CHECK],[
  85         dnl Check for --enable-valgrind
  86         AC_ARG_ENABLE([valgrind],
  87                       [AS_HELP_STRING([--enable-valgrind], [Whether to enable Valgrind on the unit tests])],
  88                       [enable_valgrind=$enableval],[enable_valgrind=])
  89
  90         AS_IF([test "$enable_valgrind" != "no"],[
  91                 # Check for Valgrind.
  92                 AC_CHECK_PROG([VALGRIND],[valgrind],[valgrind])
  93                 AS_IF([test "$VALGRIND" = ""],[
  94                         AS_IF([test "$enable_valgrind" = "yes"],[
  95                                 AC_MSG_ERROR([Could not find valgrind; either install it or reconfigure with --disable-valgrind])
  96                         ],[
  97                                 enable_valgrind=no
  98                         ])
  99                 ],[
 100                         enable_valgrind=yes
 101                 ])
 102         ])
 103
 104         AM_CONDITIONAL([VALGRIND_ENABLED],[test "$enable_valgrind" = "yes"])
 105         AC_SUBST([VALGRIND_ENABLED],[$enable_valgrind])
 106         AM_EXTRA_RECURSIVE_TARGETS([check-valgrind])
 107
 108         # Check for Valgrind tools we care about.
 109         [valgrind_enabled_tools=]
 110         m4_foreach([vgtool],[valgrind_tool_list],[
 111                 AC_ARG_ENABLE([valgrind-]vgtool,
 112                     m4_if(m4_defn([en_dflt_valgrind_]vgtool),[off],dnl
 113 [AS_HELP_STRING([--enable-valgrind-]vgtool, [Whether to use ]vgtool[ during the Valgrind tests])],dnl
 114 [AS_HELP_STRING([--disable-valgrind-]vgtool, [Whether to skip ]vgtool[ during the Valgrind tests])]),
 115                               [enable_valgrind_]vgtool[=$enableval],
 116                               [enable_valgrind_]vgtool[=])
 117                 AS_IF([test "$enable_valgrind" = "no"],[
 118                         enable_valgrind_]vgtool[=no],
 119                       [test "$enable_valgrind_]vgtool[" ]dnl
 120 m4_if(m4_defn([en_dflt_valgrind_]vgtool), [off], [= "yes"], [!= "no"]),[
 121                         AC_CACHE_CHECK([for Valgrind tool ]vgtool,
 122                                        [ax_cv_valgrind_tool_]vgtool,[
 123                                 ax_cv_valgrind_tool_]vgtool[=no
 124                                 m4_set_contains([valgrind_exp_tool_set],vgtool,
 125                                     [m4_define([vgtoolx],[exp-]vgtool)],
 126                                     [m4_define([vgtoolx],vgtool)])
 127                                 AS_IF([`$VALGRIND --tool=]vgtoolx[ --help >/dev/null 2>&1`],[
 128                                         ax_cv_valgrind_tool_]vgtool[=yes
 129                                 ])
 130                         ])
 131                         AS_IF([test "$ax_cv_valgrind_tool_]vgtool[" = "no"],[
 132                                 AS_IF([test "$enable_valgrind_]vgtool[" = "yes"],[
 133                                         AC_MSG_ERROR([Valgrind does not support ]vgtool[; reconfigure with --disable-valgrind-]vgtool)
 134                                 ],[
 135                                         enable_valgrind_]vgtool[=no
 136                                 ])
 137                         ],[
 138                                 enable_valgrind_]vgtool[=yes
 139                         ])
 140                 ])
 141                 AS_IF([test "$enable_valgrind_]vgtool[" = "yes"],[
 142                         valgrind_enabled_tools="$valgrind_enabled_tools ]m4_bpatsubst(vgtool,[^exp-])["
 143                 ])
 144                 AC_SUBST([ENABLE_VALGRIND_]vgtool,[$enable_valgrind_]vgtool)
 145                 AM_EXTRA_RECURSIVE_TARGETS([check-valgrind-]vgtool)
 146         ])
 147         AC_SUBST([valgrind_tools],["]m4_join([ ], valgrind_tool_list)["])
 148         AC_SUBST([valgrind_enabled_tools],[$valgrind_enabled_tools])
 149
 150 [VALGRIND_CHECK_RULES='
 151 # Valgrind check
 152 #
 153 # Optional:
 154 #  - VALGRIND_SUPPRESSIONS_FILES: Space-separated list of Valgrind suppressions
 155 #    files to load. (Default: empty)
 156 #  - VALGRIND_FLAGS: General flags to pass to all Valgrind tools.
 157 #    (Default: --num-callers=30)
 158 #  - VALGRIND_$toolname_FLAGS: Flags to pass to Valgrind $toolname (one of:
 159 #    memcheck, helgrind, drd, sgcheck). (Default: various)
 160
 161 # Optional variables
 162 VALGRIND_SUPPRESSIONS ?= $(addprefix --suppressions=,$(VALGRIND_SUPPRESSIONS_FILES))
 163 VALGRIND_FLAGS ?= --num-callers=30
 164 VALGRIND_memcheck_FLAGS ?= --leak-check=full --show-reachable=no
 165 VALGRIND_helgrind_FLAGS ?= --history-level=approx
 166 VALGRIND_drd_FLAGS ?=
 167 VALGRIND_sgcheck_FLAGS ?=
 168
 169 # Internal use
 170 valgrind_log_files = $(addprefix test-suite-,$(addsuffix .log,$(valgrind_tools)))
 171
 172 valgrind_memcheck_flags = --tool=memcheck $(VALGRIND_memcheck_FLAGS)
 173 valgrind_helgrind_flags = --tool=helgrind $(VALGRIND_helgrind_FLAGS)
 174 valgrind_drd_flags = --tool=drd $(VALGRIND_drd_FLAGS)
 175 valgrind_sgcheck_flags = --tool=exp-sgcheck $(VALGRIND_sgcheck_FLAGS)
 176
 177 valgrind_quiet = $(valgrind_quiet_$(V))
 178 valgrind_quiet_ = $(valgrind_quiet_$(AM_DEFAULT_VERBOSITY))
 179 valgrind_quiet_0 = --quiet
 180 valgrind_v_use   = $(valgrind_v_use_$(V))
 181 valgrind_v_use_  = $(valgrind_v_use_$(AM_DEFAULT_VERBOSITY))
 182 valgrind_v_use_0 = @echo "  USE   " $(patsubst check-valgrind-%,%,$''@):;
 183
 184 # Support running with and without libtool.
 185 ifneq ($(LIBTOOL),)
 186 valgrind_lt = $(LIBTOOL) $(AM_LIBTOOLFLAGS) $(LIBTOOLFLAGS) --mode=execute
 187 else
 188 valgrind_lt =
 189 endif
 190
 191 # Use recursive makes in order to ignore errors during check
 192 check-valgrind:
 193 ifeq ($(VALGRIND_ENABLED),yes)
 194         $(A''M_V_at)$(MAKE) $(AM_MAKEFLAGS) -k \
 195                 $(foreach tool, $(valgrind_enabled_tools), check-valgrind-$(tool))
 196 else
 197         @echo "Need to reconfigure with --enable-valgrind"
 198 endif
 199
 200 # Valgrind running
 201 VALGRIND_TESTS_ENVIRONMENT = \
 202         $(TESTS_ENVIRONMENT) \
 203         env VALGRIND=$(VALGRIND) \
 204         G_SLICE=always-malloc,debug-blocks \
 205         G_DEBUG=fatal-warnings,fatal-criticals,gc-friendly
 206
 207 VALGRIND_LOG_COMPILER = \
 208         $(valgrind_lt) \
 209         $(VALGRIND) $(VALGRIND_SUPPRESSIONS) --error-exitcode=1 $(VALGRIND_FLAGS)
 210
 211 define valgrind_tool_rule
 212 check-valgrind-$(1): $$(BUILT_SOURCES)
 213 ifeq ($$(VALGRIND_ENABLED)-$$(ENABLE_VALGRIND_$(1)),yes-yes)
 214         $$(valgrind_v_use)$$(MAKE) $$(AM_MAKEFLAGS) check-am \
 215                 TESTS_ENVIRONMENT="$$(VALGRIND_TESTS_ENVIRONMENT)" \
 216                 LOG_COMPILER="$$(VALGRIND_LOG_COMPILER)" \
 217                 LOG_FLAGS="$$(valgrind_$(1)_flags)" \
 218                 TEST_SUITE_LOG=test-suite-$(1).log
 219 else ifeq ($$(VALGRIND_ENABLED),yes)
 220         @echo "Need to reconfigure with --enable-valgrind-$(1)"
 221 else
 222         @echo "Need to reconfigure with --enable-valgrind"
 223 endif
 224 endef
 225
 226 $(foreach tool,$(valgrind_tools),$(eval $(call valgrind_tool_rule,$(tool))))
 227
 228 A''M_DISTCHECK_CONFIGURE_FLAGS ?=
 229 A''M_DISTCHECK_CONFIGURE_FLAGS += --disable-valgrind
 230
 231 MOSTLYCLEANFILES ?=
 232 MOSTLYCLEANFILES += $(valgrind_log_files)
 233
 234 .PHONY: check-valgrind $(add-prefix check-valgrind-,$(valgrind_tools))
 235 ']
 236
 237         AC_SUBST([VALGRIND_CHECK_RULES])
 238         m4_ifdef([_AM_SUBST_NOTMAKE], [_AM_SUBST_NOTMAKE([VALGRIND_CHECK_RULES])])
 239 ])