granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.368 2004/07/17 18:53:56 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [7.5devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix ;;
  60    linux*) template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      qnx*) template=qnx4 ;;
  67      sco*) template=sco ;;
  68  solaris*) template=solaris ;;
  69    sunos*) template=sunos4 ;;
  70  sysv4.2*)
  71         case $host_vendor in
  72           univel) template=univel ;;
  73         esac ;;
  74    sysv4*) template=svr4 ;;
  75    sysv5*) template=unixware ;;
  76   ultrix*) template=ultrix4 ;;
  77 esac
  78
  79   if test x"$template" = x"" ; then
  80     AC_MSG_ERROR([[
  81 *******************************************************************
  82 PostgreSQL has apparently not been ported to your platform yet.
  83 To try a manual configuration, look into the src/template directory
  84 for a similar platform and use the '--with-template=' option.
  85
  86 Please also contact <pgsql-ports@postgresql.org> to see about
  87 rectifying this.  Include the above 'checking host system type...'
  88 line.
  89 *******************************************************************
  90 ]])
  91   fi
  92
  93 ])
  94
  95 AC_MSG_RESULT([$template])
  96
  97 PORTNAME=$template
  98 AC_SUBST(PORTNAME)
  99
 100 # Initialize default assumption that we do not need separate assembly code
 101 # for TAS (test-and-set).  This can be overridden by the template file
 102 # when it's executed.
 103 need_tas=no
 104 tas_file=dummy.s
 105
 106
 107
 108 ##
 109 ## Command line options
 110 ##
 111
 112 #
 113 # Installation directory for documentation
 114 #
 115 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 116   --without-docdir        do not install the documentation],
 117          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 118          [docdir=],
 119          [docdir=$withval],
 120          [docdir='${prefix}/doc'])
 121 AC_SUBST(docdir)
 122
 123
 124 #
 125 # Add non-standard directories to the include path
 126 #
 127 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 128
 129
 130 #
 131 # Add non-standard directories to the library search path
 132 #
 133 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 134              [LIBRARY_DIRS=$withval])
 135
 136 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 137              [LIBRARY_DIRS=$withval])
 138
 139
 140 #
 141 # 64-bit integer date/time storage (--enable-integer-datetimes)
 142 #
 143 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 144 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 145               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 146                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 147 AC_MSG_RESULT([$enable_integer_datetimes])
 148
 149
 150 #
 151 # NLS
 152 #
 153 AC_MSG_CHECKING([whether NLS is wanted])
 154 PGAC_ARG_OPTARG(enable, nls,
 155                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 156                 [],
 157                 [WANTED_LANGUAGES=$enableval],
 158                 [AC_DEFINE(ENABLE_NLS, 1,
 159                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 160 AC_MSG_RESULT([$enable_nls])
 161 AC_SUBST(enable_nls)
 162 AC_SUBST(WANTED_LANGUAGES)
 163
 164 #
 165 # Default port number (--with-pgport), default 5432
 166 #
 167 AC_MSG_CHECKING([for default port number])
 168 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 169              [default_port=$withval],
 170              [default_port=5432])
 171 AC_MSG_RESULT([$default_port])
 172 # Need both of these because some places want an integer and some a string
 173 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 174 [Define to the default TCP port number on which the server listens and
 175 to which clients will try to connect.  This can be overridden at run-time,
 176 but it's convenient if your clients have the right default compiled in.
 177 (--with-pgport=PORTNUM)])
 178 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 179                    [Define to the default TCP port number as a string constant.])
 180 AC_SUBST(default_port)
 181
 182 #
 183 # Option to disable shared libraries
 184 #
 185 PGAC_ARG_BOOL(enable, shared, yes,
 186               [  --disable-shared        do not build shared libraries])
 187 AC_SUBST(enable_shared)
 188
 189 #
 190 # '-rpath'-like feature can be disabled
 191 #
 192 PGAC_ARG_BOOL(enable, rpath, yes,
 193               [  --disable-rpath         do not embed shared library search path in executables])
 194 AC_SUBST(enable_rpath)
 195
 196 #
 197 # Spinlocks
 198 #
 199 PGAC_ARG_BOOL(enable, spinlocks, yes,
 200               [  --disable-spinlocks     do not use spinlocks])
 201
 202 #
 203 # --enable-debug adds -g to compiler flags
 204 #
 205 PGAC_ARG_BOOL(enable, debug, no,
 206               [  --enable-debug          build with debugging symbols (-g)])
 207 AC_SUBST(enable_debug)
 208
 209 #
 210 # C compiler
 211 #
 212
 213 # For historical reasons you can also use --with-CC to specify the C compiler
 214 # to use, although the standard way to do this is to set the CC environment
 215 # variable.
 216 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 217
 218 case $template in
 219   aix) pgac_cc_list="gcc xlc";;
 220  irix) pgac_cc_list="cc";; # no gcc
 221     *) pgac_cc_list="gcc cc";;
 222 esac
 223
 224 AC_PROG_CC([$pgac_cc_list])
 225
 226 unset CFLAGS
 227
 228 #
 229 # Read the template
 230 #
 231 . "$srcdir/src/template/$template" || exit
 232
 233 # CFLAGS are selected so:
 234 # If the user specifies something in the environment, that is used.
 235 # else:  If the template file set something, that is used.
 236 # else:  If the compiler is GCC, then we use -O2.
 237 # else:  If the compiler is something else, then we use -0.
 238
 239 if test "$ac_env_CFLAGS_set" = set; then
 240   CFLAGS=$ac_env_CFLAGS_value
 241 elif test "${CFLAGS+set}" = set; then
 242   : # (keep what template set)
 243 elif test "$GCC" = yes; then
 244   CFLAGS="-O2"
 245 else
 246   # if the user selected debug mode, don't use -O
 247   if test "$enable_debug" != yes; then
 248     CFLAGS="-O"
 249   fi
 250 fi
 251
 252 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 253 PGAC_PROG_CC_NO_STRICT_ALIASING
 254
 255 # supply -g if --enable-debug
 256 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 257   CFLAGS="$CFLAGS -g"
 258 fi
 259
 260 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 261
 262 # We already have this in Makefile.win32, but configure needs it too
 263 if test "$PORTNAME" = "win32"; then
 264   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 265 fi
 266
 267 # Check if the compiler still works with the template settings
 268 AC_MSG_CHECKING([whether the C compiler still works])
 269 AC_TRY_LINK([], [return 0;],
 270   [AC_MSG_RESULT(yes)],
 271   [AC_MSG_RESULT(no)
 272    AC_MSG_ERROR([cannot proceed])])
 273
 274 # Defend against gcc -ffast-math
 275 if test "$GCC" = yes; then
 276 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 277 choke me
 278 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 279 fi
 280
 281 AC_PROG_CPP
 282 AC_SUBST(GCC)
 283
 284 # Create compiler version string
 285 if test x"$GCC" = x"yes" ; then
 286   cc_string="GCC `${CC} --version | sed q`"
 287 else
 288   cc_string=$CC
 289 fi
 290 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 291                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 292                    [A string containing the version number, platform, and C compiler])
 293
 294
 295 #
 296 # Set up TAS assembly code if needed; the template file has now had its
 297 # chance to request this.
 298 #
 299 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 300
 301 if test "$need_tas" = yes ; then
 302   TAS=tas.o
 303 else
 304   TAS=""
 305 fi
 306 AC_SUBST(TAS)
 307
 308
 309 #
 310 # Automatic dependency tracking
 311 #
 312 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 313               [autodepend=yes])
 314 AC_SUBST(autodepend)
 315
 316
 317 #
 318 # Enable assert checks
 319 #
 320 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 321               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 322                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 323
 324
 325 #
 326 # Include directories
 327 #
 328 ac_save_IFS=$IFS
 329 IFS="${IFS}:"
 330 # SRCH_INC comes from the template file
 331 for dir in $with_includes $SRCH_INC; do
 332   if test -d "$dir"; then
 333     INCLUDES="$INCLUDES -I$dir"
 334   else
 335     AC_MSG_WARN([*** Include directory $dir does not exist.])
 336   fi
 337 done
 338 IFS=$ac_save_IFS
 339 AC_SUBST(INCLUDES)
 340
 341
 342 #
 343 # Library directories
 344 #
 345 ac_save_IFS=$IFS
 346 IFS="${IFS}:"
 347 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 348 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 349   if test -d "$dir"; then
 350     LIBDIRS="$LIBDIRS -L$dir"
 351   else
 352     AC_MSG_WARN([*** Library directory $dir does not exist.])
 353   fi
 354 done
 355 IFS=$ac_save_IFS
 356
 357 #
 358 # Enable thread-safe client libraries
 359 #
 360 AC_MSG_CHECKING([allow thread-safe client libraries])
 361 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 362 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 363 if test "$enable_thread_safety" = yes -o
 364    test "$enable_thread_safety_force" = yes; then
 365   enable_thread_safety="yes"    # for 'force'
 366   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 367           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 368 fi
 369 AC_MSG_RESULT([$enable_thread_safety])
 370 AC_SUBST(enable_thread_safety)
 371
 372 #
 373 # Tcl/Tk
 374 #
 375 AC_MSG_CHECKING([whether to build with Tcl])
 376 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 377 AC_MSG_RESULT([$with_tcl])
 378 AC_SUBST([with_tcl])
 379
 380 # We see if the path to the Tcl/Tk configuration scripts is specified.
 381 # This will override the use of tclsh to find the paths to search.
 382
 383 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 384
 385 #
 386 # Optionally build Perl modules (PL/Perl)
 387 #
 388 AC_MSG_CHECKING([whether to build Perl modules])
 389 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 390 AC_MSG_RESULT([$with_perl])
 391 AC_SUBST(with_perl)
 392
 393 #
 394 # Optionally build Python modules (PL/Python)
 395 #
 396 AC_MSG_CHECKING([whether to build Python modules])
 397 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 398 AC_MSG_RESULT([$with_python])
 399 AC_SUBST(with_python)
 400
 401 #
 402 # Kerberos 4
 403 #
 404 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 405 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 406 [
 407   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 408   krb_srvtab="/etc/srvtab"
 409 ])
 410 AC_MSG_RESULT([$with_krb4])
 411 AC_SUBST(with_krb4)
 412
 413
 414 #
 415 # Kerberos 5
 416 #
 417 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 418 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 419 [
 420   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 421   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 422 ])
 423 AC_MSG_RESULT([$with_krb5])
 424 AC_SUBST(with_krb5)
 425
 426
 427 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 428 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 429   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 430 fi
 431
 432 AC_SUBST(krb_srvtab)
 433
 434
 435 #
 436 # Kerberos configuration parameters
 437 #
 438 PGAC_ARG_REQ(with, krb-srvnam,
 439              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 440              [],
 441              [with_krb_srvnam="postgres"])
 442 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 443                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 444
 445
 446 #
 447 # PAM
 448 #
 449 AC_MSG_CHECKING([whether to build with PAM support])
 450 PGAC_ARG_BOOL(with, pam, no,
 451               [  --with-pam              build with PAM support],
 452               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 453 AC_MSG_RESULT([$with_pam])
 454 AC_SUBST(with_pam)
 455
 456
 457 #
 458 # Rendezvous
 459 #
 460 AC_MSG_CHECKING([whether to build with Rendezvous support])
 461 PGAC_ARG_BOOL(with, rendezvous, no,
 462               [  --with-rendezvous       build with Rendezvous support],
 463               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 464 AC_MSG_RESULT([$with_rendezvous])
 465 AC_SUBST(with_rendezvous)
 466
 467
 468 #
 469 # OpenSSL
 470 #
 471 AC_MSG_CHECKING([whether to build with OpenSSL support])
 472 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 473               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 474 AC_MSG_RESULT([$with_openssl])
 475 AC_SUBST(with_openssl)
 476
 477
 478 #
 479 # Readline
 480 #
 481 PGAC_ARG_BOOL(with, readline, yes,
 482               [  --without-readline      do not use Readline])
 483
 484 #
 485 # Zlib
 486 #
 487 PGAC_ARG_BOOL(with, zlib, yes,
 488               [  --without-zlib          do not use Zlib])
 489
 490 #
 491 # Elf
 492 #
 493
 494 # Assume system is ELF if it predefines __ELF__ as 1,
 495 # otherwise believe host_os based default.
 496 case $host_os in
 497     freebsd1*|freebsd2*) elf=no;;
 498     freebsd3*|freebsd4*) elf=yes;;
 499 esac
 500
 501 AC_EGREP_CPP(yes,
 502 [#if __ELF__
 503   yes
 504 #endif
 505 ],
 506 [ELF_SYS=true],
 507 [if test "X$elf" = "Xyes" ; then
 508   ELF_SYS=true
 509 else
 510   ELF_SYS=
 511 fi])
 512 AC_SUBST(ELF_SYS)
 513
 514 #
 515 # Assignments
 516 #
 517
 518 CPPFLAGS="$CPPFLAGS $INCLUDES"
 519 LDFLAGS="$LDFLAGS $LIBDIRS"
 520
 521 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 522 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 523
 524
 525 AC_PROG_AWK
 526 PGAC_PATH_FLEX
 527 AC_PROG_LN_S
 528 PGAC_PROG_LD
 529 AC_SUBST(LD)
 530 AC_SUBST(with_gnu_ld)
 531 case $host_os in sysv5*)
 532   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 533   [
 534     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 535     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 536     LDFLAGS=$pgac_save_LDFLAGS
 537   ])
 538   ld_R_works=$pgac_cv_prog_ld_R
 539   AC_SUBST(ld_R_works)
 540 esac
 541 AC_PROG_RANLIB
 542 AC_CHECK_PROGS(LORDER, lorder)
 543 AC_PATH_PROG(TAR, tar)
 544 PGAC_CHECK_STRIP
 545
 546 AC_CHECK_PROGS(YACC, ['bison -y'])
 547
 548 if test "$YACC"; then
 549   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 550     AC_MSG_WARN([
 551 *** If you are going to modify the grammar files or build from CVS, the installed
 552 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 553   fi
 554 fi
 555
 556 if test -z "$YACC"; then
 557   AC_MSG_WARN([
 558 *** Without Bison you will not be able to build PostgreSQL from CVS or
 559 *** change any of the parser definition files.  You can obtain Bison from
 560 *** a GNU mirror site.  (If you are using the official distribution of
 561 *** PostgreSQL then you do not need to worry about this because the Bison
 562 *** output is pre-generated.)  To use a different yacc program (possible,
 563 *** but not recommended), set the environment variable YACC before running
 564 *** 'configure'.])
 565 fi
 566 AC_SUBST(YFLAGS)
 567
 568 PGAC_PATH_PERL
 569 if test "$with_perl" = yes; then
 570   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 571   PGAC_CHECK_PERL_EMBED_LDFLAGS
 572 fi
 573
 574 if test "$with_python" = yes; then
 575   PGAC_PATH_PYTHON
 576   PGAC_CHECK_PYTHON_EMBED_SETUP
 577 fi
 578
 579
 580 ##
 581 ## Libraries
 582 ##
 583
 584 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 585 then
 586         AC_CHECK_LIB(bsd,      main)
 587 fi
 588 AC_CHECK_LIB(util,     setproctitle)
 589 AC_CHECK_LIB(m,        main)
 590 AC_CHECK_LIB(dl,       main)
 591 AC_CHECK_LIB(nsl,      main)
 592 AC_CHECK_LIB(socket,   main)
 593 AC_CHECK_LIB(ipc,      main)
 594 AC_CHECK_LIB(IPC,      main)
 595 AC_CHECK_LIB(lc,       main)
 596 AC_CHECK_LIB(dld,      main)
 597 AC_CHECK_LIB(ld,       main)
 598 AC_CHECK_LIB(compat,   main)
 599 AC_CHECK_LIB(BSD,      main)
 600 AC_CHECK_LIB(gen,      main)
 601 AC_CHECK_LIB(PW,       main)
 602 AC_CHECK_LIB(resolv,   main)
 603 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 604 # QNX:
 605 AC_CHECK_LIB(unix, main)
 606 AC_SEARCH_LIBS(crypt,  crypt)
 607 # BeOS:
 608 if test "$PORTNAME" = "beos"
 609 then
 610         AC_CHECK_LIB(bind, __inet_ntoa)
 611 fi
 612 # Solaris:
 613 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 614 # Cygwin:
 615 AC_CHECK_LIB(cygipc, shmget)
 616 # WIN32:
 617 if test "$PORTNAME" = "win32"
 618 then
 619         AC_CHECK_LIB(wsock32, main)
 620 fi
 621
 622 if test "$with_readline" = yes; then
 623   PGAC_CHECK_READLINE
 624   if test x"$pgac_cv_check_readline" = x"no"; then
 625     AC_MSG_ERROR([readline library not found
 626 If you have readline already installed, see config.log for details on the
 627 failure.  It is possible the compiler isn't looking in the proper directory.
 628 Use --without-readline to disable readline support.])
 629   fi
 630 fi
 631
 632 if test "$with_zlib" = yes; then
 633   AC_CHECK_LIB(z, inflate, [],
 634                [AC_MSG_ERROR([zlib library not found
 635 If you have zlib already installed, see config.log for details on the
 636 failure.  It is possible the compiler isn't looking in the proper directory.
 637 Use --without-zlib to disable zlib support.])])
 638 fi
 639
 640 if test "$enable_spinlocks" = yes; then
 641   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 642 else
 643   AC_MSG_WARN([
 644 *** Not using spinlocks will cause poor performance.])
 645 fi
 646
 647 if test "$with_krb4" = yes ; then
 648   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 649   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 650   AC_REPLACE_FUNCS([gethostname])
 651 fi
 652
 653 if test "$with_krb5" = yes ; then
 654   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 655                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 656   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 657                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 658   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 659                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 660 fi
 661
 662 if test "$with_openssl" = yes ; then
 663   dnl Order matters!
 664   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 665   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 666 fi
 667
 668 if test "$with_pam" = yes ; then
 669   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 670 fi
 671
 672
 673 ##
 674 ## Header files
 675 ##
 676
 677 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 678 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 679
 680 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 681 # netinet/in.h is included first.
 682 AC_CHECK_HEADERS(netinet/in.h)
 683 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 684 [AC_INCLUDES_DEFAULT
 685 #ifdef HAVE_NETINET_IN_H
 686 #include <netinet/in.h>
 687 #endif
 688 ])
 689
 690 if test "$with_readline" = yes; then
 691   AC_CHECK_HEADERS(readline/readline.h, [],
 692                    [AC_CHECK_HEADERS(editline/readline.h, [],
 693                          [AC_CHECK_HEADERS(readline.h, [],
 694                                      [AC_MSG_ERROR([readline header not found
 695 If you have readline already installed, see config.log for details on the
 696 failure.  It is possible the compiler isn't looking in the proper directory.
 697 Use --without-readline to disable readline support.])])])])
 698   AC_CHECK_HEADERS(readline/history.h, [],
 699                    [AC_CHECK_HEADERS(editline/history.h, [],
 700                          [AC_CHECK_HEADERS(history.h, [],
 701                                      [AC_MSG_ERROR([history header not found
 702 If you have readline already installed, see config.log for details on the
 703 failure.  It is possible the compiler isn't looking in the proper directory.
 704 Use --without-readline to disable readline support.])])])])
 705 fi
 706
 707 if test "$with_zlib" = yes; then
 708   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 709 If you have zlib already installed, see config.log for details on the
 710 failure.  It is possible the compiler isn't looking in the proper directory.
 711 Use --without-zlib to disable zlib support.])])
 712 fi
 713
 714 if test "$with_krb4" = yes ; then
 715   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 716 fi
 717
 718 if test "$with_krb5" = yes ; then
 719   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 720   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 721 fi
 722
 723 if test "$with_openssl" = yes ; then
 724   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 725   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 726 fi
 727
 728 if test "$with_pam" = yes ; then
 729   AC_CHECK_HEADERS(security/pam_appl.h, [],
 730                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 731                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 732 fi
 733
 734 if test "$with_rendezvous" = yes ; then
 735   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 736 fi
 737
 738
 739 ##
 740 ## Types, structures, compiler characteristics
 741 ##
 742
 743 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 744 AC_C_CONST
 745 AC_C_INLINE
 746 AC_C_STRINGIZE
 747 PGAC_C_SIGNED
 748 AC_C_VOLATILE
 749 PGAC_C_FUNCNAME_SUPPORT
 750 PGAC_STRUCT_TIMEZONE
 751 PGAC_UNION_SEMUN
 752 PGAC_STRUCT_SOCKADDR_UN
 753 PGAC_STRUCT_SOCKADDR_STORAGE
 754 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 755 PGAC_STRUCT_ADDRINFO
 756
 757 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 758 [#include <sys/param.h>
 759 #include <sys/types.h>
 760 #include <sys/socket.h>
 761 #include <sys/ucred.h>])
 762
 763 AC_CHECK_TYPES([struct option], [], [],
 764 [#ifdef HAVE_GETOPT_H
 765 #include <getopt.h>
 766 #endif])
 767
 768 if test "$with_zlib" = yes; then
 769   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 770   # did not).  While we could work around the lack of z_streamp, it
 771   # seems unwise to encourage people to use such old zlib versions...
 772   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 773 Use --without-zlib to disable zlib support.])],
 774                 [#include <zlib.h>])
 775 fi
 776
 777 if test "$with_krb5" = yes; then
 778 # Check for differences between MIT and Heimdal (KTH) releases
 779   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 780                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 781                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 782                                      [#include <krb5.h>])],
 783                    [#include <krb5.h>])
 784   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 785                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 786                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 787                                      [#include <krb5.h>])],
 788                    [#include <krb5.h>])
 789 fi
 790
 791
 792 ##
 793 ## Functions, global variables
 794 ##
 795
 796 PGAC_VAR_INT_TIMEZONE
 797 AC_FUNC_ACCEPT_ARGTYPES
 798 PGAC_FUNC_GETTIMEOFDAY_1ARG
 799
 800 # SunOS doesn't handle negative byte comparisons properly with +/- return
 801 AC_FUNC_MEMCMP
 802
 803 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 804
 805 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 806
 807 HAVE_IPV6=no
 808 AC_CHECK_TYPE([struct sockaddr_in6],
 809               [AC_CHECK_FUNC(inet_ntop,
 810                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 811                                                           HAVE_IPV6=yes])],
 812               [],
 813 [$ac_includes_default
 814 #include <netinet/in.h>])
 815 AC_SUBST(HAVE_IPV6)
 816
 817 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 818 [AC_TRY_LINK(
 819 [#include <machine/vmparam.h>
 820 #include <sys/exec.h>
 821 ],
 822 [PS_STRINGS->ps_nargvstr = 1;
 823 PS_STRINGS->ps_argvstr = "foo";],
 824 [pgac_cv_var_PS_STRINGS=yes],
 825 [pgac_cv_var_PS_STRINGS=no])])
 826 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 827   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 828 fi
 829
 830
 831 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 832 # is missing.  Yes, there are machines that have only one.  We may
 833 # also decide to use snprintf.c if snprintf() is present but does not
 834 # have working "long long int" support -- see below.
 835
 836 pgac_need_repl_snprintf=no
 837 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 838 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 839
 840
 841 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 842 # include/c.h will provide declarations.  Note this is a separate test
 843 # from whether the functions exist in the C library --- there are
 844 # systems that have the functions but don't bother to declare them :-(
 845
 846 AC_CHECK_DECLS([snprintf, vsnprintf])
 847
 848
 849 # do this one the hard way in case isinf() is a macro
 850 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 851 [AC_TRY_LINK(
 852 [#include <math.h>
 853 ],
 854 [double x = 0.0; int res = isinf(x);],
 855 [ac_cv_func_isinf=yes],
 856 [ac_cv_func_isinf=no])])
 857
 858 if test $ac_cv_func_isinf = yes ; then
 859   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 860 else
 861   AC_LIBOBJ(isinf)
 862   # Look for a way to implement a substitute for isinf()
 863   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 864 fi
 865
 866 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 867
 868 # system's version of getaddrinfo(), if any, may be used only if we found
 869 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 870 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 871   AC_REPLACE_FUNCS([getaddrinfo])
 872 else
 873   AC_LIBOBJ(getaddrinfo)
 874 fi
 875
 876 # similarly, use system's getopt_long() only if system provides struct option.
 877 if test x"$ac_cv_type_struct_option" = xyes ; then
 878   AC_REPLACE_FUNCS([getopt_long])
 879 else
 880   AC_LIBOBJ(getopt_long)
 881 fi
 882
 883 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 884 # We override the previous test that said fseeko/ftello didn't exist
 885 # OS tests are also done in include/c.h and port/fseeko.c
 886 case $host_os in bsdi*|netbsd*)
 887 ac_cv_func_fseeko=yes
 888 esac
 889
 890 # Solaris has a very slow qsort in certain cases, so we replace it.
 891 case $host_os in solaris*)
 892 AC_LIBOBJ(qsort) ;;
 893 esac
 894
 895 # Win32 support
 896 case $host_os in mingw*)
 897 AC_LIBOBJ(copydir)
 898 AC_LIBOBJ(gettimeofday)
 899 AC_LIBOBJ(kill)
 900 AC_LIBOBJ(open)
 901 AC_LIBOBJ(rand) ;;
 902 esac
 903
 904 # Win32 can't do rename or unlink on an open file
 905 case $host_os in mingw*|cygwin*)
 906 AC_LIBOBJ(dirmod) ;;
 907 esac
 908
 909 if test "$with_readline" = yes; then
 910   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 911   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 912   AC_CHECK_FUNCS([replace_history_entry])
 913 fi
 914
 915
 916 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 917 AC_MSG_CHECKING(for finite)
 918 AC_TRY_LINK([#include <math.h>],
 919             [int dummy=finite(1.0);],
 920             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 921 AC_MSG_RESULT(yes)],
 922             [AC_MSG_RESULT(no)])
 923
 924 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 925 dnl (especially on GNU libc)
 926 dnl See also comments in c.h.
 927 AC_MSG_CHECKING(for sigsetjmp)
 928 AC_TRY_LINK([#include <setjmp.h>],
 929             [sigjmp_buf x; sigsetjmp(x, 1);],
 930             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 931 AC_MSG_RESULT(yes)],
 932             [AC_MSG_RESULT(no)])
 933
 934 AC_CHECK_FUNC(syslog,
 935               [AC_CHECK_HEADER(syslog.h,
 936                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 937
 938 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 939 [AC_TRY_LINK([#include <unistd.h>],
 940   [extern int optreset; optreset = 1;],
 941   [pgac_cv_var_int_optreset=yes],
 942   [pgac_cv_var_int_optreset=no])])
 943 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 944   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 945 fi
 946
 947 AC_CHECK_FUNCS([strtoll strtoq], [break])
 948 AC_CHECK_FUNCS([strtoull strtouq], [break])
 949
 950 # Check for one of atexit() or on_exit()
 951 AC_CHECK_FUNCS(atexit, [],
 952                [AC_CHECK_FUNCS(on_exit, [],
 953                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 954
 955 AC_FUNC_FSEEKO
 956
 957 #
 958 # Pthreads
 959 #
 960 # For each platform, we need to know about any special compile and link
 961 # libraries, and whether the normal C function names are thread-safe.
 962 # See the comment at the top of src/port/thread.c for more information.
 963 #
 964 if test "$enable_thread_safety" = yes; then
 965 ACX_PTHREAD     # set thread flags
 966
 967 # Some platforms use these, so just defineed them.  They can't hurt if they
 968 # are not supported.
 969 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 970
 971
 972 # At this point, we don't want to muck with the compiler name for threading.
 973 # Let's see who fails, perhaps AIX.  2004-04-23
 974 if test "$PTHREAD_CC" != "$CC"; then
 975 AC_MSG_ERROR([
 976 PostgreSQL does not support platforms that require a special
 977 compiler binary for thread-safety.
 978 ])
 979 fi
 980
 981 if test "$THREAD_SUPPORT" = no; then
 982 AC_MSG_ERROR([
 983 Cannot enable threads on your platform.
 984 Your platform is known to not support thread-safe programs.
 985 For details, compile and run src/bin/pg_thread_test.
 986 ])
 987 fi
 988
 989 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
 990
 991 # Check for *_r functions
 992 _CFLAGS="$CFLAGS"
 993 _LIBS="$LIBS"
 994 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 995 LIBS="$LIBS $PTHREAD_LIBS"
 996 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 997
 998 # Do test here with the proper thread flags
 999 PGAC_FUNC_GETPWUID_R_5ARG
1000 PGAC_FUNC_STRERROR_R_INT
1001
1002 CFLAGS="$_CFLAGS"
1003 LIBS="$_LIBS"
1004
1005 else
1006 # do not use values from template file
1007 PTHREAD_CFLAGS=
1008 PTHREAD_LIBS=
1009 fi
1010
1011 AC_SUBST(PTHREAD_CFLAGS)
1012 AC_SUBST(PTHREAD_LIBS)
1013
1014
1015 # This test makes sure that run tests work at all.  Sometimes a shared
1016 # library is found by the linker, but the runtime linker can't find it.
1017 # This check should come after all modifications of compiler or linker
1018 # variables, and before any other run tests.
1019 AC_MSG_CHECKING([test program])
1020 AC_TRY_RUN([int main() { return 0; }],
1021 [AC_MSG_RESULT(ok)],
1022 [AC_MSG_RESULT(failed)
1023 AC_MSG_ERROR([[
1024 *** Could not execute a simple test program.  This may be a problem
1025 *** related to locating shared libraries.  Check the file 'config.log'
1026 *** for the exact reason.]])],
1027 [AC_MSG_RESULT([cross-compiling])])
1028
1029
1030 dnl Check to see if we have a working 64-bit integer type.
1031 dnl This breaks down into two steps:
1032 dnl (1) figure out if the compiler has a 64-bit int type with working
1033 dnl arithmetic, and if so
1034 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1035 dnl snprintf is the only library routine we really need for int8 support.)
1036 dnl It's entirely possible to have a compiler that handles a 64-bit type
1037 dnl when the C library doesn't; this is fairly likely when using gcc on
1038 dnl an older platform, for example.
1039 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1040 dnl we force our own version of snprintf() to be used instead.
1041 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1042
1043 PGAC_TYPE_64BIT_INT([long int])
1044
1045 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1046   PGAC_TYPE_64BIT_INT([long long int])
1047 fi
1048
1049
1050 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1051
1052 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1053   AC_TRY_COMPILE([
1054 #define INT64CONST(x)  x##LL
1055 long long int foo = INT64CONST(0x1234567890123456);
1056 ],
1057         [],
1058         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1059         [])
1060 fi
1061
1062
1063 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1064 # we found we need to use "long long int", better check.  We cope with
1065 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1066 # work, fall back to our own snprintf emulation (which we know uses %lld).
1067
1068 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1069   if test $pgac_need_repl_snprintf = no; then
1070     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1071     if test "$LONG_LONG_INT_FORMAT" = ""; then
1072       # Force usage of our own snprintf, since system snprintf is broken
1073       pgac_need_repl_snprintf=yes
1074       LONG_LONG_INT_FORMAT='%lld'
1075     fi
1076   else
1077     # Here if we previously decided we needed to use our own snprintf
1078     LONG_LONG_INT_FORMAT='%lld'
1079   fi
1080   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1081   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1082   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1083 else
1084   # Here if we are not using 'long long int' at all
1085   INT64_FORMAT='"%ld"'
1086   UINT64_FORMAT='"%lu"'
1087 fi
1088
1089 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1090                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1091
1092 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1093                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1094
1095 if test $pgac_need_repl_snprintf = yes; then
1096   AC_LIBOBJ(snprintf)
1097 fi
1098
1099 # Need a #define for the size of Datum (unsigned long)
1100 AC_CHECK_SIZEOF([unsigned long])
1101
1102 # Determine memory alignment requirements for the basic C data types.
1103
1104 PGAC_CHECK_ALIGNOF(short)
1105 PGAC_CHECK_ALIGNOF(int)
1106 PGAC_CHECK_ALIGNOF(long)
1107 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1108   PGAC_CHECK_ALIGNOF(long long int)
1109 fi
1110 PGAC_CHECK_ALIGNOF(double)
1111
1112 # Compute maximum alignment of any basic type.
1113 # We assume long's alignment is at least as strong as char, short, or int;
1114 # but we must check long long (if it exists) and double.
1115
1116 MAX_ALIGNOF=$pgac_cv_alignof_long
1117 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1118   MAX_ALIGNOF=$pgac_cv_alignof_double
1119 fi
1120 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1121   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1122 fi
1123 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1124
1125
1126 # Some platforms predefine the types int8, int16, etc.  Only check
1127 # a (hopefully) representative subset.
1128 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1129 [#include <stdio.h>
1130 #ifdef HAVE_SUPPORTDEFS_H
1131 #include <SupportDefs.h>
1132 #endif])
1133
1134 # We also check for sig_atomic_t, which *should* be defined per ANSI
1135 # C, but is missing on some old platforms.
1136 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1137
1138
1139 PGAC_FUNC_POSIX_SIGNALS
1140 if test $ac_cv_func_fseeko = yes; then
1141 AC_SYS_LARGEFILE
1142 fi
1143
1144
1145 # Select semaphore implementation type.
1146 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1147   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1148   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1149 else
1150   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1151     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1152     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1153   else
1154     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1155     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1156   fi
1157 fi
1158
1159
1160 # Select shared-memory implementation type.
1161 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1162 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1163
1164
1165 if test "$enable_nls" = yes ; then
1166   PGAC_CHECK_GETTEXT
1167 fi
1168
1169 # Check for Tcl configuration script tclConfig.sh
1170 if test "$with_tcl" = yes; then
1171     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1172     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1173                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1174     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1175 fi
1176
1177 #
1178 # Check for DocBook and tools
1179 #
1180 PGAC_PROG_NSGMLS
1181 PGAC_PROG_JADE
1182 PGAC_CHECK_DOCBOOK(4.2)
1183 PGAC_PATH_DOCBOOK_STYLESHEETS
1184 PGAC_PATH_COLLATEINDEX
1185 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1186
1187 # Thread testing
1188
1189 # We have to run the thread test near the end so we have all our symbols
1190 # defined.  Cross compiling throws a warning.
1191 #
1192 if test "$enable_thread_safety_force" = yes; then
1193   AC_MSG_WARN([
1194 *** Skipping thread test program.  --enable-thread-safety-force was used.
1195 *** Run the program in src/tools/thread on the your machine and add
1196 proper locking function calls to your applications to guarantee thread
1197 safety.
1198 ])
1199 elif test "$enable_thread_safety" = yes; then
1200 AC_MSG_CHECKING([thread safety of required library functions])
1201
1202 _CFLAGS="$CFLAGS"
1203 _LIBS="$LIBS"
1204 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1205 LIBS="$LIBS $PTHREAD_LIBS"
1206 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1207   [AC_MSG_RESULT(yes)],
1208   [AC_MSG_RESULT(no)
1209   AC_MSG_ERROR([
1210 *** Thread test program failed.  Your platform is not thread-safe.
1211 *** Check the file 'config.log'for the exact reason.
1212 ***
1213 *** You can use the configure option --enable-thread-safety-force
1214 *** to force threads to be enabled.  However, you must then run
1215 *** the program in src/tools/thread and add locking function calls
1216 *** to your applications to guarantee thread safety.
1217 ])],
1218   [AC_MSG_RESULT(maybe)
1219   AC_MSG_WARN([
1220 *** Skipping thread test program because of cross-compile build.
1221 *** Run the program in src/tools/thread on the target machine.
1222 ])])
1223 CFLAGS="$_CFLAGS"
1224 LIBS="$_LIBS"
1225 fi
1226
1227 # prepare build tree if outside source tree
1228 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1229 # Note 2: /bin/pwd might be better than shell's built-in at getting
1230 #         a symlink-free name.
1231 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1232   vpath_build=no
1233 else
1234   vpath_build=yes
1235   if test "$no_create" != yes; then
1236     _AS_ECHO_N([preparing build tree... ])
1237     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1238     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1239       || AC_MSG_ERROR(failed)
1240     AC_MSG_RESULT(done)
1241   fi
1242 fi
1243 AC_SUBST(vpath_build)
1244
1245
1246 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1247
1248 AC_CONFIG_LINKS([
1249   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1250   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1251   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1252   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1253   src/include/pg_config_os.h:src/include/port/${template}.h
1254   src/Makefile.port:src/makefiles/Makefile.${template}
1255 ])
1256
1257 case $host_os in mingw*)
1258 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1259 # Links sometimes fail undetected on Mingw -
1260 # so here we detect it and warn the user
1261 for FILE in $CONFIG_LINKS
1262  do
1263         # test -e works for symlinks in the MinGW console
1264         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1265  done
1266 ])
1267         ;;
1268 esac
1269
1270 AC_CONFIG_HEADERS([src/include/pg_config.h],
1271 [
1272 # Update timestamp for pg_config.h (see Makefile.global)
1273 echo >src/include/stamp-h
1274 ])
1275
1276 AC_OUTPUT
1277