granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.475 2006/09/23 01:33:32 pgsql Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2beta1], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2006, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # DTrace
 210 #
 211 PGAC_ARG_BOOL(enable, dtrace, no,
 212               [  --enable-dtrace         build with DTrace support],
 213 [AC_DEFINE([ENABLE_DTRACE], 1,
 214            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 215 AC_CHECK_PROGS(DTRACE, dtrace)
 216 if test -z "$DTRACE"; then
 217   AC_MSG_ERROR([dtrace not found])
 218 fi
 219 AC_SUBST(DTRACEFLAGS)])
 220 AC_SUBST(enable_dtrace)
 221
 222 #
 223 # C compiler
 224 #
 225
 226 # For historical reasons you can also use --with-CC to specify the C compiler
 227 # to use, although the standard way to do this is to set the CC environment
 228 # variable.
 229 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 230
 231 case $template in
 232   aix) pgac_cc_list="gcc xlc";;
 233  irix) pgac_cc_list="cc";; # no gcc
 234     *) pgac_cc_list="gcc cc";;
 235 esac
 236
 237 AC_PROG_CC([$pgac_cc_list])
 238
 239 unset CFLAGS
 240
 241 #
 242 # Read the template
 243 #
 244 . "$srcdir/src/template/$template" || exit
 245
 246 # CFLAGS are selected so:
 247 # If the user specifies something in the environment, that is used.
 248 # else:  If the template file set something, that is used.
 249 # else:  If the compiler is GCC, then we use -O2.
 250 # else:  If the compiler is something else, then we use -0.
 251
 252 if test "$ac_env_CFLAGS_set" = set; then
 253   CFLAGS=$ac_env_CFLAGS_value
 254 elif test "${CFLAGS+set}" = set; then
 255   : # (keep what template set)
 256 elif test "$GCC" = yes; then
 257   CFLAGS="-O2"
 258 else
 259   # if the user selected debug mode, don't use -O
 260   if test "$enable_debug" != yes; then
 261     CFLAGS="-O"
 262   fi
 263 fi
 264
 265 # Some versions of GCC support some additional useful warning flags.
 266 # Check whether they are supported, and add them to CFLAGS if so.
 267
 268 if test "$GCC" = yes; then
 269
 270 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 271 # So we have to check if "GCC" is really ICC.
 272 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 273 choke me
 274 @%:@endif], [ICC=[yes]], [ICC=[no]])
 275
 276   if test "$ICC" = no; then
 277     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 278
 279     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 280     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 281   else
 282     # Intel compiler has a bug/misoptimization in checking for
 283     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 284     # CFLAGS.
 285     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 286   fi
 287
 288   # Disable strict-aliasing rules; needed for gcc 3.3+
 289   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 290 elif test x"${CC}" = x"xlc"; then
 291   # AIX xlc has to have strict aliasing turned off too
 292   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 293 fi
 294
 295 # supply -g if --enable-debug
 296 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 297   CFLAGS="$CFLAGS -g"
 298 fi
 299
 300 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 301
 302 # We already have this in Makefile.win32, but configure needs it too
 303 if test "$PORTNAME" = "win32"; then
 304   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 305 fi
 306
 307 # Check if the compiler still works with the template settings
 308 AC_MSG_CHECKING([whether the C compiler still works])
 309 AC_TRY_LINK([], [return 0;],
 310   [AC_MSG_RESULT(yes)],
 311   [AC_MSG_RESULT(no)
 312    AC_MSG_ERROR([cannot proceed])])
 313
 314 # Defend against gcc -ffast-math
 315 if test "$GCC" = yes; then
 316 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 317 choke me
 318 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 319 fi
 320
 321 AC_PROG_CPP
 322 AC_SUBST(GCC)
 323
 324 # Create compiler version string
 325 if test x"$GCC" = x"yes" ; then
 326   cc_string="GCC `${CC} --version | sed q`"
 327 else
 328   cc_string=$CC
 329 fi
 330 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 331                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 332                    [A string containing the version number, platform, and C compiler])
 333
 334
 335 #
 336 # Set up TAS assembly code if needed; the template file has now had its
 337 # chance to request this.
 338 #
 339 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 340
 341 if test "$need_tas" = yes ; then
 342   TAS=tas.o
 343 else
 344   TAS=""
 345 fi
 346 AC_SUBST(TAS)
 347
 348
 349 #
 350 # Automatic dependency tracking
 351 #
 352 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 353               [autodepend=yes])
 354 AC_SUBST(autodepend)
 355
 356
 357 #
 358 # Enable assert checks
 359 #
 360 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 361               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 362                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 363
 364
 365 #
 366 # Include directories
 367 #
 368 ac_save_IFS=$IFS
 369 IFS="${IFS}${PATH_SEPARATOR}"
 370 # SRCH_INC comes from the template file
 371 for dir in $with_includes $SRCH_INC; do
 372   if test -d "$dir"; then
 373     INCLUDES="$INCLUDES -I$dir"
 374   else
 375     AC_MSG_WARN([*** Include directory $dir does not exist.])
 376   fi
 377 done
 378 IFS=$ac_save_IFS
 379 AC_SUBST(INCLUDES)
 380
 381
 382 #
 383 # Library directories
 384 #
 385 ac_save_IFS=$IFS
 386 IFS="${IFS}${PATH_SEPARATOR}"
 387 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 388 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 389   if test -d "$dir"; then
 390     LIBDIRS="$LIBDIRS -L$dir"
 391   else
 392     AC_MSG_WARN([*** Library directory $dir does not exist.])
 393   fi
 394 done
 395 IFS=$ac_save_IFS
 396
 397 #
 398 # Enable thread-safe client libraries
 399 #
 400 AC_MSG_CHECKING([allow thread-safe client libraries])
 401 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 402 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 403 if test "$enable_thread_safety" = yes -o \
 404         "$enable_thread_safety_force" = yes; then
 405   enable_thread_safety="yes"    # for 'force'
 406   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 407           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 408 fi
 409 AC_MSG_RESULT([$enable_thread_safety])
 410 AC_SUBST(enable_thread_safety)
 411
 412 #
 413 # Optionally build Tcl modules (PL/Tcl)
 414 #
 415 AC_MSG_CHECKING([whether to build with Tcl])
 416 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 417 AC_MSG_RESULT([$with_tcl])
 418 AC_SUBST([with_tcl])
 419
 420 # We see if the path to the Tcl/Tk configuration scripts is specified.
 421 # This will override the use of tclsh to find the paths to search.
 422
 423 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 424
 425 #
 426 # Optionally build Perl modules (PL/Perl)
 427 #
 428 AC_MSG_CHECKING([whether to build Perl modules])
 429 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 430 AC_MSG_RESULT([$with_perl])
 431 AC_SUBST(with_perl)
 432
 433 #
 434 # Optionally build Python modules (PL/Python)
 435 #
 436 AC_MSG_CHECKING([whether to build Python modules])
 437 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 438 AC_MSG_RESULT([$with_python])
 439 AC_SUBST(with_python)
 440
 441 #
 442 # Kerberos 5
 443 #
 444 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 445 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 446 [
 447   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 448   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 449 ])
 450 AC_MSG_RESULT([$with_krb5])
 451 AC_SUBST(with_krb5)
 452
 453
 454 AC_SUBST(krb_srvtab)
 455
 456
 457 #
 458 # Kerberos configuration parameters
 459 #
 460 PGAC_ARG_REQ(with, krb-srvnam,
 461              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 462              [],
 463              [with_krb_srvnam="postgres"])
 464 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 465                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 466
 467
 468 #
 469 # PAM
 470 #
 471 AC_MSG_CHECKING([whether to build with PAM support])
 472 PGAC_ARG_BOOL(with, pam, no,
 473               [  --with-pam              build with PAM support],
 474               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 475 AC_MSG_RESULT([$with_pam])
 476 AC_SUBST(with_pam)
 477
 478
 479 #
 480 # LDAP
 481 #
 482 AC_MSG_CHECKING([whether to build with LDAP support])
 483 PGAC_ARG_BOOL(with, ldap, no,
 484               [  --with-ldap             build with LDAP support],
 485               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 486 AC_MSG_RESULT([$with_ldap])
 487 AC_SUBST(with_ldap)
 488
 489
 490 #
 491 # Bonjour
 492 #
 493 AC_MSG_CHECKING([whether to build with Bonjour support])
 494 PGAC_ARG_BOOL(with, bonjour, no,
 495               [  --with-bonjour          build with Bonjour support],
 496               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 497 AC_MSG_RESULT([$with_bonjour])
 498 AC_SUBST(with_bonjour)
 499
 500
 501 #
 502 # OpenSSL
 503 #
 504 AC_MSG_CHECKING([whether to build with OpenSSL support])
 505 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 506               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 507 AC_MSG_RESULT([$with_openssl])
 508 AC_SUBST(with_openssl)
 509
 510
 511 #
 512 # Prefer libedit
 513 #
 514 PGAC_ARG_BOOL(with, libedit-preferred, no,
 515               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 516
 517
 518 #
 519 # Readline
 520 #
 521 PGAC_ARG_BOOL(with, readline, yes,
 522               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 523 # readline on MinGW has problems with backslashes in psql and other bugs.
 524 # This is particularly a problem with non-US code pages.
 525 # Therefore disable its use until we understand the cause. 2004-07-20
 526 if test "$PORTNAME" = "win32"; then
 527   if test "$with_readline" = yes; then
 528     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 529     with_readline=no
 530   fi
 531 fi
 532
 533
 534 #
 535 # Zlib
 536 #
 537 PGAC_ARG_BOOL(with, zlib, yes,
 538               [  --without-zlib          do not use Zlib])
 539 AC_SUBST(with_zlib)
 540
 541 #
 542 # Elf
 543 #
 544
 545 # Assume system is ELF if it predefines __ELF__ as 1,
 546 # otherwise believe host_os based default.
 547 case $host_os in
 548     freebsd1*|freebsd2*) elf=no;;
 549     freebsd3*|freebsd4*) elf=yes;;
 550 esac
 551
 552 AC_EGREP_CPP(yes,
 553 [#if __ELF__
 554   yes
 555 #endif
 556 ],
 557 [ELF_SYS=true],
 558 [if test "X$elf" = "Xyes" ; then
 559   ELF_SYS=true
 560 else
 561   ELF_SYS=
 562 fi])
 563 AC_SUBST(ELF_SYS)
 564
 565 #
 566 # Assignments
 567 #
 568
 569 CPPFLAGS="$CPPFLAGS $INCLUDES"
 570 LDFLAGS="$LDFLAGS $LIBDIRS"
 571
 572 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 573 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 574
 575 AC_ARG_VAR(LDFLAGS_SL)
 576
 577 AC_PROG_AWK
 578 PGAC_PATH_FLEX
 579 AC_PROG_LN_S
 580 PGAC_PROG_LD
 581 AC_SUBST(LD)
 582 AC_SUBST(with_gnu_ld)
 583 case $host_os in sysv5*)
 584   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 585   [
 586     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 587     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 588     LDFLAGS=$pgac_save_LDFLAGS
 589   ])
 590   ld_R_works=$pgac_cv_prog_ld_R
 591   AC_SUBST(ld_R_works)
 592 esac
 593 AC_PROG_RANLIB
 594 AC_PATH_PROG(TAR, tar)
 595 PGAC_CHECK_STRIP
 596
 597 AC_CHECK_PROGS(YACC, ['bison -y'])
 598
 599 if test "$YACC"; then
 600   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 601     AC_MSG_WARN([
 602 *** If you are going to modify the grammar files or build from CVS, the installed
 603 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 604   fi
 605 fi
 606
 607 if test -z "$YACC"; then
 608   AC_MSG_WARN([
 609 *** Without Bison you will not be able to build PostgreSQL from CVS or
 610 *** change any of the parser definition files.  You can obtain Bison from
 611 *** a GNU mirror site.  (If you are using the official distribution of
 612 *** PostgreSQL then you do not need to worry about this because the Bison
 613 *** output is pre-generated.)  To use a different yacc program (possible,
 614 *** but not recommended), set the environment variable YACC before running
 615 *** 'configure'.])
 616 fi
 617 AC_SUBST(YFLAGS)
 618
 619 PGAC_PATH_PERL
 620 if test "$with_perl" = yes; then
 621   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 622   PGAC_CHECK_PERL_EMBED_LDFLAGS
 623 fi
 624
 625 if test "$with_python" = yes; then
 626   PGAC_PATH_PYTHON
 627   PGAC_CHECK_PYTHON_EMBED_SETUP
 628 fi
 629
 630 # Supply a numeric version string for use by 3rd party add-ons
 631 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 632 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 633 tr '.' '        ' |
 634 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 635 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 636
 637 ##
 638 ## Libraries
 639 ##
 640
 641 AC_SEARCH_LIBS(setproctitle, util)
 642 AC_SEARCH_LIBS(pow, m)
 643 AC_SEARCH_LIBS(dlopen, dl)
 644 AC_SEARCH_LIBS(socket, [socket wsock32])
 645 AC_SEARCH_LIBS(shl_load, dld)
 646 # We only use libld in port/dynloader/aix.c
 647 case $host_os in
 648      aix*)
 649         AC_SEARCH_LIBS(ldopen, ld)
 650         ;;
 651 esac
 652 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 653 AC_SEARCH_LIBS(crypt, crypt)
 654 # Solaris:
 655 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 656 # Cygwin:
 657 AC_SEARCH_LIBS(shmget, cygipc)
 658
 659 if test "$with_readline" = yes; then
 660   PGAC_CHECK_READLINE
 661   if test x"$pgac_cv_check_readline" = x"no"; then
 662     AC_MSG_ERROR([readline library not found
 663 If you have readline already installed, see config.log for details on the
 664 failure.  It is possible the compiler isn't looking in the proper directory.
 665 Use --without-readline to disable readline support.])
 666   fi
 667 fi
 668
 669 if test "$with_zlib" = yes; then
 670   AC_CHECK_LIB(z, inflate, [],
 671                [AC_MSG_ERROR([zlib library not found
 672 If you have zlib already installed, see config.log for details on the
 673 failure.  It is possible the compiler isn't looking in the proper directory.
 674 Use --without-zlib to disable zlib support.])])
 675 fi
 676
 677 if test "$enable_spinlocks" = yes; then
 678   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 679 else
 680   AC_MSG_WARN([
 681 *** Not using spinlocks will cause poor performance.])
 682 fi
 683
 684 if test "$with_krb5" = yes ; then
 685   if test "$PORTNAME" != "win32"; then
 686      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 687                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 688      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 689                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 690   else
 691      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 692                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 693   fi
 694 fi
 695
 696 if test "$with_openssl" = yes ; then
 697   dnl Order matters!
 698   if test "$PORTNAME" != "win32"; then
 699      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 700      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 701   else
 702      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 703      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 704   fi
 705 fi
 706
 707 if test "$with_pam" = yes ; then
 708   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 709 fi
 710
 711
 712 ##
 713 ## Header files
 714 ##
 715
 716 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 717 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 718
 719 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 720 # netinet/in.h is included first.
 721 AC_CHECK_HEADERS(netinet/in.h)
 722 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 723 [AC_INCLUDES_DEFAULT
 724 #ifdef HAVE_NETINET_IN_H
 725 #include <netinet/in.h>
 726 #endif
 727 ])
 728
 729 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 730   AC_CHECK_HEADERS(readline/readline.h, [],
 731         [AC_CHECK_HEADERS(readline.h, [],
 732                 [AC_MSG_ERROR([readline header not found
 733 If you have readline already installed, see config.log for details on the
 734 failure.  It is possible the compiler isn't looking in the proper directory.
 735 Use --without-readline to disable readline support.])])])
 736   AC_CHECK_HEADERS(readline/history.h, [],
 737         [AC_CHECK_HEADERS(history.h, [],
 738                 [AC_MSG_ERROR([history header not found
 739 If you have readline already installed, see config.log for details on the
 740 failure.  It is possible the compiler isn't looking in the proper directory.
 741 Use --without-readline to disable readline support.])])])
 742 fi
 743
 744 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 745 # Some installations of libedit usurp /usr/include/readline/, which seems
 746 # bad practice, since in combined installations readline will have its headers
 747 # there.  We might have to resort to AC_EGREP checks to make sure we found
 748 # the proper header...
 749   AC_CHECK_HEADERS(editline/readline.h, [],
 750         [AC_CHECK_HEADERS(readline.h, [],
 751                 [AC_CHECK_HEADERS(readline/readline.h, [],
 752                         [AC_MSG_ERROR([readline header not found
 753 If you have libedit already installed, see config.log for details on the
 754 failure.  It is possible the compiler isn't looking in the proper directory.
 755 Use --without-readline to disable libedit support.])])])])
 756   AC_CHECK_HEADERS(editline/history.h, [],
 757         [AC_CHECK_HEADERS(history.h, [],
 758                 [AC_CHECK_HEADERS(readline/history.h, [],
 759                         [AC_MSG_ERROR([history header not found
 760 If you have libedit already installed, see config.log for details on the
 761 failure.  It is possible the compiler isn't looking in the proper directory.
 762 Use --without-readline to disable libedit support.])])])])
 763 fi
 764
 765 if test "$with_zlib" = yes; then
 766   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 767 If you have zlib already installed, see config.log for details on the
 768 failure.  It is possible the compiler isn't looking in the proper directory.
 769 Use --without-zlib to disable zlib support.])])
 770 fi
 771
 772 if test "$with_krb5" = yes ; then
 773   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 774 fi
 775
 776 if test "$with_openssl" = yes ; then
 777   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 778   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 779 fi
 780
 781 if test "$with_pam" = yes ; then
 782   AC_CHECK_HEADERS(security/pam_appl.h, [],
 783                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 784                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 785 fi
 786
 787 if test "$with_ldap" = yes ; then
 788   if test "$PORTNAME" != "win32"; then
 789      AC_CHECK_HEADERS(ldap.h, [],
 790                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 791   else
 792      AC_CHECK_HEADERS(winldap.h, [],
 793                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 794                       [AC_INCLUDES_DEFAULT
 795 #include <windows.h>
 796                       ])
 797   fi
 798 fi
 799
 800 if test "$with_bonjour" = yes ; then
 801   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 802 fi
 803
 804
 805 ##
 806 ## Types, structures, compiler characteristics
 807 ##
 808
 809 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 810 AC_C_CONST
 811 AC_C_INLINE
 812 AC_C_STRINGIZE
 813 PGAC_C_SIGNED
 814 AC_C_VOLATILE
 815 PGAC_C_FUNCNAME_SUPPORT
 816 PGAC_STRUCT_TIMEZONE
 817 PGAC_UNION_SEMUN
 818 PGAC_STRUCT_SOCKADDR_UN
 819 PGAC_STRUCT_SOCKADDR_STORAGE
 820 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 821 PGAC_STRUCT_ADDRINFO
 822
 823 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 824 [#include <sys/param.h>
 825 #include <sys/types.h>
 826 #include <sys/socket.h>
 827 #include <sys/ucred.h>])
 828
 829 AC_CHECK_TYPES([struct option], [], [],
 830 [#ifdef HAVE_GETOPT_H
 831 #include <getopt.h>
 832 #endif])
 833
 834 if test "$with_zlib" = yes; then
 835   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 836   # did not).  While we could work around the lack of z_streamp, it
 837   # seems unwise to encourage people to use such old zlib versions...
 838   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 839 Use --without-zlib to disable zlib support.])],
 840                 [#include <zlib.h>])
 841 fi
 842
 843 if test "$with_krb5" = yes; then
 844 # Check for differences between MIT and Heimdal (KTH) releases
 845   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 846                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 847                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 848                                      [#include <krb5.h>])],
 849                    [#include <krb5.h>])
 850   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 851                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 852                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 853                                      [#include <krb5.h>])],
 854                    [#include <krb5.h>])
 855 fi
 856
 857 # This is probably only present on Darwin, but may as well check always
 858 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 859
 860 ##
 861 ## Functions, global variables
 862 ##
 863
 864 PGAC_VAR_INT_TIMEZONE
 865 AC_FUNC_ACCEPT_ARGTYPES
 866 PGAC_FUNC_GETTIMEOFDAY_1ARG
 867
 868 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 869
 870 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 871 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 872
 873 HAVE_IPV6=no
 874 AC_CHECK_TYPE([struct sockaddr_in6],
 875         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 876          HAVE_IPV6=yes],
 877         [],
 878 [$ac_includes_default
 879 #include <netinet/in.h>])
 880 AC_SUBST(HAVE_IPV6)
 881
 882 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 883 [AC_TRY_LINK(
 884 [#include <machine/vmparam.h>
 885 #include <sys/exec.h>
 886 ],
 887 [PS_STRINGS->ps_nargvstr = 1;
 888 PS_STRINGS->ps_argvstr = "foo";],
 889 [pgac_cv_var_PS_STRINGS=yes],
 890 [pgac_cv_var_PS_STRINGS=no])])
 891 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 892   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 893 fi
 894
 895
 896 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 897 # is missing.  Yes, there are machines that have only one.  We may
 898 # also decide to use snprintf.c if snprintf() is present but does not
 899 # have all the features we need --- see below.
 900
 901 if test "$PORTNAME" = "win32"; then
 902   # Win32 gets snprintf.c built unconditionally.
 903   #
 904   # To properly translate all NLS languages strings, we must support the
 905   # *printf() %$ format, which allows *printf() arguments to be selected
 906   # by position in the translated string.
 907   #
 908   # libintl versions < 0.13 use the native *printf() functions, and Win32
 909   # *printf() doesn't understand %$, so we must use our /port versions,
 910   # which do understand %$. libintl versions >= 0.13 include their own
 911   # *printf versions on Win32.  The libintl 0.13 release note text is:
 912   #
 913   #   C format strings with positions, as they arise when a translator
 914   #   needs to reorder a sentence, are now supported on all platforms.
 915   #   On those few platforms (NetBSD and Woe32) for which the native
 916   #   printf()/fprintf()/... functions don't support such format
 917   #   strings, replacements are provided through <libintl.h>.
 918   #
 919   # We could use libintl >= 0.13's *printf() if we were sure that we had
 920   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 921   # to guarantee that, it is best to just use our own, so we are sure to
 922   # get %$ support. In include/port.h we disable the *printf() macros
 923   # that might have been defined by libintl.
 924   #
 925   # We do this unconditionally whether NLS is used or not so we are sure
 926   # that all Win32 libraries and binaries behave the same.
 927   pgac_need_repl_snprintf=yes
 928 else
 929   pgac_need_repl_snprintf=no
 930   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 931   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 932 fi
 933
 934
 935 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 936 # include/c.h will provide declarations.  Note this is a separate test
 937 # from whether the functions exist in the C library --- there are
 938 # systems that have the functions but don't bother to declare them :-(
 939
 940 AC_CHECK_DECLS([snprintf, vsnprintf])
 941
 942
 943 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 944 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 945 [AC_TRY_LINK([
 946 #include <math.h>
 947 double glob_double;
 948 ],
 949 [return isinf(glob_double) ? 0 : 1;],
 950 [ac_cv_func_isinf=yes],
 951 [ac_cv_func_isinf=no])])
 952
 953 if test $ac_cv_func_isinf = yes ; then
 954   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 955 else
 956   AC_LIBOBJ(isinf)
 957   # Look for a way to implement a substitute for isinf()
 958   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 959 fi
 960
 961 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 962
 963 # System's version of getaddrinfo(), if any, may be used only if we found
 964 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 965 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 966 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 967 # because we want to use our own getaddrinfo.c on Windows anyway.)
 968 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 969   AC_REPLACE_FUNCS([getaddrinfo])
 970 else
 971   AC_LIBOBJ(getaddrinfo)
 972 fi
 973
 974 # similarly, use system's getopt_long() only if system provides struct option.
 975 if test x"$ac_cv_type_struct_option" = xyes ; then
 976   AC_REPLACE_FUNCS([getopt_long])
 977 else
 978   AC_LIBOBJ(getopt_long)
 979 fi
 980
 981 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 982 # We override the previous test that said fseeko/ftello didn't exist
 983 # OS tests are also done in include/c.h and port/fseeko.c
 984 case $host_os in bsdi*|netbsd*)
 985 ac_cv_func_fseeko=yes
 986 esac
 987
 988 # Solaris has a very slow qsort in certain cases, so we replace it:
 989 #   http://forum.sun.com/thread.jspa?forumID=4&threadID=7231
 990 # Supposedly it is fixed in Solaris, but not sure which version, and
 991 # no confirmed testing.  2005-12-16
 992 if test "$PORTNAME" = "solaris"; then
 993 AC_LIBOBJ(qsort)
 994 fi
 995
 996 # Win32 support
 997 if test "$PORTNAME" = "win32"; then
 998 AC_LIBOBJ(gettimeofday)
 999 AC_LIBOBJ(kill)
1000 AC_LIBOBJ(open)
1001 AC_LIBOBJ(rand)
1002 AC_LIBOBJ(win32error)
1003 AC_DEFINE([HAVE_SYMLINK], 1,
1004           [Define to 1 if you have the `symlink' function.])
1005 fi
1006
1007 if test "$with_readline" = yes; then
1008   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1009   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1010   AC_CHECK_FUNCS([replace_history_entry])
1011 fi
1012
1013
1014 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
1015 AC_MSG_CHECKING(for finite)
1016 AC_TRY_LINK([
1017 #include <math.h>
1018 double glob_double;
1019 ],
1020             [return finite(glob_double) ? 0 : 1;],
1021             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
1022 AC_MSG_RESULT(yes)],
1023             [AC_MSG_RESULT(no)])
1024
1025 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1026 dnl (especially on GNU libc)
1027 dnl See also comments in c.h.
1028 AC_MSG_CHECKING(for sigsetjmp)
1029 AC_TRY_LINK([#include <setjmp.h>],
1030             [sigjmp_buf x; sigsetjmp(x, 1);],
1031             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1032 AC_MSG_RESULT(yes)],
1033             [AC_MSG_RESULT(no)])
1034
1035 AC_CHECK_FUNC(syslog,
1036               [AC_CHECK_HEADER(syslog.h,
1037                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1038
1039 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1040 [AC_TRY_LINK([#include <unistd.h>],
1041   [extern int optreset; optreset = 1;],
1042   [pgac_cv_var_int_optreset=yes],
1043   [pgac_cv_var_int_optreset=no])])
1044 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1045   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1046 fi
1047
1048 AC_CHECK_FUNCS([strtoll strtoq], [break])
1049 AC_CHECK_FUNCS([strtoull strtouq], [break])
1050
1051 # Check for one of atexit() or on_exit()
1052 AC_CHECK_FUNCS(atexit, [],
1053                [AC_CHECK_FUNCS(on_exit, [],
1054                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1055
1056 AC_FUNC_FSEEKO
1057
1058 #
1059 # Pthreads
1060 #
1061 # For each platform, we need to know about any special compile and link
1062 # libraries, and whether the normal C function names are thread-safe.
1063 # See the comment at the top of src/port/thread.c for more information.
1064 #
1065 if test "$enable_thread_safety" = yes; then
1066 ACX_PTHREAD     # set thread flags
1067
1068 # Some platforms use these, so just defineed them.  They can't hurt if they
1069 # are not supported.
1070 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1071
1072
1073 # At this point, we don't want to muck with the compiler name for threading.
1074 # Let's see who fails, perhaps AIX.  2004-04-23
1075 if test "$PTHREAD_CC" != "$CC"; then
1076 AC_MSG_ERROR([
1077 PostgreSQL does not support platforms that require a special
1078 compiler binary for thread-safety.
1079 ])
1080 fi
1081
1082 if test "$THREAD_SUPPORT" = no; then
1083 AC_MSG_ERROR([
1084 Cannot enable threads on your platform.
1085 Your platform is known to not support thread-safe programs.
1086 For details, compile and run src/bin/pg_thread_test.
1087 ])
1088 fi
1089
1090 # Check for *_r functions
1091 _CFLAGS="$CFLAGS"
1092 _LIBS="$LIBS"
1093 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1094 LIBS="$LIBS $PTHREAD_LIBS"
1095
1096 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1097
1098 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1099
1100 # Do test here with the proper thread flags
1101 PGAC_FUNC_GETPWUID_R_5ARG
1102 PGAC_FUNC_STRERROR_R_INT
1103
1104 CFLAGS="$_CFLAGS"
1105 LIBS="$_LIBS"
1106
1107 else
1108 # do not use values from template file
1109 PTHREAD_CFLAGS=
1110 PTHREAD_LIBS=
1111 fi
1112
1113 AC_SUBST(PTHREAD_CFLAGS)
1114 AC_SUBST(PTHREAD_LIBS)
1115
1116
1117 # We can test for libldap_r only after we know PTHREAD_LIBS
1118 if test "$with_ldap" = yes ; then
1119   _LIBS="$LIBS"
1120   if test "$PORTNAME" != "win32"; then
1121     AC_CHECK_LIB(ldap, ldap_bind, [], [AC_MSG_ERROR([library 'ldap' is required for LDAP])])
1122     LDAP_LIBS_BE="-lldap"
1123     if test "$enable_thread_safety" = yes; then
1124       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1125       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1126                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1127                    [$PTHREAD_LIBS])
1128       LDAP_LIBS_FE="-lldap_r"
1129     else
1130       LDAP_LIBS_FE="-lldap"
1131     fi
1132   else
1133     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1134     LDAP_LIBS_FE="-lwldap32"
1135     LDAP_LIBS_BE="-lwldap32"
1136   fi
1137   LIBS="$_LIBS"
1138 fi
1139 AC_SUBST(LDAP_LIBS_FE)
1140 AC_SUBST(LDAP_LIBS_BE)
1141
1142
1143 # This test makes sure that run tests work at all.  Sometimes a shared
1144 # library is found by the linker, but the runtime linker can't find it.
1145 # This check should come after all modifications of compiler or linker
1146 # variables, and before any other run tests.
1147 AC_MSG_CHECKING([test program])
1148 AC_TRY_RUN([int main() { return 0; }],
1149 [AC_MSG_RESULT(ok)],
1150 [AC_MSG_RESULT(failed)
1151 AC_MSG_ERROR([[
1152 *** Could not execute a simple test program.  This may be a problem
1153 *** related to locating shared libraries.  Check the file 'config.log'
1154 *** for the exact reason.]])],
1155 [AC_MSG_RESULT([cross-compiling])])
1156
1157 # --------------------
1158 # Run tests below here
1159 # --------------------
1160
1161 # Force use of our snprintf if system's doesn't do arg control
1162 # See comment above at snprintf test for details.
1163 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1164   PGAC_FUNC_PRINTF_ARG_CONTROL
1165   if test $pgac_cv_printf_arg_control != yes ; then
1166     pgac_need_repl_snprintf=yes
1167   fi
1168 fi
1169
1170
1171 dnl Check to see if we have a working 64-bit integer type.
1172 dnl This breaks down into two steps:
1173 dnl (1) figure out if the compiler has a 64-bit int type with working
1174 dnl arithmetic, and if so
1175 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1176 dnl snprintf is the only library routine we really need for int8 support.)
1177 dnl It's entirely possible to have a compiler that handles a 64-bit type
1178 dnl when the C library doesn't; this is fairly likely when using gcc on
1179 dnl an older platform, for example.
1180 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1181 dnl we force our own version of snprintf() to be used instead.
1182 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1183
1184 PGAC_TYPE_64BIT_INT([long int])
1185
1186 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1187   PGAC_TYPE_64BIT_INT([long long int])
1188 fi
1189
1190
1191 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1192
1193 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1194   AC_TRY_COMPILE([
1195 #define INT64CONST(x)  x##LL
1196 long long int foo = INT64CONST(0x1234567890123456);
1197 ],
1198         [],
1199         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1200         [])
1201 fi
1202
1203
1204 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1205 # we found we need to use "long long int", better check.  We cope with
1206 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1207 # work, fall back to our own snprintf emulation (which we know uses %lld).
1208
1209 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1210   if test $pgac_need_repl_snprintf = no; then
1211     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1212     if test "$LONG_LONG_INT_FORMAT" = ""; then
1213       # Force usage of our own snprintf, since system snprintf is broken
1214       pgac_need_repl_snprintf=yes
1215       LONG_LONG_INT_FORMAT='%lld'
1216     fi
1217   else
1218     # Here if we previously decided we needed to use our own snprintf
1219     LONG_LONG_INT_FORMAT='%lld'
1220   fi
1221   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1222   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1223   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1224 else
1225   # Here if we are not using 'long long int' at all
1226   INT64_FORMAT='"%ld"'
1227   UINT64_FORMAT='"%lu"'
1228 fi
1229
1230 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1231                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1232
1233 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1234                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1235
1236 # Now we have checked all the reasons to replace snprintf
1237 if test $pgac_need_repl_snprintf = yes; then
1238   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1239   AC_LIBOBJ(snprintf)
1240 fi
1241
1242 # Need a #define for the size of Datum (unsigned long)
1243 AC_CHECK_SIZEOF([unsigned long])
1244
1245 # And one for the size of size_t (enables tweaks for > 32bit address space)
1246 AC_CHECK_SIZEOF([size_t])
1247
1248 # Determine memory alignment requirements for the basic C data types.
1249
1250 PGAC_CHECK_ALIGNOF(short)
1251 PGAC_CHECK_ALIGNOF(int)
1252 PGAC_CHECK_ALIGNOF(long)
1253 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1254   PGAC_CHECK_ALIGNOF(long long int)
1255 fi
1256 PGAC_CHECK_ALIGNOF(double)
1257
1258 # Compute maximum alignment of any basic type.
1259 # We assume long's alignment is at least as strong as char, short, or int;
1260 # but we must check long long (if it exists) and double.
1261
1262 MAX_ALIGNOF=$pgac_cv_alignof_long
1263 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1264   MAX_ALIGNOF=$pgac_cv_alignof_double
1265 fi
1266 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1267   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1268 fi
1269 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1270
1271
1272 # Some platforms predefine the types int8, int16, etc.  Only check
1273 # a (hopefully) representative subset.
1274 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1275 [#include <stdio.h>
1276 #ifdef HAVE_SUPPORTDEFS_H
1277 #include <SupportDefs.h>
1278 #endif])
1279
1280 # We also check for sig_atomic_t, which *should* be defined per ANSI
1281 # C, but is missing on some old platforms.
1282 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1283
1284
1285 if test x"$template" != x"win32"
1286 then
1287 PGAC_FUNC_POSIX_SIGNALS
1288 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1289   AC_MSG_ERROR([
1290 *** Thread-safety requires POSIX signals, which are not supported by your
1291 *** operating system.
1292 ])
1293 fi
1294 fi
1295
1296 if test $ac_cv_func_fseeko = yes; then
1297 AC_SYS_LARGEFILE
1298 fi
1299
1300 # SunOS doesn't handle negative byte comparisons properly with +/- return
1301 AC_FUNC_MEMCMP
1302
1303
1304 # Select semaphore implementation type.
1305 if test "$PORTNAME" != "win32"; then
1306   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1307     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1308     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1309   else
1310     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1311       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1312       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1313     else
1314       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1315       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1316     fi
1317   fi
1318 else
1319   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1320   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1321 fi
1322
1323
1324 # Select shared-memory implementation type.
1325 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1326 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1327
1328
1329 # If not set in template file, set bytes to use libc memset()
1330 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1331   MEMSET_LOOP_LIMIT=1024
1332 fi
1333 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1334
1335
1336 if test "$enable_nls" = yes ; then
1337   PGAC_CHECK_GETTEXT
1338 fi
1339
1340 # Check for Tcl configuration script tclConfig.sh
1341 if test "$with_tcl" = yes; then
1342     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1343     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1344                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1345     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1346     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1347     ac_save_CPPFLAGS=$CPPFLAGS
1348     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1349     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1350     CPPFLAGS=$ac_save_CPPFLAGS
1351 fi
1352
1353 #
1354 # Check for DocBook and tools
1355 #
1356 PGAC_PROG_NSGMLS
1357 PGAC_PROG_JADE
1358 PGAC_CHECK_DOCBOOK(4.2)
1359 PGAC_PATH_DOCBOOK_STYLESHEETS
1360 PGAC_PATH_COLLATEINDEX
1361 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1362
1363 # Thread testing
1364
1365 # We have to run the thread test near the end so we have all our symbols
1366 # defined.  Cross compiling throws a warning.
1367 #
1368 if test "$enable_thread_safety_force" = yes; then
1369 if test x"$template" != x"win32"
1370 then
1371   AC_MSG_WARN([
1372 *** Skipping thread test program.  --enable-thread-safety-force was used.
1373 *** Run the program in src/test/thread on the your machine and add
1374 proper locking function calls to your applications to guarantee thread
1375 safety.
1376 ])
1377 else
1378 AC_MSG_WARN([*** Skipping thread test on Win32])
1379 fi
1380 elif test "$enable_thread_safety" = yes; then
1381 if test x"$template" != x"win32"
1382 then
1383 AC_MSG_CHECKING([thread safety of required library functions])
1384
1385 _CFLAGS="$CFLAGS"
1386 _LIBS="$LIBS"
1387 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1388 LIBS="$LIBS $PTHREAD_LIBS"
1389 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1390   [AC_MSG_RESULT(yes)],
1391   [AC_MSG_RESULT(no)
1392   AC_MSG_ERROR([
1393 *** Thread test program failed.  Your platform is not thread-safe.
1394 *** Check the file 'config.log'for the exact reason.
1395 ***
1396 *** You can use the configure option --enable-thread-safety-force
1397 *** to force threads to be enabled.  However, you must then run
1398 *** the program in src/test/thread and add locking function calls
1399 *** to your applications to guarantee thread safety.
1400 ])],
1401   [AC_MSG_RESULT(maybe)
1402   AC_MSG_WARN([
1403 *** Skipping thread test program because of cross-compile build.
1404 *** Run the program in src/test/thread on the target machine.
1405 ])])
1406 CFLAGS="$_CFLAGS"
1407 LIBS="$_LIBS"
1408 else
1409 AC_MSG_WARN([*** Skipping thread test on Win32])
1410 fi
1411 fi
1412
1413 # prepare build tree if outside source tree
1414 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1415 # Note 2: /bin/pwd might be better than shell's built-in at getting
1416 #         a symlink-free name.
1417 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1418   vpath_build=no
1419 else
1420   vpath_build=yes
1421   if test "$no_create" != yes; then
1422     _AS_ECHO_N([preparing build tree... ])
1423     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1424     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1425       || AC_MSG_ERROR(failed)
1426     AC_MSG_RESULT(done)
1427   fi
1428 fi
1429 AC_SUBST(vpath_build)
1430
1431
1432 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1433
1434 AC_CONFIG_LINKS([
1435   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1436   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1437   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1438   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1439   src/include/pg_config_os.h:src/include/port/${template}.h
1440   src/Makefile.port:src/makefiles/Makefile.${template}
1441 ])
1442
1443 if test "$PORTNAME" = "win32"; then
1444 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1445 # Links sometimes fail undetected on Mingw -
1446 # so here we detect it and warn the user
1447 for FILE in $CONFIG_LINKS
1448  do
1449         # test -e works for symlinks in the MinGW console
1450         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1451  done
1452 ])
1453 fi
1454
1455 AC_CONFIG_HEADERS([src/include/pg_config.h],
1456 [
1457 # Update timestamp for pg_config.h (see Makefile.global)
1458 echo >src/include/stamp-h
1459 ])
1460
1461 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1462
1463
1464 #
1465 # Warn about unknown options
1466 #
1467
1468 PGAC_CHECK_ARGS
1469
1470 AC_OUTPUT
1471