granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [11devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 357     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361 AC_PROG_CXX([$pgac_cxx_list])
 362
 363 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 364 # but has idiosyncrasies of its own.  We assume icc will define
 365 # __INTEL_COMPILER regardless of CFLAGS.
 366 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 367 choke me
 368 @%:@endif])], [ICC=yes], [ICC=no])
 369
 370 # Check if it's Sun Studio compiler. We assume that
 371 # __SUNPRO_C will be defined for Sun Studio compilers
 372 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 373 choke me
 374 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 375
 376 AC_SUBST(SUN_STUDIO_CC)
 377
 378
 379 #
 380 # LLVM
 381 #
 382 # Checked early because subsequent tests depend on it.
 383 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 384               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 385 AC_SUBST(with_llvm)
 386 if test "$with_llvm" = yes ; then
 387    PGAC_LLVM_SUPPORT()
 388 fi
 389
 390
 391 unset CFLAGS
 392
 393 #
 394 # Read the template
 395 #
 396 . "$srcdir/src/template/$template" || exit
 397
 398 # C[XX]FLAGS are selected so:
 399 # If the user specifies something in the environment, that is used.
 400 # else:  If the template file set something, that is used.
 401 # else:  If coverage was enabled, don't set anything.
 402 # else:  If the compiler is GCC, then we use -O2.
 403 # else:  If the compiler is something else, then we use -O, unless debugging.
 404
 405 if test "$ac_env_CFLAGS_set" = set; then
 406   CFLAGS=$ac_env_CFLAGS_value
 407 elif test "${CFLAGS+set}" = set; then
 408   : # (keep what template set)
 409 elif test "$enable_coverage" = yes; then
 410   : # no optimization by default
 411 elif test "$GCC" = yes; then
 412   CFLAGS="-O2"
 413 else
 414   # if the user selected debug mode, don't use -O
 415   if test "$enable_debug" != yes; then
 416     CFLAGS="-O"
 417   fi
 418 fi
 419
 420 if test "$ac_env_CXXFLAGS_set" = set; then
 421   CXXFLAGS=$ac_env_CXXFLAGS_value
 422 elif test "${CXXFLAGS+set}" = set; then
 423   : # (keep what template set)
 424 elif test "$enable_coverage" = yes; then
 425   : # no optimization by default
 426 elif test "$GCC" = yes; then
 427   CXXFLAGS="-O2"
 428 else
 429   # if the user selected debug mode, don't use -O
 430   if test "$enable_debug" != yes; then
 431     CXXFLAGS="-O"
 432   fi
 433 fi
 434
 435 # When generating bitcode (for inlining) we always want to use -O2
 436 # even when --enable-debug is specified. The bitcode it's not going to
 437 # be used for line-by-line debugging, and JIT inlining doesn't work
 438 # without at least -O1 (otherwise clang will emit 'noinline'
 439 # attributes everywhere), which is bad for testing.  Still allow the
 440 # environment to override if done explicitly.
 441 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 442   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 443 else
 444   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 445 fi
 446 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 447   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 448 else
 449   BITCODE_CXXFLAGS="-O2 BITCODE_CXXFLAGS"
 450 fi
 451
 452 # C[XX]FLAGS we determined above will be added back at the end
 453 user_CFLAGS=$CFLAGS
 454 CFLAGS=""
 455 user_CXXFLAGS=$CXXFLAGS
 456 CXXFLAGS=""
 457 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 458 BITCODE_CFLAGS=""
 459 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 460 BITCODE_CXXFLAGS=""
 461
 462 # set CFLAGS_VECTOR from the environment, if available
 463 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 464   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 465 fi
 466
 467 # Some versions of GCC support some additional useful warning flags.
 468 # Check whether they are supported, and add them to CFLAGS if so.
 469 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 470 # but has its own.  Also check other compiler-specific flags here.
 471
 472 if test "$GCC" = yes -a "$ICC" = no; then
 473   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 474   CXXFLAGS="-Wall -Wpointer-arith"
 475   # These work in some but not all gcc versions
 476   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 477   # -Wdeclaration-after-statement isn't applicable for C++
 478   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 479   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 480   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 481   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 482   # This was included in -Wall/-Wformat in older GCC versions
 483   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 484   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 485   # Disable strict-aliasing rules; needed for gcc 3.3+
 486   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 487   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 488   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 489   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 490   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 491   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 492   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 493   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 494   # Optimization flags for specific files that benefit from vectorization
 495   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 496   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 497   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 498   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 499   # test for the positive form and if that works, add the negative form
 500   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 501   if test -n "$NOT_THE_CFLAGS"; then
 502     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 503   fi
 504 elif test "$ICC" = yes; then
 505   # Intel's compiler has a bug/misoptimization in checking for
 506   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 507   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 508   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 509   # Make sure strict aliasing is off (though this is said to be the default)
 510   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 511   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 512 elif test "$PORTNAME" = "aix"; then
 513   # AIX's xlc has to have strict aliasing turned off too
 514   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 515   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 516   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 517   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 518 elif test "$PORTNAME" = "hpux"; then
 519   # On some versions of HP-UX, libm functions do not set errno by default.
 520   # Fix that by using +Olibmerrno if the compiler recognizes it.
 521   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 522   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 523 fi
 524
 525 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 526
 527 # Determine flags used to emit bitcode for JIT inlining. Need to test
 528 # for behaviour changing compiler flags, to keep compatibility with
 529 # compiler used for normal postgres code.
 530 if test "$with_llvm" = yes ; then
 531   CLANGXX="$CLANG -xc++"
 532
 533   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 534   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 535   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 536   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 537   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 538   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 539 fi
 540
 541 # supply -g if --enable-debug
 542 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 543   CFLAGS="$CFLAGS -g"
 544 fi
 545
 546 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 547   CXXFLAGS="$CXXFLAGS -g"
 548 fi
 549
 550 # enable code coverage if --enable-coverage
 551 if test "$enable_coverage" = yes; then
 552   if test "$GCC" = yes; then
 553     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 554     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 555   else
 556     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 557   fi
 558 fi
 559
 560 # enable profiling if --enable-profiling
 561 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 562   if test "$GCC" = yes; then
 563     AC_DEFINE([PROFILE_PID_DIR], 1,
 564            [Define to 1 to allow profiling output to be saved separately for each process.])
 565     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 566     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 567   else
 568     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 569   fi
 570 fi
 571
 572 # We already have this in Makefile.win32, but configure needs it too
 573 if test "$PORTNAME" = "win32"; then
 574   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 575 fi
 576
 577 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 578 # user-specified flags (if any) at the end.  This lets users override
 579 # the automatic additions.
 580 CFLAGS="$CFLAGS $user_CFLAGS"
 581 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 582 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 583 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 584
 585 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 586 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 587
 588 # Check if the compiler still works with the final flag settings
 589 # (note, we're not checking that for CXX, which is optional)
 590 AC_MSG_CHECKING([whether the C compiler still works])
 591 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 592   [AC_MSG_RESULT(yes)],
 593   [AC_MSG_RESULT(no)
 594    AC_MSG_ERROR([cannot proceed])])
 595
 596 # Defend against gcc -ffast-math
 597 if test "$GCC" = yes; then
 598 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 599 choke me
 600 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 601 fi
 602
 603 AC_PROG_CPP
 604 AC_SUBST(GCC)
 605
 606
 607 #
 608 # Set up TAS assembly code if needed; the template file has now had its
 609 # chance to request this.
 610 #
 611 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 612
 613 if test "$need_tas" = yes ; then
 614   TAS=tas.o
 615 else
 616   TAS=""
 617 fi
 618 AC_SUBST(TAS)
 619
 620
 621 #
 622 # Automatic dependency tracking
 623 #
 624 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 625               [autodepend=yes])
 626 AC_SUBST(autodepend)
 627
 628
 629 #
 630 # Enable assert checks
 631 #
 632 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 633               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 634                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 635
 636
 637 #
 638 # Include directories
 639 #
 640 ac_save_IFS=$IFS
 641 IFS="${IFS}${PATH_SEPARATOR}"
 642 # SRCH_INC comes from the template file
 643 for dir in $with_includes $SRCH_INC; do
 644   if test -d "$dir"; then
 645     INCLUDES="$INCLUDES -I$dir"
 646   else
 647     AC_MSG_WARN([*** Include directory $dir does not exist.])
 648   fi
 649 done
 650 IFS=$ac_save_IFS
 651 AC_SUBST(INCLUDES)
 652
 653
 654 #
 655 # Library directories
 656 #
 657 ac_save_IFS=$IFS
 658 IFS="${IFS}${PATH_SEPARATOR}"
 659 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 660 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 661   if test -d "$dir"; then
 662     LIBDIRS="$LIBDIRS -L$dir"
 663   else
 664     AC_MSG_WARN([*** Library directory $dir does not exist.])
 665   fi
 666 done
 667 IFS=$ac_save_IFS
 668
 669 #
 670 # Enable thread-safe client libraries
 671 #
 672 AC_MSG_CHECKING([allow thread-safe client libraries])
 673 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 674 if test "$enable_thread_safety" = yes; then
 675   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 676           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 677 fi
 678 AC_MSG_RESULT([$enable_thread_safety])
 679 AC_SUBST(enable_thread_safety)
 680
 681 #
 682 # ICU
 683 #
 684 AC_MSG_CHECKING([whether to build with ICU support])
 685 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 686               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 687 AC_MSG_RESULT([$with_icu])
 688 AC_SUBST(with_icu)
 689
 690 if test "$with_icu" = yes; then
 691   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 692 fi
 693
 694 #
 695 # Optionally build Tcl modules (PL/Tcl)
 696 #
 697 AC_MSG_CHECKING([whether to build with Tcl])
 698 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 699 AC_MSG_RESULT([$with_tcl])
 700 AC_SUBST([with_tcl])
 701
 702 # We see if the path to the Tcl/Tk configuration scripts is specified.
 703 # This will override the use of tclsh to find the paths to search.
 704
 705 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 706
 707 #
 708 # Optionally build Perl modules (PL/Perl)
 709 #
 710 AC_MSG_CHECKING([whether to build Perl modules])
 711 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 712 AC_MSG_RESULT([$with_perl])
 713 AC_SUBST(with_perl)
 714
 715 #
 716 # Optionally build Python modules (PL/Python)
 717 #
 718 AC_MSG_CHECKING([whether to build Python modules])
 719 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 720 AC_MSG_RESULT([$with_python])
 721 AC_SUBST(with_python)
 722
 723 #
 724 # GSSAPI
 725 #
 726 AC_MSG_CHECKING([whether to build with GSSAPI support])
 727 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 728 [
 729   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 730   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 731 ])
 732 AC_MSG_RESULT([$with_gssapi])
 733 AC_SUBST(with_gssapi)
 734
 735
 736 AC_SUBST(krb_srvtab)
 737
 738
 739 #
 740 # Kerberos configuration parameters
 741 #
 742 PGAC_ARG_REQ(with, krb-srvnam,
 743              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 744              [],
 745              [with_krb_srvnam="postgres"])
 746 AC_SUBST(with_krb_srvnam)
 747 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 748                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 749
 750
 751 #
 752 # PAM
 753 #
 754 AC_MSG_CHECKING([whether to build with PAM support])
 755 PGAC_ARG_BOOL(with, pam, no,
 756               [build with PAM support],
 757               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 758 AC_MSG_RESULT([$with_pam])
 759
 760
 761 #
 762 # BSD AUTH
 763 #
 764 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 765 PGAC_ARG_BOOL(with, bsd-auth, no,
 766               [build with BSD Authentication support],
 767               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 768 AC_MSG_RESULT([$with_bsd_auth])
 769
 770
 771 #
 772 # LDAP
 773 #
 774 AC_MSG_CHECKING([whether to build with LDAP support])
 775 PGAC_ARG_BOOL(with, ldap, no,
 776               [build with LDAP support],
 777               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 778 AC_MSG_RESULT([$with_ldap])
 779 AC_SUBST(with_ldap)
 780
 781
 782 #
 783 # Bonjour
 784 #
 785 AC_MSG_CHECKING([whether to build with Bonjour support])
 786 PGAC_ARG_BOOL(with, bonjour, no,
 787               [build with Bonjour support],
 788               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 789 AC_MSG_RESULT([$with_bonjour])
 790
 791
 792 #
 793 # OpenSSL
 794 #
 795 AC_MSG_CHECKING([whether to build with OpenSSL support])
 796 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 797               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 798 AC_MSG_RESULT([$with_openssl])
 799 AC_SUBST(with_openssl)
 800
 801 #
 802 # SELinux
 803 #
 804 AC_MSG_CHECKING([whether to build with SELinux support])
 805 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 806 AC_SUBST(with_selinux)
 807 AC_MSG_RESULT([$with_selinux])
 808
 809 #
 810 # Systemd
 811 #
 812 AC_MSG_CHECKING([whether to build with systemd support])
 813 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 814               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 815 AC_SUBST(with_systemd)
 816 AC_MSG_RESULT([$with_systemd])
 817
 818 #
 819 # Readline
 820 #
 821 PGAC_ARG_BOOL(with, readline, yes,
 822               [do not use GNU Readline nor BSD Libedit for editing])
 823 # readline on MinGW has problems with backslashes in psql and other bugs.
 824 # This is particularly a problem with non-US code pages.
 825 # Therefore disable its use until we understand the cause. 2004-07-20
 826 if test "$PORTNAME" = "win32"; then
 827   if test "$with_readline" = yes; then
 828     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 829     with_readline=no
 830   fi
 831 fi
 832
 833
 834 #
 835 # Prefer libedit
 836 #
 837 PGAC_ARG_BOOL(with, libedit-preferred, no,
 838               [prefer BSD Libedit over GNU Readline])
 839
 840
 841 #
 842 # UUID library
 843 #
 844 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 845 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 846 # UUID library.  More than one of these might be present on a given platform,
 847 # so we make the user say which one she wants.
 848 #
 849 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 850 if test x"$with_uuid" = x"" ; then
 851   with_uuid=no
 852 fi
 853 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 854 if test "$with_ossp_uuid" = yes ; then
 855   with_uuid=ossp
 856 fi
 857
 858 if test "$with_uuid" = bsd ; then
 859   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 860   UUID_EXTRA_OBJS="md5.o sha1.o"
 861 elif test "$with_uuid" = e2fs ; then
 862   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 863   UUID_EXTRA_OBJS="md5.o sha1.o"
 864 elif test "$with_uuid" = ossp ; then
 865   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 866   UUID_EXTRA_OBJS=""
 867 elif test "$with_uuid" = no ; then
 868   UUID_EXTRA_OBJS=""
 869 else
 870   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 871 fi
 872 AC_SUBST(with_uuid)
 873 AC_SUBST(UUID_EXTRA_OBJS)
 874
 875
 876 #
 877 # XML
 878 #
 879 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 880               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 881
 882 if test "$with_libxml" = yes ; then
 883   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 884   if test -n "$XML2_CONFIG"; then
 885     for pgac_option in `$XML2_CONFIG --cflags`; do
 886       case $pgac_option in
 887         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 888       esac
 889     done
 890     for pgac_option in `$XML2_CONFIG --libs`; do
 891       case $pgac_option in
 892         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 893       esac
 894     done
 895   fi
 896 fi
 897
 898 AC_SUBST(with_libxml)
 899
 900 #
 901 # XSLT
 902 #
 903 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 904               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 905
 906
 907 AC_SUBST(with_libxslt)
 908
 909 #
 910 # tzdata
 911 #
 912 PGAC_ARG_REQ(with, system-tzdata,
 913              [DIR], [use system time zone data in DIR])
 914 AC_SUBST(with_system_tzdata)
 915
 916 #
 917 # Zlib
 918 #
 919 PGAC_ARG_BOOL(with, zlib, yes,
 920               [do not use Zlib])
 921 AC_SUBST(with_zlib)
 922
 923 #
 924 # Elf
 925 #
 926
 927 # Assume system is ELF if it predefines __ELF__ as 1,
 928 # otherwise believe host_os based default.
 929 case $host_os in
 930     freebsd1*|freebsd2*) elf=no;;
 931     freebsd3*|freebsd4*) elf=yes;;
 932 esac
 933
 934 AC_EGREP_CPP(yes,
 935 [#if __ELF__
 936   yes
 937 #endif
 938 ],
 939 [ELF_SYS=true],
 940 [if test "X$elf" = "Xyes" ; then
 941   ELF_SYS=true
 942 else
 943   ELF_SYS=
 944 fi])
 945 AC_SUBST(ELF_SYS)
 946
 947 #
 948 # Assignments
 949 #
 950
 951 CPPFLAGS="$CPPFLAGS $INCLUDES"
 952 LDFLAGS="$LDFLAGS $LIBDIRS"
 953
 954 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 955 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 956
 957 PGAC_PROG_LD
 958 AC_SUBST(LD)
 959 AC_SUBST(with_gnu_ld)
 960 AC_PROG_RANLIB
 961 PGAC_CHECK_STRIP
 962 AC_CHECK_TOOL(AR, ar, ar)
 963 if test "$PORTNAME" = "win32"; then
 964   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 965   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 966   AC_CHECK_TOOL(WINDRES, windres, windres)
 967 fi
 968
 969 AC_PROG_INSTALL
 970 # When Autoconf chooses install-sh as install program it tries to generate
 971 # a relative path to it in each makefile where it substitutes it. This clashes
 972 # with our Makefile.global concept. This workaround helps.
 973 case $INSTALL in
 974   *install-sh*) install_bin='';;
 975   *) install_bin=$INSTALL;;
 976 esac
 977 AC_SUBST(install_bin)
 978
 979 PGAC_PATH_PROGS(TAR, tar)
 980 AC_PROG_LN_S
 981 AC_PROG_AWK
 982 AC_PROG_MKDIR_P
 983 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 984 # a relative path to it in each makefile where it substitutes it. This clashes
 985 # with our Makefile.global concept. This workaround helps.
 986 case $MKDIR_P in
 987   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
 988 esac
 989
 990 PGAC_PATH_BISON
 991 PGAC_PATH_FLEX
 992
 993 PGAC_PATH_PERL
 994 if test "$with_perl" = yes; then
 995   if test -z "$PERL"; then
 996     AC_MSG_ERROR([Perl not found])
 997   fi
 998   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 999   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1000     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1001 You might have to rebuild your Perl installation.  Refer to the
