granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.310 2004/01/09 04:58:09 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [7.5devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix5 ;;
  60    linux*) template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      qnx*) template=qnx4 ;;
  67      sco*) template=sco ;;
  68  solaris*) template=solaris ;;
  69    sunos*) template=sunos4 ;;
  70  sysv4.2*)
  71         case $host_vendor in
  72           univel) template=univel ;;
  73         esac ;;
  74    sysv4*) template=svr4 ;;
  75    sysv5*) template=unixware ;;
  76   ultrix*) template=ultrix4 ;;
  77 esac
  78
  79   if test x"$template" = x"" ; then
  80     AC_MSG_ERROR([[
  81 *******************************************************************
  82 PostgreSQL has apparently not been ported to your platform yet.
  83 To try a manual configuration, look into the src/template directory
  84 for a similar platform and use the '--with-template=' option.
  85
  86 Please also contact <pgsql-ports@postgresql.org> to see about
  87 rectifying this.  Include the above 'checking host system type...'
  88 line.
  89 *******************************************************************
  90 ]])
  91   fi
  92
  93 ])
  94
  95 AC_MSG_RESULT([$template])
  96
  97 PORTNAME=$template
  98 AC_SUBST(PORTNAME)
  99
 100 # Initialize default assumption that we do not need separate assembly code
 101 # for TAS (test-and-set).  This can be overridden by the template file
 102 # when it's executed.
 103 need_tas=no
 104 tas_file=dummy.s
 105
 106
 107
 108 ##
 109 ## Command line options
 110 ##
 111
 112 #
 113 # Installation directory for documentation
 114 #
 115 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 116   --without-docdir        do not install the documentation],
 117          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 118          [docdir=],
 119          [docdir=$withval],
 120          [docdir='${prefix}/doc'])
 121 AC_SUBST(docdir)
 122
 123
 124 #
 125 # Add non-standard directories to the include path
 126 #
 127 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 128
 129
 130 #
 131 # Add non-standard directories to the library search path
 132 #
 133 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 134              [LIBRARY_DIRS=$withval])
 135
 136 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 137              [LIBRARY_DIRS=$withval])
 138
 139
 140 #
 141 # 64-bit integer date/time storage (--enable-integer-datetimes)
 142 #
 143 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 144 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 145               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 146                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 147 AC_MSG_RESULT([$enable_integer_datetimes])
 148
 149
 150 #
 151 # NLS
 152 #
 153 AC_MSG_CHECKING([whether NLS is wanted])
 154 PGAC_ARG_OPTARG(enable, nls,
 155                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 156                 [],
 157                 [WANTED_LANGUAGES=$enableval],
 158                 [AC_DEFINE(ENABLE_NLS, 1,
 159                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 160 AC_MSG_RESULT([$enable_nls])
 161 AC_SUBST(enable_nls)
 162 AC_SUBST(WANTED_LANGUAGES)
 163
 164 #
 165 # Default port number (--with-pgport), default 5432
 166 #
 167 AC_MSG_CHECKING([for default port number])
 168 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 169              [default_port=$withval],
 170              [default_port=5432])
 171 AC_MSG_RESULT([$default_port])
 172 # Need both of these because some places want an integer and some a string
 173 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 174 [Define to the default TCP port number on which the server listens and
 175 to which clients will try to connect.  This can be overridden at run-time,
 176 but it's convenient if your clients have the right default compiled in.
 177 (--with-pgport=PORTNUM)])
 178 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 179                    [Define to the default TCP port number as a string constant.])
 180 AC_SUBST(default_port)
 181
 182 #
 183 # Option to disable shared libraries
 184 #
 185 PGAC_ARG_BOOL(enable, shared, yes,
 186               [  --disable-shared        do not build shared libraries])
 187 AC_SUBST(enable_shared)
 188
 189 #
 190 # '-rpath'-like feature can be disabled
 191 #
 192 PGAC_ARG_BOOL(enable, rpath, yes,
 193               [  --disable-rpath         do not embed shared library search path in executables])
 194 AC_SUBST(enable_rpath)
 195
 196 #
 197 # Spinlocks
 198 #
 199 PGAC_ARG_BOOL(enable, spinlocks, yes,
 200               [  --disable-spinlocks     do not use spinlocks])
 201
 202 #
 203 # --enable-debug adds -g to compiler flags
 204 #
 205 PGAC_ARG_BOOL(enable, debug, no,
 206               [  --enable-debug          build with debugging symbols (-g)])
 207 AC_SUBST(enable_debug)
 208
 209 #
 210 # C compiler
 211 #
 212
 213 # For historical reasons you can also use --with-CC to specify the C compiler
 214 # to use, although the standard way to do this is to set the CC environment
 215 # variable.
 216 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 217
 218 case $template in
 219   aix) pgac_cc_list="gcc xlc";;
 220  irix) pgac_cc_list="cc";; # no gcc
 221     *) pgac_cc_list="gcc cc";;
 222 esac
 223
 224 AC_PROG_CC([$pgac_cc_list])
 225
 226 unset CFLAGS
 227
 228 #
 229 # Read the template
 230 #
 231 . "$srcdir/src/template/$template" || exit
 232
 233 # CFLAGS are selected so:
 234 # If the user specifies something in the environment, that is used.
 235 # else:  If the template file set something, that is used.
 236 # else:  If the compiler is GCC, then we use -O2.
 237 # else:  If the compiler is something else, then we use -0.
 238
 239 if test "$ac_env_CFLAGS_set" = set; then
 240   CFLAGS=$ac_env_CFLAGS_value
 241 elif test "${CFLAGS+set}" = set; then
 242   : # (keep what template set)
 243 elif test "$GCC" = yes; then
 244   CFLAGS="-O2"
 245 else
 246   # if the user selected debug mode, don't use -O
 247   if test "$enable_debug" != yes; then
 248     CFLAGS="-O"
 249   fi
 250 fi
 251
 252 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 253 PGAC_PROG_CC_NO_STRICT_ALIASING
 254
 255 # supply -g if --enable-debug
 256 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 257   CFLAGS="$CFLAGS -g"
 258 fi
 259
 260 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 261
 262 # We already have this in Makefile.win32, but configure needs it too
 263 if test "$PORTNAME" = "win32"; then
 264   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32"
 265 fi
 266
 267 # Check if the compiler still works with the template settings
 268 AC_MSG_CHECKING([whether the C compiler still works])
 269 AC_TRY_LINK([], [return 0;],
 270   [AC_MSG_RESULT(yes)],
 271   [AC_MSG_RESULT(no)
 272    AC_MSG_ERROR([cannot proceed])])
 273
 274 # Defend against gcc -ffast-math
 275 if test "$GCC" = yes; then
 276 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 277 choke me
 278 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 279 fi
 280
 281 AC_PROG_CPP
 282 AC_SUBST(GCC)
 283
 284 # Create compiler version string
 285 if test x"$GCC" = x"yes" ; then
 286   cc_string="GCC `${CC} --version | sed q`"
 287 else
 288   cc_string=$CC
 289 fi
 290 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 291                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 292                    [A string containing the version number, platform, and C compiler])
 293
 294
 295 #
 296 # Set up TAS assembly code if needed; the template file has now had its
 297 # chance to request this.
 298 #
 299 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 300
 301 if test "$need_tas" = yes ; then
 302   TAS=tas.o
 303 else
 304   TAS=""
 305 fi
 306 AC_SUBST(TAS)
 307
 308
 309 #
 310 # Automatic dependency tracking
 311 #
 312 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 313               [autodepend=yes])
 314 AC_SUBST(autodepend)
 315
 316
 317 #
 318 # Enable assert checks
 319 #
 320 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 321               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 322                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 323
 324
 325 #
 326 # Include directories
 327 #
 328 ac_save_IFS=$IFS
 329 IFS="${IFS}:"
 330 # SRCH_INC comes from the template file
 331 for dir in $with_includes $SRCH_INC; do
 332   if test -d "$dir"; then
 333     INCLUDES="$INCLUDES -I$dir"
 334   else
 335     AC_MSG_WARN([*** Include directory $dir does not exist.])
 336   fi
 337 done
 338 IFS=$ac_save_IFS
 339 AC_SUBST(INCLUDES)
 340
 341
 342 #
 343 # Library directories
 344 #
 345 ac_save_IFS=$IFS
 346 IFS="${IFS}:"
 347 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 348 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 349   if test -d "$dir"; then
 350     LIBDIRS="$LIBDIRS -L$dir"
 351   else
 352     AC_MSG_WARN([*** Library directory $dir does not exist.])
 353   fi
 354 done
 355 IFS=$ac_save_IFS
 356
 357 #
 358 # Enable thread-safe client libraries
 359 #
 360 AC_MSG_CHECKING([allow thread-safe client libraries])
 361 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 362               [AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 363                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 364 AC_MSG_RESULT([$enable_thread_safety])
 365 AC_SUBST(enable_thread_safety)
 366
 367 #
 368 # Tcl/Tk
 369 #
 370 AC_MSG_CHECKING([whether to build with Tcl])
 371 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 372 AC_MSG_RESULT([$with_tcl])
 373 AC_SUBST([with_tcl])
 374
 375 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 376 AC_MSG_CHECKING([whether to build with Tk])
 377 if test "$with_tcl" = yes; then
 378   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 379 else
 380   with_tk=no
 381 fi
 382 AC_MSG_RESULT([$with_tk])
 383 AC_SUBST([with_tk])
 384
 385
 386 # We see if the path to the Tcl/Tk configuration scripts is specified.
 387 # This will override the use of tclsh to find the paths to search.
 388
 389 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 390
 391 # We see if the path to the Tk configuration scripts is specified.
 392 # This will override the use of tclsh to find the paths to search.
 393
 394 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 395
 396 #
 397 # Optionally build Perl modules (PL/Perl)
 398 #
 399 AC_MSG_CHECKING([whether to build Perl modules])
 400 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 401 AC_MSG_RESULT([$with_perl])
 402 AC_SUBST(with_perl)
 403
 404 #
 405 # Optionally build Python modules (PL/Python)
 406 #
 407 AC_MSG_CHECKING([whether to build Python modules])
 408 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 409 AC_MSG_RESULT([$with_python])
 410 AC_SUBST(with_python)
 411
 412 #
 413 # Optionally build the Java/JDBC tools
 414 #
 415 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 416 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 417 [AC_MSG_RESULT(yes)
 418 PGAC_PATH_ANT
 419 if test -z "$ANT"; then
 420   AC_MSG_ERROR([Ant is required to build Java components
 421 If you have Ant already installed, see config.log for details on the failure.])
 422 fi
 423 if "$ANT" -version | egrep -i 'ant version' | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 424   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 425 fi],
 426 [AC_MSG_RESULT(no)])
 427 AC_SUBST(with_java)
 428
 429 #
 430 # Kerberos 4
 431 #
 432 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 433 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 434 [
 435   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 436   krb_srvtab="/etc/srvtab"
 437 ])
 438 AC_MSG_RESULT([$with_krb4])
 439 AC_SUBST(with_krb4)
 440
 441
 442 #
 443 # Kerberos 5
 444 #
 445 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 446 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 447 [
 448   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 449   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 450 ])
 451 AC_MSG_RESULT([$with_krb5])
 452 AC_SUBST(with_krb5)
 453
 454
 455 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 456 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 457   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 458 fi
 459
 460 AC_SUBST(krb_srvtab)
 461
 462
 463 #
 464 # Kerberos configuration parameters
 465 #
 466 PGAC_ARG_REQ(with, krb-srvnam,
 467              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 468              [],
 469              [with_krb_srvnam="postgres"])
 470 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 471                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 472
 473
 474 #
 475 # PAM
 476 #
 477 AC_MSG_CHECKING([whether to build with PAM support])
 478 PGAC_ARG_BOOL(with, pam, no,
 479               [  --with-pam              build with PAM support],
 480               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 481 AC_MSG_RESULT([$with_pam])
 482 AC_SUBST(with_pam)
 483
 484
 485 #
 486 # Rendezvous
 487 #
 488 AC_MSG_CHECKING([whether to build with Rendezvous support])
 489 PGAC_ARG_BOOL(with, rendezvous, no,
 490               [  --with-rendezvous       build with Rendezvous support],
 491               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 492 AC_MSG_RESULT([$with_rendezvous])
 493 AC_SUBST(with_rendezvous)
 494
 495
 496 #
 497 # OpenSSL
 498 #
 499 AC_MSG_CHECKING([whether to build with OpenSSL support])
 500 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 501               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 502 AC_MSG_RESULT([$with_openssl])
 503 AC_SUBST(with_openssl)
 504
 505
 506 #
 507 # Readline
 508 #
 509 PGAC_ARG_BOOL(with, readline, yes,
 510               [  --without-readline      do not use Readline])
 511
 512 #
 513 # Zlib
 514 #
 515 PGAC_ARG_BOOL(with, zlib, yes,
 516               [  --without-zlib          do not use Zlib])
 517
 518 #
 519 # Elf
 520 #
 521
 522 # Assume system is ELF if it predefines __ELF__ as 1,
 523 # otherwise believe host_os based default.
 524 case $host_os in
 525     freebsd1*|freebsd2*) elf=no;;
 526     freebsd3*|freebsd4*) elf=yes;;
 527 esac
 528
 529 AC_EGREP_CPP(yes,
 530 [#if __ELF__
 531   yes
 532 #endif
 533 ],
 534 [ELF_SYS=true],
 535 [if test "X$elf" = "Xyes" ; then
 536   ELF_SYS=true
 537 else
 538   ELF_SYS=
 539 fi])
 540 AC_SUBST(ELF_SYS)
 541
 542 #
 543 # Assignments
 544 #
 545
 546 CPPFLAGS="$CPPFLAGS $INCLUDES"
 547 LDFLAGS="$LDFLAGS $LIBDIRS"
 548
 549 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 550 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 551
 552
 553 AC_PROG_AWK
 554 PGAC_PATH_FLEX
 555 AC_PROG_LN_S
 556 AC_PROG_LD
 557 AC_SUBST(LD)
 558 AC_SUBST(with_gnu_ld)
 559 case $host_os in sysv5*)
 560   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 561   [
 562     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 563     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 564     LDFLAGS=$pgac_save_LDFLAGS
 565   ])
 566   ld_R_works=$pgac_cv_prog_ld_R
 567   AC_SUBST(ld_R_works)
 568 esac
 569 AC_PROG_RANLIB
 570 AC_CHECK_PROGS(LORDER, lorder)
 571 AC_PATH_PROG(TAR, tar)
 572 PGAC_CHECK_STRIP
 573
 574 AC_CHECK_PROGS(YACC, ['bison -y'])
 575
 576 if test "$YACC"; then
 577   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 578     AC_MSG_WARN([
 579 *** The installed version of Bison is too old.  PostgreSQL needs
 580 *** Bison version 1.875 or later.])
 581   fi
 582 fi
 583
 584 if test -z "$YACC"; then
 585   AC_MSG_WARN([
 586 *** Without Bison you will not be able to build PostgreSQL from CVS or
 587 *** change any of the parser definition files.  You can obtain Bison from
 588 *** a GNU mirror site.  (If you are using the official distribution of
 589 *** PostgreSQL then you do not need to worry about this because the Bison
 590 *** output is pre-generated.)  To use a different yacc program (possible,
 591 *** but not recommended), set the environment variable YACC before running
 592 *** 'configure'.])
 593 fi
 594 AC_SUBST(YFLAGS)
 595
 596 PGAC_PATH_PERL
 597 if test "$with_perl" = yes; then
 598   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 599   PGAC_CHECK_PERL_EMBED_LDFLAGS
 600 fi
 601
 602 if test "$with_python" = yes; then
 603   PGAC_PATH_PYTHON
 604   PGAC_CHECK_PYTHON_EMBED_SETUP
 605 fi
 606
 607
 608 ##
 609 ## Libraries
 610 ##
 611
 612 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 613 then
 614         AC_CHECK_LIB(bsd,      main)
 615 fi
 616 AC_CHECK_LIB(util,     setproctitle)
 617 AC_CHECK_LIB(m,        main)
 618 AC_CHECK_LIB(dl,       main)
 619 AC_CHECK_LIB(nsl,      main)
 620 AC_CHECK_LIB(socket,   main)
 621 AC_CHECK_LIB(ipc,      main)
 622 AC_CHECK_LIB(IPC,      main)
 623 AC_CHECK_LIB(lc,       main)
 624 AC_CHECK_LIB(dld,      main)
 625 AC_CHECK_LIB(ld,       main)
 626 AC_CHECK_LIB(compat,   main)
 627 AC_CHECK_LIB(BSD,      main)
 628 AC_CHECK_LIB(gen,      main)
 629 AC_CHECK_LIB(PW,       main)
 630 AC_CHECK_LIB(resolv,   main)
 631 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 632 # QNX:
 633 AC_CHECK_LIB(unix, main)
 634 AC_SEARCH_LIBS(crypt,  crypt)
 635 # BeOS:
 636 if test "$PORTNAME" = "beos"
 637 then
 638         AC_CHECK_LIB(bind, __inet_ntoa)
 639 fi
 640 # Solaris:
 641 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 642 # Cygwin:
 643 AC_CHECK_LIB(cygipc, shmget)
 644 # WIN32:
 645 if test "$PORTNAME" = "win32"
 646 then
 647         AC_CHECK_LIB(wsock32, main)
 648 fi
 649
 650 if test "$with_readline" = yes; then
 651   PGAC_CHECK_READLINE
 652   if test x"$pgac_cv_check_readline" = x"no"; then
 653     AC_MSG_ERROR([readline library not found
 654 If you have readline already installed, see config.log for details on the
 655 failure.  It is possible the compiler isn't looking in the proper directory.
 656 Use --without-readline to disable readline support.])
 657   fi
 658 fi
 659
 660 if test "$with_zlib" = yes; then
 661   AC_CHECK_LIB(z, inflate, [],
 662                [AC_MSG_ERROR([zlib library not found
 663 If you have zlib already installed, see config.log for details on the
 664 failure.  It is possible the compiler isn't looking in the proper directory.
 665 Use --without-zlib to disable zlib support.])])
 666 fi
 667
 668 if test "$enable_spinlocks" = yes; then
 669   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 670 else
 671   AC_MSG_WARN([
 672 *** Not using spinlocks will cause poor performance.])
 673 fi
 674
 675 if test "$with_krb4" = yes ; then
 676   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 677   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 678   AC_REPLACE_FUNCS([gethostname])
 679 fi
 680
 681 if test "$with_krb5" = yes ; then
 682   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 683                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 684   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 685                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 686   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 687                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 688 fi
 689
 690 if test "$with_openssl" = yes ; then
 691   dnl Order matters!
 692   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 693   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 694 fi
 695
 696 if test "$with_pam" = yes ; then
 697   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 698 fi
 699
 700
 701 ##
 702 ## Header files
 703 ##
 704
 705 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 706 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 707
 708 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 709 # netinet/in.h is included first.
 710 AC_CHECK_HEADERS(netinet/in.h)
 711 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 712 [AC_INCLUDES_DEFAULT
 713 #ifdef HAVE_NETINET_IN_H
 714 #include <netinet/in.h>
 715 #endif
 716 ])
 717
 718 if test "$with_readline" = yes; then
 719   AC_CHECK_HEADERS(readline/readline.h, [],
 720                    [AC_CHECK_HEADERS(editline/readline.h, [],
 721                          [AC_CHECK_HEADERS(readline.h, [],
 722                                      [AC_MSG_ERROR([readline header not found
 723 If you have readline already installed, see config.log for details on the
 724 failure.  It is possible the compiler isn't looking in the proper directory.
 725 Use --without-readline to disable readline support.])])])])
 726   AC_CHECK_HEADERS(readline/history.h, [],
 727                    [AC_CHECK_HEADERS(editline/history.h, [],
 728                          [AC_CHECK_HEADERS(history.h, [],
 729                                      [AC_MSG_ERROR([history header not found
 730 If you have readline already installed, see config.log for details on the
 731 failure.  It is possible the compiler isn't looking in the proper directory.
 732 Use --without-readline to disable readline support.])])])])
 733 fi
 734
 735 if test "$with_zlib" = yes; then
 736   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 737 If you have zlib already installed, see config.log for details on the
 738 failure.  It is possible the compiler isn't looking in the proper directory.
 739 Use --without-zlib to disable zlib support.])])
 740 fi
 741
 742 if test "$with_krb4" = yes ; then
 743   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 744 fi
 745
 746 if test "$with_krb5" = yes ; then
 747   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 748   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 749 fi
 750
 751 if test "$with_openssl" = yes ; then
 752   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 753   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 754 fi
 755
 756 if test "$with_pam" = yes ; then
 757   AC_CHECK_HEADERS(security/pam_appl.h, [],
 758                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 759                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 760 fi
 761
 762 if test "$with_rendezvous" = yes ; then
 763   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 764 fi
 765
 766
 767 ##
 768 ## Types, structures, compiler characteristics
 769 ##
 770
 771 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 772 AC_C_CONST
 773 AC_C_INLINE
 774 AC_C_STRINGIZE
 775 PGAC_C_SIGNED
 776 AC_C_VOLATILE
 777 PGAC_C_FUNCNAME_SUPPORT
 778 PGAC_STRUCT_TIMEZONE
 779 PGAC_UNION_SEMUN
 780 PGAC_STRUCT_SOCKADDR_UN
 781 PGAC_STRUCT_SOCKADDR_STORAGE
 782 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 783 PGAC_STRUCT_ADDRINFO
 784
 785 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 786 [#include <sys/param.h>
 787 #include <sys/types.h>
 788 #include <sys/socket.h>
 789 #include <sys/ucred.h>])
 790
 791 AC_CHECK_TYPES([struct option], [], [],
 792 [#ifdef HAVE_GETOPT_H
 793 #include <getopt.h>
 794 #endif])
 795
 796 if test "$with_zlib" = yes; then
 797   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 798   # did not).  While we could work around the lack of z_streamp, it
 799   # seems unwise to encourage people to use such old zlib versions...
 800   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 801 Use --without-zlib to disable zlib support.])],
 802                 [#include <zlib.h>])
 803 fi
 804
 805 if test "$with_krb5" = yes; then
 806 # Check for differences between MIT and Heimdal (KTH) releases
 807   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 808                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 809                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 810                                      [#include <krb5.h>])],
 811                    [#include <krb5.h>])
 812   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 813                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 814                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 815                                      [#include <krb5.h>])],
 816                    [#include <krb5.h>])
 817 fi
 818
 819
 820 ##
 821 ## Functions, global variables
 822 ##
 823
 824 PGAC_VAR_INT_TIMEZONE
 825 AC_FUNC_ACCEPT_ARGTYPES
 826 PGAC_FUNC_GETTIMEOFDAY_1ARG
 827
 828 # SunOS doesn't handle negative byte comparisons properly with +/- return
 829 AC_FUNC_MEMCMP
 830
 831 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 832
 833 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 834
 835 HAVE_IPV6=no
 836 AC_CHECK_TYPE([struct sockaddr_in6],
 837               [AC_CHECK_FUNC(inet_ntop,
 838                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 839                                                           HAVE_IPV6=yes])],
 840               [],
 841 [$ac_includes_default
 842 #include <netinet/in.h>])
 843 AC_SUBST(HAVE_IPV6)
 844
 845 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 846 [AC_TRY_LINK(
 847 [#include <machine/vmparam.h>
 848 #include <sys/exec.h>
 849 ],
 850 [PS_STRINGS->ps_nargvstr = 1;
 851 PS_STRINGS->ps_argvstr = "foo";],
 852 [pgac_cv_var_PS_STRINGS=yes],
 853 [pgac_cv_var_PS_STRINGS=no])])
 854 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 855   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 856 fi
 857
 858
 859 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 860 # is missing.  Yes, there are machines that have only one.  We may
 861 # also decide to use snprintf.c if snprintf() is present but does not
 862 # have working "long long int" support -- see below.
 863
 864 pgac_need_repl_snprintf=no
 865 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 866 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 867
 868
 869 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 870 # include/c.h will provide declarations.  Note this is a separate test
 871 # from whether the functions exist in the C library --- there are
 872 # systems that have the functions but don't bother to declare them :-(
 873
 874 AC_CHECK_DECLS([snprintf, vsnprintf])
 875
 876
 877 # do this one the hard way in case isinf() is a macro
 878 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 879 [AC_TRY_LINK(
 880 [#include <math.h>
 881 ],
 882 [double x = 0.0; int res = isinf(x);],
 883 [ac_cv_func_isinf=yes],
 884 [ac_cv_func_isinf=no])])
 885
 886 if test $ac_cv_func_isinf = yes ; then
 887   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 888 else
 889   AC_LIBOBJ(isinf)
 890   # Look for a way to implement a substitute for isinf()
 891   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 892 fi
 893
 894 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 895
 896 # system's version of getaddrinfo(), if any, may be used only if we found
 897 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 898 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 899   AC_REPLACE_FUNCS([getaddrinfo])
 900 else
 901   AC_LIBOBJ(getaddrinfo)
 902 fi
 903
 904 # similarly, use system's getopt_long() only if system provides struct option.
 905 if test x"$ac_cv_type_struct_option" = xyes ; then
 906   AC_REPLACE_FUNCS([getopt_long])
 907 else
 908   AC_LIBOBJ(getopt_long)
 909 fi
 910
 911 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 912 # We override the previous test that said fseeko/ftello didn't exist
 913 # OS tests are also done in include/c.h and port/fseeko.c
 914 case $host_os in bsdi*|netbsd*)
 915 ac_cv_func_fseeko=yes
 916 esac
 917
 918 # Solaris has a very slow qsort in certain cases, so we replace it.
 919 case $host_os in solaris*)
 920 AC_LIBOBJ(qsort) ;;
 921 esac
 922
 923 # Win32 can't to rename or unlink on an open file
 924 case $host_os in mingw*)
 925 AC_LIBOBJ(dirmod)
 926 AC_LIBOBJ(copydir)
 927 AC_LIBOBJ(gettimeofday)
 928 AC_LIBOBJ(pipe) ;;
 929 esac
 930
 931 if test "$with_readline" = yes; then
 932   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 933   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 934   AC_CHECK_FUNCS([replace_history_entry])
 935 fi
 936
 937
 938 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 939 AC_MSG_CHECKING(for finite)
 940 AC_TRY_LINK([#include <math.h>],
 941             [int dummy=finite(1.0);],
 942             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 943 AC_MSG_RESULT(yes)],
 944             [AC_MSG_RESULT(no)])
 945
 946 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 947 dnl (especially on GNU libc)
 948 dnl See also comments in c.h.
 949 AC_MSG_CHECKING(for sigsetjmp)
 950 AC_TRY_LINK([#include <setjmp.h>],
 951             [sigjmp_buf x; sigsetjmp(x, 1);],
 952             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 953 AC_MSG_RESULT(yes)],
 954             [AC_MSG_RESULT(no)])
 955
 956 AC_CHECK_FUNC(syslog,
 957               [AC_CHECK_HEADER(syslog.h,
 958                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 959
 960 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 961 [AC_TRY_LINK([#include <unistd.h>],
 962   [extern int optreset; optreset = 1;],
 963   [pgac_cv_var_int_optreset=yes],
 964   [pgac_cv_var_int_optreset=no])])
 965 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 966   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 967 fi
 968
 969 AC_CHECK_FUNCS([strtoll strtoq], [break])
 970 AC_CHECK_FUNCS([strtoull strtouq], [break])
 971
 972 # Check for one of atexit() or on_exit()
 973 AC_CHECK_FUNCS(atexit, [],
 974                [AC_CHECK_FUNCS(on_exit, [],
 975                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 976
 977 AC_FUNC_FSEEKO
 978
 979 #
 980 # Pthreads
 981 #
 982 # For each platform, we need to know about any special compile and link
 983 # libraries, and whether the normal C function names are thread-safe.
 984 # See the comment at the top of src/port/thread.c for more information.
 985 #
 986 if test "$enable_thread_safety" = yes; then
 987 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safetys])])
 988
 989 if test "$THREAD_SUPPORT" != yes; then
 990 AC_MSG_ERROR([
 991 Cannot enable threads on your platform.
 992 Please report your platform threading info to the PostgreSQL mailing lists
 993 so it can be added to the next release.  Report all compile flags, link flags,
 994 functions, or libraries required for threading support.
 995 See the comment at the top of src/port/thread.c for more information.
 996 ])
 997 fi
 998 else
 999 # do not use values from template file
1000 THREAD_CPPFLAGS=
1001 THREAD_LIBS=
1002 fi
1003 AC_SUBST(THREAD_SUPPORT)
1004 AC_SUBST(THREAD_CPPFLAGS)
1005 AC_SUBST(THREAD_LIBS)
1006
1007
1008 #
1009 # Check for re-entrant versions of certain functions
1010 #
1011 # Include special flags if threads are enabled _and_ if required for
1012 # threading on this platform.  Some platforms have *_r functions but
1013 # their natively named funcs are threadsafe, and should be used instead.
1014 #
1015 # One trick here is that if we don't call AC_CHECK_FUNCS, the
1016 # functions are marked "not found", which is perfect.
1017 #
1018 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNCS" = yes ; then
1019 _CFLAGS="$CFLAGS"
1020 _LIBS="$LIBS"
1021 CFLAGS="$CFLAGS $THREAD_CPPFLAGS"
1022 LIBS="$LIBS $THREAD_LIBS"
1023 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1024 CFLAGS="$_CFLAGS"
1025 LIBS="$_LIBS"
1026 fi
1027
1028
1029 # This test makes sure that run tests work at all.  Sometimes a shared
1030 # library is found by the linker, but the runtime linker can't find it.
1031 # This check should come after all modifications of compiler or linker
1032 # variables, and before any other run tests.
1033 AC_MSG_CHECKING([test program])
1034 AC_TRY_RUN([int main() { return 0; }],
1035 [AC_MSG_RESULT(ok)],
1036 [AC_MSG_RESULT(failed)
1037 AC_MSG_ERROR([[
1038 *** Could not execute a simple test program.  This may be a problem
1039 *** related to locating shared libraries.  Check the file 'config.log'
1040 *** for the exact reason.]])],
1041 [AC_MSG_RESULT([cross-compiling])])
1042
1043
1044 dnl Check to see if we have a working 64-bit integer type.
1045 dnl This breaks down into two steps:
1046 dnl (1) figure out if the compiler has a 64-bit int type with working
1047 dnl arithmetic, and if so
1048 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1049 dnl snprintf is the only library routine we really need for int8 support.)
1050 dnl It's entirely possible to have a compiler that handles a 64-bit type
1051 dnl when the C library doesn't; this is fairly likely when using gcc on
1052 dnl an older platform, for example.
1053 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1054 dnl we force our own version of snprintf() to be used instead.
1055 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1056
1057 PGAC_TYPE_64BIT_INT([long int])
1058
1059 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1060   PGAC_TYPE_64BIT_INT([long long int])
1061 fi
1062
1063
1064 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1065
1066 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1067   AC_TRY_COMPILE([
1068 #define INT64CONST(x)  x##LL
1069 long long int foo = INT64CONST(0x1234567890123456);
1070 ],
1071         [],
1072         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1073         [])
1074 fi
1075
1076
1077 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1078 # we found we need to use "long long int", better check.  We cope with
1079 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1080 # neither works, fall back to our own snprintf emulation (which we
1081 # know uses %lld).
1082
1083 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1084   if test $pgac_need_repl_snprintf = no; then
1085     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1086     if test "$LONG_LONG_INT_FORMAT" = ""; then
1087       # Force usage of our own snprintf, since system snprintf is broken
1088       pgac_need_repl_snprintf=yes
1089       LONG_LONG_INT_FORMAT='%lld'
1090     fi
1091   else
1092     # Here if we previously decided we needed to use our own snprintf
1093     LONG_LONG_INT_FORMAT='%lld'
1094   fi
1095   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1096 else
1097   # Here if we are not using 'long long int' at all
1098   INT64_FORMAT='"%ld"'
1099 fi
1100
1101 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1102                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1103
1104 if test $pgac_need_repl_snprintf = yes; then
1105   AC_LIBOBJ(snprintf)
1106 fi
1107
1108 # Need a #define for the size of Datum (unsigned long)
1109 AC_CHECK_SIZEOF([unsigned long])
1110
1111 # Determine memory alignment requirements for the basic C data types.
1112
1113 PGAC_CHECK_ALIGNOF(short)
1114 PGAC_CHECK_ALIGNOF(int)
1115 PGAC_CHECK_ALIGNOF(long)
1116 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1117   PGAC_CHECK_ALIGNOF(long long int)
1118 fi
1119 PGAC_CHECK_ALIGNOF(double)
1120
1121 # Compute maximum alignment of any basic type.
1122 # We assume long's alignment is at least as strong as char, short, or int;
1123 # but we must check long long (if it exists) and double.
1124
1125 MAX_ALIGNOF=$pgac_cv_alignof_long
1126 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1127   MAX_ALIGNOF=$pgac_cv_alignof_double
1128 fi
1129 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1130   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1131 fi
1132 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1133
1134
1135 # Some platforms predefine the types int8, int16, etc.  Only check
1136 # a (hopefully) representative subset.
1137 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1138 [#include <stdio.h>
1139 #ifdef HAVE_SUPPORTDEFS_H
1140 #include <SupportDefs.h>
1141 #endif])
1142
1143 # We also check for sig_atomic_t, which *should* be defined per ANSI
1144 # C, but is missing on some old platforms.
1145 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1146
1147
1148 PGAC_FUNC_POSIX_SIGNALS
1149 if test $ac_cv_func_fseeko = yes; then
1150 AC_SYS_LARGEFILE
1151 fi
1152
1153
1154 # Select semaphore implementation type.
1155 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1156   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1157   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1158 else
1159   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1160     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1161     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1162   else
1163     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1164     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1165   fi
1166 fi
1167
1168
1169 # Select shared-memory implementation type.
1170 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1171 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1172
1173
1174 if test "$enable_nls" = yes ; then
1175   PGAC_CHECK_GETTEXT
1176 fi
1177
1178 # Check for Tcl configuration script tclConfig.sh
1179 if test "$with_tcl" = yes; then
1180     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1181     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1182                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1183     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1184 fi
1185
1186 # Check for Tk configuration script tkConfig.sh
1187 if test "$with_tk" = yes; then
1188     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1189     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1190 fi
1191
1192
1193 #
1194 # Check for DocBook and tools
1195 #
1196 PGAC_PROG_NSGMLS
1197 PGAC_PROG_JADE
1198 PGAC_CHECK_DOCBOOK(4.2)
1199 PGAC_PATH_DOCBOOK_STYLESHEETS
1200 PGAC_PATH_COLLATEINDEX
1201 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1202
1203
1204 # prepare build tree if outside source tree
1205 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1206 # Note 2: /bin/pwd might be better than shell's built-in at getting
1207 #         a symlink-free name.
1208 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1209   vpath_build=no
1210 else
1211   vpath_build=yes
1212   if test "$no_create" != yes; then
1213     _AS_ECHO_N([preparing build tree... ])
1214     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1215     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1216       || AC_MSG_ERROR(failed)
1217     AC_MSG_RESULT(done)
1218   fi
1219 fi
1220 AC_SUBST(vpath_build)
1221
1222
1223 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1224
1225 AC_CONFIG_LINKS([
1226   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1227   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1228   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1229   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1230   src/include/pg_config_os.h:src/include/port/${template}.h
1231   src/Makefile.port:src/makefiles/Makefile.${template}
1232 ])
1233
1234 AC_CONFIG_HEADERS([src/include/pg_config.h],
1235 [
1236 # Update timestamp for pg_config.h (see Makefile.global)
1237 echo >src/include/stamp-h
1238 ])
1239
1240 AC_OUTPUT