granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [12devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 357     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361 AC_PROG_CC_C99()
 362
 363 # Error out if the compiler does not support C99, as the codebase
 364 # relies on that.
 365 if test "$ac_cv_prog_cc_c99" = no; then
 366     AC_MSG_ERROR([C compiler "$CC" does not support C99])
 367 fi
 368
 369 AC_PROG_CXX([$pgac_cxx_list])
 370
 371 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 372 # but has idiosyncrasies of its own.  We assume icc will define
 373 # __INTEL_COMPILER regardless of CFLAGS.
 374 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 375 choke me
 376 @%:@endif])], [ICC=yes], [ICC=no])
 377
 378 # Check if it's Sun Studio compiler. We assume that
 379 # __SUNPRO_C will be defined for Sun Studio compilers
 380 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 381 choke me
 382 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 383
 384 AC_SUBST(SUN_STUDIO_CC)
 385
 386
 387 #
 388 # LLVM
 389 #
 390 # Checked early because subsequent tests depend on it.
 391 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 392               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 393 AC_SUBST(with_llvm)
 394 if test "$with_llvm" = yes ; then
 395    PGAC_LLVM_SUPPORT()
 396 fi
 397
 398
 399 unset CFLAGS
 400 unset CXXFLAGS
 401
 402 #
 403 # Read the template
 404 #
 405 . "$srcdir/src/template/$template" || exit
 406
 407 # C[XX]FLAGS are selected so:
 408 # If the user specifies something in the environment, that is used.
 409 # else:  If the template file set something, that is used.
 410 # else:  If coverage was enabled, don't set anything.
 411 # else:  If the compiler is GCC, then we use -O2.
 412 # else:  If the compiler is something else, then we use -O, unless debugging.
 413
 414 if test "$ac_env_CFLAGS_set" = set; then
 415   CFLAGS=$ac_env_CFLAGS_value
 416 elif test "${CFLAGS+set}" = set; then
 417   : # (keep what template set)
 418 elif test "$enable_coverage" = yes; then
 419   : # no optimization by default
 420 elif test "$GCC" = yes; then
 421   CFLAGS="-O2"
 422 else
 423   # if the user selected debug mode, don't use -O
 424   if test "$enable_debug" != yes; then
 425     CFLAGS="-O"
 426   fi
 427 fi
 428
 429 if test "$ac_env_CXXFLAGS_set" = set; then
 430   CXXFLAGS=$ac_env_CXXFLAGS_value
 431 elif test "${CXXFLAGS+set}" = set; then
 432   : # (keep what template set)
 433 elif test "$enable_coverage" = yes; then
 434   : # no optimization by default
 435 elif test "$GCC" = yes; then
 436   CXXFLAGS="-O2"
 437 else
 438   # if the user selected debug mode, don't use -O
 439   if test "$enable_debug" != yes; then
 440     CXXFLAGS="-O"
 441   fi
 442 fi
 443
 444 # When generating bitcode (for inlining) we always want to use -O2
 445 # even when --enable-debug is specified. The bitcode it's not going to
 446 # be used for line-by-line debugging, and JIT inlining doesn't work
 447 # without at least -O1 (otherwise clang will emit 'noinline'
 448 # attributes everywhere), which is bad for testing.  Still allow the
 449 # environment to override if done explicitly.
 450 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 451   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 452 else
 453   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 454 fi
 455 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 456   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 457 else
 458   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 459 fi
 460
 461 # C[XX]FLAGS we determined above will be added back at the end
 462 user_CFLAGS=$CFLAGS
 463 CFLAGS=""
 464 user_CXXFLAGS=$CXXFLAGS
 465 CXXFLAGS=""
 466 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 467 BITCODE_CFLAGS=""
 468 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 469 BITCODE_CXXFLAGS=""
 470
 471 # set CFLAGS_VECTOR from the environment, if available
 472 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 473   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 474 fi
 475
 476 # Some versions of GCC support some additional useful warning flags.
 477 # Check whether they are supported, and add them to CFLAGS if so.
 478 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 479 # but has its own.  Also check other compiler-specific flags here.
 480
 481 if test "$GCC" = yes -a "$ICC" = no; then
 482   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 483   CXXFLAGS="-Wall -Wpointer-arith"
 484   # These work in some but not all gcc versions
 485   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 486   # -Wdeclaration-after-statement isn't applicable for C++
 487   # Really don't want VLAs to be used in our dialect of C
 488   PGAC_PROG_CC_CFLAGS_OPT([-Werror=vla])
 489   # -Wvla is not applicable for C++
 490   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 491   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 492   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 493   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 494   # This was included in -Wall/-Wformat in older GCC versions
 495   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 496   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 497   # Disable strict-aliasing rules; needed for gcc 3.3+
 498   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 499   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 500   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 501   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 502   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 503   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 504   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 505   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 506   # Optimization flags for specific files that benefit from vectorization
 507   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 508   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 509   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 510   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 511   # test for the positive form and if that works, add the negative form
 512   NOT_THE_CFLAGS=""
 513   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 514   if test -n "$NOT_THE_CFLAGS"; then
 515     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 516   fi
 517   # Similarly disable useless truncation warnings from gcc 8+
 518   NOT_THE_CFLAGS=""
 519   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wformat-truncation])
 520   if test -n "$NOT_THE_CFLAGS"; then
 521     CFLAGS="$CFLAGS -Wno-format-truncation"
 522   fi
 523   NOT_THE_CFLAGS=""
 524   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wstringop-truncation])
 525   if test -n "$NOT_THE_CFLAGS"; then
 526     CFLAGS="$CFLAGS -Wno-stringop-truncation"
 527   fi
 528 elif test "$ICC" = yes; then
 529   # Intel's compiler has a bug/misoptimization in checking for
 530   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 531   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 532   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 533   # Make sure strict aliasing is off (though this is said to be the default)
 534   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 535   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 536 elif test "$PORTNAME" = "aix"; then
 537   # AIX's xlc has to have strict aliasing turned off too
 538   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 539   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 540   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 541   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 542 elif test "$PORTNAME" = "hpux"; then
 543   # On some versions of HP-UX, libm functions do not set errno by default.
 544   # Fix that by using +Olibmerrno if the compiler recognizes it.
 545   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 546   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 547 fi
 548
 549 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 550
 551 # Determine flags used to emit bitcode for JIT inlining. Need to test
 552 # for behaviour changing compiler flags, to keep compatibility with
 553 # compiler used for normal postgres code.
 554 if test "$with_llvm" = yes ; then
 555   CLANGXX="$CLANG -xc++"
 556
 557   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 558   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 559   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 560   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 561   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 562   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 563 fi
 564
 565 # supply -g if --enable-debug
 566 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 567   CFLAGS="$CFLAGS -g"
 568 fi
 569
 570 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 571   CXXFLAGS="$CXXFLAGS -g"
 572 fi
 573
 574 # enable code coverage if --enable-coverage
 575 if test "$enable_coverage" = yes; then
 576   if test "$GCC" = yes; then
 577     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 578     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 579   else
 580     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 581   fi
 582 fi
 583
 584 # enable profiling if --enable-profiling
 585 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 586   if test "$GCC" = yes; then
 587     AC_DEFINE([PROFILE_PID_DIR], 1,
 588            [Define to 1 to allow profiling output to be saved separately for each process.])
 589     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 590     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 591   else
 592     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 593   fi
 594 fi
 595
 596 # We already have this in Makefile.win32, but configure needs it too
 597 if test "$PORTNAME" = "win32"; then
 598   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 599 fi
 600
 601 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 602 # user-specified flags (if any) at the end.  This lets users override
 603 # the automatic additions.
 604 CFLAGS="$CFLAGS $user_CFLAGS"
 605 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 606 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 607 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 608
 609 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 610 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 611
 612 # Check if the compiler still works with the final flag settings
 613 # (note, we're not checking that for CXX, which is optional)
 614 AC_MSG_CHECKING([whether the C compiler still works])
 615 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 616   [AC_MSG_RESULT(yes)],
 617   [AC_MSG_RESULT(no)
 618    AC_MSG_ERROR([cannot proceed])])
 619
 620 # Defend against gcc -ffast-math
 621 if test "$GCC" = yes; then
 622 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 623 choke me
 624 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 625 fi
 626
 627 AC_PROG_CPP
 628 AC_SUBST(GCC)
 629
 630
 631 #
 632 # Set up TAS assembly code if needed; the template file has now had its
 633 # chance to request this.
 634 #
 635 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 636
 637 if test "$need_tas" = yes ; then
 638   TAS=tas.o
 639 else
 640   TAS=""
 641 fi
 642 AC_SUBST(TAS)
 643
 644
 645 #
 646 # Automatic dependency tracking
 647 #
 648 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 649               [autodepend=yes])
 650 AC_SUBST(autodepend)
 651
 652
 653 #
 654 # Enable assert checks
 655 #
 656 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 657               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 658                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 659
 660
 661 #
 662 # Include directories
 663 #
 664 ac_save_IFS=$IFS
 665 IFS="${IFS}${PATH_SEPARATOR}"
 666 # SRCH_INC comes from the template file
 667 for dir in $with_includes $SRCH_INC; do
 668   if test -d "$dir"; then
 669     INCLUDES="$INCLUDES -I$dir"
 670   else
 671     AC_MSG_WARN([*** Include directory $dir does not exist.])
 672   fi
 673 done
 674 IFS=$ac_save_IFS
 675 AC_SUBST(INCLUDES)
 676
 677
 678 #
 679 # Library directories
 680 #
 681 ac_save_IFS=$IFS
 682 IFS="${IFS}${PATH_SEPARATOR}"
 683 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 684 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 685   if test -d "$dir"; then
 686     LIBDIRS="$LIBDIRS -L$dir"
 687   else
 688     AC_MSG_WARN([*** Library directory $dir does not exist.])
 689   fi
 690 done
 691 IFS=$ac_save_IFS
 692
 693 #
 694 # Enable thread-safe client libraries
 695 #
 696 AC_MSG_CHECKING([allow thread-safe client libraries])
 697 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 698 if test "$enable_thread_safety" = yes; then
 699   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 700           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 701 fi
 702 AC_MSG_RESULT([$enable_thread_safety])
 703 AC_SUBST(enable_thread_safety)
 704
 705 #
 706 # ICU
 707 #
 708 AC_MSG_CHECKING([whether to build with ICU support])
 709 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 710               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 711 AC_MSG_RESULT([$with_icu])
 712 AC_SUBST(with_icu)
 713
 714 if test "$with_icu" = yes; then
 715   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 716 fi
 717
 718 #
 719 # Optionally build Tcl modules (PL/Tcl)
 720 #
 721 AC_MSG_CHECKING([whether to build with Tcl])
 722 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 723 AC_MSG_RESULT([$with_tcl])
 724 AC_SUBST([with_tcl])
 725
 726 # We see if the path to the Tcl/Tk configuration scripts is specified.
 727 # This will override the use of tclsh to find the paths to search.
 728
 729 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 730
 731 #
 732 # Optionally build Perl modules (PL/Perl)
 733 #
 734 AC_MSG_CHECKING([whether to build Perl modules])
 735 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 736 AC_MSG_RESULT([$with_perl])
 737 AC_SUBST(with_perl)
 738
 739 #
 740 # Optionally build Python modules (PL/Python)
 741 #
 742 AC_MSG_CHECKING([whether to build Python modules])
 743 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 744 AC_MSG_RESULT([$with_python])
 745 AC_SUBST(with_python)
 746
 747 #
 748 # GSSAPI
 749 #
 750 AC_MSG_CHECKING([whether to build with GSSAPI support])
 751 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 752 [
 753   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 754   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 755 ])
 756 AC_MSG_RESULT([$with_gssapi])
 757 AC_SUBST(with_gssapi)
 758
 759
 760 AC_SUBST(krb_srvtab)
 761
 762
 763 #
 764 # Kerberos configuration parameters
 765 #
 766 PGAC_ARG_REQ(with, krb-srvnam,
 767              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 768              [],
 769              [with_krb_srvnam="postgres"])
 770 AC_SUBST(with_krb_srvnam)
 771 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 772                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 773
 774
 775 #
 776 # PAM
 777 #
 778 AC_MSG_CHECKING([whether to build with PAM support])
 779 PGAC_ARG_BOOL(with, pam, no,
 780               [build with PAM support],
 781               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 782 AC_MSG_RESULT([$with_pam])
 783
 784
 785 #
 786 # BSD AUTH
 787 #
 788 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 789 PGAC_ARG_BOOL(with, bsd-auth, no,
 790               [build with BSD Authentication support],
 791               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 792 AC_MSG_RESULT([$with_bsd_auth])
 793
 794
 795 #
 796 # LDAP
 797 #
 798 AC_MSG_CHECKING([whether to build with LDAP support])
 799 PGAC_ARG_BOOL(with, ldap, no,
 800               [build with LDAP support],
 801               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 802 AC_MSG_RESULT([$with_ldap])
 803 AC_SUBST(with_ldap)
 804
 805
 806 #
 807 # Bonjour
 808 #
 809 AC_MSG_CHECKING([whether to build with Bonjour support])
 810 PGAC_ARG_BOOL(with, bonjour, no,
 811               [build with Bonjour support],
 812               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 813 AC_MSG_RESULT([$with_bonjour])
 814
 815
 816 #
 817 # OpenSSL
 818 #
 819 AC_MSG_CHECKING([whether to build with OpenSSL support])
 820 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 821               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 822 AC_MSG_RESULT([$with_openssl])
 823 AC_SUBST(with_openssl)
 824
 825 #
 826 # SELinux
 827 #
 828 AC_MSG_CHECKING([whether to build with SELinux support])
 829 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 830 AC_SUBST(with_selinux)
 831 AC_MSG_RESULT([$with_selinux])
 832
 833 #
 834 # Systemd
 835 #
 836 AC_MSG_CHECKING([whether to build with systemd support])
 837 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 838               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 839 AC_SUBST(with_systemd)
 840 AC_MSG_RESULT([$with_systemd])
 841
 842 #
 843 # Readline
 844 #
 845 PGAC_ARG_BOOL(with, readline, yes,
 846               [do not use GNU Readline nor BSD Libedit for editing])
 847 # readline on MinGW has problems with backslashes in psql and other bugs.
 848 # This is particularly a problem with non-US code pages.
 849 # Therefore disable its use until we understand the cause. 2004-07-20
 850 if test "$PORTNAME" = "win32"; then
 851   if test "$with_readline" = yes; then
 852     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 853     with_readline=no
 854   fi
 855 fi
 856
 857
 858 #
 859 # Prefer libedit
 860 #
 861 PGAC_ARG_BOOL(with, libedit-preferred, no,
 862               [prefer BSD Libedit over GNU Readline])
 863
 864
 865 #
 866 # UUID library
 867 #
 868 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 869 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 870 # UUID library.  More than one of these might be present on a given platform,
 871 # so we make the user say which one she wants.
 872 #
 873 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 874 if test x"$with_uuid" = x"" ; then
 875   with_uuid=no
 876 fi
 877 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 878 if test "$with_ossp_uuid" = yes ; then
 879   with_uuid=ossp
 880 fi
 881
 882 if test "$with_uuid" = bsd ; then
 883   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 884   UUID_EXTRA_OBJS="md5.o sha1.o"
 885 elif test "$with_uuid" = e2fs ; then
 886   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 887   UUID_EXTRA_OBJS="md5.o sha1.o"
 888 elif test "$with_uuid" = ossp ; then
 889   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 890   UUID_EXTRA_OBJS=""
 891 elif test "$with_uuid" = no ; then
 892   UUID_EXTRA_OBJS=""
 893 else
 894   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 895 fi
 896 AC_SUBST(with_uuid)
 897 AC_SUBST(UUID_EXTRA_OBJS)
 898
 899
 900 #
 901 # XML
 902 #
 903 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 904               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 905
 906 if test "$with_libxml" = yes ; then
 907   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 908   if test -n "$XML2_CONFIG"; then
 909     for pgac_option in `$XML2_CONFIG --cflags`; do
 910       case $pgac_option in
 911         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 912       esac
 913     done
 914     for pgac_option in `$XML2_CONFIG --libs`; do
 915       case $pgac_option in
 916         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 917       esac
 918     done
 919   fi
 920 fi
 921
 922 AC_SUBST(with_libxml)
 923
 924 #
 925 # XSLT
 926 #
 927 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 928               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 929
 930
 931 AC_SUBST(with_libxslt)
 932
 933 #
 934 # tzdata
 935 #
 936 PGAC_ARG_REQ(with, system-tzdata,
 937              [DIR], [use system time zone data in DIR])
 938 AC_SUBST(with_system_tzdata)
 939
 940 #
 941 # Zlib
 942 #
 943 PGAC_ARG_BOOL(with, zlib, yes,
 944               [do not use Zlib])
 945 AC_SUBST(with_zlib)
 946
 947 #
 948 # Elf
 949 #
 950
 951 # Assume system is ELF if it predefines __ELF__ as 1,
 952 # otherwise believe host_os based default.
 953 case $host_os in
 954     freebsd1*|freebsd2*) elf=no;;
 955     freebsd3*|freebsd4*) elf=yes;;
 956 esac
 957
 958 AC_EGREP_CPP(yes,
 959 [#if __ELF__
 960   yes
 961 #endif
 962 ],
 963 [ELF_SYS=true],
 964 [if test "X$elf" = "Xyes" ; then
 965   ELF_SYS=true
 966 else
 967   ELF_SYS=
 968 fi])
 969 AC_SUBST(ELF_SYS)
 970
 971 #
 972 # Assignments
 973 #
 974
 975 CPPFLAGS="$CPPFLAGS $INCLUDES"
 976 LDFLAGS="$LDFLAGS $LIBDIRS"
 977
 978 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 979 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 980
 981 PGAC_PROG_LD
 982 AC_SUBST(LD)
 983 AC_SUBST(with_gnu_ld)
 984 AC_PROG_RANLIB
 985 PGAC_CHECK_STRIP
 986 AC_CHECK_TOOL(AR, ar, ar)
 987 if test "$PORTNAME" = "win32"; then
 988   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 989   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 990   AC_CHECK_TOOL(WINDRES, windres, windres)
 991 fi
 992
 993 AC_PROG_INSTALL
 994 # When Autoconf chooses install-sh as install program it tries to generate
 995 # a relative path to it in each makefile where it substitutes it. This clashes
 996 # with our Makefile.global concept. This workaround helps.
 997 case $INSTALL in
 998   *install-sh*) install_bin='';;
 999   *) install_bin=$INSTALL;;