1002 documentation for details.  Use --without-perl to disable building
1003 PL/Perl.])
1004   fi
1005   PGAC_CHECK_PERL_EMBED_CCFLAGS
1006   PGAC_CHECK_PERL_EMBED_LDFLAGS
1007 fi
1008
1009 if test "$with_python" = yes; then
1010   PGAC_PATH_PYTHON
1011   PGAC_CHECK_PYTHON_EMBED_SETUP
1012 fi
1013
1014 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1015   PGAC_PATH_PROGS(ZIC, zic)
1016   if test -z "$ZIC"; then
1017     AC_MSG_ERROR([
1018 When cross-compiling, either use the option --with-system-tzdata to use
1019 existing time-zone data, or set the environment variable ZIC to a zic
1020 program to use during the build.])
1021   fi
1022 fi
1023
1024 #
1025 # Pthreads
1026 #
1027 # For each platform, we need to know about any special compile and link
1028 # libraries, and whether the normal C function names are thread-safe.
1029 # See the comment at the top of src/port/thread.c for more information.
1030 # WIN32 doesn't need the pthread tests;  it always uses threads
1031 #
1032 # These tests are run before the library-tests, because linking with the
1033 # other libraries can pull in the pthread functions as a side-effect.  We
1034 # want to use the -pthread or similar flags directly, and not rely on
1035 # the side-effects of linking with some other library.
1036 #
1037 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1038 # invocation below is the first one in the script, and autoconf generates
1039 # additional code for that, which must not be inside the if-block. AS_IF
1040 # knows how to do that.
1041 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1042 [ # then
1043 AX_PTHREAD      # set thread flags
1044
1045 # Some platforms use these, so just define them.  They can't hurt if they
1046 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1047 # enables 5-arg getpwuid_r, among other things.
1048 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1049
1050 # Check for *_r functions
1051 _CFLAGS="$CFLAGS"
1052 _LIBS="$LIBS"
1053 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1054 LIBS="$LIBS $PTHREAD_LIBS"
1055
1056 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1057 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1058
1059 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1060
1061 # Do test here with the proper thread flags
1062 PGAC_FUNC_STRERROR_R_INT
1063
1064 CFLAGS="$_CFLAGS"
1065 LIBS="$_LIBS"
1066
1067 ], [ # else
1068 # do not use values from template file
1069 PTHREAD_CFLAGS=
1070 PTHREAD_LIBS=
1071 ]) # fi
1072
1073 AC_SUBST(PTHREAD_CFLAGS)
1074 AC_SUBST(PTHREAD_LIBS)
1075
1076
1077 ##
1078 ## Libraries
1079 ##
1080 ## Most libraries are included only if they demonstrably provide a function
1081 ## we need, but libm is an exception: always include it, because there are
1082 ## too many compilers that play cute optimization games that will break
1083 ## probes for standard functions such as pow().
1084 ##
1085
1086 AC_CHECK_LIB(m, main)
1087 AC_SEARCH_LIBS(setproctitle, util)
1088 AC_SEARCH_LIBS(dlopen, dl)
1089 AC_SEARCH_LIBS(socket, [socket ws2_32])
1090 AC_SEARCH_LIBS(shl_load, dld)
1091 # We only use libld in port/dynloader/aix.c
1092 case $host_os in
1093      aix*)
1094         AC_SEARCH_LIBS(ldopen, ld)
1095         ;;
1096 esac
1097 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1098 AC_SEARCH_LIBS(crypt, crypt)
1099 AC_SEARCH_LIBS(shm_open, rt)
1100 AC_SEARCH_LIBS(shm_unlink, rt)
1101 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1102 # Solaris:
1103 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1104 # Required for thread_test.c on Solaris
1105 AC_SEARCH_LIBS(sched_yield, rt)
1106 # Required for thread_test.c on Solaris 2.5:
1107 # Other ports use it too (HP-UX) so test unconditionally
1108 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1109 # Cygwin:
1110 AC_SEARCH_LIBS(shmget, cygipc)
1111
1112 if test "$with_readline" = yes; then
1113   PGAC_CHECK_READLINE
1114   if test x"$pgac_cv_check_readline" = x"no"; then
1115     AC_MSG_ERROR([readline library not found
1116 If you have readline already installed, see config.log for details on the
1117 failure.  It is possible the compiler isn't looking in the proper directory.
1118 Use --without-readline to disable readline support.])
1119   fi
1120 fi
1121
1122 if test "$with_zlib" = yes; then
1123   AC_CHECK_LIB(z, inflate, [],
1124                [AC_MSG_ERROR([zlib library not found
1125 If you have zlib already installed, see config.log for details on the
1126 failure.  It is possible the compiler isn't looking in the proper directory.
1127 Use --without-zlib to disable zlib support.])])
1128 fi
1129
1130 if test "$enable_spinlocks" = yes; then
1131   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1132 else
1133   AC_MSG_WARN([
1134 *** Not using spinlocks will cause poor performance.])
1135 fi
1136
1137 if test "$enable_atomics" = yes; then
1138   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1139 else
1140   AC_MSG_WARN([
1141 *** Not using atomic operations will cause poor performance.])
1142 fi
1143
1144 if test "$with_gssapi" = yes ; then
1145   if test "$PORTNAME" != "win32"; then
1146     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1147                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1148   else
1149     LIBS="$LIBS -lgssapi32"
1150   fi
1151 fi
1152
1153 if test "$with_openssl" = yes ; then
1154   dnl Order matters!
1155   if test "$PORTNAME" != "win32"; then
1156      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1157      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1158   else
1159      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1160      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1161   fi
1162   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1163   # Functions introduced in OpenSSL 1.1.0. We used to check for
1164   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1165   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1166   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1167   # functions.
1168   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1169   # OpenSSL versions before 1.1.0 required setting callback functions, for
1170   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1171   # function was removed.
1172   AC_CHECK_FUNCS([CRYPTO_lock])
1173 fi
1174
1175 if test "$with_pam" = yes ; then
1176   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1177 fi
1178
1179 if test "$with_libxml" = yes ; then
1180   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1181 fi
1182
1183 if test "$with_libxslt" = yes ; then
1184   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1185 fi
1186
1187 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1188 if test "$with_ldap" = yes ; then
1189   _LIBS="$LIBS"
1190   if test "$PORTNAME" != "win32"; then
1191     AC_CHECK_LIB(ldap, ldap_bind, [],
1192                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1193                  [$EXTRA_LDAP_LIBS])
1194     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1195     if test "$enable_thread_safety" = yes; then
1196       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1197       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1198                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1199                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1200       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1201     else
1202       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1203     fi
1204     AC_CHECK_FUNCS([ldap_initialize])
1205   else
1206     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1207     LDAP_LIBS_FE="-lwldap32"
1208     LDAP_LIBS_BE="-lwldap32"
1209   fi
1210   LIBS="$_LIBS"
1211 fi
1212 AC_SUBST(LDAP_LIBS_FE)
1213 AC_SUBST(LDAP_LIBS_BE)
1214
1215 # for contrib/sepgsql
1216 if test "$with_selinux" = yes; then
1217   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1218                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1219 fi
1220
1221 # for contrib/uuid-ossp
1222 if test "$with_uuid" = bsd ; then
1223   # On BSD, the UUID functions are in libc
1224   AC_CHECK_FUNC(uuid_to_string,
1225     [UUID_LIBS=""],
1226     [AC_MSG_ERROR([BSD UUID functions are not present])])
1227 elif test "$with_uuid" = e2fs ; then
1228   # On macOS, the UUID functions are in libc
1229   AC_CHECK_FUNC(uuid_generate,
1230     [UUID_LIBS=""],
1231     [AC_CHECK_LIB(uuid, uuid_generate,
1232       [UUID_LIBS="-luuid"],
1233       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1234 elif test "$with_uuid" = ossp ; then
1235   AC_CHECK_LIB(ossp-uuid, uuid_export,
1236     [UUID_LIBS="-lossp-uuid"],
1237     [AC_CHECK_LIB(uuid, uuid_export,
1238       [UUID_LIBS="-luuid"],
1239       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1240 fi
1241 AC_SUBST(UUID_LIBS)
1242
1243
1244 ##
1245 ## Header files
1246 ##
1247
1248 AC_HEADER_STDBOOL
1249
1250 AC_CHECK_HEADERS([atomic.h crypt.h dld.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1251
1252 # On BSD, test for net/if.h will fail unless sys/socket.h
1253 # is included first.
1254 AC_CHECK_HEADERS(net/if.h, [], [],
1255 [AC_INCLUDES_DEFAULT
1256 #include <sys/socket.h>
1257 ])
1258
1259 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1260 # is included first.
1261 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1262 [AC_INCLUDES_DEFAULT
1263 #include <sys/param.h>
1264 ])
1265
1266 # At least on IRIX, test for netinet/tcp.h will fail unless
1267 # netinet/in.h is included first.
1268 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1269 [AC_INCLUDES_DEFAULT
1270 #include <netinet/in.h>
1271 ])
1272
1273 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1274   AC_CHECK_HEADERS(readline/readline.h, [],
1275         [AC_CHECK_HEADERS(readline.h, [],
1276                 [AC_MSG_ERROR([readline header not found
1277 If you have readline already installed, see config.log for details on the
1278 failure.  It is possible the compiler isn't looking in the proper directory.
1279 Use --without-readline to disable readline support.])])])
1280   AC_CHECK_HEADERS(readline/history.h, [],
1281         [AC_CHECK_HEADERS(history.h, [],
1282                 [AC_MSG_ERROR([history header not found
1283 If you have readline already installed, see config.log for details on the
1284 failure.  It is possible the compiler isn't looking in the proper directory.
1285 Use --without-readline to disable readline support.])])])
1286 fi
1287
1288 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1289 # Some installations of libedit usurp /usr/include/readline/, which seems
1290 # bad practice, since in combined installations readline will have its headers
1291 # there.  We might have to resort to AC_EGREP checks to make sure we found
1292 # the proper header...
1293   AC_CHECK_HEADERS(editline/readline.h, [],
1294         [AC_CHECK_HEADERS(readline.h, [],
1295                 [AC_CHECK_HEADERS(readline/readline.h, [],
1296                         [AC_MSG_ERROR([readline header not found
1297 If you have libedit already installed, see config.log for details on the
1298 failure.  It is possible the compiler isn't looking in the proper directory.
1299 Use --without-readline to disable libedit support.])])])])
1300 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1301 # not be there at all.  Hence, don't complain if not found.  We must check
1302 # though, since in yet other versions it is an independent header.
1303   AC_CHECK_HEADERS(editline/history.h, [],
1304         [AC_CHECK_HEADERS(history.h, [],
1305                 [AC_CHECK_HEADERS(readline/history.h)])])
1306 fi
1307
1308 if test "$with_zlib" = yes; then
1309   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1310 If you have zlib already installed, see config.log for details on the
1311 failure.  It is possible the compiler isn't looking in the proper directory.
1312 Use --without-zlib to disable zlib support.])])
1313 fi
1314
1315 if test "$with_gssapi" = yes ; then
1316   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1317         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1318 fi
1319
1320 if test "$with_openssl" = yes ; then
1321   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1322   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1323 fi
1324
1325 if test "$with_pam" = yes ; then
1326   AC_CHECK_HEADERS(security/pam_appl.h, [],
1327                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1328                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1329 fi
1330
1331 if test "$with_bsd_auth" = yes ; then
1332   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1333 fi
1334
1335 if test "$with_systemd" = yes ; then
1336   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1337 fi
1338
1339 if test "$with_libxml" = yes ; then
1340   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1341 fi
1342
1343 if test "$with_libxslt" = yes ; then
1344   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1345 fi
1346
1347 if test "$with_ldap" = yes ; then
1348   if test "$PORTNAME" != "win32"; then
1349      AC_CHECK_HEADERS(ldap.h, [],
1350                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1351      PGAC_LDAP_SAFE
1352   else
1353      AC_CHECK_HEADERS(winldap.h, [],
1354                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1355                       [AC_INCLUDES_DEFAULT
1356 #include <windows.h>
1357                       ])
1358   fi
1359 fi
1360
1361 if test "$with_bonjour" = yes ; then
1362   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1363 dnl At some point we might add something like
1364 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1365 dnl but right now, what that would mainly accomplish is to encourage
1366 dnl people to try to use the avahi implementation, which does not work.
1367 dnl If you want to use Apple's own Bonjour code on another platform,
1368 dnl just add -ldns_sd to LIBS manually.
1369 fi
1370
1371 # for contrib/uuid-ossp
1372 if test "$with_uuid" = bsd ; then
1373   AC_CHECK_HEADERS(uuid.h,
1374     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1375       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1376     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1377 elif test "$with_uuid" = e2fs ; then
1378   AC_CHECK_HEADERS(uuid/uuid.h,
1379     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1380       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1381     [AC_CHECK_HEADERS(uuid.h,
1382       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1383         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1384       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1385 elif test "$with_uuid" = ossp ; then
1386   AC_CHECK_HEADERS(ossp/uuid.h,
1387     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1388       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1389     [AC_CHECK_HEADERS(uuid.h,
1390       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1391         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1392       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1393 fi
1394
1395 if test "$PORTNAME" = "win32" ; then
1396    AC_CHECK_HEADERS(crtdefs.h)
1397 fi
1398
1399 ##
1400 ## Types, structures, compiler characteristics
1401 ##
1402
1403 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1404 AC_C_BIGENDIAN
1405 AC_C_INLINE
1406 PGAC_PRINTF_ARCHETYPE
1407 AC_C_FLEXIBLE_ARRAY_MEMBER
1408 PGAC_C_SIGNED
1409 PGAC_C_FUNCNAME_SUPPORT
1410 PGAC_C_STATIC_ASSERT
1411 PGAC_C_TYPEOF
1412 PGAC_C_TYPES_COMPATIBLE
1413 PGAC_C_BUILTIN_BSWAP16
1414 PGAC_C_BUILTIN_BSWAP32
1415 PGAC_C_BUILTIN_BSWAP64
1416 PGAC_C_BUILTIN_CONSTANT_P
1417 PGAC_C_BUILTIN_UNREACHABLE
1418 PGAC_C_COMPUTED_GOTO
1419 PGAC_C_VA_ARGS
1420 PGAC_STRUCT_TIMEZONE
1421 PGAC_UNION_SEMUN
1422 PGAC_STRUCT_SOCKADDR_UN
1423 PGAC_STRUCT_SOCKADDR_STORAGE
1424 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1425 PGAC_STRUCT_ADDRINFO
1426 AC_TYPE_INTPTR_T
1427 AC_TYPE_UINTPTR_T
1428 AC_TYPE_LONG_LONG_INT
1429
1430 PGAC_TYPE_LOCALE_T
1431
1432 # MSVC doesn't cope well with defining restrict to __restrict, the
1433 # spelling it understands, because it conflicts with
1434 # __declspec(restrict). Therefore we define pg_restrict to the
1435 # appropriate definition, which presumably won't conflict.
1436 #
1437 # Allow platforms with buggy compilers to force restrict to not be
1438 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1439 # template.
1440 AC_C_RESTRICT
1441 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1442   pg_restrict=""
1443 else
1444   pg_restrict="$ac_cv_c_restrict"
1445 fi
1446 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1447 [Define to keyword to use for C99 restrict support, or to nothing if not
1448 supported])
1449
1450 AC_CHECK_TYPES([struct cmsgcred], [], [],
1451 [#include <sys/socket.h>
1452 #include <sys/param.h>
1453 #ifdef HAVE_SYS_UCRED_H
1454 #include <sys/ucred.h>
1455 #endif])
1456
1457 AC_CHECK_TYPES([struct option], [], [],
1458 [#ifdef HAVE_GETOPT_H
1459 #include <getopt.h>
1460 #endif])
1461
1462 if test "$with_zlib" = yes; then
1463   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1464   # did not).  While we could work around the lack of z_streamp, it
1465   # seems unwise to encourage people to use such old zlib versions...
1466   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1467 Use --without-zlib to disable zlib support.])],
1468                 [#include <zlib.h>])
1469 fi
1470
1471 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1472 case $host_cpu in
1473   ppc*|powerpc*)
1474     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1475     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1476         [int a = 0; int *p = &a; int r;
1477          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1478         [pgac_cv_have_ppc_mutex_hint=yes],
1479         [pgac_cv_have_ppc_mutex_hint=no])
1480     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1481     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1482         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1483     fi
1484   ;;
1485 esac
1486
1487 # Check largefile support.  You might think this is a system service not a
1488 # compiler characteristic, but you'd be wrong.  We must check this before
1489 # probing existence of related functions such as fseeko, since the largefile
1490 # defines can affect what is generated for that.
1491 if test "$PORTNAME" != "win32"; then
1492    AC_SYS_LARGEFILE
1493    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1494    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1495    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1496    dnl versions where the feature actually works, it's on by default anyway.
1497    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1498 fi
1499
1500 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1501 AC_CHECK_SIZEOF([off_t])
1502
1503 # If we don't have largefile support, can't handle segsize >= 2GB.
1504 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1505    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1506 fi
1507
1508 AC_CHECK_SIZEOF([bool], [],
1509 [#ifdef HAVE_STDBOOL_H
1510 #include <stdbool.h>
1511 #endif])
1512
1513
1514 ##
1515 ## Functions, global variables
1516 ##
1517
1518 PGAC_VAR_INT_TIMEZONE
1519 AC_FUNC_ACCEPT_ARGTYPES
1520 PGAC_FUNC_GETTIMEOFDAY_1ARG
1521 PGAC_FUNC_WCSTOMBS_L
1522
1523 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1524 # symbols that that library has no business exposing to the world.  Pending
1525 # acquisition of a clue by those developers, ignore libedit (including its
1526 # possible alias of libreadline) while checking for everything else.
1527 LIBS_including_readline="$LIBS"
1528 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1529
1530 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1531
1532 AC_REPLACE_FUNCS(fseeko)
1533 case $host_os in
1534         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1535         # Mingw uses macros to access Win32 API calls
1536         netbsd*|mingw*)
1537                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1538                 ac_cv_func_fseeko=yes;;
1539         *)
1540                 AC_FUNC_FSEEKO;;
1541 esac
1542
1543 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1544 # by calling it, 2009-04-02
1545 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1546 if test "$PORTNAME" != "solaris"; then
1547 AC_CHECK_FUNCS(posix_fadvise)
1548 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1549 fi
1550
1551 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1552 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1553 # This is probably only present on macOS, but may as well check always
1554 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1555
1556 HAVE_IPV6=no
1557 AC_CHECK_TYPE([struct sockaddr_in6],
1558         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1559          HAVE_IPV6=yes],
1560         [],
1561 [$ac_includes_default
1562 #include <netinet/in.h>])
1563 AC_SUBST(HAVE_IPV6)
1564
1565 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1566 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1567 [#include <machine/vmparam.h>
1568 #include <sys/exec.h>
1569 ],
1570 [PS_STRINGS->ps_nargvstr = 1;
1571 PS_STRINGS->ps_argvstr = "foo";])],
1572 [pgac_cv_var_PS_STRINGS=yes],
1573 [pgac_cv_var_PS_STRINGS=no])])
1574 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1575   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1576 fi
1577
1578
1579 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1580 # is missing.  Yes, there are machines that have only one.  We may
1581 # also decide to use snprintf.c if snprintf() is present but does not
1582 # have all the features we need --- see below.
1583
1584 if test "$PORTNAME" = "win32"; then
1585   # Win32 gets snprintf.c built unconditionally.
1586   #
1587   # To properly translate all NLS languages strings, we must support the
1588   # *printf() %$ format, which allows *printf() arguments to be selected
1589   # by position in the translated string.
1590   #
1591   # libintl versions < 0.13 use the native *printf() functions, and Win32
1592   # *printf() doesn't understand %$, so we must use our /port versions,
1593   # which do understand %$. libintl versions >= 0.13 include their own
1594   # *printf versions on Win32.  The libintl 0.13 release note text is:
1595   #
1596   #   C format strings with positions, as they arise when a translator
1597   #   needs to reorder a sentence, are now supported on all platforms.
1598   #   On those few platforms (NetBSD and Woe32) for which the native
1599   #   printf()/fprintf()/... functions don't support such format
1600   #   strings, replacements are provided through <libintl.h>.
1601   #
1602   # We could use libintl >= 0.13's *printf() if we were sure that we had
1603   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1604   # to guarantee that, it is best to just use our own, so we are sure to
1605   # get %$ support. In include/port.h we disable the *printf() macros
1606   # that might have been defined by libintl.
1607   #
1608   # We do this unconditionally whether NLS is used or not so we are sure
1609   # that all Win32 libraries and binaries behave the same.
1610   pgac_need_repl_snprintf=yes
1611 else
1612   pgac_need_repl_snprintf=no
1613   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1614   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1615 fi
1616
1617
1618 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1619 # include/c.h will provide declarations.  Note this is a separate test
1620 # from whether the functions exist in the C library --- there are
1621 # systems that have the functions but don't bother to declare them :-(
1622
1623 AC_CHECK_DECLS([snprintf, vsnprintf])
1624
1625
1626 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1627 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1628 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1629 #include <math.h>
1630 double glob_double;
1631 ],
1632 [return isinf(glob_double) ? 0 : 1;])],
1633 [ac_cv_func_isinf=yes],
1634 [ac_cv_func_isinf=no])])
1635
1636 if test $ac_cv_func_isinf = yes ; then
1637   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1638 else
1639   AC_LIBOBJ(isinf)
1640   # Look for a way to implement a substitute for isinf()
1641   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1642 fi
1643
1644 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1645
1646 case $host_os in
1647
1648         # Windows uses a specialised env handler
1649         # and doesn't need a replacement getpeereid because it doesn't use
1650         # Unix sockets.
1651         mingw*)
1652                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1653                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1654                 ac_cv_func_unsetenv=yes
1655                 ac_cv_func_getpeereid=yes;;
1656         *)
1657                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1658                 ;;
1659 esac
1660
1661 # System's version of getaddrinfo(), if any, may be used only if we found
1662 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1663 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1664 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1665    test "$PORTNAME" != "win32"; then
1666   AC_REPLACE_FUNCS([getaddrinfo])
1667 else
1668   AC_LIBOBJ(getaddrinfo)
1669 fi
1670
1671 # Similarly, use system's getopt_long() only if system provides struct option.
1672 if test x"$ac_cv_type_struct_option" = xyes ; then
1673   AC_REPLACE_FUNCS([getopt_long])
1674 else
1675   AC_LIBOBJ(getopt_long)
1676 fi
1677
1678 # Solaris' getopt() doesn't do what we want for long options, so always use
1679 # our version on that platform.
1680 if test "$PORTNAME" = "solaris"; then
1681   AC_LIBOBJ(getopt)
1682 fi
1683
1684 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1685 # so always use our version on Windows.
1686 if test "$PORTNAME" = "win32"; then
1687   AC_LIBOBJ(getopt)
1688   AC_LIBOBJ(getopt_long)
1689 fi
1690
1691 # Win32 (really MinGW) support
1692 if test "$PORTNAME" = "win32"; then
1693   AC_REPLACE_FUNCS(gettimeofday)
1694   AC_LIBOBJ(dirmod)
1695   AC_LIBOBJ(kill)
1696   AC_LIBOBJ(open)
1697   AC_LIBOBJ(system)
1698   AC_LIBOBJ(win32env)
1699   AC_LIBOBJ(win32error)
1700   AC_LIBOBJ(win32security)
1701   AC_LIBOBJ(win32setlocale)
1702   AC_DEFINE([HAVE_SYMLINK], 1,
1703             [Define to 1 if you have the `symlink' function.])
1704   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1705 #define WIN32_LEAN_AND_MEAN
1706 #include <windows.h>
1707 #include <string.h>
1708 #include <dbghelp.h>])
1709 fi
1710 if test x"$pgac_minidump_type" = x"yes" ; then
1711   AC_SUBST(have_win32_dbghelp,yes)
1712 else
1713   AC_SUBST(have_win32_dbghelp,no)
1714 fi
1715
1716 # Cygwin needs only a bit of that
1717 if test "$PORTNAME" = "cygwin"; then
1718   AC_LIBOBJ(dirmod)
1719 fi
1720
1721 AC_CHECK_DECLS([sys_siglist], [], [],
1722 [#include <signal.h>
1723 /* NetBSD declares sys_siglist in unistd.h.  */
1724 #ifdef HAVE_UNISTD_H
1725 # include <unistd.h>
1726 #endif
1727 ])
1728
1729 AC_CHECK_FUNC(syslog,
1730               [AC_CHECK_HEADER(syslog.h,
1731                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1732
1733 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1734 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1735   [extern int opterr; opterr = 1;])],
1736   [pgac_cv_var_int_opterr=yes],
1737   [pgac_cv_var_int_opterr=no])])
1738 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1739   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1740 fi
1741
1742 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1743 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1744   [extern int optreset; optreset = 1;])],
1745   [pgac_cv_var_int_optreset=yes],
1746   [pgac_cv_var_int_optreset=no])])
1747 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1748   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1749 fi
1750
1751 AC_CHECK_FUNCS([strtoll strtoq], [break])
1752 AC_CHECK_FUNCS([strtoull strtouq], [break])
1753
1754 if test "$with_icu" = yes; then
1755   ac_save_CPPFLAGS=$CPPFLAGS
1756   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1757
1758   # Verify we have ICU's header files
1759   AC_CHECK_HEADER(unicode/ucol.h, [],
1760         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1761
1762   CPPFLAGS=$ac_save_CPPFLAGS
1763 fi
1764
1765 # Lastly, restore full LIBS list and check for readline/libedit symbols
1766 LIBS="$LIBS_including_readline"
1767
1768 if test "$with_readline" = yes; then
1769   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1770   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1771   AC_CHECK_FUNCS([append_history history_truncate_file])
1772 fi
1773
1774
1775 # This test makes sure that run tests work at all.  Sometimes a shared
1776 # library is found by the linker, but the runtime linker can't find it.
1777 # This check should come after all modifications of compiler or linker
1778 # variables, and before any other run tests.
1779 AC_MSG_CHECKING([test program])
1780 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1781 [AC_MSG_RESULT(ok)],
1782 [AC_MSG_RESULT(failed)
1783 AC_MSG_ERROR([[
1784 Could not execute a simple test program.  This may be a problem
1785 related to locating shared libraries.  Check the file 'config.log'
1786 for the exact reason.]])],
1787 [AC_MSG_RESULT([cross-compiling])])
1788
1789 # --------------------
1790 # Run tests below here
1791 # --------------------
1792
1793 # Force use of our snprintf if system's doesn't do arg control
1794 # See comment above at snprintf test for details.
1795 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1796   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1797   if test $pgac_cv_snprintf_arg_control != yes ; then
1798     pgac_need_repl_snprintf=yes
1799   fi
1800 fi
1801
1802
1803 dnl Check to see if we have a working 64-bit integer type.
1804 dnl This breaks down into two steps:
1805 dnl (1) figure out if the compiler has a 64-bit int type with working
1806 dnl arithmetic, and if so
1807 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1808 dnl snprintf is the only library routine we really need for int8 support.)
1809 dnl It's entirely possible to have a compiler that handles a 64-bit type
1810 dnl when the C library doesn't; this is fairly likely when using gcc on
1811 dnl an older platform, for example.
1812 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1813 dnl we force our own version of snprintf() to be used instead.
1814 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1815
1816 dnl As of Postgres 8.4, we no longer support compilers without a working
1817 dnl 64-bit type.  But we still handle the case of snprintf being broken.
1818
1819 PGAC_TYPE_64BIT_INT([long int])
1820
1821 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1822   pg_int64_type="long int"
1823 else
1824   PGAC_TYPE_64BIT_INT([long long int])
1825   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1826     pg_int64_type="long long int"
1827   else
1828     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1829   fi
1830 fi
1831
1832 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1833   [Define to the name of a signed 64-bit integer type.])
1834
1835 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1836 # we found we need to use "long long int", better check.  We cope with
1837 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1838 # work, fall back to our own snprintf emulation (which we know uses %lld).
1839
1840 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1841   if test $pgac_need_repl_snprintf = no; then
1842     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_MODIFIER
1843     if test "$LONG_LONG_INT_MODIFIER" = ""; then
1844       # Force usage of our own snprintf, since system snprintf is broken
1845       pgac_need_repl_snprintf=yes
1846       LONG_LONG_INT_MODIFIER='ll'
1847     fi
1848   else
1849     # Here if we previously decided we needed to use our own snprintf
1850     LONG_LONG_INT_MODIFIER='ll'
1851   fi
1852 else
1853   # Here if we are not using 'long long int' at all
1854   LONG_LONG_INT_MODIFIER='l'
1855 fi
1856
1857 INT64_MODIFIER="\"$LONG_LONG_INT_MODIFIER\""
1858
1859 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1860                    [Define to the appropriate snprintf length modifier for 64-bit ints.])
1861
1862 # Also force use of our snprintf if the system's doesn't support the %z flag.
1863 if test "$pgac_need_repl_snprintf" = no; then
1864   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1865   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1866     pgac_need_repl_snprintf=yes
1867   fi
1868 fi
1869
1870 # Now we have checked all the reasons to replace snprintf
1871 if test $pgac_need_repl_snprintf = yes; then
1872   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1873   AC_LIBOBJ(snprintf)
1874 fi
1875
1876 # has to be down here, rather than with the other builtins, because
1877 # the test uses PG_INT64_TYPE.
1878 PGAC_C_BUILTIN_OP_OVERFLOW
1879
1880 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1881 AC_CHECK_SIZEOF([void *])
1882 AC_CHECK_SIZEOF([size_t])
1883 AC_CHECK_SIZEOF([long])
1884
1885 # Decide whether float4 is passed by value: user-selectable, enabled by default
1886 AC_MSG_CHECKING([whether to build with float4 passed by value])
1887 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1888               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1889                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1890                float4passbyval=true],
1891               [float4passbyval=false])
1892 AC_MSG_RESULT([$enable_float4_byval])
1893 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1894
1895 # Decide whether float8 is passed by value.
1896 # Note: this setting also controls int8 and related types such as timestamp.
1897 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1898 # If not, trying to select it is an error.
1899 AC_MSG_CHECKING([whether to build with float8 passed by value])
1900 if test $ac_cv_sizeof_void_p -ge 8 ; then
1901   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1902 else
1903   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1904   if test "$enable_float8_byval" = yes ; then
1905     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1906   fi
1907 fi
1908 if test "$enable_float8_byval" = yes ; then
1909   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1910             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1911   float8passbyval=true
1912 else
1913   float8passbyval=false
1914 fi
1915 AC_MSG_RESULT([$enable_float8_byval])
1916 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1917
1918 # Determine memory alignment requirements for the basic C data types.
1919
1920 AC_CHECK_ALIGNOF(short)
1921 AC_CHECK_ALIGNOF(int)
1922 AC_CHECK_ALIGNOF(long)
1923 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1924   AC_CHECK_ALIGNOF(long long int)
1925 fi
1926 AC_CHECK_ALIGNOF(double)
1927
1928 # Compute maximum alignment of any basic type.
1929 # We assume long's alignment is at least as strong as char, short, or int;
1930 # but we must check long long (if it is being used for int64) and double.
1931 # Note that we intentionally do not consider any types wider than 64 bits,
1932 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1933 # for disk and memory space.
1934
1935 MAX_ALIGNOF=$ac_cv_alignof_long
1936 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1937   MAX_ALIGNOF=$ac_cv_alignof_double
1938 fi
1939 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1940   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1941 fi
1942 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1943
1944
1945 # Some platforms predefine the types int8, int16, etc.  Only check
1946 # a (hopefully) representative subset.
1947 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1948 [#include <stdio.h>])
1949
1950 # Some compilers offer a 128-bit integer scalar type.
1951 PGAC_TYPE_128BIT_INT
1952
1953 # Check for various atomic operations now that we have checked how to declare
1954 # 64bit integers.
1955 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1956 PGAC_HAVE_GCC__SYNC_INT32_TAS
1957 PGAC_HAVE_GCC__SYNC_INT32_CAS
1958 PGAC_HAVE_GCC__SYNC_INT64_CAS
1959 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1960 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1961
1962
1963 # Check for x86 cpuid instruction
1964 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1965 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1966   [[unsigned int exx[4] = {0, 0, 0, 0};
1967   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1968   ]])],
1969   [pgac_cv__get_cpuid="yes"],
1970   [pgac_cv__get_cpuid="no"])])
1971 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1972   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1973 fi
1974
1975 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1976 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1977   [[unsigned int exx[4] = {0, 0, 0, 0};
1978   __get_cpuid(exx[0], 1);
1979   ]])],
1980   [pgac_cv__cpuid="yes"],
1981   [pgac_cv__cpuid="no"])])
1982 if test x"$pgac_cv__cpuid" = x"yes"; then
1983   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1984 fi
1985
1986 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1987 #
1988 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1989 # with the default compiler flags. If not, check if adding the -msse4.2
1990 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1991 PGAC_SSE42_CRC32_INTRINSICS([])
1992 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1993   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1994 fi
1995 AC_SUBST(CFLAGS_SSE42)
1996
1997 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1998 # define __SSE4_2__ in that case.
1999 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2000 #ifndef __SSE4_2__
2001 #error __SSE4_2__ not defined
2002 #endif
2003 ])], [SSE4_2_TARGETED=1])
2004
2005 # Select CRC-32C implementation.
2006 #
2007 # If we are targeting a processor that has SSE 4.2 instructions, we can use the
2008 # special CRC instructions for calculating CRC-32C. If we're not targeting such
2009 # a processor, but we can nevertheless produce code that uses the SSE
2010 # intrinsics, perhaps with some extra CFLAGS, compile both implementations and
2011 # select which one to use at runtime, depending on whether SSE 4.2 is supported
2012 # by the processor we're running on.
2013 #
2014 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2015 # in the template or configure command line.
2016 if test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_SLICING_BY_8_CRC32C" = x""; then
2017   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2018     USE_SSE42_CRC32C=1
2019   else
2020     # the CPUID instruction is needed for the runtime check.
2021     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2022       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2023     else
2024       # fall back to slicing-by-8 algorithm which doesn't require any special
2025       # CPU support.
2026       USE_SLICING_BY_8_CRC32C=1
2027     fi
2028   fi
2029 fi
2030
2031 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2032 AC_MSG_CHECKING([which CRC-32C implementation to use])
2033 if test x"$USE_SSE42_CRC32C" = x"1"; then
2034   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2035   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2036   AC_MSG_RESULT(SSE 4.2)
2037 else
2038   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2039     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSSE 4.2 CRC instructions with a runtime check.])
2040     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_choose.o"
2041     AC_MSG_RESULT(SSE 4.2 with runtime check)
2042   else
2043     AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2044     PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2045     AC_MSG_RESULT(slicing-by-8)
2046   fi
2047 fi
2048 AC_SUBST(PG_CRC32C_OBJS)
2049
2050
2051 # Select semaphore implementation type.
2052 if test "$PORTNAME" != "win32"; then
2053   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2054     # Need sem_open for this
2055     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2056   fi
2057   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2058     # Need sem_init for this
2059     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2060   fi
2061   AC_MSG_CHECKING([which semaphore API to use])
2062   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2063     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2064     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2065     sematype="named POSIX"
2066   else
2067     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2068       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2069       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2070       sematype="unnamed POSIX"
2071     else
2072       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2073       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2074       sematype="System V"
2075     fi
2076   fi
2077   AC_MSG_RESULT([$sematype])
2078 else
2079   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2080   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2081 fi
2082
2083
2084 # Select shared-memory implementation type.
2085 if test "$PORTNAME" != "win32"; then
2086   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2087   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2088 else
2089   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2090   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2091 fi
2092
2093 # Select random number source
2094 #
2095 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2096 # in the template or configure command line.
2097
2098 # If not selected manually, try to select a source automatically.
2099 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2100   if test x"$with_openssl" = x"yes" ; then
2101     USE_OPENSSL_RANDOM=1
2102   elif test "$PORTNAME" = "win32" ; then
2103     USE_WIN32_RANDOM=1
2104   else
2105     AC_CHECK_FILE([/dev/urandom], [], [])
2106
2107     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2108       USE_DEV_URANDOM=1
2109     fi
2110   fi
2111 fi
2112
2113 AC_MSG_CHECKING([which random number source to use])
2114 if test "$enable_strong_random" = yes ; then
2115   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2116     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2117     AC_MSG_RESULT([OpenSSL])
2118   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2119     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2120     AC_MSG_RESULT([Windows native])
2121   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2122     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2123     AC_MSG_RESULT([/dev/urandom])
2124   else
2125     AC_MSG_ERROR([
2126 no source of strong random numbers was found
2127 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2128 for authentication protocols. You can use --disable-strong-random to use a
2129 built-in pseudo random number generator, but that may be insecure.])
2130   fi
2131   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2132 else
2133     AC_MSG_RESULT([weak builtin PRNG])
2134     AC_MSG_WARN([
2135 *** Not using a strong random number source may be insecure.])
2136 fi
2137
2138 # If not set in template file, set bytes to use libc memset()
2139 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2140   MEMSET_LOOP_LIMIT=1024
2141 fi
2142 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2143
2144
2145 if test "$enable_nls" = yes ; then
2146   PGAC_CHECK_GETTEXT
2147 fi
2148
2149 # Check for Tcl configuration script tclConfig.sh
2150 if test "$with_tcl" = yes; then
2151     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2152     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2153                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2154     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2155     if test "$TCL_SHARED_BUILD" != 1; then
2156       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2157 Use --without-tcl to disable building PL/Tcl.])
2158     fi
2159     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2160     ac_save_CPPFLAGS=$CPPFLAGS
2161     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2162     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2163     CPPFLAGS=$ac_save_CPPFLAGS
2164 fi
2165
2166 # check for <perl.h>
2167 if test "$with_perl" = yes; then
2168   ac_save_CPPFLAGS=$CPPFLAGS
2169   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2170   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2171                   [#include <EXTERN.h>])
2172   # While we're at it, check that we can link to libperl.
2173   # On most platforms, if perl.h is there then libperl.so will be too, but at
2174   # this writing Debian packages them separately.  There is no known reason to
2175   # waste cycles on separate probes for the Tcl or Python libraries, though.
2176   pgac_save_LIBS=$LIBS
2177   LIBS="$perl_embed_ldflags"
2178   AC_MSG_CHECKING([for libperl])
2179   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2180 #include <EXTERN.h>
2181 #include <perl.h>
2182 ],  [perl_alloc();])],
2183     [AC_MSG_RESULT(yes)],
2184     [AC_MSG_RESULT(no)
2185      AC_MSG_ERROR([libperl library is required for Perl])])
2186   LIBS=$pgac_save_LIBS
2187   CPPFLAGS=$ac_save_CPPFLAGS
2188 fi
2189
2190 # check for <Python.h>
2191 if test "$with_python" = yes; then
2192   ac_save_CPPFLAGS=$CPPFLAGS
2193   CPPFLAGS="$python_includespec $CPPFLAGS"
2194   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2195   CPPFLAGS=$ac_save_CPPFLAGS
2196 fi
2197
2198 #
2199 # Check for DocBook and tools
2200 #
2201 PGAC_PATH_XMLLINT
2202 PGAC_CHECK_DOCBOOK(4.2)
2203 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2204 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2205 PGAC_PATH_PROGS(FOP, fop)
2206
2207 #
2208 # Check for test tools
2209 #
2210 if test "$enable_tap_tests" = yes; then
2211   # Check for necessary modules, unless user has specified the "prove" to use;
2212   # in that case it's her responsibility to have a working configuration.
2213   # (prove might be part of a different Perl installation than perl, eg on
2214   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2215   if test -z "$PROVE"; then
2216     # Test::More and Time::HiRes are supposed to be part of core Perl,
2217     # but some distros omit them in a minimal installation.
2218     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2219       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2220   fi
2221   # Now make sure we know where prove is
2222   PGAC_PATH_PROGS(PROVE, prove)
2223   if test -z "$PROVE"; then
2224     AC_MSG_ERROR([prove not found])
2225   fi
2226 fi
2227
2228 # Thread testing
2229
2230 # We have to run the thread test near the end so we have all our symbols
2231 # defined.  Cross compiling throws a warning.
2232 #
2233 if test "$enable_thread_safety" = yes; then
2234 if test "$PORTNAME" != "win32"
2235 then
2236 AC_MSG_CHECKING([thread safety of required library functions])
2237
2238 _CFLAGS="$CFLAGS"
2239 _LIBS="$LIBS"
2240 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2241 LIBS="$LIBS $PTHREAD_LIBS"
2242 AC_RUN_IFELSE(
2243   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2244   [AC_MSG_RESULT(yes)],
2245   [AC_MSG_RESULT(no)
2246   AC_MSG_ERROR([thread test program failed
2247 This platform is not thread-safe.  Check the file 'config.log' or compile
2248 and run src/test/thread/thread_test for the exact reason.
2249 Use --disable-thread-safety to disable thread safety.])],
2250   [AC_MSG_RESULT(maybe)
2251   AC_MSG_WARN([
2252 *** Skipping thread test program because of cross-compile build.
2253 *** Run the program in src/test/thread on the target machine.
2254 ])])
2255 CFLAGS="$_CFLAGS"
2256 LIBS="$_LIBS"
2257 else
2258 AC_MSG_WARN([*** skipping thread test on Win32])
2259 fi
2260 fi
2261
2262 # If compiler will take -Wl,--as-needed (or various platform-specific
2263 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2264 # trying to filter LIBS to the minimum for each executable.
2265 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2266 # libreadline; therefore we postpone testing it until we know what library
2267 # dependencies readline has.  The test code will try to link with $LIBS.
2268 if test "$with_readline" = yes; then
2269   link_test_func=readline
2270 else
2271   link_test_func=exit
2272 fi
2273
2274 if test "$PORTNAME" = "darwin"; then
2275   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2276 elif test "$PORTNAME" = "openbsd"; then
2277   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2278 else
2279   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2280 fi
2281
2282 # Create compiler version string
2283 if test x"$GCC" = x"yes" ; then
2284   cc_string=`${CC} --version | sed q`
2285   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2286 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2287   cc_string=`${CC} -V 2>&1 | sed q`
2288 else
2289   cc_string=$CC
2290 fi
2291
2292 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2293                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2294                    [A string containing the version number, platform, and C compiler])
2295
2296 # Supply a numeric version string for use by 3rd party add-ons
2297 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2298 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2299 tr '.' '        ' |
2300 $AWK '{printf "%d%04d", $1, $2}'`"]
2301 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2302 AC_SUBST(PG_VERSION_NUM)
2303
2304
2305 # Begin output steps
2306
2307 AC_MSG_NOTICE([using compiler=$cc_string])
2308 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2309 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2310 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2311 # Currently only used when LLVM is used
2312 if test "$with_llvm" = yes ; then
2313    AC_MSG_NOTICE([using CXX=$CXX])
2314    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2315    AC_MSG_NOTICE([using CLANG=$CLANG])
2316    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2317    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2318 fi
2319
2320 # prepare build tree if outside source tree
2321 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2322 # Note 2: /bin/pwd might be better than shell's built-in at getting
2323 #         a symlink-free name.
2324 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2325   vpath_build=no
2326 else
2327   vpath_build=yes
2328   if test "$no_create" != yes; then
2329     _AS_ECHO_N([preparing build tree... ])
2330     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2331     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2332       || AC_MSG_ERROR(failed)
2333     AC_MSG_RESULT(done)
2334   fi
2335 fi
2336 AC_SUBST(vpath_build)
2337
2338
2339 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2340
2341 AC_CONFIG_LINKS([
2342   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2343   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2344   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2345   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2346   src/include/pg_config_os.h:src/include/port/${template}.h
2347   src/Makefile.port:src/makefiles/Makefile.${template}
2348 ])
2349
2350 if test "$PORTNAME" = "win32"; then
2351 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2352 # Links sometimes fail undetected on Mingw -
2353 # so here we detect it and warn the user
2354 for FILE in $CONFIG_LINKS
2355  do
2356         # test -e works for symlinks in the MinGW console
2357         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2358  done
2359 ])
2360 fi
2361
2362 AC_CONFIG_HEADERS([src/include/pg_config.h],
2363 [
2364 # Update timestamp for pg_config.h (see Makefile.global)
2365 echo >src/include/stamp-h
2366 ])
2367
2368 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2369 [
2370 # Update timestamp for pg_config_ext.h (see Makefile.global)
2371 echo >src/include/stamp-ext-h
2372 ])
2373
2374 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2375                   [echo >src/interfaces/ecpg/include/stamp-h])
2376
2377 AC_OUTPUT