granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.579 2009/01/05 10:25:59 petere Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.4devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.61], [], [m4_fatal([Autoconf version 2.61 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2009, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  33 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\.[0-9][0-9]*\)'`]
  34 AC_SUBST(PG_MAJORVERSION)
  35 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  36
  37 AC_CANONICAL_HOST
  38
  39 template=
  40 AC_MSG_CHECKING([which template to use])
  41
  42 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  43 [
  44   case $withval in
  45     list)   echo; ls "$srcdir/src/template"; exit;;
  46     *)      if test -f "$srcdir/src/template/$with_template" ; then
  47               template=$withval
  48             else
  49               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  50             fi;;
  51   esac
  52 ],
  53 [
  54 # --with-template not given
  55
  56 case $host_os in
  57      aix*) template=aix ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=cygwin ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix ;;
  65  linux*|gnu*|k*bsd*-gnu)
  66            template=linux ;;
  67    mingw*) template=win32 ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      sco*) template=sco ;;
  73  solaris*) template=solaris ;;
  74    sunos*) template=sunos4 ;;
  75  sysv4.2*)
  76         case $host_vendor in
  77           univel) template=univel ;;
  78         esac ;;
  79    sysv4*) template=svr4 ;;
  80    sysv5*) template=unixware ;;
  81   ultrix*) template=ultrix4 ;;
  82 esac
  83
  84   if test x"$template" = x"" ; then
  85     AC_MSG_ERROR([[
  86 *******************************************************************
  87 PostgreSQL has apparently not been ported to your platform yet.
  88 To try a manual configuration, look into the src/template directory
  89 for a similar platform and use the '--with-template=' option.
  90
  91 Please also contact <pgsql-ports@postgresql.org> to see about
  92 rectifying this.  Include the above 'checking host system type...'
  93 line.
  94 *******************************************************************
  95 ]])
  96   fi
  97
  98 ])
  99
 100 AC_MSG_RESULT([$template])
 101
 102 PORTNAME=$template
 103 AC_SUBST(PORTNAME)
 104
 105 # Initialize default assumption that we do not need separate assembly code
 106 # for TAS (test-and-set).  This can be overridden by the template file
 107 # when it's executed.
 108 need_tas=no
 109 tas_file=dummy.s
 110
 111
 112
 113 ##
 114 ## Command line options
 115 ##
 116
 117 #
 118 # Add non-standard directories to the include path
 119 #
 120 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 121
 122
 123 #
 124 # Add non-standard directories to the library search path
 125 #
 126 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 127              [LIBRARY_DIRS=$withval])
 128
 129 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 130              [LIBRARY_DIRS=$withval])
 131
 132
 133 #
 134 # 64-bit integer date/time storage: enabled by default.
 135 #
 136 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 137 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [disable 64-bit integer date/time support],
 138               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 139                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 140 AC_MSG_RESULT([$enable_integer_datetimes])
 141
 142
 143 #
 144 # NLS
 145 #
 146 AC_MSG_CHECKING([whether NLS is wanted])
 147 PGAC_ARG_OPTARG(enable, nls,
 148                 [LANGUAGES], [enable Native Language Support],
 149                 [],
 150                 [WANTED_LANGUAGES=$enableval],
 151                 [AC_DEFINE(ENABLE_NLS, 1,
 152                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 153 AC_MSG_RESULT([$enable_nls])
 154 AC_SUBST(enable_nls)
 155 AC_SUBST(WANTED_LANGUAGES)
 156
 157 #
 158 # Default port number (--with-pgport), default 5432
 159 #
 160 AC_MSG_CHECKING([for default port number])
 161 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 162              [default_port=$withval],
 163              [default_port=5432])
 164 AC_MSG_RESULT([$default_port])
 165 # Need both of these because some places want an integer and some a string
 166 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 167 [Define to the default TCP port number on which the server listens and
 168 to which clients will try to connect.  This can be overridden at run-time,
 169 but it's convenient if your clients have the right default compiled in.
 170 (--with-pgport=PORTNUM)])
 171 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 172                    [Define to the default TCP port number as a string constant.])
 173 AC_SUBST(default_port)
 174
 175 #
 176 # Option to disable shared libraries
 177 #
 178 PGAC_ARG_BOOL(enable, shared, yes,
 179               [do not build shared libraries])
 180 AC_SUBST(enable_shared)
 181
 182 #
 183 # '-rpath'-like feature can be disabled
 184 #
 185 PGAC_ARG_BOOL(enable, rpath, yes,
 186               [do not embed shared library search path in executables])
 187 AC_SUBST(enable_rpath)
 188
 189 #
 190 # Spinlocks
 191 #
 192 PGAC_ARG_BOOL(enable, spinlocks, yes,
 193               [do not use spinlocks])
 194
 195 #
 196 # --enable-debug adds -g to compiler flags
 197 #
 198 PGAC_ARG_BOOL(enable, debug, no,
 199               [build with debugging symbols (-g)])
 200 AC_SUBST(enable_debug)
 201
 202 #
 203 # --enable-profiling enables gcc profiling
 204 #
 205 PGAC_ARG_BOOL(enable, profiling, no,
 206               [build with profiling enabled ])
 207 AC_SUBST(enable_profiling)
 208
 209 #
 210 # --enable-coverage enables generation of code coverage metrics with gcov
 211 #
 212 PGAC_ARG_BOOL(enable, coverage, no,
 213               [build with coverage testing instrumentation],
 214 [AC_CHECK_PROGS(GCOV, gcov)
 215 if test -z "$GCOV"; then
 216   AC_MSG_ERROR([gcov not found])
 217 fi
 218 AC_CHECK_PROGS(LCOV, lcov)
 219 if test -z "$LCOV"; then
 220   AC_MSG_ERROR([lcov not found])
 221 fi
 222 AC_CHECK_PROGS(GENHTML, genhtml)
 223 if test -z "$GENHTML"; then
 224   AC_MSG_ERROR([genhtml not found])
 225 fi])
 226 AC_SUBST(enable_coverage)
 227
 228 #
 229 # DTrace
 230 #
 231 PGAC_ARG_BOOL(enable, dtrace, no,
 232               [build with DTrace support],
 233 [AC_DEFINE([ENABLE_DTRACE], 1,
 234            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 235 AC_CHECK_PROGS(DTRACE, dtrace)
 236 if test -z "$DTRACE"; then
 237   AC_MSG_ERROR([dtrace not found])
 238 fi
 239 AC_SUBST(DTRACEFLAGS)])
 240 AC_SUBST(enable_dtrace)
 241
 242 #
 243 # Block size
 244 #
 245 AC_MSG_CHECKING([for block size])
 246 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 247              [blocksize=$withval],
 248              [blocksize=8])
 249 case ${blocksize} in
 250   1) BLCKSZ=1024;;
 251   2) BLCKSZ=2048;;
 252   4) BLCKSZ=4096;;
 253   8) BLCKSZ=8192;;
 254  16) BLCKSZ=16384;;
 255  32) BLCKSZ=32768;;
 256   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 257 esac
 258 AC_MSG_RESULT([${blocksize}kB])
 259
 260 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 261  Size of a disk block --- this also limits the size of a tuple.  You
 262  can set it bigger if you need bigger tuples (although TOAST should
 263  reduce the need to have large tuples, since fields can be spread
 264  across multiple tuples).
 265
 266  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 267  is currently 2^15 (32768).  This is determined by the 15-bit widths
 268  of the lp_off and lp_len fields in ItemIdData (see
 269  include/storage/itemid.h).
 270
 271  Changing BLCKSZ requires an initdb.
 272 ])
 273
 274 #
 275 # Relation segment size
 276 #
 277 AC_MSG_CHECKING([for segment size])
 278 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 279              [segsize=$withval],
 280              [segsize=1])
 281 # this expression is set up to avoid unnecessary integer overflow
 282 # blocksize is already guaranteed to be a factor of 1024
 283 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 284 test $? -eq 0 || exit 1
 285 AC_MSG_RESULT([${segsize}GB])
 286
 287 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 288  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 289  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 290  relations bigger than that are divided into multiple files.
 291
 292  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 293  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 294  have large file support enabled.  By default, we make the limit 1 GB
 295  to avoid any possible integer-overflow problems within the OS.
 296  A limit smaller than necessary only means we divide a large
 297  relation into more chunks than necessary, so it seems best to err
 298  in the direction of a small limit.
 299
 300  A power-of-2 value is recommended to save a few cycles in md.c,
 301  but is not absolutely required.
 302
 303  Changing RELSEG_SIZE requires an initdb.
 304 ])
 305
 306 #
 307 # WAL block size
 308 #
 309 AC_MSG_CHECKING([for WAL block size])
 310 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 311              [wal_blocksize=$withval],
 312              [wal_blocksize=8])
 313 case ${wal_blocksize} in
 314   1) XLOG_BLCKSZ=1024;;
 315   2) XLOG_BLCKSZ=2048;;
 316   4) XLOG_BLCKSZ=4096;;
 317   8) XLOG_BLCKSZ=8192;;
 318  16) XLOG_BLCKSZ=16384;;
 319  32) XLOG_BLCKSZ=32768;;
 320  64) XLOG_BLCKSZ=65536;;
 321   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 322 esac
 323 AC_MSG_RESULT([${wal_blocksize}kB])
 324
 325 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 326  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 327  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 328  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 329  buffers, else direct I/O may fail.
 330
 331  Changing XLOG_BLCKSZ requires an initdb.
 332 ])
 333
 334 #
 335 # WAL segment size
 336 #
 337 AC_MSG_CHECKING([for WAL segment size])
 338 PGAC_ARG_REQ(with, wal-segsize, [SEGSIZE], [set WAL segment size in MB [16]],
 339              [wal_segsize=$withval],
 340              [wal_segsize=16])
 341 case ${wal_segsize} in
 342   1) ;;
 343   2) ;;
 344   4) ;;
 345   8) ;;
 346  16) ;;
 347  32) ;;
 348  64) ;;
 349   *) AC_MSG_ERROR([Invalid WAL segment size. Allowed values are 1,2,4,8,16,32,64.])
 350 esac
 351 AC_MSG_RESULT([${wal_segsize}MB])
 352
 353 AC_DEFINE_UNQUOTED([XLOG_SEG_SIZE], [(${wal_segsize} * 1024 * 1024)], [
 354  XLOG_SEG_SIZE is the size of a single WAL file.  This must be a power of 2
 355  and larger than XLOG_BLCKSZ (preferably, a great deal larger than
 356  XLOG_BLCKSZ).
 357
 358  Changing XLOG_SEG_SIZE requires an initdb.
 359 ])
 360
 361 #
 362 # C compiler
 363 #
 364
 365 # For historical reasons you can also use --with-CC to specify the C compiler
 366 # to use, although the standard way to do this is to set the CC environment
 367 # variable.
 368 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 369
 370 case $template in
 371   aix) pgac_cc_list="gcc xlc";;
 372  irix) pgac_cc_list="cc";; # no gcc
 373     *) pgac_cc_list="gcc cc";;
 374 esac
 375
 376 AC_PROG_CC([$pgac_cc_list])
 377
 378 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 379 # but has idiosyncrasies of its own.  We assume icc will define
 380 # __INTEL_COMPILER regardless of CFLAGS.
 381 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 382 choke me
 383 @%:@endif], [ICC=[yes]], [ICC=[no]])
 384
 385 # Check if it's Sun Studio compiler. We assume that
 386 # __SUNPRO_C will be defined for Sun Studio compilers
 387 AC_TRY_COMPILE([], [@%:@ifndef __SUNPRO_C
 388 choke me
 389 @%:@endif], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 390
 391 AC_SUBST(SUN_STUDIO_CC)
 392
 393 unset CFLAGS
 394
 395 #
 396 # Read the template
 397 #
 398 . "$srcdir/src/template/$template" || exit
 399
 400 # CFLAGS are selected so:
 401 # If the user specifies something in the environment, that is used.
 402 # else:  If the template file set something, that is used.
 403 # else:  If coverage was enabled, don't set anything.
 404 # else:  If the compiler is GCC, then we use -O2.
 405 # else:  If the compiler is something else, then we use -O.
 406
 407 if test "$ac_env_CFLAGS_set" = set; then
 408   CFLAGS=$ac_env_CFLAGS_value
 409 elif test "${CFLAGS+set}" = set; then
 410   : # (keep what template set)
 411 elif test "$enable_coverage" = yes; then
 412   : # no optimization by default
 413 elif test "$GCC" = yes; then
 414   CFLAGS="-O2"
 415 else
 416   # if the user selected debug mode, don't use -O
 417   if test "$enable_debug" != yes; then
 418     CFLAGS="-O"
 419   fi
 420 fi
 421
 422 # Some versions of GCC support some additional useful warning flags.
 423 # Check whether they are supported, and add them to CFLAGS if so.
 424 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 425
 426 if test "$GCC" = yes -a "$ICC" = no; then
 427   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 428   # These work in some but not all gcc versions
 429   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 430   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 431   # Disable strict-aliasing rules; needed for gcc 3.3+
 432   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 433   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 434   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 435 elif test "$ICC" = yes; then
 436   # Intel's compiler has a bug/misoptimization in checking for
 437   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 438   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 439   # Make sure strict aliasing is off (though this is said to be the default)
 440   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 441 elif test x"${CC}" = x"xlc"; then
 442   # AIX xlc has to have strict aliasing turned off too
 443   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 444 fi
 445
 446 # supply -g if --enable-debug
 447 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 448   CFLAGS="$CFLAGS -g"
 449 fi
 450
 451 # enable code coverage if --enable-coverage
 452 if test "$enable_coverage" = yes; then
 453   if test "$GCC" = yes; then
 454     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 455   else
 456     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 457   fi
 458 fi
 459
 460 # enable profiling if --enable-profiling
 461 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 462   if test "$GCC" = yes; then
 463     AC_DEFINE([PROFILE_PID_DIR], 1,
 464            [Define to 1 to allow profiling output to be saved separately for each process.])
 465     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 466   else
 467     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 468   fi
 469 fi
 470
 471 # We already have this in Makefile.win32, but configure needs it too
 472 if test "$PORTNAME" = "win32"; then
 473   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 474 fi
 475
 476 # Check if the compiler still works with the template settings
 477 AC_MSG_CHECKING([whether the C compiler still works])
 478 AC_TRY_LINK([], [return 0;],
 479   [AC_MSG_RESULT(yes)],
 480   [AC_MSG_RESULT(no)
 481    AC_MSG_ERROR([cannot proceed])])
 482
 483 # Defend against gcc -ffast-math
 484 if test "$GCC" = yes; then
 485 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 486 choke me
 487 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 488 fi
 489
 490 AC_PROG_CPP
 491 AC_SUBST(GCC)
 492
 493 # Create compiler version string
 494 if test x"$GCC" = x"yes" ; then
 495   cc_string="GCC `${CC} --version | sed q`"
 496 else
 497   cc_string=$CC
 498 fi
 499 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 500                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 501                    [A string containing the version number, platform, and C compiler])
 502
 503
 504 #
 505 # Set up TAS assembly code if needed; the template file has now had its
 506 # chance to request this.
 507 #
 508 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 509
 510 if test "$need_tas" = yes ; then
 511   TAS=tas.o
 512 else
 513   TAS=""
 514 fi
 515 AC_SUBST(TAS)
 516
 517
 518 #
 519 # Automatic dependency tracking
 520 #
 521 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 522               [autodepend=yes])
 523 AC_SUBST(autodepend)
 524
 525
 526 #
 527 # Enable assert checks
 528 #
 529 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 530               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 531                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 532
 533
 534 #
 535 # Include directories
 536 #
 537 ac_save_IFS=$IFS
 538 IFS="${IFS}${PATH_SEPARATOR}"
 539 # SRCH_INC comes from the template file
 540 for dir in $with_includes $SRCH_INC; do
 541   if test -d "$dir"; then
 542     INCLUDES="$INCLUDES -I$dir"
 543   else
 544     AC_MSG_WARN([*** Include directory $dir does not exist.])
 545   fi
 546 done
 547 IFS=$ac_save_IFS
 548 AC_SUBST(INCLUDES)
 549
 550
 551 #
 552 # Library directories
 553 #
 554 ac_save_IFS=$IFS
 555 IFS="${IFS}${PATH_SEPARATOR}"
 556 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 557 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 558   if test -d "$dir"; then
 559     LIBDIRS="$LIBDIRS -L$dir"
 560   else
 561     AC_MSG_WARN([*** Library directory $dir does not exist.])
 562   fi
 563 done
 564 IFS=$ac_save_IFS
 565
 566 #
 567 # Enable thread-safe client libraries
 568 #
 569 AC_MSG_CHECKING([allow thread-safe client libraries])
 570 if test "$PORTNAME" != "win32"; then
 571 PGAC_ARG_BOOL(enable, thread-safety, no, [make client libraries thread-safe])
 572 else
 573 # Win32 should always use threads
 574 PGAC_ARG_BOOL(enable, thread-safety, yes, [make client libraries thread-safe])
 575 fi
 576
 577 PGAC_ARG_BOOL(enable, thread-safety-force, no, [force thread-safety despite thread test failure])
 578 if test "$enable_thread_safety" = yes -o \
 579         "$enable_thread_safety_force" = yes; then
 580   enable_thread_safety="yes"    # for 'force'
 581   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 582           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 583 fi
 584 AC_MSG_RESULT([$enable_thread_safety])
 585 AC_SUBST(enable_thread_safety)
 586
 587 #
 588 # Optionally build Tcl modules (PL/Tcl)
 589 #
 590 AC_MSG_CHECKING([whether to build with Tcl])
 591 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 592 AC_MSG_RESULT([$with_tcl])
 593 AC_SUBST([with_tcl])
 594
 595 # We see if the path to the Tcl/Tk configuration scripts is specified.
 596 # This will override the use of tclsh to find the paths to search.
 597
 598 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 599
 600 #
 601 # Optionally build Perl modules (PL/Perl)
 602 #
 603 AC_MSG_CHECKING([whether to build Perl modules])
 604 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 605 AC_MSG_RESULT([$with_perl])
 606 AC_SUBST(with_perl)
 607
 608 #
 609 # Optionally build Python modules (PL/Python)
 610 #
 611 AC_MSG_CHECKING([whether to build Python modules])
 612 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 613 AC_MSG_RESULT([$with_python])
 614 AC_SUBST(with_python)
 615
 616 #
 617 # GSSAPI
 618 #
 619 AC_MSG_CHECKING([whether to build with GSSAPI support])
 620 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 621 [
 622   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 623   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 624 ])
 625 AC_MSG_RESULT([$with_gssapi])
 626 AC_SUBST(with_gssapi)
 627
 628 #
 629 # Kerberos 5
 630 #
 631 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 632 PGAC_ARG_BOOL(with, krb5, no, [build with Kerberos 5 support],
 633 [
 634   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 635   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 636 ])
 637 AC_MSG_RESULT([$with_krb5])
 638 AC_SUBST(with_krb5)
 639
 640
 641 AC_SUBST(krb_srvtab)
 642
 643
 644 #
 645 # Kerberos configuration parameters
 646 #
 647 PGAC_ARG_REQ(with, krb-srvnam,
 648              [NAME], [default service principal name in Kerberos [postgres]],
 649              [],
 650              [with_krb_srvnam="postgres"])
 651 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 652                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 653
 654
 655 #
 656 # PAM
 657 #
 658 AC_MSG_CHECKING([whether to build with PAM support])
 659 PGAC_ARG_BOOL(with, pam, no,
 660               [build with PAM support],
 661               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 662 AC_MSG_RESULT([$with_pam])
 663 AC_SUBST(with_pam)
 664
 665
 666 #
 667 # LDAP
 668 #
 669 AC_MSG_CHECKING([whether to build with LDAP support])
 670 PGAC_ARG_BOOL(with, ldap, no,
 671               [build with LDAP support],
 672               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 673 AC_MSG_RESULT([$with_ldap])
 674 AC_SUBST(with_ldap)
 675
 676
 677 #
 678 # Bonjour
 679 #
 680 AC_MSG_CHECKING([whether to build with Bonjour support])
 681 PGAC_ARG_BOOL(with, bonjour, no,
 682               [build with Bonjour support],
 683               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 684 AC_MSG_RESULT([$with_bonjour])
 685 AC_SUBST(with_bonjour)
 686
 687
 688 #
 689 # OpenSSL
 690 #
 691 AC_MSG_CHECKING([whether to build with OpenSSL support])
 692 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 693               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 694 AC_MSG_RESULT([$with_openssl])
 695 AC_SUBST(with_openssl)
 696
 697
 698 #
 699 # Readline
 700 #
 701 PGAC_ARG_BOOL(with, readline, yes,
 702               [do not use GNU Readline nor BSD Libedit for editing])
 703 # readline on MinGW has problems with backslashes in psql and other bugs.
 704 # This is particularly a problem with non-US code pages.
 705 # Therefore disable its use until we understand the cause. 2004-07-20
 706 if test "$PORTNAME" = "win32"; then
 707   if test "$with_readline" = yes; then
 708     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 709     with_readline=no
 710   fi
 711 fi
 712
 713
 714 #
 715 # Prefer libedit
 716 #
 717 PGAC_ARG_BOOL(with, libedit-preferred, no,
 718               [prefer BSD Libedit over GNU Readline])
 719
 720
 721 #
 722 # OSSP UUID library
 723 #
 724 PGAC_ARG_BOOL(with, ossp-uuid, no, [use OSSP UUID library when building contrib/uuid-ossp])
 725 AC_SUBST(with_ossp_uuid)
 726
 727
 728 #
 729 # XML
 730 #
 731 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 732               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 733
 734 if test "$with_libxml" = yes ; then
 735   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 736   if test -n "$XML2_CONFIG"; then
 737     for pgac_option in `$XML2_CONFIG --cflags`; do
 738       case $pgac_option in
 739         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 740       esac
 741     done
 742     for pgac_option in `$XML2_CONFIG --libs`; do
 743       case $pgac_option in
 744         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 745       esac
 746     done
 747   fi
 748 fi
 749
 750 AC_SUBST(with_libxml)
 751
 752 #
 753 # XSLT
 754 #
 755 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 756               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 757
 758
 759 AC_SUBST(with_libxslt)
 760
 761 #
 762 # tzdata
 763 #
 764 PGAC_ARG_REQ(with, system-tzdata,
 765              [DIR], [use system time zone data in DIR])
 766 AC_SUBST(with_system_tzdata)
 767
 768 #
 769 # Zlib
 770 #
 771 PGAC_ARG_BOOL(with, zlib, yes,
 772               [do not use Zlib])
 773 AC_SUBST(with_zlib)
 774
 775 #
 776 # Elf
 777 #
 778
 779 # Assume system is ELF if it predefines __ELF__ as 1,
 780 # otherwise believe host_os based default.
 781 case $host_os in
 782     freebsd1*|freebsd2*) elf=no;;
 783     freebsd3*|freebsd4*) elf=yes;;
 784 esac
 785
 786 AC_EGREP_CPP(yes,
 787 [#if __ELF__
 788   yes
 789 #endif
 790 ],
 791 [ELF_SYS=true],
 792 [if test "X$elf" = "Xyes" ; then
 793   ELF_SYS=true
 794 else
 795   ELF_SYS=
 796 fi])
 797 AC_SUBST(ELF_SYS)
 798
 799 #
 800 # Assignments
 801 #
 802
 803 CPPFLAGS="$CPPFLAGS $INCLUDES"
 804 LDFLAGS="$LDFLAGS $LIBDIRS"
 805
 806 AC_ARG_VAR(LDFLAGS_SL)
 807
 808 PGAC_PROG_LD
 809 AC_SUBST(LD)
 810 AC_SUBST(with_gnu_ld)
 811 case $host_os in sysv5*)
 812   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 813   [
 814     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 815     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 816     LDFLAGS=$pgac_save_LDFLAGS
 817   ])
 818   ld_R_works=$pgac_cv_prog_ld_R
 819   AC_SUBST(ld_R_works)
 820 esac
 821 AC_PROG_RANLIB
 822 PGAC_CHECK_STRIP
 823 AC_CHECK_TOOL(AR, ar, ar)
 824 if test "$PORTNAME" = "win32"; then
 825   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
 826   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
 827   AC_CHECK_TOOL(WINDRES, windres, windres)
 828 fi
 829
 830 AC_PATH_PROG(TAR, tar)
 831 AC_PROG_LN_S
 832 AC_PROG_AWK
 833
 834 PGAC_PATH_BISON
 835 PGAC_PATH_FLEX
 836
 837 PGAC_PATH_PERL
 838 if test "$with_perl" = yes; then
 839   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 840   PGAC_CHECK_PERL_EMBED_LDFLAGS
 841 fi
 842
 843 if test "$with_python" = yes; then
 844   PGAC_PATH_PYTHON
 845   PGAC_CHECK_PYTHON_EMBED_SETUP
 846 fi
 847
 848 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
 849   AC_PATH_PROG(ZIC, zic)
 850   if test -z "$ZIC"; then
 851     AC_MSG_ERROR([
 852 When cross-compiling, either use the option --with-system-tzdata to use
 853 existing time-zone data, or set the environment variable ZIC to a zic
 854 program to use during the build.])
 855   fi
 856 fi
 857
 858 # Supply a numeric version string for use by 3rd party add-ons
 859 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 860 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 861 tr '.' '        ' |
 862 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 863 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 864
 865 ##
 866 ## Libraries
 867 ##
 868 ## Most libraries are included only if they demonstrably provide a function
 869 ## we need, but libm is an exception: always include it, because there are
 870 ## too many compilers that play cute optimization games that will break
 871 ## probes for standard functions such as pow().
 872 ##
 873
 874 AC_CHECK_LIB(m, main)
 875 AC_SEARCH_LIBS(setproctitle, util)
 876 AC_SEARCH_LIBS(dlopen, dl)
 877 AC_SEARCH_LIBS(socket, [socket wsock32])
 878 AC_SEARCH_LIBS(shl_load, dld)
 879 # We only use libld in port/dynloader/aix.c
 880 case $host_os in
 881      aix*)
 882         AC_SEARCH_LIBS(ldopen, ld)
 883         ;;
 884 esac
 885 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 886 AC_SEARCH_LIBS(crypt, crypt)
 887 # Solaris:
 888 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 889 # Cygwin:
 890 AC_SEARCH_LIBS(shmget, cygipc)
 891
 892 if test "$with_readline" = yes; then
 893   PGAC_CHECK_READLINE
 894   if test x"$pgac_cv_check_readline" = x"no"; then
 895     AC_MSG_ERROR([readline library not found
 896 If you have readline already installed, see config.log for details on the
 897 failure.  It is possible the compiler isn't looking in the proper directory.
 898 Use --without-readline to disable readline support.])
 899   fi
 900 fi
 901
 902 if test "$with_zlib" = yes; then
 903   AC_CHECK_LIB(z, inflate, [],
 904                [AC_MSG_ERROR([zlib library not found
 905 If you have zlib already installed, see config.log for details on the
 906 failure.  It is possible the compiler isn't looking in the proper directory.
 907 Use --without-zlib to disable zlib support.])])
 908 fi
 909
 910 if test "$enable_spinlocks" = yes; then
 911   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 912 else
 913   AC_MSG_WARN([
 914 *** Not using spinlocks will cause poor performance.])
 915 fi
 916
 917 if test "$with_gssapi" = yes ; then
 918   if test "$PORTNAME" != "win32"; then
 919     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
 920                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 921   else
 922     LIBS="$LIBS -lgssapi32"
 923   fi
 924 fi
 925
 926 if test "$with_krb5" = yes ; then
 927   if test "$PORTNAME" != "win32"; then
 928      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 929                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 930      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 931                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 932   else
 933      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 934                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 935   fi
 936 fi
 937
 938 if test "$with_openssl" = yes ; then
 939   dnl Order matters!
 940   if test "$PORTNAME" != "win32"; then
 941      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 942      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 943   else
 944      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 945      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 946   fi
 947 fi
 948
 949 if test "$with_pam" = yes ; then
 950   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 951 fi
 952
 953 if test "$with_libxml" = yes ; then
 954   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 955 fi
 956
 957 if test "$with_libxslt" = yes ; then
 958   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 959 fi
 960
 961 # for contrib/uuid-ossp
 962 if test "$with_ossp_uuid" = yes ; then
 963   AC_CHECK_LIB(ossp-uuid, uuid_export,
 964     [OSSP_UUID_LIBS="-lossp-uuid"],
 965     [AC_CHECK_LIB(uuid, uuid_export,
 966       [OSSP_UUID_LIBS="-luuid"],
 967       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP-UUID])])])
 968 fi
 969 AC_SUBST(OSSP_UUID_LIBS)
 970
 971
 972 ##
 973 ## Header files
 974 ##
 975
 976 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 977 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 978
 979 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 980 # netinet/in.h is included first.
 981 AC_CHECK_HEADERS(netinet/in.h)
 982 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 983 [AC_INCLUDES_DEFAULT
 984 #ifdef HAVE_NETINET_IN_H
 985 #include <netinet/in.h>
 986 #endif
 987 ])
 988
 989 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 990   AC_CHECK_HEADERS(readline/readline.h, [],
 991         [AC_CHECK_HEADERS(readline.h, [],
 992                 [AC_MSG_ERROR([readline header not found
 993 If you have readline already installed, see config.log for details on the
 994 failure.  It is possible the compiler isn't looking in the proper directory.
 995 Use --without-readline to disable readline support.])])])
 996   AC_CHECK_HEADERS(readline/history.h, [],
 997         [AC_CHECK_HEADERS(history.h, [],
 998                 [AC_MSG_ERROR([history header not found
 999 If you have readline already installed, see config.log for details on the
1000 failure.  It is possible the compiler isn't looking in the proper directory.
1001 Use --without-readline to disable readline support.])])])
1002 fi
1003
1004 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1005 # Some installations of libedit usurp /usr/include/readline/, which seems
1006 # bad practice, since in combined installations readline will have its headers
1007 # there.  We might have to resort to AC_EGREP checks to make sure we found
1008 # the proper header...
1009   AC_CHECK_HEADERS(editline/readline.h, [],
1010         [AC_CHECK_HEADERS(readline.h, [],
1011                 [AC_CHECK_HEADERS(readline/readline.h, [],
1012                         [AC_MSG_ERROR([readline header not found
1013 If you have libedit already installed, see config.log for details on the
1014 failure.  It is possible the compiler isn't looking in the proper directory.
1015 Use --without-readline to disable libedit support.])])])])
1016 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1017 # not be there at all.  Hence, don't complain if not found.  We must check
1018 # though, since in yet other versions it is an independent header.
1019   AC_CHECK_HEADERS(editline/history.h, [],
1020         [AC_CHECK_HEADERS(history.h, [],
1021                 [AC_CHECK_HEADERS(readline/history.h)])])
1022 fi
1023
1024 if test "$with_zlib" = yes; then
1025   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1026 If you have zlib already installed, see config.log for details on the
1027 failure.  It is possible the compiler isn't looking in the proper directory.
1028 Use --without-zlib to disable zlib support.])])
1029 fi
1030
1031 if test "$with_gssapi" = yes ; then
1032   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1033         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1034 fi
1035
1036 if test "$with_krb5" = yes ; then
1037   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
1038 fi
1039
1040 if test "$with_openssl" = yes ; then
1041   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1042   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1043   AC_CHECK_FUNCS([ERR_set_mark])
1044 fi
1045
1046 if test "$with_pam" = yes ; then
1047   AC_CHECK_HEADERS(security/pam_appl.h, [],
1048                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1049                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1050 fi
1051
1052 if test "$with_libxml" = yes ; then
1053   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1054 fi
1055
1056 if test "$with_libxslt" = yes ; then
1057   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1058 fi
1059
1060 if test "$with_ldap" = yes ; then
1061   if test "$PORTNAME" != "win32"; then
1062      AC_CHECK_HEADERS(ldap.h, [],
1063                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1064   else
1065      AC_CHECK_HEADERS(winldap.h, [],
1066                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1067                       [AC_INCLUDES_DEFAULT
1068 #include <windows.h>
1069                       ])
1070   fi
1071 fi
1072
1073 if test "$with_bonjour" = yes ; then
1074   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
1075 fi
1076
1077 # for contrib/uuid-ossp
1078 if test "$with_ossp_uuid" = yes ; then
1079   AC_CHECK_HEADERS(ossp/uuid.h, [], [
1080     AC_CHECK_HEADERS(uuid.h, [],
1081       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP-UUID])])])
1082 fi
1083
1084
1085 ##
1086 ## Types, structures, compiler characteristics
1087 ##
1088
1089 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1090 AC_C_BIGENDIAN
1091 AC_C_CONST
1092 AC_C_INLINE
1093 AC_C_STRINGIZE
1094 PGAC_C_SIGNED
1095 AC_C_VOLATILE
1096 PGAC_C_FUNCNAME_SUPPORT
1097 PGAC_STRUCT_TIMEZONE
1098 PGAC_UNION_SEMUN
1099 PGAC_STRUCT_SOCKADDR_UN
1100 PGAC_STRUCT_SOCKADDR_STORAGE
1101 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1102 PGAC_STRUCT_ADDRINFO
1103
1104 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
1105 [#include <sys/param.h>
1106 #include <sys/types.h>
1107 #include <sys/socket.h>
1108 #include <sys/ucred.h>])
1109
1110 AC_CHECK_TYPES([struct option], [], [],
1111 [#ifdef HAVE_GETOPT_H
1112 #include <getopt.h>
1113 #endif])
1114
1115 if test "$with_zlib" = yes; then
1116   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1117   # did not).  While we could work around the lack of z_streamp, it
1118   # seems unwise to encourage people to use such old zlib versions...
1119   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1120 Use --without-zlib to disable zlib support.])],
1121                 [#include <zlib.h>])
1122 fi
1123
1124 if test "$with_krb5" = yes; then
1125 # Check for differences between MIT and Heimdal (KTH) releases
1126   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
1127                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
1128                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
1129                                      [#include <krb5.h>])],
1130                    [#include <krb5.h>])
1131   AC_CHECK_MEMBERS(krb5_error.text.data, [],
1132                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
1133                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
1134                                      [#include <krb5.h>])],
1135                    [#include <krb5.h>])
1136
1137 # Win32 requires headers to be loaded for __stdcall, so can't use
1138 # AC_CHECK_FUNCS here.
1139   AC_MSG_CHECKING(for krb5_free_unparsed_name)
1140   AC_TRY_LINK([#include <krb5.h>],
1141               [krb5_free_unparsed_name(NULL,NULL);],
1142               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
1143 AC_MSG_RESULT(yes)],
1144               [AC_MSG_RESULT(no)])
1145 fi
1146
1147
1148 ##
1149 ## Functions, global variables
1150 ##
1151
1152 PGAC_VAR_INT_TIMEZONE
1153 AC_FUNC_ACCEPT_ARGTYPES
1154 PGAC_FUNC_GETTIMEOFDAY_1ARG
1155
1156 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getpeerucred getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
1157
1158 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1159 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1160 AC_CHECK_DECLS([strlcat, strlcpy])
1161 # This is probably only present on Darwin, but may as well check always
1162 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1163
1164 HAVE_IPV6=no
1165 AC_CHECK_TYPE([struct sockaddr_in6],
1166         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1167          HAVE_IPV6=yes],
1168         [],
1169 [$ac_includes_default
1170 #include <netinet/in.h>])
1171 AC_SUBST(HAVE_IPV6)
1172
1173 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1174 [AC_TRY_LINK(
1175 [#include <machine/vmparam.h>
1176 #include <sys/exec.h>
1177 ],
1178 [PS_STRINGS->ps_nargvstr = 1;
1179 PS_STRINGS->ps_argvstr = "foo";],
1180 [pgac_cv_var_PS_STRINGS=yes],
1181 [pgac_cv_var_PS_STRINGS=no])])
1182 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1183   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1184 fi
1185
1186
1187 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1188 # is missing.  Yes, there are machines that have only one.  We may
1189 # also decide to use snprintf.c if snprintf() is present but does not
1190 # have all the features we need --- see below.
1191
1192 if test "$PORTNAME" = "win32"; then
1193   # Win32 gets snprintf.c built unconditionally.
1194   #
1195   # To properly translate all NLS languages strings, we must support the
1196   # *printf() %$ format, which allows *printf() arguments to be selected
1197   # by position in the translated string.
1198   #
1199   # libintl versions < 0.13 use the native *printf() functions, and Win32
1200   # *printf() doesn't understand %$, so we must use our /port versions,
1201   # which do understand %$. libintl versions >= 0.13 include their own
1202   # *printf versions on Win32.  The libintl 0.13 release note text is:
1203   #
1204   #   C format strings with positions, as they arise when a translator
1205   #   needs to reorder a sentence, are now supported on all platforms.
1206   #   On those few platforms (NetBSD and Woe32) for which the native
1207   #   printf()/fprintf()/... functions don't support such format
1208   #   strings, replacements are provided through <libintl.h>.
1209   #
1210   # We could use libintl >= 0.13's *printf() if we were sure that we had
1211   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1212   # to guarantee that, it is best to just use our own, so we are sure to
1213   # get %$ support. In include/port.h we disable the *printf() macros
1214   # that might have been defined by libintl.
1215   #
1216   # We do this unconditionally whether NLS is used or not so we are sure
1217   # that all Win32 libraries and binaries behave the same.
1218   pgac_need_repl_snprintf=yes
1219 else
1220   pgac_need_repl_snprintf=no
1221   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1222   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1223 fi
1224
1225
1226 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1227 # include/c.h will provide declarations.  Note this is a separate test
1228 # from whether the functions exist in the C library --- there are
1229 # systems that have the functions but don't bother to declare them :-(
1230
1231 AC_CHECK_DECLS([snprintf, vsnprintf])
1232
1233
1234 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1235 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1236 [AC_TRY_LINK([
1237 #include <math.h>
1238 double glob_double;
1239 ],
1240 [return isinf(glob_double) ? 0 : 1;],
1241 [ac_cv_func_isinf=yes],
1242 [ac_cv_func_isinf=no])])
1243
1244 if test $ac_cv_func_isinf = yes ; then
1245   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1246 else
1247   AC_LIBOBJ(isinf)
1248   # Look for a way to implement a substitute for isinf()
1249   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1250 fi
1251
1252 # Some versions of libedit contain strlcpy(); so disregard that library while
1253 # checking for these standard libc functions.
1254 pgac_save_LIBS="$LIBS"
1255 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1256
1257 AC_REPLACE_FUNCS([crypt getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1258
1259 LIBS="$pgac_save_LIBS"
1260
1261 # System's version of getaddrinfo(), if any, may be used only if we found
1262 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1263 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1264 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1265 # because we want to use our own getaddrinfo.c on Windows anyway.)
1266 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1267   AC_REPLACE_FUNCS([getaddrinfo])
1268 else
1269   AC_LIBOBJ(getaddrinfo)
1270 fi
1271
1272 # Similarly, use system's getopt_long() only if system provides struct option.
1273 # Solaris' getopt() doesn't do what we want for long options, so always use
1274 # our versions on that platform.
1275 if test "$PORTNAME" = "solaris"; then
1276   AC_LIBOBJ(getopt)
1277   AC_LIBOBJ(getopt_long)
1278 elif test x"$ac_cv_type_struct_option" = xyes ; then
1279   AC_REPLACE_FUNCS([getopt_long])
1280 else
1281   AC_LIBOBJ(getopt_long)
1282 fi
1283
1284 # Win32 support
1285 if test "$PORTNAME" = "win32"; then
1286 AC_REPLACE_FUNCS(gettimeofday)
1287 AC_LIBOBJ(kill)
1288 AC_LIBOBJ(open)
1289 AC_LIBOBJ(rand)
1290 AC_LIBOBJ(win32error)
1291 AC_DEFINE([HAVE_SYMLINK], 1,
1292           [Define to 1 if you have the `symlink' function.])
1293 fi
1294
1295 if test "$with_readline" = yes; then
1296   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1297   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1298   AC_CHECK_FUNCS([replace_history_entry])
1299 fi
1300
1301
1302 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1303 dnl (especially on GNU libc)
1304 dnl See also comments in c.h.
1305 AC_MSG_CHECKING(for sigsetjmp)
1306 AC_TRY_LINK([#include <setjmp.h>],
1307             [sigjmp_buf x; sigsetjmp(x, 1);],
1308             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1309 AC_MSG_RESULT(yes)],
1310             [AC_MSG_RESULT(no)])
1311
1312 AC_DECL_SYS_SIGLIST
1313
1314 AC_CHECK_FUNC(syslog,
1315               [AC_CHECK_HEADER(syslog.h,
1316                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1317
1318 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1319 [AC_TRY_LINK([#include <unistd.h>],
1320   [extern int optreset; optreset = 1;],
1321   [pgac_cv_var_int_optreset=yes],
1322   [pgac_cv_var_int_optreset=no])])
1323 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1324   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1325 fi
1326
1327 AC_CHECK_FUNCS([strtoll strtoq], [break])
1328 AC_CHECK_FUNCS([strtoull strtouq], [break])
1329
1330 # Check for one of atexit() or on_exit()
1331 AC_CHECK_FUNCS(atexit, [],
1332                [AC_CHECK_FUNCS(on_exit, [],
1333                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1334
1335 AC_REPLACE_FUNCS(fseeko)
1336 case $host_os in
1337         # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1338         bsdi*|netbsd*)
1339                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1340                 ac_cv_func_fseeko=yes;;
1341         *)
1342                 AC_FUNC_FSEEKO;;
1343 esac
1344
1345
1346 #
1347 # Pthreads
1348 #
1349 # For each platform, we need to know about any special compile and link
1350 # libraries, and whether the normal C function names are thread-safe.
1351 # See the comment at the top of src/port/thread.c for more information.
1352 # WIN32 doesn't need the pthread tests;  it always uses threads
1353 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1354 ACX_PTHREAD     # set thread flags
1355
1356 # Some platforms use these, so just define them.  They can't hurt if they
1357 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1358 # enables 5-arg getpwuid_r, among other things.
1359 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1360
1361
1362 # At this point, we don't want to muck with the compiler name for threading.
1363 # Let's see who fails, perhaps AIX.  2004-04-23
1364 if test "$PTHREAD_CC" != "$CC"; then
1365 AC_MSG_ERROR([
1366 PostgreSQL does not support platforms that require a special compiler
1367 for thread safety.])
1368 fi
1369
1370 if test "$THREAD_SUPPORT" = no; then
1371 AC_MSG_ERROR([cannot enable threads on this platform
1372 This platform is known to not support thread-safe programs.  For details,
1373 compile and run src/bin/pg_thread_test.])
1374 fi
1375
1376 # Check for *_r functions
1377 _CFLAGS="$CFLAGS"
1378 _LIBS="$LIBS"
1379 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1380 LIBS="$LIBS $PTHREAD_LIBS"
1381
1382 if test "$PORTNAME" != "win32"; then
1383 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1384 fi
1385
1386 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1387
1388 # Do test here with the proper thread flags
1389 PGAC_FUNC_GETPWUID_R_5ARG
1390 PGAC_FUNC_STRERROR_R_INT
1391
1392 CFLAGS="$_CFLAGS"
1393 LIBS="$_LIBS"
1394
1395 else
1396 # do not use values from template file
1397 PTHREAD_CFLAGS=
1398 PTHREAD_LIBS=
1399 fi
1400
1401 AC_SUBST(PTHREAD_CFLAGS)
1402 AC_SUBST(PTHREAD_LIBS)
1403
1404
1405 # We can test for libldap_r only after we know PTHREAD_LIBS
1406 if test "$with_ldap" = yes ; then
1407   _LIBS="$LIBS"
1408   if test "$PORTNAME" != "win32"; then
1409     AC_CHECK_LIB(ldap, ldap_bind, [],
1410                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1411                  [$EXTRA_LDAP_LIBS])
1412     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1413     if test "$enable_thread_safety" = yes; then
1414       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1415       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1416                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1417                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1418       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1419     else
1420       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1421     fi
1422   else
1423     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1424     LDAP_LIBS_FE="-lwldap32"
1425     LDAP_LIBS_BE="-lwldap32"
1426   fi
1427   LIBS="$_LIBS"
1428 fi
1429 AC_SUBST(LDAP_LIBS_FE)
1430 AC_SUBST(LDAP_LIBS_BE)
1431
1432
1433 # This test makes sure that run tests work at all.  Sometimes a shared
1434 # library is found by the linker, but the runtime linker can't find it.
1435 # This check should come after all modifications of compiler or linker
1436 # variables, and before any other run tests.
1437 AC_MSG_CHECKING([test program])
1438 AC_TRY_RUN([int main() { return 0; }],
1439 [AC_MSG_RESULT(ok)],
1440 [AC_MSG_RESULT(failed)
1441 AC_MSG_ERROR([[
1442 Could not execute a simple test program.  This may be a problem
1443 related to locating shared libraries.  Check the file 'config.log'
1444 for the exact reason.]])],
1445 [AC_MSG_RESULT([cross-compiling])])
1446
1447 # --------------------
1448 # Run tests below here
1449 # --------------------
1450
1451 # Force use of our snprintf if system's doesn't do arg control
1452 # See comment above at snprintf test for details.
1453 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1454   PGAC_FUNC_PRINTF_ARG_CONTROL
1455   if test $pgac_cv_printf_arg_control != yes ; then
1456     pgac_need_repl_snprintf=yes
1457   fi
1458 fi
1459
1460
1461 dnl Check to see if we have a working 64-bit integer type.
1462 dnl This breaks down into two steps:
1463 dnl (1) figure out if the compiler has a 64-bit int type with working
1464 dnl arithmetic, and if so
1465 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1466 dnl snprintf is the only library routine we really need for int8 support.)
1467 dnl It's entirely possible to have a compiler that handles a 64-bit type
1468 dnl when the C library doesn't; this is fairly likely when using gcc on
1469 dnl an older platform, for example.
1470 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1471 dnl we force our own version of snprintf() to be used instead.
1472 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1473
1474 PGAC_TYPE_64BIT_INT([long int])
1475
1476 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1477   PGAC_TYPE_64BIT_INT([long long int])
1478 fi
1479
1480
1481 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1482
1483 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1484   AC_TRY_COMPILE([
1485 #define INT64CONST(x)  x##LL
1486 long long int foo = INT64CONST(0x1234567890123456);
1487 ],
1488         [],
1489         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1490         [])
1491 fi
1492
1493
1494 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1495 # we found we need to use "long long int", better check.  We cope with
1496 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1497 # work, fall back to our own snprintf emulation (which we know uses %lld).
1498
1499 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1500   if test $pgac_need_repl_snprintf = no; then
1501     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1502     if test "$LONG_LONG_INT_FORMAT" = ""; then
1503       # Force usage of our own snprintf, since system snprintf is broken
1504       pgac_need_repl_snprintf=yes
1505       LONG_LONG_INT_FORMAT='%lld'
1506     fi
1507   else
1508     # Here if we previously decided we needed to use our own snprintf
1509     LONG_LONG_INT_FORMAT='%lld'
1510   fi
1511   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1512   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1513   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1514 else
1515   # Here if we are not using 'long long int' at all
1516   INT64_FORMAT='"%ld"'
1517   UINT64_FORMAT='"%lu"'
1518 fi
1519
1520 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1521                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1522
1523 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1524                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1525
1526 # Now we have checked all the reasons to replace snprintf
1527 if test $pgac_need_repl_snprintf = yes; then
1528   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1529   AC_LIBOBJ(snprintf)
1530 fi
1531
1532 # Need a #define for the size of Datum (unsigned long)
1533 AC_CHECK_SIZEOF([unsigned long])
1534
1535 # And one for the size of size_t (enables tweaks for > 32bit address space)
1536 AC_CHECK_SIZEOF([size_t])
1537
1538 # Decide whether float4 is passed by value: user-selectable, enabled by default
1539 AC_MSG_CHECKING([whether to build with float4 passed by value])
1540 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1541               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1542                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1543                float4passbyval=true],
1544               [float4passbyval=false])
1545 AC_MSG_RESULT([$enable_float4_byval])
1546 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1547
1548 # Decide whether float8 is passed by value.
1549 # Note: this setting also controls int8 and related types such as timestamp.
1550 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1551 # If not, trying to select it is an error.
1552 AC_MSG_CHECKING([whether to build with float8 passed by value])
1553 if test $ac_cv_sizeof_unsigned_long -ge 8 ; then
1554   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1555 else
1556   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1557   if test "$enable_float8_byval" = yes ; then
1558     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1559   fi
1560 fi
1561 if test "$enable_float8_byval" = yes ; then
1562   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1563             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1564   float8passbyval=true
1565 else
1566   float8passbyval=false
1567 fi
1568 AC_MSG_RESULT([$enable_float8_byval])
1569 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1570
1571 # Determine memory alignment requirements for the basic C data types.
1572
1573 AC_CHECK_ALIGNOF(short)
1574 AC_CHECK_ALIGNOF(int)
1575 AC_CHECK_ALIGNOF(long)
1576 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1577   AC_CHECK_ALIGNOF(long long int)
1578 fi
1579 AC_CHECK_ALIGNOF(double)
1580
1581 # Compute maximum alignment of any basic type.
1582 # We assume long's alignment is at least as strong as char, short, or int;
1583 # but we must check long long (if it exists) and double.
1584
1585 MAX_ALIGNOF=$ac_cv_alignof_long
1586 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1587   MAX_ALIGNOF=$ac_cv_alignof_double
1588 fi
1589 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1590   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1591 fi
1592 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1593
1594
1595 # Some platforms predefine the types int8, int16, etc.  Only check
1596 # a (hopefully) representative subset.
1597 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1598 [#include <stdio.h>
1599 #ifdef HAVE_SUPPORTDEFS_H
1600 #include <SupportDefs.h>
1601 #endif])
1602
1603 # We also check for sig_atomic_t, which *should* be defined per ANSI
1604 # C, but is missing on some old platforms.
1605 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1606
1607
1608 # If the user did not disable integer datetimes, check that
1609 # there is a working 64-bit integral type to use.
1610 if test x"$USE_INTEGER_DATETIMES" = x"yes" &&
1611    test x"$HAVE_LONG_INT_64" = x"no" &&
1612    test x"$HAVE_LONG_LONG_INT_64" = x"no" &&
1613    test x"$HAVE_INT64" = x"no" ; then
1614   AC_MSG_ERROR([
1615 Integer-based datetime support requires a 64-bit integer type,
1616 but no such type could be found. The --disable-integer-datetimes
1617 configure option can be used to disable integer-based storage
1618 of datetime values.])
1619 fi
1620
1621
1622 if test "$PORTNAME" != "win32"
1623 then
1624 PGAC_FUNC_POSIX_SIGNALS
1625 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1626   AC_MSG_ERROR([
1627 Thread-safety requires POSIX signals, which are not supported by this
1628 operating system.])
1629 fi
1630 fi
1631
1632 if test $ac_cv_func_fseeko = yes; then
1633 AC_SYS_LARGEFILE
1634 fi
1635
1636 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1637 AC_CHECK_SIZEOF([off_t])
1638
1639 # If we don't have largefile support, can't handle segsize >= 2GB.
1640 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1641    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1642 fi
1643
1644 # SunOS doesn't handle negative byte comparisons properly with +/- return
1645 AC_FUNC_MEMCMP
1646
1647
1648 # Select semaphore implementation type.
1649 if test "$PORTNAME" != "win32"; then
1650   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1651     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1652     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1653   else
1654     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1655       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1656       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1657     else
1658       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1659       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1660     fi
1661   fi
1662 else
1663   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1664   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1665 fi
1666
1667
1668 # Select shared-memory implementation type.
1669 if test "$PORTNAME" != "win32"; then
1670   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1671   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1672 else
1673   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1674   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1675 fi
1676
1677 # If not set in template file, set bytes to use libc memset()
1678 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1679   MEMSET_LOOP_LIMIT=1024
1680 fi
1681 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1682
1683
1684 if test "$enable_nls" = yes ; then
1685   PGAC_CHECK_GETTEXT
1686 fi
1687
1688 # Check for Tcl configuration script tclConfig.sh
1689 if test "$with_tcl" = yes; then
1690     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1691     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1692                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1693     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1694     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1695     ac_save_CPPFLAGS=$CPPFLAGS
1696     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1697     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1698     CPPFLAGS=$ac_save_CPPFLAGS
1699 fi
1700
1701 #
1702 # Check for DocBook and tools
1703 #
1704 PGAC_PROG_NSGMLS
1705 PGAC_PROG_JADE
1706 PGAC_CHECK_DOCBOOK(4.2)
1707 PGAC_PATH_DOCBOOK_STYLESHEETS
1708 PGAC_PATH_COLLATEINDEX
1709 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1710 PGAC_PATH_DOCBOOK2MAN
1711
1712 # Thread testing
1713
1714 # We have to run the thread test near the end so we have all our symbols
1715 # defined.  Cross compiling throws a warning.
1716 #
1717 if test "$enable_thread_safety_force" = yes; then
1718 if test "$PORTNAME" != "win32"
1719 then
1720   AC_MSG_WARN([
1721 *** Skipping thread test program.  --enable-thread-safety-force was used.
1722 *** Run the program in src/test/thread on the your machine and add proper
1723 *** locking function calls to your applications to guarantee thread safety.
1724 ])
1725 else
1726 AC_MSG_WARN([*** skipping thread test on Win32])
1727 fi
1728 elif test "$enable_thread_safety" = yes; then
1729 if test "$PORTNAME" != "win32"
1730 then
1731 AC_MSG_CHECKING([thread safety of required library functions])
1732
1733 _CFLAGS="$CFLAGS"
1734 _LIBS="$LIBS"
1735 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1736 LIBS="$LIBS $PTHREAD_LIBS"
1737 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1738   [AC_MSG_RESULT(yes)],
1739   [AC_MSG_RESULT(no)
1740   AC_MSG_ERROR([thread test program failed
1741 This platform is not thread-safe.  Check the file 'config.log' for the
1742 exact reason.
1743
1744 You can use the configure option --enable-thread-safety-force to force
1745 threads to be enabled.  But you must then run the program in
1746 src/test/thread and add locking function calls to your applications to
1747 guarantee thread safety.])],
1748   [AC_MSG_RESULT(maybe)
1749   AC_MSG_WARN([
1750 *** Skipping thread test program because of cross-compile build.
1751 *** Run the program in src/test/thread on the target machine.
1752 ])])
1753 CFLAGS="$_CFLAGS"
1754 LIBS="$_LIBS"
1755 else
1756 AC_MSG_WARN([*** skipping thread test on Win32])
1757 fi
1758 fi
1759
1760 # If compiler will take -Wl,--as-needed then add that to LDFLAGS.
1761 # This is much easier than trying to filter LIBS to the minimum for each
1762 # executable.  (Note that shared library links won't use this switch, though.)
1763 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
1764 # libreadline; therefore we postpone testing it until we know what library
1765 # dependencies readline has.  The test code will try to link with $LIBS.
1766 if test "$with_readline" = yes; then
1767   link_test_func=readline
1768 else
1769   link_test_func=exit
1770 fi
1771 if test "$PORTNAME" != "darwin"; then
1772   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
1773 else
1774   # On Darwin it's spelled -Wl,-dead_strip_dylibs, but don't try that elsewhere
1775   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
1776 fi
1777
1778
1779 # Begin output steps
1780
1781 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
1782 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
1783 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
1784
1785 # prepare build tree if outside source tree
1786 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1787 # Note 2: /bin/pwd might be better than shell's built-in at getting
1788 #         a symlink-free name.
1789 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1790   vpath_build=no
1791 else
1792   vpath_build=yes
1793   if test "$no_create" != yes; then
1794     _AS_ECHO_N([preparing build tree... ])
1795     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1796     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1797       || AC_MSG_ERROR(failed)
1798     AC_MSG_RESULT(done)
1799   fi
1800 fi
1801 AC_SUBST(vpath_build)
1802
1803
1804 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1805
1806 AC_CONFIG_LINKS([
1807   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1808   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1809   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1810   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1811   src/include/pg_config_os.h:src/include/port/${template}.h
1812   src/Makefile.port:src/makefiles/Makefile.${template}
1813 ])
1814
1815 if test "$PORTNAME" = "win32"; then
1816 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1817 # Links sometimes fail undetected on Mingw -
1818 # so here we detect it and warn the user
1819 for FILE in $CONFIG_LINKS
1820  do
1821         # test -e works for symlinks in the MinGW console
1822         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1823  done
1824 ])
1825 fi
1826
1827 AC_CONFIG_HEADERS([src/include/pg_config.h],
1828 [
1829 # Update timestamp for pg_config.h (see Makefile.global)
1830 echo >src/include/stamp-h
1831 ])
1832
1833 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1834
1835 AC_OUTPUT
1836
1837 # Warn about unknown options
1838 PGAC_ARG_CHECK