1000 esac
1001 AC_SUBST(install_bin)
1002
1003 PGAC_PATH_PROGS(TAR, tar)
1004 AC_PROG_LN_S
1005 AC_PROG_AWK
1006 AC_PROG_MKDIR_P
1007 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
1008 # a relative path to it in each makefile where it substitutes it. This clashes
1009 # with our Makefile.global concept. This workaround helps.
1010 case $MKDIR_P in
1011   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
1012 esac
1013
1014 PGAC_PATH_BISON
1015 PGAC_PATH_FLEX
1016
1017 PGAC_PATH_PERL
1018 if test "$with_perl" = yes; then
1019   if test -z "$PERL"; then
1020     AC_MSG_ERROR([Perl not found])
1021   fi
1022   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1023   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1024     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1025 You might have to rebuild your Perl installation.  Refer to the
1026 documentation for details.  Use --without-perl to disable building
1027 PL/Perl.])
1028   fi
1029   PGAC_CHECK_PERL_EMBED_CCFLAGS
1030   PGAC_CHECK_PERL_EMBED_LDFLAGS
1031 fi
1032
1033 if test "$with_python" = yes; then
1034   PGAC_PATH_PYTHON
1035   PGAC_CHECK_PYTHON_EMBED_SETUP
1036 fi
1037
1038 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1039   PGAC_PATH_PROGS(ZIC, zic)
1040   if test -z "$ZIC"; then
1041     AC_MSG_ERROR([
1042 When cross-compiling, either use the option --with-system-tzdata to use
1043 existing time-zone data, or set the environment variable ZIC to a zic
1044 program to use during the build.])
1045   fi
1046 fi
1047
1048 #
1049 # Pthreads
1050 #
1051 # For each platform, we need to know about any special compile and link
1052 # libraries, and whether the normal C function names are thread-safe.
1053 # See the comment at the top of src/port/thread.c for more information.
1054 # WIN32 doesn't need the pthread tests;  it always uses threads
1055 #
1056 # These tests are run before the library-tests, because linking with the
1057 # other libraries can pull in the pthread functions as a side-effect.  We
1058 # want to use the -pthread or similar flags directly, and not rely on
1059 # the side-effects of linking with some other library.
1060 #
1061 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1062 # invocation below is the first one in the script, and autoconf generates
1063 # additional code for that, which must not be inside the if-block. AS_IF
1064 # knows how to do that.
1065 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1066 [ # then
1067 AX_PTHREAD      # set thread flags
1068
1069 # Some platforms use these, so just define them.  They can't hurt if they
1070 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1071 # enables 5-arg getpwuid_r, among other things.
1072 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1073
1074 # Check for *_r functions
1075 _CFLAGS="$CFLAGS"
1076 _LIBS="$LIBS"
1077 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1078 LIBS="$LIBS $PTHREAD_LIBS"
1079
1080 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1081 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1082
1083 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1084
1085 # Do test here with the proper thread flags
1086 PGAC_FUNC_STRERROR_R_INT
1087
1088 CFLAGS="$_CFLAGS"
1089 LIBS="$_LIBS"
1090
1091 ], [ # else
1092 # do not use values from template file
1093 PTHREAD_CFLAGS=
1094 PTHREAD_LIBS=
1095 ]) # fi
1096
1097 AC_SUBST(PTHREAD_CFLAGS)
1098 AC_SUBST(PTHREAD_LIBS)
1099
1100
1101 ##
1102 ## Libraries
1103 ##
1104 ## Most libraries are included only if they demonstrably provide a function
1105 ## we need, but libm is an exception: always include it, because there are
1106 ## too many compilers that play cute optimization games that will break
1107 ## probes for standard functions such as pow().
1108 ##
1109
1110 AC_CHECK_LIB(m, main)
1111 AC_SEARCH_LIBS(setproctitle, util)
1112 AC_SEARCH_LIBS(dlopen, dl)
1113 AC_SEARCH_LIBS(socket, [socket ws2_32])
1114 AC_SEARCH_LIBS(shl_load, dld)
1115 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1116 AC_SEARCH_LIBS(crypt, crypt)
1117 AC_SEARCH_LIBS(shm_open, rt)
1118 AC_SEARCH_LIBS(shm_unlink, rt)
1119 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1120 # Solaris:
1121 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1122 # Required for thread_test.c on Solaris
1123 AC_SEARCH_LIBS(sched_yield, rt)
1124 # Required for thread_test.c on Solaris 2.5:
1125 # Other ports use it too (HP-UX) so test unconditionally
1126 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1127 # Cygwin:
1128 AC_SEARCH_LIBS(shmget, cygipc)
1129
1130 if test "$with_readline" = yes; then
1131   PGAC_CHECK_READLINE
1132   if test x"$pgac_cv_check_readline" = x"no"; then
1133     AC_MSG_ERROR([readline library not found
1134 If you have readline already installed, see config.log for details on the
1135 failure.  It is possible the compiler isn't looking in the proper directory.
1136 Use --without-readline to disable readline support.])
1137   fi
1138 fi
1139
1140 if test "$with_zlib" = yes; then
1141   AC_CHECK_LIB(z, inflate, [],
1142                [AC_MSG_ERROR([zlib library not found
1143 If you have zlib already installed, see config.log for details on the
1144 failure.  It is possible the compiler isn't looking in the proper directory.
1145 Use --without-zlib to disable zlib support.])])
1146 fi
1147
1148 if test "$enable_spinlocks" = yes; then
1149   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1150 else
1151   AC_MSG_WARN([
1152 *** Not using spinlocks will cause poor performance.])
1153 fi
1154
1155 if test "$enable_atomics" = yes; then
1156   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1157 else
1158   AC_MSG_WARN([
1159 *** Not using atomic operations will cause poor performance.])
1160 fi
1161
1162 if test "$with_gssapi" = yes ; then
1163   if test "$PORTNAME" != "win32"; then
1164     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1165                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1166   else
1167     LIBS="$LIBS -lgssapi32"
1168   fi
1169 fi
1170
1171 if test "$with_openssl" = yes ; then
1172   dnl Order matters!
1173   if test "$PORTNAME" != "win32"; then
1174      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1175      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1176   else
1177      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1178      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1179   fi
1180   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1181   # Functions introduced in OpenSSL 1.1.0. We used to check for
1182   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1183   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1184   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1185   # functions.
1186   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1187   # OpenSSL versions before 1.1.0 required setting callback functions, for
1188   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1189   # function was removed.
1190   AC_CHECK_FUNCS([CRYPTO_lock])
1191 fi
1192
1193 if test "$with_pam" = yes ; then
1194   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1195 fi
1196
1197 if test "$with_libxml" = yes ; then
1198   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1199 fi
1200
1201 if test "$with_libxslt" = yes ; then
1202   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1203 fi
1204
1205 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1206 if test "$with_ldap" = yes ; then
1207   _LIBS="$LIBS"
1208   if test "$PORTNAME" != "win32"; then
1209     AC_CHECK_LIB(ldap, ldap_bind, [],
1210                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1211                  [$EXTRA_LDAP_LIBS])
1212     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1213     if test "$enable_thread_safety" = yes; then
1214       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1215       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1216                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1217                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1218       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1219     else
1220       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1221     fi
1222     AC_CHECK_FUNCS([ldap_initialize])
1223   else
1224     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1225     LDAP_LIBS_FE="-lwldap32"
1226     LDAP_LIBS_BE="-lwldap32"
1227   fi
1228   LIBS="$_LIBS"
1229 fi
1230 AC_SUBST(LDAP_LIBS_FE)
1231 AC_SUBST(LDAP_LIBS_BE)
1232
1233 # for contrib/sepgsql
1234 if test "$with_selinux" = yes; then
1235   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1236                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1237 fi
1238
1239 # for contrib/uuid-ossp
1240 if test "$with_uuid" = bsd ; then
1241   # On BSD, the UUID functions are in libc
1242   AC_CHECK_FUNC(uuid_to_string,
1243     [UUID_LIBS=""],
1244     [AC_MSG_ERROR([BSD UUID functions are not present])])
1245 elif test "$with_uuid" = e2fs ; then
1246   # On macOS, the UUID functions are in libc
1247   AC_CHECK_FUNC(uuid_generate,
1248     [UUID_LIBS=""],
1249     [AC_CHECK_LIB(uuid, uuid_generate,
1250       [UUID_LIBS="-luuid"],
1251       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1252 elif test "$with_uuid" = ossp ; then
1253   AC_CHECK_LIB(ossp-uuid, uuid_export,
1254     [UUID_LIBS="-lossp-uuid"],
1255     [AC_CHECK_LIB(uuid, uuid_export,
1256       [UUID_LIBS="-luuid"],
1257       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1258 fi
1259 AC_SUBST(UUID_LIBS)
1260
1261
1262 ##
1263 ## Header files
1264 ##
1265
1266 AC_HEADER_STDBOOL
1267
1268 AC_CHECK_HEADERS([atomic.h crypt.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/prctl.h sys/procctl.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1269
1270 # On BSD, test for net/if.h will fail unless sys/socket.h
1271 # is included first.
1272 AC_CHECK_HEADERS(net/if.h, [], [],
1273 [AC_INCLUDES_DEFAULT
1274 #include <sys/socket.h>
1275 ])
1276
1277 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1278 # is included first.
1279 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1280 [AC_INCLUDES_DEFAULT
1281 #include <sys/param.h>
1282 ])
1283
1284 # At least on IRIX, test for netinet/tcp.h will fail unless
1285 # netinet/in.h is included first.
1286 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1287 [AC_INCLUDES_DEFAULT
1288 #include <netinet/in.h>
1289 ])
1290
1291 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1292   AC_CHECK_HEADERS(readline/readline.h, [],
1293         [AC_CHECK_HEADERS(readline.h, [],
1294                 [AC_MSG_ERROR([readline header not found
1295 If you have readline already installed, see config.log for details on the
1296 failure.  It is possible the compiler isn't looking in the proper directory.
1297 Use --without-readline to disable readline support.])])])
1298   AC_CHECK_HEADERS(readline/history.h, [],
1299         [AC_CHECK_HEADERS(history.h, [],
1300                 [AC_MSG_ERROR([history header not found
1301 If you have readline already installed, see config.log for details on the
1302 failure.  It is possible the compiler isn't looking in the proper directory.
1303 Use --without-readline to disable readline support.])])])
1304 fi
1305
1306 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1307 # Some installations of libedit usurp /usr/include/readline/, which seems
1308 # bad practice, since in combined installations readline will have its headers
1309 # there.  We might have to resort to AC_EGREP checks to make sure we found
1310 # the proper header...
1311   AC_CHECK_HEADERS(editline/readline.h, [],
1312         [AC_CHECK_HEADERS(readline.h, [],
1313                 [AC_CHECK_HEADERS(readline/readline.h, [],
1314                         [AC_MSG_ERROR([readline header not found
1315 If you have libedit already installed, see config.log for details on the
1316 failure.  It is possible the compiler isn't looking in the proper directory.
1317 Use --without-readline to disable libedit support.])])])])
1318 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1319 # not be there at all.  Hence, don't complain if not found.  We must check
1320 # though, since in yet other versions it is an independent header.
1321   AC_CHECK_HEADERS(editline/history.h, [],
1322         [AC_CHECK_HEADERS(history.h, [],
1323                 [AC_CHECK_HEADERS(readline/history.h)])])
1324 fi
1325
1326 if test "$with_zlib" = yes; then
1327   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1328 If you have zlib already installed, see config.log for details on the
1329 failure.  It is possible the compiler isn't looking in the proper directory.
1330 Use --without-zlib to disable zlib support.])])
1331 fi
1332
1333 if test "$with_gssapi" = yes ; then
1334   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1335         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1336 fi
1337
1338 if test "$with_openssl" = yes ; then
1339   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1340   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1341 fi
1342
1343 if test "$with_pam" = yes ; then
1344   AC_CHECK_HEADERS(security/pam_appl.h, [],
1345                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1346                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1347 fi
1348
1349 if test "$with_bsd_auth" = yes ; then
1350   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1351 fi
1352
1353 if test "$with_systemd" = yes ; then
1354   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1355 fi
1356
1357 if test "$with_libxml" = yes ; then
1358   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1359 fi
1360
1361 if test "$with_libxslt" = yes ; then
1362   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1363 fi
1364
1365 if test "$with_ldap" = yes ; then
1366   if test "$PORTNAME" != "win32"; then
1367      AC_CHECK_HEADERS(ldap.h, [],
1368                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1369      PGAC_LDAP_SAFE
1370   else
1371      AC_CHECK_HEADERS(winldap.h, [],
1372                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1373                       [AC_INCLUDES_DEFAULT
1374 #include <windows.h>
1375                       ])
1376   fi
1377 fi
1378
1379 if test "$with_bonjour" = yes ; then
1380   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1381 dnl At some point we might add something like
1382 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1383 dnl but right now, what that would mainly accomplish is to encourage
1384 dnl people to try to use the avahi implementation, which does not work.
1385 dnl If you want to use Apple's own Bonjour code on another platform,
1386 dnl just add -ldns_sd to LIBS manually.
1387 fi
1388
1389 # for contrib/uuid-ossp
1390 if test "$with_uuid" = bsd ; then
1391   AC_CHECK_HEADERS(uuid.h,
1392     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1393       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1394     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1395 elif test "$with_uuid" = e2fs ; then
1396   AC_CHECK_HEADERS(uuid/uuid.h,
1397     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1398       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1399     [AC_CHECK_HEADERS(uuid.h,
1400       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1401         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1402       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1403 elif test "$with_uuid" = ossp ; then
1404   AC_CHECK_HEADERS(ossp/uuid.h,
1405     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1406       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1407     [AC_CHECK_HEADERS(uuid.h,
1408       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1409         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1410       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1411 fi
1412
1413 if test "$PORTNAME" = "win32" ; then
1414    AC_CHECK_HEADERS(crtdefs.h)
1415 fi
1416
1417 ##
1418 ## Types, structures, compiler characteristics
1419 ##
1420
1421 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1422 AC_C_BIGENDIAN
1423 AC_C_INLINE
1424 PGAC_PRINTF_ARCHETYPE
1425 AC_C_FLEXIBLE_ARRAY_MEMBER
1426 PGAC_C_SIGNED
1427 PGAC_C_FUNCNAME_SUPPORT
1428 PGAC_C_STATIC_ASSERT
1429 PGAC_C_TYPEOF
1430 PGAC_C_TYPES_COMPATIBLE
1431 PGAC_C_BUILTIN_BSWAP16
1432 PGAC_C_BUILTIN_BSWAP32
1433 PGAC_C_BUILTIN_BSWAP64
1434 PGAC_C_BUILTIN_CONSTANT_P
1435 PGAC_C_BUILTIN_UNREACHABLE
1436 PGAC_C_COMPUTED_GOTO
1437 PGAC_C_VA_ARGS
1438 PGAC_STRUCT_TIMEZONE
1439 PGAC_UNION_SEMUN
1440 PGAC_STRUCT_SOCKADDR_UN
1441 PGAC_STRUCT_SOCKADDR_STORAGE
1442 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1443 PGAC_STRUCT_ADDRINFO
1444 AC_TYPE_INTPTR_T
1445 AC_TYPE_UINTPTR_T
1446 AC_TYPE_LONG_LONG_INT
1447
1448 PGAC_TYPE_LOCALE_T
1449
1450 # MSVC doesn't cope well with defining restrict to __restrict, the
1451 # spelling it understands, because it conflicts with
1452 # __declspec(restrict). Therefore we define pg_restrict to the
1453 # appropriate definition, which presumably won't conflict.
1454 #
1455 # Allow platforms with buggy compilers to force restrict to not be
1456 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1457 # template.
1458 AC_C_RESTRICT
1459 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1460   pg_restrict=""
1461 else
1462   pg_restrict="$ac_cv_c_restrict"
1463 fi
1464 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1465 [Define to keyword to use for C99 restrict support, or to nothing if not
1466 supported])
1467
1468 AC_CHECK_TYPES([struct cmsgcred], [], [],
1469 [#include <sys/socket.h>
1470 #include <sys/param.h>
1471 #ifdef HAVE_SYS_UCRED_H
1472 #include <sys/ucred.h>
1473 #endif])
1474
1475 AC_CHECK_TYPES([struct option], [], [],
1476 [#ifdef HAVE_GETOPT_H
1477 #include <getopt.h>
1478 #endif])
1479
1480 if test "$with_zlib" = yes; then
1481   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1482   # did not).  While we could work around the lack of z_streamp, it
1483   # seems unwise to encourage people to use such old zlib versions...
1484   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1485 Use --without-zlib to disable zlib support.])],
1486                 [#include <zlib.h>])
1487 fi
1488
1489 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1490 case $host_cpu in
1491   ppc*|powerpc*)
1492     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1493     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1494         [int a = 0; int *p = &a; int r;
1495          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1496         [pgac_cv_have_ppc_mutex_hint=yes],
1497         [pgac_cv_have_ppc_mutex_hint=no])
1498     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1499     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1500         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1501     fi
1502   ;;
1503 esac
1504
1505 # Check largefile support.  You might think this is a system service not a
1506 # compiler characteristic, but you'd be wrong.  We must check this before
1507 # probing existence of related functions such as fseeko, since the largefile
1508 # defines can affect what is generated for that.
1509 if test "$PORTNAME" != "win32"; then
1510    AC_SYS_LARGEFILE
1511    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1512    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1513    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1514    dnl versions where the feature actually works, it's on by default anyway.
1515    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1516 fi
1517
1518 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1519 AC_CHECK_SIZEOF([off_t])
1520
1521 # If we don't have largefile support, can't handle segsize >= 2GB.
1522 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1523    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1524 fi
1525
1526 AC_CHECK_SIZEOF([bool], [],
1527 [#ifdef HAVE_STDBOOL_H
1528 #include <stdbool.h>
1529 #endif])
1530
1531
1532 ##
1533 ## Functions, global variables
1534 ##
1535
1536 PGAC_VAR_INT_TIMEZONE
1537 AC_FUNC_ACCEPT_ARGTYPES
1538 PGAC_FUNC_GETTIMEOFDAY_1ARG
1539 PGAC_FUNC_WCSTOMBS_L
1540
1541 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1542 # symbols that that library has no business exposing to the world.  Pending
1543 # acquisition of a clue by those developers, ignore libedit (including its
1544 # possible alias of libreadline) while checking for everything else.
1545 LIBS_including_readline="$LIBS"
1546 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1547
1548 AC_CHECK_FUNCS([cbrt clock_gettime dlopen fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate pstat pthread_is_threaded_np readlink setproctitle setproctitle_fast setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1549
1550 AC_REPLACE_FUNCS(fseeko)
1551 case $host_os in
1552         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1553         # Mingw uses macros to access Win32 API calls
1554         netbsd*|mingw*)
1555                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1556                 ac_cv_func_fseeko=yes;;
1557         *)
1558                 AC_FUNC_FSEEKO;;
1559 esac
1560
1561 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1562 # by calling it, 2009-04-02
1563 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1564 if test "$PORTNAME" != "solaris"; then
1565 AC_CHECK_FUNCS(posix_fadvise)
1566 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1567 fi
1568
1569 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1570 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1571 # This is probably only present on macOS, but may as well check always
1572 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1573
1574 HAVE_IPV6=no
1575 AC_CHECK_TYPE([struct sockaddr_in6],
1576         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1577          HAVE_IPV6=yes],
1578         [],
1579 [$ac_includes_default
1580 #include <netinet/in.h>])
1581 AC_SUBST(HAVE_IPV6)
1582
1583 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1584 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1585 [#include <machine/vmparam.h>
1586 #include <sys/exec.h>
1587 ],
1588 [PS_STRINGS->ps_nargvstr = 1;
1589 PS_STRINGS->ps_argvstr = "foo";])],
1590 [pgac_cv_var_PS_STRINGS=yes],
1591 [pgac_cv_var_PS_STRINGS=no])])
1592 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1593   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1594 fi
1595
1596
1597 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1598 # is missing.  Yes, there are machines that have only one.  We may
1599 # also decide to use snprintf.c if snprintf() is present but does not
1600 # have all the features we need --- see below.
1601
1602 if test "$PORTNAME" = "win32"; then
1603   # Win32 gets snprintf.c built unconditionally.
1604   #
1605   # To properly translate all NLS languages strings, we must support the
1606   # *printf() %$ format, which allows *printf() arguments to be selected
1607   # by position in the translated string.
1608   #
1609   # libintl versions < 0.13 use the native *printf() functions, and Win32
1610   # *printf() doesn't understand %$, so we must use our /port versions,
1611   # which do understand %$. libintl versions >= 0.13 include their own
1612   # *printf versions on Win32.  The libintl 0.13 release note text is:
1613   #
1614   #   C format strings with positions, as they arise when a translator
1615   #   needs to reorder a sentence, are now supported on all platforms.
1616   #   On those few platforms (NetBSD and Woe32) for which the native
1617   #   printf()/fprintf()/... functions don't support such format
1618   #   strings, replacements are provided through <libintl.h>.
1619   #
1620   # We could use libintl >= 0.13's *printf() if we were sure that we had
1621   # a libintl >= 0.13 at runtime, but seeing that there is no clean way
1622   # to guarantee that, it is best to just use our own, so we are sure to
1623   # get %$ support. In include/port.h we disable the *printf() macros
1624   # that might have been defined by libintl.
1625   #
1626   # We do this unconditionally whether NLS is used or not so we are sure
1627   # that all Win32 libraries and binaries behave the same.
1628   pgac_need_repl_snprintf=yes
1629 else
1630   pgac_need_repl_snprintf=no
1631   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1632   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1633 fi
1634
1635
1636 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1637 # include/c.h will provide declarations.  Note this is a separate test
1638 # from whether the functions exist in the C library --- there are
1639 # systems that have the functions but don't bother to declare them :-(
1640
1641 AC_CHECK_DECLS([snprintf, vsnprintf])
1642
1643
1644 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1645 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1646 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1647 #include <math.h>
1648 double glob_double;
1649 ],
1650 [return isinf(glob_double) ? 0 : 1;])],
1651 [ac_cv_func_isinf=yes],
1652 [ac_cv_func_isinf=no])])
1653
1654 if test $ac_cv_func_isinf = yes ; then
1655   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1656 else
1657   AC_LIBOBJ(isinf)
1658   # Look for a way to implement a substitute for isinf()
1659   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1660 fi
1661
1662 AC_REPLACE_FUNCS([crypt fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1663
1664 case $host_os in
1665
1666         # Windows uses a specialised env handler
1667         # and doesn't need a replacement getpeereid because it doesn't use
1668         # Unix sockets.
1669         mingw*)
1670                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1671                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1672                 ac_cv_func_unsetenv=yes
1673                 ac_cv_func_getpeereid=yes;;
1674         *)
1675                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1676                 ;;
1677 esac
1678
1679 # System's version of getaddrinfo(), if any, may be used only if we found
1680 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1681 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1682 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1683    test "$PORTNAME" != "win32"; then
1684   AC_REPLACE_FUNCS([getaddrinfo])
1685 else
1686   AC_LIBOBJ(getaddrinfo)
1687 fi
1688
1689 # Similarly, use system's getopt_long() only if system provides struct option.
1690 if test x"$ac_cv_type_struct_option" = xyes ; then
1691   AC_REPLACE_FUNCS([getopt_long])
1692 else
1693   AC_LIBOBJ(getopt_long)
1694 fi
1695
1696 # Solaris' getopt() doesn't do what we want for long options, so always use
1697 # our version on that platform.
1698 if test "$PORTNAME" = "solaris"; then
1699   AC_LIBOBJ(getopt)
1700 fi
1701
1702 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1703 # so always use our version on Windows.
1704 if test "$PORTNAME" = "win32"; then
1705   AC_LIBOBJ(getopt)
1706   AC_LIBOBJ(getopt_long)
1707 fi
1708
1709 # Win32 (really MinGW) support
1710 if test "$PORTNAME" = "win32"; then
1711   AC_REPLACE_FUNCS(gettimeofday)
1712   AC_LIBOBJ(dirmod)
1713   AC_LIBOBJ(kill)
1714   AC_LIBOBJ(open)
1715   AC_LIBOBJ(system)
1716   AC_LIBOBJ(win32env)
1717   AC_LIBOBJ(win32error)
1718   AC_LIBOBJ(win32security)
1719   AC_LIBOBJ(win32setlocale)
1720   AC_DEFINE([HAVE_SYMLINK], 1,
1721             [Define to 1 if you have the `symlink' function.])
1722   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1723 #define WIN32_LEAN_AND_MEAN
1724 #include <windows.h>
1725 #include <string.h>
1726 #include <dbghelp.h>])
1727 fi
1728 if test x"$pgac_minidump_type" = x"yes" ; then
1729   AC_SUBST(have_win32_dbghelp,yes)
1730 else
1731   AC_SUBST(have_win32_dbghelp,no)
1732 fi
1733
1734 # Cygwin needs only a bit of that
1735 if test "$PORTNAME" = "cygwin"; then
1736   AC_LIBOBJ(dirmod)
1737 fi
1738
1739 AC_CHECK_DECLS([sys_siglist], [], [],
1740 [#include <signal.h>
1741 /* NetBSD declares sys_siglist in unistd.h.  */
1742 #ifdef HAVE_UNISTD_H
1743 # include <unistd.h>
1744 #endif
1745 ])
1746
1747 AC_CHECK_FUNC(syslog,
1748               [AC_CHECK_HEADER(syslog.h,
1749                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1750
1751 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1752 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1753   [extern int opterr; opterr = 1;])],
1754   [pgac_cv_var_int_opterr=yes],
1755   [pgac_cv_var_int_opterr=no])])
1756 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1757   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1758 fi
1759
1760 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1761 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1762   [extern int optreset; optreset = 1;])],
1763   [pgac_cv_var_int_optreset=yes],
1764   [pgac_cv_var_int_optreset=no])])
1765 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1766   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1767 fi
1768
1769 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1770 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1771 # strto[u]ll may exist but not be declared
1772 AC_CHECK_DECLS([strtoll, strtoull])
1773
1774 if test "$with_icu" = yes; then
1775   ac_save_CPPFLAGS=$CPPFLAGS
1776   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1777
1778   # Verify we have ICU's header files
1779   AC_CHECK_HEADER(unicode/ucol.h, [],
1780         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1781
1782   CPPFLAGS=$ac_save_CPPFLAGS
1783 fi
1784
1785 # Lastly, restore full LIBS list and check for readline/libedit symbols
1786 LIBS="$LIBS_including_readline"
1787
1788 if test "$with_readline" = yes; then
1789   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1790   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1791   AC_CHECK_FUNCS([append_history history_truncate_file])
1792 fi
1793
1794
1795 # This test makes sure that run tests work at all.  Sometimes a shared
1796 # library is found by the linker, but the runtime linker can't find it.
1797 # This check should come after all modifications of compiler or linker
1798 # variables, and before any other run tests.
1799 AC_MSG_CHECKING([test program])
1800 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1801 [AC_MSG_RESULT(ok)],
1802 [AC_MSG_RESULT(failed)
1803 AC_MSG_ERROR([[
1804 Could not execute a simple test program.  This may be a problem
1805 related to locating shared libraries.  Check the file 'config.log'
1806 for the exact reason.]])],
1807 [AC_MSG_RESULT([cross-compiling])])
1808
1809 # --------------------
1810 # Run tests below here
1811 # --------------------
1812
1813 # For NLS, force use of our snprintf if system's doesn't do arg control.
1814 # See comment above at snprintf test for details.
1815 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1816   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1817   if test $pgac_cv_snprintf_arg_control != yes ; then
1818     pgac_need_repl_snprintf=yes
1819   fi
1820 fi
1821
1822
1823 dnl Check to see if we have a working 64-bit integer type.
1824 dnl Since Postgres 8.4, we no longer support compilers without a working
1825 dnl 64-bit type; but we have to determine whether that type is called
1826 dnl "long int" or "long long int".
1827
1828 PGAC_TYPE_64BIT_INT([long int])
1829
1830 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1831   pg_int64_type="long int"
1832 else
1833   PGAC_TYPE_64BIT_INT([long long int])
1834   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1835     pg_int64_type="long long int"
1836   else
1837     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1838   fi
1839 fi
1840
1841 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1842   [Define to the name of a signed 64-bit integer type.])
1843
1844 # Select the printf length modifier that goes with that, too.
1845 # (This used to be bound up with replacement-snprintf selection, but now
1846 # we assume that the native *printf functions use standard length modifiers.)
1847 if test x"$pg_int64_type" = x"long long int" ; then
1848   INT64_MODIFIER='"ll"'
1849 else
1850   INT64_MODIFIER='"l"'
1851 fi
1852
1853 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1854                    [Define to the appropriate printf length modifier for 64-bit ints.])
1855
1856 # Force use of our snprintf if the system's doesn't support the %z flag.
1857 # (Note this test uses PG_INT64_TYPE and INT64_MODIFIER.)
1858 if test "$pgac_need_repl_snprintf" = no; then
1859   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1860   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1861     pgac_need_repl_snprintf=yes
1862   fi
1863 fi
1864
1865 # Force use of our snprintf if the system's doesn't handle buffer overrun
1866 # as specified by C99.
1867 if test "$pgac_need_repl_snprintf" = no; then
1868   PGAC_FUNC_SNPRINTF_C99_RESULT
1869   if test "$pgac_cv_snprintf_c99_result" != yes; then
1870     pgac_need_repl_snprintf=yes
1871   fi
1872 fi
1873
1874 # Now we have checked all the reasons to replace snprintf
1875 if test $pgac_need_repl_snprintf = yes; then
1876   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1877   AC_LIBOBJ(snprintf)
1878 fi
1879
1880 # has to be down here, rather than with the other builtins, because
1881 # the test uses PG_INT64_TYPE.
1882 PGAC_C_BUILTIN_OP_OVERFLOW
1883
1884 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1885 AC_CHECK_SIZEOF([void *])
1886 AC_CHECK_SIZEOF([size_t])
1887 AC_CHECK_SIZEOF([long])
1888
1889 # Decide whether float4 is passed by value: user-selectable, enabled by default
1890 AC_MSG_CHECKING([whether to build with float4 passed by value])
1891 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1892               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1893                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1894                float4passbyval=true],
1895               [float4passbyval=false])
1896 AC_MSG_RESULT([$enable_float4_byval])
1897 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1898
1899 # Decide whether float8 is passed by value.
1900 # Note: this setting also controls int8 and related types such as timestamp.
1901 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1902 # If not, trying to select it is an error.
1903 AC_MSG_CHECKING([whether to build with float8 passed by value])
1904 if test $ac_cv_sizeof_void_p -ge 8 ; then
1905   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1906 else
1907   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1908   if test "$enable_float8_byval" = yes ; then
1909     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1910   fi
1911 fi
1912 if test "$enable_float8_byval" = yes ; then
1913   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1914             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1915   float8passbyval=true
1916 else
1917   float8passbyval=false
1918 fi
1919 AC_MSG_RESULT([$enable_float8_byval])
1920 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1921
1922 # Determine memory alignment requirements for the basic C data types.
1923
1924 AC_CHECK_ALIGNOF(short)
1925 AC_CHECK_ALIGNOF(int)
1926 AC_CHECK_ALIGNOF(long)
1927 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1928   AC_CHECK_ALIGNOF(long long int)
1929 fi
1930 AC_CHECK_ALIGNOF(double)
1931
1932 # Compute maximum alignment of any basic type.
1933 # We assume long's alignment is at least as strong as char, short, or int;
1934 # but we must check long long (if it is being used for int64) and double.
1935 # Note that we intentionally do not consider any types wider than 64 bits,
1936 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1937 # for disk and memory space.
1938
1939 MAX_ALIGNOF=$ac_cv_alignof_long
1940 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1941   MAX_ALIGNOF=$ac_cv_alignof_double
1942 fi
1943 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1944   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1945 fi
1946 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1947
1948
1949 # Some platforms predefine the types int8, int16, etc.  Only check
1950 # a (hopefully) representative subset.
1951 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1952 [#include <stdio.h>])
1953
1954 # Some compilers offer a 128-bit integer scalar type.
1955 PGAC_TYPE_128BIT_INT
1956
1957 # Check for various atomic operations now that we have checked how to declare
1958 # 64bit integers.
1959 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1960 PGAC_HAVE_GCC__SYNC_INT32_TAS
1961 PGAC_HAVE_GCC__SYNC_INT32_CAS
1962 PGAC_HAVE_GCC__SYNC_INT64_CAS
1963 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1964 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1965
1966
1967 # Check for x86 cpuid instruction
1968 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1969 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1970   [[unsigned int exx[4] = {0, 0, 0, 0};
1971   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1972   ]])],
1973   [pgac_cv__get_cpuid="yes"],
1974   [pgac_cv__get_cpuid="no"])])
1975 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1976   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1977 fi
1978
1979 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1980 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1981   [[unsigned int exx[4] = {0, 0, 0, 0};
1982   __get_cpuid(exx[0], 1);
1983   ]])],
1984   [pgac_cv__cpuid="yes"],
1985   [pgac_cv__cpuid="no"])])
1986 if test x"$pgac_cv__cpuid" = x"yes"; then
1987   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1988 fi
1989
1990 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
1991 #
1992 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
1993 # with the default compiler flags. If not, check if adding the -msse4.2
1994 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
1995 PGAC_SSE42_CRC32_INTRINSICS([])
1996 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
1997   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
1998 fi
1999 AC_SUBST(CFLAGS_SSE42)
2000
2001 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
2002 # define __SSE4_2__ in that case.
2003 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2004 #ifndef __SSE4_2__
2005 #error __SSE4_2__ not defined
2006 #endif
2007 ])], [SSE4_2_TARGETED=1])
2008
2009 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
2010 #
2011 # First check if __crc32c* intrinsics can be used with the default compiler
2012 # flags. If not, check if adding -march=armv8-a+crc flag helps.
2013 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
2014 PGAC_ARMV8_CRC32C_INTRINSICS([])
2015 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
2016   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
2017 fi
2018 AC_SUBST(CFLAGS_ARMV8_CRC32C)
2019
2020 # Select CRC-32C implementation.
2021 #
2022 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
2023 # use the special CRC instructions for calculating CRC-32C. If we're not
2024 # targeting such a processor, but we can nevertheless produce code that uses
2025 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2026 # implementations and select which one to use at runtime, depending on whether
2027 # SSE 4.2 is supported by the processor we're running on.
2028 #
2029 # Similarly, if we are targeting an ARM processor that has the CRC
2030 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2031 # we're not targeting such a processor, but can nevertheless produce code that
2032 # uses the CRC instructions, compile both, and select at runtime.
2033 #
2034 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2035 # in the template or configure command line.
2036 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2037   # Use Intel SSE 4.2 if available.
2038   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2039     USE_SSE42_CRC32C=1
2040   else
2041     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2042     # the runtime check.
2043     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2044       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2045     else
2046       # Use ARM CRC Extension if available.
2047       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2048         USE_ARMV8_CRC32C=1
2049       else
2050         # ARM CRC Extension, with runtime check?
2051         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2052           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2053         else
2054           # fall back to slicing-by-8 algorithm, which doesn't require any
2055           # special CPU support.
2056           USE_SLICING_BY_8_CRC32C=1
2057         fi
2058       fi
2059     fi
2060   fi
2061 fi
2062
2063 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2064 AC_MSG_CHECKING([which CRC-32C implementation to use])
2065 if test x"$USE_SSE42_CRC32C" = x"1"; then
2066   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2067   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2068   AC_MSG_RESULT(SSE 4.2)
2069 else
2070   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2071     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2072     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2073     AC_MSG_RESULT(SSE 4.2 with runtime check)
2074   else
2075     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2076       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2077       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2078       AC_MSG_RESULT(ARMv8 CRC instructions)
2079     else
2080       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2081         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2082         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2083         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2084       else
2085         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2086         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2087         AC_MSG_RESULT(slicing-by-8)
2088       fi
2089     fi
2090   fi
2091 fi
2092 AC_SUBST(PG_CRC32C_OBJS)
2093
2094
2095 # Select semaphore implementation type.
2096 if test "$PORTNAME" != "win32"; then
2097   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2098     # Need sem_open for this
2099     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2100   fi
2101   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2102     # Need sem_init for this
2103     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2104   fi
2105   AC_MSG_CHECKING([which semaphore API to use])
2106   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2107     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2108     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2109     sematype="named POSIX"
2110   else
2111     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2112       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2113       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2114       sematype="unnamed POSIX"
2115     else
2116       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2117       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2118       sematype="System V"
2119     fi
2120   fi
2121   AC_MSG_RESULT([$sematype])
2122 else
2123   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2124   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2125 fi
2126
2127
2128 # Select shared-memory implementation type.
2129 if test "$PORTNAME" != "win32"; then
2130   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2131   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2132 else
2133   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2134   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2135 fi
2136
2137 # Select random number source
2138 #
2139 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2140 # in the template or configure command line.
2141
2142 # If not selected manually, try to select a source automatically.
2143 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2144   if test x"$with_openssl" = x"yes" ; then
2145     USE_OPENSSL_RANDOM=1
2146   elif test "$PORTNAME" = "win32" ; then
2147     USE_WIN32_RANDOM=1
2148   else
2149     AC_CHECK_FILE([/dev/urandom], [], [])
2150
2151     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2152       USE_DEV_URANDOM=1
2153     fi
2154   fi
2155 fi
2156
2157 AC_MSG_CHECKING([which random number source to use])
2158 if test "$enable_strong_random" = yes ; then
2159   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2160     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2161     AC_MSG_RESULT([OpenSSL])
2162   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2163     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2164     AC_MSG_RESULT([Windows native])
2165   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2166     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2167     AC_MSG_RESULT([/dev/urandom])
2168   else
2169     AC_MSG_ERROR([
2170 no source of strong random numbers was found
2171 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2172 for authentication protocols. You can use --disable-strong-random to use a
2173 built-in pseudo random number generator, but that may be insecure.])
2174   fi
2175   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2176 else
2177     AC_MSG_RESULT([weak builtin PRNG])
2178     AC_MSG_WARN([
2179 *** Not using a strong random number source may be insecure.])
2180 fi
2181
2182 # If not set in template file, set bytes to use libc memset()
2183 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2184   MEMSET_LOOP_LIMIT=1024
2185 fi
2186 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2187
2188
2189 if test "$enable_nls" = yes ; then
2190   PGAC_CHECK_GETTEXT
2191 fi
2192
2193 # Check for Tcl configuration script tclConfig.sh
2194 if test "$with_tcl" = yes; then
2195     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2196     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2197                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2198     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2199     if test "$TCL_SHARED_BUILD" != 1; then
2200       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2201 Use --without-tcl to disable building PL/Tcl.])
2202     fi
2203     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2204     ac_save_CPPFLAGS=$CPPFLAGS
2205     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2206     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2207     CPPFLAGS=$ac_save_CPPFLAGS
2208 fi
2209
2210 # check for <perl.h>
2211 if test "$with_perl" = yes; then
2212   ac_save_CPPFLAGS=$CPPFLAGS
2213   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2214   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2215                   [#include <EXTERN.h>])
2216   # While we're at it, check that we can link to libperl.
2217   # On most platforms, if perl.h is there then libperl.so will be too, but at
2218   # this writing Debian packages them separately.  There is no known reason to
2219   # waste cycles on separate probes for the Tcl or Python libraries, though.
2220   pgac_save_LIBS=$LIBS
2221   LIBS="$perl_embed_ldflags"
2222   AC_MSG_CHECKING([for libperl])
2223   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2224 #include <EXTERN.h>
2225 #include <perl.h>
2226 ],  [perl_alloc();])],
2227     [AC_MSG_RESULT(yes)],
2228     [AC_MSG_RESULT(no)
2229      AC_MSG_ERROR([libperl library is required for Perl])])
2230   LIBS=$pgac_save_LIBS
2231   CPPFLAGS=$ac_save_CPPFLAGS
2232 fi
2233
2234 # check for <Python.h>
2235 if test "$with_python" = yes; then
2236   ac_save_CPPFLAGS=$CPPFLAGS
2237   CPPFLAGS="$python_includespec $CPPFLAGS"
2238   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2239   CPPFLAGS=$ac_save_CPPFLAGS
2240 fi
2241
2242 #
2243 # Check for DocBook and tools
2244 #
2245 PGAC_PATH_XMLLINT
2246 PGAC_CHECK_DOCBOOK(4.2)
2247 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2248 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2249 PGAC_PATH_PROGS(FOP, fop)
2250
2251 #
2252 # Check for test tools
2253 #
2254 if test "$enable_tap_tests" = yes; then
2255   # Check for necessary modules, unless user has specified the "prove" to use;
2256   # in that case it's her responsibility to have a working configuration.
2257   # (prove might be part of a different Perl installation than perl, eg on
2258   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2259   if test -z "$PROVE"; then
2260     # Test::More and Time::HiRes are supposed to be part of core Perl,
2261     # but some distros omit them in a minimal installation.
2262     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2263       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2264   fi
2265   # Now make sure we know where prove is
2266   PGAC_PATH_PROGS(PROVE, prove)
2267   if test -z "$PROVE"; then
2268     AC_MSG_ERROR([prove not found])
2269   fi
2270 fi
2271
2272 # Thread testing
2273
2274 # We have to run the thread test near the end so we have all our symbols
2275 # defined.  Cross compiling throws a warning.
2276 #
2277 if test "$enable_thread_safety" = yes; then
2278 if test "$PORTNAME" != "win32"
2279 then
2280 AC_MSG_CHECKING([thread safety of required library functions])
2281
2282 _CFLAGS="$CFLAGS"
2283 _LIBS="$LIBS"
2284 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2285 LIBS="$LIBS $PTHREAD_LIBS"
2286 AC_RUN_IFELSE(
2287   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2288   [AC_MSG_RESULT(yes)],
2289   [AC_MSG_RESULT(no)
2290   AC_MSG_ERROR([thread test program failed
2291 This platform is not thread-safe.  Check the file 'config.log' or compile
2292 and run src/test/thread/thread_test for the exact reason.
2293 Use --disable-thread-safety to disable thread safety.])],
2294   [AC_MSG_RESULT(maybe)
2295   AC_MSG_WARN([
2296 *** Skipping thread test program because of cross-compile build.
2297 *** Run the program in src/test/thread on the target machine.
2298 ])])
2299 CFLAGS="$_CFLAGS"
2300 LIBS="$_LIBS"
2301 else
2302 AC_MSG_WARN([*** skipping thread test on Win32])
2303 fi
2304 fi
2305
2306 # If compiler will take -Wl,--as-needed (or various platform-specific
2307 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2308 # trying to filter LIBS to the minimum for each executable.
2309 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2310 # libreadline; therefore we postpone testing it until we know what library
2311 # dependencies readline has.  The test code will try to link with $LIBS.
2312 if test "$with_readline" = yes; then
2313   link_test_func=readline
2314 else
2315   link_test_func=exit
2316 fi
2317
2318 if test "$PORTNAME" = "darwin"; then
2319   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2320 elif test "$PORTNAME" = "openbsd"; then
2321   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2322 else
2323   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2324 fi
2325
2326 # Create compiler version string
2327 if test x"$GCC" = x"yes" ; then
2328   cc_string=`${CC} --version | sed q`
2329   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2330 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2331   cc_string=`${CC} -V 2>&1 | sed q`
2332 else
2333   cc_string=$CC
2334 fi
2335
2336 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2337                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2338                    [A string containing the version number, platform, and C compiler])
2339
2340 # Supply a numeric version string for use by 3rd party add-ons
2341 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2342 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2343 tr '.' '        ' |
2344 $AWK '{printf "%d%04d", $1, $2}'`"]
2345 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2346 AC_SUBST(PG_VERSION_NUM)
2347
2348
2349 # Begin output steps
2350
2351 AC_MSG_NOTICE([using compiler=$cc_string])
2352 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2353 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2354 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2355 # Currently only used when LLVM is used
2356 if test "$with_llvm" = yes ; then
2357    AC_MSG_NOTICE([using CXX=$CXX])
2358    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2359    AC_MSG_NOTICE([using CLANG=$CLANG])
2360    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2361    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2362 fi
2363
2364 # prepare build tree if outside source tree
2365 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2366 # Note 2: /bin/pwd might be better than shell's built-in at getting
2367 #         a symlink-free name.
2368 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2369   vpath_build=no
2370 else
2371   vpath_build=yes
2372   if test "$no_create" != yes; then
2373     _AS_ECHO_N([preparing build tree... ])
2374     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2375     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2376       || AC_MSG_ERROR(failed)
2377     AC_MSG_RESULT(done)
2378   fi
2379 fi
2380 AC_SUBST(vpath_build)
2381
2382
2383 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2384
2385 AC_CONFIG_LINKS([
2386   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
2387   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2388   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2389   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
2390   src/include/pg_config_os.h:src/include/port/${template}.h
2391   src/Makefile.port:src/makefiles/Makefile.${template}
2392 ])
2393
2394 if test "$PORTNAME" = "win32"; then
2395 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2396 # Links sometimes fail undetected on Mingw -
2397 # so here we detect it and warn the user
2398 for FILE in $CONFIG_LINKS
2399  do
2400         # test -e works for symlinks in the MinGW console
2401         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2402  done
2403 ])
2404 fi
2405
2406 AC_CONFIG_HEADERS([src/include/pg_config.h],
2407 [
2408 # Update timestamp for pg_config.h (see Makefile.global)
2409 echo >src/include/stamp-h
2410 ])
2411
2412 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2413 [
2414 # Update timestamp for pg_config_ext.h (see Makefile.global)
2415 echo >src/include/stamp-ext-h
2416 ])
2417
2418 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2419                   [echo >src/interfaces/ecpg/include/stamp-h])
2420
2421 AC_OUTPUT