granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [11devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc";;
 357     *) pgac_cc_list="gcc cc";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361
 362 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 363 # but has idiosyncrasies of its own.  We assume icc will define
 364 # __INTEL_COMPILER regardless of CFLAGS.
 365 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 366 choke me
 367 @%:@endif])], [ICC=yes], [ICC=no])
 368
 369 # Check if it's Sun Studio compiler. We assume that
 370 # __SUNPRO_C will be defined for Sun Studio compilers
 371 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 372 choke me
 373 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 374
 375 AC_SUBST(SUN_STUDIO_CC)
 376
 377 unset CFLAGS
 378
 379 #
 380 # Read the template
 381 #
 382 . "$srcdir/src/template/$template" || exit
 383
 384 # CFLAGS are selected so:
 385 # If the user specifies something in the environment, that is used.
 386 # else:  If the template file set something, that is used.
 387 # else:  If coverage was enabled, don't set anything.
 388 # else:  If the compiler is GCC, then we use -O2.
 389 # else:  If the compiler is something else, then we use -O, unless debugging.
 390
 391 if test "$ac_env_CFLAGS_set" = set; then
 392   CFLAGS=$ac_env_CFLAGS_value
 393 elif test "${CFLAGS+set}" = set; then
 394   : # (keep what template set)
 395 elif test "$enable_coverage" = yes; then
 396   : # no optimization by default
 397 elif test "$GCC" = yes; then
 398   CFLAGS="-O2"
 399 else
 400   # if the user selected debug mode, don't use -O
 401   if test "$enable_debug" != yes; then
 402     CFLAGS="-O"
 403   fi
 404 fi
 405
 406 # CFLAGS we determined above will be added back at the end
 407 user_CFLAGS=$CFLAGS
 408 CFLAGS=""
 409
 410 # set CFLAGS_VECTOR from the environment, if available
 411 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 412   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 413 fi
 414
 415 # Some versions of GCC support some additional useful warning flags.
 416 # Check whether they are supported, and add them to CFLAGS if so.
 417 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 418 # but has its own.  Also check other compiler-specific flags here.
 419
 420 if test "$GCC" = yes -a "$ICC" = no; then
 421   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 422   # These work in some but not all gcc versions
 423   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 424   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 425   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 426   # This was included in -Wall/-Wformat in older GCC versions
 427   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 428   # Disable strict-aliasing rules; needed for gcc 3.3+
 429   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 430   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 431   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 432   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 433   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 434   # Optimization flags for specific files that benefit from vectorization
 435   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 436   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 437   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 438   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 439   # test for the positive form and if that works, add the negative form
 440   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 441   if test -n "$NOT_THE_CFLAGS"; then
 442     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 443   fi
 444 elif test "$ICC" = yes; then
 445   # Intel's compiler has a bug/misoptimization in checking for
 446   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 447   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 448   # Make sure strict aliasing is off (though this is said to be the default)
 449   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 450 elif test "$PORTNAME" = "aix"; then
 451   # AIX's xlc has to have strict aliasing turned off too
 452   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 453   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 454 elif test "$PORTNAME" = "hpux"; then
 455   # On some versions of HP-UX, libm functions do not set errno by default.
 456   # Fix that by using +Olibmerrno if the compiler recognizes it.
 457   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 458 fi
 459
 460 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 461
 462 # supply -g if --enable-debug
 463 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 464   CFLAGS="$CFLAGS -g"
 465 fi
 466
 467 # enable code coverage if --enable-coverage
 468 if test "$enable_coverage" = yes; then
 469   if test "$GCC" = yes; then
 470     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 471   else
 472     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 473   fi
 474 fi
 475
 476 # enable profiling if --enable-profiling
 477 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 478   if test "$GCC" = yes; then
 479     AC_DEFINE([PROFILE_PID_DIR], 1,
 480            [Define to 1 to allow profiling output to be saved separately for each process.])
 481     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 482   else
 483     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 484   fi
 485 fi
 486
 487 # We already have this in Makefile.win32, but configure needs it too
 488 if test "$PORTNAME" = "win32"; then
 489   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 490 fi
 491
 492 # Now that we're done automatically adding stuff to CFLAGS, put back the
 493 # user-specified flags (if any) at the end.  This lets users override
 494 # the automatic additions.
 495 CFLAGS="$CFLAGS $user_CFLAGS"
 496
 497 # Check if the compiler still works with the final flag settings
 498 AC_MSG_CHECKING([whether the C compiler still works])
 499 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 500   [AC_MSG_RESULT(yes)],
 501   [AC_MSG_RESULT(no)
 502    AC_MSG_ERROR([cannot proceed])])
 503
 504 # Defend against gcc -ffast-math
 505 if test "$GCC" = yes; then
 506 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 507 choke me
 508 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 509 fi
 510
 511 AC_PROG_CPP
 512 AC_SUBST(GCC)
 513
 514
 515 #
 516 # Set up TAS assembly code if needed; the template file has now had its
 517 # chance to request this.
 518 #
 519 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 520
 521 if test "$need_tas" = yes ; then
 522   TAS=tas.o
 523 else
 524   TAS=""
 525 fi
 526 AC_SUBST(TAS)
 527
 528
 529 #
 530 # Automatic dependency tracking
 531 #
 532 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 533               [autodepend=yes])
 534 AC_SUBST(autodepend)
 535
 536
 537 #
 538 # Enable assert checks
 539 #
 540 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 541               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 542                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 543
 544
 545 #
 546 # Include directories
 547 #
 548 ac_save_IFS=$IFS
 549 IFS="${IFS}${PATH_SEPARATOR}"
 550 # SRCH_INC comes from the template file
 551 for dir in $with_includes $SRCH_INC; do
 552   if test -d "$dir"; then
 553     INCLUDES="$INCLUDES -I$dir"
 554   else
 555     AC_MSG_WARN([*** Include directory $dir does not exist.])
 556   fi
 557 done
 558 IFS=$ac_save_IFS
 559 AC_SUBST(INCLUDES)
 560
 561
 562 #
 563 # Library directories
 564 #
 565 ac_save_IFS=$IFS
 566 IFS="${IFS}${PATH_SEPARATOR}"
 567 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 568 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 569   if test -d "$dir"; then
 570     LIBDIRS="$LIBDIRS -L$dir"
 571   else
 572     AC_MSG_WARN([*** Library directory $dir does not exist.])
 573   fi
 574 done
 575 IFS=$ac_save_IFS
 576
 577 #
 578 # Enable thread-safe client libraries
 579 #
 580 AC_MSG_CHECKING([allow thread-safe client libraries])
 581 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 582 if test "$enable_thread_safety" = yes; then
 583   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 584           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 585 fi
 586 AC_MSG_RESULT([$enable_thread_safety])
 587 AC_SUBST(enable_thread_safety)
 588
 589 #
 590 # ICU
 591 #
 592 AC_MSG_CHECKING([whether to build with ICU support])
 593 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 594               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 595 AC_MSG_RESULT([$with_icu])
 596 AC_SUBST(with_icu)
 597
 598 if test "$with_icu" = yes; then
 599   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 600 fi
 601
 602 #
 603 # Optionally build Tcl modules (PL/Tcl)
 604 #
 605 AC_MSG_CHECKING([whether to build with Tcl])
 606 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 607 AC_MSG_RESULT([$with_tcl])
 608 AC_SUBST([with_tcl])
 609
 610 # We see if the path to the Tcl/Tk configuration scripts is specified.
 611 # This will override the use of tclsh to find the paths to search.
 612
 613 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 614
 615 #
 616 # Optionally build Perl modules (PL/Perl)
 617 #
 618 AC_MSG_CHECKING([whether to build Perl modules])
 619 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 620 AC_MSG_RESULT([$with_perl])
 621 AC_SUBST(with_perl)
 622
 623 #
 624 # Optionally build Python modules (PL/Python)
 625 #
 626 AC_MSG_CHECKING([whether to build Python modules])
 627 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 628 AC_MSG_RESULT([$with_python])
 629 AC_SUBST(with_python)
 630
 631 #
 632 # GSSAPI
 633 #
 634 AC_MSG_CHECKING([whether to build with GSSAPI support])
 635 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 636 [
 637   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 638   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 639 ])
 640 AC_MSG_RESULT([$with_gssapi])
 641
 642
 643 AC_SUBST(krb_srvtab)
 644
 645
 646 #
 647 # Kerberos configuration parameters
 648 #
 649 PGAC_ARG_REQ(with, krb-srvnam,
 650              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 651              [],
 652              [with_krb_srvnam="postgres"])
 653 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 654                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 655
 656
 657 #
 658 # PAM
 659 #
 660 AC_MSG_CHECKING([whether to build with PAM support])
 661 PGAC_ARG_BOOL(with, pam, no,
 662               [build with PAM support],
 663               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 664 AC_MSG_RESULT([$with_pam])
 665
 666
 667 #
 668 # BSD AUTH
 669 #
 670 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 671 PGAC_ARG_BOOL(with, bsd-auth, no,
 672               [build with BSD Authentication support],
 673               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 674 AC_MSG_RESULT([$with_bsd_auth])
 675
 676
 677 #
 678 # LDAP
 679 #
 680 AC_MSG_CHECKING([whether to build with LDAP support])
 681 PGAC_ARG_BOOL(with, ldap, no,
 682               [build with LDAP support],
 683               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 684 AC_MSG_RESULT([$with_ldap])
 685 AC_SUBST(with_ldap)
 686
 687
 688 #
 689 # Bonjour
 690 #
 691 AC_MSG_CHECKING([whether to build with Bonjour support])
 692 PGAC_ARG_BOOL(with, bonjour, no,
 693               [build with Bonjour support],
 694               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 695 AC_MSG_RESULT([$with_bonjour])
 696
 697
 698 #
 699 # OpenSSL
 700 #
 701 AC_MSG_CHECKING([whether to build with OpenSSL support])
 702 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 703               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 704 AC_MSG_RESULT([$with_openssl])
 705 AC_SUBST(with_openssl)
 706
 707 #
 708 # SELinux
 709 #
 710 AC_MSG_CHECKING([whether to build with SELinux support])
 711 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 712 AC_SUBST(with_selinux)
 713 AC_MSG_RESULT([$with_selinux])
 714
 715 #
 716 # Systemd
 717 #
 718 AC_MSG_CHECKING([whether to build with systemd support])
 719 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 720               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 721 AC_SUBST(with_systemd)
 722 AC_MSG_RESULT([$with_systemd])
 723
 724 #
 725 # Readline
 726 #
 727 PGAC_ARG_BOOL(with, readline, yes,
 728               [do not use GNU Readline nor BSD Libedit for editing])
 729 # readline on MinGW has problems with backslashes in psql and other bugs.
 730 # This is particularly a problem with non-US code pages.
 731 # Therefore disable its use until we understand the cause. 2004-07-20
 732 if test "$PORTNAME" = "win32"; then
 733   if test "$with_readline" = yes; then
 734     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 735     with_readline=no
 736   fi
 737 fi
 738
 739
 740 #
 741 # Prefer libedit
 742 #
 743 PGAC_ARG_BOOL(with, libedit-preferred, no,
 744               [prefer BSD Libedit over GNU Readline])
 745
 746
 747 #
 748 # UUID library
 749 #
 750 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 751 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 752 # UUID library.  More than one of these might be present on a given platform,
 753 # so we make the user say which one she wants.
 754 #
 755 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 756 if test x"$with_uuid" = x"" ; then
 757   with_uuid=no
 758 fi
 759 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 760 if test "$with_ossp_uuid" = yes ; then
 761   with_uuid=ossp
 762 fi
 763
 764 if test "$with_uuid" = bsd ; then
 765   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 766   UUID_EXTRA_OBJS="md5.o sha1.o"
 767 elif test "$with_uuid" = e2fs ; then
 768   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 769   UUID_EXTRA_OBJS="md5.o sha1.o"
 770 elif test "$with_uuid" = ossp ; then
 771   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 772   UUID_EXTRA_OBJS=""
 773 elif test "$with_uuid" = no ; then
 774   UUID_EXTRA_OBJS=""
 775 else
 776   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 777 fi
 778 AC_SUBST(with_uuid)
 779 AC_SUBST(UUID_EXTRA_OBJS)
 780
 781
 782 #
 783 # XML
 784 #
 785 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 786               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 787
 788 if test "$with_libxml" = yes ; then
 789   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 790   if test -n "$XML2_CONFIG"; then
 791     for pgac_option in `$XML2_CONFIG --cflags`; do
 792       case $pgac_option in
 793         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 794       esac
 795     done
 796     for pgac_option in `$XML2_CONFIG --libs`; do
 797       case $pgac_option in
 798         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 799       esac
 800     done
 801   fi
 802 fi
 803
 804 AC_SUBST(with_libxml)
 805
 806 #
 807 # XSLT
 808 #
 809 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 810               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 811
 812
 813 AC_SUBST(with_libxslt)
 814
 815 #
 816 # tzdata
 817 #
 818 PGAC_ARG_REQ(with, system-tzdata,
 819              [DIR], [use system time zone data in DIR])
 820 AC_SUBST(with_system_tzdata)
 821
 822 #
 823 # Zlib
 824 #
 825 PGAC_ARG_BOOL(with, zlib, yes,
 826               [do not use Zlib])
 827 AC_SUBST(with_zlib)
 828
 829 #
 830 # Elf
 831 #
 832
 833 # Assume system is ELF if it predefines __ELF__ as 1,
 834 # otherwise believe host_os based default.
 835 case $host_os in
 836     freebsd1*|freebsd2*) elf=no;;
 837     freebsd3*|freebsd4*) elf=yes;;
 838 esac
 839
 840 AC_EGREP_CPP(yes,
 841 [#if __ELF__
 842   yes
 843 #endif
 844 ],
 845 [ELF_SYS=true],
 846 [if test "X$elf" = "Xyes" ; then
 847   ELF_SYS=true
 848 else
 849   ELF_SYS=
 850 fi])
 851 AC_SUBST(ELF_SYS)
 852
 853 #
 854 # Assignments
 855 #
 856
 857 CPPFLAGS="$CPPFLAGS $INCLUDES"
 858 LDFLAGS="$LDFLAGS $LIBDIRS"
 859
 860 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 861 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 862
 863 PGAC_PROG_LD
 864 AC_SUBST(LD)
 865 AC_SUBST(with_gnu_ld)
 866 AC_PROG_RANLIB
 867 PGAC_CHECK_STRIP
 868 AC_CHECK_TOOL(AR, ar, ar)
 869 if test "$PORTNAME" = "win32"; then
 870   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 871   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 872   AC_CHECK_TOOL(WINDRES, windres, windres)
 873 fi
 874
 875 AC_PROG_INSTALL
 876 # When Autoconf chooses install-sh as install program it tries to generate
 877 # a relative path to it in each makefile where it substitutes it. This clashes
 878 # with our Makefile.global concept. This workaround helps.
 879 case $INSTALL in
 880   *install-sh*) install_bin='';;
 881   *) install_bin=$INSTALL;;
 882 esac
 883 AC_SUBST(install_bin)
 884
 885 PGAC_PATH_PROGS(TAR, tar)
 886 AC_PROG_LN_S
 887 AC_PROG_AWK
 888 AC_PROG_MKDIR_P
 889 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 890 # a relative path to it in each makefile where it substitutes it. This clashes
 891 # with our Makefile.global concept. This workaround helps.
 892 case $MKDIR_P in
 893   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 894 esac
 895
 896 PGAC_PATH_BISON
 897 PGAC_PATH_FLEX
 898
 899 PGAC_PATH_PERL
 900 if test "$with_perl" = yes; then
 901   if test -z "$PERL"; then
 902     AC_MSG_ERROR([Perl not found])
 903   fi
 904   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 905   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
 906     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
 907 You might have to rebuild your Perl installation.  Refer to the
 908 documentation for details.  Use --without-perl to disable building
 909 PL/Perl.])
 910   fi
 911   PGAC_CHECK_PERL_EMBED_CCFLAGS
 912   PGAC_CHECK_PERL_EMBED_LDFLAGS
 913 fi
 914
 915 if test "$with_python" = yes; then
 916   PGAC_PATH_PYTHON
 917   PGAC_CHECK_PYTHON_EMBED_SETUP
 918 fi
 919
 920 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 921   PGAC_PATH_PROGS(ZIC, zic)
 922   if test -z "$ZIC"; then
 923     AC_MSG_ERROR([
 924 When cross-compiling, either use the option --with-system-tzdata to use
 925 existing time-zone data, or set the environment variable ZIC to a zic
 926 program to use during the build.])
 927   fi
 928 fi
 929
 930 #
 931 # Pthreads
 932 #
 933 # For each platform, we need to know about any special compile and link
 934 # libraries, and whether the normal C function names are thread-safe.
 935 # See the comment at the top of src/port/thread.c for more information.
 936 # WIN32 doesn't need the pthread tests;  it always uses threads
 937 #
 938 # These tests are run before the library-tests, because linking with the
 939 # other libraries can pull in the pthread functions as a side-effect.  We
 940 # want to use the -pthread or similar flags directly, and not rely on
 941 # the side-effects of linking with some other library.
 942 #
 943 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
 944 # invocation below is the first one in the script, and autoconf generates
 945 # additional code for that, which must not be inside the if-block. AS_IF
 946 # knows how to do that.
 947 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
 948 [ # then
 949 AX_PTHREAD      # set thread flags
 950
 951 # Some platforms use these, so just define them.  They can't hurt if they
 952 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
 953 # enables 5-arg getpwuid_r, among other things.
 954 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 955
 956 # Check for *_r functions
 957 _CFLAGS="$CFLAGS"
 958 _LIBS="$LIBS"
 959 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 960 LIBS="$LIBS $PTHREAD_LIBS"
 961
 962 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
 963 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
 964
 965 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 966
 967 # Do test here with the proper thread flags
 968 PGAC_FUNC_STRERROR_R_INT
 969
 970 CFLAGS="$_CFLAGS"
 971 LIBS="$_LIBS"
 972
 973 ], [ # else
 974 # do not use values from template file
 975 PTHREAD_CFLAGS=
 976 PTHREAD_LIBS=
 977 ]) # fi
 978
 979 AC_SUBST(PTHREAD_CFLAGS)
 980 AC_SUBST(PTHREAD_LIBS)
 981
 982
 983 ##
 984 ## Libraries
 985 ##
 986 ## Most libraries are included only if they demonstrably provide a function
 987 ## we need, but libm is an exception: always include it, because there are
 988 ## too many compilers that play cute optimization games that will break
 989 ## probes for standard functions such as pow().
 990 ##
 991
 992 AC_CHECK_LIB(m, main)
 993 AC_SEARCH_LIBS(setproctitle, util)
 994 AC_SEARCH_LIBS(dlopen, dl)
 995 AC_SEARCH_LIBS(socket, [socket ws2_32])
 996 AC_SEARCH_LIBS(shl_load, dld)
 997 # We only use libld in port/dynloader/aix.c
 998 case $host_os in
 999      aix*)
