granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [12devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 357     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361 AC_PROG_CC_C99()
 362
 363 # Error out if the compiler does not support C99, as the codebase
 364 # relies on that.
 365 if test "$ac_cv_prog_cc_c99" = no; then
 366     AC_MSG_ERROR([C compiler "$CC" does not support C99])
 367 fi
 368
 369 AC_PROG_CXX([$pgac_cxx_list])
 370
 371 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 372 # but has idiosyncrasies of its own.  We assume icc will define
 373 # __INTEL_COMPILER regardless of CFLAGS.
 374 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 375 choke me
 376 @%:@endif])], [ICC=yes], [ICC=no])
 377
 378 # Check if it's Sun Studio compiler. We assume that
 379 # __SUNPRO_C will be defined for Sun Studio compilers
 380 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 381 choke me
 382 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 383
 384 AC_SUBST(SUN_STUDIO_CC)
 385
 386
 387 #
 388 # LLVM
 389 #
 390 # Checked early because subsequent tests depend on it.
 391 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 392               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 393 AC_SUBST(with_llvm)
 394 if test "$with_llvm" = yes ; then
 395    PGAC_LLVM_SUPPORT()
 396 fi
 397
 398
 399 unset CFLAGS
 400 unset CXXFLAGS
 401
 402 #
 403 # Read the template
 404 #
 405 . "$srcdir/src/template/$template" || exit
 406
 407 # C[XX]FLAGS are selected so:
 408 # If the user specifies something in the environment, that is used.
 409 # else:  If the template file set something, that is used.
 410 # else:  If coverage was enabled, don't set anything.
 411 # else:  If the compiler is GCC, then we use -O2.
 412 # else:  If the compiler is something else, then we use -O, unless debugging.
 413
 414 if test "$ac_env_CFLAGS_set" = set; then
 415   CFLAGS=$ac_env_CFLAGS_value
 416 elif test "${CFLAGS+set}" = set; then
 417   : # (keep what template set)
 418 elif test "$enable_coverage" = yes; then
 419   : # no optimization by default
 420 elif test "$GCC" = yes; then
 421   CFLAGS="-O2"
 422 else
 423   # if the user selected debug mode, don't use -O
 424   if test "$enable_debug" != yes; then
 425     CFLAGS="-O"
 426   fi
 427 fi
 428
 429 if test "$ac_env_CXXFLAGS_set" = set; then
 430   CXXFLAGS=$ac_env_CXXFLAGS_value
 431 elif test "${CXXFLAGS+set}" = set; then
 432   : # (keep what template set)
 433 elif test "$enable_coverage" = yes; then
 434   : # no optimization by default
 435 elif test "$GCC" = yes; then
 436   CXXFLAGS="-O2"
 437 else
 438   # if the user selected debug mode, don't use -O
 439   if test "$enable_debug" != yes; then
 440     CXXFLAGS="-O"
 441   fi
 442 fi
 443
 444 # When generating bitcode (for inlining) we always want to use -O2
 445 # even when --enable-debug is specified. The bitcode it's not going to
 446 # be used for line-by-line debugging, and JIT inlining doesn't work
 447 # without at least -O1 (otherwise clang will emit 'noinline'
 448 # attributes everywhere), which is bad for testing.  Still allow the
 449 # environment to override if done explicitly.
 450 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 451   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 452 else
 453   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 454 fi
 455 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 456   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 457 else
 458   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 459 fi
 460
 461 # C[XX]FLAGS we determined above will be added back at the end
 462 user_CFLAGS=$CFLAGS
 463 CFLAGS=""
 464 user_CXXFLAGS=$CXXFLAGS
 465 CXXFLAGS=""
 466 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 467 BITCODE_CFLAGS=""
 468 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 469 BITCODE_CXXFLAGS=""
 470
 471 # set CFLAGS_VECTOR from the environment, if available
 472 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 473   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 474 fi
 475
 476 # Some versions of GCC support some additional useful warning flags.
 477 # Check whether they are supported, and add them to CFLAGS if so.
 478 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 479 # but has its own.  Also check other compiler-specific flags here.
 480
 481 if test "$GCC" = yes -a "$ICC" = no; then
 482   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 483   CXXFLAGS="-Wall -Wpointer-arith"
 484   # These work in some but not all gcc versions
 485   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 486   # -Wdeclaration-after-statement isn't applicable for C++
 487   # Really don't want VLAs to be used in our dialect of C
 488   PGAC_PROG_CC_CFLAGS_OPT([-Werror=vla])
 489   # -Wvla is not applicable for C++
 490   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 491   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 492   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 493   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 494   # This was included in -Wall/-Wformat in older GCC versions
 495   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 496   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 497   # Disable strict-aliasing rules; needed for gcc 3.3+
 498   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 499   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 500   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 501   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 502   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 503   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 504   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 505   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 506   # Optimization flags for specific files that benefit from vectorization
 507   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 508   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 509   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 510   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 511   # test for the positive form and if that works, add the negative form
 512   NOT_THE_CFLAGS=""
 513   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 514   if test -n "$NOT_THE_CFLAGS"; then
 515     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 516   fi
 517   # Similarly disable useless truncation warnings from gcc 8+
 518   NOT_THE_CFLAGS=""
 519   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wformat-truncation])
 520   if test -n "$NOT_THE_CFLAGS"; then
 521     CFLAGS="$CFLAGS -Wno-format-truncation"
 522   fi
 523   NOT_THE_CFLAGS=""
 524   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wstringop-truncation])
 525   if test -n "$NOT_THE_CFLAGS"; then
 526     CFLAGS="$CFLAGS -Wno-stringop-truncation"
 527   fi
 528 elif test "$ICC" = yes; then
 529   # Intel's compiler has a bug/misoptimization in checking for
 530   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 531   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 532   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 533   # Make sure strict aliasing is off (though this is said to be the default)
 534   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 535   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 536 elif test "$PORTNAME" = "aix"; then
 537   # AIX's xlc has to have strict aliasing turned off too
 538   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 539   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 540   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 541   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 542 elif test "$PORTNAME" = "hpux"; then
 543   # On some versions of HP-UX, libm functions do not set errno by default.
 544   # Fix that by using +Olibmerrno if the compiler recognizes it.
 545   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 546   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 547 fi
 548
 549 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 550
 551 # Determine flags used to emit bitcode for JIT inlining. Need to test
 552 # for behaviour changing compiler flags, to keep compatibility with
 553 # compiler used for normal postgres code.
 554 if test "$with_llvm" = yes ; then
 555   CLANGXX="$CLANG -xc++"
 556
 557   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 558   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 559   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 560   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 561   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 562   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 563 fi
 564
 565 # supply -g if --enable-debug
 566 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 567   CFLAGS="$CFLAGS -g"
 568 fi
 569
 570 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 571   CXXFLAGS="$CXXFLAGS -g"
 572 fi
 573
 574 # enable code coverage if --enable-coverage
 575 if test "$enable_coverage" = yes; then
 576   if test "$GCC" = yes; then
 577     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 578     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 579   else
 580     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 581   fi
 582 fi
 583
 584 # enable profiling if --enable-profiling
 585 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 586   if test "$GCC" = yes; then
 587     AC_DEFINE([PROFILE_PID_DIR], 1,
 588            [Define to 1 to allow profiling output to be saved separately for each process.])
 589     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 590     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 591   else
 592     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 593   fi
 594 fi
 595
 596 # We already have this in Makefile.win32, but configure needs it too
 597 if test "$PORTNAME" = "win32"; then
 598   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 599 fi
 600
 601 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 602 # user-specified flags (if any) at the end.  This lets users override
 603 # the automatic additions.
 604 CFLAGS="$CFLAGS $user_CFLAGS"
 605 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 606 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 607 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 608
 609 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 610 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 611
 612 # Check if the compiler still works with the final flag settings
 613 # (note, we're not checking that for CXX, which is optional)
 614 AC_MSG_CHECKING([whether the C compiler still works])
 615 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 616   [AC_MSG_RESULT(yes)],
 617   [AC_MSG_RESULT(no)
 618    AC_MSG_ERROR([cannot proceed])])
 619
 620 # Defend against gcc -ffast-math
 621 if test "$GCC" = yes; then
 622 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 623 choke me
 624 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 625 fi
 626
 627 # Defend against clang being used on x86-32 without SSE2 enabled.  As current
 628 # versions of clang do not understand -fexcess-precision=standard, the use of
 629 # x87 floating point operations leads to problems like isinf possibly returning
 630 # false for a value that is infinite when converted from the 80bit register to
 631 # the 8byte memory representation.
 632 #
 633 # Only perform the test if the compiler doesn't understand
 634 # -fexcess-precision=standard, that way a potentially fixed compiler will work
 635 # automatically.
 636 if test "$pgac_cv_prog_CC_cflags__fexcess_precision_standard" = no; then
 637 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 638 @%:@if defined(__clang__) && defined(__i386__) && !defined(__SSE2_MATH__)
 639 choke me
 640 @%:@endif
 641 ])], [],
 642 [AC_MSG_ERROR([Compiling PostgreSQL with clang, on 32bit x86, requires SSE2 support. Use -msse2 or use gcc.])])
 643 fi
 644
 645 AC_PROG_CPP
 646 AC_SUBST(GCC)
 647
 648
 649 #
 650 # Set up TAS assembly code if needed; the template file has now had its
 651 # chance to request this.
 652 #
 653 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 654
 655 if test "$need_tas" = yes ; then
 656   TAS=tas.o
 657 else
 658   TAS=""
 659 fi
 660 AC_SUBST(TAS)
 661
 662
 663 #
 664 # Automatic dependency tracking
 665 #
 666 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 667               [autodepend=yes])
 668 AC_SUBST(autodepend)
 669
 670
 671 #
 672 # Enable assert checks
 673 #
 674 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 675               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 676                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 677
 678
 679 #
 680 # Include directories
 681 #
 682 ac_save_IFS=$IFS
 683 IFS="${IFS}${PATH_SEPARATOR}"
 684 # SRCH_INC comes from the template file
 685 for dir in $with_includes $SRCH_INC; do
 686   if test -d "$dir"; then
 687     INCLUDES="$INCLUDES -I$dir"
 688   else
 689     AC_MSG_WARN([*** Include directory $dir does not exist.])
 690   fi
 691 done
 692 IFS=$ac_save_IFS
 693 AC_SUBST(INCLUDES)
 694
 695
 696 #
 697 # Library directories
 698 #
 699 ac_save_IFS=$IFS
 700 IFS="${IFS}${PATH_SEPARATOR}"
 701 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 702 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 703   if test -d "$dir"; then
 704     LIBDIRS="$LIBDIRS -L$dir"
 705   else
 706     AC_MSG_WARN([*** Library directory $dir does not exist.])
 707   fi
 708 done
 709 IFS=$ac_save_IFS
 710
 711 #
 712 # Enable thread-safe client libraries
 713 #
 714 AC_MSG_CHECKING([allow thread-safe client libraries])
 715 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 716 if test "$enable_thread_safety" = yes; then
 717   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 718           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 719 fi
 720 AC_MSG_RESULT([$enable_thread_safety])
 721 AC_SUBST(enable_thread_safety)
 722
 723 #
 724 # ICU
 725 #
 726 AC_MSG_CHECKING([whether to build with ICU support])
 727 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 728               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 729 AC_MSG_RESULT([$with_icu])
 730 AC_SUBST(with_icu)
 731
 732 if test "$with_icu" = yes; then
 733   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 734 fi
 735
 736 #
 737 # Optionally build Tcl modules (PL/Tcl)
 738 #
 739 AC_MSG_CHECKING([whether to build with Tcl])
 740 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 741 AC_MSG_RESULT([$with_tcl])
 742 AC_SUBST([with_tcl])
 743
 744 # We see if the path to the Tcl/Tk configuration scripts is specified.
 745 # This will override the use of tclsh to find the paths to search.
 746
 747 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 748
 749 #
 750 # Optionally build Perl modules (PL/Perl)
 751 #
 752 AC_MSG_CHECKING([whether to build Perl modules])
 753 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 754 AC_MSG_RESULT([$with_perl])
 755 AC_SUBST(with_perl)
 756
 757 #
 758 # Optionally build Python modules (PL/Python)
 759 #
 760 AC_MSG_CHECKING([whether to build Python modules])
 761 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 762 AC_MSG_RESULT([$with_python])
 763 AC_SUBST(with_python)
 764
 765 #
 766 # GSSAPI
 767 #
 768 AC_MSG_CHECKING([whether to build with GSSAPI support])
 769 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 770 [
 771   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 772   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 773 ])
 774 AC_MSG_RESULT([$with_gssapi])
 775 AC_SUBST(with_gssapi)
 776
 777
 778 AC_SUBST(krb_srvtab)
 779
 780
 781 #
 782 # Kerberos configuration parameters
 783 #
 784 PGAC_ARG_REQ(with, krb-srvnam,
 785              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 786              [],
 787              [with_krb_srvnam="postgres"])
 788 AC_SUBST(with_krb_srvnam)
 789 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 790                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 791
 792
 793 #
 794 # PAM
 795 #
 796 AC_MSG_CHECKING([whether to build with PAM support])
 797 PGAC_ARG_BOOL(with, pam, no,
 798               [build with PAM support],
 799               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 800 AC_MSG_RESULT([$with_pam])
 801
 802
 803 #
 804 # BSD AUTH
 805 #
 806 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 807 PGAC_ARG_BOOL(with, bsd-auth, no,
 808               [build with BSD Authentication support],
 809               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 810 AC_MSG_RESULT([$with_bsd_auth])
 811
 812
 813 #
 814 # LDAP
 815 #
 816 AC_MSG_CHECKING([whether to build with LDAP support])
 817 PGAC_ARG_BOOL(with, ldap, no,
 818               [build with LDAP support],
 819               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 820 AC_MSG_RESULT([$with_ldap])
 821 AC_SUBST(with_ldap)
 822
 823
 824 #
 825 # Bonjour
 826 #
 827 AC_MSG_CHECKING([whether to build with Bonjour support])
 828 PGAC_ARG_BOOL(with, bonjour, no,
 829               [build with Bonjour support],
 830               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 831 AC_MSG_RESULT([$with_bonjour])
 832
 833
 834 #
 835 # OpenSSL
 836 #
 837 AC_MSG_CHECKING([whether to build with OpenSSL support])
 838 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 839               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 840 AC_MSG_RESULT([$with_openssl])
 841 AC_SUBST(with_openssl)
 842
 843 #
 844 # SELinux
 845 #
 846 AC_MSG_CHECKING([whether to build with SELinux support])
 847 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 848 AC_SUBST(with_selinux)
 849 AC_MSG_RESULT([$with_selinux])
 850
 851 #
 852 # Systemd
 853 #
 854 AC_MSG_CHECKING([whether to build with systemd support])
 855 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 856               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 857 AC_SUBST(with_systemd)
 858 AC_MSG_RESULT([$with_systemd])
 859
 860 #
 861 # Readline
 862 #
 863 PGAC_ARG_BOOL(with, readline, yes,
 864               [do not use GNU Readline nor BSD Libedit for editing])
 865 # readline on MinGW has problems with backslashes in psql and other bugs.
 866 # This is particularly a problem with non-US code pages.
 867 # Therefore disable its use until we understand the cause. 2004-07-20
 868 if test "$PORTNAME" = "win32"; then
 869   if test "$with_readline" = yes; then
 870     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 871     with_readline=no
 872   fi
 873 fi
 874
 875
 876 #
 877 # Prefer libedit
 878 #
 879 PGAC_ARG_BOOL(with, libedit-preferred, no,
 880               [prefer BSD Libedit over GNU Readline])
 881
 882
 883 #
 884 # UUID library
 885 #
 886 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 887 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 888 # UUID library.  More than one of these might be present on a given platform,
 889 # so we make the user say which one she wants.
 890 #
 891 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 892 if test x"$with_uuid" = x"" ; then
 893   with_uuid=no
 894 fi
 895 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 896 if test "$with_ossp_uuid" = yes ; then
 897   with_uuid=ossp
 898 fi
 899
 900 if test "$with_uuid" = bsd ; then
 901   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 902   UUID_EXTRA_OBJS="md5.o sha1.o"
 903 elif test "$with_uuid" = e2fs ; then
 904   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 905   UUID_EXTRA_OBJS="md5.o sha1.o"
 906 elif test "$with_uuid" = ossp ; then
 907   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 908   UUID_EXTRA_OBJS=""
 909 elif test "$with_uuid" = no ; then
 910   UUID_EXTRA_OBJS=""
 911 else
 912   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 913 fi
 914 AC_SUBST(with_uuid)
 915 AC_SUBST(UUID_EXTRA_OBJS)
 916
 917
 918 #
 919 # XML
 920 #
 921 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 922               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 923
 924 if test "$with_libxml" = yes ; then
 925   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 926   if test -n "$XML2_CONFIG"; then
 927     for pgac_option in `$XML2_CONFIG --cflags`; do
 928       case $pgac_option in
 929         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 930       esac
 931     done
 932     for pgac_option in `$XML2_CONFIG --libs`; do
 933       case $pgac_option in
 934         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 935       esac
 936     done
 937   fi
 938 fi
 939
 940 AC_SUBST(with_libxml)
 941
 942 #
 943 # XSLT
 944 #
 945 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 946               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 947
 948
 949 AC_SUBST(with_libxslt)
 950
 951 #
 952 # tzdata
 953 #
 954 PGAC_ARG_REQ(with, system-tzdata,
 955              [DIR], [use system time zone data in DIR])
 956 AC_SUBST(with_system_tzdata)
 957
 958 #
 959 # Zlib
 960 #
 961 PGAC_ARG_BOOL(with, zlib, yes,
 962               [do not use Zlib])
 963 AC_SUBST(with_zlib)
 964
 965 #
 966 # Elf
 967 #
 968
 969 # Assume system is ELF if it predefines __ELF__ as 1,
 970 # otherwise believe host_os based default.
 971 case $host_os in
 972     freebsd1*|freebsd2*) elf=no;;
 973     freebsd3*|freebsd4*) elf=yes;;
 974 esac
 975
 976 AC_EGREP_CPP(yes,
 977 [#if __ELF__
 978   yes
 979 #endif
 980 ],
 981 [ELF_SYS=true],
 982 [if test "X$elf" = "Xyes" ; then
 983   ELF_SYS=true
 984 else
 985   ELF_SYS=
 986 fi])
 987 AC_SUBST(ELF_SYS)
 988
 989 #
 990 # Assignments
 991 #
 992
 993 CPPFLAGS="$CPPFLAGS $INCLUDES"
 994 LDFLAGS="$LDFLAGS $LIBDIRS"
 995
 996 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 997 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 998
 999 PGAC_PROG_LD
1000 AC_SUBST(LD)
1001 AC_SUBST(with_gnu_ld)
1002 AC_PROG_RANLIB
1003 PGAC_CHECK_STRIP
1004 AC_CHECK_TOOL(AR, ar, ar)
1005 if test "$PORTNAME" = "win32"; then
1006   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
1007   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
1008   AC_CHECK_TOOL(WINDRES, windres, windres)
1009 fi
1010
1011 AC_PROG_INSTALL
1012 # When Autoconf chooses install-sh as install program it tries to generate
1013 # a relative path to it in each makefile where it substitutes it. This clashes
1014 # with our Makefile.global concept. This workaround helps.
1015 case $INSTALL in
1016   *install-sh*) install_bin='';;
1017   *) install_bin=$INSTALL;;
1018 esac
1019 AC_SUBST(install_bin)
1020
1021 PGAC_PATH_PROGS(TAR, tar)
1022 AC_PROG_LN_S
1023 AC_PROG_AWK
1024 AC_PROG_MKDIR_P
1025 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
1026 # a relative path to it in each makefile where it substitutes it. This clashes
1027 # with our Makefile.global concept. This workaround helps.
1028 case $MKDIR_P in
1029   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
1030 esac
1031
1032 PGAC_PATH_BISON
1033 PGAC_PATH_FLEX
1034
1035 PGAC_PATH_PERL
1036 if test "$with_perl" = yes; then
1037   if test -z "$PERL"; then
1038     AC_MSG_ERROR([Perl not found])
1039   fi
1040   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1041   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1042     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1043 You might have to rebuild your Perl installation.  Refer to the
1044 documentation for details.  Use --without-perl to disable building
1045 PL/Perl.])
1046   fi
1047   # On most platforms, archlibexp is also where the Perl include files live ...
1048   perl_includespec="-I$perl_archlibexp/CORE"
1049   # ... but on newer macOS versions, we must use -iwithsysroot to look
1050   # under $PG_SYSROOT
1051   if test \! -f "$perl_archlibexp/CORE/perl.h" ; then
1052     if test -f "$PG_SYSROOT$perl_archlibexp/CORE/perl.h" ; then
1053       perl_includespec="-iwithsysroot $perl_archlibexp/CORE"
1054     fi
1055   fi
1056   AC_SUBST(perl_includespec)dnl
1057   PGAC_CHECK_PERL_EMBED_CCFLAGS
1058   PGAC_CHECK_PERL_EMBED_LDFLAGS
1059 fi
1060
1061 if test "$with_python" = yes; then
1062   PGAC_PATH_PYTHON
1063   PGAC_CHECK_PYTHON_EMBED_SETUP
1064 fi
1065
1066 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1067   PGAC_PATH_PROGS(ZIC, zic)
1068   if test -z "$ZIC"; then
1069     AC_MSG_ERROR([
1070 When cross-compiling, either use the option --with-system-tzdata to use
1071 existing time-zone data, or set the environment variable ZIC to a zic
1072 program to use during the build.])
1073   fi
1074 fi
1075
1076 #
1077 # Pthreads
1078 #
1079 # For each platform, we need to know about any special compile and link
1080 # libraries, and whether the normal C function names are thread-safe.
1081 # See the comment at the top of src/port/thread.c for more information.
1082 # WIN32 doesn't need the pthread tests;  it always uses threads
1083 #
1084 # These tests are run before the library-tests, because linking with the
1085 # other libraries can pull in the pthread functions as a side-effect.  We
1086 # want to use the -pthread or similar flags directly, and not rely on
1087 # the side-effects of linking with some other library.
1088 #
1089 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1090 # invocation below is the first one in the script, and autoconf generates
1091 # additional code for that, which must not be inside the if-block. AS_IF
1092 # knows how to do that.
1093 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1094 [ # then
1095 AX_PTHREAD      # set thread flags
1096
1097 # Some platforms use these, so just define them.  They can't hurt if they
1098 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1099 # enables 5-arg getpwuid_r, among other things.
1100 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1101
1102 # Check for *_r functions
1103 _CFLAGS="$CFLAGS"
1104 _LIBS="$LIBS"
1105 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1106 LIBS="$LIBS $PTHREAD_LIBS"
1107
1108 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1109 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1110
1111 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1112
1113 # Do test here with the proper thread flags
1114 PGAC_FUNC_STRERROR_R_INT
1115
1116 CFLAGS="$_CFLAGS"
1117 LIBS="$_LIBS"
1118
1119 ], [ # else
1120 # do not use values from template file
1121 PTHREAD_CFLAGS=
1122 PTHREAD_LIBS=
1123 ]) # fi
1124
1125 AC_SUBST(PTHREAD_CFLAGS)
1126 AC_SUBST(PTHREAD_LIBS)
1127
1128
1129 ##
1130 ## Libraries
1131 ##
1132 ## Most libraries are included only if they demonstrably provide a function
1133 ## we need, but libm is an exception: always include it, because there are
1134 ## too many compilers that play cute optimization games that will break
1135 ## probes for standard functions such as pow().
1136 ##
1137
1138 AC_CHECK_LIB(m, main)
1139 AC_SEARCH_LIBS(setproctitle, util)
1140 AC_SEARCH_LIBS(dlopen, dl)
1141 AC_SEARCH_LIBS(socket, [socket ws2_32])
1142 AC_SEARCH_LIBS(shl_load, dld)
1143 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1144 AC_SEARCH_LIBS(crypt, crypt)
1145 AC_SEARCH_LIBS(shm_open, rt)
1146 AC_SEARCH_LIBS(shm_unlink, rt)
1147 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1148 # Solaris:
1149 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1150 # Required for thread_test.c on Solaris
1151 AC_SEARCH_LIBS(sched_yield, rt)
1152 # Required for thread_test.c on Solaris 2.5:
1153 # Other ports use it too (HP-UX) so test unconditionally
1154 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1155 # Cygwin:
1156 AC_SEARCH_LIBS(shmget, cygipc)
1157
1158 if test "$with_readline" = yes; then
1159   PGAC_CHECK_READLINE
1160   if test x"$pgac_cv_check_readline" = x"no"; then
1161     AC_MSG_ERROR([readline library not found
1162 If you have readline already installed, see config.log for details on the
1163 failure.  It is possible the compiler isn't looking in the proper directory.
1164 Use --without-readline to disable readline support.])
1165   fi
1166 fi
1167
1168 if test "$with_zlib" = yes; then
1169   AC_CHECK_LIB(z, inflate, [],
1170                [AC_MSG_ERROR([zlib library not found
1171 If you have zlib already installed, see config.log for details on the
1172 failure.  It is possible the compiler isn't looking in the proper directory.
1173 Use --without-zlib to disable zlib support.])])
1174 fi
1175
1176 if test "$enable_spinlocks" = yes; then
1177   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1178 else
1179   AC_MSG_WARN([
1180 *** Not using spinlocks will cause poor performance.])
1181 fi
1182
1183 if test "$enable_atomics" = yes; then
1184   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1185 else
1186   AC_MSG_WARN([
1187 *** Not using atomic operations will cause poor performance.])
1188 fi
1189
1190 if test "$with_gssapi" = yes ; then
1191   if test "$PORTNAME" != "win32"; then
1192     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1193                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1194   else
1195     LIBS="$LIBS -lgssapi32"
1196   fi
1197 fi
1198
1199 if test "$with_openssl" = yes ; then
1200   dnl Order matters!
1201   if test "$PORTNAME" != "win32"; then
1202      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1203      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1204   else
1205      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1206      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1207   fi
1208   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1209   # Functions introduced in OpenSSL 1.1.0. We used to check for
1210   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1211   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1212   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1213   # functions.
1214   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1215   # OpenSSL versions before 1.1.0 required setting callback functions, for
1216   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1217   # function was removed.
1218   AC_CHECK_FUNCS([CRYPTO_lock])
1219 fi
1220
1221 if test "$with_pam" = yes ; then
1222   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1223 fi
1224
1225 if test "$with_libxml" = yes ; then
1226   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1227 fi
1228
1229 if test "$with_libxslt" = yes ; then
1230   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1231 fi
1232
1233 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1234 if test "$with_ldap" = yes ; then
1235   _LIBS="$LIBS"
1236   if test "$PORTNAME" != "win32"; then
1237     AC_CHECK_LIB(ldap, ldap_bind, [],
1238                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1239                  [$EXTRA_LDAP_LIBS])
1240     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1241     if test "$enable_thread_safety" = yes; then
1242       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1243       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1244                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1245                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1246       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1247     else
1248       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1249     fi
1250     AC_CHECK_FUNCS([ldap_initialize])
1251   else
1252     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1253     LDAP_LIBS_FE="-lwldap32"
1254     LDAP_LIBS_BE="-lwldap32"
1255   fi
1256   LIBS="$_LIBS"
1257 fi
1258 AC_SUBST(LDAP_LIBS_FE)
1259 AC_SUBST(LDAP_LIBS_BE)
1260
1261 # for contrib/sepgsql
1262 if test "$with_selinux" = yes; then
1263   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1264                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1265 fi
1266
1267 # for contrib/uuid-ossp
1268 if test "$with_uuid" = bsd ; then
1269   # On BSD, the UUID functions are in libc
1270   AC_CHECK_FUNC(uuid_to_string,
1271     [UUID_LIBS=""],
1272     [AC_MSG_ERROR([BSD UUID functions are not present])])
1273 elif test "$with_uuid" = e2fs ; then
1274   # On macOS, the UUID functions are in libc
1275   AC_CHECK_FUNC(uuid_generate,
1276     [UUID_LIBS=""],
1277     [AC_CHECK_LIB(uuid, uuid_generate,
1278       [UUID_LIBS="-luuid"],
1279       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1280 elif test "$with_uuid" = ossp ; then
1281   AC_CHECK_LIB(ossp-uuid, uuid_export,
1282     [UUID_LIBS="-lossp-uuid"],
1283     [AC_CHECK_LIB(uuid, uuid_export,
1284       [UUID_LIBS="-luuid"],
1285       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1286 fi
1287 AC_SUBST(UUID_LIBS)
1288
1289
1290 ##
1291 ## Header files
1292 ##
1293
1294 AC_HEADER_STDBOOL
1295
1296 AC_CHECK_HEADERS(m4_normalize([
1297         atomic.h
1298         copyfile.h
1299         crypt.h
1300         fp_class.h
1301         getopt.h
1302         ieeefp.h
1303         ifaddrs.h
1304         langinfo.h
1305         mbarrier.h
1306         poll.h
1307         sys/epoll.h
1308         sys/ipc.h
1309         sys/prctl.h
1310         sys/procctl.h
1311         sys/pstat.h
1312         sys/resource.h
1313         sys/select.h
1314         sys/sem.h
1315         sys/shm.h
1316         sys/sockio.h
1317         sys/tas.h
1318         sys/un.h
1319         termios.h
1320         ucred.h
1321         utime.h
1322         wchar.h
1323         wctype.h
1324 ]))
1325
1326 # On BSD, test for net/if.h will fail unless sys/socket.h
1327 # is included first.
1328 AC_CHECK_HEADERS(net/if.h, [], [],
1329 [AC_INCLUDES_DEFAULT
1330 #include <sys/socket.h>
1331 ])
1332
1333 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1334 # is included first.
1335 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1336 [AC_INCLUDES_DEFAULT
1337 #include <sys/param.h>
1338 ])
1339
1340 # At least on IRIX, test for netinet/tcp.h will fail unless
1341 # netinet/in.h is included first.
1342 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1343 [AC_INCLUDES_DEFAULT
1344 #include <netinet/in.h>
1345 ])
1346
1347 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1348   AC_CHECK_HEADERS(readline/readline.h, [],
1349         [AC_CHECK_HEADERS(readline.h, [],
1350                 [AC_MSG_ERROR([readline header not found
1351 If you have readline already installed, see config.log for details on the
1352 failure.  It is possible the compiler isn't looking in the proper directory.
1353 Use --without-readline to disable readline support.])])])
1354   AC_CHECK_HEADERS(readline/history.h, [],
1355         [AC_CHECK_HEADERS(history.h, [],
1356                 [AC_MSG_ERROR([history header not found
1357 If you have readline already installed, see config.log for details on the
1358 failure.  It is possible the compiler isn't looking in the proper directory.
1359 Use --without-readline to disable readline support.])])])
1360 fi
1361
1362 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1363 # Some installations of libedit usurp /usr/include/readline/, which seems
1364 # bad practice, since in combined installations readline will have its headers
1365 # there.  We might have to resort to AC_EGREP checks to make sure we found
1366 # the proper header...
1367   AC_CHECK_HEADERS(editline/readline.h, [],
1368         [AC_CHECK_HEADERS(readline.h, [],
1369                 [AC_CHECK_HEADERS(readline/readline.h, [],
1370                         [AC_MSG_ERROR([readline header not found
1371 If you have libedit already installed, see config.log for details on the
1372 failure.  It is possible the compiler isn't looking in the proper directory.
1373 Use --without-readline to disable libedit support.])])])])
1374 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1375 # not be there at all.  Hence, don't complain if not found.  We must check
1376 # though, since in yet other versions it is an independent header.
1377   AC_CHECK_HEADERS(editline/history.h, [],
1378         [AC_CHECK_HEADERS(history.h, [],
1379                 [AC_CHECK_HEADERS(readline/history.h)])])
1380 fi
1381
1382 if test "$with_zlib" = yes; then
1383   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1384 If you have zlib already installed, see config.log for details on the
1385 failure.  It is possible the compiler isn't looking in the proper directory.
1386 Use --without-zlib to disable zlib support.])])
1387 fi
1388
1389 if test "$with_gssapi" = yes ; then
1390   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1391         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1392 fi
1393
1394 if test "$with_openssl" = yes ; then
1395   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1396   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1397 fi
1398
1399 if test "$with_pam" = yes ; then
1400   AC_CHECK_HEADERS(security/pam_appl.h, [],
1401                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1402                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1403 fi
1404
1405 if test "$with_bsd_auth" = yes ; then
1406   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1407 fi
1408
1409 if test "$with_systemd" = yes ; then
1410   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1411 fi
1412
1413 if test "$with_libxml" = yes ; then
1414   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1415 fi
1416
1417 if test "$with_libxslt" = yes ; then
1418   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1419 fi
1420
1421 if test "$with_ldap" = yes ; then
1422   if test "$PORTNAME" != "win32"; then
1423      AC_CHECK_HEADERS(ldap.h, [],
1424                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1425      PGAC_LDAP_SAFE
1426   else
1427      AC_CHECK_HEADERS(winldap.h, [],
1428                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1429                       [AC_INCLUDES_DEFAULT
1430 #include <windows.h>
1431                       ])
1432   fi
1433 fi
1434
1435 if test "$with_bonjour" = yes ; then
1436   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1437 dnl At some point we might add something like
1438 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1439 dnl but right now, what that would mainly accomplish is to encourage
1440 dnl people to try to use the avahi implementation, which does not work.
1441 dnl If you want to use Apple's own Bonjour code on another platform,
1442 dnl just add -ldns_sd to LIBS manually.
1443 fi
1444
1445 # for contrib/uuid-ossp
1446 if test "$with_uuid" = bsd ; then
1447   AC_CHECK_HEADERS(uuid.h,
1448     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1449       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1450     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1451 elif test "$with_uuid" = e2fs ; then
1452   AC_CHECK_HEADERS(uuid/uuid.h,
1453     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1454       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1455     [AC_CHECK_HEADERS(uuid.h,
1456       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1457         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1458       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1459 elif test "$with_uuid" = ossp ; then
1460   AC_CHECK_HEADERS(ossp/uuid.h,
1461     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1462       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1463     [AC_CHECK_HEADERS(uuid.h,
1464       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1465         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1466       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1467 fi
1468
1469 if test "$PORTNAME" = "win32" ; then
1470    AC_CHECK_HEADERS(crtdefs.h)
1471 fi
1472
1473 ##
1474 ## Types, structures, compiler characteristics
1475 ##
1476
1477 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1478 AC_C_BIGENDIAN
1479 AC_C_INLINE
1480 PGAC_PRINTF_ARCHETYPE
1481 AC_C_FLEXIBLE_ARRAY_MEMBER
1482 PGAC_C_SIGNED
1483 PGAC_C_FUNCNAME_SUPPORT
1484 PGAC_C_STATIC_ASSERT
1485 PGAC_C_TYPEOF
1486 PGAC_C_TYPES_COMPATIBLE
1487 PGAC_C_BUILTIN_BSWAP16
1488 PGAC_C_BUILTIN_BSWAP32
1489 PGAC_C_BUILTIN_BSWAP64
1490 PGAC_C_BUILTIN_CONSTANT_P
1491 PGAC_C_BUILTIN_UNREACHABLE
1492 PGAC_C_COMPUTED_GOTO
1493 PGAC_STRUCT_TIMEZONE
1494 PGAC_UNION_SEMUN
1495 PGAC_STRUCT_SOCKADDR_UN
1496 PGAC_STRUCT_SOCKADDR_STORAGE
1497 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1498 PGAC_STRUCT_ADDRINFO
1499 AC_TYPE_INTPTR_T
1500 AC_TYPE_UINTPTR_T
1501 AC_TYPE_LONG_LONG_INT
1502
1503 PGAC_TYPE_LOCALE_T
1504
1505 # MSVC doesn't cope well with defining restrict to __restrict, the
1506 # spelling it understands, because it conflicts with
1507 # __declspec(restrict). Therefore we define pg_restrict to the
1508 # appropriate definition, which presumably won't conflict.
1509 #
1510 # Allow platforms with buggy compilers to force restrict to not be
1511 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1512 # template.
1513 AC_C_RESTRICT
1514 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1515   pg_restrict=""
1516 else
1517   pg_restrict="$ac_cv_c_restrict"
1518 fi
1519 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1520 [Define to keyword to use for C99 restrict support, or to nothing if not
1521 supported])
1522
1523 AC_CHECK_TYPES([struct cmsgcred], [], [],
1524 [#include <sys/socket.h>
1525 #include <sys/param.h>
1526 #ifdef HAVE_SYS_UCRED_H
1527 #include <sys/ucred.h>
1528 #endif])
1529
1530 AC_CHECK_TYPES([struct option], [], [],
1531 [#ifdef HAVE_GETOPT_H
1532 #include <getopt.h>
1533 #endif])
1534
1535 if test "$with_zlib" = yes; then
1536   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1537   # did not).  While we could work around the lack of z_streamp, it
1538   # seems unwise to encourage people to use such old zlib versions...
1539   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1540 Use --without-zlib to disable zlib support.])],
1541                 [#include <zlib.h>])
1542 fi
1543
1544 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1545 case $host_cpu in
1546   ppc*|powerpc*)
1547     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1548     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1549         [int a = 0; int *p = &a; int r;
1550          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1551         [pgac_cv_have_ppc_mutex_hint=yes],
1552         [pgac_cv_have_ppc_mutex_hint=no])
1553     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1554     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1555         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1556     fi
1557   ;;
1558 esac
1559
1560 # Check largefile support.  You might think this is a system service not a
1561 # compiler characteristic, but you'd be wrong.  We must check this before
1562 # probing existence of related functions such as fseeko, since the largefile
1563 # defines can affect what is generated for that.
1564 if test "$PORTNAME" != "win32"; then
1565    AC_SYS_LARGEFILE
1566    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1567    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1568    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1569    dnl versions where the feature actually works, it's on by default anyway.
1570    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1571 fi
1572
1573 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1574 AC_CHECK_SIZEOF([off_t])
1575
1576 # If we don't have largefile support, can't handle segsize >= 2GB.
1577 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1578    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1579 fi
1580
1581 AC_CHECK_SIZEOF([bool], [],
1582 [#ifdef HAVE_STDBOOL_H
1583 #include <stdbool.h>
1584 #endif])
1585
1586
1587 ##
1588 ## Functions, global variables
1589 ##
1590
1591 PGAC_VAR_INT_TIMEZONE
1592 AC_FUNC_ACCEPT_ARGTYPES
1593 PGAC_FUNC_GETTIMEOFDAY_1ARG
1594 PGAC_FUNC_WCSTOMBS_L
1595
1596 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1597 # symbols that that library has no business exposing to the world.  Pending
1598 # acquisition of a clue by those developers, ignore libedit (including its
1599 # possible alias of libreadline) while checking for everything else.
1600 LIBS_including_readline="$LIBS"
1601 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1602
1603 AC_CHECK_FUNCS(m4_normalize([
1604         cbrt
1605         clock_gettime
1606         copyfile
1607         fdatasync
1608         getifaddrs
1609         getpeerucred
1610         getrlimit
1611         mbstowcs_l
1612         memmove
1613         poll
1614         posix_fallocate
1615         ppoll
1616         pstat
1617         pthread_is_threaded_np
1618         readlink
1619         setproctitle
1620         setproctitle_fast
1621         setsid
1622         shm_open
1623         strchrnul
1624         symlink
1625         sync_file_range
1626         utime
1627         utimes
1628         wcstombs_l
1629 ]))
1630
1631 AC_REPLACE_FUNCS(fseeko)
1632 case $host_os in
1633         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1634         # Mingw uses macros to access Win32 API calls
1635         netbsd*|mingw*)
1636                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1637                 ac_cv_func_fseeko=yes;;
1638         *)
1639                 AC_FUNC_FSEEKO;;
1640 esac
1641
1642 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1643 # by calling it, 2009-04-02
1644 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1645 if test "$PORTNAME" != "solaris"; then
1646 AC_CHECK_FUNCS(posix_fadvise)
1647 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1648 fi
1649
1650 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1651 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1652 # This is probably only present on macOS, but may as well check always
1653 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1654
1655 AC_CHECK_DECLS([RTLD_GLOBAL, RTLD_NOW], [], [], [#include <dlfcn.h>])
1656
1657 AC_CHECK_TYPE([struct sockaddr_in6],
1658         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])],
1659         [],
1660 [$ac_includes_default
1661 #include <netinet/in.h>])
1662
1663 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1664 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1665 [#include <machine/vmparam.h>
1666 #include <sys/exec.h>
1667 ],
1668 [PS_STRINGS->ps_nargvstr = 1;
1669 PS_STRINGS->ps_argvstr = "foo";])],
1670 [pgac_cv_var_PS_STRINGS=yes],
1671 [pgac_cv_var_PS_STRINGS=no])])
1672 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1673   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1674 fi
1675
1676
1677 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1678 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1679 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1680 #include <math.h>
1681 double glob_double;
1682 ],
1683 [return isinf(glob_double) ? 0 : 1;])],
1684 [ac_cv_func_isinf=yes],
1685 [ac_cv_func_isinf=no])])
1686
1687 if test $ac_cv_func_isinf = yes ; then
1688   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1689 else
1690   AC_LIBOBJ(isinf)
1691   # Look for a way to implement a substitute for isinf()
1692   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1693 fi
1694
1695 AC_REPLACE_FUNCS(m4_normalize([
1696         crypt
1697         dlopen
1698         fls
1699         getopt
1700         getrusage
1701         inet_aton
1702         mkdtemp
1703         pread
1704         pwrite
1705         random
1706         rint
1707         srandom
1708         strlcat
1709         strlcpy
1710         strnlen
1711 ]))
1712
1713 case $host_os in
1714
1715         # Windows uses a specialised env handler
1716         # and doesn't need a replacement getpeereid because it doesn't use
1717         # Unix sockets.
1718         mingw*)
1719                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1720                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1721                 ac_cv_func_unsetenv=yes
1722                 ac_cv_func_getpeereid=yes;;
1723         *)
1724                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1725                 ;;
1726 esac
1727
1728 # System's version of getaddrinfo(), if any, may be used only if we found
1729 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1730 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1731 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1732    test "$PORTNAME" != "win32"; then
1733   AC_REPLACE_FUNCS([getaddrinfo])
1734 else
1735   AC_LIBOBJ(getaddrinfo)
1736 fi
1737
1738 # Similarly, use system's getopt_long() only if system provides struct option.
1739 if test x"$ac_cv_type_struct_option" = xyes ; then
1740   AC_REPLACE_FUNCS([getopt_long])
1741 else
1742   AC_LIBOBJ(getopt_long)
1743 fi
1744
1745 # Solaris' getopt() doesn't do what we want for long options, so always use
1746 # our version on that platform.
1747 if test "$PORTNAME" = "solaris"; then
1748   AC_LIBOBJ(getopt)
1749 fi
1750
1751 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1752 # so always use our version on Windows.
1753 if test "$PORTNAME" = "win32"; then
1754   AC_LIBOBJ(getopt)
1755   AC_LIBOBJ(getopt_long)
1756 fi
1757
1758 # Win32 (really MinGW) support
1759 if test "$PORTNAME" = "win32"; then
1760   AC_REPLACE_FUNCS(gettimeofday)
1761   AC_LIBOBJ(dirmod)
1762   AC_LIBOBJ(kill)
1763   AC_LIBOBJ(open)
1764   AC_LIBOBJ(system)
1765   AC_LIBOBJ(win32env)
1766   AC_LIBOBJ(win32error)
1767   AC_LIBOBJ(win32security)
1768   AC_LIBOBJ(win32setlocale)
1769   AC_DEFINE([HAVE_SYMLINK], 1,
1770             [Define to 1 if you have the `symlink' function.])
1771   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1772 #define WIN32_LEAN_AND_MEAN
1773 #include <windows.h>
1774 #include <string.h>
1775 #include <dbghelp.h>])
1776 fi
1777 if test x"$pgac_minidump_type" = x"yes" ; then
1778   AC_SUBST(have_win32_dbghelp,yes)
1779 else
1780   AC_SUBST(have_win32_dbghelp,no)
1781 fi
1782
1783 # Cygwin needs only a bit of that
1784 if test "$PORTNAME" = "cygwin"; then
1785   AC_LIBOBJ(dirmod)
1786 fi
1787
1788 AC_CHECK_DECLS([sys_siglist], [], [],
1789 [#include <signal.h>
1790 /* NetBSD declares sys_siglist in unistd.h.  */
1791 #ifdef HAVE_UNISTD_H
1792 # include <unistd.h>
1793 #endif
1794 ])
1795
1796 AC_CHECK_FUNC(syslog,
1797               [AC_CHECK_HEADER(syslog.h,
1798                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1799
1800 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1801 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1802   [extern int opterr; opterr = 1;])],
1803   [pgac_cv_var_int_opterr=yes],
1804   [pgac_cv_var_int_opterr=no])])
1805 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1806   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1807 fi
1808
1809 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1810 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1811   [extern int optreset; optreset = 1;])],
1812   [pgac_cv_var_int_optreset=yes],
1813   [pgac_cv_var_int_optreset=no])])
1814 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1815   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1816 fi
1817
1818 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1819 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1820 # strto[u]ll may exist but not be declared
1821 AC_CHECK_DECLS([strtoll, strtoull])
1822
1823 if test "$with_icu" = yes; then
1824   ac_save_CPPFLAGS=$CPPFLAGS
1825   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1826
1827   # Verify we have ICU's header files
1828   AC_CHECK_HEADER(unicode/ucol.h, [],
1829         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1830
1831   CPPFLAGS=$ac_save_CPPFLAGS
1832 fi
1833
1834 # Lastly, restore full LIBS list and check for readline/libedit symbols
1835 LIBS="$LIBS_including_readline"
1836
1837 if test "$with_readline" = yes; then
1838   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1839   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1840   AC_CHECK_FUNCS([append_history history_truncate_file])
1841 fi
1842
1843
1844 # This test makes sure that run tests work at all.  Sometimes a shared
1845 # library is found by the linker, but the runtime linker can't find it.
1846 # This check should come after all modifications of compiler or linker
1847 # variables, and before any other run tests.
1848 AC_MSG_CHECKING([test program])
1849 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1850 [AC_MSG_RESULT(ok)],
1851 [AC_MSG_RESULT(failed)
1852 AC_MSG_ERROR([[
1853 Could not execute a simple test program.  This may be a problem
1854 related to locating shared libraries.  Check the file 'config.log'
1855 for the exact reason.]])],
1856 [AC_MSG_RESULT([cross-compiling])])
1857
1858 # --------------------
1859 # Run tests below here
1860 # --------------------
1861
1862 dnl Check to see if we have a working 64-bit integer type.
1863 dnl Since Postgres 8.4, we no longer support compilers without a working
1864 dnl 64-bit type; but we have to determine whether that type is called
1865 dnl "long int" or "long long int".
1866
1867 PGAC_TYPE_64BIT_INT([long int])
1868
1869 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1870   pg_int64_type="long int"
1871 else
1872   PGAC_TYPE_64BIT_INT([long long int])
1873   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1874     pg_int64_type="long long int"
1875   else
1876     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1877   fi
1878 fi
1879
1880 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1881   [Define to the name of a signed 64-bit integer type.])
1882
1883 # Select the printf length modifier that goes with that, too.
1884 if test x"$pg_int64_type" = x"long long int" ; then
1885   INT64_MODIFIER='"ll"'
1886 else
1887   INT64_MODIFIER='"l"'
1888 fi
1889
1890 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1891                    [Define to the appropriate printf length modifier for 64-bit ints.])
1892
1893 # has to be down here, rather than with the other builtins, because
1894 # the test uses PG_INT64_TYPE.
1895 PGAC_C_BUILTIN_OP_OVERFLOW
1896
1897 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1898 AC_CHECK_SIZEOF([void *])
1899 AC_CHECK_SIZEOF([size_t])
1900 AC_CHECK_SIZEOF([long])
1901
1902 # Decide whether float4 is passed by value: user-selectable, enabled by default
1903 AC_MSG_CHECKING([whether to build with float4 passed by value])
1904 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1905               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1906                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1907                float4passbyval=true],
1908               [float4passbyval=false])
1909 AC_MSG_RESULT([$enable_float4_byval])
1910 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1911
1912 # Decide whether float8 is passed by value.
1913 # Note: this setting also controls int8 and related types such as timestamp.
1914 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1915 # If not, trying to select it is an error.
1916 AC_MSG_CHECKING([whether to build with float8 passed by value])
1917 if test $ac_cv_sizeof_void_p -ge 8 ; then
1918   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1919 else
1920   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1921   if test "$enable_float8_byval" = yes ; then
1922     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1923   fi
1924 fi
1925 if test "$enable_float8_byval" = yes ; then
1926   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1927             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1928   float8passbyval=true
1929 else
1930   float8passbyval=false
1931 fi
1932 AC_MSG_RESULT([$enable_float8_byval])
1933 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1934
1935 # Determine memory alignment requirements for the basic C data types.
1936
1937 AC_CHECK_ALIGNOF(short)
1938 AC_CHECK_ALIGNOF(int)
1939 AC_CHECK_ALIGNOF(long)
1940 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1941   AC_CHECK_ALIGNOF(long long int)
1942 fi
1943 AC_CHECK_ALIGNOF(double)
1944
1945 # Compute maximum alignment of any basic type.
1946 # We assume long's alignment is at least as strong as char, short, or int;
1947 # but we must check long long (if it is being used for int64) and double.
1948 # Note that we intentionally do not consider any types wider than 64 bits,
1949 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1950 # for disk and memory space.
1951
1952 MAX_ALIGNOF=$ac_cv_alignof_long
1953 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1954   MAX_ALIGNOF=$ac_cv_alignof_double
1955 fi
1956 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1957   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1958 fi
1959 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1960
1961
1962 # Some platforms predefine the types int8, int16, etc.  Only check
1963 # a (hopefully) representative subset.
1964 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1965 [#include <stdio.h>])
1966
1967 # Some compilers offer a 128-bit integer scalar type.
1968 PGAC_TYPE_128BIT_INT
1969
1970 # Check for various atomic operations now that we have checked how to declare
1971 # 64bit integers.
1972 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1973 PGAC_HAVE_GCC__SYNC_INT32_TAS
1974 PGAC_HAVE_GCC__SYNC_INT32_CAS
1975 PGAC_HAVE_GCC__SYNC_INT64_CAS
1976 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1977 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1978
1979
1980 # Check for x86 cpuid instruction
1981 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1982 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1983   [[unsigned int exx[4] = {0, 0, 0, 0};
1984   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1985   ]])],
1986   [pgac_cv__get_cpuid="yes"],
1987   [pgac_cv__get_cpuid="no"])])
1988 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1989   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1990 fi
1991
1992 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1993 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
1994   [[unsigned int exx[4] = {0, 0, 0, 0};
1995   __get_cpuid(exx[0], 1);
1996   ]])],
1997   [pgac_cv__cpuid="yes"],
1998   [pgac_cv__cpuid="no"])])
1999 if test x"$pgac_cv__cpuid" = x"yes"; then
2000   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
2001 fi
2002
2003 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
2004 #
2005 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
2006 # with the default compiler flags. If not, check if adding the -msse4.2
2007 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
2008 PGAC_SSE42_CRC32_INTRINSICS([])
2009 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
2010   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
2011 fi
2012 AC_SUBST(CFLAGS_SSE42)
2013
2014 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
2015 # define __SSE4_2__ in that case.
2016 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2017 #ifndef __SSE4_2__
2018 #error __SSE4_2__ not defined
2019 #endif
2020 ])], [SSE4_2_TARGETED=1])
2021
2022 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
2023 #
2024 # First check if __crc32c* intrinsics can be used with the default compiler
2025 # flags. If not, check if adding -march=armv8-a+crc flag helps.
2026 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
2027 PGAC_ARMV8_CRC32C_INTRINSICS([])
2028 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
2029   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
2030 fi
2031 AC_SUBST(CFLAGS_ARMV8_CRC32C)
2032
2033 # Select CRC-32C implementation.
2034 #
2035 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
2036 # use the special CRC instructions for calculating CRC-32C. If we're not
2037 # targeting such a processor, but we can nevertheless produce code that uses
2038 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2039 # implementations and select which one to use at runtime, depending on whether
2040 # SSE 4.2 is supported by the processor we're running on.
2041 #
2042 # Similarly, if we are targeting an ARM processor that has the CRC
2043 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2044 # we're not targeting such a processor, but can nevertheless produce code that
2045 # uses the CRC instructions, compile both, and select at runtime.
2046 #
2047 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2048 # in the template or configure command line.
2049 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2050   # Use Intel SSE 4.2 if available.
2051   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2052     USE_SSE42_CRC32C=1
2053   else
2054     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2055     # the runtime check.
2056     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2057       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2058     else
2059       # Use ARM CRC Extension if available.
2060       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2061         USE_ARMV8_CRC32C=1
2062       else
2063         # ARM CRC Extension, with runtime check?
2064         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2065           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2066         else
2067           # fall back to slicing-by-8 algorithm, which doesn't require any
2068           # special CPU support.
2069           USE_SLICING_BY_8_CRC32C=1
2070         fi
2071       fi
2072     fi
2073   fi
2074 fi
2075
2076 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2077 AC_MSG_CHECKING([which CRC-32C implementation to use])
2078 if test x"$USE_SSE42_CRC32C" = x"1"; then
2079   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2080   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2081   AC_MSG_RESULT(SSE 4.2)
2082 else
2083   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2084     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2085     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2086     AC_MSG_RESULT(SSE 4.2 with runtime check)
2087   else
2088     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2089       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2090       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2091       AC_MSG_RESULT(ARMv8 CRC instructions)
2092     else
2093       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2094         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2095         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2096         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2097       else
2098         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2099         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2100         AC_MSG_RESULT(slicing-by-8)
2101       fi
2102     fi
2103   fi
2104 fi
2105 AC_SUBST(PG_CRC32C_OBJS)
2106
2107
2108 # Select semaphore implementation type.
2109 if test "$PORTNAME" != "win32"; then
2110   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2111     # Need sem_open for this
2112     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2113   fi
2114   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2115     # Need sem_init for this
2116     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2117   fi
2118   AC_MSG_CHECKING([which semaphore API to use])
2119   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2120     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2121     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2122     sematype="named POSIX"
2123   else
2124     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2125       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2126       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2127       sematype="unnamed POSIX"
2128     else
2129       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2130       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2131       sematype="System V"
2132     fi
2133   fi
2134   AC_MSG_RESULT([$sematype])
2135 else
2136   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2137   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2138 fi
2139
2140
2141 # Select shared-memory implementation type.
2142 if test "$PORTNAME" != "win32"; then
2143   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2144   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2145 else
2146   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2147   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2148 fi
2149
2150 # Select random number source
2151 #
2152 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2153 # in the template or configure command line.
2154
2155 # If not selected manually, try to select a source automatically.
2156 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2157   if test x"$with_openssl" = x"yes" ; then
2158     USE_OPENSSL_RANDOM=1
2159   elif test "$PORTNAME" = "win32" ; then
2160     USE_WIN32_RANDOM=1
2161   else
2162     AC_CHECK_FILE([/dev/urandom], [], [])
2163
2164     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2165       USE_DEV_URANDOM=1
2166     fi
2167   fi
2168 fi
2169
2170 AC_MSG_CHECKING([which random number source to use])
2171 if test "$enable_strong_random" = yes ; then
2172   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2173     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2174     AC_MSG_RESULT([OpenSSL])
2175   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2176     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2177     AC_MSG_RESULT([Windows native])
2178   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2179     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2180     AC_MSG_RESULT([/dev/urandom])
2181   else
2182     AC_MSG_ERROR([
2183 no source of strong random numbers was found
2184 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2185 for authentication protocols. You can use --disable-strong-random to use a
2186 built-in pseudo random number generator, but that may be insecure.])
2187   fi
2188   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2189 else
2190     AC_MSG_RESULT([weak builtin PRNG])
2191     AC_MSG_WARN([
2192 *** Not using a strong random number source may be insecure.])
2193 fi
2194
2195 # If not set in template file, set bytes to use libc memset()
2196 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2197   MEMSET_LOOP_LIMIT=1024
2198 fi
2199 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2200
2201
2202 if test "$enable_nls" = yes ; then
2203   PGAC_CHECK_GETTEXT
2204 fi
2205
2206 # Check for Tcl configuration script tclConfig.sh
2207 if test "$with_tcl" = yes; then
2208     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2209     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2210                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2211     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2212     if test "$TCL_SHARED_BUILD" != 1; then
2213       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2214 Use --without-tcl to disable building PL/Tcl.])
2215     fi
2216     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2217     ac_save_CPPFLAGS=$CPPFLAGS
2218     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2219     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2220     CPPFLAGS=$ac_save_CPPFLAGS
2221 fi
2222
2223 # check for <perl.h>
2224 if test "$with_perl" = yes; then
2225   ac_save_CPPFLAGS=$CPPFLAGS
2226   CPPFLAGS="$CPPFLAGS $perl_includespec"
2227   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2228                   [#include <EXTERN.h>])
2229   # While we're at it, check that we can link to libperl.
2230   # On most platforms, if perl.h is there then libperl.so will be too, but at
2231   # this writing Debian packages them separately.  There is no known reason to
2232   # waste cycles on separate probes for the Tcl or Python libraries, though.
2233   pgac_save_LIBS=$LIBS
2234   LIBS="$perl_embed_ldflags"
2235   AC_MSG_CHECKING([for libperl])
2236   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2237 #include <EXTERN.h>
2238 #include <perl.h>
2239 ],  [perl_alloc();])],
2240     [AC_MSG_RESULT(yes)],
2241     [AC_MSG_RESULT(no)
2242      AC_MSG_ERROR([libperl library is required for Perl])])
2243   LIBS=$pgac_save_LIBS
2244   CPPFLAGS=$ac_save_CPPFLAGS
2245 fi
2246
2247 # check for <Python.h>
2248 if test "$with_python" = yes; then
2249   ac_save_CPPFLAGS=$CPPFLAGS
2250   CPPFLAGS="$python_includespec $CPPFLAGS"
2251   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2252   CPPFLAGS=$ac_save_CPPFLAGS
2253 fi
2254
2255 #
2256 # Check for DocBook and tools
2257 #
2258 PGAC_PATH_XMLLINT
2259 PGAC_CHECK_DOCBOOK(4.2)
2260 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2261 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2262 PGAC_PATH_PROGS(FOP, fop)
2263
2264 #
2265 # Check for test tools
2266 #
2267 if test "$enable_tap_tests" = yes; then
2268   # Check for necessary modules, unless user has specified the "prove" to use;
2269   # in that case it's her responsibility to have a working configuration.
2270   # (prove might be part of a different Perl installation than perl, eg on
2271   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2272   if test -z "$PROVE"; then
2273     # Test::More and Time::HiRes are supposed to be part of core Perl,
2274     # but some distros omit them in a minimal installation.
2275     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2276       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2277   fi
2278   # Now make sure we know where prove is
2279   PGAC_PATH_PROGS(PROVE, prove)
2280   if test -z "$PROVE"; then
2281     AC_MSG_ERROR([prove not found])
2282   fi
2283 fi
2284
2285 # Thread testing
2286
2287 # We have to run the thread test near the end so we have all our symbols
2288 # defined.  Cross compiling throws a warning.
2289 #
2290 if test "$enable_thread_safety" = yes; then
2291 if test "$PORTNAME" != "win32"
2292 then
2293 AC_MSG_CHECKING([thread safety of required library functions])
2294
2295 _CFLAGS="$CFLAGS"
2296 _LIBS="$LIBS"
2297 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2298 LIBS="$LIBS $PTHREAD_LIBS"
2299 AC_RUN_IFELSE(
2300   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2301   [AC_MSG_RESULT(yes)],
2302   [AC_MSG_RESULT(no)
2303   AC_MSG_ERROR([thread test program failed
2304 This platform is not thread-safe.  Check the file 'config.log' or compile
2305 and run src/test/thread/thread_test for the exact reason.
2306 Use --disable-thread-safety to disable thread safety.])],
2307   [AC_MSG_RESULT(maybe)
2308   AC_MSG_WARN([
2309 *** Skipping thread test program because of cross-compile build.
2310 *** Run the program in src/test/thread on the target machine.
2311 ])])
2312 CFLAGS="$_CFLAGS"
2313 LIBS="$_LIBS"
2314 else
2315 AC_MSG_WARN([*** skipping thread test on Win32])
2316 fi
2317 fi
2318
2319 # If compiler will take -Wl,--as-needed (or various platform-specific
2320 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2321 # trying to filter LIBS to the minimum for each executable.
2322 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2323 # libreadline; therefore we postpone testing it until we know what library
2324 # dependencies readline has.  The test code will try to link with $LIBS.
2325 if test "$with_readline" = yes; then
2326   link_test_func=readline
2327 else
2328   link_test_func=exit
2329 fi
2330
2331 if test "$PORTNAME" = "darwin"; then
2332   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2333 elif test "$PORTNAME" = "openbsd"; then
2334   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2335 else
2336   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2337 fi
2338
2339 # Create compiler version string
2340 if test x"$GCC" = x"yes" ; then
2341   cc_string=`${CC} --version | sed q`
2342   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2343 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2344   cc_string=`${CC} -V 2>&1 | sed q`
2345 else
2346   cc_string=$CC
2347 fi
2348
2349 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2350                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2351                    [A string containing the version number, platform, and C compiler])
2352
2353 # Supply a numeric version string for use by 3rd party add-ons
2354 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2355 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2356 tr '.' '        ' |
2357 $AWK '{printf "%d%04d", $1, $2}'`"]
2358 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2359 AC_SUBST(PG_VERSION_NUM)
2360
2361 # If we are inserting PG_SYSROOT into CPPFLAGS, do so symbolically not
2362 # literally, so that it's possible to override it at build time using
2363 # a command like "make ... PG_SYSROOT=path".  This has to be done after
2364 # we've finished all configure checks that depend on CPPFLAGS.
2365 if test x"$PG_SYSROOT" != x; then
2366   CPPFLAGS=`echo "$CPPFLAGS" | sed -e "s| $PG_SYSROOT | \\\$(PG_SYSROOT) |"`
2367 fi
2368 AC_SUBST(PG_SYSROOT)
2369
2370
2371 # Begin output steps
2372
2373 AC_MSG_NOTICE([using compiler=$cc_string])
2374 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2375 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2376 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2377 # Currently only used when LLVM is used
2378 if test "$with_llvm" = yes ; then
2379    AC_MSG_NOTICE([using CXX=$CXX])
2380    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2381    AC_MSG_NOTICE([using CLANG=$CLANG])
2382    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2383    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2384 fi
2385
2386 # prepare build tree if outside source tree
2387 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2388 # Note 2: /bin/pwd might be better than shell's built-in at getting
2389 #         a symlink-free name.
2390 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2391   vpath_build=no
2392 else
2393   vpath_build=yes
2394   if test "$no_create" != yes; then
2395     _AS_ECHO_N([preparing build tree... ])
2396     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2397     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2398       || AC_MSG_ERROR(failed)
2399     AC_MSG_RESULT(done)
2400   fi
2401 fi
2402 AC_SUBST(vpath_build)
2403
2404
2405 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2406
2407 AC_CONFIG_LINKS([
2408   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2409   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2410   src/include/pg_config_os.h:src/include/port/${template}.h
2411   src/Makefile.port:src/makefiles/Makefile.${template}
2412 ])
2413
2414 if test "$PORTNAME" = "win32"; then
2415 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2416 # Links sometimes fail undetected on Mingw -
2417 # so here we detect it and warn the user
2418 for FILE in $CONFIG_LINKS
2419  do
2420         # test -e works for symlinks in the MinGW console
2421         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2422  done
2423 ])
2424 fi
2425
2426 AC_CONFIG_HEADERS([src/include/pg_config.h],
2427 [
2428 # Update timestamp for pg_config.h (see Makefile.global)
2429 echo >src/include/stamp-h
2430 ])
2431
2432 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2433 [
2434 # Update timestamp for pg_config_ext.h (see Makefile.global)
2435 echo >src/include/stamp-ext-h
2436 ])
2437
2438 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2439                   [echo >src/interfaces/ecpg/include/stamp-h])
2440
2441 AC_OUTPUT