granicus.if.org Git - icinga2/blob - lib/config/CMakeLists.txt

   1 # Icinga 2
   2 # Copyright (C) 2012-2018 Icinga Development Team (https://www.icinga.com/)
   3 #
   4 # This program is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU General Public License
   6 # as published by the Free Software Foundation; either version 2
   7 # of the License, or (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; if not, write to the Free Software Foundation
  16 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA.
  17
  18 find_package(BISON 2.3.0 REQUIRED)
  19 find_package(FLEX 2.5.31 REQUIRED)
  20
  21 bison_target(config_parser config_parser.yy ${CMAKE_CURRENT_BINARY_DIR}/config_parser.cc)
  22 set_property(SOURCE ${CMAKE_CURRENT_BINARY_DIR}/config_parser.cc PROPERTY EXCLUDE_UNITY_BUILD TRUE)
  23
  24 flex_target(config_lexer config_lexer.ll ${CMAKE_CURRENT_BINARY_DIR}/config_lexer.cc)
  25 set_property(SOURCE ${CMAKE_CURRENT_BINARY_DIR}/config_lexer.cc PROPERTY EXCLUDE_UNITY_BUILD TRUE)
  26
  27 if(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  28   set_property(SOURCE ${CMAKE_CURRENT_BINARY_DIR}/config_parser.cc PROPERTY COMPILE_FLAGS "-Wno-deprecated-register -Wno-parentheses-equality -Wno-unused-function")
  29   set_property(SOURCE ${CMAKE_CURRENT_BINARY_DIR}/config_lexer.cc PROPERTY COMPILE_FLAGS "-Wno-deprecated-register -Wno-null-conversion")
  30 endif()
  31
  32 add_flex_bison_dependency(config_lexer config_parser)
  33
  34 include_directories(${CMAKE_CURRENT_BINARY_DIR} ${CMAKE_CURRENT_SOURCE_DIR})
  35
  36 set(config_SOURCES
  37   activationcontext.cpp applyrule.cpp
  38   configcompilercontext.cpp configcompiler.cpp configitembuilder.cpp
  39   configitem.cpp ${FLEX_config_lexer_OUTPUTS} ${BISON_config_parser_OUTPUTS}
  40   expression.cpp objectrule.cpp
  41 )
  42
  43 if(ICINGA2_UNITY_BUILD)
  44     mkunity_target(config config config_SOURCES)
  45 endif()
  46
  47 add_library(config SHARED ${config_SOURCES})
  48
  49 target_link_libraries(config ${Boost_LIBRARIES} base)
  50
  51 set_target_properties (
  52   config PROPERTIES
  53   INSTALL_RPATH ${CMAKE_INSTALL_FULL_LIBDIR}/icinga2
  54   DEFINE_SYMBOL I2_CONFIG_BUILD
  55   FOLDER Lib
  56   VERSION ${SPEC_VERSION}
  57 )
  58
  59 install(
  60   TARGETS config
  61   RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR}
  62   LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}/icinga2
  63 )
  64
  65 if(APPLE)
  66   install(
  67     TARGETS config
  68     LIBRARY DESTINATION ${CMAKE_INSTALL_BINDIR}/icinga-studio.app/Contents
  69   )
  70 endif()