granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [12devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 357     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361 AC_PROG_CC_C99()
 362 AC_PROG_CXX([$pgac_cxx_list])
 363
 364 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 365 # but has idiosyncrasies of its own.  We assume icc will define
 366 # __INTEL_COMPILER regardless of CFLAGS.
 367 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 368 choke me
 369 @%:@endif])], [ICC=yes], [ICC=no])
 370
 371 # Check if it's Sun Studio compiler. We assume that
 372 # __SUNPRO_C will be defined for Sun Studio compilers
 373 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 374 choke me
 375 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 376
 377 AC_SUBST(SUN_STUDIO_CC)
 378
 379
 380 #
 381 # LLVM
 382 #
 383 # Checked early because subsequent tests depend on it.
 384 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 385               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 386 AC_SUBST(with_llvm)
 387 if test "$with_llvm" = yes ; then
 388    PGAC_LLVM_SUPPORT()
 389 fi
 390
 391
 392 unset CFLAGS
 393 unset CXXFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # C[XX]FLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O, unless debugging.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 if test "$ac_env_CXXFLAGS_set" = set; then
 423   CXXFLAGS=$ac_env_CXXFLAGS_value
 424 elif test "${CXXFLAGS+set}" = set; then
 425   : # (keep what template set)
 426 elif test "$enable_coverage" = yes; then
 427   : # no optimization by default
 428 elif test "$GCC" = yes; then
 429   CXXFLAGS="-O2"
 430 else
 431   # if the user selected debug mode, don't use -O
 432   if test "$enable_debug" != yes; then
 433     CXXFLAGS="-O"
 434   fi
 435 fi
 436
 437 # When generating bitcode (for inlining) we always want to use -O2
 438 # even when --enable-debug is specified. The bitcode it's not going to
 439 # be used for line-by-line debugging, and JIT inlining doesn't work
 440 # without at least -O1 (otherwise clang will emit 'noinline'
 441 # attributes everywhere), which is bad for testing.  Still allow the
 442 # environment to override if done explicitly.
 443 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 444   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 445 else
 446   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 447 fi
 448 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 449   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 450 else
 451   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 452 fi
 453
 454 # C[XX]FLAGS we determined above will be added back at the end
 455 user_CFLAGS=$CFLAGS
 456 CFLAGS=""
 457 user_CXXFLAGS=$CXXFLAGS
 458 CXXFLAGS=""
 459 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 460 BITCODE_CFLAGS=""
 461 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 462 BITCODE_CXXFLAGS=""
 463
 464 # set CFLAGS_VECTOR from the environment, if available
 465 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 466   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 467 fi
 468
 469 # Some versions of GCC support some additional useful warning flags.
 470 # Check whether they are supported, and add them to CFLAGS if so.
 471 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 472 # but has its own.  Also check other compiler-specific flags here.
 473
 474 if test "$GCC" = yes -a "$ICC" = no; then
 475   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 476   CXXFLAGS="-Wall -Wpointer-arith"
 477   # These work in some but not all gcc versions
 478   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 479   # -Wdeclaration-after-statement isn't applicable for C++
 480   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 481   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 482   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 483   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 484   # This was included in -Wall/-Wformat in older GCC versions
 485   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 486   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 487   # Disable strict-aliasing rules; needed for gcc 3.3+
 488   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 489   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 490   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 491   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 492   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 493   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 494   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 495   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 496   # Optimization flags for specific files that benefit from vectorization
 497   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 498   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 499   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 500   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 501   # test for the positive form and if that works, add the negative form
 502   NOT_THE_CFLAGS=""
 503   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 504   if test -n "$NOT_THE_CFLAGS"; then
 505     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 506   fi
 507   # Similarly disable useless truncation warnings from gcc 8+
 508   NOT_THE_CFLAGS=""
 509   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wformat-truncation])
 510   if test -n "$NOT_THE_CFLAGS"; then
 511     CFLAGS="$CFLAGS -Wno-format-truncation"
 512   fi
 513   NOT_THE_CFLAGS=""
 514   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wstringop-truncation])
 515   if test -n "$NOT_THE_CFLAGS"; then
 516     CFLAGS="$CFLAGS -Wno-stringop-truncation"
 517   fi
 518 elif test "$ICC" = yes; then
 519   # Intel's compiler has a bug/misoptimization in checking for
 520   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 521   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 522   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 523   # Make sure strict aliasing is off (though this is said to be the default)
 524   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 525   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 526 elif test "$PORTNAME" = "aix"; then
 527   # AIX's xlc has to have strict aliasing turned off too
 528   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 529   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 530   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 531   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 532 elif test "$PORTNAME" = "hpux"; then
 533   # On some versions of HP-UX, libm functions do not set errno by default.
 534   # Fix that by using +Olibmerrno if the compiler recognizes it.
 535   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 536   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 537 fi
 538
 539 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 540
 541 # Determine flags used to emit bitcode for JIT inlining. Need to test
 542 # for behaviour changing compiler flags, to keep compatibility with
 543 # compiler used for normal postgres code.
 544 if test "$with_llvm" = yes ; then
 545   CLANGXX="$CLANG -xc++"
 546
 547   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 548   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 549   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 550   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 551   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 552   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 553 fi
 554
 555 # supply -g if --enable-debug
 556 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 557   CFLAGS="$CFLAGS -g"
 558 fi
 559
 560 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 561   CXXFLAGS="$CXXFLAGS -g"
 562 fi
 563
 564 # enable code coverage if --enable-coverage
 565 if test "$enable_coverage" = yes; then
 566   if test "$GCC" = yes; then
 567     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 568     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 569   else
 570     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 571   fi
 572 fi
 573
 574 # enable profiling if --enable-profiling
 575 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 576   if test "$GCC" = yes; then
 577     AC_DEFINE([PROFILE_PID_DIR], 1,
 578            [Define to 1 to allow profiling output to be saved separately for each process.])
 579     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 580     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 581   else
 582     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 583   fi
 584 fi
 585
 586 # We already have this in Makefile.win32, but configure needs it too
 587 if test "$PORTNAME" = "win32"; then
 588   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 589 fi
 590
 591 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 592 # user-specified flags (if any) at the end.  This lets users override
 593 # the automatic additions.
 594 CFLAGS="$CFLAGS $user_CFLAGS"
 595 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 596 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 597 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 598
 599 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 600 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 601
 602 # Check if the compiler still works with the final flag settings
 603 # (note, we're not checking that for CXX, which is optional)
 604 AC_MSG_CHECKING([whether the C compiler still works])
 605 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 606   [AC_MSG_RESULT(yes)],
 607   [AC_MSG_RESULT(no)
 608    AC_MSG_ERROR([cannot proceed])])
 609
 610 # Defend against gcc -ffast-math
 611 if test "$GCC" = yes; then
 612 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 613 choke me
 614 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 615 fi
 616
 617 AC_PROG_CPP
 618 AC_SUBST(GCC)
 619
 620
 621 #
 622 # Set up TAS assembly code if needed; the template file has now had its
 623 # chance to request this.
 624 #
 625 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 626
 627 if test "$need_tas" = yes ; then
 628   TAS=tas.o
 629 else
 630   TAS=""
 631 fi
 632 AC_SUBST(TAS)
 633
 634
 635 #
 636 # Automatic dependency tracking
 637 #
 638 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 639               [autodepend=yes])
 640 AC_SUBST(autodepend)
 641
 642
 643 #
 644 # Enable assert checks
 645 #
 646 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 647               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 648                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 649
 650
 651 #
 652 # Include directories
 653 #
 654 ac_save_IFS=$IFS
 655 IFS="${IFS}${PATH_SEPARATOR}"
 656 # SRCH_INC comes from the template file
 657 for dir in $with_includes $SRCH_INC; do
 658   if test -d "$dir"; then
 659     INCLUDES="$INCLUDES -I$dir"
 660   else
 661     AC_MSG_WARN([*** Include directory $dir does not exist.])
 662   fi
 663 done
 664 IFS=$ac_save_IFS
 665 AC_SUBST(INCLUDES)
 666
 667
 668 #
 669 # Library directories
 670 #
 671 ac_save_IFS=$IFS
 672 IFS="${IFS}${PATH_SEPARATOR}"
 673 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 674 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 675   if test -d "$dir"; then
 676     LIBDIRS="$LIBDIRS -L$dir"
 677   else
 678     AC_MSG_WARN([*** Library directory $dir does not exist.])
 679   fi
 680 done
 681 IFS=$ac_save_IFS
 682
 683 #
 684 # Enable thread-safe client libraries
 685 #
 686 AC_MSG_CHECKING([allow thread-safe client libraries])
 687 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 688 if test "$enable_thread_safety" = yes; then
 689   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 690           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 691 fi
 692 AC_MSG_RESULT([$enable_thread_safety])
 693 AC_SUBST(enable_thread_safety)
 694
 695 #
 696 # ICU
 697 #
 698 AC_MSG_CHECKING([whether to build with ICU support])
 699 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 700               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 701 AC_MSG_RESULT([$with_icu])
 702 AC_SUBST(with_icu)
 703
 704 if test "$with_icu" = yes; then
 705   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 706 fi
 707
 708 #
 709 # Optionally build Tcl modules (PL/Tcl)
 710 #
 711 AC_MSG_CHECKING([whether to build with Tcl])
 712 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 713 AC_MSG_RESULT([$with_tcl])
 714 AC_SUBST([with_tcl])
 715
 716 # We see if the path to the Tcl/Tk configuration scripts is specified.
 717 # This will override the use of tclsh to find the paths to search.
 718
 719 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 720
 721 #
 722 # Optionally build Perl modules (PL/Perl)
 723 #
 724 AC_MSG_CHECKING([whether to build Perl modules])
 725 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 726 AC_MSG_RESULT([$with_perl])
 727 AC_SUBST(with_perl)
 728
 729 #
 730 # Optionally build Python modules (PL/Python)
 731 #
 732 AC_MSG_CHECKING([whether to build Python modules])
 733 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 734 AC_MSG_RESULT([$with_python])
 735 AC_SUBST(with_python)
 736
 737 #
 738 # GSSAPI
 739 #
 740 AC_MSG_CHECKING([whether to build with GSSAPI support])
 741 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 742 [
 743   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 744   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 745 ])
 746 AC_MSG_RESULT([$with_gssapi])
 747 AC_SUBST(with_gssapi)
 748
 749
 750 AC_SUBST(krb_srvtab)
 751
 752
 753 #
 754 # Kerberos configuration parameters
 755 #
 756 PGAC_ARG_REQ(with, krb-srvnam,
 757              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 758              [],
 759              [with_krb_srvnam="postgres"])
 760 AC_SUBST(with_krb_srvnam)
 761 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 762                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 763
 764
 765 #
 766 # PAM
 767 #
 768 AC_MSG_CHECKING([whether to build with PAM support])
 769 PGAC_ARG_BOOL(with, pam, no,
 770               [build with PAM support],
 771               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 772 AC_MSG_RESULT([$with_pam])
 773
 774
 775 #
 776 # BSD AUTH
 777 #
 778 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 779 PGAC_ARG_BOOL(with, bsd-auth, no,
 780               [build with BSD Authentication support],
 781               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 782 AC_MSG_RESULT([$with_bsd_auth])
 783
 784
 785 #
 786 # LDAP
 787 #
 788 AC_MSG_CHECKING([whether to build with LDAP support])
 789 PGAC_ARG_BOOL(with, ldap, no,
 790               [build with LDAP support],
 791               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 792 AC_MSG_RESULT([$with_ldap])
 793 AC_SUBST(with_ldap)
 794
 795
 796 #
 797 # Bonjour
 798 #
 799 AC_MSG_CHECKING([whether to build with Bonjour support])
 800 PGAC_ARG_BOOL(with, bonjour, no,
 801               [build with Bonjour support],
 802               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 803 AC_MSG_RESULT([$with_bonjour])
 804
 805
 806 #
 807 # OpenSSL
 808 #
 809 AC_MSG_CHECKING([whether to build with OpenSSL support])
 810 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 811               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 812 AC_MSG_RESULT([$with_openssl])
 813 AC_SUBST(with_openssl)
 814
 815 #
 816 # SELinux
 817 #
 818 AC_MSG_CHECKING([whether to build with SELinux support])
 819 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 820 AC_SUBST(with_selinux)
 821 AC_MSG_RESULT([$with_selinux])
 822
 823 #
 824 # Systemd
 825 #
 826 AC_MSG_CHECKING([whether to build with systemd support])
 827 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 828               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 829 AC_SUBST(with_systemd)
 830 AC_MSG_RESULT([$with_systemd])
 831
 832 #
 833 # Readline
 834 #
 835 PGAC_ARG_BOOL(with, readline, yes,
 836               [do not use GNU Readline nor BSD Libedit for editing])
 837 # readline on MinGW has problems with backslashes in psql and other bugs.
 838 # This is particularly a problem with non-US code pages.
 839 # Therefore disable its use until we understand the cause. 2004-07-20
 840 if test "$PORTNAME" = "win32"; then
 841   if test "$with_readline" = yes; then
 842     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 843     with_readline=no
 844   fi
 845 fi
 846
 847
 848 #
 849 # Prefer libedit
 850 #
 851 PGAC_ARG_BOOL(with, libedit-preferred, no,
 852               [prefer BSD Libedit over GNU Readline])
 853
 854
 855 #
 856 # UUID library
 857 #
 858 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 859 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 860 # UUID library.  More than one of these might be present on a given platform,
 861 # so we make the user say which one she wants.
 862 #
 863 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 864 if test x"$with_uuid" = x"" ; then
 865   with_uuid=no
 866 fi
 867 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 868 if test "$with_ossp_uuid" = yes ; then
 869   with_uuid=ossp
 870 fi
 871
 872 if test "$with_uuid" = bsd ; then
 873   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 874   UUID_EXTRA_OBJS="md5.o sha1.o"
 875 elif test "$with_uuid" = e2fs ; then
 876   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 877   UUID_EXTRA_OBJS="md5.o sha1.o"
 878 elif test "$with_uuid" = ossp ; then
 879   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 880   UUID_EXTRA_OBJS=""
 881 elif test "$with_uuid" = no ; then
 882   UUID_EXTRA_OBJS=""
 883 else
 884   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 885 fi
 886 AC_SUBST(with_uuid)
 887 AC_SUBST(UUID_EXTRA_OBJS)
 888
 889
 890 #
 891 # XML
 892 #
 893 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 894               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 895
 896 if test "$with_libxml" = yes ; then
 897   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 898   if test -n "$XML2_CONFIG"; then
 899     for pgac_option in `$XML2_CONFIG --cflags`; do
 900       case $pgac_option in
 901         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 902       esac
 903     done
 904     for pgac_option in `$XML2_CONFIG --libs`; do
 905       case $pgac_option in
 906         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 907       esac
 908     done
 909   fi
 910 fi
 911
 912 AC_SUBST(with_libxml)
 913
 914 #
 915 # XSLT
 916 #
 917 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 918               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 919
 920
 921 AC_SUBST(with_libxslt)
 922
 923 #
 924 # tzdata
 925 #
 926 PGAC_ARG_REQ(with, system-tzdata,
 927              [DIR], [use system time zone data in DIR])
 928 AC_SUBST(with_system_tzdata)
 929
 930 #
 931 # Zlib
 932 #
 933 PGAC_ARG_BOOL(with, zlib, yes,
 934               [do not use Zlib])
 935 AC_SUBST(with_zlib)
 936
 937 #
 938 # Elf
 939 #
 940
 941 # Assume system is ELF if it predefines __ELF__ as 1,
 942 # otherwise believe host_os based default.
 943 case $host_os in
 944     freebsd1*|freebsd2*) elf=no;;
 945     freebsd3*|freebsd4*) elf=yes;;
 946 esac
 947
 948 AC_EGREP_CPP(yes,
 949 [#if __ELF__
 950   yes
 951 #endif
 952 ],
 953 [ELF_SYS=true],
 954 [if test "X$elf" = "Xyes" ; then
 955   ELF_SYS=true
 956 else
 957   ELF_SYS=
 958 fi])
 959 AC_SUBST(ELF_SYS)
 960
 961 #
 962 # Assignments
 963 #
 964
 965 CPPFLAGS="$CPPFLAGS $INCLUDES"
 966 LDFLAGS="$LDFLAGS $LIBDIRS"
 967
 968 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 969 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 970
 971 PGAC_PROG_LD
 972 AC_SUBST(LD)
 973 AC_SUBST(with_gnu_ld)
 974 AC_PROG_RANLIB
 975 PGAC_CHECK_STRIP
 976 AC_CHECK_TOOL(AR, ar, ar)
 977 if test "$PORTNAME" = "win32"; then
 978   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 979   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 980   AC_CHECK_TOOL(WINDRES, windres, windres)
 981 fi
 982
 983 AC_PROG_INSTALL
 984 # When Autoconf chooses install-sh as install program it tries to generate
 985 # a relative path to it in each makefile where it substitutes it. This clashes
 986 # with our Makefile.global concept. This workaround helps.
 987 case $INSTALL in
 988   *install-sh*) install_bin='';;
 989   *) install_bin=$INSTALL;;
 990 esac
 991 AC_SUBST(install_bin)
 992
 993 PGAC_PATH_PROGS(TAR, tar)
 994 AC_PROG_LN_S
 995 AC_PROG_AWK
 996 AC_PROG_MKDIR_P
 997 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
 998 # a relative path to it in each makefile where it substitutes it. This clashes
 999 # with our Makefile.global concept. This workaround helps.