1000         AC_SEARCH_LIBS(ldopen, ld)
1001         ;;
1002 esac
1003 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1004 AC_SEARCH_LIBS(crypt, crypt)
1005 AC_SEARCH_LIBS(shm_open, rt)
1006 AC_SEARCH_LIBS(shm_unlink, rt)
1007 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1008 # Solaris:
1009 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1010 # Required for thread_test.c on Solaris
1011 AC_SEARCH_LIBS(sched_yield, rt)
1012 # Required for thread_test.c on Solaris 2.5:
1013 # Other ports use it too (HP-UX) so test unconditionally
1014 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1015 # Cygwin:
1016 AC_SEARCH_LIBS(shmget, cygipc)
1017
1018 if test "$with_readline" = yes; then
1019   PGAC_CHECK_READLINE
1020   if test x"$pgac_cv_check_readline" = x"no"; then
1021     AC_MSG_ERROR([readline library not found
1022 If you have readline already installed, see config.log for details on the
1023 failure.  It is possible the compiler isn't looking in the proper directory.
1024 Use --without-readline to disable readline support.])
1025   fi
1026 fi
1027
1028 if test "$with_zlib" = yes; then
1029   AC_CHECK_LIB(z, inflate, [],
1030                [AC_MSG_ERROR([zlib library not found
1031 If you have zlib already installed, see config.log for details on the
1032 failure.  It is possible the compiler isn't looking in the proper directory.
1033 Use --without-zlib to disable zlib support.])])
1034 fi
1035
1036 if test "$enable_spinlocks" = yes; then
1037   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1038 else
1039   AC_MSG_WARN([
1040 *** Not using spinlocks will cause poor performance.])
1041 fi
1042
1043 if test "$enable_atomics" = yes; then
1044   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1045 else
1046   AC_MSG_WARN([
1047 *** Not using atomic operations will cause poor performance.])
1048 fi
1049
1050 if test "$with_gssapi" = yes ; then
1051   if test "$PORTNAME" != "win32"; then
1052     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1053                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1054   else
1055     LIBS="$LIBS -lgssapi32"
1056   fi
1057 fi
1058
1059 if test "$with_openssl" = yes ; then
1060   dnl Order matters!
1061   if test "$PORTNAME" != "win32"; then
1062      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1063      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1064   else
1065      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1066      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1067   fi
1068   AC_CHECK_FUNCS([SSL_get_current_compression X509_get_signature_nid])
1069   # Functions introduced in OpenSSL 1.1.0. We used to check for
1070   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1071   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1072   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1073   # functions.
1074   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1075   # OpenSSL versions before 1.1.0 required setting callback functions, for
1076   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1077   # function was removed.
1078   AC_CHECK_FUNCS([CRYPTO_lock])
1079 fi
1080
1081 if test "$with_pam" = yes ; then
1082   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1083 fi
1084
1085 if test "$with_libxml" = yes ; then
1086   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1087 fi
1088
1089 if test "$with_libxslt" = yes ; then
1090   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1091 fi
1092
1093 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1094 if test "$with_ldap" = yes ; then
1095   _LIBS="$LIBS"
1096   if test "$PORTNAME" != "win32"; then
1097     AC_CHECK_LIB(ldap, ldap_bind, [],
1098                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1099                  [$EXTRA_LDAP_LIBS])
1100     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1101     if test "$enable_thread_safety" = yes; then
1102       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1103       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1104                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1105                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1106       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1107     else
1108       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1109     fi
1110     AC_CHECK_FUNCS([ldap_initialize])
1111   else
1112     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1113     LDAP_LIBS_FE="-lwldap32"
1114     LDAP_LIBS_BE="-lwldap32"
1115   fi
1116   LIBS="$_LIBS"
1117 fi
1118 AC_SUBST(LDAP_LIBS_FE)
1119 AC_SUBST(LDAP_LIBS_BE)
1120
1121 # for contrib/sepgsql
1122 if test "$with_selinux" = yes; then
1123   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1124                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1125 fi
1126
1127 # for contrib/uuid-ossp
1128 if test "$with_uuid" = bsd ; then
1129   # On BSD, the UUID functions are in libc
1130   AC_CHECK_FUNC(uuid_to_string,
1131     [UUID_LIBS=""],
1132     [AC_MSG_ERROR([BSD UUID functions are not present])])
1133 elif test "$with_uuid" = e2fs ; then
1134   # On macOS, the UUID functions are in libc
1135   AC_CHECK_FUNC(uuid_generate,
1136     [UUID_LIBS=""],
1137     [AC_CHECK_LIB(uuid, uuid_generate,
1138       [UUID_LIBS="-luuid"],
1139       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1140 elif test "$with_uuid" = ossp ; then
1141   AC_CHECK_LIB(ossp-uuid, uuid_export,
1142     [UUID_LIBS="-lossp-uuid"],
1143     [AC_CHECK_LIB(uuid, uuid_export,
1144       [UUID_LIBS="-luuid"],
1145       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1146 fi
1147 AC_SUBST(UUID_LIBS)
1148
1149
1150 ##
1151 ## Header files
1152 ##
1153
1154 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1155
1156 # On BSD, test for net/if.h will fail unless sys/socket.h
1157 # is included first.
1158 AC_CHECK_HEADERS(net/if.h, [], [],
1159 [AC_INCLUDES_DEFAULT
1160 #include <sys/socket.h>
1161 ])
1162
1163 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1164 # is included first.
1165 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1166 [AC_INCLUDES_DEFAULT
1167 #include <sys/param.h>
1168 ])
1169
1170 # At least on IRIX, test for netinet/tcp.h will fail unless
1171 # netinet/in.h is included first.
1172 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1173 [AC_INCLUDES_DEFAULT
1174 #include <netinet/in.h>
1175 ])
1176
1177 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1178   AC_CHECK_HEADERS(readline/readline.h, [],
1179         [AC_CHECK_HEADERS(readline.h, [],
1180                 [AC_MSG_ERROR([readline header not found
1181 If you have readline already installed, see config.log for details on the
1182 failure.  It is possible the compiler isn't looking in the proper directory.
1183 Use --without-readline to disable readline support.])])])
1184   AC_CHECK_HEADERS(readline/history.h, [],
1185         [AC_CHECK_HEADERS(history.h, [],
1186                 [AC_MSG_ERROR([history header not found
1187 If you have readline already installed, see config.log for details on the
1188 failure.  It is possible the compiler isn't looking in the proper directory.
1189 Use --without-readline to disable readline support.])])])
1190 fi
1191
1192 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1193 # Some installations of libedit usurp /usr/include/readline/, which seems
1194 # bad practice, since in combined installations readline will have its headers
1195 # there.  We might have to resort to AC_EGREP checks to make sure we found
1196 # the proper header...
1197   AC_CHECK_HEADERS(editline/readline.h, [],
1198         [AC_CHECK_HEADERS(readline.h, [],
1199                 [AC_CHECK_HEADERS(readline/readline.h, [],
1200                         [AC_MSG_ERROR([readline header not found
1201 If you have libedit already installed, see config.log for details on the
1202 failure.  It is possible the compiler isn't looking in the proper directory.
1203 Use --without-readline to disable libedit support.])])])])
1204 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1205 # not be there at all.  Hence, don't complain if not found.  We must check
1206 # though, since in yet other versions it is an independent header.
1207   AC_CHECK_HEADERS(editline/history.h, [],
1208         [AC_CHECK_HEADERS(history.h, [],
1209                 [AC_CHECK_HEADERS(readline/history.h)])])
1210 fi
1211
1212 if test "$with_zlib" = yes; then
1213   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1214 If you have zlib already installed, see config.log for details on the
1215 failure.  It is possible the compiler isn't looking in the proper directory.
1216 Use --without-zlib to disable zlib support.])])
1217 fi
1218
1219 if test "$with_gssapi" = yes ; then
1220   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1221         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1222 fi
1223
1224 if test "$with_openssl" = yes ; then
1225   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1226   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1227 fi
1228
1229 if test "$with_pam" = yes ; then
1230   AC_CHECK_HEADERS(security/pam_appl.h, [],
1231                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1232                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1233 fi
1234
1235 if test "$with_bsd_auth" = yes ; then
1236   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1237 fi
1238
1239 if test "$with_systemd" = yes ; then
1240   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1241 fi
1242
1243 if test "$with_libxml" = yes ; then
1244   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1245 fi
1246
1247 if test "$with_libxslt" = yes ; then
1248   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1249 fi
1250
1251 if test "$with_ldap" = yes ; then
1252   if test "$PORTNAME" != "win32"; then
1253      AC_CHECK_HEADERS(ldap.h, [],
1254                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1255      PGAC_LDAP_SAFE
1256   else
1257      AC_CHECK_HEADERS(winldap.h, [],
1258                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1259                       [AC_INCLUDES_DEFAULT
1260 #include <windows.h>
1261                       ])
1262   fi
1263 fi
1264
1265 if test "$with_bonjour" = yes ; then
1266   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1267 dnl At some point we might add something like
1268 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1269 dnl but right now, what that would mainly accomplish is to encourage
1270 dnl people to try to use the avahi implementation, which does not work.
1271 dnl If you want to use Apple's own Bonjour code on another platform,
1272 dnl just add -ldns_sd to LIBS manually.
1273 fi
1274
1275 # for contrib/uuid-ossp
1276 if test "$with_uuid" = bsd ; then
1277   AC_CHECK_HEADERS(uuid.h,
1278     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1279       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1280     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1281 elif test "$with_uuid" = e2fs ; then
1282   AC_CHECK_HEADERS(uuid/uuid.h,
1283     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1284       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1285     [AC_CHECK_HEADERS(uuid.h,
1286       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1287         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1288       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1289 elif test "$with_uuid" = ossp ; then
1290   AC_CHECK_HEADERS(ossp/uuid.h,
1291     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1292       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1293     [AC_CHECK_HEADERS(uuid.h,
1294       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1295         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1296       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1297 fi
1298
1299 if test "$PORTNAME" = "win32" ; then
1300    AC_CHECK_HEADERS(crtdefs.h)
1301 fi
1302
1303 ##
1304 ## Types, structures, compiler characteristics
1305 ##
1306
1307 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1308 AC_C_BIGENDIAN
1309 AC_C_INLINE
1310 PGAC_PRINTF_ARCHETYPE
1311 AC_C_FLEXIBLE_ARRAY_MEMBER
1312 PGAC_C_SIGNED
1313 PGAC_C_FUNCNAME_SUPPORT
1314 PGAC_C_STATIC_ASSERT
1315 PGAC_C_TYPEOF
1316 PGAC_C_TYPES_COMPATIBLE
1317 PGAC_C_BUILTIN_BSWAP16
1318 PGAC_C_BUILTIN_BSWAP32
1319 PGAC_C_BUILTIN_BSWAP64
1320 PGAC_C_BUILTIN_CONSTANT_P
1321 PGAC_C_BUILTIN_UNREACHABLE
1322 PGAC_C_COMPUTED_GOTO
1323 PGAC_C_VA_ARGS
1324 PGAC_STRUCT_TIMEZONE
1325 PGAC_UNION_SEMUN
1326 PGAC_STRUCT_SOCKADDR_UN
1327 PGAC_STRUCT_SOCKADDR_STORAGE
1328 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1329 PGAC_STRUCT_ADDRINFO
1330 AC_TYPE_INTPTR_T
1331 AC_TYPE_UINTPTR_T
1332 AC_TYPE_LONG_LONG_INT
1333
1334 PGAC_TYPE_LOCALE_T
1335
1336 # MSVC doesn't cope well with defining restrict to __restrict, the
1337 # spelling it understands, because it conflicts with
1338 # __declspec(restrict). Therefore we define pg_restrict to the
1339 # appropriate definition, which presumably won't conflict.
1340 #
1341 # Allow platforms with buggy compilers to force restrict to not be
1342 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1343 # template.
1344 AC_C_RESTRICT
1345 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1346   pg_restrict=""
1347 else
1348   pg_restrict="$ac_cv_c_restrict"
1349 fi
1350 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1351 [Define to keyword to use for C99 restrict support, or to nothing if not
1352 supported])
1353
1354 AC_CHECK_TYPES([struct cmsgcred], [], [],
1355 [#include <sys/socket.h>
1356 #include <sys/param.h>
1357 #ifdef HAVE_SYS_UCRED_H
1358 #include <sys/ucred.h>
1359 #endif])
1360
1361 AC_CHECK_TYPES([struct option], [], [],
1362 [#ifdef HAVE_GETOPT_H
1363 #include <getopt.h>
1364 #endif])
1365
1366 if test "$with_zlib" = yes; then
1367   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1368   # did not).  While we could work around the lack of z_streamp, it
1369   # seems unwise to encourage people to use such old zlib versions...
1370   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1371 Use --without-zlib to disable zlib support.])],
1372                 [#include <zlib.h>])
1373 fi
1374
1375 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1376 case $host_cpu in
1377   ppc*|powerpc*)
1378     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1379     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1380         [int a = 0; int *p = &a; int r;
1381          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1382         [pgac_cv_have_ppc_mutex_hint=yes],
1383         [pgac_cv_have_ppc_mutex_hint=no])
1384     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1385     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1386         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1387     fi
1388   ;;
1389 esac
1390
1391 # Check largefile support.  You might think this is a system service not a
1392 # compiler characteristic, but you'd be wrong.  We must check this before
1393 # probing existence of related functions such as fseeko, since the largefile
1394 # defines can affect what is generated for that.
1395 if test "$PORTNAME" != "win32"; then
1396    AC_SYS_LARGEFILE
1397    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1398    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1399    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1400    dnl versions where the feature actually works, it's on by default anyway.
1401    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1402 fi
1403
1404 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1405 AC_CHECK_SIZEOF([off_t])
1406
1407 # If we don't have largefile support, can't handle segsize >= 2GB.
1408 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1409    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1410 fi
1411
1412
1413 ##
1414 ## Functions, global variables
1415 ##
1416
1417 PGAC_VAR_INT_TIMEZONE
1418 AC_FUNC_ACCEPT_ARGTYPES
1419 PGAC_FUNC_GETTIMEOFDAY_1ARG
1420 PGAC_FUNC_WCSTOMBS_L
1421
1422 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1423 # symbols that that library has no business exposing to the world.  Pending
1424 # acquisition of a clue by those developers, ignore libedit (including its
1425 # possible alias of libreadline) while checking for everything else.
1426 LIBS_including_readline="$LIBS"
1427 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1428
1429 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1430
1431 AC_REPLACE_FUNCS(fseeko)
1432 case $host_os in
1433         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1434         # Mingw uses macros to access Win32 API calls
1435         netbsd*|mingw*)
1436                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1437                 ac_cv_func_fseeko=yes;;
1438         *)
1439                 AC_FUNC_FSEEKO;;
1440 esac
1441
1442 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1443 # by calling it, 2009-04-02
1444 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1445 if test "$PORTNAME" != "solaris"; then
1446 AC_CHECK_FUNCS(posix_fadvise)
1447 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1448 fi
1449
1450 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1451 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1452 # This is probably only present on macOS, but may as well check always
1453 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1454
1455 HAVE_IPV6=no
1456 AC_CHECK_TYPE([struct sockaddr_in6],
1457         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1458          HAVE_IPV6=yes],
1459         [],
1460 [$ac_includes_default
1461 #include <netinet/in.h>])
1462 AC_SUBST(HAVE_IPV6)
1463
1464 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1465 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1466 [#include <machine/vmparam.h>
1467 #include <sys/exec.h>
1468 ],
1469 [PS_STRINGS->ps_nargvstr = 1;
1470 PS_STRINGS->ps_argvstr = "foo";])],
1471 [pgac_cv_var_PS_STRINGS=yes],
1472 [pgac_cv_var_PS_STRINGS=no])])
1473 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1474   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1475 fi
1476
1477
1478 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1479 # is missing.  Yes, there are machines that have only one.  We may
1480 # also decide to use snprintf.c if snprintf() is present but does not
1481 # have all the features we need --- see below.
1482
1483 if test "$PORTNAME" = "win32"; then
1484   # Win32 gets snprintf.c built unconditionally.
1485   #
1486   # To properly translate all NLS languages strings, we must support the
1487   # *printf() %$ format, which allows *printf() arguments to be selected
1488   # by position in the translated string.
1489   #
1490   # libintl versions < 0.13 use the native *printf() functions, and Win32
1491   # *printf() doesn't understand %$, so we must use our /port versions,
1492   # which do understand %$. libintl versions >= 0.13 include their own
1493   # *printf versions on Win32.  The libintl 0.13 release note text is:
1494   #
1495   #   C format strings with positions, as they arise when a translator
1496   #   needs to reorder a sentence, are now supported on all platforms.
1497   #   On those few platforms (NetBSD and Woe32) for which the native
1498   #   printf()/fprintf()/... functions don't support such format
1499   #   strings, replacements are provided through <libintl.h>.
1500   #
1501   # We could use libintl >= 0.13's *printf() if we were sure that we had
1502   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1503   # to guarantee that, it is best to just use our own, so we are sure to
1504   # get %$ support. In include/port.h we disable the *printf() macros
1505   # that might have been defined by libintl.
1506   #
1507   # We do this unconditionally whether NLS is used or not so we are sure
1508   # that all Win32 libraries and binaries behave the same.
1509   pgac_need_repl_snprintf=yes
1510 else
1511   pgac_need_repl_snprintf=no
1512   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1513   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1514 fi
1515
1516
1517 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1518 # include/c.h will provide declarations.  Note this is a separate test
1519 # from whether the functions exist in the C library --- there are
1520 # systems that have the functions but don't bother to declare them :-(
1521
1522 AC_CHECK_DECLS([snprintf, vsnprintf])
1523
1524
1525 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1526 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1527 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1528 #include <math.h>
1529 double glob_double;
1530 ],
1531 [return isinf(glob_double) ? 0 : 1;])],
1532 [ac_cv_func_isinf=yes],
1533 [ac_cv_func_isinf=no])])
1534
1535 if test $ac_cv_func_isinf = yes ; then
1536   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1537 else
1538   AC_LIBOBJ(isinf)
1539   # Look for a way to implement a substitute for isinf()
1540   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1541 fi
1542
1543 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1544
1545 case $host_os in
1546
1547         # Windows uses a specialised env handler
1548         # and doesn't need a replacement getpeereid because it doesn't use
1549         # Unix sockets.
1550         mingw*)
1551                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1552                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1553                 ac_cv_func_unsetenv=yes
1554                 ac_cv_func_getpeereid=yes;;
1555         *)
1556                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1557                 ;;
1558 esac
1559
1560 # System's version of getaddrinfo(), if any, may be used only if we found
1561 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1562 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1563 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1564    test "$PORTNAME" != "win32"; then
1565   AC_REPLACE_FUNCS([getaddrinfo])
1566 else
1567   AC_LIBOBJ(getaddrinfo)
1568 fi
1569
1570 # Similarly, use system's getopt_long() only if system provides struct option.
1571 if test x"$ac_cv_type_struct_option" = xyes ; then
1572   AC_REPLACE_FUNCS([getopt_long])
1573 else
1574   AC_LIBOBJ(getopt_long)
1575 fi
1576
1577 # Solaris' getopt() doesn't do what we want for long options, so always use
1578 # our version on that platform.
1579 if test "$PORTNAME" = "solaris"; then
1580   AC_LIBOBJ(getopt)
1581 fi
1582
1583 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1584 # so always use our version on Windows.
1585 if test "$PORTNAME" = "win32"; then
1586   AC_LIBOBJ(getopt)
1587   AC_LIBOBJ(getopt_long)
1588 fi
1589
1590 # Win32 (really MinGW) support
1591 if test "$PORTNAME" = "win32"; then
1592   AC_REPLACE_FUNCS(gettimeofday)
1593   AC_LIBOBJ(dirmod)
1594   AC_LIBOBJ(kill)
1595   AC_LIBOBJ(open)
1596   AC_LIBOBJ(system)
1597   AC_LIBOBJ(win32env)
1598   AC_LIBOBJ(win32error)
1599   AC_LIBOBJ(win32security)
1600   AC_LIBOBJ(win32setlocale)
1601   AC_DEFINE([HAVE_SYMLINK], 1,
1602             [Define to 1 if you have the `symlink' function.])
1603   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1604 #define WIN32_LEAN_AND_MEAN
1605 #include <windows.h>
1606 #include <string.h>
1607 #include <dbghelp.h>])
1608 fi
1609 if test x"$pgac_minidump_type" = x"yes" ; then
1610   AC_SUBST(have_win32_dbghelp,yes)
1611 else
1612   AC_SUBST(have_win32_dbghelp,no)
1613 fi
1614
1615 # Cygwin needs only a bit of that
1616 if test "$PORTNAME" = "cygwin"; then
1617   AC_LIBOBJ(dirmod)
1618 fi
1619
1620 AC_CHECK_DECLS([sys_siglist], [], [],
1621 [#include <signal.h>
1622 /* NetBSD declares sys_siglist in unistd.h.  */
1623 #ifdef HAVE_UNISTD_H
1624 # include <unistd.h>
1625 #endif
1626 ])
1627
1628 AC_CHECK_FUNC(syslog,
1629               [AC_CHECK_HEADER(syslog.h,
1630                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1631
1632 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1633 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1634   [extern int opterr; opterr = 1;])],
1635   [pgac_cv_var_int_opterr=yes],
1636   [pgac_cv_var_int_opterr=no])])
1637 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1638   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1639 fi
1640
1641 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1642 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1643   [extern int optreset; optreset = 1;])],
1644   [pgac_cv_var_int_optreset=yes],
1645   [pgac_cv_var_int_optreset=no])])
1646 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1647   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1648 fi
1649
1650 AC_CHECK_FUNCS([strtoll strtoq], [break])
1651 AC_CHECK_FUNCS([strtoull strtouq], [break])
1652
1653 if test "$with_icu" = yes; then
1654   ac_save_CPPFLAGS=$CPPFLAGS
1655   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1656
1657   # Verify we have ICU's header files
1658   AC_CHECK_HEADER(unicode/ucol.h, [],
1659         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1660
1661   CPPFLAGS=$ac_save_CPPFLAGS
1662 fi
1663
1664 # Lastly, restore full LIBS list and check for readline/libedit symbols
1665 LIBS="$LIBS_including_readline"
1666
1667 if test "$with_readline" = yes; then
1668   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1669   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1670   AC_CHECK_FUNCS([append_history history_truncate_file])
1671 fi
1672
1673
1674 # This test makes sure that run tests work at all.  Sometimes a shared
1675 # library is found by the linker, but the runtime linker can't find it.
1676 # This check should come after all modifications of compiler or linker
1677 # variables, and before any other run tests.
1678 AC_MSG_CHECKING([test program])
1679 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1680 [AC_MSG_RESULT(ok)],
1681 [AC_MSG_RESULT(failed)
1682 AC_MSG_ERROR([[
1683 Could not execute a simple test program.  This may be a problem
1684 related to locating shared libraries.  Check the file 'config.log'
1685 for the exact reason.]])],
1686 [AC_MSG_RESULT([cross-compiling])])
1687
1688 # --------------------
1689 # Run tests below here
1690 # --------------------
1691
1692 # Force use of our snprintf if system's doesn't do arg control
1693 # See comment above at snprintf test for details.
1694 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1695   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1696   if test $pgac_cv_snprintf_arg_control != yes ; then
1697     pgac_need_repl_snprintf=yes
1698   fi
1699 fi
1700
1701
1702 dnl Check to see if we have a working 64-bit integer type.
1703 dnl This breaks down into two steps:
1704 dnl (1) figure out if the compiler has a 64-bit int type with working
1705 dnl arithmetic, and if so
1706 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1707 dnl snprintf is the only library routine we really need for int8 support.)
1708 dnl It's entirely possible to have a compiler that handles a 64-bit type
1709 dnl when the C library doesn't; this is fairly likely when using gcc on
1710 dnl an older platform, for example.
1711 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1712 dnl we force our own version of snprintf() to be used instead.
1713 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1714
1715 dnl As of Postgres 8.4, we no longer support compilers without a working
1716 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1717
1718 PGAC_TYPE_64BIT_INT([long int])
1719
1720 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1721   pg_int64_type="long int"
1722 else
1723   PGAC_TYPE_64BIT_INT([long long int])
1724   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1725     pg_int64_type="long long int"
1726   else
1727     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1728   fi
1729 fi
1730
1731 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1732   [Define to the name of a signed 64-bit integer type.])
1733
1734 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1735 # we found we need to use "long long int", better check.  We cope with
1736 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1737 # work, fall back to our own snprintf emulation (which we know uses %lld).
1738
1739 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1740   if test $pgac_need_repl_snprintf = no; then
1741     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1742     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1743       # Force usage of our own snprintf, since system snprintf is broken
1744       pgac_need_repl_snprintf=yes
1745       LONG_LONG_INT_MODIFIER='ll'
1746     fi
1747   else
1748     # Here if we previously decided we needed to use our own snprintf
1749     LONG_LONG_INT_MODIFIER='ll'
1750   fi
1751 else
1752   # Here if we are not using 'long long int' at all
1753   LONG_LONG_INT_MODIFIER='l'
1754 fi
1755
1756 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1757
1758 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1759                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1760
1761 # Also force use of our snprintf if the system's doesn't support the %z flag.
1762 if test "$pgac_need_repl_snprintf" = no; then
1763   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1764   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1765     pgac_need_repl_snprintf=yes
1766   fi
1767 fi
1768
1769 # Now we have checked all the reasons to replace snprintf
1770 if test $pgac_need_repl_snprintf = yes; then
1771   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1772   AC_LIBOBJ(snprintf)
1773 fi
1774
1775 # has to be down here, rather than with the other builtins, because
1776 # the test uses PG_INT64_TYPE.
1777 PGAC_C_BUILTIN_OP_OVERFLOW
1778
1779 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1780 AC_CHECK_SIZEOF([void *])
1781 AC_CHECK_SIZEOF([size_t])
1782 AC_CHECK_SIZEOF([long])
1783
1784 # Decide whether float4 is passed by value: user-selectable, enabled by default
1785 AC_MSG_CHECKING([whether to build with float4 passed by value])
1786 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1787               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1788                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1789                float4passbyval=true],
1790               [float4passbyval=false])
1791 AC_MSG_RESULT([$enable_float4_byval])
1792 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1793
1794 # Decide whether float8 is passed by value.
1795 # Note: this setting also controls int8 and related types such as timestamp.
1796 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1797 # If not, trying to select it is an error.
1798 AC_MSG_CHECKING([whether to build with float8 passed by value])
1799 if test $ac_cv_sizeof_void_p -ge 8 ; then
1800   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1801 else
1802   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1803   if test "$enable_float8_byval" = yes ; then
1804     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1805   fi
1806 fi
1807 if test "$enable_float8_byval" = yes ; then
1808   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1809             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1810   float8passbyval=true
1811 else
1812   float8passbyval=false
1813 fi
1814 AC_MSG_RESULT([$enable_float8_byval])
1815 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1816
1817 # Determine memory alignment requirements for the basic C data types.
1818
1819 AC_CHECK_ALIGNOF(short)
1820 AC_CHECK_ALIGNOF(int)
1821 AC_CHECK_ALIGNOF(long)
1822 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1823   AC_CHECK_ALIGNOF(long long int)
1824 fi
1825 AC_CHECK_ALIGNOF(double)
1826
1827 # Compute maximum alignment of any basic type.
1828 # We assume long's alignment is at least as strong as char, short, or int;
1829 # but we must check long long (if it is being used for int64) and double.
1830 # Note that we intentionally do not consider any types wider than 64 bits,
1831 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1832 # for disk and memory space.
1833
1834 MAX_ALIGNOF=$ac_cv_alignof_long
1835 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1836   MAX_ALIGNOF=$ac_cv_alignof_double
1837 fi
1838 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1839   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1840 fi
1841 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1842
1843
1844 # Some platforms predefine the types int8, int16, etc.  Only check
1845 # a (hopefully) representative subset.
1846 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1847 [#include <stdio.h>])
1848
1849 # Some compilers offer a 128-bit integer scalar type.
1850 PGAC_TYPE_128BIT_INT
1851
1852 # Check for various atomic operations now that we have checked how to declare
1853 # 64bit integers.
1854 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1855 PGAC_HAVE_GCC__SYNC_INT32_TAS
1856 PGAC_HAVE_GCC__SYNC_INT32_CAS
1857 PGAC_HAVE_GCC__SYNC_INT64_CAS
1858 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1859 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1860
1861
1862 # Check for x86 cpuid instruction
1863 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1864 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1865   [[unsigned int exx[4] = {0, 0, 0, 0};
1866   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1867   ]])],
1868   [pgac_cv__get_cpuid="yes"],
1869   [pgac_cv__get_cpuid="no"])])
1870 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1871   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1872 fi
1873
1874 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1875 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1876   [[unsigned int exx[4] = {0, 0, 0, 0};
1877   __get_cpuid(exx[0], 1);
1878   ]])],
1879   [pgac_cv__cpuid="yes"],
1880   [pgac_cv__cpuid="no"])])
1881 if test x"$pgac_cv__cpuid" = x"yes"; then
1882   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1883 fi
1884
1885 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1886 #
1887 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1888 # with the default compiler flags. If not, check if adding the -msse4.2
1889 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1890 PGAC_SSE42_CRC32_INTRINSICS([])
1891 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1892   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1893 fi
1894 AC_SUBST(CFLAGS_SSE42)
1895
1896 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1897 # define __SSE4_2__ in that case.
1898 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
1899 #ifndef __SSE4_2__
1900 #error __SSE4_2__ not defined
1901 #endif
1902 ])], [SSE4_2_TARGETED=1])
1903
1904 # Select CRC-32C implementation.
1905 #
1906 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
1907 # special CRC instructions for calculating CRC-32C. If we're not targeting such
1908 # a processor, but we can nevertheless produce code that uses the SSE
1909 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
1910 # select which one to use at runtime, depending on whether SSE 4.2 is supported
1911 # by the processor we're running on.
1912 #
1913 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
1914 # in the template or configure command line.
1915 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
1916   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
1917     USE_SSE42_CRC32C=1
1918   else
1919     # the CPUID instruction is needed for the runtime check.
1920     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
1921       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
1922     else
1923       # fall back to slicing-by-8 algorithm which doesn't require any special
1924       # CPU support.
1925       USE_SLICING_BY_8_CRC32C=1
1926     fi
1927   fi
1928 fi
1929
1930 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
1931 AC_MSG_CHECKING([which CRC-32C implementation to use])
1932 if test x"$USE_SSE42_CRC32C" = x"1"; then
1933   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
1934   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
1935   AC_MSG_RESULT(SSE 4.2)
1936 else
1937   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
1938     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
1939     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
1940     AC_MSG_RESULT(SSE 4.2 with runtime check)
1941   else
1942     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
1943     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
1944     AC_MSG_RESULT(slicing-by-8)
1945   fi
1946 fi
1947 AC_SUBST(PG_CRC32C_OBJS)
1948
1949
1950 # Select semaphore implementation type.
1951 if test "$PORTNAME" != "win32"; then
1952   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
1953     # Need sem_open for this
1954     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
1955   fi
1956   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
1957     # Need sem_init for this
1958     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
1959   fi
1960   AC_MSG_CHECKING([which semaphore API to use])
1961   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1962     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1963     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1964     sematype="named POSIX"
1965   else
1966     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1967       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1968       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1969       sematype="unnamed POSIX"
1970     else
1971       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1972       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1973       sematype="System V"
1974     fi
1975   fi
1976   AC_MSG_RESULT([$sematype])
1977 else
1978   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1979   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1980 fi
1981
1982
1983 # Select shared-memory implementation type.
1984 if test "$PORTNAME" != "win32"; then
1985   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1986   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1987 else
1988   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1989   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1990 fi
1991
1992 # Select random number source
1993 #
1994 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
1995 # in the template or configure command line.
1996
1997 # If not selected manually, try to select a source automatically.
1998 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
1999   if test x"$with_openssl" = x"yes" ; then
2000     USE_OPENSSL_RANDOM=1
2001   elif test "$PORTNAME" = "win32" ; then
2002     USE_WIN32_RANDOM=1
2003   else
2004     AC_CHECK_FILE([/dev/urandom], [], [])
2005
2006     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2007       USE_DEV_URANDOM=1
2008     fi
2009   fi
2010 fi
2011
2012 AC_MSG_CHECKING([which random number source to use])
2013 if test "$enable_strong_random" = yes ; then
2014   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2015     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2016     AC_MSG_RESULT([OpenSSL])
2017   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2018     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2019     AC_MSG_RESULT([Windows native])
2020   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2021     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2022     AC_MSG_RESULT([/dev/urandom])
2023   else
2024     AC_MSG_ERROR([
2025 no source of strong random numbers was found
2026 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2027 for authentication protocols. You can use --disable-strong-random to use a
2028 built-in pseudo random number generator, but that may be insecure.])
2029   fi
2030   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2031 else
2032     AC_MSG_RESULT([weak builtin PRNG])
2033     AC_MSG_WARN([
2034 *** Not using a strong random number source may be insecure.])
2035 fi
2036
2037 # If not set in template file, set bytes to use libc memset()
2038 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2039   MEMSET_LOOP_LIMIT=1024
2040 fi
2041 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2042
2043
2044 if test "$enable_nls" = yes ; then
2045   PGAC_CHECK_GETTEXT
2046 fi
2047
2048 # Check for Tcl configuration script tclConfig.sh
2049 if test "$with_tcl" = yes; then
2050     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2051     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2052                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2053     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2054     if test "$TCL_SHARED_BUILD" != 1; then
2055       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2056 Use --without-tcl to disable building PL/Tcl.])
2057     fi
2058     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2059     ac_save_CPPFLAGS=$CPPFLAGS
2060     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2061     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2062     CPPFLAGS=$ac_save_CPPFLAGS
2063 fi
2064
2065 # check for <perl.h>
2066 if test "$with_perl" = yes; then
2067   ac_save_CPPFLAGS=$CPPFLAGS
2068   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2069   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2070                   [#include <EXTERN.h>])
2071   # While we're at it, check that we can link to libperl.
2072   # On most platforms, if perl.h is there then libperl.so will be too, but at
2073   # this writing Debian packages them separately.  There is no known reason to
2074   # waste cycles on separate probes for the Tcl or Python libraries, though.
2075   pgac_save_LIBS=$LIBS
2076   LIBS="$perl_embed_ldflags"
2077   AC_MSG_CHECKING([for libperl])
2078   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2079 #include <EXTERN.h>
2080 #include <perl.h>
2081 ],  [perl_alloc();])],
2082     [AC_MSG_RESULT(yes)],
2083     [AC_MSG_RESULT(no)
2084      AC_MSG_ERROR([libperl library is required for Perl])])
2085   LIBS=$pgac_save_LIBS
2086   CPPFLAGS=$ac_save_CPPFLAGS
2087 fi
2088
2089 # check for <Python.h>
2090 if test "$with_python" = yes; then
2091   ac_save_CPPFLAGS=$CPPFLAGS
2092   CPPFLAGS="$python_includespec $CPPFLAGS"
2093   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2094   CPPFLAGS=$ac_save_CPPFLAGS
2095 fi
2096
2097 #
2098 # Check for DocBook and tools
2099 #
2100 PGAC_PATH_XMLLINT
2101 PGAC_CHECK_DOCBOOK(4.2)
2102 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2103 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2104 PGAC_PATH_PROGS(FOP, fop)
2105
2106 #
2107 # Check for test tools
2108 #
2109 if test "$enable_tap_tests" = yes; then
2110   # Check for necessary modules, unless user has specified the "prove" to use;
2111   # in that case it's her responsibility to have a working configuration.
2112   # (prove might be part of a different Perl installation than perl, eg on
2113   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2114   if test -z "$PROVE"; then
2115     AX_PROG_PERL_MODULES(IPC::Run, ,
2116       AC_MSG_ERROR([Perl module IPC::Run is required to run TAP tests]))
2117   fi
2118   # Now make sure we know where prove is
2119   PGAC_PATH_PROGS(PROVE, prove)
2120   if test -z "$PROVE"; then
2121     AC_MSG_ERROR([prove not found])
2122   fi
2123 fi
2124
2125 # Thread testing
2126
2127 # We have to run the thread test near the end so we have all our symbols
2128 # defined.  Cross compiling throws a warning.
2129 #
2130 if test "$enable_thread_safety" = yes; then
2131 if test "$PORTNAME" != "win32"
2132 then
2133 AC_MSG_CHECKING([thread safety of required library functions])
2134
2135 _CFLAGS="$CFLAGS"
2136 _LIBS="$LIBS"
2137 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2138 LIBS="$LIBS $PTHREAD_LIBS"
2139 AC_RUN_IFELSE(
2140   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2141   [AC_MSG_RESULT(yes)],
2142   [AC_MSG_RESULT(no)
2143   AC_MSG_ERROR([thread test program failed
2144 This platform is not thread-safe.  Check the file 'config.log' or compile
2145 and run src/test/thread/thread_test for the exact reason.
2146 Use --disable-thread-safety to disable thread safety.])],
2147   [AC_MSG_RESULT(maybe)
2148   AC_MSG_WARN([
2149 *** Skipping thread test program because of cross-compile build.
2150 *** Run the program in src/test/thread on the target machine.
2151 ])])
2152 CFLAGS="$_CFLAGS"
2153 LIBS="$_LIBS"
2154 else
2155 AC_MSG_WARN([*** skipping thread test on Win32])
2156 fi
2157 fi
2158
2159 # If compiler will take -Wl,--as-needed (or various platform-specific
2160 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2161 # trying to filter LIBS to the minimum for each executable.
2162 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2163 # libreadline; therefore we postpone testing it until we know what library
2164 # dependencies readline has.  The test code will try to link with $LIBS.
2165 if test "$with_readline" = yes; then
2166   link_test_func=readline
2167 else
2168   link_test_func=exit
2169 fi
2170
2171 if test "$PORTNAME" = "darwin"; then
2172   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2173 elif test "$PORTNAME" = "openbsd"; then
2174   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2175 else
2176   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2177 fi
2178
2179 # Create compiler version string
2180 if test x"$GCC" = x"yes" ; then
2181   cc_string=`${CC} --version | sed q`
2182   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2183 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2184   cc_string=`${CC} -V 2>&1 | sed q`
2185 else
2186   cc_string=$CC
2187 fi
2188
2189 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2190                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2191                    [A string containing the version number, platform, and C compiler])
2192
2193 # Supply a numeric version string for use by 3rd party add-ons
2194 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2195 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2196 tr '.' '        ' |
2197 $AWK '{printf "%d%04d", $1, $2}'`"]
2198 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2199 AC_SUBST(PG_VERSION_NUM)
2200
2201
2202 # Begin output steps
2203
2204 AC_MSG_NOTICE([using compiler=$cc_string])
2205 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2206 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2207 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2208
2209 # prepare build tree if outside source tree
2210 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2211 # Note 2: /bin/pwd might be better than shell's built-in at getting
2212 #         a symlink-free name.
2213 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2214   vpath_build=no
2215 else
2216   vpath_build=yes
2217   if test "$no_create" != yes; then
2218     _AS_ECHO_N([preparing build tree... ])
2219     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2220     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2221       || AC_MSG_ERROR(failed)
2222     AC_MSG_RESULT(done)
2223   fi
2224 fi
2225 AC_SUBST(vpath_build)
2226
2227
2228 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2229
2230 AC_CONFIG_LINKS([
2231   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2232   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2233   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2234   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2235   src/include/pg_config_os.h:src/include/port/${template}.h
2236   src/Makefile.port:src/makefiles/Makefile.${template}
2237 ])
2238
2239 if test "$PORTNAME" = "win32"; then
2240 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2241 # Links sometimes fail undetected on Mingw -
2242 # so here we detect it and warn the user
2243 for FILE in $CONFIG_LINKS
2244  do
2245         # test -e works for symlinks in the MinGW console
2246         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2247  done
2248 ])
2249 fi
2250
2251 AC_CONFIG_HEADERS([src/include/pg_config.h],
2252 [
2253 # Update timestamp for pg_config.h (see Makefile.global)
2254 echo >src/include/stamp-h
2255 ])
2256
2257 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2258 [
2259 # Update timestamp for pg_config_ext.h (see Makefile.global)
2260 echo >src/include/stamp-ext-h
2261 ])
2262
2263 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2264                   [echo >src/interfaces/ecpg/include/stamp-h])
2265
2266 AC_OUTPUT