granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.436 2005/12/06 18:35:09 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2005, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix ;;
  60  linux*|gnu*|k*bsd*-gnu)
  61            template=linux ;;
  62    mingw*) template=win32 ;;
  63   netbsd*) template=netbsd ;;
  64 nextstep*) template=nextstep ;;
  65  openbsd*) template=openbsd ;;
  66      osf*) template=osf ;;
  67      qnx*) template=qnx4 ;;
  68      sco*) template=sco ;;
  69  solaris*) template=solaris ;;
  70    sunos*) template=sunos4 ;;
  71  sysv4.2*)
  72         case $host_vendor in
  73           univel) template=univel ;;
  74         esac ;;
  75    sysv4*) template=svr4 ;;
  76    sysv5*) template=unixware ;;
  77   ultrix*) template=ultrix4 ;;
  78 esac
  79
  80   if test x"$template" = x"" ; then
  81     AC_MSG_ERROR([[
  82 *******************************************************************
  83 PostgreSQL has apparently not been ported to your platform yet.
  84 To try a manual configuration, look into the src/template directory
  85 for a similar platform and use the '--with-template=' option.
  86
  87 Please also contact <pgsql-ports@postgresql.org> to see about
  88 rectifying this.  Include the above 'checking host system type...'
  89 line.
  90 *******************************************************************
  91 ]])
  92   fi
  93
  94 ])
  95
  96 AC_MSG_RESULT([$template])
  97
  98 PORTNAME=$template
  99 AC_SUBST(PORTNAME)
 100
 101 # Initialize default assumption that we do not need separate assembly code
 102 # for TAS (test-and-set).  This can be overridden by the template file
 103 # when it's executed.
 104 need_tas=no
 105 tas_file=dummy.s
 106
 107
 108
 109 ##
 110 ## Command line options
 111 ##
 112
 113 #
 114 # Installation directory for documentation
 115 #
 116 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 117   --without-docdir        do not install the documentation],
 118          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 119          [docdir=],
 120          [docdir=$withval],
 121          [docdir='${prefix}/doc'])
 122 AC_SUBST(docdir)
 123
 124
 125 #
 126 # Add non-standard directories to the include path
 127 #
 128 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 129
 130
 131 #
 132 # Add non-standard directories to the library search path
 133 #
 134 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 135              [LIBRARY_DIRS=$withval])
 136
 137 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 138              [LIBRARY_DIRS=$withval])
 139
 140
 141 #
 142 # 64-bit integer date/time storage (--enable-integer-datetimes)
 143 #
 144 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 145 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 146               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 147                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 148 AC_MSG_RESULT([$enable_integer_datetimes])
 149
 150
 151 #
 152 # NLS
 153 #
 154 AC_MSG_CHECKING([whether NLS is wanted])
 155 PGAC_ARG_OPTARG(enable, nls,
 156                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 157                 [],
 158                 [WANTED_LANGUAGES=$enableval],
 159                 [AC_DEFINE(ENABLE_NLS, 1,
 160                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 161 AC_MSG_RESULT([$enable_nls])
 162 AC_SUBST(enable_nls)
 163 AC_SUBST(WANTED_LANGUAGES)
 164
 165 #
 166 # Default port number (--with-pgport), default 5432
 167 #
 168 AC_MSG_CHECKING([for default port number])
 169 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 170              [default_port=$withval],
 171              [default_port=5432])
 172 AC_MSG_RESULT([$default_port])
 173 # Need both of these because some places want an integer and some a string
 174 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 175 [Define to the default TCP port number on which the server listens and
 176 to which clients will try to connect.  This can be overridden at run-time,
 177 but it's convenient if your clients have the right default compiled in.
 178 (--with-pgport=PORTNUM)])
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 180                    [Define to the default TCP port number as a string constant.])
 181 AC_SUBST(default_port)
 182
 183 #
 184 # Option to disable shared libraries
 185 #
 186 PGAC_ARG_BOOL(enable, shared, yes,
 187               [  --disable-shared        do not build shared libraries])
 188 AC_SUBST(enable_shared)
 189
 190 #
 191 # '-rpath'-like feature can be disabled
 192 #
 193 PGAC_ARG_BOOL(enable, rpath, yes,
 194               [  --disable-rpath         do not embed shared library search path in executables])
 195 AC_SUBST(enable_rpath)
 196
 197 #
 198 # Spinlocks
 199 #
 200 PGAC_ARG_BOOL(enable, spinlocks, yes,
 201               [  --disable-spinlocks     do not use spinlocks])
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226
 227 unset CFLAGS
 228
 229 #
 230 # Read the template
 231 #
 232 . "$srcdir/src/template/$template" || exit
 233
 234 # CFLAGS are selected so:
 235 # If the user specifies something in the environment, that is used.
 236 # else:  If the template file set something, that is used.
 237 # else:  If the compiler is GCC, then we use -O2.
 238 # else:  If the compiler is something else, then we use -0.
 239
 240 if test "$ac_env_CFLAGS_set" = set; then
 241   CFLAGS=$ac_env_CFLAGS_value
 242 elif test "${CFLAGS+set}" = set; then
 243   : # (keep what template set)
 244 elif test "$GCC" = yes; then
 245   CFLAGS="-O2"
 246 else
 247   # if the user selected debug mode, don't use -O
 248   if test "$enable_debug" != yes; then
 249     CFLAGS="-O"
 250   fi
 251 fi
 252
 253 if test "$GCC" = yes; then
 254   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 255
 256   # Some versions of GCC support some additional useful warning flags.
 257   # Check whether they are supported, and add them to CFLAGS if so.
 258   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 259   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 260
 261   # Disable strict-aliasing rules; needed for gcc 3.3+
 262   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 263 fi
 264
 265 # supply -g if --enable-debug
 266 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 267   CFLAGS="$CFLAGS -g"
 268 fi
 269
 270 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 271
 272 # We already have this in Makefile.win32, but configure needs it too
 273 if test "$PORTNAME" = "win32"; then
 274   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 275 fi
 276
 277 # Check if the compiler still works with the template settings
 278 AC_MSG_CHECKING([whether the C compiler still works])
 279 AC_TRY_LINK([], [return 0;],
 280   [AC_MSG_RESULT(yes)],
 281   [AC_MSG_RESULT(no)
 282    AC_MSG_ERROR([cannot proceed])])
 283
 284 # Defend against gcc -ffast-math
 285 if test "$GCC" = yes; then
 286 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 287 choke me
 288 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 289 fi
 290
 291 AC_PROG_CPP
 292 AC_SUBST(GCC)
 293
 294 # Create compiler version string
 295 if test x"$GCC" = x"yes" ; then
 296   cc_string="GCC `${CC} --version | sed q`"
 297 else
 298   cc_string=$CC
 299 fi
 300 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 301                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 302                    [A string containing the version number, platform, and C compiler])
 303
 304
 305 #
 306 # Set up TAS assembly code if needed; the template file has now had its
 307 # chance to request this.
 308 #
 309 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 310
 311 if test "$need_tas" = yes ; then
 312   TAS=tas.o
 313 else
 314   TAS=""
 315 fi
 316 AC_SUBST(TAS)
 317
 318
 319 #
 320 # Automatic dependency tracking
 321 #
 322 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 323               [autodepend=yes])
 324 AC_SUBST(autodepend)
 325
 326
 327 #
 328 # Enable assert checks
 329 #
 330 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 331               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 332                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 333
 334
 335 #
 336 # Include directories
 337 #
 338 ac_save_IFS=$IFS
 339 IFS="${IFS}${PATH_SEPARATOR}"
 340 # SRCH_INC comes from the template file
 341 for dir in $with_includes $SRCH_INC; do
 342   if test -d "$dir"; then
 343     INCLUDES="$INCLUDES -I$dir"
 344   else
 345     AC_MSG_WARN([*** Include directory $dir does not exist.])
 346   fi
 347 done
 348 IFS=$ac_save_IFS
 349 AC_SUBST(INCLUDES)
 350
 351
 352 #
 353 # Library directories
 354 #
 355 ac_save_IFS=$IFS
 356 IFS="${IFS}${PATH_SEPARATOR}"
 357 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 358 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 359   if test -d "$dir"; then
 360     LIBDIRS="$LIBDIRS -L$dir"
 361   else
 362     AC_MSG_WARN([*** Library directory $dir does not exist.])
 363   fi
 364 done
 365 IFS=$ac_save_IFS
 366
 367 #
 368 # Enable thread-safe client libraries
 369 #
 370 AC_MSG_CHECKING([allow thread-safe client libraries])
 371 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 372 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 373 if test "$enable_thread_safety" = yes -o \
 374         "$enable_thread_safety_force" = yes; then
 375   enable_thread_safety="yes"    # for 'force'
 376   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 377           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 378 fi
 379 AC_MSG_RESULT([$enable_thread_safety])
 380 AC_SUBST(enable_thread_safety)
 381
 382 #
 383 # Optionally build Tcl modules (PL/Tcl)
 384 #
 385 AC_MSG_CHECKING([whether to build with Tcl])
 386 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 387 AC_MSG_RESULT([$with_tcl])
 388 AC_SUBST([with_tcl])
 389
 390 # We see if the path to the Tcl/Tk configuration scripts is specified.
 391 # This will override the use of tclsh to find the paths to search.
 392
 393 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 394
 395 #
 396 # Optionally build Perl modules (PL/Perl)
 397 #
 398 AC_MSG_CHECKING([whether to build Perl modules])
 399 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 400 AC_MSG_RESULT([$with_perl])
 401 AC_SUBST(with_perl)
 402
 403 #
 404 # Optionally build Python modules (PL/Python)
 405 #
 406 AC_MSG_CHECKING([whether to build Python modules])
 407 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 408 AC_MSG_RESULT([$with_python])
 409 AC_SUBST(with_python)
 410
 411 #
 412 # Kerberos 5
 413 #
 414 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 415 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 416 [
 417   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 418   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 419 ])
 420 AC_MSG_RESULT([$with_krb5])
 421 AC_SUBST(with_krb5)
 422
 423
 424 AC_SUBST(krb_srvtab)
 425
 426
 427 #
 428 # Kerberos configuration parameters
 429 #
 430 PGAC_ARG_REQ(with, krb-srvnam,
 431              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 432              [],
 433              [with_krb_srvnam="postgres"])
 434 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 435                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 436
 437
 438 #
 439 # PAM
 440 #
 441 AC_MSG_CHECKING([whether to build with PAM support])
 442 PGAC_ARG_BOOL(with, pam, no,
 443               [  --with-pam              build with PAM support],
 444               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 445 AC_MSG_RESULT([$with_pam])
 446 AC_SUBST(with_pam)
 447
 448
 449 #
 450 # Bonjour
 451 #
 452 AC_MSG_CHECKING([whether to build with Bonjour support])
 453 PGAC_ARG_BOOL(with, bonjour, no,
 454               [  --with-bonjour          build with Bonjour support],
 455               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 456 AC_MSG_RESULT([$with_bonjour])
 457 AC_SUBST(with_bonjour)
 458
 459
 460 #
 461 # OpenSSL
 462 #
 463 AC_MSG_CHECKING([whether to build with OpenSSL support])
 464 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 465               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 466 AC_MSG_RESULT([$with_openssl])
 467 AC_SUBST(with_openssl)
 468
 469
 470 #
 471 # Prefer libedit
 472 #
 473 PGAC_ARG_BOOL(with, libedit-preferred, no,
 474               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 475
 476
 477 #
 478 # Readline
 479 #
 480 PGAC_ARG_BOOL(with, readline, yes,
 481               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 482 # readline on MinGW has problems with backslashes in psql and other bugs.
 483 # This is particularly a problem with non-US code pages.
 484 # Therefore disable its use until we understand the cause. 2004-07-20
 485 if test "$PORTNAME" = "win32"; then
 486   if test "$with_readline" = yes; then
 487     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 488     with_readline=no
 489   fi
 490 fi
 491
 492
 493 #
 494 # Zlib
 495 #
 496 PGAC_ARG_BOOL(with, zlib, yes,
 497               [  --without-zlib          do not use Zlib])
 498 AC_SUBST(with_zlib)
 499
 500 #
 501 # Elf
 502 #
 503
 504 # Assume system is ELF if it predefines __ELF__ as 1,
 505 # otherwise believe host_os based default.
 506 case $host_os in
 507     freebsd1*|freebsd2*) elf=no;;
 508     freebsd3*|freebsd4*) elf=yes;;
 509 esac
 510
 511 AC_EGREP_CPP(yes,
 512 [#if __ELF__
 513   yes
 514 #endif
 515 ],
 516 [ELF_SYS=true],
 517 [if test "X$elf" = "Xyes" ; then
 518   ELF_SYS=true
 519 else
 520   ELF_SYS=
 521 fi])
 522 AC_SUBST(ELF_SYS)
 523
 524 #
 525 # Assignments
 526 #
 527
 528 CPPFLAGS="$CPPFLAGS $INCLUDES"
 529 LDFLAGS="$LDFLAGS $LIBDIRS"
 530
 531 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 532 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 533
 534 AC_ARG_VAR(LDFLAGS_SL)
 535
 536 AC_PROG_AWK
 537 PGAC_PATH_FLEX
 538 AC_PROG_LN_S
 539 PGAC_PROG_LD
 540 AC_SUBST(LD)
 541 AC_SUBST(with_gnu_ld)
 542 case $host_os in sysv5*)
 543   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 544   [
 545     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 546     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 547     LDFLAGS=$pgac_save_LDFLAGS
 548   ])
 549   ld_R_works=$pgac_cv_prog_ld_R
 550   AC_SUBST(ld_R_works)
 551 esac
 552 AC_PROG_RANLIB
 553 AC_CHECK_PROGS(LORDER, lorder)
 554 AC_PATH_PROG(TAR, tar)
 555 PGAC_CHECK_STRIP
 556
 557 AC_CHECK_PROGS(YACC, ['bison -y'])
 558
 559 if test "$YACC"; then
 560   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 561     AC_MSG_WARN([
 562 *** If you are going to modify the grammar files or build from CVS, the installed
 563 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 564   fi
 565 fi
 566
 567 if test -z "$YACC"; then
 568   AC_MSG_WARN([
 569 *** Without Bison you will not be able to build PostgreSQL from CVS or
 570 *** change any of the parser definition files.  You can obtain Bison from
 571 *** a GNU mirror site.  (If you are using the official distribution of
 572 *** PostgreSQL then you do not need to worry about this because the Bison
 573 *** output is pre-generated.)  To use a different yacc program (possible,
 574 *** but not recommended), set the environment variable YACC before running
 575 *** 'configure'.])
 576 fi
 577 AC_SUBST(YFLAGS)
 578
 579 PGAC_PATH_PERL
 580 if test "$with_perl" = yes; then
 581   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 582   PGAC_CHECK_PERL_EMBED_LDFLAGS
 583 fi
 584
 585 if test "$with_python" = yes; then
 586   PGAC_PATH_PYTHON
 587   PGAC_CHECK_PYTHON_EMBED_SETUP
 588 fi
 589
 590
 591 ##
 592 ## Libraries
 593 ##
 594
 595 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 596 then
 597         AC_CHECK_LIB(bsd,      main)
 598 fi
 599 AC_CHECK_LIB(util,     setproctitle)
 600 AC_CHECK_LIB(m,        main)
 601 AC_CHECK_LIB(dl,       main)
 602 AC_CHECK_LIB(nsl,      main)
 603 AC_CHECK_LIB(socket,   main)
 604 AC_CHECK_LIB(ipc,      main)
 605 AC_CHECK_LIB(IPC,      main)
 606 AC_CHECK_LIB(lc,       main)
 607 AC_CHECK_LIB(dld,      main)
 608 AC_CHECK_LIB(ld,       main)
 609 AC_CHECK_LIB(compat,   main)
 610 AC_CHECK_LIB(BSD,      main)
 611 AC_CHECK_LIB(gen,      main)
 612 AC_CHECK_LIB(PW,       main)
 613 AC_CHECK_LIB(resolv,   main)
 614 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 615 # QNX:
 616 AC_CHECK_LIB(unix, main)
 617 AC_SEARCH_LIBS(crypt,  crypt)
 618 # BeOS:
 619 if test "$PORTNAME" = "beos"
 620 then
 621         AC_CHECK_LIB(bind, __inet_ntoa)
 622 fi
 623 # Solaris:
 624 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 625 # Cygwin:
 626 AC_CHECK_LIB(cygipc, shmget)
 627 # WIN32:
 628 if test "$PORTNAME" = "win32"
 629 then
 630         AC_CHECK_LIB(wsock32, main)
 631 fi
 632
 633 if test "$with_readline" = yes; then
 634   PGAC_CHECK_READLINE
 635   if test x"$pgac_cv_check_readline" = x"no"; then
 636     AC_MSG_ERROR([readline library not found
 637 If you have readline already installed, see config.log for details on the
 638 failure.  It is possible the compiler isn't looking in the proper directory.
 639 Use --without-readline to disable readline support.])
 640   fi
 641 fi
 642
 643 if test "$with_zlib" = yes; then
 644   AC_CHECK_LIB(z, inflate, [],
 645                [AC_MSG_ERROR([zlib library not found
 646 If you have zlib already installed, see config.log for details on the
 647 failure.  It is possible the compiler isn't looking in the proper directory.
 648 Use --without-zlib to disable zlib support.])])
 649 fi
 650
 651 if test "$enable_spinlocks" = yes; then
 652   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 653 else
 654   AC_MSG_WARN([
 655 *** Not using spinlocks will cause poor performance.])
 656 fi
 657
 658 if test "$with_krb5" = yes ; then
 659   if test "$PORTNAME" != "win32"; then
 660      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 661                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 662      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 663                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 664      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 665                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 666   else
 667      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 668                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 669   fi
 670 fi
 671
 672 if test "$with_openssl" = yes ; then
 673   dnl Order matters!
 674   if test "$PORTNAME" != "win32"; then
 675      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 676      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 677   else
 678      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 679      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 680   fi
 681 fi
 682
 683 if test "$with_pam" = yes ; then
 684   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 685 fi
 686
 687
 688 ##
 689 ## Header files
 690 ##
 691
 692 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 693 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 694
 695 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 696 # netinet/in.h is included first.
 697 AC_CHECK_HEADERS(netinet/in.h)
 698 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 699 [AC_INCLUDES_DEFAULT
 700 #ifdef HAVE_NETINET_IN_H
 701 #include <netinet/in.h>
 702 #endif
 703 ])
 704
 705 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 706   AC_CHECK_HEADERS(readline/readline.h, [],
 707         [AC_CHECK_HEADERS(readline.h, [],
 708                 [AC_MSG_ERROR([readline header not found
 709 If you have readline already installed, see config.log for details on the
 710 failure.  It is possible the compiler isn't looking in the proper directory.
 711 Use --without-readline to disable readline support.])])])
 712   AC_CHECK_HEADERS(readline/history.h, [],
 713         [AC_CHECK_HEADERS(history.h, [],
 714                 [AC_MSG_ERROR([history header not found
 715 If you have readline already installed, see config.log for details on the
 716 failure.  It is possible the compiler isn't looking in the proper directory.
 717 Use --without-readline to disable readline support.])])])
 718 fi
 719
 720 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 721 # Some installations of libedit usurp /usr/include/readline/, which seems
 722 # bad practice, since in combined installations readline will have its headers
 723 # there.  We might have to resort to AC_EGREP checks to make sure we found
 724 # the proper header...
 725   AC_CHECK_HEADERS(editline/readline.h, [],
 726         [AC_CHECK_HEADERS(readline.h, [],
 727                 [AC_CHECK_HEADERS(readline/readline.h, [],
 728                         [AC_MSG_ERROR([readline header not found
 729 If you have libedit already installed, see config.log for details on the
 730 failure.  It is possible the compiler isn't looking in the proper directory.
 731 Use --without-readline to disable libedit support.])])])])
 732   AC_CHECK_HEADERS(editline/history.h, [],
 733         [AC_CHECK_HEADERS(history.h, [],
 734                 [AC_CHECK_HEADERS(readline/history.h, [],
 735                         [AC_MSG_ERROR([history header not found
 736 If you have libedit already installed, see config.log for details on the
 737 failure.  It is possible the compiler isn't looking in the proper directory.
 738 Use --without-readline to disable libedit support.])])])])
 739 fi
 740
 741 if test "$with_zlib" = yes; then
 742   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 743 If you have zlib already installed, see config.log for details on the
 744 failure.  It is possible the compiler isn't looking in the proper directory.
 745 Use --without-zlib to disable zlib support.])])
 746 fi
 747
 748 if test "$with_krb5" = yes ; then
 749   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 750 fi
 751
 752 if test "$with_openssl" = yes ; then
 753   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 754   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 755 fi
 756
 757 if test "$with_pam" = yes ; then
 758   AC_CHECK_HEADERS(security/pam_appl.h, [],
 759                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 760                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 761 fi
 762
 763 if test "$with_bonjour" = yes ; then
 764   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 765 fi
 766
 767
 768 ##
 769 ## Types, structures, compiler characteristics
 770 ##
 771
 772 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 773 AC_C_CONST
 774 AC_C_INLINE
 775 AC_C_STRINGIZE
 776 PGAC_C_SIGNED
 777 AC_C_VOLATILE
 778 PGAC_C_FUNCNAME_SUPPORT
 779 PGAC_STRUCT_TIMEZONE
 780 PGAC_UNION_SEMUN
 781 PGAC_STRUCT_SOCKADDR_UN
 782 PGAC_STRUCT_SOCKADDR_STORAGE
 783 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 784 PGAC_STRUCT_ADDRINFO
 785
 786 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 787 [#include <sys/param.h>
 788 #include <sys/types.h>
 789 #include <sys/socket.h>
 790 #include <sys/ucred.h>])
 791
 792 AC_CHECK_TYPES([struct option], [], [],
 793 [#ifdef HAVE_GETOPT_H
 794 #include <getopt.h>
 795 #endif])
 796
 797 if test "$with_zlib" = yes; then
 798   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 799   # did not).  While we could work around the lack of z_streamp, it
 800   # seems unwise to encourage people to use such old zlib versions...
 801   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 802 Use --without-zlib to disable zlib support.])],
 803                 [#include <zlib.h>])
 804 fi
 805
 806 if test "$with_krb5" = yes; then
 807 # Check for differences between MIT and Heimdal (KTH) releases
 808   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 809                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 810                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 811                                      [#include <krb5.h>])],
 812                    [#include <krb5.h>])
 813   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 814                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 815                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 816                                      [#include <krb5.h>])],
 817                    [#include <krb5.h>])
 818 fi
 819
 820 ##
 821 ## Functions, global variables
 822 ##
 823
 824 PGAC_VAR_INT_TIMEZONE
 825 AC_FUNC_ACCEPT_ARGTYPES
 826 PGAC_FUNC_GETTIMEOFDAY_1ARG
 827
 828 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 829
 830 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 831
 832 HAVE_IPV6=no
 833 AC_CHECK_TYPE([struct sockaddr_in6],
 834         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 835          HAVE_IPV6=yes],
 836         [],
 837 [$ac_includes_default
 838 #include <netinet/in.h>])
 839 AC_SUBST(HAVE_IPV6)
 840
 841 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 842 [AC_TRY_LINK(
 843 [#include <machine/vmparam.h>
 844 #include <sys/exec.h>
 845 ],
 846 [PS_STRINGS->ps_nargvstr = 1;
 847 PS_STRINGS->ps_argvstr = "foo";],
 848 [pgac_cv_var_PS_STRINGS=yes],
 849 [pgac_cv_var_PS_STRINGS=no])])
 850 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 851   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 852 fi
 853
 854
 855 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 856 # is missing.  Yes, there are machines that have only one.  We may
 857 # also decide to use snprintf.c if snprintf() is present but does not
 858 # have all the features we need --- see below.
 859
 860 if test "$PORTNAME" = "win32"; then
 861   # Win32 gets snprintf.c built unconditionally.
 862   #
 863   # To properly translate all NLS languages strings, we must support the
 864   # *printf() %$ format, which allows *printf() arguments to be selected
 865   # by position in the translated string.
 866   #
 867   # libintl versions < 0.13 use the native *printf() functions, and Win32
 868   # *printf() doesn't understand %$, so we must use our /port versions,
 869   # which do understand %$. libintl versions >= 0.13 include their own
 870   # *printf versions on Win32.  The libintl 0.13 release note text is:
 871   #
 872   #   C format strings with positions, as they arise when a translator
 873   #   needs to reorder a sentence, are now supported on all platforms.
 874   #   On those few platforms (NetBSD and Woe32) for which the native
 875   #   printf()/fprintf()/... functions don't support such format
 876   #   strings, replacements are provided through <libintl.h>.
 877   #
 878   # We could use libintl >= 0.13's *printf() if we were sure that we had
 879   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 880   # to guarantee that, it is best to just use our own, so we are sure to
 881   # get %$ support. In include/port.h we disable the *printf() macros
 882   # that might have been defined by libintl.
 883   #
 884   # We do this unconditionally whether NLS is used or not so we are sure
 885   # that all Win32 libraries and binaries behave the same.
 886   pgac_need_repl_snprintf=yes
 887 else
 888   pgac_need_repl_snprintf=no
 889   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 890   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 891 fi
 892
 893
 894 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 895 # include/c.h will provide declarations.  Note this is a separate test
 896 # from whether the functions exist in the C library --- there are
 897 # systems that have the functions but don't bother to declare them :-(
 898
 899 AC_CHECK_DECLS([snprintf, vsnprintf])
 900
 901
 902 # do this one the hard way in case isinf() is a macro
 903 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 904 [AC_TRY_LINK(
 905 [#include <math.h>
 906 ],
 907 [double x = 0.0; int res = isinf(x);],
 908 [ac_cv_func_isinf=yes],
 909 [ac_cv_func_isinf=no])])
 910
 911 if test $ac_cv_func_isinf = yes ; then
 912   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 913 else
 914   AC_LIBOBJ(isinf)
 915   # Look for a way to implement a substitute for isinf()
 916   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 917 fi
 918
 919 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 920
 921 # System's version of getaddrinfo(), if any, may be used only if we found
 922 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 923 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 924 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 925 # because we want to use our own getaddrinfo.c on Windows anyway.)
 926 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 927   AC_REPLACE_FUNCS([getaddrinfo])
 928 else
 929   AC_LIBOBJ(getaddrinfo)
 930 fi
 931
 932 # similarly, use system's getopt_long() only if system provides struct option.
 933 if test x"$ac_cv_type_struct_option" = xyes ; then
 934   AC_REPLACE_FUNCS([getopt_long])
 935 else
 936   AC_LIBOBJ(getopt_long)
 937 fi
 938
 939 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 940 # We override the previous test that said fseeko/ftello didn't exist
 941 # OS tests are also done in include/c.h and port/fseeko.c
 942 case $host_os in bsdi*|netbsd*)
 943 ac_cv_func_fseeko=yes
 944 esac
 945
 946 # Solaris has a very slow qsort in certain cases, so we replace it.
 947 if test "$PORTNAME" = "solaris"; then
 948 AC_LIBOBJ(qsort)
 949 fi
 950
 951 # Win32 support
 952 if test "$PORTNAME" = "win32"; then
 953 AC_LIBOBJ(gettimeofday)
 954 AC_LIBOBJ(kill)
 955 AC_LIBOBJ(open)
 956 AC_LIBOBJ(rand)
 957 AC_DEFINE([HAVE_SYMLINK], 1,
 958           [Define to 1 if you have the `symlink' function.])
 959 fi
 960
 961 if test "$with_readline" = yes; then
 962   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 963   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 964   AC_CHECK_FUNCS([replace_history_entry])
 965 fi
 966
 967
 968 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 969 AC_MSG_CHECKING(for finite)
 970 AC_TRY_LINK([#include <math.h>],
 971             [int dummy=finite(1.0);],
 972             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 973 AC_MSG_RESULT(yes)],
 974             [AC_MSG_RESULT(no)])
 975
 976 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 977 dnl (especially on GNU libc)
 978 dnl See also comments in c.h.
 979 AC_MSG_CHECKING(for sigsetjmp)
 980 AC_TRY_LINK([#include <setjmp.h>],
 981             [sigjmp_buf x; sigsetjmp(x, 1);],
 982             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 983 AC_MSG_RESULT(yes)],
 984             [AC_MSG_RESULT(no)])
 985
 986 AC_CHECK_FUNC(syslog,
 987               [AC_CHECK_HEADER(syslog.h,
 988                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 989
 990 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 991 [AC_TRY_LINK([#include <unistd.h>],
 992   [extern int optreset; optreset = 1;],
 993   [pgac_cv_var_int_optreset=yes],
 994   [pgac_cv_var_int_optreset=no])])
 995 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 996   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 997 fi
 998
 999 AC_CHECK_FUNCS([strtoll strtoq], [break])
1000 AC_CHECK_FUNCS([strtoull strtouq], [break])
1001
1002 # Check for one of atexit() or on_exit()
1003 AC_CHECK_FUNCS(atexit, [],
1004                [AC_CHECK_FUNCS(on_exit, [],
1005                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1006
1007 AC_FUNC_FSEEKO
1008
1009 #
1010 # Pthreads
1011 #
1012 # For each platform, we need to know about any special compile and link
1013 # libraries, and whether the normal C function names are thread-safe.
1014 # See the comment at the top of src/port/thread.c for more information.
1015 #
1016 if test "$enable_thread_safety" = yes; then
1017 ACX_PTHREAD     # set thread flags
1018
1019 # Some platforms use these, so just defineed them.  They can't hurt if they
1020 # are not supported.
1021 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1022
1023
1024 # At this point, we don't want to muck with the compiler name for threading.
1025 # Let's see who fails, perhaps AIX.  2004-04-23
1026 if test "$PTHREAD_CC" != "$CC"; then
1027 AC_MSG_ERROR([
1028 PostgreSQL does not support platforms that require a special
1029 compiler binary for thread-safety.
1030 ])
1031 fi
1032
1033 if test "$THREAD_SUPPORT" = no; then
1034 AC_MSG_ERROR([
1035 Cannot enable threads on your platform.
1036 Your platform is known to not support thread-safe programs.
1037 For details, compile and run src/bin/pg_thread_test.
1038 ])
1039 fi
1040
1041 # Check for *_r functions
1042 _CFLAGS="$CFLAGS"
1043 _LIBS="$LIBS"
1044 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1045 LIBS="$LIBS $PTHREAD_LIBS"
1046
1047 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1048
1049 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1050
1051 # Do test here with the proper thread flags
1052 PGAC_FUNC_GETPWUID_R_5ARG
1053 PGAC_FUNC_STRERROR_R_INT
1054
1055 CFLAGS="$_CFLAGS"
1056 LIBS="$_LIBS"
1057
1058 else
1059 # do not use values from template file
1060 PTHREAD_CFLAGS=
1061 PTHREAD_LIBS=
1062 fi
1063
1064 AC_SUBST(PTHREAD_CFLAGS)
1065 AC_SUBST(PTHREAD_LIBS)
1066
1067
1068 # This test makes sure that run tests work at all.  Sometimes a shared
1069 # library is found by the linker, but the runtime linker can't find it.
1070 # This check should come after all modifications of compiler or linker
1071 # variables, and before any other run tests.
1072 AC_MSG_CHECKING([test program])
1073 AC_TRY_RUN([int main() { return 0; }],
1074 [AC_MSG_RESULT(ok)],
1075 [AC_MSG_RESULT(failed)
1076 AC_MSG_ERROR([[
1077 *** Could not execute a simple test program.  This may be a problem
1078 *** related to locating shared libraries.  Check the file 'config.log'
1079 *** for the exact reason.]])],
1080 [AC_MSG_RESULT([cross-compiling])])
1081
1082 # --------------------
1083 # Run tests below here
1084 # --------------------
1085
1086 # Force use of our snprintf if system's doesn't do arg control
1087 # See comment above at snprintf test for details.
1088 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1089   PGAC_FUNC_PRINTF_ARG_CONTROL
1090   if test $pgac_cv_printf_arg_control != yes ; then
1091     pgac_need_repl_snprintf=yes
1092   fi
1093 fi
1094
1095
1096 dnl Check to see if we have a working 64-bit integer type.
1097 dnl This breaks down into two steps:
1098 dnl (1) figure out if the compiler has a 64-bit int type with working
1099 dnl arithmetic, and if so
1100 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1101 dnl snprintf is the only library routine we really need for int8 support.)
1102 dnl It's entirely possible to have a compiler that handles a 64-bit type
1103 dnl when the C library doesn't; this is fairly likely when using gcc on
1104 dnl an older platform, for example.
1105 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1106 dnl we force our own version of snprintf() to be used instead.
1107 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1108
1109 PGAC_TYPE_64BIT_INT([long int])
1110
1111 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1112   PGAC_TYPE_64BIT_INT([long long int])
1113 fi
1114
1115
1116 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1117
1118 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1119   AC_TRY_COMPILE([
1120 #define INT64CONST(x)  x##LL
1121 long long int foo = INT64CONST(0x1234567890123456);
1122 ],
1123         [],
1124         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1125         [])
1126 fi
1127
1128
1129 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1130 # we found we need to use "long long int", better check.  We cope with
1131 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1132 # work, fall back to our own snprintf emulation (which we know uses %lld).
1133
1134 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1135   if test $pgac_need_repl_snprintf = no; then
1136     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1137     if test "$LONG_LONG_INT_FORMAT" = ""; then
1138       # Force usage of our own snprintf, since system snprintf is broken
1139       pgac_need_repl_snprintf=yes
1140       LONG_LONG_INT_FORMAT='%lld'
1141     fi
1142   else
1143     # Here if we previously decided we needed to use our own snprintf
1144     LONG_LONG_INT_FORMAT='%lld'
1145   fi
1146   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1147   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1148   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1149 else
1150   # Here if we are not using 'long long int' at all
1151   INT64_FORMAT='"%ld"'
1152   UINT64_FORMAT='"%lu"'
1153 fi
1154
1155 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1156                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1157
1158 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1159                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1160
1161 # Now we have checked all the reasons to replace snprintf
1162 if test $pgac_need_repl_snprintf = yes; then
1163   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1164   AC_LIBOBJ(snprintf)
1165 fi
1166
1167 # Need a #define for the size of Datum (unsigned long)
1168 AC_CHECK_SIZEOF([unsigned long])
1169
1170 # And one for the size of size_t (enables tweaks for > 32bit address space)
1171 AC_CHECK_SIZEOF([size_t])
1172
1173 # Determine memory alignment requirements for the basic C data types.
1174
1175 PGAC_CHECK_ALIGNOF(short)
1176 PGAC_CHECK_ALIGNOF(int)
1177 PGAC_CHECK_ALIGNOF(long)
1178 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1179   PGAC_CHECK_ALIGNOF(long long int)
1180 fi
1181 PGAC_CHECK_ALIGNOF(double)
1182
1183 # Compute maximum alignment of any basic type.
1184 # We assume long's alignment is at least as strong as char, short, or int;
1185 # but we must check long long (if it exists) and double.
1186
1187 MAX_ALIGNOF=$pgac_cv_alignof_long
1188 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1189   MAX_ALIGNOF=$pgac_cv_alignof_double
1190 fi
1191 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1192   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1193 fi
1194 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1195
1196
1197 # Some platforms predefine the types int8, int16, etc.  Only check
1198 # a (hopefully) representative subset.
1199 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1200 [#include <stdio.h>
1201 #ifdef HAVE_SUPPORTDEFS_H
1202 #include <SupportDefs.h>
1203 #endif])
1204
1205 # We also check for sig_atomic_t, which *should* be defined per ANSI
1206 # C, but is missing on some old platforms.
1207 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1208
1209
1210 if test x"$template" != x"win32"
1211 then
1212 PGAC_FUNC_POSIX_SIGNALS
1213 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1214   AC_MSG_ERROR([
1215 *** Thread-safety requires POSIX signals, which are not supported by your
1216 *** operating system.
1217 ])
1218 fi
1219 fi
1220
1221 if test $ac_cv_func_fseeko = yes; then
1222 AC_SYS_LARGEFILE
1223 fi
1224
1225 # SunOS doesn't handle negative byte comparisons properly with +/- return
1226 AC_FUNC_MEMCMP
1227
1228
1229 # Select semaphore implementation type.
1230 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1231   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1232   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1233 else
1234   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1235     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1236     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1237   else
1238     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1239     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1240   fi
1241 fi
1242
1243
1244 # Select shared-memory implementation type.
1245 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1246 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1247
1248
1249 if test "$enable_nls" = yes ; then
1250   PGAC_CHECK_GETTEXT
1251 fi
1252
1253 # Check for Tcl configuration script tclConfig.sh
1254 if test "$with_tcl" = yes; then
1255     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1256     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1257                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1258     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1259     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1260     ac_save_CPPFLAGS=$CPPFLAGS
1261     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1262     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1263     CPPFLAGS=$ac_save_CPPFLAGS
1264 fi
1265
1266 #
1267 # Check for DocBook and tools
1268 #
1269 PGAC_PROG_NSGMLS
1270 PGAC_PROG_JADE
1271 PGAC_CHECK_DOCBOOK(4.2)
1272 PGAC_PATH_DOCBOOK_STYLESHEETS
1273 PGAC_PATH_COLLATEINDEX
1274 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1275
1276 # Thread testing
1277
1278 # We have to run the thread test near the end so we have all our symbols
1279 # defined.  Cross compiling throws a warning.
1280 #
1281 if test "$enable_thread_safety_force" = yes; then
1282 if test x"$template" != x"win32"
1283 then
1284   AC_MSG_WARN([
1285 *** Skipping thread test program.  --enable-thread-safety-force was used.
1286 *** Run the program in src/tools/thread on the your machine and add
1287 proper locking function calls to your applications to guarantee thread
1288 safety.
1289 ])
1290 else
1291 AC_MSG_WARN([*** Skipping thread test on Win32])
1292 fi
1293 elif test "$enable_thread_safety" = yes; then
1294 if test x"$template" != x"win32"
1295 then
1296 AC_MSG_CHECKING([thread safety of required library functions])
1297
1298 _CFLAGS="$CFLAGS"
1299 _LIBS="$LIBS"
1300 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1301 LIBS="$LIBS $PTHREAD_LIBS"
1302 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1303   [AC_MSG_RESULT(yes)],
1304   [AC_MSG_RESULT(no)
1305   AC_MSG_ERROR([
1306 *** Thread test program failed.  Your platform is not thread-safe.
1307 *** Check the file 'config.log'for the exact reason.
1308 ***
1309 *** You can use the configure option --enable-thread-safety-force
1310 *** to force threads to be enabled.  However, you must then run
1311 *** the program in src/tools/thread and add locking function calls
1312 *** to your applications to guarantee thread safety.
1313 ])],
1314   [AC_MSG_RESULT(maybe)
1315   AC_MSG_WARN([
1316 *** Skipping thread test program because of cross-compile build.
1317 *** Run the program in src/tools/thread on the target machine.
1318 ])])
1319 CFLAGS="$_CFLAGS"
1320 LIBS="$_LIBS"
1321 else
1322 AC_MSG_WARN([*** Skipping thread test on Win32])
1323 fi
1324 fi
1325
1326 # prepare build tree if outside source tree
1327 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1328 # Note 2: /bin/pwd might be better than shell's built-in at getting
1329 #         a symlink-free name.
1330 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1331   vpath_build=no
1332 else
1333   vpath_build=yes
1334   if test "$no_create" != yes; then
1335     _AS_ECHO_N([preparing build tree... ])
1336     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1337     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1338       || AC_MSG_ERROR(failed)
1339     AC_MSG_RESULT(done)
1340   fi
1341 fi
1342 AC_SUBST(vpath_build)
1343
1344
1345 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1346
1347 AC_CONFIG_LINKS([
1348   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1349   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1350   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1351   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1352   src/include/pg_config_os.h:src/include/port/${template}.h
1353   src/Makefile.port:src/makefiles/Makefile.${template}
1354 ])
1355
1356 if test "$PORTNAME" = "win32"; then
1357 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1358 # Links sometimes fail undetected on Mingw -
1359 # so here we detect it and warn the user
1360 for FILE in $CONFIG_LINKS
1361  do
1362         # test -e works for symlinks in the MinGW console
1363         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1364  done
1365 ])
1366 fi
1367
1368 AC_CONFIG_HEADERS([src/include/pg_config.h],
1369 [
1370 # Update timestamp for pg_config.h (see Makefile.global)
1371 echo >src/include/stamp-h
1372 ])
1373
1374 AC_OUTPUT
1375