granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.344 2004/05/05 21:18:29 tgl Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [7.5devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix5 ;;
  60    linux*) template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      qnx*) template=qnx4 ;;
  67      sco*) template=sco ;;
  68  solaris*) template=solaris ;;
  69    sunos*) template=sunos4 ;;
  70  sysv4.2*)
  71         case $host_vendor in
  72           univel) template=univel ;;
  73         esac ;;
  74    sysv4*) template=svr4 ;;
  75    sysv5*) template=unixware ;;
  76   ultrix*) template=ultrix4 ;;
  77 esac
  78
  79   if test x"$template" = x"" ; then
  80     AC_MSG_ERROR([[
  81 *******************************************************************
  82 PostgreSQL has apparently not been ported to your platform yet.
  83 To try a manual configuration, look into the src/template directory
  84 for a similar platform and use the '--with-template=' option.
  85
  86 Please also contact <pgsql-ports@postgresql.org> to see about
  87 rectifying this.  Include the above 'checking host system type...'
  88 line.
  89 *******************************************************************
  90 ]])
  91   fi
  92
  93 ])
  94
  95 AC_MSG_RESULT([$template])
  96
  97 PORTNAME=$template
  98 AC_SUBST(PORTNAME)
  99
 100 # Initialize default assumption that we do not need separate assembly code
 101 # for TAS (test-and-set).  This can be overridden by the template file
 102 # when it's executed.
 103 need_tas=no
 104 tas_file=dummy.s
 105
 106
 107
 108 ##
 109 ## Command line options
 110 ##
 111
 112 #
 113 # Installation directory for documentation
 114 #
 115 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 116   --without-docdir        do not install the documentation],
 117          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 118          [docdir=],
 119          [docdir=$withval],
 120          [docdir='${prefix}/doc'])
 121 AC_SUBST(docdir)
 122
 123
 124 #
 125 # Add non-standard directories to the include path
 126 #
 127 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 128
 129
 130 #
 131 # Add non-standard directories to the library search path
 132 #
 133 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 134              [LIBRARY_DIRS=$withval])
 135
 136 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 137              [LIBRARY_DIRS=$withval])
 138
 139
 140 #
 141 # 64-bit integer date/time storage (--enable-integer-datetimes)
 142 #
 143 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 144 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 145               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 146                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 147 AC_MSG_RESULT([$enable_integer_datetimes])
 148
 149
 150 #
 151 # NLS
 152 #
 153 AC_MSG_CHECKING([whether NLS is wanted])
 154 PGAC_ARG_OPTARG(enable, nls,
 155                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 156                 [],
 157                 [WANTED_LANGUAGES=$enableval],
 158                 [AC_DEFINE(ENABLE_NLS, 1,
 159                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 160 AC_MSG_RESULT([$enable_nls])
 161 AC_SUBST(enable_nls)
 162 AC_SUBST(WANTED_LANGUAGES)
 163
 164 #
 165 # Default port number (--with-pgport), default 5432
 166 #
 167 AC_MSG_CHECKING([for default port number])
 168 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 169              [default_port=$withval],
 170              [default_port=5432])
 171 AC_MSG_RESULT([$default_port])
 172 # Need both of these because some places want an integer and some a string
 173 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 174 [Define to the default TCP port number on which the server listens and
 175 to which clients will try to connect.  This can be overridden at run-time,
 176 but it's convenient if your clients have the right default compiled in.
 177 (--with-pgport=PORTNUM)])
 178 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 179                    [Define to the default TCP port number as a string constant.])
 180 AC_SUBST(default_port)
 181
 182 #
 183 # Option to disable shared libraries
 184 #
 185 PGAC_ARG_BOOL(enable, shared, yes,
 186               [  --disable-shared        do not build shared libraries])
 187 AC_SUBST(enable_shared)
 188
 189 #
 190 # '-rpath'-like feature can be disabled
 191 #
 192 PGAC_ARG_BOOL(enable, rpath, yes,
 193               [  --disable-rpath         do not embed shared library search path in executables])
 194 AC_SUBST(enable_rpath)
 195
 196 #
 197 # Spinlocks
 198 #
 199 PGAC_ARG_BOOL(enable, spinlocks, yes,
 200               [  --disable-spinlocks     do not use spinlocks])
 201
 202 #
 203 # --enable-debug adds -g to compiler flags
 204 #
 205 PGAC_ARG_BOOL(enable, debug, no,
 206               [  --enable-debug          build with debugging symbols (-g)])
 207 AC_SUBST(enable_debug)
 208
 209 #
 210 # C compiler
 211 #
 212
 213 # For historical reasons you can also use --with-CC to specify the C compiler
 214 # to use, although the standard way to do this is to set the CC environment
 215 # variable.
 216 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 217
 218 case $template in
 219   aix) pgac_cc_list="gcc xlc";;
 220  irix) pgac_cc_list="cc";; # no gcc
 221     *) pgac_cc_list="gcc cc";;
 222 esac
 223
 224 AC_PROG_CC([$pgac_cc_list])
 225
 226 unset CFLAGS
 227
 228 #
 229 # Read the template
 230 #
 231 . "$srcdir/src/template/$template" || exit
 232
 233 # CFLAGS are selected so:
 234 # If the user specifies something in the environment, that is used.
 235 # else:  If the template file set something, that is used.
 236 # else:  If the compiler is GCC, then we use -O2.
 237 # else:  If the compiler is something else, then we use -0.
 238
 239 if test "$ac_env_CFLAGS_set" = set; then
 240   CFLAGS=$ac_env_CFLAGS_value
 241 elif test "${CFLAGS+set}" = set; then
 242   : # (keep what template set)
 243 elif test "$GCC" = yes; then
 244   CFLAGS="-O2"
 245 else
 246   # if the user selected debug mode, don't use -O
 247   if test "$enable_debug" != yes; then
 248     CFLAGS="-O"
 249   fi
 250 fi
 251
 252 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 253 PGAC_PROG_CC_NO_STRICT_ALIASING
 254
 255 # supply -g if --enable-debug
 256 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 257   CFLAGS="$CFLAGS -g"
 258 fi
 259
 260 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 261
 262 # We already have this in Makefile.win32, but configure needs it too
 263 if test "$PORTNAME" = "win32"; then
 264   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 265 fi
 266
 267 # Check if the compiler still works with the template settings
 268 AC_MSG_CHECKING([whether the C compiler still works])
 269 AC_TRY_LINK([], [return 0;],
 270   [AC_MSG_RESULT(yes)],
 271   [AC_MSG_RESULT(no)
 272    AC_MSG_ERROR([cannot proceed])])
 273
 274 # Defend against gcc -ffast-math
 275 if test "$GCC" = yes; then
 276 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 277 choke me
 278 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 279 fi
 280
 281 AC_PROG_CPP
 282 AC_SUBST(GCC)
 283
 284 # Create compiler version string
 285 if test x"$GCC" = x"yes" ; then
 286   cc_string="GCC `${CC} --version | sed q`"
 287 else
 288   cc_string=$CC
 289 fi
 290 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 291                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 292                    [A string containing the version number, platform, and C compiler])
 293
 294
 295 #
 296 # Set up TAS assembly code if needed; the template file has now had its
 297 # chance to request this.
 298 #
 299 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 300
 301 if test "$need_tas" = yes ; then
 302   TAS=tas.o
 303 else
 304   TAS=""
 305 fi
 306 AC_SUBST(TAS)
 307
 308
 309 #
 310 # Automatic dependency tracking
 311 #
 312 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 313               [autodepend=yes])
 314 AC_SUBST(autodepend)
 315
 316
 317 #
 318 # Enable assert checks
 319 #
 320 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 321               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 322                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 323
 324
 325 #
 326 # Include directories
 327 #
 328 ac_save_IFS=$IFS
 329 IFS="${IFS}:"
 330 # SRCH_INC comes from the template file
 331 for dir in $with_includes $SRCH_INC; do
 332   if test -d "$dir"; then
 333     INCLUDES="$INCLUDES -I$dir"
 334   else
 335     AC_MSG_WARN([*** Include directory $dir does not exist.])
 336   fi
 337 done
 338 IFS=$ac_save_IFS
 339 AC_SUBST(INCLUDES)
 340
 341
 342 #
 343 # Library directories
 344 #
 345 ac_save_IFS=$IFS
 346 IFS="${IFS}:"
 347 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 348 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 349   if test -d "$dir"; then
 350     LIBDIRS="$LIBDIRS -L$dir"
 351   else
 352     AC_MSG_WARN([*** Library directory $dir does not exist.])
 353   fi
 354 done
 355 IFS=$ac_save_IFS
 356
 357 #
 358 # Enable thread-safe client libraries
 359 #
 360 AC_MSG_CHECKING([allow thread-safe client libraries])
 361 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 362               [AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 363                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 364 AC_MSG_RESULT([$enable_thread_safety])
 365 AC_SUBST(enable_thread_safety)
 366
 367 #
 368 # Tcl/Tk
 369 #
 370 AC_MSG_CHECKING([whether to build with Tcl])
 371 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 372 AC_MSG_RESULT([$with_tcl])
 373 AC_SUBST([with_tcl])
 374
 375 # We see if the path to the Tcl/Tk configuration scripts is specified.
 376 # This will override the use of tclsh to find the paths to search.
 377
 378 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 379
 380 #
 381 # Optionally build Perl modules (PL/Perl)
 382 #
 383 AC_MSG_CHECKING([whether to build Perl modules])
 384 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 385 AC_MSG_RESULT([$with_perl])
 386 AC_SUBST(with_perl)
 387
 388 #
 389 # Optionally build Python modules (PL/Python)
 390 #
 391 AC_MSG_CHECKING([whether to build Python modules])
 392 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 393 AC_MSG_RESULT([$with_python])
 394 AC_SUBST(with_python)
 395
 396 #
 397 # Kerberos 4
 398 #
 399 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 400 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 401 [
 402   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 403   krb_srvtab="/etc/srvtab"
 404 ])
 405 AC_MSG_RESULT([$with_krb4])
 406 AC_SUBST(with_krb4)
 407
 408
 409 #
 410 # Kerberos 5
 411 #
 412 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 413 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 414 [
 415   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 416   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 417 ])
 418 AC_MSG_RESULT([$with_krb5])
 419 AC_SUBST(with_krb5)
 420
 421
 422 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 423 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 424   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 425 fi
 426
 427 AC_SUBST(krb_srvtab)
 428
 429
 430 #
 431 # Kerberos configuration parameters
 432 #
 433 PGAC_ARG_REQ(with, krb-srvnam,
 434              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 435              [],
 436              [with_krb_srvnam="postgres"])
 437 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 438                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 439
 440
 441 #
 442 # PAM
 443 #
 444 AC_MSG_CHECKING([whether to build with PAM support])
 445 PGAC_ARG_BOOL(with, pam, no,
 446               [  --with-pam              build with PAM support],
 447               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 448 AC_MSG_RESULT([$with_pam])
 449 AC_SUBST(with_pam)
 450
 451
 452 #
 453 # Rendezvous
 454 #
 455 AC_MSG_CHECKING([whether to build with Rendezvous support])
 456 PGAC_ARG_BOOL(with, rendezvous, no,
 457               [  --with-rendezvous       build with Rendezvous support],
 458               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 459 AC_MSG_RESULT([$with_rendezvous])
 460 AC_SUBST(with_rendezvous)
 461
 462
 463 #
 464 # OpenSSL
 465 #
 466 AC_MSG_CHECKING([whether to build with OpenSSL support])
 467 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 468               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 469 AC_MSG_RESULT([$with_openssl])
 470 AC_SUBST(with_openssl)
 471
 472
 473 #
 474 # Readline
 475 #
 476 PGAC_ARG_BOOL(with, readline, yes,
 477               [  --without-readline      do not use Readline])
 478
 479 #
 480 # Zlib
 481 #
 482 PGAC_ARG_BOOL(with, zlib, yes,
 483               [  --without-zlib          do not use Zlib])
 484
 485 #
 486 # Elf
 487 #
 488
 489 # Assume system is ELF if it predefines __ELF__ as 1,
 490 # otherwise believe host_os based default.
 491 case $host_os in
 492     freebsd1*|freebsd2*) elf=no;;
 493     freebsd3*|freebsd4*) elf=yes;;
 494 esac
 495
 496 AC_EGREP_CPP(yes,
 497 [#if __ELF__
 498   yes
 499 #endif
 500 ],
 501 [ELF_SYS=true],
 502 [if test "X$elf" = "Xyes" ; then
 503   ELF_SYS=true
 504 else
 505   ELF_SYS=
 506 fi])
 507 AC_SUBST(ELF_SYS)
 508
 509 #
 510 # Assignments
 511 #
 512
 513 CPPFLAGS="$CPPFLAGS $INCLUDES"
 514 LDFLAGS="$LDFLAGS $LIBDIRS"
 515
 516 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 517 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 518
 519
 520 AC_PROG_AWK
 521 PGAC_PATH_FLEX
 522 AC_PROG_LN_S
 523 AC_PROG_LD
 524 AC_SUBST(LD)
 525 AC_SUBST(with_gnu_ld)
 526 case $host_os in sysv5*)
 527   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 528   [
 529     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 530     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 531     LDFLAGS=$pgac_save_LDFLAGS
 532   ])
 533   ld_R_works=$pgac_cv_prog_ld_R
 534   AC_SUBST(ld_R_works)
 535 esac
 536 AC_PROG_RANLIB
 537 AC_CHECK_PROGS(LORDER, lorder)
 538 AC_PATH_PROG(TAR, tar)
 539 PGAC_CHECK_STRIP
 540
 541 AC_CHECK_PROGS(YACC, ['bison -y'])
 542
 543 if test "$YACC"; then
 544   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 545     AC_MSG_WARN([
 546 *** If you are going to modify the grammar files or build from CVS, the installed
 547 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 548   fi
 549 fi
 550
 551 if test -z "$YACC"; then
 552   AC_MSG_WARN([
 553 *** Without Bison you will not be able to build PostgreSQL from CVS or
 554 *** change any of the parser definition files.  You can obtain Bison from
 555 *** a GNU mirror site.  (If you are using the official distribution of
 556 *** PostgreSQL then you do not need to worry about this because the Bison
 557 *** output is pre-generated.)  To use a different yacc program (possible,
 558 *** but not recommended), set the environment variable YACC before running
 559 *** 'configure'.])
 560 fi
 561 AC_SUBST(YFLAGS)
 562
 563 PGAC_PATH_PERL
 564 if test "$with_perl" = yes; then
 565   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 566   PGAC_CHECK_PERL_EMBED_LDFLAGS
 567 fi
 568
 569 if test "$with_python" = yes; then
 570   PGAC_PATH_PYTHON
 571   PGAC_CHECK_PYTHON_EMBED_SETUP
 572 fi
 573
 574
 575 ##
 576 ## Libraries
 577 ##
 578
 579 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 580 then
 581         AC_CHECK_LIB(bsd,      main)
 582 fi
 583 AC_CHECK_LIB(util,     setproctitle)
 584 AC_CHECK_LIB(m,        main)
 585 AC_CHECK_LIB(dl,       main)
 586 AC_CHECK_LIB(nsl,      main)
 587 AC_CHECK_LIB(socket,   main)
 588 AC_CHECK_LIB(ipc,      main)
 589 AC_CHECK_LIB(IPC,      main)
 590 AC_CHECK_LIB(lc,       main)
 591 AC_CHECK_LIB(dld,      main)
 592 AC_CHECK_LIB(ld,       main)
 593 AC_CHECK_LIB(compat,   main)
 594 AC_CHECK_LIB(BSD,      main)
 595 AC_CHECK_LIB(gen,      main)
 596 AC_CHECK_LIB(PW,       main)
 597 AC_CHECK_LIB(resolv,   main)
 598 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 599 # QNX:
 600 AC_CHECK_LIB(unix, main)
 601 AC_SEARCH_LIBS(crypt,  crypt)
 602 # BeOS:
 603 if test "$PORTNAME" = "beos"
 604 then
 605         AC_CHECK_LIB(bind, __inet_ntoa)
 606 fi
 607 # Solaris:
 608 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 609 # Cygwin:
 610 AC_CHECK_LIB(cygipc, shmget)
 611 # WIN32:
 612 if test "$PORTNAME" = "win32"
 613 then
 614         AC_CHECK_LIB(wsock32, main)
 615 fi
 616
 617 if test "$with_readline" = yes; then
 618   PGAC_CHECK_READLINE
 619   if test x"$pgac_cv_check_readline" = x"no"; then
 620     AC_MSG_ERROR([readline library not found
 621 If you have readline already installed, see config.log for details on the
 622 failure.  It is possible the compiler isn't looking in the proper directory.
 623 Use --without-readline to disable readline support.])
 624   fi
 625 fi
 626
 627 if test "$with_zlib" = yes; then
 628   AC_CHECK_LIB(z, inflate, [],
 629                [AC_MSG_ERROR([zlib library not found
 630 If you have zlib already installed, see config.log for details on the
 631 failure.  It is possible the compiler isn't looking in the proper directory.
 632 Use --without-zlib to disable zlib support.])])
 633 fi
 634
 635 if test "$enable_spinlocks" = yes; then
 636   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 637 else
 638   AC_MSG_WARN([
 639 *** Not using spinlocks will cause poor performance.])
 640 fi
 641
 642 if test "$with_krb4" = yes ; then
 643   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 644   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 645   AC_REPLACE_FUNCS([gethostname])
 646 fi
 647
 648 if test "$with_krb5" = yes ; then
 649   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 650                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 651   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 652                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 653   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 654                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 655 fi
 656
 657 if test "$with_openssl" = yes ; then
 658   dnl Order matters!
 659   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 660   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 661 fi
 662
 663 if test "$with_pam" = yes ; then
 664   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 665 fi
 666
 667
 668 ##
 669 ## Header files
 670 ##
 671
 672 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 673 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 674
 675 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 676 # netinet/in.h is included first.
 677 AC_CHECK_HEADERS(netinet/in.h)
 678 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 679 [AC_INCLUDES_DEFAULT
 680 #ifdef HAVE_NETINET_IN_H
 681 #include <netinet/in.h>
 682 #endif
 683 ])
 684
 685 if test "$with_readline" = yes; then
 686   AC_CHECK_HEADERS(readline/readline.h, [],
 687                    [AC_CHECK_HEADERS(editline/readline.h, [],
 688                          [AC_CHECK_HEADERS(readline.h, [],
 689                                      [AC_MSG_ERROR([readline header not found
 690 If you have readline already installed, see config.log for details on the
 691 failure.  It is possible the compiler isn't looking in the proper directory.
 692 Use --without-readline to disable readline support.])])])])
 693   AC_CHECK_HEADERS(readline/history.h, [],
 694                    [AC_CHECK_HEADERS(editline/history.h, [],
 695                          [AC_CHECK_HEADERS(history.h, [],
 696                                      [AC_MSG_ERROR([history header not found
 697 If you have readline already installed, see config.log for details on the
 698 failure.  It is possible the compiler isn't looking in the proper directory.
 699 Use --without-readline to disable readline support.])])])])
 700 fi
 701
 702 if test "$with_zlib" = yes; then
 703   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 704 If you have zlib already installed, see config.log for details on the
 705 failure.  It is possible the compiler isn't looking in the proper directory.
 706 Use --without-zlib to disable zlib support.])])
 707 fi
 708
 709 if test "$with_krb4" = yes ; then
 710   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 711 fi
 712
 713 if test "$with_krb5" = yes ; then
 714   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 715   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 716 fi
 717
 718 if test "$with_openssl" = yes ; then
 719   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 720   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 721 fi
 722
 723 if test "$with_pam" = yes ; then
 724   AC_CHECK_HEADERS(security/pam_appl.h, [],
 725                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 726                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 727 fi
 728
 729 if test "$with_rendezvous" = yes ; then
 730   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 731 fi
 732
 733
 734 ##
 735 ## Types, structures, compiler characteristics
 736 ##
 737
 738 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 739 AC_C_CONST
 740 AC_C_INLINE
 741 AC_C_STRINGIZE
 742 PGAC_C_SIGNED
 743 AC_C_VOLATILE
 744 PGAC_C_FUNCNAME_SUPPORT
 745 PGAC_STRUCT_TIMEZONE
 746 PGAC_UNION_SEMUN
 747 PGAC_STRUCT_SOCKADDR_UN
 748 PGAC_STRUCT_SOCKADDR_STORAGE
 749 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 750 PGAC_STRUCT_ADDRINFO
 751
 752 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 753 [#include <sys/param.h>
 754 #include <sys/types.h>
 755 #include <sys/socket.h>
 756 #include <sys/ucred.h>])
 757
 758 AC_CHECK_TYPES([struct option], [], [],
 759 [#ifdef HAVE_GETOPT_H
 760 #include <getopt.h>
 761 #endif])
 762
 763 if test "$with_zlib" = yes; then
 764   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 765   # did not).  While we could work around the lack of z_streamp, it
 766   # seems unwise to encourage people to use such old zlib versions...
 767   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 768 Use --without-zlib to disable zlib support.])],
 769                 [#include <zlib.h>])
 770 fi
 771
 772 if test "$with_krb5" = yes; then
 773 # Check for differences between MIT and Heimdal (KTH) releases
 774   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 775                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 776                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 777                                      [#include <krb5.h>])],
 778                    [#include <krb5.h>])
 779   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 780                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 781                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 782                                      [#include <krb5.h>])],
 783                    [#include <krb5.h>])
 784 fi
 785
 786
 787 ##
 788 ## Functions, global variables
 789 ##
 790
 791 PGAC_VAR_INT_TIMEZONE
 792 AC_FUNC_ACCEPT_ARGTYPES
 793 PGAC_FUNC_GETTIMEOFDAY_1ARG
 794
 795 # SunOS doesn't handle negative byte comparisons properly with +/- return
 796 AC_FUNC_MEMCMP
 797
 798 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 799
 800 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 801
 802 HAVE_IPV6=no
 803 AC_CHECK_TYPE([struct sockaddr_in6],
 804               [AC_CHECK_FUNC(inet_ntop,
 805                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 806                                                           HAVE_IPV6=yes])],
 807               [],
 808 [$ac_includes_default
 809 #include <netinet/in.h>])
 810 AC_SUBST(HAVE_IPV6)
 811
 812 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 813 [AC_TRY_LINK(
 814 [#include <machine/vmparam.h>
 815 #include <sys/exec.h>
 816 ],
 817 [PS_STRINGS->ps_nargvstr = 1;
 818 PS_STRINGS->ps_argvstr = "foo";],
 819 [pgac_cv_var_PS_STRINGS=yes],
 820 [pgac_cv_var_PS_STRINGS=no])])
 821 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 822   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 823 fi
 824
 825
 826 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 827 # is missing.  Yes, there are machines that have only one.  We may
 828 # also decide to use snprintf.c if snprintf() is present but does not
 829 # have working "long long int" support -- see below.
 830
 831 pgac_need_repl_snprintf=no
 832 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 833 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 834
 835
 836 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 837 # include/c.h will provide declarations.  Note this is a separate test
 838 # from whether the functions exist in the C library --- there are
 839 # systems that have the functions but don't bother to declare them :-(
 840
 841 AC_CHECK_DECLS([snprintf, vsnprintf])
 842
 843
 844 # do this one the hard way in case isinf() is a macro
 845 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 846 [AC_TRY_LINK(
 847 [#include <math.h>
 848 ],
 849 [double x = 0.0; int res = isinf(x);],
 850 [ac_cv_func_isinf=yes],
 851 [ac_cv_func_isinf=no])])
 852
 853 if test $ac_cv_func_isinf = yes ; then
 854   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 855 else
 856   AC_LIBOBJ(isinf)
 857   # Look for a way to implement a substitute for isinf()
 858   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 859 fi
 860
 861 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul unsetenv])
 862
 863 # system's version of getaddrinfo(), if any, may be used only if we found
 864 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 865 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 866   AC_REPLACE_FUNCS([getaddrinfo])
 867 else
 868   AC_LIBOBJ(getaddrinfo)
 869 fi
 870
 871 # similarly, use system's getopt_long() only if system provides struct option.
 872 if test x"$ac_cv_type_struct_option" = xyes ; then
 873   AC_REPLACE_FUNCS([getopt_long])
 874 else
 875   AC_LIBOBJ(getopt_long)
 876 fi
 877
 878 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 879 # We override the previous test that said fseeko/ftello didn't exist
 880 # OS tests are also done in include/c.h and port/fseeko.c
 881 case $host_os in bsdi*|netbsd*)
 882 ac_cv_func_fseeko=yes
 883 esac
 884
 885 # Solaris has a very slow qsort in certain cases, so we replace it.
 886 case $host_os in solaris*)
 887 AC_LIBOBJ(qsort) ;;
 888 esac
 889
 890 # Win32 support
 891 case $host_os in mingw*)
 892 AC_LIBOBJ(copydir)
 893 AC_LIBOBJ(gettimeofday)
 894 AC_LIBOBJ(open)
 895 AC_LIBOBJ(pipe)
 896 AC_LIBOBJ(rand)
 897 AC_DEFINE(USE_PGTZ, 1,
 898         [Define to 1 to use our own timezone library])
 899 USE_PGTZ=yes
 900 AC_SUBST(USE_PGTZ) ;;
 901 esac
 902
 903 # Win32 can't to rename or unlink on an open file
 904 case $host_os in mingw*|cygwin*)
 905 AC_LIBOBJ(dirmod) ;;
 906 esac
 907
 908 if test "$with_readline" = yes; then
 909   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 910   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 911   AC_CHECK_FUNCS([replace_history_entry])
 912 fi
 913
 914
 915 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 916 AC_MSG_CHECKING(for finite)
 917 AC_TRY_LINK([#include <math.h>],
 918             [int dummy=finite(1.0);],
 919             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 920 AC_MSG_RESULT(yes)],
 921             [AC_MSG_RESULT(no)])
 922
 923 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 924 dnl (especially on GNU libc)
 925 dnl See also comments in c.h.
 926 AC_MSG_CHECKING(for sigsetjmp)
 927 AC_TRY_LINK([#include <setjmp.h>],
 928             [sigjmp_buf x; sigsetjmp(x, 1);],
 929             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 930 AC_MSG_RESULT(yes)],
 931             [AC_MSG_RESULT(no)])
 932
 933 AC_CHECK_FUNC(syslog,
 934               [AC_CHECK_HEADER(syslog.h,
 935                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 936
 937 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 938 [AC_TRY_LINK([#include <unistd.h>],
 939   [extern int optreset; optreset = 1;],
 940   [pgac_cv_var_int_optreset=yes],
 941   [pgac_cv_var_int_optreset=no])])
 942 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 943   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 944 fi
 945
 946 AC_CHECK_FUNCS([strtoll strtoq], [break])
 947 AC_CHECK_FUNCS([strtoull strtouq], [break])
 948
 949 # Check for one of atexit() or on_exit()
 950 AC_CHECK_FUNCS(atexit, [],
 951                [AC_CHECK_FUNCS(on_exit, [],
 952                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 953
 954 AC_FUNC_FSEEKO
 955
 956 #
 957 # Pthreads
 958 #
 959 # For each platform, we need to know about any special compile and link
 960 # libraries, and whether the normal C function names are thread-safe.
 961 # See the comment at the top of src/port/thread.c for more information.
 962 #
 963 if test "$enable_thread_safety" = yes; then
 964 ACX_PTHREAD     # set thread flags
 965
 966 # Some platforms use these, so just defineed them.  They can't hurt if they
 967 # are not supported.
 968 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 969
 970
 971 # At this point, we don't want to muck with the compiler name for threading.
 972 # Let's see who fails, perhaps AIX.  2004-04-23
 973 if test "$PTHREAD_CC" != "$CC"; then
 974 AC_MSG_ERROR([
 975 PostgreSQL does not support platforms that require a special
 976 compiler binary for thread-safety.
 977 ])
 978 fi
 979
 980 if test "$THREAD_SUPPORT" = no; then
 981 AC_MSG_ERROR([
 982 Cannot enable threads on your platform.
 983 Your platform is known to not support thread-safe programs.
 984 For details, compile and run src/bin/pg_thread_test.
 985 ])
 986 fi
 987
 988 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
 989
 990 # Check for *_r functions
 991 _CFLAGS="$CFLAGS"
 992 _LIBS="$LIBS"
 993 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 994 LIBS="$LIBS $PTHREAD_LIBS"
 995 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 996 CFLAGS="$_CFLAGS"
 997 LIBS="$_LIBS"
 998
 999 PGAC_FUNC_GETPWUID_R_5ARG
1000
1001 else
1002 # do not use values from template file
1003 PTHREAD_CFLAGS=
1004 PTHREAD_LIBS=
1005 fi
1006
1007 AC_SUBST(PTHREAD_CFLAGS)
1008 AC_SUBST(PTHREAD_LIBS)
1009
1010
1011 # This test makes sure that run tests work at all.  Sometimes a shared
1012 # library is found by the linker, but the runtime linker can't find it.
1013 # This check should come after all modifications of compiler or linker
1014 # variables, and before any other run tests.
1015 AC_MSG_CHECKING([test program])
1016 AC_TRY_RUN([int main() { return 0; }],
1017 [AC_MSG_RESULT(ok)],
1018 [AC_MSG_RESULT(failed)
1019 AC_MSG_ERROR([[
1020 *** Could not execute a simple test program.  This may be a problem
1021 *** related to locating shared libraries.  Check the file 'config.log'
1022 *** for the exact reason.]])],
1023 [AC_MSG_RESULT([cross-compiling])])
1024
1025
1026 dnl Check to see if we have a working 64-bit integer type.
1027 dnl This breaks down into two steps:
1028 dnl (1) figure out if the compiler has a 64-bit int type with working
1029 dnl arithmetic, and if so
1030 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1031 dnl snprintf is the only library routine we really need for int8 support.)
1032 dnl It's entirely possible to have a compiler that handles a 64-bit type
1033 dnl when the C library doesn't; this is fairly likely when using gcc on
1034 dnl an older platform, for example.
1035 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1036 dnl we force our own version of snprintf() to be used instead.
1037 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1038
1039 PGAC_TYPE_64BIT_INT([long int])
1040
1041 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1042   PGAC_TYPE_64BIT_INT([long long int])
1043 fi
1044
1045
1046 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1047
1048 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1049   AC_TRY_COMPILE([
1050 #define INT64CONST(x)  x##LL
1051 long long int foo = INT64CONST(0x1234567890123456);
1052 ],
1053         [],
1054         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1055         [])
1056 fi
1057
1058
1059 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1060 # we found we need to use "long long int", better check.  We cope with
1061 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1062 # work, fall back to our own snprintf emulation (which we know uses %lld).
1063
1064 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1065   if test $pgac_need_repl_snprintf = no; then
1066     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1067     if test "$LONG_LONG_INT_FORMAT" = ""; then
1068       # Force usage of our own snprintf, since system snprintf is broken
1069       pgac_need_repl_snprintf=yes
1070       LONG_LONG_INT_FORMAT='%lld'
1071     fi
1072   else
1073     # Here if we previously decided we needed to use our own snprintf
1074     LONG_LONG_INT_FORMAT='%lld'
1075   fi
1076   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1077   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1078   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1079 else
1080   # Here if we are not using 'long long int' at all
1081   INT64_FORMAT='"%ld"'
1082   UINT64_FORMAT='"%lu"'
1083 fi
1084
1085 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1086                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1087
1088 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1089                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1090
1091 if test $pgac_need_repl_snprintf = yes; then
1092   AC_LIBOBJ(snprintf)
1093 fi
1094
1095 # Need a #define for the size of Datum (unsigned long)
1096 AC_CHECK_SIZEOF([unsigned long])
1097
1098 # Determine memory alignment requirements for the basic C data types.
1099
1100 PGAC_CHECK_ALIGNOF(short)
1101 PGAC_CHECK_ALIGNOF(int)
1102 PGAC_CHECK_ALIGNOF(long)
1103 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1104   PGAC_CHECK_ALIGNOF(long long int)
1105 fi
1106 PGAC_CHECK_ALIGNOF(double)
1107
1108 # Compute maximum alignment of any basic type.
1109 # We assume long's alignment is at least as strong as char, short, or int;
1110 # but we must check long long (if it exists) and double.
1111
1112 MAX_ALIGNOF=$pgac_cv_alignof_long
1113 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1114   MAX_ALIGNOF=$pgac_cv_alignof_double
1115 fi
1116 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1117   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1118 fi
1119 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1120
1121
1122 # Some platforms predefine the types int8, int16, etc.  Only check
1123 # a (hopefully) representative subset.
1124 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1125 [#include <stdio.h>
1126 #ifdef HAVE_SUPPORTDEFS_H
1127 #include <SupportDefs.h>
1128 #endif])
1129
1130 # We also check for sig_atomic_t, which *should* be defined per ANSI
1131 # C, but is missing on some old platforms.
1132 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1133
1134
1135 PGAC_FUNC_POSIX_SIGNALS
1136 if test $ac_cv_func_fseeko = yes; then
1137 AC_SYS_LARGEFILE
1138 fi
1139
1140
1141 # Select semaphore implementation type.
1142 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1143   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1144   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1145 else
1146   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1147     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1148     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1149   else
1150     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1151     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1152   fi
1153 fi
1154
1155
1156 # Select shared-memory implementation type.
1157 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1158 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1159
1160
1161 if test "$enable_nls" = yes ; then
1162   PGAC_CHECK_GETTEXT
1163 fi
1164
1165 # Check for Tcl configuration script tclConfig.sh
1166 if test "$with_tcl" = yes; then
1167     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1168     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1169                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1170     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1171 fi
1172
1173 #
1174 # Check for DocBook and tools
1175 #
1176 PGAC_PROG_NSGMLS
1177 PGAC_PROG_JADE
1178 PGAC_CHECK_DOCBOOK(4.2)
1179 PGAC_PATH_DOCBOOK_STYLESHEETS
1180 PGAC_PATH_COLLATEINDEX
1181 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1182
1183 # Thread testing
1184
1185 # We have to run the thread test near the end so we have all our symbols
1186 # defined.  Cross compiling throws a warning.
1187 #
1188 if test "$enable_thread_safety" = yes; then
1189 AC_MSG_CHECKING([thread safety of required library functions])
1190
1191 _CFLAGS="$CFLAGS"
1192 _LIBS="$LIBS"
1193 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1194 LIBS="$LIBS $PTHREAD_LIBS"
1195 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1196   [AC_MSG_RESULT(yes)],
1197   [AC_MSG_RESULT(no)
1198   AC_MSG_ERROR([
1199 *** Thread test program failed.  Your platform is not thread-safe.
1200 *** Check the file 'config.log'for the exact reason.])],
1201   [AC_MSG_RESULT(maybe)
1202   AC_MSG_WARN([
1203 *** Skipping thread test program because of cross-compile build.
1204 *** Run the program in src/tools/thread on the target matchine.
1205 ])])
1206 CFLAGS="$_CFLAGS"
1207 LIBS="$_LIBS"
1208 fi
1209
1210 # prepare build tree if outside source tree
1211 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1212 # Note 2: /bin/pwd might be better than shell's built-in at getting
1213 #         a symlink-free name.
1214 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1215   vpath_build=no
1216 else
1217   vpath_build=yes
1218   if test "$no_create" != yes; then
1219     _AS_ECHO_N([preparing build tree... ])
1220     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1221     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1222       || AC_MSG_ERROR(failed)
1223     AC_MSG_RESULT(done)
1224   fi
1225 fi
1226 AC_SUBST(vpath_build)
1227
1228
1229 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1230
1231 AC_CONFIG_LINKS([
1232   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1233   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1234   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1235   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1236   src/include/pg_config_os.h:src/include/port/${template}.h
1237   src/Makefile.port:src/makefiles/Makefile.${template}
1238 ])
1239
1240 AC_CONFIG_HEADERS([src/include/pg_config.h],
1241 [
1242 # Update timestamp for pg_config.h (see Makefile.global)
1243 echo >src/include/stamp-h
1244 ])
1245
1246 AC_OUTPUT