granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.252 2003/05/16 01:57:51 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55   # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   *-*-hpux*)        need_tas=yes; tas_file=hpux.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 # Character set recode (--enable-recode)
 157 #
 158 AC_MSG_CHECKING([whether to build with recode support])
 159 PGAC_ARG_BOOL(enable, recode, no, [  --enable-recode         enable single-byte recode support],
 160               [AC_DEFINE([CYR_RECODE], 1,
 161                          [Define to 1 if you want single-byte recode support. (--enable-recode)])])
 162 AC_MSG_RESULT([$enable_recode])
 163
 164
 165 #
 166 # NLS
 167 #
 168 AC_MSG_CHECKING([whether NLS is wanted])
 169 PGAC_ARG_OPTARG(enable, nls,
 170                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 171                 [],
 172                 [WANTED_LANGUAGES=$enableval],
 173                 [AC_DEFINE(ENABLE_NLS, 1,
 174                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 175 AC_MSG_RESULT([$enable_nls])
 176 AC_SUBST(enable_nls)
 177 AC_SUBST(WANTED_LANGUAGES)
 178
 179 #
 180 # Default port number (--with-pgport), default 5432
 181 #
 182 AC_MSG_CHECKING([for default port number])
 183 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 184              [default_port=$withval],
 185              [default_port=5432])
 186 AC_MSG_RESULT([$default_port])
 187 # Need both of these because some places want an integer and some a string
 188 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 189 [Define to the default TCP port number on which the server listens and
 190 to which clients will try to connect to.  This can be overridden at
 191 run-time, but it's convenient if your clients have the right default
 192 compiled in.  (--with-pgport=PORTNUM)])
 193 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 194                    [Define to the default TCP port number as string constant.])
 195 AC_SUBST(default_port)
 196
 197 #
 198 # Option to disable shared libraries
 199 #
 200 PGAC_ARG_BOOL(enable, shared, yes,
 201               [  --disable-shared        do not build shared libraries])
 202 AC_SUBST(enable_shared)
 203
 204 #
 205 # '-rpath'-like feature can be disabled
 206 #
 207 PGAC_ARG_BOOL(enable, rpath, yes,
 208               [  --disable-rpath         do not embed shared library search path in executables])
 209 AC_SUBST(enable_rpath)
 210
 211
 212 #
 213 # --enable-debug adds -g to compiler flags
 214 #
 215 PGAC_ARG_BOOL(enable, debug, no,
 216               [  --enable-debug          build with debugging symbols (-g)])
 217 AC_SUBST(enable_debug)
 218
 219 #
 220 # C compiler
 221 #
 222
 223 # For historical reasons you can also use --with-CC to specify the C compiler
 224 # to use, although the standard way to do this is to set the CC environment
 225 # variable.
 226 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 227
 228 case $template in
 229   aix) pgac_cc_list="gcc xlc";;
 230  irix) pgac_cc_list="cc";; # no gcc
 231     *) pgac_cc_list="gcc cc";;
 232 esac
 233
 234 AC_PROG_CC([$pgac_cc_list])
 235 # Read the template
 236 . "$srcdir/src/template/$template" || exit
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 fi
 241 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 242   CFLAGS="$CFLAGS -g"
 243 fi
 244 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 245
 246 # Check if the compiler still works with the template settings
 247 AC_MSG_CHECKING([whether the C compiler still works])
 248 AC_TRY_LINK([], [return 0;],
 249   [AC_MSG_RESULT(yes)],
 250   [AC_MSG_RESULT(no)
 251    AC_MSG_ERROR([cannot proceed])])
 252
 253 # Defend against gcc -ffastmath
 254 if test "$GCC" = yes; then
 255 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 256 choke me
 257 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 258 fi
 259
 260 AC_PROG_CPP
 261 AC_SUBST(GCC)
 262
 263 # Create compiler version string
 264 if test x"$GCC" = x"yes" ; then
 265   cc_string="GCC `${CC} --version | sed q`"
 266 else
 267   cc_string=$CC
 268 fi
 269 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 270                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 271                    [A string containing the version number, platform, and C compiler])
 272
 273
 274 #
 275 # Automatic dependency tracking
 276 #
 277 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 278               [autodepend=yes])
 279 AC_SUBST(autodepend)
 280
 281
 282 #
 283 # Enable assert checks
 284 #
 285 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 286               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 287                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 288
 289
 290 #
 291 # Include directories
 292 #
 293 ac_save_IFS=$IFS
 294 IFS="${IFS}:"
 295 # SRCH_INC comes from the template file
 296 for dir in $with_includes $SRCH_INC; do
 297   if test -d "$dir"; then
 298     INCLUDES="$INCLUDES -I$dir"
 299   else
 300     AC_MSG_WARN([*** Include directory $dir does not exist.])
 301   fi
 302 done
 303 IFS=$ac_save_IFS
 304 AC_SUBST(INCLUDES)
 305
 306
 307 #
 308 # Library directories
 309 #
 310 ac_save_IFS=$IFS
 311 IFS="${IFS}:"
 312 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 313 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 314   if test -d "$dir"; then
 315     LIBDIRS="$LIBDIRS -L$dir"
 316   else
 317     AC_MSG_WARN([*** Library directory $dir does not exist.])
 318   fi
 319 done
 320 IFS=$ac_save_IFS
 321
 322 #
 323 # Tcl/Tk
 324 #
 325 AC_MSG_CHECKING([whether to build with Tcl])
 326 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 327 AC_MSG_RESULT([$with_tcl])
 328 AC_SUBST([with_tcl])
 329
 330 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 331 AC_MSG_CHECKING([whether to build with Tk])
 332 if test "$with_tcl" = yes; then
 333   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 334 else
 335   with_tk=no
 336 fi
 337 AC_MSG_RESULT([$with_tk])
 338 AC_SUBST([with_tk])
 339
 340
 341 # We see if the path to the Tcl/Tk configuration scripts is specified.
 342 # This will override the use of tclsh to find the paths to search.
 343
 344 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 345
 346 # We see if the path to the Tk configuration scripts is specified.
 347 # This will override the use of tclsh to find the paths to search.
 348
 349 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 350
 351 #
 352 # Optionally build Perl modules (PL/Perl)
 353 #
 354 AC_MSG_CHECKING([whether to build Perl modules])
 355 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 356 AC_MSG_RESULT([$with_perl])
 357 AC_SUBST(with_perl)
 358
 359 #
 360 # Optionally build Python interface module
 361 #
 362 AC_MSG_CHECKING([whether to build Python modules])
 363 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 364 AC_MSG_RESULT([$with_python])
 365 AC_SUBST(with_python)
 366
 367 #
 368 # Optionally build the Java/JDBC tools
 369 #
 370 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 371 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 372 [AC_MSG_RESULT(yes)
 373 PGAC_PATH_ANT
 374 if test -z "$ANT"; then
 375   AC_MSG_ERROR([Ant is required to build Java components
 376 If you have Ant already installed, see config.log for details on the failure.])
 377 fi
 378 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 379   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 380 fi],
 381 [AC_MSG_RESULT(no)])
 382 AC_SUBST(with_java)
 383
 384 dnl A note on the Kerberos and OpenSSL options:
 385 dnl
 386 dnl The user can give an argument to the option in order the specify
 387 dnl the base path of the respective installation (what he specified
 388 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 389 dnl then we take the path where the package installs by default. This
 390 dnl way the user doesn't have to use redundant --with-includes and
 391 dnl --with-libraries options, but he can still use them if the layout
 392 dnl is non-standard.
 393
 394 #
 395 # Kerberos 4
 396 #
 397 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 398 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 399                 [krb4_prefix=/usr/athena],
 400                 [krb4_prefix=$withval],
 401 [
 402   AC_MSG_RESULT(yes)
 403   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 404
 405   if test -d "$krb4_prefix/include"; then
 406     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 407   fi
 408   if test -d "$krb4_prefix/lib"; then
 409     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 410   fi
 411
 412   krb_srvtab="/etc/srvtab"
 413 ],
 414 [AC_MSG_RESULT(no)])
 415
 416 AC_SUBST(with_krb4)
 417
 418
 419 #
 420 # Kerberos 5
 421 #
 422 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 423 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 424               [krb5_prefix=/usr/athena],
 425               [krb5_prefix=$withval],
 426 [
 427   AC_MSG_RESULT([yes])
 428   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 429
 430   if test -d "$krb5_prefix/include"; then
 431     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 432   fi
 433   if test -d "$krb5_prefix/lib"; then
 434     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 435   fi
 436
 437   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 438 ],
 439 [AC_MSG_RESULT(no)])
 440
 441 AC_SUBST(with_krb5)
 442
 443
 444 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 445 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 446   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 447 fi
 448
 449 AC_SUBST(krb_srvtab)
 450
 451
 452 #
 453 # Kerberos configuration parameters
 454 #
 455 PGAC_ARG_REQ(with, krb-srvnam,
 456              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 457              [],
 458              [with_krb_srvnam="postgres"])
 459 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 460                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 461
 462
 463 #
 464 # PAM
 465 #
 466 AC_MSG_CHECKING([whether to build with PAM support])
 467 PGAC_ARG_BOOL(with, pam, no,
 468               [  --with-pam              build with PAM support],
 469               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 470 AC_MSG_RESULT([$with_pam])
 471 AC_SUBST(with_pam)
 472
 473
 474 #
 475 # OpenSSL
 476 #
 477 PGAC_ARG_OPTARG(with, openssl,
 478                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 479                 [openssl_prefix=/usr/local/ssl],
 480                 [openssl_prefix=$withval],
 481 [
 482   AC_MSG_RESULT([building with OpenSSL support])
 483   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 484
 485   if test -d "${openssl_prefix}/include" ; then
 486     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 487   fi
 488   if test -d "${openssl_prefix}/lib" ; then
 489     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 490   fi
 491 ])
 492
 493 AC_SUBST(with_openssl)
 494
 495
 496 #
 497 # Readline
 498 #
 499 PGAC_ARG_BOOL(with, readline, yes,
 500               [  --without-readline      do not use Readline])
 501
 502 #
 503 # Zlib
 504 #
 505 PGAC_ARG_BOOL(with, zlib, yes,
 506               [  --without-zlib          do not use Zlib])
 507
 508
 509
 510 # Assume system is ELF if it predefines __ELF__ as 1,
 511 # otherwise believe host_os based default.
 512 case $host_os in
 513     freebsd1*|freebsd2*) elf=no;;
 514     freebsd3*|freebsd4*) elf=yes;;
 515 esac
 516
 517 AC_EGREP_CPP(yes,
 518 [#if __ELF__
 519   yes
 520 #endif
 521 ],
 522 [ELF_SYS=true],
 523 [if test "X$elf" = "Xyes" ; then
 524   ELF_SYS=true
 525 else
 526   ELF_SYS=
 527 fi])
 528 AC_SUBST(ELF_SYS)
 529
 530
 531
 532 CPPFLAGS="$CPPFLAGS $INCLUDES"
 533 LDFLAGS="$LDFLAGS $LIBDIRS"
 534
 535 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 536 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 537
 538
 539 AC_PROG_AWK
 540 PGAC_PATH_FLEX
 541 AC_PROG_LN_S
 542 AC_PROG_LD
 543 AC_SUBST(LD)
 544 AC_SUBST(with_gnu_ld)
 545 case $host_os in sysv5*)
 546   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 547   [
 548     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 549     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 550     LDFLAGS=$pgac_save_LDFLAGS
 551   ])
 552   ld_R_works=$pgac_cv_prog_ld_R
 553   AC_SUBST(ld_R_works)
 554 esac
 555 AC_PROG_RANLIB
 556 AC_CHECK_PROGS(LORDER, lorder)
 557 AC_PATH_PROG(TAR, tar)
 558 PGAC_CHECK_STRIP
 559
 560 AC_CHECK_PROGS(YACC, ['bison -y'])
 561 if test -z "$YACC"; then
 562   AC_MSG_WARN([
 563 *** Without Bison you will not be able to build PostgreSQL from CVS or
 564 *** change any of the parser definition files.  You can obtain Bison from
 565 *** a GNU mirror site.  (If you are using the official distribution of
 566 *** PostgreSQL then you do not need to worry about this because the Bison
 567 *** output is pre-generated.)  To use a different yacc program (possible,
 568 *** but not recommended), set the environment variable YACC before running
 569 *** 'configure'.])
 570 fi
 571 AC_SUBST(YFLAGS)
 572
 573 PGAC_PATH_PERL
 574 if test "$with_perl" = yes; then
 575   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 576   PGAC_CHECK_PERL_EMBED_LDFLAGS
 577 fi
 578
 579 if test "$with_python" = yes; then
 580   PGAC_PATH_PYTHON
 581   PGAC_CHECK_PYTHON_MODULE_SETUP
 582   PGAC_CHECK_PYTHON_EMBED_SETUP
 583 fi
 584
 585
 586 ##
 587 ## Libraries
 588 ##
 589
 590 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 591 then
 592         AC_CHECK_LIB(bsd,      main)
 593 fi
 594 AC_CHECK_LIB(util,     setproctitle)
 595 AC_CHECK_LIB(m,        main)
 596 AC_CHECK_LIB(dl,       main)
 597 AC_CHECK_LIB(nsl,      main)
 598 AC_CHECK_LIB(socket,   main)
 599 AC_CHECK_LIB(ipc,      main)
 600 AC_CHECK_LIB(IPC,      main)
 601 AC_CHECK_LIB(lc,       main)
 602 AC_CHECK_LIB(dld,      main)
 603 AC_CHECK_LIB(ld,       main)
 604 AC_CHECK_LIB(compat,   main)
 605 AC_CHECK_LIB(BSD,      main)
 606 AC_CHECK_LIB(gen,      main)
 607 AC_CHECK_LIB(PW,       main)
 608 AC_CHECK_LIB(resolv,   main)
 609 AC_CHECK_LIB(wsock32,   main)
 610 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 611 # QNX:
 612 AC_CHECK_LIB(unix, main)
 613 AC_SEARCH_LIBS(crypt,  crypt)
 614 # BeOS:
 615 AC_CHECK_LIB(bind, __inet_ntoa)
 616 # Solaris:
 617 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 618 # Cygwin:
 619 AC_CHECK_LIB(cygipc, shmget)
 620
 621 if test "$with_readline" = yes; then
 622   PGAC_CHECK_READLINE
 623   if test x"$pgac_cv_check_readline" = x"no"; then
 624     AC_MSG_ERROR([readline library not found
 625 If you have readline already installed, see config.log for details on the
 626 failure.  It is possible the compiler isn't looking in the proper directory.
 627 Use --without-readline to disable readline support.])
 628   fi
 629 fi
 630
 631 if test "$with_zlib" = yes; then
 632   AC_CHECK_LIB(z, inflate, [],
 633                [AC_MSG_ERROR([zlib library not found
 634 If you have zlib already installed, see config.log for details on the
 635 failure.  It is possible the compiler isn't looking in the proper directory.
 636 Use --without-zlib to disable zlib support.])])
 637 fi
 638
 639 if test "$with_krb4" = yes ; then
 640   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 641   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 642   AC_REPLACE_FUNCS([gethostname])
 643 fi
 644
 645 if test "$with_krb5" = yes ; then
 646   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 647                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 648   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 649                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 650   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 651                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 652 fi
 653
 654 if test "$with_openssl" = yes ; then
 655   dnl Order matters!
 656   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 657   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 658 fi
 659
 660 if test "$with_pam" = yes ; then
 661   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 662 fi
 663
 664
 665 ##
 666 ## Header files
 667 ##
 668
 669 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 670 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 671
 672 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 673 # netinet/in.h is included first.
 674 AC_CHECK_HEADERS(netinet/in.h)
 675 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 676 [AC_INCLUDES_DEFAULT
 677 #ifdef HAVE_NETINET_IN_H
 678 #include <netinet/in.h>
 679 #endif
 680 ])
 681
 682 if test "$with_readline" = yes; then
 683   AC_CHECK_HEADERS(readline/readline.h, [],
 684                    [AC_CHECK_HEADERS(editline/readline.h, [],
 685                          [AC_CHECK_HEADERS(readline.h, [],
 686                                      [AC_MSG_ERROR([readline header not found
 687 If you have readline already installed, see config.log for details on the
 688 failure.  It is possible the compiler isn't looking in the proper directory.
 689 Use --without-readline to disable readline support.])])])])
 690   AC_CHECK_HEADERS(readline/history.h, [],
 691                    [AC_CHECK_HEADERS(editline/history.h, [],
 692                          [AC_CHECK_HEADERS(history.h, [],
 693                                      [AC_MSG_ERROR([history header not found
 694 If you have readline already installed, see config.log for details on the
 695 failure.  It is possible the compiler isn't looking in the proper directory.
 696 Use --without-readline to disable readline support.])])])])
 697 fi
 698
 699 if test "$with_zlib" = yes; then
 700   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 701 If you have zlib already installed, see config.log for details on the
 702 failure.  It is possible the compiler isn't looking in the proper directory.
 703 Use --without-zlib to disable zlib support.])])
 704 fi
 705
 706 if test "$with_krb4" = yes ; then
 707   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 708 fi
 709
 710 if test "$with_krb5" = yes ; then
 711   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 712   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 713 fi
 714
 715 if test "$with_openssl" = yes ; then
 716   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 717   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 718 fi
 719
 720 if test "$with_pam" = yes ; then
 721   AC_CHECK_HEADERS(security/pam_appl.h, [],
 722                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 723                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 724 fi
 725
 726
 727 ##
 728 ## Types, structures, compiler characteristics
 729 ##
 730
 731 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 732 AC_C_CONST
 733 AC_C_INLINE
 734 AC_C_STRINGIZE
 735 PGAC_C_SIGNED
 736 AC_C_VOLATILE
 737 PGAC_C_FUNCNAME_SUPPORT
 738 AC_STRUCT_TIMEZONE
 739 PGAC_UNION_SEMUN
 740 PGAC_STRUCT_SOCKADDR_UN
 741 PGAC_STRUCT_ADDRINFO
 742
 743 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 744 [#include <sys/param.h>
 745 #include <sys/socket.h>
 746 #include <sys/ucred.h>])
 747
 748 if test "$with_zlib" = yes; then
 749   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 750   # did not).  While we could work around the lack of z_streamp, it
 751   # seems unwise to encourage people to use such old zlib versions...
 752   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 753 Use --without-zlib to disable zlib support.])],
 754                 [#include <zlib.h>])
 755 fi
 756
 757 if test "$with_krb5" = yes; then
 758 # Check for differences between MIT and Heimdal (KTH) releases
 759   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 760                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 761                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 762                                      [#include <krb5.h>])],
 763                    [#include <krb5.h>])
 764   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 765                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 766                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 767                                      [#include <krb5.h>])],
 768                    [#include <krb5.h>])
 769 fi
 770
 771
 772 ##
 773 ## Functions, global variables
 774 ##
 775
 776 PGAC_VAR_INT_TIMEZONE
 777 AC_FUNC_ACCEPT_ARGTYPES
 778 PGAC_FUNC_GETTIMEOFDAY_1ARG
 779
 780 # SunOS doesn't handle negative byte comparisons properly with +/- return
 781 AC_FUNC_MEMCMP
 782
 783 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 784
 785 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 786
 787 AC_CHECK_TYPE([struct sockaddr_in6],
 788               [AC_CHECK_FUNC(inet_ntop,
 789                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])])],
 790               [],
 791 [$ac_includes_default
 792 #include <netinet/in.h>])
 793
 794 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 795 [AC_TRY_LINK(
 796 [#include <machine/vmparam.h>
 797 #include <sys/exec.h>
 798 ],
 799 [PS_STRINGS->ps_nargvstr = 1;
 800 PS_STRINGS->ps_argvstr = "foo";],
 801 [pgac_cv_var_PS_STRINGS=yes],
 802 [pgac_cv_var_PS_STRINGS=no])])
 803 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 804   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 805 fi
 806
 807
 808 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 809 # is missing.  Yes, there are machines that have only one.  We may
 810 # also decide to use snprintf.c if snprintf() is present but does not
 811 # have working "long long int" support -- see below.
 812
 813 pgac_need_repl_snprintf=no
 814 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 815 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 816
 817
 818 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 819 # include/c.h will provide declarations.  Note this is a separate test
 820 # from whether the functions exist in the C library --- there are
 821 # systems that have the functions but don't bother to declare them :-(
 822
 823 AC_CHECK_DECLS([snprintf, vsnprintf])
 824
 825
 826 # do this one the hard way in case isinf() is a macro
 827 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 828 [AC_TRY_LINK(
 829 [#include <math.h>
 830 ],
 831 [double x = 0.0; int res = isinf(x);],
 832 [ac_cv_func_isinf=yes],
 833 [ac_cv_func_isinf=no])])
 834
 835 if test $ac_cv_func_isinf = yes ; then
 836   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 837 else
 838   AC_LIBOBJ(isinf)
 839   # Look for a way to implement a substitute for isinf()
 840   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 841 fi
 842
 843 AC_REPLACE_FUNCS([crypt fseeko getopt getopt_long getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 844
 845 # system's version of getaddrinfo(), if any, may be used only if we found
 846 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 847 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 848   AC_REPLACE_FUNCS([getaddrinfo])
 849 else
 850   AC_LIBOBJ(getaddrinfo)
 851 fi
 852
 853 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 854 # We override the previous test that said fseeko/ftello didn't exist
 855 # OS tests are also done in include/c.h and port/fseeko.c
 856 case $host_os in bsdi*|netbsd*)
 857 ac_cv_func_fseeko=yes
 858 esac
 859
 860 # Solaris has a very slow qsort in certain cases, so we replace it.
 861 case $host_os in solaris*)
 862 AC_LIBOBJ(qsort) ;;
 863 esac
 864
 865 # Win32 can't to rename or unlink on an open file
 866 case $host_os in mingw*)
 867 AC_LIBOBJ(dirmod)
 868 AC_LIBOBJ(copydir)
 869 AC_LIBOBJ(gettimeofday) ;;
 870 esac
 871
 872 if test "$with_readline" = yes; then
 873   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 874   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 875   AC_CHECK_FUNCS([replace_history_entry])
 876 fi
 877
 878
 879 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 880 AC_MSG_CHECKING(for finite)
 881 AC_TRY_LINK([#include <math.h>],
 882             [int dummy=finite(1.0);],
 883             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 884 AC_MSG_RESULT(yes)],
 885             [AC_MSG_RESULT(no)])
 886
 887 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 888 dnl (especially on GNU libc)
 889 dnl See also comments in c.h.
 890 AC_MSG_CHECKING(for sigsetjmp)
 891 AC_TRY_LINK([#include <setjmp.h>],
 892             [sigjmp_buf x; sigsetjmp(x, 1);],
 893             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 894 AC_MSG_RESULT(yes)],
 895             [AC_MSG_RESULT(no)])
 896
 897 AC_CHECK_FUNC(syslog,
 898               [AC_CHECK_HEADER(syslog.h,
 899                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 900
 901 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 902 [AC_TRY_LINK([#include <unistd.h>],
 903   [extern int optreset; optreset = 1;],
 904   [pgac_cv_var_int_optreset=yes],
 905   [pgac_cv_var_int_optreset=no])])
 906 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 907   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 908 fi
 909
 910 AC_CHECK_FUNCS([strtoll strtoq], [break])
 911 AC_CHECK_FUNCS([strtoull strtouq], [break])
 912
 913 # Check for one of atexit() or on_exit()
 914 AC_CHECK_FUNCS(atexit, [],
 915                [AC_CHECK_FUNCS(on_exit, [],
 916                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 917
 918 AC_FUNC_FSEEKO
 919
 920
 921 # This test makes sure that run tests work at all.  Sometimes a shared
 922 # library is found by the linker, but the runtime linker can't find it.
 923 # This check should come after all modifications of compiler or linker
 924 # variables, and before any other run tests.
 925 AC_MSG_CHECKING([test program])
 926 AC_TRY_RUN([int main() { return 0; }],
 927 [AC_MSG_RESULT(ok)],
 928 [AC_MSG_RESULT(failed)
 929 AC_MSG_ERROR([[
 930 *** Could not execute a simple test program.  This may be a problem
 931 *** related to locating shared libraries.  Check the file 'config.log'
 932 *** for the exact reason.]])],
 933 [AC_MSG_RESULT([cross-compiling])])
 934
 935
 936 dnl Check to see if we have a working 64-bit integer type.
 937 dnl This breaks down into two steps:
 938 dnl (1) figure out if the compiler has a 64-bit int type with working
 939 dnl arithmetic, and if so
 940 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
 941 dnl snprintf is the only library routine we really need for int8 support.)
 942 dnl It's entirely possible to have a compiler that handles a 64-bit type
 943 dnl when the C library doesn't; this is fairly likely when using gcc on
 944 dnl an older platform, for example.
 945 dnl If there is no native snprintf() or it does not handle the 64-bit type,
 946 dnl we force our own version of snprintf() to be used instead.
 947 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
 948
 949 PGAC_TYPE_64BIT_INT([long int])
 950
 951 if test x"$HAVE_LONG_INT_64" = x"no" ; then
 952   PGAC_TYPE_64BIT_INT([long long int])
 953 fi
 954
 955
 956 dnl If we need to use "long long int", figure out whether nnnLL notation works.
 957
 958 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
 959   AC_TRY_COMPILE([
 960 #define INT64CONST(x)  x##LL
 961 long long int foo = INT64CONST(0x1234567890123456);
 962 ],
 963         [],
 964         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
 965         [])
 966 fi
 967
 968
 969 # If we found "long int" is 64 bits, assume snprintf handles it.  If
 970 # we found we need to use "long long int", better check.  We cope with
 971 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
 972 # neither works, fall back to our own snprintf emulation (which we
 973 # know uses %lld).
 974
 975 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
 976   if test $pgac_need_repl_snprintf = no; then
 977     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
 978     if test "$LONG_LONG_INT_FORMAT" = ""; then
 979       # Force usage of our own snprintf, since system snprintf is broken
 980       pgac_need_repl_snprintf=yes
 981       LONG_LONG_INT_FORMAT='%lld'
 982     fi
 983   else
 984     # Here if we previously decided we needed to use our own snprintf
 985     LONG_LONG_INT_FORMAT='%lld'
 986   fi
 987   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
 988 else
 989   # Here if we are not using 'long long int' at all
 990   INT64_FORMAT='"%ld"'
 991 fi
 992
 993 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
 994                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
 995
 996 if test $pgac_need_repl_snprintf = yes; then
 997   AC_LIBOBJ(snprintf)
 998 fi
 999
1000 # Need a #define for the size of Datum (unsigned long)
1001 AC_CHECK_SIZEOF([unsigned long])
1002
1003 # Determine memory alignment requirements for the basic C data types.
1004
1005 PGAC_CHECK_ALIGNOF(short)
1006 PGAC_CHECK_ALIGNOF(int)
1007 PGAC_CHECK_ALIGNOF(long)
1008 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1009   PGAC_CHECK_ALIGNOF(long long int)
1010 fi
1011 PGAC_CHECK_ALIGNOF(double)
1012
1013 # Compute maximum alignment of any basic type.
1014 # We assume long's alignment is at least as strong as char, short, or int;
1015 # but we must check long long (if it exists) and double.
1016
1017 MAX_ALIGNOF=$pgac_cv_alignof_long
1018 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1019   MAX_ALIGNOF=$pgac_cv_alignof_double
1020 fi
1021 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1022   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1023 fi
1024 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1025
1026
1027 # Some platforms predefine the types int8, int16, etc.  Only check
1028 # a (hopefully) representative subset.
1029 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1030 [#include <stdio.h>
1031 #ifdef HAVE_SUPPORTDEFS_H
1032 #include <SupportDefs.h>
1033 #endif])
1034
1035 # We also check for sig_atomic_t, which *should* be defined per ANSI
1036 # C, but is missing on some old platforms.
1037 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1038
1039
1040 PGAC_FUNC_POSIX_SIGNALS
1041 if test $ac_cv_func_fseeko = yes; then
1042 AC_SYS_LARGEFILE
1043 fi
1044
1045
1046 # Select semaphore implementation type.
1047 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1048   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1049   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1050 else
1051   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1052     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1053     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1054   else
1055     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1056     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1057   fi
1058 fi
1059
1060
1061 # Select shared-memory implementation type.
1062 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1063 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1064
1065
1066 if test "$enable_nls" = yes ; then
1067   PGAC_CHECK_GETTEXT
1068 fi
1069
1070 # Check for Tcl configuration script tclConfig.sh
1071 if test "$with_tcl" = yes; then
1072     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1073     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1074                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1075     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1076 fi
1077
1078 # Check for Tk configuration script tkConfig.sh
1079 if test "$with_tk" = yes; then
1080     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1081     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1082 fi
1083
1084
1085 #
1086 # Check for DocBook and tools
1087 #
1088 PGAC_PROG_NSGMLS
1089 PGAC_PROG_JADE
1090 PGAC_CHECK_DOCBOOK(3.1)
1091 PGAC_PATH_DOCBOOK_STYLESHEETS
1092 PGAC_PATH_COLLATEINDEX
1093 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1094
1095
1096 # prepare build tree if outside source tree
1097 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1098 # Note 2: /bin/pwd might be better than shell's built-in at getting
1099 #         a symlink-free name.
1100 if test "$no_create" != yes; then
1101   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1102     :
1103   else
1104     AC_SUBST(vpath_build, yes)
1105     _AS_ECHO_N([preparing build tree... ])
1106     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1107     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1108       || AC_MSG_ERROR(failed)
1109     AC_MSG_RESULT(done)
1110   fi
1111 fi
1112
1113
1114 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1115
1116 AC_CONFIG_LINKS([
1117   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1118   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1119   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1120   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1121   src/include/pg_config_os.h:src/include/port/${template}.h
1122   src/Makefile.port:src/makefiles/Makefile.${template}
1123 ])
1124
1125 AC_CONFIG_HEADERS([src/include/pg_config.h],
1126 [
1127 # Update timestamp for pg_config.h (see Makefile.global)
1128 echo >src/include/stamp-h
1129 ])
1130
1131 AC_OUTPUT