granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [12devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 357     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361 AC_PROG_CC_C99()
 362
 363 # Error out if the compiler does not support C99, as the codebase
 364 # relies on that.
 365 if test "$ac_cv_prog_cc_c99" = no; then
 366     AC_MSG_ERROR([C compiler "$CC" does not support C99])
 367 fi
 368
 369 AC_PROG_CXX([$pgac_cxx_list])
 370
 371 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 372 # but has idiosyncrasies of its own.  We assume icc will define
 373 # __INTEL_COMPILER regardless of CFLAGS.
 374 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 375 choke me
 376 @%:@endif])], [ICC=yes], [ICC=no])
 377
 378 # Check if it's Sun Studio compiler. We assume that
 379 # __SUNPRO_C will be defined for Sun Studio compilers
 380 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 381 choke me
 382 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 383
 384 AC_SUBST(SUN_STUDIO_CC)
 385
 386
 387 #
 388 # LLVM
 389 #
 390 # Checked early because subsequent tests depend on it.
 391 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 392               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 393 AC_SUBST(with_llvm)
 394 dnl must use AS_IF here, else AC_REQUIRES inside PGAC_LLVM_SUPPORT malfunctions
 395 AS_IF([test "$with_llvm" = yes], [
 396   PGAC_LLVM_SUPPORT()
 397 ]) # fi
 398
 399
 400 unset CFLAGS
 401 unset CXXFLAGS
 402
 403 #
 404 # Read the template
 405 #
 406 . "$srcdir/src/template/$template" || exit
 407
 408 # C[XX]FLAGS are selected so:
 409 # If the user specifies something in the environment, that is used.
 410 # else:  If the template file set something, that is used.
 411 # else:  If coverage was enabled, don't set anything.
 412 # else:  If the compiler is GCC, then we use -O2.
 413 # else:  If the compiler is something else, then we use -O, unless debugging.
 414
 415 if test "$ac_env_CFLAGS_set" = set; then
 416   CFLAGS=$ac_env_CFLAGS_value
 417 elif test "${CFLAGS+set}" = set; then
 418   : # (keep what template set)
 419 elif test "$enable_coverage" = yes; then
 420   : # no optimization by default
 421 elif test "$GCC" = yes; then
 422   CFLAGS="-O2"
 423 else
 424   # if the user selected debug mode, don't use -O
 425   if test "$enable_debug" != yes; then
 426     CFLAGS="-O"
 427   fi
 428 fi
 429
 430 if test "$ac_env_CXXFLAGS_set" = set; then
 431   CXXFLAGS=$ac_env_CXXFLAGS_value
 432 elif test "${CXXFLAGS+set}" = set; then
 433   : # (keep what template set)
 434 elif test "$enable_coverage" = yes; then
 435   : # no optimization by default
 436 elif test "$GCC" = yes; then
 437   CXXFLAGS="-O2"
 438 else
 439   # if the user selected debug mode, don't use -O
 440   if test "$enable_debug" != yes; then
 441     CXXFLAGS="-O"
 442   fi
 443 fi
 444
 445 # When generating bitcode (for inlining) we always want to use -O2
 446 # even when --enable-debug is specified. The bitcode it's not going to
 447 # be used for line-by-line debugging, and JIT inlining doesn't work
 448 # without at least -O1 (otherwise clang will emit 'noinline'
 449 # attributes everywhere), which is bad for testing.  Still allow the
 450 # environment to override if done explicitly.
 451 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 452   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 453 else
 454   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 455 fi
 456 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 457   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 458 else
 459   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 460 fi
 461
 462 # C[XX]FLAGS we determined above will be added back at the end
 463 user_CFLAGS=$CFLAGS
 464 CFLAGS=""
 465 user_CXXFLAGS=$CXXFLAGS
 466 CXXFLAGS=""
 467 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 468 BITCODE_CFLAGS=""
 469 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 470 BITCODE_CXXFLAGS=""
 471
 472 # set CFLAGS_VECTOR from the environment, if available
 473 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 474   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 475 fi
 476
 477 # Some versions of GCC support some additional useful warning flags.
 478 # Check whether they are supported, and add them to CFLAGS if so.
 479 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 480 # but has its own.  Also check other compiler-specific flags here.
 481
 482 if test "$GCC" = yes -a "$ICC" = no; then
 483   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 484   CXXFLAGS="-Wall -Wpointer-arith"
 485   # These work in some but not all gcc versions
 486   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 487   # -Wdeclaration-after-statement isn't applicable for C++
 488   # Really don't want VLAs to be used in our dialect of C
 489   PGAC_PROG_CC_CFLAGS_OPT([-Werror=vla])
 490   # -Wvla is not applicable for C++
 491   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 492   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 493   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 494   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 495   # This was included in -Wall/-Wformat in older GCC versions
 496   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 497   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 498   # Disable strict-aliasing rules; needed for gcc 3.3+
 499   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 500   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 501   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 502   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 503   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 504   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 505   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 506   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 507   # Optimization flags for specific files that benefit from vectorization
 508   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 509   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 510   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 511   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 512   # test for the positive form and if that works, add the negative form
 513   NOT_THE_CFLAGS=""
 514   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 515   if test -n "$NOT_THE_CFLAGS"; then
 516     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 517   fi
 518   # Similarly disable useless truncation warnings from gcc 8+
 519   NOT_THE_CFLAGS=""
 520   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wformat-truncation])
 521   if test -n "$NOT_THE_CFLAGS"; then
 522     CFLAGS="$CFLAGS -Wno-format-truncation"
 523   fi
 524   NOT_THE_CFLAGS=""
 525   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wstringop-truncation])
 526   if test -n "$NOT_THE_CFLAGS"; then
 527     CFLAGS="$CFLAGS -Wno-stringop-truncation"
 528   fi
 529 elif test "$ICC" = yes; then
 530   # Intel's compiler has a bug/misoptimization in checking for
 531   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 532   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 533   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 534   # Make sure strict aliasing is off (though this is said to be the default)
 535   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 536   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 537 elif test "$PORTNAME" = "aix"; then
 538   # AIX's xlc has to have strict aliasing turned off too
 539   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 540   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 541   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 542   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 543 elif test "$PORTNAME" = "hpux"; then
 544   # On some versions of HP-UX, libm functions do not set errno by default.
 545   # Fix that by using +Olibmerrno if the compiler recognizes it.
 546   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 547   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 548 fi
 549
 550 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 551
 552 # Determine flags used to emit bitcode for JIT inlining. Need to test
 553 # for behaviour changing compiler flags, to keep compatibility with
 554 # compiler used for normal postgres code.
 555 if test "$with_llvm" = yes ; then
 556   CLANGXX="$CLANG -xc++"
 557
 558   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 559   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 560   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 561   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 562   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 563   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 564 fi
 565
 566 # supply -g if --enable-debug
 567 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 568   CFLAGS="$CFLAGS -g"
 569 fi
 570
 571 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 572   CXXFLAGS="$CXXFLAGS -g"
 573 fi
 574
 575 # enable code coverage if --enable-coverage
 576 if test "$enable_coverage" = yes; then
 577   if test "$GCC" = yes; then
 578     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 579     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 580   else
 581     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 582   fi
 583 fi
 584
 585 # enable profiling if --enable-profiling
 586 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 587   if test "$GCC" = yes; then
 588     AC_DEFINE([PROFILE_PID_DIR], 1,
 589            [Define to 1 to allow profiling output to be saved separately for each process.])
 590     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 591     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 592   else
 593     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 594   fi
 595 fi
 596
 597 # We already have this in Makefile.win32, but configure needs it too
 598 if test "$PORTNAME" = "win32"; then
 599   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 600 fi
 601
 602 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 603 # user-specified flags (if any) at the end.  This lets users override
 604 # the automatic additions.
 605 CFLAGS="$CFLAGS $user_CFLAGS"
 606 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 607 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 608 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 609
 610 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 611 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 612
 613 # Check if the compiler still works with the final flag settings
 614 # (note, we're not checking that for CXX, which is optional)
 615 AC_MSG_CHECKING([whether the C compiler still works])
 616 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 617   [AC_MSG_RESULT(yes)],
 618   [AC_MSG_RESULT(no)
 619    AC_MSG_ERROR([cannot proceed])])
 620
 621 # Defend against gcc -ffast-math
 622 if test "$GCC" = yes; then
 623 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 624 choke me
 625 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 626 fi
 627
 628 # Defend against clang being used on x86-32 without SSE2 enabled.  As current
 629 # versions of clang do not understand -fexcess-precision=standard, the use of
 630 # x87 floating point operations leads to problems like isinf possibly returning
 631 # false for a value that is infinite when converted from the 80bit register to
 632 # the 8byte memory representation.
 633 #
 634 # Only perform the test if the compiler doesn't understand
 635 # -fexcess-precision=standard, that way a potentially fixed compiler will work
 636 # automatically.
 637 if test "$pgac_cv_prog_CC_cflags__fexcess_precision_standard" = no; then
 638 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 639 @%:@if defined(__clang__) && defined(__i386__) && !defined(__SSE2_MATH__)
 640 choke me
 641 @%:@endif
 642 ])], [],
 643 [AC_MSG_ERROR([Compiling PostgreSQL with clang, on 32bit x86, requires SSE2 support. Use -msse2 or use gcc.])])
 644 fi
 645
 646 AC_PROG_CPP
 647 AC_SUBST(GCC)
 648
 649
 650 #
 651 # Set up TAS assembly code if needed; the template file has now had its
 652 # chance to request this.
 653 #
 654 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 655
 656 if test "$need_tas" = yes ; then
 657   TAS=tas.o
 658 else
 659   TAS=""
 660 fi
 661 AC_SUBST(TAS)
 662
 663
 664 #
 665 # Automatic dependency tracking
 666 #
 667 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 668               [autodepend=yes])
 669 AC_SUBST(autodepend)
 670
 671
 672 #
 673 # Enable assert checks
 674 #
 675 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 676               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 677                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 678
 679
 680 #
 681 # Include directories
 682 #
 683 ac_save_IFS=$IFS
 684 IFS="${IFS}${PATH_SEPARATOR}"
 685 # SRCH_INC comes from the template file
 686 for dir in $with_includes $SRCH_INC; do
 687   if test -d "$dir"; then
 688     INCLUDES="$INCLUDES -I$dir"
 689   else
 690     AC_MSG_WARN([*** Include directory $dir does not exist.])
 691   fi
 692 done
 693 IFS=$ac_save_IFS
 694 AC_SUBST(INCLUDES)
 695
 696
 697 #
 698 # Library directories
 699 #
 700 ac_save_IFS=$IFS
 701 IFS="${IFS}${PATH_SEPARATOR}"
 702 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 703 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 704   if test -d "$dir"; then
 705     LIBDIRS="$LIBDIRS -L$dir"
 706   else
 707     AC_MSG_WARN([*** Library directory $dir does not exist.])
 708   fi
 709 done
 710 IFS=$ac_save_IFS
 711
 712 #
 713 # Enable thread-safe client libraries
 714 #
 715 AC_MSG_CHECKING([allow thread-safe client libraries])
 716 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 717 if test "$enable_thread_safety" = yes; then
 718   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 719           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 720 fi
 721 AC_MSG_RESULT([$enable_thread_safety])
 722 AC_SUBST(enable_thread_safety)
 723
 724 #
 725 # ICU
 726 #
 727 AC_MSG_CHECKING([whether to build with ICU support])
 728 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 729               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 730 AC_MSG_RESULT([$with_icu])
 731 AC_SUBST(with_icu)
 732
 733 if test "$with_icu" = yes; then
 734   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 735 fi
 736
 737 #
 738 # Optionally build Tcl modules (PL/Tcl)
 739 #
 740 AC_MSG_CHECKING([whether to build with Tcl])
 741 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 742 AC_MSG_RESULT([$with_tcl])
 743 AC_SUBST([with_tcl])
 744
 745 # We see if the path to the Tcl/Tk configuration scripts is specified.
 746 # This will override the use of tclsh to find the paths to search.
 747
 748 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 749
 750 #
 751 # Optionally build Perl modules (PL/Perl)
 752 #
 753 AC_MSG_CHECKING([whether to build Perl modules])
 754 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 755 AC_MSG_RESULT([$with_perl])
 756 AC_SUBST(with_perl)
 757
 758 #
 759 # Optionally build Python modules (PL/Python)
 760 #
 761 AC_MSG_CHECKING([whether to build Python modules])
 762 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 763 AC_MSG_RESULT([$with_python])
 764 AC_SUBST(with_python)
 765
 766 #
 767 # GSSAPI
 768 #
 769 AC_MSG_CHECKING([whether to build with GSSAPI support])
 770 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 771 [
 772   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 773   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 774 ])
 775 AC_MSG_RESULT([$with_gssapi])
 776 AC_SUBST(with_gssapi)
 777
 778
 779 AC_SUBST(krb_srvtab)
 780
 781
 782 #
 783 # Kerberos configuration parameters
 784 #
 785 PGAC_ARG_REQ(with, krb-srvnam,
 786              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 787              [],
 788              [with_krb_srvnam="postgres"])
 789 AC_SUBST(with_krb_srvnam)
 790 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 791                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 792
 793
 794 #
 795 # PAM
 796 #
 797 AC_MSG_CHECKING([whether to build with PAM support])
 798 PGAC_ARG_BOOL(with, pam, no,
 799               [build with PAM support],
 800               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 801 AC_MSG_RESULT([$with_pam])
 802
 803
 804 #
 805 # BSD AUTH
 806 #
 807 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 808 PGAC_ARG_BOOL(with, bsd-auth, no,
 809               [build with BSD Authentication support],
 810               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 811 AC_MSG_RESULT([$with_bsd_auth])
 812
 813
 814 #
 815 # LDAP
 816 #
 817 AC_MSG_CHECKING([whether to build with LDAP support])
 818 PGAC_ARG_BOOL(with, ldap, no,
 819               [build with LDAP support],
 820               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 821 AC_MSG_RESULT([$with_ldap])
 822 AC_SUBST(with_ldap)
 823
 824
 825 #
 826 # Bonjour
 827 #
 828 AC_MSG_CHECKING([whether to build with Bonjour support])
 829 PGAC_ARG_BOOL(with, bonjour, no,
 830               [build with Bonjour support],
 831               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 832 AC_MSG_RESULT([$with_bonjour])
 833
 834
 835 #
 836 # OpenSSL
 837 #
 838 AC_MSG_CHECKING([whether to build with OpenSSL support])
 839 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 840               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 841 AC_MSG_RESULT([$with_openssl])
 842 AC_SUBST(with_openssl)
 843
 844 #
 845 # SELinux
 846 #
 847 AC_MSG_CHECKING([whether to build with SELinux support])
 848 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 849 AC_SUBST(with_selinux)
 850 AC_MSG_RESULT([$with_selinux])
 851
 852 #
 853 # Systemd
 854 #
 855 AC_MSG_CHECKING([whether to build with systemd support])
 856 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 857               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 858 AC_SUBST(with_systemd)
 859 AC_MSG_RESULT([$with_systemd])
 860
 861 #
 862 # Readline
 863 #
 864 PGAC_ARG_BOOL(with, readline, yes,
 865               [do not use GNU Readline nor BSD Libedit for editing])
 866 # readline on MinGW has problems with backslashes in psql and other bugs.
 867 # This is particularly a problem with non-US code pages.
 868 # Therefore disable its use until we understand the cause. 2004-07-20
 869 if test "$PORTNAME" = "win32"; then
 870   if test "$with_readline" = yes; then
 871     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 872     with_readline=no
 873   fi
 874 fi
 875
 876
 877 #
 878 # Prefer libedit
 879 #
 880 PGAC_ARG_BOOL(with, libedit-preferred, no,
 881               [prefer BSD Libedit over GNU Readline])
 882
 883
 884 #
 885 # UUID library
 886 #
 887 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 888 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 889 # UUID library.  More than one of these might be present on a given platform,
 890 # so we make the user say which one she wants.
 891 #
 892 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 893 if test x"$with_uuid" = x"" ; then
 894   with_uuid=no
 895 fi
 896 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 897 if test "$with_ossp_uuid" = yes ; then
 898   with_uuid=ossp
 899 fi
 900
 901 if test "$with_uuid" = bsd ; then
 902   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 903   UUID_EXTRA_OBJS="md5.o sha1.o"
 904 elif test "$with_uuid" = e2fs ; then
 905   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 906   UUID_EXTRA_OBJS="md5.o sha1.o"
 907 elif test "$with_uuid" = ossp ; then
 908   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 909   UUID_EXTRA_OBJS=""
 910 elif test "$with_uuid" = no ; then
 911   UUID_EXTRA_OBJS=""
 912 else
 913   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 914 fi
 915 AC_SUBST(with_uuid)
 916 AC_SUBST(UUID_EXTRA_OBJS)
 917
 918
 919 #
 920 # XML
 921 #
 922 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 923               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 924
 925 if test "$with_libxml" = yes ; then
 926   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 927   if test -n "$XML2_CONFIG"; then
 928     for pgac_option in `$XML2_CONFIG --cflags`; do
 929       case $pgac_option in
 930         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 931       esac
 932     done
 933     for pgac_option in `$XML2_CONFIG --libs`; do
 934       case $pgac_option in
 935         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 936       esac
 937     done
 938   fi
 939 fi
 940
 941 AC_SUBST(with_libxml)
 942
 943 #
 944 # XSLT
 945 #
 946 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 947               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 948
 949
 950 AC_SUBST(with_libxslt)
 951
 952 #
 953 # tzdata
 954 #
 955 PGAC_ARG_REQ(with, system-tzdata,
 956              [DIR], [use system time zone data in DIR])
 957 AC_SUBST(with_system_tzdata)
 958
 959 #
 960 # Zlib
 961 #
 962 PGAC_ARG_BOOL(with, zlib, yes,
 963               [do not use Zlib])
 964 AC_SUBST(with_zlib)
 965
 966 #
 967 # Elf
 968 #
 969
 970 # Assume system is ELF if it predefines __ELF__ as 1,
 971 # otherwise believe host_os based default.
 972 case $host_os in
 973     freebsd1*|freebsd2*) elf=no;;
 974     freebsd3*|freebsd4*) elf=yes;;
 975 esac
 976
 977 AC_EGREP_CPP(yes,
 978 [#if __ELF__
 979   yes
 980 #endif
 981 ],
 982 [ELF_SYS=true],
 983 [if test "X$elf" = "Xyes" ; then
 984   ELF_SYS=true
 985 else
 986   ELF_SYS=
 987 fi])
 988 AC_SUBST(ELF_SYS)
 989
 990 #
 991 # Assignments
 992 #
 993
 994 CPPFLAGS="$CPPFLAGS $INCLUDES"
 995 LDFLAGS="$LDFLAGS $LIBDIRS"
 996
 997 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 998 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 999
1000 PGAC_PROG_LD
1001 AC_SUBST(LD)
1002 AC_SUBST(with_gnu_ld)
1003 AC_PROG_RANLIB
1004 PGAC_CHECK_STRIP
1005 AC_CHECK_TOOL(AR, ar, ar)
1006 if test "$PORTNAME" = "win32"; then
1007   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
1008   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
1009   AC_CHECK_TOOL(WINDRES, windres, windres)
1010 fi
1011
1012 AC_PROG_INSTALL
1013 # When Autoconf chooses install-sh as install program it tries to generate
1014 # a relative path to it in each makefile where it substitutes it. This clashes
1015 # with our Makefile.global concept. This workaround helps.
1016 case $INSTALL in
1017   *install-sh*) install_bin='';;
1018   *) install_bin=$INSTALL;;
1019 esac
1020 AC_SUBST(install_bin)
1021
1022 PGAC_PATH_PROGS(TAR, tar)
1023 AC_PROG_LN_S
1024 AC_PROG_MKDIR_P
1025 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
1026 # a relative path to it in each makefile where it substitutes it. This clashes
1027 # with our Makefile.global concept. This workaround helps.
1028 case $MKDIR_P in
1029   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
1030 esac
1031
1032 PGAC_PATH_BISON
1033 PGAC_PATH_FLEX
1034
1035 PGAC_PATH_PERL
1036 if test "$with_perl" = yes; then
1037   if test -z "$PERL"; then
1038     AC_MSG_ERROR([Perl not found])
1039   fi
1040   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1041   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1042     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1043 You might have to rebuild your Perl installation.  Refer to the
1044 documentation for details.  Use --without-perl to disable building
1045 PL/Perl.])
1046   fi
1047   # On most platforms, archlibexp is also where the Perl include files live ...
1048   perl_includespec="-I$perl_archlibexp/CORE"
1049   # ... but on newer macOS versions, we must use -iwithsysroot to look
1050   # under $PG_SYSROOT
1051   if test \! -f "$perl_archlibexp/CORE/perl.h" ; then
1052     if test -f "$PG_SYSROOT$perl_archlibexp/CORE/perl.h" ; then
1053       perl_includespec="-iwithsysroot $perl_archlibexp/CORE"
1054     fi
1055   fi
1056   AC_SUBST(perl_includespec)dnl
1057   PGAC_CHECK_PERL_EMBED_CCFLAGS
1058   PGAC_CHECK_PERL_EMBED_LDFLAGS
1059 fi
1060
1061 if test "$with_python" = yes; then
1062   PGAC_PATH_PYTHON
1063   PGAC_CHECK_PYTHON_EMBED_SETUP
1064 fi
1065
1066 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1067   PGAC_PATH_PROGS(ZIC, zic)
1068   if test -z "$ZIC"; then
1069     AC_MSG_ERROR([
1070 When cross-compiling, either use the option --with-system-tzdata to use
1071 existing time-zone data, or set the environment variable ZIC to a zic
1072 program to use during the build.])
1073   fi
1074 fi
1075
1076 #
1077 # Pthreads
1078 #
1079 # For each platform, we need to know about any special compile and link
1080 # libraries, and whether the normal C function names are thread-safe.
1081 # See the comment at the top of src/port/thread.c for more information.
1082 # WIN32 doesn't need the pthread tests;  it always uses threads
1083 #
1084 # These tests are run before the library-tests, because linking with the
1085 # other libraries can pull in the pthread functions as a side-effect.  We
1086 # want to use the -pthread or similar flags directly, and not rely on
1087 # the side-effects of linking with some other library.
1088 #
1089 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1090 # invocation below is the first one in the script, and autoconf generates
1091 # additional code for that, which must not be inside the if-block. AS_IF
1092 # knows how to do that.
1093 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1094 [ # then
1095 AX_PTHREAD      # set thread flags
1096
1097 # Some platforms use these, so just define them.  They can't hurt if they
1098 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1099 # enables 5-arg getpwuid_r, among other things.
1100 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1101
1102 # Check for *_r functions
1103 _CFLAGS="$CFLAGS"
1104 _LIBS="$LIBS"
1105 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1106 LIBS="$LIBS $PTHREAD_LIBS"
1107
1108 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1109 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1110
1111 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1112
1113 # Do test here with the proper thread flags
1114 PGAC_FUNC_STRERROR_R_INT
1115
1116 CFLAGS="$_CFLAGS"
1117 LIBS="$_LIBS"
1118
1119 ], [ # else
1120 # do not use values from template file
1121 PTHREAD_CFLAGS=
1122 PTHREAD_LIBS=
1123 ]) # fi
1124
1125 AC_SUBST(PTHREAD_CFLAGS)
1126 AC_SUBST(PTHREAD_LIBS)
1127
1128
1129 ##
1130 ## Libraries
1131 ##
1132 ## Most libraries are included only if they demonstrably provide a function
1133 ## we need, but libm is an exception: always include it, because there are
1134 ## too many compilers that play cute optimization games that will break
1135 ## probes for standard functions such as pow().
1136 ##
1137
1138 AC_CHECK_LIB(m, main)
1139 AC_SEARCH_LIBS(setproctitle, util)
1140 AC_SEARCH_LIBS(dlopen, dl)
1141 AC_SEARCH_LIBS(socket, [socket ws2_32])
1142 AC_SEARCH_LIBS(shl_load, dld)
1143 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1144 AC_SEARCH_LIBS(crypt, crypt)
1145 AC_SEARCH_LIBS(shm_open, rt)
1146 AC_SEARCH_LIBS(shm_unlink, rt)
1147 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1148 # Solaris:
1149 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1150 # Required for thread_test.c on Solaris
1151 AC_SEARCH_LIBS(sched_yield, rt)
1152 # Required for thread_test.c on Solaris 2.5:
1153 # Other ports use it too (HP-UX) so test unconditionally
1154 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1155 # Cygwin:
1156 AC_SEARCH_LIBS(shmget, cygipc)
1157
1158 if test "$with_readline" = yes; then
1159   PGAC_CHECK_READLINE
1160   if test x"$pgac_cv_check_readline" = x"no"; then
1161     AC_MSG_ERROR([readline library not found
1162 If you have readline already installed, see config.log for details on the
1163 failure.  It is possible the compiler isn't looking in the proper directory.
1164 Use --without-readline to disable readline support.])
1165   fi
1166 fi
1167
1168 if test "$with_zlib" = yes; then
1169   AC_CHECK_LIB(z, inflate, [],
1170                [AC_MSG_ERROR([zlib library not found
1171 If you have zlib already installed, see config.log for details on the
1172 failure.  It is possible the compiler isn't looking in the proper directory.
1173 Use --without-zlib to disable zlib support.])])
1174 fi
1175
1176 if test "$enable_spinlocks" = yes; then
1177   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1178 else
1179   AC_MSG_WARN([
1180 *** Not using spinlocks will cause poor performance.])
1181 fi
1182
1183 if test "$enable_atomics" = yes; then
1184   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1185 else
1186   AC_MSG_WARN([
1187 *** Not using atomic operations will cause poor performance.])
1188 fi
1189
1190 if test "$with_gssapi" = yes ; then
1191   if test "$PORTNAME" != "win32"; then
1192     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1193                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1194   else
1195     LIBS="$LIBS -lgssapi32"
1196   fi
1197 fi
1198
1199 if test "$with_openssl" = yes ; then
1200   dnl Order matters!
1201   if test "$PORTNAME" != "win32"; then
1202      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1203      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1204   else
1205      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1206      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1207   fi
1208   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1209   # Functions introduced in OpenSSL 1.1.0. We used to check for
1210   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1211   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1212   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1213   # functions.
1214   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1215   # OpenSSL versions before 1.1.0 required setting callback functions, for
1216   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1217   # function was removed.
1218   AC_CHECK_FUNCS([CRYPTO_lock])
1219 fi
1220
1221 if test "$with_pam" = yes ; then
1222   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1223 fi
1224
1225 if test "$with_libxml" = yes ; then
1226   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1227 fi
1228
1229 if test "$with_libxslt" = yes ; then
1230   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1231 fi
1232
1233 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1234 if test "$with_ldap" = yes ; then
1235   _LIBS="$LIBS"
1236   if test "$PORTNAME" != "win32"; then
1237     AC_CHECK_LIB(ldap, ldap_bind, [],
1238                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1239                  [$EXTRA_LDAP_LIBS])
1240     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1241     if test "$enable_thread_safety" = yes; then
1242       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1243       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1244                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1245                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1246       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1247     else
1248       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1249     fi
1250     AC_CHECK_FUNCS([ldap_initialize])
1251   else
1252     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1253     LDAP_LIBS_FE="-lwldap32"
1254     LDAP_LIBS_BE="-lwldap32"
1255   fi
1256   LIBS="$_LIBS"
1257 fi
1258 AC_SUBST(LDAP_LIBS_FE)
1259 AC_SUBST(LDAP_LIBS_BE)
1260
1261 # for contrib/sepgsql
1262 if test "$with_selinux" = yes; then
1263   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1264                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1265 fi
1266
1267 # for contrib/uuid-ossp
1268 if test "$with_uuid" = bsd ; then
1269   # On BSD, the UUID functions are in libc
1270   AC_CHECK_FUNC(uuid_to_string,
1271     [UUID_LIBS=""],
1272     [AC_MSG_ERROR([BSD UUID functions are not present])])
1273 elif test "$with_uuid" = e2fs ; then
1274   # On macOS, the UUID functions are in libc
1275   AC_CHECK_FUNC(uuid_generate,
1276     [UUID_LIBS=""],
1277     [AC_CHECK_LIB(uuid, uuid_generate,
1278       [UUID_LIBS="-luuid"],
1279       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1280 elif test "$with_uuid" = ossp ; then
1281   AC_CHECK_LIB(ossp-uuid, uuid_export,
1282     [UUID_LIBS="-lossp-uuid"],
1283     [AC_CHECK_LIB(uuid, uuid_export,
1284       [UUID_LIBS="-luuid"],
1285       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1286 fi
1287 AC_SUBST(UUID_LIBS)
1288
1289
1290 ##
1291 ## Header files
1292 ##
1293
1294 AC_HEADER_STDBOOL
1295
1296 AC_CHECK_HEADERS(m4_normalize([
1297         atomic.h
1298         copyfile.h
1299         crypt.h
1300         fp_class.h
1301         getopt.h
1302         ieeefp.h
1303         ifaddrs.h
1304         langinfo.h
1305         mbarrier.h
1306         poll.h
1307         sys/epoll.h
1308         sys/ipc.h
1309         sys/prctl.h
1310         sys/procctl.h
1311         sys/pstat.h
1312         sys/resource.h
1313         sys/select.h
1314         sys/sem.h
1315         sys/shm.h
1316         sys/sockio.h
1317         sys/tas.h
1318         sys/un.h
1319         termios.h
1320         ucred.h
1321         utime.h
1322         wchar.h
1323         wctype.h
1324 ]))
1325
1326 # On BSD, test for net/if.h will fail unless sys/socket.h
1327 # is included first.
1328 AC_CHECK_HEADERS(net/if.h, [], [],
1329 [AC_INCLUDES_DEFAULT
1330 #include <sys/socket.h>
1331 ])
1332
1333 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1334 # is included first.
1335 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1336 [AC_INCLUDES_DEFAULT
1337 #include <sys/param.h>
1338 ])
1339
1340 # At least on IRIX, test for netinet/tcp.h will fail unless
1341 # netinet/in.h is included first.
1342 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1343 [AC_INCLUDES_DEFAULT
1344 #include <netinet/in.h>
1345 ])
1346
1347 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1348   AC_CHECK_HEADERS(readline/readline.h, [],
1349         [AC_CHECK_HEADERS(readline.h, [],
1350                 [AC_MSG_ERROR([readline header not found
1351 If you have readline already installed, see config.log for details on the
1352 failure.  It is possible the compiler isn't looking in the proper directory.
1353 Use --without-readline to disable readline support.])])])
1354   AC_CHECK_HEADERS(readline/history.h, [],
1355         [AC_CHECK_HEADERS(history.h, [],
1356                 [AC_MSG_ERROR([history header not found
1357 If you have readline already installed, see config.log for details on the
1358 failure.  It is possible the compiler isn't looking in the proper directory.
1359 Use --without-readline to disable readline support.])])])
1360 fi
1361
1362 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1363 # Some installations of libedit usurp /usr/include/readline/, which seems
1364 # bad practice, since in combined installations readline will have its headers
1365 # there.  We might have to resort to AC_EGREP checks to make sure we found
1366 # the proper header...
1367   AC_CHECK_HEADERS(editline/readline.h, [],
1368         [AC_CHECK_HEADERS(readline.h, [],
1369                 [AC_CHECK_HEADERS(readline/readline.h, [],
1370                         [AC_MSG_ERROR([readline header not found
1371 If you have libedit already installed, see config.log for details on the
1372 failure.  It is possible the compiler isn't looking in the proper directory.
1373 Use --without-readline to disable libedit support.])])])])
1374 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1375 # not be there at all.  Hence, don't complain if not found.  We must check
1376 # though, since in yet other versions it is an independent header.
1377   AC_CHECK_HEADERS(editline/history.h, [],
1378         [AC_CHECK_HEADERS(history.h, [],
1379                 [AC_CHECK_HEADERS(readline/history.h)])])
1380 fi
1381
1382 if test "$with_zlib" = yes; then
1383   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1384 If you have zlib already installed, see config.log for details on the
1385 failure.  It is possible the compiler isn't looking in the proper directory.
1386 Use --without-zlib to disable zlib support.])])
1387 fi
1388
1389 if test "$with_gssapi" = yes ; then
1390   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1391         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1392 fi
1393
1394 if test "$with_openssl" = yes ; then
1395   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1396   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1397 fi
1398
1399 if test "$with_pam" = yes ; then
1400   AC_CHECK_HEADERS(security/pam_appl.h, [],
1401                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1402                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1403 fi
1404
1405 if test "$with_bsd_auth" = yes ; then
1406   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1407 fi
1408
1409 if test "$with_systemd" = yes ; then
1410   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1411 fi
1412
1413 if test "$with_libxml" = yes ; then
1414   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1415 fi
1416
1417 if test "$with_libxslt" = yes ; then
1418   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1419 fi
1420
1421 if test "$with_ldap" = yes ; then
1422   if test "$PORTNAME" != "win32"; then
1423      AC_CHECK_HEADERS(ldap.h, [],
1424                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1425      PGAC_LDAP_SAFE
1426   else
1427      AC_CHECK_HEADERS(winldap.h, [],
1428                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1429                       [AC_INCLUDES_DEFAULT
1430 #include <windows.h>
1431                       ])
1432   fi
1433 fi
1434
1435 if test "$with_bonjour" = yes ; then
1436   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1437 dnl At some point we might add something like
1438 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1439 dnl but right now, what that would mainly accomplish is to encourage
1440 dnl people to try to use the avahi implementation, which does not work.
1441 dnl If you want to use Apple's own Bonjour code on another platform,
1442 dnl just add -ldns_sd to LIBS manually.
1443 fi
1444
1445 # for contrib/uuid-ossp
1446 if test "$with_uuid" = bsd ; then
1447   AC_CHECK_HEADERS(uuid.h,
1448     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1449       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1450     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1451 elif test "$with_uuid" = e2fs ; then
1452   AC_CHECK_HEADERS(uuid/uuid.h,
1453     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1454       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1455     [AC_CHECK_HEADERS(uuid.h,
1456       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1457         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1458       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1459 elif test "$with_uuid" = ossp ; then
1460   AC_CHECK_HEADERS(ossp/uuid.h,
1461     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1462       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1463     [AC_CHECK_HEADERS(uuid.h,
1464       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1465         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1466       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1467 fi
1468
1469 if test "$PORTNAME" = "win32" ; then
1470    AC_CHECK_HEADERS(crtdefs.h)
1471 fi
1472
1473 ##
1474 ## Types, structures, compiler characteristics
1475 ##
1476
1477 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1478 AC_C_BIGENDIAN
1479 AC_C_INLINE
1480 PGAC_PRINTF_ARCHETYPE
1481 AC_C_FLEXIBLE_ARRAY_MEMBER
1482 PGAC_C_SIGNED
1483 PGAC_C_FUNCNAME_SUPPORT
1484 PGAC_C_STATIC_ASSERT
1485 PGAC_C_TYPEOF
1486 PGAC_C_TYPES_COMPATIBLE
1487 PGAC_C_BUILTIN_BSWAP16
1488 PGAC_C_BUILTIN_BSWAP32
1489 PGAC_C_BUILTIN_BSWAP64
1490 PGAC_C_BUILTIN_CONSTANT_P
1491 PGAC_C_BUILTIN_UNREACHABLE
1492 PGAC_C_COMPUTED_GOTO
1493 PGAC_STRUCT_TIMEZONE
1494 PGAC_UNION_SEMUN
1495 PGAC_STRUCT_SOCKADDR_UN
1496 PGAC_STRUCT_SOCKADDR_STORAGE
1497 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1498 PGAC_STRUCT_ADDRINFO
1499 AC_TYPE_INTPTR_T
1500 AC_TYPE_UINTPTR_T
1501 AC_TYPE_LONG_LONG_INT
1502
1503 PGAC_TYPE_LOCALE_T
1504
1505 # MSVC doesn't cope well with defining restrict to __restrict, the
1506 # spelling it understands, because it conflicts with
1507 # __declspec(restrict). Therefore we define pg_restrict to the
1508 # appropriate definition, which presumably won't conflict.
1509 #
1510 # Allow platforms with buggy compilers to force restrict to not be
1511 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1512 # template.
1513 AC_C_RESTRICT
1514 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1515   pg_restrict=""
1516 else
1517   pg_restrict="$ac_cv_c_restrict"
1518 fi
1519 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1520 [Define to keyword to use for C99 restrict support, or to nothing if not
1521 supported])
1522
1523 AC_CHECK_TYPES([struct cmsgcred], [], [],
1524 [#include <sys/socket.h>
1525 #include <sys/param.h>
1526 #ifdef HAVE_SYS_UCRED_H
1527 #include <sys/ucred.h>
1528 #endif])
1529
1530 AC_CHECK_TYPES([struct option], [], [],
1531 [#ifdef HAVE_GETOPT_H
1532 #include <getopt.h>
1533 #endif])
1534
1535 if test "$with_zlib" = yes; then
1536   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1537   # did not).  While we could work around the lack of z_streamp, it
1538   # seems unwise to encourage people to use such old zlib versions...
1539   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1540 Use --without-zlib to disable zlib support.])],
1541                 [#include <zlib.h>])
1542 fi
1543
1544 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1545 case $host_cpu in
1546   ppc*|powerpc*)
1547     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1548     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1549         [int a = 0; int *p = &a; int r;
1550          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1551         [pgac_cv_have_ppc_mutex_hint=yes],
1552         [pgac_cv_have_ppc_mutex_hint=no])
1553     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1554     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1555         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1556     fi
1557   ;;
1558 esac
1559
1560 # Check largefile support.  You might think this is a system service not a
1561 # compiler characteristic, but you'd be wrong.  We must check this before
1562 # probing existence of related functions such as fseeko, since the largefile
1563 # defines can affect what is generated for that.
1564 if test "$PORTNAME" != "win32"; then
1565    AC_SYS_LARGEFILE
1566    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1567    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1568    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1569    dnl versions where the feature actually works, it's on by default anyway.
1570    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1571 fi
1572
1573 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1574 AC_CHECK_SIZEOF([off_t])
1575
1576 # If we don't have largefile support, can't handle segsize >= 2GB.
1577 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1578    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1579 fi
1580
1581 AC_CHECK_SIZEOF([bool], [],
1582 [#ifdef HAVE_STDBOOL_H
1583 #include <stdbool.h>
1584 #endif])
1585
1586
1587 ##
1588 ## Functions, global variables
1589 ##
1590
1591 PGAC_VAR_INT_TIMEZONE
1592 AC_FUNC_ACCEPT_ARGTYPES
1593 PGAC_FUNC_GETTIMEOFDAY_1ARG
1594 PGAC_FUNC_WCSTOMBS_L
1595
1596 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1597 # symbols that that library has no business exposing to the world.  Pending
1598 # acquisition of a clue by those developers, ignore libedit (including its
1599 # possible alias of libreadline) while checking for everything else.
1600 LIBS_including_readline="$LIBS"
1601 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1602
1603 AC_CHECK_FUNCS(m4_normalize([
1604         cbrt
1605         clock_gettime
1606         copyfile
1607         fdatasync
1608         getifaddrs
1609         getpeerucred
1610         getrlimit
1611         mbstowcs_l
1612         memmove
1613         poll
1614         posix_fallocate
1615         ppoll
1616         pstat
1617         pthread_is_threaded_np
1618         readlink
1619         setproctitle
1620         setproctitle_fast
1621         setsid
1622         shm_open
1623         strchrnul
1624         strsignal
1625         symlink
1626         sync_file_range
1627         utime
1628         utimes
1629         wcstombs_l
1630 ]))
1631
1632 AC_REPLACE_FUNCS(fseeko)
1633 case $host_os in
1634         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1635         # Mingw uses macros to access Win32 API calls
1636         netbsd*|mingw*)
1637                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1638                 ac_cv_func_fseeko=yes;;
1639         *)
1640                 AC_FUNC_FSEEKO;;
1641 esac
1642
1643 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1644 # by calling it, 2009-04-02
1645 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1646 dnl must use AS_IF here, else AC_REQUIRES inside AC_CHECK_DECLS malfunctions
1647 AS_IF([test "$PORTNAME" != "solaris"], [
1648 AC_CHECK_FUNCS(posix_fadvise)
1649 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1650 ]) # fi
1651
1652 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1653 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1654 # This is probably only present on macOS, but may as well check always
1655 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1656
1657 AC_CHECK_DECLS([RTLD_GLOBAL, RTLD_NOW], [], [], [#include <dlfcn.h>])
1658
1659 AC_CHECK_TYPE([struct sockaddr_in6],
1660         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])],
1661         [],
1662 [$ac_includes_default
1663 #include <netinet/in.h>])
1664
1665 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1666 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1667 [#include <machine/vmparam.h>
1668 #include <sys/exec.h>
1669 ],
1670 [PS_STRINGS->ps_nargvstr = 1;
1671 PS_STRINGS->ps_argvstr = "foo";])],
1672 [pgac_cv_var_PS_STRINGS=yes],
1673 [pgac_cv_var_PS_STRINGS=no])])
1674 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1675   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1676 fi
1677
1678
1679 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1680 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1681 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1682 #include <math.h>
1683 double glob_double;
1684 ],
1685 [return isinf(glob_double) ? 0 : 1;])],
1686 [ac_cv_func_isinf=yes],
1687 [ac_cv_func_isinf=no])])
1688
1689 if test $ac_cv_func_isinf = yes ; then
1690   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1691 else
1692   AC_LIBOBJ(isinf)
1693   # Look for a way to implement a substitute for isinf()
1694   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1695 fi
1696
1697 AC_REPLACE_FUNCS(m4_normalize([
1698         crypt
1699         dlopen
1700         fls
1701         getopt
1702         getrusage
1703         inet_aton
1704         mkdtemp
1705         pread
1706         pwrite
1707         random
1708         rint
1709         srandom
1710         strlcat
1711         strlcpy
1712         strnlen
1713 ]))
1714
1715 case $host_os in
1716
1717         # Windows uses a specialised env handler
1718         # and doesn't need a replacement getpeereid because it doesn't use
1719         # Unix sockets.
1720         mingw*)
1721                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1722                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1723                 ac_cv_func_unsetenv=yes
1724                 ac_cv_func_getpeereid=yes;;
1725         *)
1726                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1727                 ;;
1728 esac
1729
1730 # System's version of getaddrinfo(), if any, may be used only if we found
1731 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1732 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1733 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1734    test "$PORTNAME" != "win32"; then
1735   AC_REPLACE_FUNCS([getaddrinfo])
1736 else
1737   AC_LIBOBJ(getaddrinfo)
1738 fi
1739
1740 # Similarly, use system's getopt_long() only if system provides struct option.
1741 if test x"$ac_cv_type_struct_option" = xyes ; then
1742   AC_REPLACE_FUNCS([getopt_long])
1743 else
1744   AC_LIBOBJ(getopt_long)
1745 fi
1746
1747 # Solaris' getopt() doesn't do what we want for long options, so always use
1748 # our version on that platform.
1749 if test "$PORTNAME" = "solaris"; then
1750   AC_LIBOBJ(getopt)
1751 fi
1752
1753 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1754 # so always use our version on Windows.
1755 if test "$PORTNAME" = "win32"; then
1756   AC_LIBOBJ(getopt)
1757   AC_LIBOBJ(getopt_long)
1758 fi
1759
1760 # Win32 (really MinGW) support
1761 if test "$PORTNAME" = "win32"; then
1762   AC_REPLACE_FUNCS(gettimeofday)
1763   AC_LIBOBJ(dirmod)
1764   AC_LIBOBJ(kill)
1765   AC_LIBOBJ(open)
1766   AC_LIBOBJ(system)
1767   AC_LIBOBJ(win32env)
1768   AC_LIBOBJ(win32error)
1769   AC_LIBOBJ(win32security)
1770   AC_LIBOBJ(win32setlocale)
1771   AC_DEFINE([HAVE_SYMLINK], 1,
1772             [Define to 1 if you have the `symlink' function.])
1773   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1774 #define WIN32_LEAN_AND_MEAN
1775 #include <windows.h>
1776 #include <string.h>
1777 #include <dbghelp.h>])
1778 fi
1779 if test x"$pgac_minidump_type" = x"yes" ; then
1780   AC_SUBST(have_win32_dbghelp,yes)
1781 else
1782   AC_SUBST(have_win32_dbghelp,no)
1783 fi
1784
1785 # Cygwin needs only a bit of that
1786 if test "$PORTNAME" = "cygwin"; then
1787   AC_LIBOBJ(dirmod)
1788 fi
1789
1790 AC_CHECK_FUNC(syslog,
1791               [AC_CHECK_HEADER(syslog.h,
1792                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1793
1794 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1795 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1796   [extern int opterr; opterr = 1;])],
1797   [pgac_cv_var_int_opterr=yes],
1798   [pgac_cv_var_int_opterr=no])])
1799 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1800   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1801 fi
1802
1803 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1804 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1805   [extern int optreset; optreset = 1;])],
1806   [pgac_cv_var_int_optreset=yes],
1807   [pgac_cv_var_int_optreset=no])])
1808 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1809   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1810 fi
1811
1812 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1813 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1814 # strto[u]ll may exist but not be declared
1815 AC_CHECK_DECLS([strtoll, strtoull])
1816
1817 if test "$with_icu" = yes; then
1818   ac_save_CPPFLAGS=$CPPFLAGS
1819   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1820
1821   # Verify we have ICU's header files
1822   AC_CHECK_HEADER(unicode/ucol.h, [],
1823         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1824
1825   CPPFLAGS=$ac_save_CPPFLAGS
1826 fi
1827
1828 if test "$with_llvm" = yes; then
1829   PGAC_CHECK_LLVM_FUNCTIONS()
1830 fi
1831
1832 # Lastly, restore full LIBS list and check for readline/libedit symbols
1833 LIBS="$LIBS_including_readline"
1834
1835 if test "$with_readline" = yes; then
1836   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1837   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1838   AC_CHECK_FUNCS([append_history history_truncate_file])
1839 fi
1840
1841
1842 # This test makes sure that run tests work at all.  Sometimes a shared
1843 # library is found by the linker, but the runtime linker can't find it.
1844 # This check should come after all modifications of compiler or linker
1845 # variables, and before any other run tests.
1846 AC_MSG_CHECKING([test program])
1847 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1848 [AC_MSG_RESULT(ok)],
1849 [AC_MSG_RESULT(failed)
1850 AC_MSG_ERROR([[
1851 Could not execute a simple test program.  This may be a problem
1852 related to locating shared libraries.  Check the file 'config.log'
1853 for the exact reason.]])],
1854 [AC_MSG_RESULT([cross-compiling])])
1855
1856 # --------------------
1857 # Run tests below here
1858 # --------------------
1859
1860 dnl Check to see if we have a working 64-bit integer type.
1861 dnl Since Postgres 8.4, we no longer support compilers without a working
1862 dnl 64-bit type; but we have to determine whether that type is called
1863 dnl "long int" or "long long int".
1864
1865 PGAC_TYPE_64BIT_INT([long int])
1866
1867 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1868   pg_int64_type="long int"
1869 else
1870   PGAC_TYPE_64BIT_INT([long long int])
1871   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1872     pg_int64_type="long long int"
1873   else
1874     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1875   fi
1876 fi
1877
1878 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1879   [Define to the name of a signed 64-bit integer type.])
1880
1881 # Select the printf length modifier that goes with that, too.
1882 if test x"$pg_int64_type" = x"long long int" ; then
1883   INT64_MODIFIER='"ll"'
1884 else
1885   INT64_MODIFIER='"l"'
1886 fi
1887
1888 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1889                    [Define to the appropriate printf length modifier for 64-bit ints.])
1890
1891 # has to be down here, rather than with the other builtins, because
1892 # the test uses PG_INT64_TYPE.
1893 PGAC_C_BUILTIN_OP_OVERFLOW
1894
1895 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1896 AC_CHECK_SIZEOF([void *])
1897 AC_CHECK_SIZEOF([size_t])
1898 AC_CHECK_SIZEOF([long])
1899
1900 # Decide whether float4 is passed by value: user-selectable, enabled by default
1901 AC_MSG_CHECKING([whether to build with float4 passed by value])
1902 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1903               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1904                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1905                float4passbyval=true],
1906               [float4passbyval=false])
1907 AC_MSG_RESULT([$enable_float4_byval])
1908 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1909
1910 # Decide whether float8 is passed by value.
1911 # Note: this setting also controls int8 and related types such as timestamp.
1912 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1913 # If not, trying to select it is an error.
1914 AC_MSG_CHECKING([whether to build with float8 passed by value])
1915 if test $ac_cv_sizeof_void_p -ge 8 ; then
1916   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1917 else
1918   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1919   if test "$enable_float8_byval" = yes ; then
1920     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1921   fi
1922 fi
1923 if test "$enable_float8_byval" = yes ; then
1924   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1925             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1926   float8passbyval=true
1927 else
1928   float8passbyval=false
1929 fi
1930 AC_MSG_RESULT([$enable_float8_byval])
1931 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1932
1933 # Determine memory alignment requirements for the basic C data types.
1934
1935 AC_CHECK_ALIGNOF(short)
1936 AC_CHECK_ALIGNOF(int)
1937 AC_CHECK_ALIGNOF(long)
1938 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1939   AC_CHECK_ALIGNOF(long long int)
1940 fi
1941 AC_CHECK_ALIGNOF(double)
1942
1943 # Compute maximum alignment of any basic type.
1944 # We assume long's alignment is at least as strong as char, short, or int;
1945 # but we must check long long (if it is being used for int64) and double.
1946 # Note that we intentionally do not consider any types wider than 64 bits,
1947 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1948 # for disk and memory space.
1949
1950 MAX_ALIGNOF=$ac_cv_alignof_long
1951 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1952   MAX_ALIGNOF=$ac_cv_alignof_double
1953 fi
1954 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1955   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1956 fi
1957 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1958
1959
1960 # Some platforms predefine the types int8, int16, etc.  Only check
1961 # a (hopefully) representative subset.
1962 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1963 [#include <stdio.h>])
1964
1965 # Some compilers offer a 128-bit integer scalar type.
1966 PGAC_TYPE_128BIT_INT
1967
1968 # Check for various atomic operations now that we have checked how to declare
1969 # 64bit integers.
1970 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1971 PGAC_HAVE_GCC__SYNC_INT32_TAS
1972 PGAC_HAVE_GCC__SYNC_INT32_CAS
1973 PGAC_HAVE_GCC__SYNC_INT64_CAS
1974 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1975 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1976
1977
1978 # Check for x86 cpuid instruction
1979 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1980 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1981   [[unsigned int exx[4] = {0, 0, 0, 0};
1982   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1983   ]])],
1984   [pgac_cv__get_cpuid="yes"],
1985   [pgac_cv__get_cpuid="no"])])
1986 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1987   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1988 fi
1989
1990 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1991 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1992   [[unsigned int exx[4] = {0, 0, 0, 0};
1993   __get_cpuid(exx[0], 1);
1994   ]])],
1995   [pgac_cv__cpuid="yes"],
1996   [pgac_cv__cpuid="no"])])
1997 if test x"$pgac_cv__cpuid" = x"yes"; then
1998   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
1999 fi
2000
2001 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
2002 #
2003 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
2004 # with the default compiler flags. If not, check if adding the -msse4.2
2005 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
2006 PGAC_SSE42_CRC32_INTRINSICS([])
2007 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
2008   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
2009 fi
2010 AC_SUBST(CFLAGS_SSE42)
2011
2012 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
2013 # define __SSE4_2__ in that case.
2014 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2015 #ifndef __SSE4_2__
2016 #error __SSE4_2__ not defined
2017 #endif
2018 ])], [SSE4_2_TARGETED=1])
2019
2020 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
2021 #
2022 # First check if __crc32c* intrinsics can be used with the default compiler
2023 # flags. If not, check if adding -march=armv8-a+crc flag helps.
2024 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
2025 PGAC_ARMV8_CRC32C_INTRINSICS([])
2026 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
2027   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
2028 fi
2029 AC_SUBST(CFLAGS_ARMV8_CRC32C)
2030
2031 # Select CRC-32C implementation.
2032 #
2033 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
2034 # use the special CRC instructions for calculating CRC-32C. If we're not
2035 # targeting such a processor, but we can nevertheless produce code that uses
2036 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2037 # implementations and select which one to use at runtime, depending on whether
2038 # SSE 4.2 is supported by the processor we're running on.
2039 #
2040 # Similarly, if we are targeting an ARM processor that has the CRC
2041 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2042 # we're not targeting such a processor, but can nevertheless produce code that
2043 # uses the CRC instructions, compile both, and select at runtime.
2044 #
2045 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2046 # in the template or configure command line.
2047 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2048   # Use Intel SSE 4.2 if available.
2049   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2050     USE_SSE42_CRC32C=1
2051   else
2052     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2053     # the runtime check.
2054     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2055       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2056     else
2057       # Use ARM CRC Extension if available.
2058       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2059         USE_ARMV8_CRC32C=1
2060       else
2061         # ARM CRC Extension, with runtime check?
2062         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2063           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2064         else
2065           # fall back to slicing-by-8 algorithm, which doesn't require any
2066           # special CPU support.
2067           USE_SLICING_BY_8_CRC32C=1
2068         fi
2069       fi
2070     fi
2071   fi
2072 fi
2073
2074 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2075 AC_MSG_CHECKING([which CRC-32C implementation to use])
2076 if test x"$USE_SSE42_CRC32C" = x"1"; then
2077   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2078   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2079   AC_MSG_RESULT(SSE 4.2)
2080 else
2081   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2082     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2083     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2084     AC_MSG_RESULT(SSE 4.2 with runtime check)
2085   else
2086     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2087       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2088       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2089       AC_MSG_RESULT(ARMv8 CRC instructions)
2090     else
2091       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2092         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2093         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2094         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2095       else
2096         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2097         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2098         AC_MSG_RESULT(slicing-by-8)
2099       fi
2100     fi
2101   fi
2102 fi
2103 AC_SUBST(PG_CRC32C_OBJS)
2104
2105
2106 # Select semaphore implementation type.
2107 if test "$PORTNAME" != "win32"; then
2108   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2109     # Need sem_open for this
2110     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2111   fi
2112   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2113     # Need sem_init for this
2114     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2115   fi
2116   AC_MSG_CHECKING([which semaphore API to use])
2117   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2118     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2119     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2120     sematype="named POSIX"
2121   else
2122     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2123       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2124       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2125       sematype="unnamed POSIX"
2126     else
2127       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2128       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2129       sematype="System V"
2130     fi
2131   fi
2132   AC_MSG_RESULT([$sematype])
2133 else
2134   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2135   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2136 fi
2137
2138
2139 # Select shared-memory implementation type.
2140 if test "$PORTNAME" != "win32"; then
2141   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2142   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2143 else
2144   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2145   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2146 fi
2147
2148 # Select random number source
2149 #
2150 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2151 # in the template or configure command line.
2152
2153 # If not selected manually, try to select a source automatically.
2154 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2155   if test x"$with_openssl" = x"yes" ; then
2156     USE_OPENSSL_RANDOM=1
2157   elif test "$PORTNAME" = "win32" ; then
2158     USE_WIN32_RANDOM=1
2159   else
2160     AC_CHECK_FILE([/dev/urandom], [], [])
2161
2162     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2163       USE_DEV_URANDOM=1
2164     fi
2165   fi
2166 fi
2167
2168 AC_MSG_CHECKING([which random number source to use])
2169 if test "$enable_strong_random" = yes ; then
2170   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2171     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2172     AC_MSG_RESULT([OpenSSL])
2173   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2174     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2175     AC_MSG_RESULT([Windows native])
2176   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2177     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2178     AC_MSG_RESULT([/dev/urandom])
2179   else
2180     AC_MSG_ERROR([
2181 no source of strong random numbers was found
2182 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2183 for authentication protocols. You can use --disable-strong-random to use a
2184 built-in pseudo random number generator, but that may be insecure.])
2185   fi
2186   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2187 else
2188     AC_MSG_RESULT([weak builtin PRNG])
2189     AC_MSG_WARN([
2190 *** Not using a strong random number source may be insecure.])
2191 fi
2192
2193 # If not set in template file, set bytes to use libc memset()
2194 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2195   MEMSET_LOOP_LIMIT=1024
2196 fi
2197 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2198
2199
2200 if test "$enable_nls" = yes ; then
2201   PGAC_CHECK_GETTEXT
2202 fi
2203
2204 # Check for Tcl configuration script tclConfig.sh
2205 if test "$with_tcl" = yes; then
2206     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2207     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2208                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2209     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2210     if test "$TCL_SHARED_BUILD" != 1; then
2211       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2212 Use --without-tcl to disable building PL/Tcl.])
2213     fi
2214     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2215     ac_save_CPPFLAGS=$CPPFLAGS
2216     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2217     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2218     CPPFLAGS=$ac_save_CPPFLAGS
2219 fi
2220
2221 # check for <perl.h>
2222 if test "$with_perl" = yes; then
2223   ac_save_CPPFLAGS=$CPPFLAGS
2224   CPPFLAGS="$CPPFLAGS $perl_includespec"
2225   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2226                   [#include <EXTERN.h>])
2227   # While we're at it, check that we can link to libperl.
2228   # On most platforms, if perl.h is there then libperl.so will be too, but at
2229   # this writing Debian packages them separately.  There is no known reason to
2230   # waste cycles on separate probes for the Tcl or Python libraries, though.
2231   pgac_save_LIBS=$LIBS
2232   LIBS="$perl_embed_ldflags"
2233   AC_MSG_CHECKING([for libperl])
2234   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2235 #include <EXTERN.h>
2236 #include <perl.h>
2237 ],  [perl_alloc();])],
2238     [AC_MSG_RESULT(yes)],
2239     [AC_MSG_RESULT(no)
2240      AC_MSG_ERROR([libperl library is required for Perl])])
2241   LIBS=$pgac_save_LIBS
2242   CPPFLAGS=$ac_save_CPPFLAGS
2243 fi
2244
2245 # check for <Python.h>
2246 if test "$with_python" = yes; then
2247   ac_save_CPPFLAGS=$CPPFLAGS
2248   CPPFLAGS="$python_includespec $CPPFLAGS"
2249   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2250   CPPFLAGS=$ac_save_CPPFLAGS
2251 fi
2252
2253 #
2254 # Check for DocBook and tools
2255 #
2256 PGAC_PATH_XMLLINT
2257 PGAC_CHECK_DOCBOOK(4.2)
2258 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2259 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2260 PGAC_PATH_PROGS(FOP, fop)
2261
2262 #
2263 # Check for test tools
2264 #
2265 if test "$enable_tap_tests" = yes; then
2266   # Check for necessary modules, unless user has specified the "prove" to use;
2267   # in that case it's her responsibility to have a working configuration.
2268   # (prove might be part of a different Perl installation than perl, eg on
2269   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2270   if test -z "$PROVE"; then
2271     # Test::More and Time::HiRes are supposed to be part of core Perl,
2272     # but some distros omit them in a minimal installation.
2273     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2274       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2275   fi
2276   # Now make sure we know where prove is
2277   PGAC_PATH_PROGS(PROVE, prove)
2278   if test -z "$PROVE"; then
2279     AC_MSG_ERROR([prove not found])
2280   fi
2281 fi
2282
2283 # Thread testing
2284
2285 # We have to run the thread test near the end so we have all our symbols
2286 # defined.  Cross compiling throws a warning.
2287 #
2288 if test "$enable_thread_safety" = yes; then
2289 if test "$PORTNAME" != "win32"
2290 then
2291 AC_MSG_CHECKING([thread safety of required library functions])
2292
2293 _CFLAGS="$CFLAGS"
2294 _LIBS="$LIBS"
2295 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2296 LIBS="$LIBS $PTHREAD_LIBS"
2297 AC_RUN_IFELSE(
2298   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2299   [AC_MSG_RESULT(yes)],
2300   [AC_MSG_RESULT(no)
2301   AC_MSG_ERROR([thread test program failed
2302 This platform is not thread-safe.  Check the file 'config.log' or compile
2303 and run src/test/thread/thread_test for the exact reason.
2304 Use --disable-thread-safety to disable thread safety.])],
2305   [AC_MSG_RESULT(maybe)
2306   AC_MSG_WARN([
2307 *** Skipping thread test program because of cross-compile build.
2308 *** Run the program in src/test/thread on the target machine.
2309 ])])
2310 CFLAGS="$_CFLAGS"
2311 LIBS="$_LIBS"
2312 else
2313 AC_MSG_WARN([*** skipping thread test on Win32])
2314 fi
2315 fi
2316
2317 # If compiler will take -Wl,--as-needed (or various platform-specific
2318 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2319 # trying to filter LIBS to the minimum for each executable.
2320 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2321 # libreadline; therefore we postpone testing it until we know what library
2322 # dependencies readline has.  The test code will try to link with $LIBS.
2323 if test "$with_readline" = yes; then
2324   link_test_func=readline
2325 else
2326   link_test_func=exit
2327 fi
2328
2329 if test "$PORTNAME" = "darwin"; then
2330   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2331 elif test "$PORTNAME" = "openbsd"; then
2332   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2333 else
2334   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2335 fi
2336
2337 # Create compiler version string
2338 if test x"$GCC" = x"yes" ; then
2339   cc_string=`${CC} --version | sed q`
2340   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2341 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2342   cc_string=`${CC} -V 2>&1 | sed q`
2343 else
2344   cc_string=$CC
2345 fi
2346
2347 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2348                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2349                    [A string containing the version number, platform, and C compiler])
2350
2351 # Supply a numeric version string for use by 3rd party add-ons
2352 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2353 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2354 tr '.' '        ' |
2355 $AWK '{printf "%d%04d", $1, $2}'`"]
2356 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2357 AC_SUBST(PG_VERSION_NUM)
2358
2359 # If we are inserting PG_SYSROOT into CPPFLAGS, do so symbolically not
2360 # literally, so that it's possible to override it at build time using
2361 # a command like "make ... PG_SYSROOT=path".  This has to be done after
2362 # we've finished all configure checks that depend on CPPFLAGS.
2363 if test x"$PG_SYSROOT" != x; then
2364   CPPFLAGS=`echo "$CPPFLAGS" | sed -e "s| $PG_SYSROOT | \\\$(PG_SYSROOT) |"`
2365 fi
2366 AC_SUBST(PG_SYSROOT)
2367
2368
2369 # Begin output steps
2370
2371 AC_MSG_NOTICE([using compiler=$cc_string])
2372 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2373 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2374 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2375 # Currently only used when LLVM is used
2376 if test "$with_llvm" = yes ; then
2377    AC_MSG_NOTICE([using CXX=$CXX])
2378    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2379    AC_MSG_NOTICE([using CLANG=$CLANG])
2380    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2381    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2382 fi
2383
2384 # prepare build tree if outside source tree
2385 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2386 # Note 2: /bin/pwd might be better than shell's built-in at getting
2387 #         a symlink-free name.
2388 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2389   vpath_build=no
2390 else
2391   vpath_build=yes
2392   if test "$no_create" != yes; then
2393     _AS_ECHO_N([preparing build tree... ])
2394     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2395     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2396       || AC_MSG_ERROR(failed)
2397     AC_MSG_RESULT(done)
2398   fi
2399 fi
2400 AC_SUBST(vpath_build)
2401
2402
2403 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2404
2405 AC_CONFIG_LINKS([
2406   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2407   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2408   src/include/pg_config_os.h:src/include/port/${template}.h
2409   src/Makefile.port:src/makefiles/Makefile.${template}
2410 ])
2411
2412 if test "$PORTNAME" = "win32"; then
2413 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2414 # Links sometimes fail undetected on Mingw -
2415 # so here we detect it and warn the user
2416 for FILE in $CONFIG_LINKS
2417  do
2418         # test -e works for symlinks in the MinGW console
2419         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2420  done
2421 ])
2422 fi
2423
2424 AC_CONFIG_HEADERS([src/include/pg_config.h],
2425 [
2426 # Update timestamp for pg_config.h (see Makefile.global)
2427 echo >src/include/stamp-h
2428 ])
2429
2430 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2431 [
2432 # Update timestamp for pg_config_ext.h (see Makefile.global)
2433 echo >src/include/stamp-ext-h
2434 ])
2435
2436 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2437                   [echo >src/interfaces/ecpg/include/stamp-h])
2438
2439 AC_OUTPUT