1000 case $MKDIR_P in
1001   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
1002 esac
1003
1004 PGAC_PATH_BISON
1005 PGAC_PATH_FLEX
1006
1007 PGAC_PATH_PERL
1008 if test "$with_perl" = yes; then
1009   if test -z "$PERL"; then
1010     AC_MSG_ERROR([Perl not found])
1011   fi
1012   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1013   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1014     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1015 You might have to rebuild your Perl installation.  Refer to the
1016 documentation for details.  Use --without-perl to disable building
1017 PL/Perl.])
1018   fi
1019   PGAC_CHECK_PERL_EMBED_CCFLAGS
1020   PGAC_CHECK_PERL_EMBED_LDFLAGS
1021 fi
1022
1023 if test "$with_python" = yes; then
1024   PGAC_PATH_PYTHON
1025   PGAC_CHECK_PYTHON_EMBED_SETUP
1026 fi
1027
1028 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1029   PGAC_PATH_PROGS(ZIC, zic)
1030   if test -z "$ZIC"; then
1031     AC_MSG_ERROR([
1032 When cross-compiling, either use the option --with-system-tzdata to use
1033 existing time-zone data, or set the environment variable ZIC to a zic
1034 program to use during the build.])
1035   fi
1036 fi
1037
1038 #
1039 # Pthreads
1040 #
1041 # For each platform, we need to know about any special compile and link
1042 # libraries, and whether the normal C function names are thread-safe.
1043 # See the comment at the top of src/port/thread.c for more information.
1044 # WIN32 doesn't need the pthread tests;  it always uses threads
1045 #
1046 # These tests are run before the library-tests, because linking with the
1047 # other libraries can pull in the pthread functions as a side-effect.  We
1048 # want to use the -pthread or similar flags directly, and not rely on
1049 # the side-effects of linking with some other library.
1050 #
1051 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1052 # invocation below is the first one in the script, and autoconf generates
1053 # additional code for that, which must not be inside the if-block. AS_IF
1054 # knows how to do that.
1055 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1056 [ # then
1057 AX_PTHREAD      # set thread flags
1058
1059 # Some platforms use these, so just define them.  They can't hurt if they
1060 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1061 # enables 5-arg getpwuid_r, among other things.
1062 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1063
1064 # Check for *_r functions
1065 _CFLAGS="$CFLAGS"
1066 _LIBS="$LIBS"
1067 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1068 LIBS="$LIBS $PTHREAD_LIBS"
1069
1070 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1071 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1072
1073 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1074
1075 # Do test here with the proper thread flags
1076 PGAC_FUNC_STRERROR_R_INT
1077
1078 CFLAGS="$_CFLAGS"
1079 LIBS="$_LIBS"
1080
1081 ], [ # else
1082 # do not use values from template file
1083 PTHREAD_CFLAGS=
1084 PTHREAD_LIBS=
1085 ]) # fi
1086
1087 AC_SUBST(PTHREAD_CFLAGS)
1088 AC_SUBST(PTHREAD_LIBS)
1089
1090
1091 ##
1092 ## Libraries
1093 ##
1094 ## Most libraries are included only if they demonstrably provide a function
1095 ## we need, but libm is an exception: always include it, because there are
1096 ## too many compilers that play cute optimization games that will break
1097 ## probes for standard functions such as pow().
1098 ##
1099
1100 AC_CHECK_LIB(m, main)
1101 AC_SEARCH_LIBS(setproctitle, util)
1102 AC_SEARCH_LIBS(dlopen, dl)
1103 AC_SEARCH_LIBS(socket, [socket ws2_32])
1104 AC_SEARCH_LIBS(shl_load, dld)
1105 # We only use libld in port/dynloader/aix.c
1106 case $host_os in
1107      aix*)
1108         AC_SEARCH_LIBS(ldopen, ld)
1109         ;;
1110 esac
1111 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1112 AC_SEARCH_LIBS(crypt, crypt)
1113 AC_SEARCH_LIBS(shm_open, rt)
1114 AC_SEARCH_LIBS(shm_unlink, rt)
1115 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1116 # Solaris:
1117 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1118 # Required for thread_test.c on Solaris
1119 AC_SEARCH_LIBS(sched_yield, rt)
1120 # Required for thread_test.c on Solaris 2.5:
1121 # Other ports use it too (HP-UX) so test unconditionally
1122 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1123 # Cygwin:
1124 AC_SEARCH_LIBS(shmget, cygipc)
1125
1126 if test "$with_readline" = yes; then
1127   PGAC_CHECK_READLINE
1128   if test x"$pgac_cv_check_readline" = x"no"; then
1129     AC_MSG_ERROR([readline library not found
1130 If you have readline already installed, see config.log for details on the
1131 failure.  It is possible the compiler isn't looking in the proper directory.
1132 Use --without-readline to disable readline support.])
1133   fi
1134 fi
1135
1136 if test "$with_zlib" = yes; then
1137   AC_CHECK_LIB(z, inflate, [],
1138                [AC_MSG_ERROR([zlib library not found
1139 If you have zlib already installed, see config.log for details on the
1140 failure.  It is possible the compiler isn't looking in the proper directory.
1141 Use --without-zlib to disable zlib support.])])
1142 fi
1143
1144 if test "$enable_spinlocks" = yes; then
1145   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1146 else
1147   AC_MSG_WARN([
1148 *** Not using spinlocks will cause poor performance.])
1149 fi
1150
1151 if test "$enable_atomics" = yes; then
1152   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1153 else
1154   AC_MSG_WARN([
1155 *** Not using atomic operations will cause poor performance.])
1156 fi
1157
1158 if test "$with_gssapi" = yes ; then
1159   if test "$PORTNAME" != "win32"; then
1160     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1161                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1162   else
1163     LIBS="$LIBS -lgssapi32"
1164   fi
1165 fi
1166
1167 if test "$with_openssl" = yes ; then
1168   dnl Order matters!
1169   if test "$PORTNAME" != "win32"; then
1170      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1171      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1172   else
1173      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1174      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1175   fi
1176   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1177   # Functions introduced in OpenSSL 1.1.0. We used to check for
1178   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1179   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1180   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1181   # functions.
1182   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1183   # OpenSSL versions before 1.1.0 required setting callback functions, for
1184   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1185   # function was removed.
1186   AC_CHECK_FUNCS([CRYPTO_lock])
1187 fi
1188
1189 if test "$with_pam" = yes ; then
1190   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1191 fi
1192
1193 if test "$with_libxml" = yes ; then
1194   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1195 fi
1196
1197 if test "$with_libxslt" = yes ; then
1198   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1199 fi
1200
1201 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1202 if test "$with_ldap" = yes ; then
1203   _LIBS="$LIBS"
1204   if test "$PORTNAME" != "win32"; then
1205     AC_CHECK_LIB(ldap, ldap_bind, [],
1206                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1207                  [$EXTRA_LDAP_LIBS])
1208     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1209     if test "$enable_thread_safety" = yes; then
1210       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1211       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1212                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1213                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1214       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1215     else
1216       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1217     fi
1218     AC_CHECK_FUNCS([ldap_initialize])
1219   else
1220     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1221     LDAP_LIBS_FE="-lwldap32"
1222     LDAP_LIBS_BE="-lwldap32"
1223   fi
1224   LIBS="$_LIBS"
1225 fi
1226 AC_SUBST(LDAP_LIBS_FE)
1227 AC_SUBST(LDAP_LIBS_BE)
1228
1229 # for contrib/sepgsql
1230 if test "$with_selinux" = yes; then
1231   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1232                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1233 fi
1234
1235 # for contrib/uuid-ossp
1236 if test "$with_uuid" = bsd ; then
1237   # On BSD, the UUID functions are in libc
1238   AC_CHECK_FUNC(uuid_to_string,
1239     [UUID_LIBS=""],
1240     [AC_MSG_ERROR([BSD UUID functions are not present])])
1241 elif test "$with_uuid" = e2fs ; then
1242   # On macOS, the UUID functions are in libc
1243   AC_CHECK_FUNC(uuid_generate,
1244     [UUID_LIBS=""],
1245     [AC_CHECK_LIB(uuid, uuid_generate,
1246       [UUID_LIBS="-luuid"],
1247       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1248 elif test "$with_uuid" = ossp ; then
1249   AC_CHECK_LIB(ossp-uuid, uuid_export,
1250     [UUID_LIBS="-lossp-uuid"],
1251     [AC_CHECK_LIB(uuid, uuid_export,
1252       [UUID_LIBS="-luuid"],
1253       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1254 fi
1255 AC_SUBST(UUID_LIBS)
1256
1257
1258 ##
1259 ## Header files
1260 ##
1261
1262 AC_HEADER_STDBOOL
1263
1264 AC_CHECK_HEADERS([atomic.h crypt.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/prctl.h sys/procctl.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1265
1266 # On BSD, test for net/if.h will fail unless sys/socket.h
1267 # is included first.
1268 AC_CHECK_HEADERS(net/if.h, [], [],
1269 [AC_INCLUDES_DEFAULT
1270 #include <sys/socket.h>
1271 ])
1272
1273 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1274 # is included first.
1275 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1276 [AC_INCLUDES_DEFAULT
1277 #include <sys/param.h>
1278 ])
1279
1280 # At least on IRIX, test for netinet/tcp.h will fail unless
1281 # netinet/in.h is included first.
1282 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1283 [AC_INCLUDES_DEFAULT
1284 #include <netinet/in.h>
1285 ])
1286
1287 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1288   AC_CHECK_HEADERS(readline/readline.h, [],
1289         [AC_CHECK_HEADERS(readline.h, [],
1290                 [AC_MSG_ERROR([readline header not found
1291 If you have readline already installed, see config.log for details on the
1292 failure.  It is possible the compiler isn't looking in the proper directory.
1293 Use --without-readline to disable readline support.])])])
1294   AC_CHECK_HEADERS(readline/history.h, [],
1295         [AC_CHECK_HEADERS(history.h, [],
1296                 [AC_MSG_ERROR([history header not found
1297 If you have readline already installed, see config.log for details on the
1298 failure.  It is possible the compiler isn't looking in the proper directory.
1299 Use --without-readline to disable readline support.])])])
1300 fi
1301
1302 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1303 # Some installations of libedit usurp /usr/include/readline/, which seems
1304 # bad practice, since in combined installations readline will have its headers
1305 # there.  We might have to resort to AC_EGREP checks to make sure we found
1306 # the proper header...
1307   AC_CHECK_HEADERS(editline/readline.h, [],
1308         [AC_CHECK_HEADERS(readline.h, [],
1309                 [AC_CHECK_HEADERS(readline/readline.h, [],
1310                         [AC_MSG_ERROR([readline header not found
1311 If you have libedit already installed, see config.log for details on the
1312 failure.  It is possible the compiler isn't looking in the proper directory.
1313 Use --without-readline to disable libedit support.])])])])
1314 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1315 # not be there at all.  Hence, don't complain if not found.  We must check
1316 # though, since in yet other versions it is an independent header.
1317   AC_CHECK_HEADERS(editline/history.h, [],
1318         [AC_CHECK_HEADERS(history.h, [],
1319                 [AC_CHECK_HEADERS(readline/history.h)])])
1320 fi
1321
1322 if test "$with_zlib" = yes; then
1323   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1324 If you have zlib already installed, see config.log for details on the
1325 failure.  It is possible the compiler isn't looking in the proper directory.
1326 Use --without-zlib to disable zlib support.])])
1327 fi
1328
1329 if test "$with_gssapi" = yes ; then
1330   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1331         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1332 fi
1333
1334 if test "$with_openssl" = yes ; then
1335   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1336   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1337 fi
1338
1339 if test "$with_pam" = yes ; then
1340   AC_CHECK_HEADERS(security/pam_appl.h, [],
1341                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1342                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1343 fi
1344
1345 if test "$with_bsd_auth" = yes ; then
1346   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1347 fi
1348
1349 if test "$with_systemd" = yes ; then
1350   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1351 fi
1352
1353 if test "$with_libxml" = yes ; then
1354   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1355 fi
1356
1357 if test "$with_libxslt" = yes ; then
1358   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1359 fi
1360
1361 if test "$with_ldap" = yes ; then
1362   if test "$PORTNAME" != "win32"; then
1363      AC_CHECK_HEADERS(ldap.h, [],
1364                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1365      PGAC_LDAP_SAFE
1366   else
1367      AC_CHECK_HEADERS(winldap.h, [],
1368                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1369                       [AC_INCLUDES_DEFAULT
1370 #include <windows.h>
1371                       ])
1372   fi
1373 fi
1374
1375 if test "$with_bonjour" = yes ; then
1376   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1377 dnl At some point we might add something like
1378 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1379 dnl but right now, what that would mainly accomplish is to encourage
1380 dnl people to try to use the avahi implementation, which does not work.
1381 dnl If you want to use Apple's own Bonjour code on another platform,
1382 dnl just add -ldns_sd to LIBS manually.
1383 fi
1384
1385 # for contrib/uuid-ossp
1386 if test "$with_uuid" = bsd ; then
1387   AC_CHECK_HEADERS(uuid.h,
1388     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1389       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1390     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1391 elif test "$with_uuid" = e2fs ; then
1392   AC_CHECK_HEADERS(uuid/uuid.h,
1393     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1394       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1395     [AC_CHECK_HEADERS(uuid.h,
1396       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1397         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1398       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1399 elif test "$with_uuid" = ossp ; then
1400   AC_CHECK_HEADERS(ossp/uuid.h,
1401     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1402       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1403     [AC_CHECK_HEADERS(uuid.h,
1404       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1405         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1406       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1407 fi
1408
1409 if test "$PORTNAME" = "win32" ; then
1410    AC_CHECK_HEADERS(crtdefs.h)
1411 fi
1412
1413 ##
1414 ## Types, structures, compiler characteristics
1415 ##
1416
1417 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1418 AC_C_BIGENDIAN
1419 AC_C_INLINE
1420 PGAC_PRINTF_ARCHETYPE
1421 AC_C_FLEXIBLE_ARRAY_MEMBER
1422 PGAC_C_SIGNED
1423 PGAC_C_FUNCNAME_SUPPORT
1424 PGAC_C_STATIC_ASSERT
1425 PGAC_C_TYPEOF
1426 PGAC_C_TYPES_COMPATIBLE
1427 PGAC_C_BUILTIN_BSWAP16
1428 PGAC_C_BUILTIN_BSWAP32
1429 PGAC_C_BUILTIN_BSWAP64
1430 PGAC_C_BUILTIN_CONSTANT_P
1431 PGAC_C_BUILTIN_UNREACHABLE
1432 PGAC_C_COMPUTED_GOTO
1433 PGAC_C_VA_ARGS
1434 PGAC_STRUCT_TIMEZONE
1435 PGAC_UNION_SEMUN
1436 PGAC_STRUCT_SOCKADDR_UN
1437 PGAC_STRUCT_SOCKADDR_STORAGE
1438 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1439 PGAC_STRUCT_ADDRINFO
1440 AC_TYPE_INTPTR_T
1441 AC_TYPE_UINTPTR_T
1442 AC_TYPE_LONG_LONG_INT
1443
1444 PGAC_TYPE_LOCALE_T
1445
1446 # MSVC doesn't cope well with defining restrict to __restrict, the
1447 # spelling it understands, because it conflicts with
1448 # __declspec(restrict). Therefore we define pg_restrict to the
1449 # appropriate definition, which presumably won't conflict.
1450 #
1451 # Allow platforms with buggy compilers to force restrict to not be
1452 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1453 # template.
1454 AC_C_RESTRICT
1455 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1456   pg_restrict=""
1457 else
1458   pg_restrict="$ac_cv_c_restrict"
1459 fi
1460 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1461 [Define to keyword to use for C99 restrict support, or to nothing if not
1462 supported])
1463
1464 AC_CHECK_TYPES([struct cmsgcred], [], [],
1465 [#include <sys/socket.h>
1466 #include <sys/param.h>
1467 #ifdef HAVE_SYS_UCRED_H
1468 #include <sys/ucred.h>
1469 #endif])
1470
1471 AC_CHECK_TYPES([struct option], [], [],
1472 [#ifdef HAVE_GETOPT_H
1473 #include <getopt.h>
1474 #endif])
1475
1476 if test "$with_zlib" = yes; then
1477   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1478   # did not).  While we could work around the lack of z_streamp, it
1479   # seems unwise to encourage people to use such old zlib versions...
1480   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1481 Use --without-zlib to disable zlib support.])],
1482                 [#include <zlib.h>])
1483 fi
1484
1485 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1486 case $host_cpu in
1487   ppc*|powerpc*)
1488     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1489     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1490         [int a = 0; int *p = &a; int r;
1491          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1492         [pgac_cv_have_ppc_mutex_hint=yes],
1493         [pgac_cv_have_ppc_mutex_hint=no])
1494     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1495     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1496         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1497     fi
1498   ;;
1499 esac
1500
1501 # Check largefile support.  You might think this is a system service not a
1502 # compiler characteristic, but you'd be wrong.  We must check this before
1503 # probing existence of related functions such as fseeko, since the largefile
1504 # defines can affect what is generated for that.
1505 if test "$PORTNAME" != "win32"; then
1506    AC_SYS_LARGEFILE
1507    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1508    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1509    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1510    dnl versions where the feature actually works, it's on by default anyway.
1511    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1512 fi
1513
1514 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1515 AC_CHECK_SIZEOF([off_t])
1516
1517 # If we don't have largefile support, can't handle segsize >= 2GB.
1518 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1519    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1520 fi
1521
1522 AC_CHECK_SIZEOF([bool], [],
1523 [#ifdef HAVE_STDBOOL_H
1524 #include <stdbool.h>
1525 #endif])
1526
1527
1528 ##
1529 ## Functions, global variables
1530 ##
1531
1532 PGAC_VAR_INT_TIMEZONE
1533 AC_FUNC_ACCEPT_ARGTYPES
1534 PGAC_FUNC_GETTIMEOFDAY_1ARG
1535 PGAC_FUNC_WCSTOMBS_L
1536
1537 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1538 # symbols that that library has no business exposing to the world.  Pending
1539 # acquisition of a clue by those developers, ignore libedit (including its
1540 # possible alias of libreadline) while checking for everything else.
1541 LIBS_including_readline="$LIBS"
1542 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1543
1544 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setproctitle_fast setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1545
1546 AC_REPLACE_FUNCS(fseeko)
1547 case $host_os in
1548         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1549         # Mingw uses macros to access Win32 API calls
1550         netbsd*|mingw*)
1551                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1552                 ac_cv_func_fseeko=yes;;
1553         *)
1554                 AC_FUNC_FSEEKO;;
1555 esac
1556
1557 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1558 # by calling it, 2009-04-02
1559 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1560 if test "$PORTNAME" != "solaris"; then
1561 AC_CHECK_FUNCS(posix_fadvise)
1562 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1563 fi
1564
1565 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1566 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1567 # This is probably only present on macOS, but may as well check always
1568 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1569
1570 HAVE_IPV6=no
1571 AC_CHECK_TYPE([struct sockaddr_in6],
1572         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1573          HAVE_IPV6=yes],
1574         [],
1575 [$ac_includes_default
1576 #include <netinet/in.h>])
1577 AC_SUBST(HAVE_IPV6)
1578
1579 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1580 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1581 [#include <machine/vmparam.h>
1582 #include <sys/exec.h>
1583 ],
1584 [PS_STRINGS->ps_nargvstr = 1;
1585 PS_STRINGS->ps_argvstr = "foo";])],
1586 [pgac_cv_var_PS_STRINGS=yes],
1587 [pgac_cv_var_PS_STRINGS=no])])
1588 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1589   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1590 fi
1591
1592
1593 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1594 # is missing.  Yes, there are machines that have only one.  We may
1595 # also decide to use snprintf.c if snprintf() is present but does not
1596 # have all the features we need --- see below.
1597
1598 if test "$PORTNAME" = "win32"; then
1599   # Win32 gets snprintf.c built unconditionally.
1600   #
1601   # To properly translate all NLS languages strings, we must support the
1602   # *printf() %$ format, which allows *printf() arguments to be selected
1603   # by position in the translated string.
1604   #
1605   # libintl versions < 0.13 use the native *printf() functions, and Win32
1606   # *printf() doesn't understand %$, so we must use our /port versions,
1607   # which do understand %$. libintl versions >= 0.13 include their own
1608   # *printf versions on Win32.  The libintl 0.13 release note text is:
1609   #
1610   #   C format strings with positions, as they arise when a translator
1611   #   needs to reorder a sentence, are now supported on all platforms.
1612   #   On those few platforms (NetBSD and Woe32) for which the native
1613   #   printf()/fprintf()/... functions don't support such format
1614   #   strings, replacements are provided through <libintl.h>.
1615   #
1616   # We could use libintl >= 0.13's *printf() if we were sure that we had
1617   # a libintl >= 0.13 at runtime, but seeing that there is no clean way
1618   # to guarantee that, it is best to just use our own, so we are sure to
1619   # get %$ support. In include/port.h we disable the *printf() macros
1620   # that might have been defined by libintl.
1621   #
1622   # We do this unconditionally whether NLS is used or not so we are sure
1623   # that all Win32 libraries and binaries behave the same.
1624   pgac_need_repl_snprintf=yes
1625 else
1626   pgac_need_repl_snprintf=no
1627   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1628   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1629 fi
1630
1631
1632 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1633 # include/c.h will provide declarations.  Note this is a separate test
1634 # from whether the functions exist in the C library --- there are
1635 # systems that have the functions but don't bother to declare them :-(
1636
1637 AC_CHECK_DECLS([snprintf, vsnprintf])
1638
1639
1640 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1641 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1642 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1643 #include <math.h>
1644 double glob_double;
1645 ],
1646 [return isinf(glob_double) ? 0 : 1;])],
1647 [ac_cv_func_isinf=yes],
1648 [ac_cv_func_isinf=no])])
1649
1650 if test $ac_cv_func_isinf = yes ; then
1651   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1652 else
1653   AC_LIBOBJ(isinf)
1654   # Look for a way to implement a substitute for isinf()
1655   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1656 fi
1657
1658 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1659
1660 case $host_os in
1661
1662         # Windows uses a specialised env handler
1663         # and doesn't need a replacement getpeereid because it doesn't use
1664         # Unix sockets.
1665         mingw*)
1666                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1667                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1668                 ac_cv_func_unsetenv=yes
1669                 ac_cv_func_getpeereid=yes;;
1670         *)
1671                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1672                 ;;
1673 esac
1674
1675 # System's version of getaddrinfo(), if any, may be used only if we found
1676 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1677 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1678 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1679    test "$PORTNAME" != "win32"; then
1680   AC_REPLACE_FUNCS([getaddrinfo])
1681 else
1682   AC_LIBOBJ(getaddrinfo)
1683 fi
1684
1685 # Similarly, use system's getopt_long() only if system provides struct option.
1686 if test x"$ac_cv_type_struct_option" = xyes ; then
1687   AC_REPLACE_FUNCS([getopt_long])
1688 else
1689   AC_LIBOBJ(getopt_long)
1690 fi
1691
1692 # Solaris' getopt() doesn't do what we want for long options, so always use
1693 # our version on that platform.
1694 if test "$PORTNAME" = "solaris"; then
1695   AC_LIBOBJ(getopt)
1696 fi
1697
1698 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1699 # so always use our version on Windows.
1700 if test "$PORTNAME" = "win32"; then
1701   AC_LIBOBJ(getopt)
1702   AC_LIBOBJ(getopt_long)
1703 fi
1704
1705 # Win32 (really MinGW) support
1706 if test "$PORTNAME" = "win32"; then
1707   AC_REPLACE_FUNCS(gettimeofday)
1708   AC_LIBOBJ(dirmod)
1709   AC_LIBOBJ(kill)
1710   AC_LIBOBJ(open)
1711   AC_LIBOBJ(system)
1712   AC_LIBOBJ(win32env)
1713   AC_LIBOBJ(win32error)
1714   AC_LIBOBJ(win32security)
1715   AC_LIBOBJ(win32setlocale)
1716   AC_DEFINE([HAVE_SYMLINK], 1,
1717             [Define to 1 if you have the `symlink' function.])
1718   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1719 #define WIN32_LEAN_AND_MEAN
1720 #include <windows.h>
1721 #include <string.h>
1722 #include <dbghelp.h>])
1723 fi
1724 if test x"$pgac_minidump_type" = x"yes" ; then
1725   AC_SUBST(have_win32_dbghelp,yes)
1726 else
1727   AC_SUBST(have_win32_dbghelp,no)
1728 fi
1729
1730 # Cygwin needs only a bit of that
1731 if test "$PORTNAME" = "cygwin"; then
1732   AC_LIBOBJ(dirmod)
1733 fi
1734
1735 AC_CHECK_DECLS([sys_siglist], [], [],
1736 [#include <signal.h>
1737 /* NetBSD declares sys_siglist in unistd.h.  */
1738 #ifdef HAVE_UNISTD_H
1739 # include <unistd.h>
1740 #endif
1741 ])
1742
1743 AC_CHECK_FUNC(syslog,
1744               [AC_CHECK_HEADER(syslog.h,
1745                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1746
1747 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1748 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1749   [extern int opterr; opterr = 1;])],
1750   [pgac_cv_var_int_opterr=yes],
1751   [pgac_cv_var_int_opterr=no])])
1752 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1753   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1754 fi
1755
1756 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1757 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1758   [extern int optreset; optreset = 1;])],
1759   [pgac_cv_var_int_optreset=yes],
1760   [pgac_cv_var_int_optreset=no])])
1761 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1762   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1763 fi
1764
1765 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1766 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1767 # strto[u]ll may exist but not be declared
1768 AC_CHECK_DECLS([strtoll, strtoull])
1769
1770 if test "$with_icu" = yes; then
1771   ac_save_CPPFLAGS=$CPPFLAGS
1772   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1773
1774   # Verify we have ICU's header files
1775   AC_CHECK_HEADER(unicode/ucol.h, [],
1776         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1777
1778   CPPFLAGS=$ac_save_CPPFLAGS
1779 fi
1780
1781 # Lastly, restore full LIBS list and check for readline/libedit symbols
1782 LIBS="$LIBS_including_readline"
1783
1784 if test "$with_readline" = yes; then
1785   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1786   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1787   AC_CHECK_FUNCS([append_history history_truncate_file])
1788 fi
1789
1790
1791 # This test makes sure that run tests work at all.  Sometimes a shared
1792 # library is found by the linker, but the runtime linker can't find it.
1793 # This check should come after all modifications of compiler or linker
1794 # variables, and before any other run tests.
1795 AC_MSG_CHECKING([test program])
1796 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1797 [AC_MSG_RESULT(ok)],
1798 [AC_MSG_RESULT(failed)
1799 AC_MSG_ERROR([[
1800 Could not execute a simple test program.  This may be a problem
1801 related to locating shared libraries.  Check the file 'config.log'
1802 for the exact reason.]])],
1803 [AC_MSG_RESULT([cross-compiling])])
1804
1805 # --------------------
1806 # Run tests below here
1807 # --------------------
1808
1809 # For NLS, force use of our snprintf if system's doesn't do arg control.
1810 # See comment above at snprintf test for details.
1811 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1812   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1813   if test $pgac_cv_snprintf_arg_control != yes ; then
1814     pgac_need_repl_snprintf=yes
1815   fi
1816 fi
1817
1818
1819 dnl Check to see if we have a working 64-bit integer type.
1820 dnl Since Postgres 8.4, we no longer support compilers without a working
1821 dnl 64-bit type; but we have to determine whether that type is called
1822 dnl "long int" or "long long int".
1823
1824 PGAC_TYPE_64BIT_INT([long int])
1825
1826 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1827   pg_int64_type="long int"
1828 else
1829   PGAC_TYPE_64BIT_INT([long long int])
1830   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1831     pg_int64_type="long long int"
1832   else
1833     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1834   fi
1835 fi
1836
1837 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1838   [Define to the name of a signed 64-bit integer type.])
1839
1840 # Select the printf length modifier that goes with that, too.
1841 # (This used to be bound up with replacement-snprintf selection, but now
1842 # we assume that the native *printf functions use standard length modifiers.)
1843 if test x"$pg_int64_type" = x"long long int" ; then
1844   INT64_MODIFIER='"ll"'
1845 else
1846   INT64_MODIFIER='"l"'
1847 fi
1848
1849 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1850                    [Define to the appropriate printf length modifier for 64-bit ints.])
1851
1852 # Force use of our snprintf if the system's doesn't support the %z flag.
1853 # (Note this test uses PG_INT64_TYPE and INT64_MODIFIER.)
1854 if test "$pgac_need_repl_snprintf" = no; then
1855   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1856   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1857     pgac_need_repl_snprintf=yes
1858   fi
1859 fi
1860
1861 # Force use of our snprintf if the system's doesn't handle buffer overrun
1862 # as specified by C99.
1863 if test "$pgac_need_repl_snprintf" = no; then
1864   PGAC_FUNC_SNPRINTF_C99_RESULT
1865   if test "$pgac_cv_snprintf_c99_result" != yes; then
1866     pgac_need_repl_snprintf=yes
1867   fi
1868 fi
1869
1870 # Now we have checked all the reasons to replace snprintf
1871 if test $pgac_need_repl_snprintf = yes; then
1872   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1873   AC_LIBOBJ(snprintf)
1874 fi
1875
1876 # has to be down here, rather than with the other builtins, because
1877 # the test uses PG_INT64_TYPE.
1878 PGAC_C_BUILTIN_OP_OVERFLOW
1879
1880 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1881 AC_CHECK_SIZEOF([void *])
1882 AC_CHECK_SIZEOF([size_t])
1883 AC_CHECK_SIZEOF([long])
1884
1885 # Decide whether float4 is passed by value: user-selectable, enabled by default
1886 AC_MSG_CHECKING([whether to build with float4 passed by value])
1887 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1888               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1889                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1890                float4passbyval=true],
1891               [float4passbyval=false])
1892 AC_MSG_RESULT([$enable_float4_byval])
1893 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1894
1895 # Decide whether float8 is passed by value.
1896 # Note: this setting also controls int8 and related types such as timestamp.
1897 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1898 # If not, trying to select it is an error.
1899 AC_MSG_CHECKING([whether to build with float8 passed by value])
1900 if test $ac_cv_sizeof_void_p -ge 8 ; then
1901   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1902 else
1903   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1904   if test "$enable_float8_byval" = yes ; then
1905     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1906   fi
1907 fi
1908 if test "$enable_float8_byval" = yes ; then
1909   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1910             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1911   float8passbyval=true
1912 else
1913   float8passbyval=false
1914 fi
1915 AC_MSG_RESULT([$enable_float8_byval])
1916 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1917
1918 # Determine memory alignment requirements for the basic C data types.
1919
1920 AC_CHECK_ALIGNOF(short)
1921 AC_CHECK_ALIGNOF(int)
1922 AC_CHECK_ALIGNOF(long)
1923 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1924   AC_CHECK_ALIGNOF(long long int)
1925 fi
1926 AC_CHECK_ALIGNOF(double)
1927
1928 # Compute maximum alignment of any basic type.
1929 # We assume long's alignment is at least as strong as char, short, or int;
1930 # but we must check long long (if it is being used for int64) and double.
1931 # Note that we intentionally do not consider any types wider than 64 bits,
1932 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1933 # for disk and memory space.
1934
1935 MAX_ALIGNOF=$ac_cv_alignof_long
1936 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1937   MAX_ALIGNOF=$ac_cv_alignof_double
1938 fi
1939 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1940   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1941 fi
1942 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1943
1944
1945 # Some platforms predefine the types int8, int16, etc.  Only check
1946 # a (hopefully) representative subset.
1947 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1948 [#include <stdio.h>])
1949
1950 # Some compilers offer a 128-bit integer scalar type.
1951 PGAC_TYPE_128BIT_INT
1952
1953 # Check for various atomic operations now that we have checked how to declare
1954 # 64bit integers.
1955 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1956 PGAC_HAVE_GCC__SYNC_INT32_TAS
1957 PGAC_HAVE_GCC__SYNC_INT32_CAS
1958 PGAC_HAVE_GCC__SYNC_INT64_CAS
1959 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1960 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1961
1962
1963 # Check for x86 cpuid instruction
1964 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1965 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1966   [[unsigned int exx[4] = {0, 0, 0, 0};
1967   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1968   ]])],
1969   [pgac_cv__get_cpuid="yes"],
1970   [pgac_cv__get_cpuid="no"])])
1971 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1972   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1973 fi
1974
1975 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1976 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1977   [[unsigned int exx[4] = {0, 0, 0, 0};
1978   __get_cpuid(exx[0], 1);
1979   ]])],
1980   [pgac_cv__cpuid="yes"],
1981   [pgac_cv__cpuid="no"])])
1982 if test x"$pgac_cv__cpuid" = x"yes"; then
1983   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1984 fi
1985
1986 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1987 #
1988 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1989 # with the default compiler flags. If not, check if adding the -msse4.2
1990 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1991 PGAC_SSE42_CRC32_INTRINSICS([])
1992 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1993   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1994 fi
1995 AC_SUBST(CFLAGS_SSE42)
1996
1997 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
1998 # define __SSE4_2__ in that case.
1999 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2000 #ifndef __SSE4_2__
2001 #error __SSE4_2__ not defined
2002 #endif
2003 ])], [SSE4_2_TARGETED=1])
2004
2005 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
2006 #
2007 # First check if __crc32c* intrinsics can be used with the default compiler
2008 # flags. If not, check if adding -march=armv8-a+crc flag helps.
2009 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
2010 PGAC_ARMV8_CRC32C_INTRINSICS([])
2011 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
2012   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
2013 fi
2014 AC_SUBST(CFLAGS_ARMV8_CRC32C)
2015
2016 # Select CRC-32C implementation.
2017 #
2018 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
2019 # use the special CRC instructions for calculating CRC-32C. If we're not
2020 # targeting such a processor, but we can nevertheless produce code that uses
2021 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2022 # implementations and select which one to use at runtime, depending on whether
2023 # SSE 4.2 is supported by the processor we're running on.
2024 #
2025 # Similarly, if we are targeting an ARM processor that has the CRC
2026 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2027 # we're not targeting such a processor, but can nevertheless produce code that
2028 # uses the CRC instructions, compile both, and select at runtime.
2029 #
2030 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2031 # in the template or configure command line.
2032 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2033   # Use Intel SSE 4.2 if available.
2034   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2035     USE_SSE42_CRC32C=1
2036   else
2037     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2038     # the runtime check.
2039     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2040       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2041     else
2042       # Use ARM CRC Extension if available.
2043       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2044         USE_ARMV8_CRC32C=1
2045       else
2046         # ARM CRC Extension, with runtime check?
2047         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2048           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2049         else
2050           # fall back to slicing-by-8 algorithm, which doesn't require any
2051           # special CPU support.
2052           USE_SLICING_BY_8_CRC32C=1
2053         fi
2054       fi
2055     fi
2056   fi
2057 fi
2058
2059 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2060 AC_MSG_CHECKING([which CRC-32C implementation to use])
2061 if test x"$USE_SSE42_CRC32C" = x"1"; then
2062   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2063   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2064   AC_MSG_RESULT(SSE 4.2)
2065 else
2066   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2067     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2068     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2069     AC_MSG_RESULT(SSE 4.2 with runtime check)
2070   else
2071     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2072       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2073       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2074       AC_MSG_RESULT(ARMv8 CRC instructions)
2075     else
2076       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2077         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2078         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2079         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2080       else
2081         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2082         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2083         AC_MSG_RESULT(slicing-by-8)
2084       fi
2085     fi
2086   fi
2087 fi
2088 AC_SUBST(PG_CRC32C_OBJS)
2089
2090
2091 # Select semaphore implementation type.
2092 if test "$PORTNAME" != "win32"; then
2093   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2094     # Need sem_open for this
2095     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2096   fi
2097   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2098     # Need sem_init for this
2099     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2100   fi
2101   AC_MSG_CHECKING([which semaphore API to use])
2102   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2103     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2104     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2105     sematype="named POSIX"
2106   else
2107     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2108       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2109       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2110       sematype="unnamed POSIX"
2111     else
2112       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2113       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2114       sematype="System V"
2115     fi
2116   fi
2117   AC_MSG_RESULT([$sematype])
2118 else
2119   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2120   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2121 fi
2122
2123
2124 # Select shared-memory implementation type.
2125 if test "$PORTNAME" != "win32"; then
2126   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2127   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2128 else
2129   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2130   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2131 fi
2132
2133 # Select random number source
2134 #
2135 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2136 # in the template or configure command line.
2137
2138 # If not selected manually, try to select a source automatically.
2139 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2140   if test x"$with_openssl" = x"yes" ; then
2141     USE_OPENSSL_RANDOM=1
2142   elif test "$PORTNAME" = "win32" ; then
2143     USE_WIN32_RANDOM=1
2144   else
2145     AC_CHECK_FILE([/dev/urandom], [], [])
2146
2147     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2148       USE_DEV_URANDOM=1
2149     fi
2150   fi
2151 fi
2152
2153 AC_MSG_CHECKING([which random number source to use])
2154 if test "$enable_strong_random" = yes ; then
2155   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2156     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2157     AC_MSG_RESULT([OpenSSL])
2158   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2159     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2160     AC_MSG_RESULT([Windows native])
2161   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2162     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2163     AC_MSG_RESULT([/dev/urandom])
2164   else
2165     AC_MSG_ERROR([
2166 no source of strong random numbers was found
2167 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2168 for authentication protocols. You can use --disable-strong-random to use a
2169 built-in pseudo random number generator, but that may be insecure.])
2170   fi
2171   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2172 else
2173     AC_MSG_RESULT([weak builtin PRNG])
2174     AC_MSG_WARN([
2175 *** Not using a strong random number source may be insecure.])
2176 fi
2177
2178 # If not set in template file, set bytes to use libc memset()
2179 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2180   MEMSET_LOOP_LIMIT=1024
2181 fi
2182 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2183
2184
2185 if test "$enable_nls" = yes ; then
2186   PGAC_CHECK_GETTEXT
2187 fi
2188
2189 # Check for Tcl configuration script tclConfig.sh
2190 if test "$with_tcl" = yes; then
2191     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2192     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2193                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2194     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2195     if test "$TCL_SHARED_BUILD" != 1; then
2196       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2197 Use --without-tcl to disable building PL/Tcl.])
2198     fi
2199     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2200     ac_save_CPPFLAGS=$CPPFLAGS
2201     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2202     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2203     CPPFLAGS=$ac_save_CPPFLAGS
2204 fi
2205
2206 # check for <perl.h>
2207 if test "$with_perl" = yes; then
2208   ac_save_CPPFLAGS=$CPPFLAGS
2209   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2210   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2211                   [#include <EXTERN.h>])
2212   # While we're at it, check that we can link to libperl.
2213   # On most platforms, if perl.h is there then libperl.so will be too, but at
2214   # this writing Debian packages them separately.  There is no known reason to
2215   # waste cycles on separate probes for the Tcl or Python libraries, though.
2216   pgac_save_LIBS=$LIBS
2217   LIBS="$perl_embed_ldflags"
2218   AC_MSG_CHECKING([for libperl])
2219   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2220 #include <EXTERN.h>
2221 #include <perl.h>
2222 ],  [perl_alloc();])],
2223     [AC_MSG_RESULT(yes)],
2224     [AC_MSG_RESULT(no)
2225      AC_MSG_ERROR([libperl library is required for Perl])])
2226   LIBS=$pgac_save_LIBS
2227   CPPFLAGS=$ac_save_CPPFLAGS
2228 fi
2229
2230 # check for <Python.h>
2231 if test "$with_python" = yes; then
2232   ac_save_CPPFLAGS=$CPPFLAGS
2233   CPPFLAGS="$python_includespec $CPPFLAGS"
2234   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2235   CPPFLAGS=$ac_save_CPPFLAGS
2236 fi
2237
2238 #
2239 # Check for DocBook and tools
2240 #
2241 PGAC_PATH_XMLLINT
2242 PGAC_CHECK_DOCBOOK(4.2)
2243 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2244 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2245 PGAC_PATH_PROGS(FOP, fop)
2246
2247 #
2248 # Check for test tools
2249 #
2250 if test "$enable_tap_tests" = yes; then
2251   # Check for necessary modules, unless user has specified the "prove" to use;
2252   # in that case it's her responsibility to have a working configuration.
2253   # (prove might be part of a different Perl installation than perl, eg on
2254   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2255   if test -z "$PROVE"; then
2256     # Test::More and Time::HiRes are supposed to be part of core Perl,
2257     # but some distros omit them in a minimal installation.
2258     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2259       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2260   fi
2261   # Now make sure we know where prove is
2262   PGAC_PATH_PROGS(PROVE, prove)
2263   if test -z "$PROVE"; then
2264     AC_MSG_ERROR([prove not found])
2265   fi
2266 fi
2267
2268 # Thread testing
2269
2270 # We have to run the thread test near the end so we have all our symbols
2271 # defined.  Cross compiling throws a warning.
2272 #
2273 if test "$enable_thread_safety" = yes; then
2274 if test "$PORTNAME" != "win32"
2275 then
2276 AC_MSG_CHECKING([thread safety of required library functions])
2277
2278 _CFLAGS="$CFLAGS"
2279 _LIBS="$LIBS"
2280 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2281 LIBS="$LIBS $PTHREAD_LIBS"
2282 AC_RUN_IFELSE(
2283   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2284   [AC_MSG_RESULT(yes)],
2285   [AC_MSG_RESULT(no)
2286   AC_MSG_ERROR([thread test program failed
2287 This platform is not thread-safe.  Check the file 'config.log' or compile
2288 and run src/test/thread/thread_test for the exact reason.
2289 Use --disable-thread-safety to disable thread safety.])],
2290   [AC_MSG_RESULT(maybe)
2291   AC_MSG_WARN([
2292 *** Skipping thread test program because of cross-compile build.
2293 *** Run the program in src/test/thread on the target machine.
2294 ])])
2295 CFLAGS="$_CFLAGS"
2296 LIBS="$_LIBS"
2297 else
2298 AC_MSG_WARN([*** skipping thread test on Win32])
2299 fi
2300 fi
2301
2302 # If compiler will take -Wl,--as-needed (or various platform-specific
2303 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2304 # trying to filter LIBS to the minimum for each executable.
2305 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2306 # libreadline; therefore we postpone testing it until we know what library
2307 # dependencies readline has.  The test code will try to link with $LIBS.
2308 if test "$with_readline" = yes; then
2309   link_test_func=readline
2310 else
2311   link_test_func=exit
2312 fi
2313
2314 if test "$PORTNAME" = "darwin"; then
2315   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2316 elif test "$PORTNAME" = "openbsd"; then
2317   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2318 else
2319   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2320 fi
2321
2322 # Create compiler version string
2323 if test x"$GCC" = x"yes" ; then
2324   cc_string=`${CC} --version | sed q`
2325   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2326 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2327   cc_string=`${CC} -V 2>&1 | sed q`
2328 else
2329   cc_string=$CC
2330 fi
2331
2332 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2333                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2334                    [A string containing the version number, platform, and C compiler])
2335
2336 # Supply a numeric version string for use by 3rd party add-ons
2337 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2338 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2339 tr '.' '        ' |
2340 $AWK '{printf "%d%04d", $1, $2}'`"]
2341 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2342 AC_SUBST(PG_VERSION_NUM)
2343
2344
2345 # Begin output steps
2346
2347 AC_MSG_NOTICE([using compiler=$cc_string])
2348 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2349 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2350 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2351 # Currently only used when LLVM is used
2352 if test "$with_llvm" = yes ; then
2353    AC_MSG_NOTICE([using CXX=$CXX])
2354    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2355    AC_MSG_NOTICE([using CLANG=$CLANG])
2356    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2357    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2358 fi
2359
2360 # prepare build tree if outside source tree
2361 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2362 # Note 2: /bin/pwd might be better than shell's built-in at getting
2363 #         a symlink-free name.
2364 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2365   vpath_build=no
2366 else
2367   vpath_build=yes
2368   if test "$no_create" != yes; then
2369     _AS_ECHO_N([preparing build tree... ])
2370     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2371     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2372       || AC_MSG_ERROR(failed)
2373     AC_MSG_RESULT(done)
2374   fi
2375 fi
2376 AC_SUBST(vpath_build)
2377
2378
2379 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2380
2381 AC_CONFIG_LINKS([
2382   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2383   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2384   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2385   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2386   src/include/pg_config_os.h:src/include/port/${template}.h
2387   src/Makefile.port:src/makefiles/Makefile.${template}
2388 ])
2389
2390 if test "$PORTNAME" = "win32"; then
2391 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2392 # Links sometimes fail undetected on Mingw -
2393 # so here we detect it and warn the user
2394 for FILE in $CONFIG_LINKS
2395  do
2396         # test -e works for symlinks in the MinGW console
2397         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2398  done
2399 ])
2400 fi
2401
2402 AC_CONFIG_HEADERS([src/include/pg_config.h],
2403 [
2404 # Update timestamp for pg_config.h (see Makefile.global)
2405 echo >src/include/stamp-h
2406 ])
2407
2408 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2409 [
2410 # Update timestamp for pg_config_ext.h (see Makefile.global)
2411 echo >src/include/stamp-ext-h
2412 ])
2413
2414 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2415                   [echo >src/interfaces/ecpg/include/stamp-h])
2416
2417 AC_OUTPUT