granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1)
  65
  66 if test "$apr_found" = "no"; then
  67   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  68 fi
  69
  70 if test "$apr_found" = "reconfig"; then
  71   APR_SUBDIR_CONFIG(srclib/apr,
  72                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
  73                     [--enable-layout=*|\'--enable-layout=*])
  74   dnl We must be the first to build and the last to be cleaned
  75   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  76   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  77 fi
  78
  79 APR_SETIFNULL(CC, `$apr_config --cc`)
  80 APR_SETIFNULL(CPP, `$apr_config --cpp`)
  81 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  82 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  83 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  84 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  85 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  86 APR_BINDIR=`$apr_config --bindir`
  87 APR_INCLUDEDIR=`$apr_config --includedir`
  88 APR_VERSION=`$apr_config --version`
  89 APR_CONFIG="$APR_BINDIR/apr-`echo ${APR_VERSION} | sed 's,\..*,,'`-config"
  90
  91 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  92
  93 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1)
  94
  95 if test "$apu_found" = "no"; then
  96   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  97 fi
  98
  99 if test "$apu_found" = "reconfig"; then
 100   APR_SUBDIR_CONFIG(srclib/apr-util,
 101                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 102                     [--enable-layout=*|\'--enable-layout=*])
 103   dnl We must be the last to build and the first to be cleaned
 104   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 105   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 106 fi
 107
 108 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 109 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 110 APU_BINDIR=`$apu_config --bindir`
 111 APU_INCLUDEDIR=`$apu_config --includedir`
 112 APU_VERSION=`$apu_config --version`
 113 APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 114
 115 dnl In case we picked up CC and CPP from APR, get that info into the
 116 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 117 dnl PCRE and for our config tests will be whatever PCRE determines.
 118 AC_PROG_CC
 119 AC_PROG_CPP
 120
 121 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 122
 123 APR_SUBDIR_CONFIG(srclib/pcre,
 124                   [--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir])
 125
 126 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 127
 128 dnl Absolute source/build directory
 129 abs_srcdir=`(cd $srcdir && pwd)`
 130 abs_builddir=`pwd`
 131
 132 dnl If the source dir is not equal to the build dir,
 133 dnl then we are running in VPATH mode.
 134
 135 APR_ADDTO(INCLUDES, [-I.])
 136
 137 if test "$abs_builddir" != "$abs_srcdir"; then
 138   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 139 fi
 140
 141 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include -I\$(top_srcdir)/modules/generators -I\$(top_srcdir)/modules/mappers])
 142
 143 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 144
 145 case $host in
 146   *os2*)
 147       # Use a custom made libtool replacement
 148       echo "using aplibtool"
 149       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 150       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 151       SH_LIBS="\$(ALL_LIBS)"
 152       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 153       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 154       MK_IMPLIB="emximp"
 155       other_targets="$other_targets os2core"
 156       INSTALL_PROG_FLAGS="-e .exe"
 157       SHLTCFLAGS=""
 158       LTCFLAGS=""
 159       ;;
 160   *)
 161       if test "x$LTFLAGS" = "x"; then
 162           LTFLAGS='--silent'
 163       fi
 164       my_libtool=`$apr_config --apr-libtool`
 165       LIBTOOL="$my_libtool \$(LTFLAGS)"
 166       libtoolversion=`$my_libtool --version`
 167       case $libtoolversion in
 168           *1.[[45]]*)
 169               SH_LIBTOOL='$(LIBTOOL)'
 170               SHLTCFLAGS="-prefer-pic"
 171               LTCFLAGS="-prefer-non-pic -static"
 172               ;;
 173           *)
 174               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 175               SHLTCFLAGS=""
 176               LTCFLAGS=""
 177               ;;
 178       esac
 179       ;;
 180 esac
 181 APACHE_SUBST(SHLTCFLAGS)
 182 APACHE_SUBST(LTCFLAGS)
 183
 184 AP_SIG_GRACEFUL=USR1
 185
 186 case $host in
 187   *-apple-aux3*)
 188       APR_SETVAR(APACHE_MPM, [prefork])
 189       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 190       ;;
 191   *-beos*)
 192       APR_SETVAR(APACHE_MPM, [beos])
 193       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 194       ;;
 195   *os2_emx*)
 196       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 197       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 198       ;;
 199   *-linux-*)
 200       case `uname -r` in
 201         2.0* )
 202             AP_SIG_GRACEFUL=WINCH
 203             ;;
 204         2.[[2-9]]* )
 205             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 206             ;;
 207         * )
 208             ;;
 209       esac
 210       ;;
 211   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 212       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 213       ;;
 214   *-solaris2*)
 215       dnl This is a hack -- we should be using AC_TRY_RUN instead
 216       ap_platform_runtime_link_flag="-R"
 217       dnl solaris 8 and above don't have a thundering herd
 218       dnl not sure about rev's before this one.
 219       case `uname -r` in
 220         5.[567]*)
 221             ;;
 222         * )
 223             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 224             ;;
 225       esac
 226       ;;
 227   *cygwin*)
 228       APR_SETVAR(APACHE_MPM, [prefork])
 229       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 230       ;;
 231   *aix*)
 232       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 233       if test $aixver -ge 4320; then
 234         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 235       fi
 236       ;;
 237   *os390*)
 238       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 239       ;;
 240 esac
 241
 242 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 243
 244 dnl
 245 dnl Process command line arguments. This is done early in the process so the
 246 dnl user can get feedback quickly in case of an error.
 247 dnl
 248 dnl ### need to move some of the arguments "up here"
 249
 250 dnl ## Check for programs
 251
 252 AC_PATH_PROG(RM, rm)
 253 AC_PATH_PROG(PKGCONFIG, pkg-config)
 254 AC_PROG_AWK
 255 AC_PROG_INSTALL
 256 AC_PROG_LN_S
 257 AC_CHECK_TOOL(RANLIB, ranlib, true)
 258 dnl AC_PATH_PROG(PERL_PATH, perl)
 259 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 260
 261 dnl various OS checks that apparently set required flags
 262 AC_AIX
 263 AC_ISC_POSIX
 264 AC_MINIX
 265
 266 dnl Check for what we can generate dependency files with
 267 APR_CHECK_DEPEND
 268
 269 dnl ## Check for libraries
 270
 271 dnl ## Check for header files
 272
 273 dnl I think these are just used all over the place, so just check for
 274 dnl them at the base of the tree. If some are specific to a single
 275 dnl directory, they should be moved (Comment #Spoon)
 276
 277 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 278 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 279 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 280
 281 AC_HEADER_STDC
 282 AC_CHECK_HEADERS( \
 283 string.h \
 284 limits.h \
 285 unistd.h \
 286 sys/socket.h \
 287 pwd.h \
 288 grp.h \
 289 strings.h \
 290 sys/prctl.h \
 291 sys/processor.h \
 292 sys/sem.h
 293 )
 294 AC_HEADER_SYS_WAIT
 295
 296 dnl ## Check for typedefs, structures, and compiler characteristics.
 297
 298 AC_C_CONST
 299 if test "x$GCC" = "xyes"; then
 300   AC_DEFINE([AP_HAVE_DESIGNATED_INITIALIZER], 1,
 301             [Define if the compiler supports designated initializers])
 302 fi
 303
 304 dnl ## Check for library functions
 305 AC_SEARCH_LIBS(sqrt, m)
 306
 307 dnl See Comment #Spoon
 308
 309 AC_CHECK_FUNCS( \
 310 getpwnam \
 311 getgrnam \
 312 initgroups \
 313 bindprocessor \
 314 prctl \
 315 timegm \
 316 )
 317
 318 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 319 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 320 [AC_TRY_COMPILE([#include <sys/types.h>
 321 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 322   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 323 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 324     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 325 fi
 326
 327 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 328
 329 case $host in
 330     *aix*)
 331         # for 32-bit builds, increase MAXDATA to allow lots of threads
 332         if test x$OBJECT_MODE != x64; then
 333             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 334         fi
 335         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 336         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 337         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 338         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 339         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 340         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 341         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 342         ;;
 343     *os390*)
 344         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 345         ;;
 346     *)
 347         OS_SPECIFIC_VARS=""
 348 esac
 349
 350 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 351         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 352         [PORT=80])
 353
 354 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 355
 356 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 357 [
 358   v4mapped=$enableval
 359 ],
 360 [
 361     case $host in
 362     *freebsd5*|*netbsd*|*openbsd*)
 363         v4mapped=no
 364         ;;
 365     *)
 366         v4mapped=yes
 367         ;;
 368 esac
 369 ])
 370
 371 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 372     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 373               [Allow IPv4 connections on IPv6 listening sockets])
 374 fi
 375
 376 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 377 [
 378     AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 379               [Allow modules to run hook after a fatal exception])
 380 ])dnl
 381
 382 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 383 [
 384   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 385 ])dnl
 386
 387 prefix="$orig_prefix"
 388 APACHE_ENABLE_MODULES
 389
 390 dnl reading config stubs
 391 esyscmd(./build/config-stubs .)
 392
 393 APACHE_SUBST(progname)
 394 APACHE_SUBST(MPM_LIB)
 395 APACHE_SUBST(OS)
 396 APACHE_SUBST(OS_DIR)
 397 APACHE_SUBST(BUILTIN_LIBS)
 398 APACHE_SUBST(SHLIBPATH_VAR)
 399 APACHE_SUBST(OS_SPECIFIC_VARS)
 400
 401 PRE_SHARED_CMDS='echo ""'
 402 POST_SHARED_CMDS='echo ""'
 403
 404 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 405
 406 if test "$apache_need_shared" = "yes"; then
 407   if test -f $ac_aux_dir/ltconfig; then
 408     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 409   fi
 410   shared_build="shared-build"
 411 fi
 412
 413 dnl enable_so tells us if *any* modules can be built as DSOs
 414
 415 if test "$enable_so" = "yes"; then
 416   case $host in
 417     *-ibm-aix*)
 418       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 419       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 420       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 421       ;;
 422     *beos)
 423       SH_LDFLAGS='$(top_builddir)/_APP_'
 424       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 425       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 426       ;;
 427     *os390)
 428       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 429       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 430   esac
 431 fi
 432
 433 APACHE_SUBST(PRE_SHARED_CMDS)
 434 APACHE_SUBST(POST_SHARED_CMDS)
 435 APACHE_SUBST(shared_build)
 436
 437 AC_ARG_WITH(program-name,
 438 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 439   progname="$withval" ], [
 440   progname="httpd"] )
 441
 442 # SuExec parameters
 443 AC_ARG_WITH(suexec-bin,
 444 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 445   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 446 ] )
 447
 448 AC_ARG_WITH(suexec-caller,
 449 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 450   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 451
 452 AC_ARG_WITH(suexec-userdir,
 453 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 454   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 455
 456 AC_ARG_WITH(suexec-docroot,
 457 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 458   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 459
 460 AC_ARG_WITH(suexec-uidmin,
 461 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 462   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 463
 464 AC_ARG_WITH(suexec-gidmin,
 465 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 466   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 467
 468 AC_ARG_WITH(suexec-logfile,
 469 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 470   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 471
 472 AC_ARG_WITH(suexec-safepath,
 473 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 474   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 475
 476 AC_ARG_WITH(suexec-umask,
 477 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 478   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 479
 480 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 481 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 482
 483 dnl APR should go after the other libs, so the right symbols can be picked up
 484 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 485 APACHE_SUBST(AP_LIBS)
 486 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 487 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 488
 489 AC_DEFINE(AP_USING_AUTOCONF, 1,
 490                 [Using autoconf to configure Apache])
 491
 492 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 493     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 494               [This platform doesn't suffer from the thundering herd problem])
 495 fi
 496
 497 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 498     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 499               [Listening sockets are non-blocking when there are more than 1])
 500 fi
 501
 502 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 503 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 504 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 505 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 506 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 507 AC_SUBST(AP_SIG_GRACEFUL)
 508 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 509 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 510
 511 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 512 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 513 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 514
 515 if test -d ./test; then
 516     APACHE_FAST_OUTPUT(test/Makefile)
 517 fi
 518
 519 dnl ## Finalize the variables
 520 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 521
 522 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 523 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 524 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 525 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 526 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 527 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 528
 529 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 530
 531 APACHE_GEN_CONFIG_VARS
 532
 533 dnl ## Build modules.c
 534 rm -f modules.c
 535 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 536
 537 APR_EXPAND_VAR(ap_prefix, $prefix)
 538 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 539         [Root directory of the Apache install area])
 540 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 541         [Location of the config file, relative to the Apache root directory])
 542 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 543         [Location of the MIME types config file, relative to the Apache root directory])
 544 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 545         [Location of the source for the current MPM])
 546
 547 perlbin=`$ac_aux_dir/PrintPath perl`
 548 if test "x$perlbin" = "x"; then
 549     perlbin="/replace/with/path/to/perl/interpreter"
 550 fi
 551 AC_SUBST(perlbin)
 552
 553 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 554
 555 BSD_MAKEFILE=no
 556 ap_make_include=include
 557 ap_make_delimiter=' '
 558 case $host in
 559 *bsdi*)
 560     # Check whether they've installed GNU make
 561     if make --version > /dev/null 2>&1; then
 562         true
 563     else
 564         BSD_MAKEFILE=yes
 565         ap_make_include=.include
 566         ap_make_delimiter='"'
 567     fi
 568     ;;
 569 esac
 570 AC_SUBST(ap_make_include)
 571 AC_SUBST(ap_make_delimiter)
 572
 573 dnl Ensure that docs/conf is created.
 574 test -d docs/conf||$mkdir_p docs/conf
 575
 576 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf docs/conf/ssl-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 577   APACHE_GEN_MAKEFILES
 578 ])
 579