granicus.if.org Git - icinga2/blob - icinga-app/CMakeLists.txt

   1 # Icinga 2 | (c) 2012 Icinga GmbH | GPLv2+
   2
   3 if(MSVC)
   4   set(WindowsSources icinga.rc)
   5 else()
   6   set(WindowsSources "")
   7 endif()
   8
   9 set(icingaloader_SOURCES
  10   icinga.cpp
  11   ${WindowsSources}
  12 )
  13
  14 add_library(icingaloader OBJECT ${icingaloader_SOURCES})
  15 add_dependencies(icingaloader base config cli)
  16
  17 set_target_properties (
  18   icingaloader PROPERTIES
  19   FOLDER Lib
  20 )
  21
  22 include_directories(${Boost_INCLUDE_DIRS})
  23
  24 if(ICINGA2_WITH_CHECKER)
  25   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:checker>)
  26 endif()
  27
  28 if(ICINGA2_WITH_COMPAT)
  29   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:compat>)
  30 endif()
  31
  32 if(ICINGA2_WITH_MYSQL OR ICINGA2_WITH_PGSQL)
  33   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:db_ido>)
  34 endif()
  35
  36 if(ICINGA2_WITH_MYSQL)
  37   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:db_ido_mysql>)
  38 endif()
  39
  40 if(ICINGA2_WITH_PGSQL)
  41   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:db_ido_pgsql>)
  42 endif()
  43
  44 if(ICINGA2_WITH_LIVESTATUS)
  45   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:livestatus>)
  46 endif()
  47
  48 if(ICINGA2_WITH_NOTIFICATION)
  49   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:notification>)
  50 endif()
  51
  52 if(ICINGA2_WITH_PERFDATA)
  53   list(APPEND icinga_app_SOURCES $<TARGET_OBJECTS:perfdata>)
  54 endif()
  55
  56 add_executable(icinga-app
  57   $<TARGET_OBJECTS:icingaloader>
  58   ${base_OBJS}
  59   $<TARGET_OBJECTS:config>
  60   $<TARGET_OBJECTS:remote>
  61   $<TARGET_OBJECTS:cli>
  62   $<TARGET_OBJECTS:icinga>
  63   $<TARGET_OBJECTS:methods>
  64   ${icinga_app_SOURCES}
  65 )
  66
  67 target_link_libraries(icinga-app ${base_DEPS})
  68
  69 set_target_properties (
  70   icinga-app PROPERTIES
  71   FOLDER Bin
  72   OUTPUT_NAME icinga2
  73 )
  74
  75 if(WIN32)
  76   set(InstallPath "${CMAKE_INSTALL_SBINDIR}")
  77 else()
  78   configure_file(icinga2.cmake ${CMAKE_CURRENT_BINARY_DIR}/icinga2 @ONLY)
  79
  80   install(
  81     FILES ${CMAKE_CURRENT_BINARY_DIR}/icinga2
  82     DESTINATION ${CMAKE_INSTALL_SBINDIR}
  83     PERMISSIONS OWNER_EXECUTE OWNER_WRITE OWNER_READ GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
  84   )
  85
  86   set(InstallPath "${CMAKE_INSTALL_LIBDIR}/icinga2/sbin")
  87 endif()
  88
  89 install(
  90   TARGETS icinga-app
  91   RUNTIME DESTINATION ${InstallPath}
  92 )
  93
  94 install(CODE "file(MAKE_DIRECTORY \"\$ENV{DESTDIR}${ICINGA2_FULL_LOGDIR}\")")
  95 install(CODE "file(MAKE_DIRECTORY \"\$ENV{DESTDIR}${ICINGA2_FULL_DATADIR}\")")
  96 install(CODE "file(MAKE_DIRECTORY \"\$ENV{DESTDIR}${ICINGA2_FULL_INITRUNDIR}\")")