granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.295 2003/10/14 00:48:09 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4beta4], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55 # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   hppa*-*-hpux*)        need_tas=yes; tas_file=hpux_hppa.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 #
 157 # NLS
 158 #
 159 AC_MSG_CHECKING([whether NLS is wanted])
 160 PGAC_ARG_OPTARG(enable, nls,
 161                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 162                 [],
 163                 [WANTED_LANGUAGES=$enableval],
 164                 [AC_DEFINE(ENABLE_NLS, 1,
 165                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 166 AC_MSG_RESULT([$enable_nls])
 167 AC_SUBST(enable_nls)
 168 AC_SUBST(WANTED_LANGUAGES)
 169
 170 #
 171 # Default port number (--with-pgport), default 5432
 172 #
 173 AC_MSG_CHECKING([for default port number])
 174 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 175              [default_port=$withval],
 176              [default_port=5432])
 177 AC_MSG_RESULT([$default_port])
 178 # Need both of these because some places want an integer and some a string
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 180 [Define to the default TCP port number on which the server listens and
 181 to which clients will try to connect.  This can be overridden at run-time,
 182 but it's convenient if your clients have the right default compiled in.
 183 (--with-pgport=PORTNUM)])
 184 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 185                    [Define to the default TCP port number as a string constant.])
 186 AC_SUBST(default_port)
 187
 188 #
 189 # Option to disable shared libraries
 190 #
 191 PGAC_ARG_BOOL(enable, shared, yes,
 192               [  --disable-shared        do not build shared libraries])
 193 AC_SUBST(enable_shared)
 194
 195 #
 196 # '-rpath'-like feature can be disabled
 197 #
 198 PGAC_ARG_BOOL(enable, rpath, yes,
 199               [  --disable-rpath         do not embed shared library search path in executables])
 200 AC_SUBST(enable_rpath)
 201
 202 #
 203 # Spinlocks
 204 #
 205 PGAC_ARG_BOOL(enable, spinlocks, yes,
 206               [  --disable-spinlocks     do not use Spinlocks])
 207
 208 #
 209 # --enable-debug adds -g to compiler flags
 210 #
 211 PGAC_ARG_BOOL(enable, debug, no,
 212               [  --enable-debug          build with debugging symbols (-g)])
 213 AC_SUBST(enable_debug)
 214
 215 #
 216 # C compiler
 217 #
 218
 219 # For historical reasons you can also use --with-CC to specify the C compiler
 220 # to use, although the standard way to do this is to set the CC environment
 221 # variable.
 222 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 223
 224 case $template in
 225   aix) pgac_cc_list="gcc xlc";;
 226  irix) pgac_cc_list="cc";; # no gcc
 227     *) pgac_cc_list="gcc cc";;
 228 esac
 229
 230 AC_PROG_CC([$pgac_cc_list])
 231
 232 #
 233 # Read the template
 234 #
 235 . "$srcdir/src/template/$template" || exit
 236
 237 # adjust CFLAGS per template
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 fi
 241 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 242   CFLAGS="$CFLAGS -g"
 243 else
 244   # configure sets CFLAGS to -O2 for gcc, so this is only for non-gcc
 245   if test x"$CFLAGS" = x""; then
 246     CFLAGS="-O"
 247   fi
 248 fi
 249 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 250
 251 # We already have this in Makefile.win32, but configure needs it too
 252 if test "$PORTNAME" = "win32"
 253 then
 254         CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32"
 255 fi
 256
 257 # Check if the compiler still works with the template settings
 258 AC_MSG_CHECKING([whether the C compiler still works])
 259 AC_TRY_LINK([], [return 0;],
 260   [AC_MSG_RESULT(yes)],
 261   [AC_MSG_RESULT(no)
 262    AC_MSG_ERROR([cannot proceed])])
 263
 264 # Defend against gcc -ffastmath
 265 if test "$GCC" = yes; then
 266 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 267 choke me
 268 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 269 fi
 270
 271 AC_PROG_CPP
 272 AC_SUBST(GCC)
 273
 274 # Create compiler version string
 275 if test x"$GCC" = x"yes" ; then
 276   cc_string="GCC `${CC} --version | sed q`"
 277 else
 278   cc_string=$CC
 279 fi
 280 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 281                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 282                    [A string containing the version number, platform, and C compiler])
 283
 284
 285 #
 286 # Automatic dependency tracking
 287 #
 288 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 289               [autodepend=yes])
 290 AC_SUBST(autodepend)
 291
 292
 293 #
 294 # Enable assert checks
 295 #
 296 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 297               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 298                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 299
 300
 301 #
 302 # Include directories
 303 #
 304 ac_save_IFS=$IFS
 305 IFS="${IFS}:"
 306 # SRCH_INC comes from the template file
 307 for dir in $with_includes $SRCH_INC; do
 308   if test -d "$dir"; then
 309     INCLUDES="$INCLUDES -I$dir"
 310   else
 311     AC_MSG_WARN([*** Include directory $dir does not exist.])
 312   fi
 313 done
 314 IFS=$ac_save_IFS
 315 AC_SUBST(INCLUDES)
 316
 317
 318 #
 319 # Library directories
 320 #
 321 ac_save_IFS=$IFS
 322 IFS="${IFS}:"
 323 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 324 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 325   if test -d "$dir"; then
 326     LIBDIRS="$LIBDIRS -L$dir"
 327   else
 328     AC_MSG_WARN([*** Library directory $dir does not exist.])
 329   fi
 330 done
 331 IFS=$ac_save_IFS
 332
 333 #
 334 # Enable thread-safe client libraries
 335 #
 336 AC_MSG_CHECKING([allow thread-safe client libraries])
 337 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 338               [AC_DEFINE([USE_THREADS], 1,
 339                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 340 AC_MSG_RESULT([$enable_thread_safety])
 341 AC_SUBST(enable_thread_safety)
 342
 343 #
 344 # Tcl/Tk
 345 #
 346 AC_MSG_CHECKING([whether to build with Tcl])
 347 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 348 AC_MSG_RESULT([$with_tcl])
 349 AC_SUBST([with_tcl])
 350
 351 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 352 AC_MSG_CHECKING([whether to build with Tk])
 353 if test "$with_tcl" = yes; then
 354   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 355 else
 356   with_tk=no
 357 fi
 358 AC_MSG_RESULT([$with_tk])
 359 AC_SUBST([with_tk])
 360
 361
 362 # We see if the path to the Tcl/Tk configuration scripts is specified.
 363 # This will override the use of tclsh to find the paths to search.
 364
 365 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 366
 367 # We see if the path to the Tk configuration scripts is specified.
 368 # This will override the use of tclsh to find the paths to search.
 369
 370 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 371
 372 #
 373 # Optionally build Perl modules (PL/Perl)
 374 #
 375 AC_MSG_CHECKING([whether to build Perl modules])
 376 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 377 AC_MSG_RESULT([$with_perl])
 378 AC_SUBST(with_perl)
 379
 380 #
 381 # Optionally build Python modules (PL/Python)
 382 #
 383 AC_MSG_CHECKING([whether to build Python modules])
 384 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 385 AC_MSG_RESULT([$with_python])
 386 AC_SUBST(with_python)
 387
 388 #
 389 # Optionally build the Java/JDBC tools
 390 #
 391 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 392 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 393 [AC_MSG_RESULT(yes)
 394 PGAC_PATH_ANT
 395 if test -z "$ANT"; then
 396   AC_MSG_ERROR([Ant is required to build Java components
 397 If you have Ant already installed, see config.log for details on the failure.])
 398 fi
 399 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 400   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 401 fi],
 402 [AC_MSG_RESULT(no)])
 403 AC_SUBST(with_java)
 404
 405 dnl A note on the Kerberos and OpenSSL options:
 406 dnl
 407 dnl The user can give an argument to the option in order the specify
 408 dnl the base path of the respective installation (what he specified
 409 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 410 dnl then we take the path where the package installs by default. This
 411 dnl way the user doesn't have to use redundant --with-includes and
 412 dnl --with-libraries options, but he can still use them if the layout
 413 dnl is non-standard.
 414
 415 #
 416 # Kerberos 4
 417 #
 418 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 419 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 420                 [krb4_prefix=/usr/athena],
 421                 [krb4_prefix=$withval],
 422 [
 423   AC_MSG_RESULT(yes)
 424   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 425
 426   if test -d "$krb4_prefix/include"; then
 427     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 428   fi
 429   if test -d "$krb4_prefix/lib"; then
 430     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 431   fi
 432
 433   krb_srvtab="/etc/srvtab"
 434 ],
 435 [AC_MSG_RESULT(no)])
 436
 437 AC_SUBST(with_krb4)
 438
 439
 440 #
 441 # Kerberos 5
 442 #
 443 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 444 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 445               [krb5_prefix=/usr/athena],
 446               [krb5_prefix=$withval],
 447 [
 448   AC_MSG_RESULT([yes])
 449   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 450
 451   if test -d "$krb5_prefix/include"; then
 452     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 453   fi
 454   if test -d "$krb5_prefix/lib"; then
 455     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 456   fi
 457
 458   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 459 ],
 460 [AC_MSG_RESULT(no)])
 461
 462 AC_SUBST(with_krb5)
 463
 464
 465 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 466 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 467   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 468 fi
 469
 470 AC_SUBST(krb_srvtab)
 471
 472
 473 #
 474 # Kerberos configuration parameters
 475 #
 476 PGAC_ARG_REQ(with, krb-srvnam,
 477              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 478              [],
 479              [with_krb_srvnam="postgres"])
 480 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 481                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 482
 483
 484 #
 485 # PAM
 486 #
 487 AC_MSG_CHECKING([whether to build with PAM support])
 488 PGAC_ARG_BOOL(with, pam, no,
 489               [  --with-pam              build with PAM support],
 490               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 491 AC_MSG_RESULT([$with_pam])
 492 AC_SUBST(with_pam)
 493
 494
 495 #
 496 # Rendezvous
 497 #
 498 AC_MSG_CHECKING([whether to build with Rendezvous support])
 499 PGAC_ARG_BOOL(with, rendezvous, no,
 500               [  --with-rendezvous       build with Rendezvous support],
 501               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 502 AC_MSG_RESULT([$with_rendezvous])
 503 AC_SUBST(with_rendezvous)
 504
 505
 506 #
 507 # OpenSSL
 508 #
 509 PGAC_ARG_OPTARG(with, openssl,
 510                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 511                 [openssl_prefix=/usr/local/ssl],
 512                 [openssl_prefix=$withval],
 513 [
 514   AC_MSG_RESULT([building with OpenSSL support])
 515   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 516
 517   if test -d "${openssl_prefix}/include" ; then
 518     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 519   fi
 520   if test -d "${openssl_prefix}/lib" ; then
 521     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 522   fi
 523 ])
 524
 525 AC_SUBST(with_openssl)
 526
 527
 528 #
 529 # Readline
 530 #
 531 PGAC_ARG_BOOL(with, readline, yes,
 532               [  --without-readline      do not use Readline])
 533
 534 #
 535 # Zlib
 536 #
 537 PGAC_ARG_BOOL(with, zlib, yes,
 538               [  --without-zlib          do not use Zlib])
 539
 540 #
 541 # Elf
 542 #
 543
 544 # Assume system is ELF if it predefines __ELF__ as 1,
 545 # otherwise believe host_os based default.
 546 case $host_os in
 547     freebsd1*|freebsd2*) elf=no;;
 548     freebsd3*|freebsd4*) elf=yes;;
 549 esac
 550
 551 AC_EGREP_CPP(yes,
 552 [#if __ELF__
 553   yes
 554 #endif
 555 ],
 556 [ELF_SYS=true],
 557 [if test "X$elf" = "Xyes" ; then
 558   ELF_SYS=true
 559 else
 560   ELF_SYS=
 561 fi])
 562 AC_SUBST(ELF_SYS)
 563
 564 #
 565 # Assignments
 566 #
 567
 568 CPPFLAGS="$CPPFLAGS $INCLUDES"
 569 LDFLAGS="$LDFLAGS $LIBDIRS"
 570
 571 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 572 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 573
 574
 575 AC_PROG_AWK
 576 PGAC_PATH_FLEX
 577 AC_PROG_LN_S
 578 AC_PROG_LD
 579 AC_SUBST(LD)
 580 AC_SUBST(with_gnu_ld)
 581 case $host_os in sysv5*)
 582   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 583   [
 584     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 585     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 586     LDFLAGS=$pgac_save_LDFLAGS
 587   ])
 588   ld_R_works=$pgac_cv_prog_ld_R
 589   AC_SUBST(ld_R_works)
 590 esac
 591 AC_PROG_RANLIB
 592 AC_CHECK_PROGS(LORDER, lorder)
 593 AC_PATH_PROG(TAR, tar)
 594 PGAC_CHECK_STRIP
 595
 596 AC_CHECK_PROGS(YACC, ['bison -y'])
 597
 598 if test "$YACC"; then
 599   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 600     AC_MSG_WARN([
 601 *** The installed version of Bison is too old.  PostgreSQL needs
 602 *** Bison version 1.875 or later.])
 603   fi
 604 fi
 605
 606 if test -z "$YACC"; then
 607   AC_MSG_WARN([
 608 *** Without Bison you will not be able to build PostgreSQL from CVS or
 609 *** change any of the parser definition files.  You can obtain Bison from
 610 *** a GNU mirror site.  (If you are using the official distribution of
 611 *** PostgreSQL then you do not need to worry about this because the Bison
 612 *** output is pre-generated.)  To use a different yacc program (possible,
 613 *** but not recommended), set the environment variable YACC before running
 614 *** 'configure'.])
 615 fi
 616 AC_SUBST(YFLAGS)
 617
 618 PGAC_PATH_PERL
 619 if test "$with_perl" = yes; then
 620   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 621   PGAC_CHECK_PERL_EMBED_LDFLAGS
 622 fi
 623
 624 if test "$with_python" = yes; then
 625   PGAC_PATH_PYTHON
 626   PGAC_CHECK_PYTHON_EMBED_SETUP
 627 fi
 628
 629
 630 ##
 631 ## Libraries
 632 ##
 633
 634 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 635 then
 636         AC_CHECK_LIB(bsd,      main)
 637 fi
 638 AC_CHECK_LIB(util,     setproctitle)
 639 AC_CHECK_LIB(m,        main)
 640 AC_CHECK_LIB(dl,       main)
 641 AC_CHECK_LIB(nsl,      main)
 642 AC_CHECK_LIB(socket,   main)
 643 AC_CHECK_LIB(ipc,      main)
 644 AC_CHECK_LIB(IPC,      main)
 645 AC_CHECK_LIB(lc,       main)
 646 AC_CHECK_LIB(dld,      main)
 647 AC_CHECK_LIB(ld,       main)
 648 AC_CHECK_LIB(compat,   main)
 649 AC_CHECK_LIB(BSD,      main)
 650 AC_CHECK_LIB(gen,      main)
 651 AC_CHECK_LIB(PW,       main)
 652 AC_CHECK_LIB(resolv,   main)
 653 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 654 # QNX:
 655 AC_CHECK_LIB(unix, main)
 656 AC_SEARCH_LIBS(crypt,  crypt)
 657 # BeOS:
 658 if test "$PORTNAME" = "beos"
 659 then
 660         AC_CHECK_LIB(bind, __inet_ntoa)
 661 fi
 662 # Solaris:
 663 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 664 # Cygwin:
 665 AC_CHECK_LIB(cygipc, shmget)
 666 # WIN32:
 667 if test "$PORTNAME" = "win32"
 668 then
 669         AC_CHECK_LIB(wsock32, main)
 670 fi
 671
 672 if test "$with_readline" = yes; then
 673   PGAC_CHECK_READLINE
 674   if test x"$pgac_cv_check_readline" = x"no"; then
 675     AC_MSG_ERROR([readline library not found
 676 If you have readline already installed, see config.log for details on the
 677 failure.  It is possible the compiler isn't looking in the proper directory.
 678 Use --without-readline to disable readline support.])
 679   fi
 680 fi
 681
 682 if test "$with_zlib" = yes; then
 683   AC_CHECK_LIB(z, inflate, [],
 684                [AC_MSG_ERROR([zlib library not found
 685 If you have zlib already installed, see config.log for details on the
 686 failure.  It is possible the compiler isn't looking in the proper directory.
 687 Use --without-zlib to disable zlib support.])])
 688 fi
 689
 690 if test "$enable_spinlocks" = yes; then
 691   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 692 else
 693   AC_MSG_WARN([
 694 *** Not using spinlocks will cause poor performance.])
 695 fi
 696
 697 if test "$with_krb4" = yes ; then
 698   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 699   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 700   AC_REPLACE_FUNCS([gethostname])
 701 fi
 702
 703 if test "$with_krb5" = yes ; then
 704   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 705                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 706   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 707                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 708   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 709                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 710 fi
 711
 712 if test "$with_openssl" = yes ; then
 713   dnl Order matters!
 714   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 715   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 716 fi
 717
 718 if test "$with_pam" = yes ; then
 719   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 720 fi
 721
 722
 723 ##
 724 ## Header files
 725 ##
 726
 727 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 728 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 729
 730 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 731 # netinet/in.h is included first.
 732 AC_CHECK_HEADERS(netinet/in.h)
 733 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 734 [AC_INCLUDES_DEFAULT
 735 #ifdef HAVE_NETINET_IN_H
 736 #include <netinet/in.h>
 737 #endif
 738 ])
 739
 740 if test "$with_readline" = yes; then
 741   AC_CHECK_HEADERS(readline/readline.h, [],
 742                    [AC_CHECK_HEADERS(editline/readline.h, [],
 743                          [AC_CHECK_HEADERS(readline.h, [],
 744                                      [AC_MSG_ERROR([readline header not found
 745 If you have readline already installed, see config.log for details on the
 746 failure.  It is possible the compiler isn't looking in the proper directory.
 747 Use --without-readline to disable readline support.])])])])
 748   AC_CHECK_HEADERS(readline/history.h, [],
 749                    [AC_CHECK_HEADERS(editline/history.h, [],
 750                          [AC_CHECK_HEADERS(history.h, [],
 751                                      [AC_MSG_ERROR([history header not found
 752 If you have readline already installed, see config.log for details on the
 753 failure.  It is possible the compiler isn't looking in the proper directory.
 754 Use --without-readline to disable readline support.])])])])
 755 fi
 756
 757 if test "$with_zlib" = yes; then
 758   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 759 If you have zlib already installed, see config.log for details on the
 760 failure.  It is possible the compiler isn't looking in the proper directory.
 761 Use --without-zlib to disable zlib support.])])
 762 fi
 763
 764 if test "$with_krb4" = yes ; then
 765   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 766 fi
 767
 768 if test "$with_krb5" = yes ; then
 769   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 770   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 771 fi
 772
 773 if test "$with_openssl" = yes ; then
 774   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 775   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 776 fi
 777
 778 if test "$with_pam" = yes ; then
 779   AC_CHECK_HEADERS(security/pam_appl.h, [],
 780                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 781                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 782 fi
 783
 784 if test "$with_rendezvous" = yes ; then
 785   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 786 fi
 787
 788
 789 ##
 790 ## Types, structures, compiler characteristics
 791 ##
 792
 793 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 794 AC_C_CONST
 795 AC_C_INLINE
 796 AC_C_STRINGIZE
 797 PGAC_C_SIGNED
 798 AC_C_VOLATILE
 799 PGAC_C_FUNCNAME_SUPPORT
 800 PGAC_STRUCT_TIMEZONE
 801 PGAC_UNION_SEMUN
 802 PGAC_STRUCT_SOCKADDR_UN
 803 PGAC_STRUCT_SOCKADDR_STORAGE
 804 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 805 PGAC_STRUCT_ADDRINFO
 806
 807 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 808 [#include <sys/param.h>
 809 #include <sys/types.h>
 810 #include <sys/socket.h>
 811 #include <sys/ucred.h>])
 812
 813 AC_CHECK_TYPES([struct option], [], [],
 814 [#ifdef HAVE_GETOPT_H
 815 #include <getopt.h>
 816 #endif])
 817
 818 if test "$with_zlib" = yes; then
 819   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 820   # did not).  While we could work around the lack of z_streamp, it
 821   # seems unwise to encourage people to use such old zlib versions...
 822   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 823 Use --without-zlib to disable zlib support.])],
 824                 [#include <zlib.h>])
 825 fi
 826
 827 if test "$with_krb5" = yes; then
 828 # Check for differences between MIT and Heimdal (KTH) releases
 829   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 830                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 831                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 832                                      [#include <krb5.h>])],
 833                    [#include <krb5.h>])
 834   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 835                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 836                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 837                                      [#include <krb5.h>])],
 838                    [#include <krb5.h>])
 839 fi
 840
 841
 842 ##
 843 ## Functions, global variables
 844 ##
 845
 846 PGAC_VAR_INT_TIMEZONE
 847 AC_FUNC_ACCEPT_ARGTYPES
 848 PGAC_FUNC_GETTIMEOFDAY_1ARG
 849
 850 # SunOS doesn't handle negative byte comparisons properly with +/- return
 851 AC_FUNC_MEMCMP
 852
 853 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 854
 855 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 856
 857 HAVE_IPV6=no
 858 AC_CHECK_TYPE([struct sockaddr_in6],
 859               [AC_CHECK_FUNC(inet_ntop,
 860                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 861                                                           HAVE_IPV6=yes])],
 862               [],
 863 [$ac_includes_default
 864 #include <netinet/in.h>])
 865 AC_SUBST(HAVE_IPV6)
 866
 867 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 868 [AC_TRY_LINK(
 869 [#include <machine/vmparam.h>
 870 #include <sys/exec.h>
 871 ],
 872 [PS_STRINGS->ps_nargvstr = 1;
 873 PS_STRINGS->ps_argvstr = "foo";],
 874 [pgac_cv_var_PS_STRINGS=yes],
 875 [pgac_cv_var_PS_STRINGS=no])])
 876 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 877   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 878 fi
 879
 880
 881 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 882 # is missing.  Yes, there are machines that have only one.  We may
 883 # also decide to use snprintf.c if snprintf() is present but does not
 884 # have working "long long int" support -- see below.
 885
 886 pgac_need_repl_snprintf=no
 887 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 888 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 889
 890
 891 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 892 # include/c.h will provide declarations.  Note this is a separate test
 893 # from whether the functions exist in the C library --- there are
 894 # systems that have the functions but don't bother to declare them :-(
 895
 896 AC_CHECK_DECLS([snprintf, vsnprintf])
 897
 898
 899 # do this one the hard way in case isinf() is a macro
 900 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 901 [AC_TRY_LINK(
 902 [#include <math.h>
 903 ],
 904 [double x = 0.0; int res = isinf(x);],
 905 [ac_cv_func_isinf=yes],
 906 [ac_cv_func_isinf=no])])
 907
 908 if test $ac_cv_func_isinf = yes ; then
 909   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 910 else
 911   AC_LIBOBJ(isinf)
 912   # Look for a way to implement a substitute for isinf()
 913   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 914 fi
 915
 916 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 917
 918 # system's version of getaddrinfo(), if any, may be used only if we found
 919 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 920 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 921   AC_REPLACE_FUNCS([getaddrinfo])
 922 else
 923   AC_LIBOBJ(getaddrinfo)
 924 fi
 925
 926 # similarly, use system's getopt_long() only if system provides struct option.
 927 if test x"$ac_cv_type_struct_option" = xyes ; then
 928   AC_REPLACE_FUNCS([getopt_long])
 929 else
 930   AC_LIBOBJ(getopt_long)
 931 fi
 932
 933 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 934 # We override the previous test that said fseeko/ftello didn't exist
 935 # OS tests are also done in include/c.h and port/fseeko.c
 936 case $host_os in bsdi*|netbsd*)
 937 ac_cv_func_fseeko=yes
 938 esac
 939
 940 # Solaris has a very slow qsort in certain cases, so we replace it.
 941 case $host_os in solaris*)
 942 AC_LIBOBJ(qsort) ;;
 943 esac
 944
 945 # Win32 can't to rename or unlink on an open file
 946 case $host_os in mingw*)
 947 AC_LIBOBJ(dirmod)
 948 AC_LIBOBJ(copydir)
 949 AC_LIBOBJ(gettimeofday) ;;
 950 esac
 951
 952 if test "$with_readline" = yes; then
 953   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 954   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 955   AC_CHECK_FUNCS([replace_history_entry])
 956 fi
 957
 958
 959 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 960 AC_MSG_CHECKING(for finite)
 961 AC_TRY_LINK([#include <math.h>],
 962             [int dummy=finite(1.0);],
 963             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 964 AC_MSG_RESULT(yes)],
 965             [AC_MSG_RESULT(no)])
 966
 967 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 968 dnl (especially on GNU libc)
 969 dnl See also comments in c.h.
 970 AC_MSG_CHECKING(for sigsetjmp)
 971 AC_TRY_LINK([#include <setjmp.h>],
 972             [sigjmp_buf x; sigsetjmp(x, 1);],
 973             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 974 AC_MSG_RESULT(yes)],
 975             [AC_MSG_RESULT(no)])
 976
 977 AC_CHECK_FUNC(syslog,
 978               [AC_CHECK_HEADER(syslog.h,
 979                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 980
 981 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 982 [AC_TRY_LINK([#include <unistd.h>],
 983   [extern int optreset; optreset = 1;],
 984   [pgac_cv_var_int_optreset=yes],
 985   [pgac_cv_var_int_optreset=no])])
 986 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 987   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 988 fi
 989
 990 AC_CHECK_FUNCS([strtoll strtoq], [break])
 991 AC_CHECK_FUNCS([strtoull strtouq], [break])
 992
 993 # Check for one of atexit() or on_exit()
 994 AC_CHECK_FUNCS(atexit, [],
 995                [AC_CHECK_FUNCS(on_exit, [],
 996                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 997
 998 AC_FUNC_FSEEKO
 999
1000 #
1001 # Pthreads
1002 #
1003 # For each platform, we need to know about any special compile and link
1004 # libraries, and whether the normal C function names are thread-safe.
1005 # See the comment at the top of src/port/thread.c for more information.
1006 #
1007 if test "$enable_thread_safety" = yes; then
1008 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safetys])])
1009
1010 if test "$THREAD_SUPPORT" != yes; then
1011 AC_MSG_ERROR([
1012 Cannot enable threads on your platform.
1013 Please report your platform threading info to the PostgreSQL mailing lists
1014 so it can be added to the next release.  Report all compile flags, link flags,
1015 functions, or libraries required for threading support.
1016 See the comment at the top of src/port/thread.c for more information.
1017 ])
1018 fi
1019 else
1020 # do not use values from template file
1021 THREAD_CPPFLAGS=
1022 THREAD_LIBS=
1023 fi
1024 AC_SUBST(THREAD_SUPPORT)
1025 AC_SUBST(THREAD_CPPFLAGS)
1026 AC_SUBST(THREAD_LIBS)
1027
1028
1029 #
1030 # Check for re-entrant versions of certain functions
1031 #
1032 # Include special flags if threads are enabled _and_ if required for
1033 # threading on this platform.  Some platforms have *_r functions but
1034 # their natively named funcs are threadsafe, and should be used instead.
1035 #
1036 # One trick here is that if we don't call AC_CHECK_FUNCS, the
1037 # functions are marked "not found", which is perfect.
1038 #
1039 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNCS" = yes ; then
1040 _CFLAGS="$CFLAGS"
1041 _LIBS="$LIBS"
1042 CFLAGS="$CFLAGS $THREAD_CPPFLAGS"
1043 LIBS="$LIBS $THREAD_LIBS"
1044 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1045 CFLAGS="$_CFLAGS"
1046 LIBS="$_LIBS"
1047 fi
1048
1049
1050 # This test makes sure that run tests work at all.  Sometimes a shared
1051 # library is found by the linker, but the runtime linker can't find it.
1052 # This check should come after all modifications of compiler or linker
1053 # variables, and before any other run tests.
1054 AC_MSG_CHECKING([test program])
1055 AC_TRY_RUN([int main() { return 0; }],
1056 [AC_MSG_RESULT(ok)],
1057 [AC_MSG_RESULT(failed)
1058 AC_MSG_ERROR([[
1059 *** Could not execute a simple test program.  This may be a problem
1060 *** related to locating shared libraries.  Check the file 'config.log'
1061 *** for the exact reason.]])],
1062 [AC_MSG_RESULT([cross-compiling])])
1063
1064
1065 dnl Check to see if we have a working 64-bit integer type.
1066 dnl This breaks down into two steps:
1067 dnl (1) figure out if the compiler has a 64-bit int type with working
1068 dnl arithmetic, and if so
1069 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1070 dnl snprintf is the only library routine we really need for int8 support.)
1071 dnl It's entirely possible to have a compiler that handles a 64-bit type
1072 dnl when the C library doesn't; this is fairly likely when using gcc on
1073 dnl an older platform, for example.
1074 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1075 dnl we force our own version of snprintf() to be used instead.
1076 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1077
1078 PGAC_TYPE_64BIT_INT([long int])
1079
1080 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1081   PGAC_TYPE_64BIT_INT([long long int])
1082 fi
1083
1084
1085 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1086
1087 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1088   AC_TRY_COMPILE([
1089 #define INT64CONST(x)  x##LL
1090 long long int foo = INT64CONST(0x1234567890123456);
1091 ],
1092         [],
1093         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1094         [])
1095 fi
1096
1097
1098 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1099 # we found we need to use "long long int", better check.  We cope with
1100 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1101 # neither works, fall back to our own snprintf emulation (which we
1102 # know uses %lld).
1103
1104 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1105   if test $pgac_need_repl_snprintf = no; then
1106     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1107     if test "$LONG_LONG_INT_FORMAT" = ""; then
1108       # Force usage of our own snprintf, since system snprintf is broken
1109       pgac_need_repl_snprintf=yes
1110       LONG_LONG_INT_FORMAT='%lld'
1111     fi
1112   else
1113     # Here if we previously decided we needed to use our own snprintf
1114     LONG_LONG_INT_FORMAT='%lld'
1115   fi
1116   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1117 else
1118   # Here if we are not using 'long long int' at all
1119   INT64_FORMAT='"%ld"'
1120 fi
1121
1122 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1123                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1124
1125 if test $pgac_need_repl_snprintf = yes; then
1126   AC_LIBOBJ(snprintf)
1127 fi
1128
1129 # Need a #define for the size of Datum (unsigned long)
1130 AC_CHECK_SIZEOF([unsigned long])
1131
1132 # Determine memory alignment requirements for the basic C data types.
1133
1134 PGAC_CHECK_ALIGNOF(short)
1135 PGAC_CHECK_ALIGNOF(int)
1136 PGAC_CHECK_ALIGNOF(long)
1137 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1138   PGAC_CHECK_ALIGNOF(long long int)
1139 fi
1140 PGAC_CHECK_ALIGNOF(double)
1141
1142 # Compute maximum alignment of any basic type.
1143 # We assume long's alignment is at least as strong as char, short, or int;
1144 # but we must check long long (if it exists) and double.
1145
1146 MAX_ALIGNOF=$pgac_cv_alignof_long
1147 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1148   MAX_ALIGNOF=$pgac_cv_alignof_double
1149 fi
1150 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1151   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1152 fi
1153 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1154
1155
1156 # Some platforms predefine the types int8, int16, etc.  Only check
1157 # a (hopefully) representative subset.
1158 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1159 [#include <stdio.h>
1160 #ifdef HAVE_SUPPORTDEFS_H
1161 #include <SupportDefs.h>
1162 #endif])
1163
1164 # We also check for sig_atomic_t, which *should* be defined per ANSI
1165 # C, but is missing on some old platforms.
1166 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1167
1168
1169 PGAC_FUNC_POSIX_SIGNALS
1170 if test $ac_cv_func_fseeko = yes; then
1171 AC_SYS_LARGEFILE
1172 fi
1173
1174
1175 # Select semaphore implementation type.
1176 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1177   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1178   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1179 else
1180   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1181     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1182     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1183   else
1184     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1185     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1186   fi
1187 fi
1188
1189
1190 # Select shared-memory implementation type.
1191 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1192 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1193
1194
1195 if test "$enable_nls" = yes ; then
1196   PGAC_CHECK_GETTEXT
1197 fi
1198
1199 # Check for Tcl configuration script tclConfig.sh
1200 if test "$with_tcl" = yes; then
1201     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1202     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1203                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1204     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1205 fi
1206
1207 # Check for Tk configuration script tkConfig.sh
1208 if test "$with_tk" = yes; then
1209     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1210     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1211 fi
1212
1213
1214 #
1215 # Check for DocBook and tools
1216 #
1217 PGAC_PROG_NSGMLS
1218 PGAC_PROG_JADE
1219 PGAC_CHECK_DOCBOOK(3.1)
1220 PGAC_PATH_DOCBOOK_STYLESHEETS
1221 PGAC_PATH_COLLATEINDEX
1222 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1223
1224
1225 # prepare build tree if outside source tree
1226 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1227 # Note 2: /bin/pwd might be better than shell's built-in at getting
1228 #         a symlink-free name.
1229 if test "$no_create" != yes; then
1230   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1231     :
1232   else
1233     AC_SUBST(vpath_build, yes)
1234     _AS_ECHO_N([preparing build tree... ])
1235     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1236     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1237       || AC_MSG_ERROR(failed)
1238     AC_MSG_RESULT(done)
1239   fi
1240 fi
1241
1242
1243 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1244
1245 AC_CONFIG_LINKS([
1246   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1247   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1248   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1249   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1250   src/include/pg_config_os.h:src/include/port/${template}.h
1251   src/Makefile.port:src/makefiles/Makefile.${template}
1252 ])
1253
1254 AC_CONFIG_HEADERS([src/include/pg_config.h],
1255 [
1256 # Update timestamp for pg_config.h (see Makefile.global)
1257 echo >src/include/stamp-h
1258 ])
1259
1260 AC_OUTPUT