granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.487 2006/11/07 17:59:02 pgsql Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2beta3], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2006, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # DTrace
 210 #
 211 PGAC_ARG_BOOL(enable, dtrace, no,
 212               [  --enable-dtrace         build with DTrace support],
 213 [AC_DEFINE([ENABLE_DTRACE], 1,
 214            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 215 AC_CHECK_PROGS(DTRACE, dtrace)
 216 if test -z "$DTRACE"; then
 217   AC_MSG_ERROR([dtrace not found])
 218 fi
 219 AC_SUBST(DTRACEFLAGS)])
 220 AC_SUBST(enable_dtrace)
 221
 222 #
 223 # C compiler
 224 #
 225
 226 # For historical reasons you can also use --with-CC to specify the C compiler
 227 # to use, although the standard way to do this is to set the CC environment
 228 # variable.
 229 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 230
 231 case $template in
 232   aix) pgac_cc_list="gcc xlc";;
 233  irix) pgac_cc_list="cc";; # no gcc
 234     *) pgac_cc_list="gcc cc";;
 235 esac
 236
 237 AC_PROG_CC([$pgac_cc_list])
 238
 239 unset CFLAGS
 240
 241 #
 242 # Read the template
 243 #
 244 . "$srcdir/src/template/$template" || exit
 245
 246 # CFLAGS are selected so:
 247 # If the user specifies something in the environment, that is used.
 248 # else:  If the template file set something, that is used.
 249 # else:  If the compiler is GCC, then we use -O2.
 250 # else:  If the compiler is something else, then we use -0.
 251
 252 if test "$ac_env_CFLAGS_set" = set; then
 253   CFLAGS=$ac_env_CFLAGS_value
 254 elif test "${CFLAGS+set}" = set; then
 255   : # (keep what template set)
 256 elif test "$GCC" = yes; then
 257   CFLAGS="-O2"
 258 else
 259   # if the user selected debug mode, don't use -O
 260   if test "$enable_debug" != yes; then
 261     CFLAGS="-O"
 262   fi
 263 fi
 264
 265 # Some versions of GCC support some additional useful warning flags.
 266 # Check whether they are supported, and add them to CFLAGS if so.
 267
 268 if test "$GCC" = yes; then
 269
 270 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 271 # So we have to check if "GCC" is really ICC.
 272 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 273 choke me
 274 @%:@endif], [ICC=[yes]], [ICC=[no]])
 275
 276   if test "$ICC" = no; then
 277     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 278
 279     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 280     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 281   else
 282     # Intel compiler has a bug/misoptimization in checking for
 283     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 284     # CFLAGS.
 285     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 286   fi
 287
 288   # Disable strict-aliasing rules; needed for gcc 3.3+
 289   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 290 elif test x"${CC}" = x"xlc"; then
 291   # AIX xlc has to have strict aliasing turned off too
 292   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 293 fi
 294
 295 # supply -g if --enable-debug
 296 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 297   CFLAGS="$CFLAGS -g"
 298 fi
 299
 300 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 301
 302 # We already have this in Makefile.win32, but configure needs it too
 303 if test "$PORTNAME" = "win32"; then
 304   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 305 fi
 306
 307 # Check if the compiler still works with the template settings
 308 AC_MSG_CHECKING([whether the C compiler still works])
 309 AC_TRY_LINK([], [return 0;],
 310   [AC_MSG_RESULT(yes)],
 311   [AC_MSG_RESULT(no)
 312    AC_MSG_ERROR([cannot proceed])])
 313
 314 # Defend against gcc -ffast-math
 315 if test "$GCC" = yes; then
 316 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 317 choke me
 318 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 319 fi
 320
 321 AC_PROG_CPP
 322 AC_SUBST(GCC)
 323
 324 # Create compiler version string
 325 if test x"$GCC" = x"yes" ; then
 326   cc_string="GCC `${CC} --version | sed q`"
 327 else
 328   cc_string=$CC
 329 fi
 330 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 331                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 332                    [A string containing the version number, platform, and C compiler])
 333
 334
 335 #
 336 # Set up TAS assembly code if needed; the template file has now had its
 337 # chance to request this.
 338 #
 339 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 340
 341 if test "$need_tas" = yes ; then
 342   TAS=tas.o
 343 else
 344   TAS=""
 345 fi
 346 AC_SUBST(TAS)
 347
 348
 349 #
 350 # Automatic dependency tracking
 351 #
 352 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 353               [autodepend=yes])
 354 AC_SUBST(autodepend)
 355
 356
 357 #
 358 # Enable assert checks
 359 #
 360 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 361               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 362                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 363
 364
 365 #
 366 # Include directories
 367 #
 368 ac_save_IFS=$IFS
 369 IFS="${IFS}${PATH_SEPARATOR}"
 370 # SRCH_INC comes from the template file
 371 for dir in $with_includes $SRCH_INC; do
 372   if test -d "$dir"; then
 373     INCLUDES="$INCLUDES -I$dir"
 374   else
 375     AC_MSG_WARN([*** Include directory $dir does not exist.])
 376   fi
 377 done
 378 IFS=$ac_save_IFS
 379 AC_SUBST(INCLUDES)
 380
 381
 382 #
 383 # Library directories
 384 #
 385 ac_save_IFS=$IFS
 386 IFS="${IFS}${PATH_SEPARATOR}"
 387 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 388 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 389   if test -d "$dir"; then
 390     LIBDIRS="$LIBDIRS -L$dir"
 391   else
 392     AC_MSG_WARN([*** Library directory $dir does not exist.])
 393   fi
 394 done
 395 IFS=$ac_save_IFS
 396
 397 #
 398 # Enable thread-safe client libraries
 399 #
 400 AC_MSG_CHECKING([allow thread-safe client libraries])
 401 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 402 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 403 if test "$enable_thread_safety" = yes -o \
 404         "$enable_thread_safety_force" = yes; then
 405   enable_thread_safety="yes"    # for 'force'
 406   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 407           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 408 fi
 409 AC_MSG_RESULT([$enable_thread_safety])
 410 AC_SUBST(enable_thread_safety)
 411
 412 #
 413 # Optionally build Tcl modules (PL/Tcl)
 414 #
 415 AC_MSG_CHECKING([whether to build with Tcl])
 416 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 417 AC_MSG_RESULT([$with_tcl])
 418 AC_SUBST([with_tcl])
 419
 420 # We see if the path to the Tcl/Tk configuration scripts is specified.
 421 # This will override the use of tclsh to find the paths to search.
 422
 423 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 424
 425 #
 426 # Optionally build Perl modules (PL/Perl)
 427 #
 428 AC_MSG_CHECKING([whether to build Perl modules])
 429 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 430 AC_MSG_RESULT([$with_perl])
 431 AC_SUBST(with_perl)
 432
 433 #
 434 # Optionally build Python modules (PL/Python)
 435 #
 436 AC_MSG_CHECKING([whether to build Python modules])
 437 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 438 AC_MSG_RESULT([$with_python])
 439 AC_SUBST(with_python)
 440
 441 #
 442 # Kerberos 5
 443 #
 444 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 445 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 446 [
 447   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 448   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 449 ])
 450 AC_MSG_RESULT([$with_krb5])
 451 AC_SUBST(with_krb5)
 452
 453
 454 AC_SUBST(krb_srvtab)
 455
 456
 457 #
 458 # Kerberos configuration parameters
 459 #
 460 PGAC_ARG_REQ(with, krb-srvnam,
 461              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 462              [],
 463              [with_krb_srvnam="postgres"])
 464 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 465                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 466
 467
 468 #
 469 # PAM
 470 #
 471 AC_MSG_CHECKING([whether to build with PAM support])
 472 PGAC_ARG_BOOL(with, pam, no,
 473               [  --with-pam              build with PAM support],
 474               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 475 AC_MSG_RESULT([$with_pam])
 476 AC_SUBST(with_pam)
 477
 478
 479 #
 480 # LDAP
 481 #
 482 AC_MSG_CHECKING([whether to build with LDAP support])
 483 PGAC_ARG_BOOL(with, ldap, no,
 484               [  --with-ldap             build with LDAP support],
 485               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 486 AC_MSG_RESULT([$with_ldap])
 487 AC_SUBST(with_ldap)
 488
 489
 490 #
 491 # Bonjour
 492 #
 493 AC_MSG_CHECKING([whether to build with Bonjour support])
 494 PGAC_ARG_BOOL(with, bonjour, no,
 495               [  --with-bonjour          build with Bonjour support],
 496               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 497 AC_MSG_RESULT([$with_bonjour])
 498 AC_SUBST(with_bonjour)
 499
 500
 501 #
 502 # OpenSSL
 503 #
 504 AC_MSG_CHECKING([whether to build with OpenSSL support])
 505 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 506               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 507 AC_MSG_RESULT([$with_openssl])
 508 AC_SUBST(with_openssl)
 509
 510
 511 #
 512 # Readline
 513 #
 514 PGAC_ARG_BOOL(with, readline, yes,
 515               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 516 # readline on MinGW has problems with backslashes in psql and other bugs.
 517 # This is particularly a problem with non-US code pages.
 518 # Therefore disable its use until we understand the cause. 2004-07-20
 519 if test "$PORTNAME" = "win32"; then
 520   if test "$with_readline" = yes; then
 521     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 522     with_readline=no
 523   fi
 524 fi
 525
 526
 527 #
 528 # Prefer libedit
 529 #
 530 PGAC_ARG_BOOL(with, libedit-preferred, no,
 531               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 532
 533
 534 #
 535 # Zlib
 536 #
 537 PGAC_ARG_BOOL(with, zlib, yes,
 538               [  --without-zlib          do not use Zlib])
 539 AC_SUBST(with_zlib)
 540
 541 #
 542 # Elf
 543 #
 544
 545 # Assume system is ELF if it predefines __ELF__ as 1,
 546 # otherwise believe host_os based default.
 547 case $host_os in
 548     freebsd1*|freebsd2*) elf=no;;
 549     freebsd3*|freebsd4*) elf=yes;;
 550 esac
 551
 552 AC_EGREP_CPP(yes,
 553 [#if __ELF__
 554   yes
 555 #endif
 556 ],
 557 [ELF_SYS=true],
 558 [if test "X$elf" = "Xyes" ; then
 559   ELF_SYS=true
 560 else
 561   ELF_SYS=
 562 fi])
 563 AC_SUBST(ELF_SYS)
 564
 565 #
 566 # Assignments
 567 #
 568
 569 CPPFLAGS="$CPPFLAGS $INCLUDES"
 570 LDFLAGS="$LDFLAGS $LIBDIRS"
 571
 572 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 573 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 574
 575 AC_ARG_VAR(LDFLAGS_SL)
 576
 577 AC_PROG_AWK
 578 PGAC_PATH_FLEX
 579 AC_PROG_LN_S
 580 PGAC_PROG_LD
 581 AC_SUBST(LD)
 582 AC_SUBST(with_gnu_ld)
 583 case $host_os in sysv5*)
 584   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 585   [
 586     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 587     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 588     LDFLAGS=$pgac_save_LDFLAGS
 589   ])
 590   ld_R_works=$pgac_cv_prog_ld_R
 591   AC_SUBST(ld_R_works)
 592 esac
 593 AC_PROG_RANLIB
 594 AC_PATH_PROG(TAR, tar)
 595 PGAC_CHECK_STRIP
 596
 597 if test -z "$YACC"; then
 598   AC_CHECK_PROGS(YACC, ['bison -y'])
 599
 600   if test "$YACC"; then
 601     if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 602       AC_MSG_WARN([
 603 *** The installed version of Bison is too old to use with PostgreSQL.
 604 *** Bison version 1.875 or later is required.])
 605       YACC=""
 606     fi
 607   fi
 608
 609   if test -z "$YACC"; then
 610     AC_MSG_WARN([
 611 *** Without Bison you will not be able to build PostgreSQL from CVS nor
 612 *** change any of the parser definition files.  You can obtain Bison from
 613 *** a GNU mirror site.  (If you are using the official distribution of
 614 *** PostgreSQL then you do not need to worry about this, because the Bison
 615 *** output is pre-generated.)  To use a different yacc program (possible,
 616 *** but not recommended), set the environment variable YACC before running
 617 *** 'configure'.])
 618   fi
 619 fi
 620 AC_SUBST(YFLAGS)
 621
 622 PGAC_PATH_PERL
 623 if test "$with_perl" = yes; then
 624   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 625   PGAC_CHECK_PERL_EMBED_LDFLAGS
 626 fi
 627
 628 if test "$with_python" = yes; then
 629   PGAC_PATH_PYTHON
 630   PGAC_CHECK_PYTHON_EMBED_SETUP
 631 fi
 632
 633 # Supply a numeric version string for use by 3rd party add-ons
 634 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 635 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 636 tr '.' '        ' |
 637 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 638 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 639
 640 ##
 641 ## Libraries
 642 ##
 643 ## Most libraries are included only if they demonstrably provide a function
 644 ## we need, but libm is an exception: always include it, because there are
 645 ## too many compilers that play cute optimization games that will break
 646 ## probes for standard functions such as pow().
 647 ##
 648
 649 AC_CHECK_LIB(m, main)
 650 AC_SEARCH_LIBS(setproctitle, util)
 651 AC_SEARCH_LIBS(dlopen, dl)
 652 AC_SEARCH_LIBS(socket, [socket wsock32])
 653 AC_SEARCH_LIBS(shl_load, dld)
 654 # We only use libld in port/dynloader/aix.c
 655 case $host_os in
 656      aix*)
 657         AC_SEARCH_LIBS(ldopen, ld)
 658         ;;
 659 esac
 660 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 661 AC_SEARCH_LIBS(crypt, crypt)
 662 # Solaris:
 663 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 664 # Cygwin:
 665 AC_SEARCH_LIBS(shmget, cygipc)
 666
 667 if test "$with_readline" = yes; then
 668   PGAC_CHECK_READLINE
 669   if test x"$pgac_cv_check_readline" = x"no"; then
 670     AC_MSG_ERROR([readline library not found
 671 If you have readline already installed, see config.log for details on the
 672 failure.  It is possible the compiler isn't looking in the proper directory.
 673 Use --without-readline to disable readline support.])
 674   fi
 675 fi
 676
 677 if test "$with_zlib" = yes; then
 678   AC_CHECK_LIB(z, inflate, [],
 679                [AC_MSG_ERROR([zlib library not found
 680 If you have zlib already installed, see config.log for details on the
 681 failure.  It is possible the compiler isn't looking in the proper directory.
 682 Use --without-zlib to disable zlib support.])])
 683 fi
 684
 685 if test "$enable_spinlocks" = yes; then
 686   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 687 else
 688   AC_MSG_WARN([
 689 *** Not using spinlocks will cause poor performance.])
 690 fi
 691
 692 if test "$with_krb5" = yes ; then
 693   if test "$PORTNAME" != "win32"; then
 694      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 695                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 696      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 697                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 698   else
 699      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 700                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 701   fi
 702 fi
 703
 704 if test "$with_openssl" = yes ; then
 705   dnl Order matters!
 706   if test "$PORTNAME" != "win32"; then
 707      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 708      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 709   else
 710      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 711      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 712   fi
 713 fi
 714
 715 if test "$with_pam" = yes ; then
 716   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 717 fi
 718
 719
 720 ##
 721 ## Header files
 722 ##
 723
 724 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 725 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 726
 727 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 728 # netinet/in.h is included first.
 729 AC_CHECK_HEADERS(netinet/in.h)
 730 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 731 [AC_INCLUDES_DEFAULT
 732 #ifdef HAVE_NETINET_IN_H
 733 #include <netinet/in.h>
 734 #endif
 735 ])
 736
 737 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 738   AC_CHECK_HEADERS(readline/readline.h, [],
 739         [AC_CHECK_HEADERS(readline.h, [],
 740                 [AC_MSG_ERROR([readline header not found
 741 If you have readline already installed, see config.log for details on the
 742 failure.  It is possible the compiler isn't looking in the proper directory.
 743 Use --without-readline to disable readline support.])])])
 744   AC_CHECK_HEADERS(readline/history.h, [],
 745         [AC_CHECK_HEADERS(history.h, [],
 746                 [AC_MSG_ERROR([history header not found
 747 If you have readline already installed, see config.log for details on the
 748 failure.  It is possible the compiler isn't looking in the proper directory.
 749 Use --without-readline to disable readline support.])])])
 750 fi
 751
 752 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 753 # Some installations of libedit usurp /usr/include/readline/, which seems
 754 # bad practice, since in combined installations readline will have its headers
 755 # there.  We might have to resort to AC_EGREP checks to make sure we found
 756 # the proper header...
 757   AC_CHECK_HEADERS(editline/readline.h, [],
 758         [AC_CHECK_HEADERS(readline.h, [],
 759                 [AC_CHECK_HEADERS(readline/readline.h, [],
 760                         [AC_MSG_ERROR([readline header not found
 761 If you have libedit already installed, see config.log for details on the
 762 failure.  It is possible the compiler isn't looking in the proper directory.
 763 Use --without-readline to disable libedit support.])])])])
 764 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 765 # not be there at all.  Hence, don't complain if not found.  We must check
 766 # though, since in yet other versions it is an independent header.
 767   AC_CHECK_HEADERS(editline/history.h, [],
 768         [AC_CHECK_HEADERS(history.h, [],
 769                 [AC_CHECK_HEADERS(readline/history.h)])])
 770 fi
 771
 772 if test "$with_zlib" = yes; then
 773   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 774 If you have zlib already installed, see config.log for details on the
 775 failure.  It is possible the compiler isn't looking in the proper directory.
 776 Use --without-zlib to disable zlib support.])])
 777 fi
 778
 779 if test "$with_krb5" = yes ; then
 780   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 781 fi
 782
 783 if test "$with_openssl" = yes ; then
 784   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 785   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 786 fi
 787
 788 if test "$with_pam" = yes ; then
 789   AC_CHECK_HEADERS(security/pam_appl.h, [],
 790                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 791                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 792 fi
 793
 794 if test "$with_ldap" = yes ; then
 795   if test "$PORTNAME" != "win32"; then
 796      AC_CHECK_HEADERS(ldap.h, [],
 797                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 798   else
 799      AC_CHECK_HEADERS(winldap.h, [],
 800                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 801                       [AC_INCLUDES_DEFAULT
 802 #include <windows.h>
 803                       ])
 804   fi
 805 fi
 806
 807 if test "$with_bonjour" = yes ; then
 808   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 809 fi
 810
 811
 812 ##
 813 ## Types, structures, compiler characteristics
 814 ##
 815
 816 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 817 AC_C_CONST
 818 AC_C_INLINE
 819 AC_C_STRINGIZE
 820 PGAC_C_SIGNED
 821 AC_C_VOLATILE
 822 PGAC_C_FUNCNAME_SUPPORT
 823 PGAC_STRUCT_TIMEZONE
 824 PGAC_UNION_SEMUN
 825 PGAC_STRUCT_SOCKADDR_UN
 826 PGAC_STRUCT_SOCKADDR_STORAGE
 827 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 828 PGAC_STRUCT_ADDRINFO
 829
 830 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 831 [#include <sys/param.h>
 832 #include <sys/types.h>
 833 #include <sys/socket.h>
 834 #include <sys/ucred.h>])
 835
 836 AC_CHECK_TYPES([struct option], [], [],
 837 [#ifdef HAVE_GETOPT_H
 838 #include <getopt.h>
 839 #endif])
 840
 841 if test "$with_zlib" = yes; then
 842   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 843   # did not).  While we could work around the lack of z_streamp, it
 844   # seems unwise to encourage people to use such old zlib versions...
 845   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 846 Use --without-zlib to disable zlib support.])],
 847                 [#include <zlib.h>])
 848 fi
 849
 850 if test "$with_krb5" = yes; then
 851 # Check for differences between MIT and Heimdal (KTH) releases
 852   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 853                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 854                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 855                                      [#include <krb5.h>])],
 856                    [#include <krb5.h>])
 857   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 858                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 859                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 860                                      [#include <krb5.h>])],
 861                    [#include <krb5.h>])
 862 fi
 863
 864
 865 ##
 866 ## Functions, global variables
 867 ##
 868
 869 PGAC_VAR_INT_TIMEZONE
 870 AC_FUNC_ACCEPT_ARGTYPES
 871 PGAC_FUNC_GETTIMEOFDAY_1ARG
 872
 873 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 874
 875 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 876 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 877 AC_CHECK_DECLS(strlcpy)
 878 # This is probably only present on Darwin, but may as well check always
 879 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 880
 881 HAVE_IPV6=no
 882 AC_CHECK_TYPE([struct sockaddr_in6],
 883         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 884          HAVE_IPV6=yes],
 885         [],
 886 [$ac_includes_default
 887 #include <netinet/in.h>])
 888 AC_SUBST(HAVE_IPV6)
 889
 890 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 891 [AC_TRY_LINK(
 892 [#include <machine/vmparam.h>
 893 #include <sys/exec.h>
 894 ],
 895 [PS_STRINGS->ps_nargvstr = 1;
 896 PS_STRINGS->ps_argvstr = "foo";],
 897 [pgac_cv_var_PS_STRINGS=yes],
 898 [pgac_cv_var_PS_STRINGS=no])])
 899 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 900   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 901 fi
 902
 903
 904 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 905 # is missing.  Yes, there are machines that have only one.  We may
 906 # also decide to use snprintf.c if snprintf() is present but does not
 907 # have all the features we need --- see below.
 908
 909 if test "$PORTNAME" = "win32"; then
 910   # Win32 gets snprintf.c built unconditionally.
 911   #
 912   # To properly translate all NLS languages strings, we must support the
 913   # *printf() %$ format, which allows *printf() arguments to be selected
 914   # by position in the translated string.
 915   #
 916   # libintl versions < 0.13 use the native *printf() functions, and Win32
 917   # *printf() doesn't understand %$, so we must use our /port versions,
 918   # which do understand %$. libintl versions >= 0.13 include their own
 919   # *printf versions on Win32.  The libintl 0.13 release note text is:
 920   #
 921   #   C format strings with positions, as they arise when a translator
 922   #   needs to reorder a sentence, are now supported on all platforms.
 923   #   On those few platforms (NetBSD and Woe32) for which the native
 924   #   printf()/fprintf()/... functions don't support such format
 925   #   strings, replacements are provided through <libintl.h>.
 926   #
 927   # We could use libintl >= 0.13's *printf() if we were sure that we had
 928   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 929   # to guarantee that, it is best to just use our own, so we are sure to
 930   # get %$ support. In include/port.h we disable the *printf() macros
 931   # that might have been defined by libintl.
 932   #
 933   # We do this unconditionally whether NLS is used or not so we are sure
 934   # that all Win32 libraries and binaries behave the same.
 935   pgac_need_repl_snprintf=yes
 936 else
 937   pgac_need_repl_snprintf=no
 938   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 939   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 940 fi
 941
 942
 943 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 944 # include/c.h will provide declarations.  Note this is a separate test
 945 # from whether the functions exist in the C library --- there are
 946 # systems that have the functions but don't bother to declare them :-(
 947
 948 AC_CHECK_DECLS([snprintf, vsnprintf])
 949
 950
 951 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 952 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 953 [AC_TRY_LINK([
 954 #include <math.h>
 955 double glob_double;
 956 ],
 957 [return isinf(glob_double) ? 0 : 1;],
 958 [ac_cv_func_isinf=yes],
 959 [ac_cv_func_isinf=no])])
 960
 961 if test $ac_cv_func_isinf = yes ; then
 962   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 963 else
 964   AC_LIBOBJ(isinf)
 965   # Look for a way to implement a substitute for isinf()
 966   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 967 fi
 968
 969 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcpy strtol strtoul unsetenv])
 970
 971 # System's version of getaddrinfo(), if any, may be used only if we found
 972 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 973 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 974 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 975 # because we want to use our own getaddrinfo.c on Windows anyway.)
 976 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 977   AC_REPLACE_FUNCS([getaddrinfo])
 978 else
 979   AC_LIBOBJ(getaddrinfo)
 980 fi
 981
 982 # similarly, use system's getopt_long() only if system provides struct option.
 983 if test x"$ac_cv_type_struct_option" = xyes ; then
 984   AC_REPLACE_FUNCS([getopt_long])
 985 else
 986   AC_LIBOBJ(getopt_long)
 987 fi
 988
 989 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 990 # We override the previous test that said fseeko/ftello didn't exist
 991 # OS tests are also done in include/c.h and port/fseeko.c
 992 case $host_os in bsdi*|netbsd*)
 993 ac_cv_func_fseeko=yes
 994 esac
 995
 996 # Win32 support
 997 if test "$PORTNAME" = "win32"; then
 998 AC_LIBOBJ(gettimeofday)
 999 AC_LIBOBJ(kill)
1000 AC_LIBOBJ(open)
1001 AC_LIBOBJ(rand)
1002 AC_LIBOBJ(win32error)
1003 AC_DEFINE([HAVE_SYMLINK], 1,
1004           [Define to 1 if you have the `symlink' function.])
1005 fi
1006
1007 if test "$with_readline" = yes; then
1008   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1009   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1010   AC_CHECK_FUNCS([replace_history_entry])
1011 fi
1012
1013
1014 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
1015 AC_MSG_CHECKING(for finite)
1016 AC_TRY_LINK([
1017 #include <math.h>
1018 double glob_double;
1019 ],
1020             [return finite(glob_double) ? 0 : 1;],
1021             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
1022 AC_MSG_RESULT(yes)],
1023             [AC_MSG_RESULT(no)])
1024
1025 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1026 dnl (especially on GNU libc)
1027 dnl See also comments in c.h.
1028 AC_MSG_CHECKING(for sigsetjmp)
1029 AC_TRY_LINK([#include <setjmp.h>],
1030             [sigjmp_buf x; sigsetjmp(x, 1);],
1031             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1032 AC_MSG_RESULT(yes)],
1033             [AC_MSG_RESULT(no)])
1034
1035 AC_CHECK_FUNC(syslog,
1036               [AC_CHECK_HEADER(syslog.h,
1037                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1038
1039 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1040 [AC_TRY_LINK([#include <unistd.h>],
1041   [extern int optreset; optreset = 1;],
1042   [pgac_cv_var_int_optreset=yes],
1043   [pgac_cv_var_int_optreset=no])])
1044 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1045   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1046 fi
1047
1048 AC_CHECK_FUNCS([strtoll strtoq], [break])
1049 AC_CHECK_FUNCS([strtoull strtouq], [break])
1050
1051 # Check for one of atexit() or on_exit()
1052 AC_CHECK_FUNCS(atexit, [],
1053                [AC_CHECK_FUNCS(on_exit, [],
1054                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1055
1056 AC_FUNC_FSEEKO
1057
1058 #
1059 # Pthreads
1060 #
1061 # For each platform, we need to know about any special compile and link
1062 # libraries, and whether the normal C function names are thread-safe.
1063 # See the comment at the top of src/port/thread.c for more information.
1064 #
1065 if test "$enable_thread_safety" = yes; then
1066 ACX_PTHREAD     # set thread flags
1067
1068 # Some platforms use these, so just defineed them.  They can't hurt if they
1069 # are not supported.
1070 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1071
1072
1073 # At this point, we don't want to muck with the compiler name for threading.
1074 # Let's see who fails, perhaps AIX.  2004-04-23
1075 if test "$PTHREAD_CC" != "$CC"; then
1076 AC_MSG_ERROR([
1077 PostgreSQL does not support platforms that require a special compiler
1078 for thread safety.])
1079 fi
1080
1081 if test "$THREAD_SUPPORT" = no; then
1082 AC_MSG_ERROR([cannot enable threads on this platform
1083 This platform is known to not support thread-safe programs.  For details,
1084 compile and run src/bin/pg_thread_test.])
1085 fi
1086
1087 # Check for *_r functions
1088 _CFLAGS="$CFLAGS"
1089 _LIBS="$LIBS"
1090 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1091 LIBS="$LIBS $PTHREAD_LIBS"
1092
1093 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1094
1095 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1096
1097 # Do test here with the proper thread flags
1098 PGAC_FUNC_GETPWUID_R_5ARG
1099 PGAC_FUNC_STRERROR_R_INT
1100
1101 CFLAGS="$_CFLAGS"
1102 LIBS="$_LIBS"
1103
1104 else
1105 # do not use values from template file
1106 PTHREAD_CFLAGS=
1107 PTHREAD_LIBS=
1108 fi
1109
1110 AC_SUBST(PTHREAD_CFLAGS)
1111 AC_SUBST(PTHREAD_LIBS)
1112
1113
1114 # We can test for libldap_r only after we know PTHREAD_LIBS
1115 if test "$with_ldap" = yes ; then
1116   _LIBS="$LIBS"
1117   if test "$PORTNAME" != "win32"; then
1118     AC_CHECK_LIB(ldap, ldap_bind, [], [AC_MSG_ERROR([library 'ldap' is required for LDAP])])
1119     LDAP_LIBS_BE="-lldap"
1120     if test "$enable_thread_safety" = yes; then
1121       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1122       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1123                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1124                    [$PTHREAD_LIBS])
1125       LDAP_LIBS_FE="-lldap_r"
1126     else
1127       LDAP_LIBS_FE="-lldap"
1128     fi
1129   else
1130     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1131     LDAP_LIBS_FE="-lwldap32"
1132     LDAP_LIBS_BE="-lwldap32"
1133   fi
1134   LIBS="$_LIBS"
1135 fi
1136 AC_SUBST(LDAP_LIBS_FE)
1137 AC_SUBST(LDAP_LIBS_BE)
1138
1139
1140 # This test makes sure that run tests work at all.  Sometimes a shared
1141 # library is found by the linker, but the runtime linker can't find it.
1142 # This check should come after all modifications of compiler or linker
1143 # variables, and before any other run tests.
1144 AC_MSG_CHECKING([test program])
1145 AC_TRY_RUN([int main() { return 0; }],
1146 [AC_MSG_RESULT(ok)],
1147 [AC_MSG_RESULT(failed)
1148 AC_MSG_ERROR([[
1149 Could not execute a simple test program.  This may be a problem
1150 related to locating shared libraries.  Check the file 'config.log'
1151 for the exact reason.]])],
1152 [AC_MSG_RESULT([cross-compiling])])
1153
1154 # --------------------
1155 # Run tests below here
1156 # --------------------
1157
1158 # Force use of our snprintf if system's doesn't do arg control
1159 # See comment above at snprintf test for details.
1160 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1161   PGAC_FUNC_PRINTF_ARG_CONTROL
1162   if test $pgac_cv_printf_arg_control != yes ; then
1163     pgac_need_repl_snprintf=yes
1164   fi
1165 fi
1166
1167
1168 dnl Check to see if we have a working 64-bit integer type.
1169 dnl This breaks down into two steps:
1170 dnl (1) figure out if the compiler has a 64-bit int type with working
1171 dnl arithmetic, and if so
1172 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1173 dnl snprintf is the only library routine we really need for int8 support.)
1174 dnl It's entirely possible to have a compiler that handles a 64-bit type
1175 dnl when the C library doesn't; this is fairly likely when using gcc on
1176 dnl an older platform, for example.
1177 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1178 dnl we force our own version of snprintf() to be used instead.
1179 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1180
1181 PGAC_TYPE_64BIT_INT([long int])
1182
1183 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1184   PGAC_TYPE_64BIT_INT([long long int])
1185 fi
1186
1187
1188 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1189
1190 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1191   AC_TRY_COMPILE([
1192 #define INT64CONST(x)  x##LL
1193 long long int foo = INT64CONST(0x1234567890123456);
1194 ],
1195         [],
1196         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1197         [])
1198 fi
1199
1200
1201 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1202 # we found we need to use "long long int", better check.  We cope with
1203 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1204 # work, fall back to our own snprintf emulation (which we know uses %lld).
1205
1206 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1207   if test $pgac_need_repl_snprintf = no; then
1208     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1209     if test "$LONG_LONG_INT_FORMAT" = ""; then
1210       # Force usage of our own snprintf, since system snprintf is broken
1211       pgac_need_repl_snprintf=yes
1212       LONG_LONG_INT_FORMAT='%lld'
1213     fi
1214   else
1215     # Here if we previously decided we needed to use our own snprintf
1216     LONG_LONG_INT_FORMAT='%lld'
1217   fi
1218   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1219   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1220   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1221 else
1222   # Here if we are not using 'long long int' at all
1223   INT64_FORMAT='"%ld"'
1224   UINT64_FORMAT='"%lu"'
1225 fi
1226
1227 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1228                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1229
1230 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1231                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1232
1233 # Now we have checked all the reasons to replace snprintf
1234 if test $pgac_need_repl_snprintf = yes; then
1235   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1236   AC_LIBOBJ(snprintf)
1237 fi
1238
1239 # Need a #define for the size of Datum (unsigned long)
1240 AC_CHECK_SIZEOF([unsigned long])
1241
1242 # And one for the size of size_t (enables tweaks for > 32bit address space)
1243 AC_CHECK_SIZEOF([size_t])
1244
1245 # Determine memory alignment requirements for the basic C data types.
1246
1247 PGAC_CHECK_ALIGNOF(short)
1248 PGAC_CHECK_ALIGNOF(int)
1249 PGAC_CHECK_ALIGNOF(long)
1250 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1251   PGAC_CHECK_ALIGNOF(long long int)
1252 fi
1253 PGAC_CHECK_ALIGNOF(double)
1254
1255 # Compute maximum alignment of any basic type.
1256 # We assume long's alignment is at least as strong as char, short, or int;
1257 # but we must check long long (if it exists) and double.
1258
1259 MAX_ALIGNOF=$pgac_cv_alignof_long
1260 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1261   MAX_ALIGNOF=$pgac_cv_alignof_double
1262 fi
1263 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1264   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1265 fi
1266 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1267
1268
1269 # Some platforms predefine the types int8, int16, etc.  Only check
1270 # a (hopefully) representative subset.
1271 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1272 [#include <stdio.h>
1273 #ifdef HAVE_SUPPORTDEFS_H
1274 #include <SupportDefs.h>
1275 #endif])
1276
1277 # We also check for sig_atomic_t, which *should* be defined per ANSI
1278 # C, but is missing on some old platforms.
1279 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1280
1281
1282 if test x"$template" != x"win32"
1283 then
1284 PGAC_FUNC_POSIX_SIGNALS
1285 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1286   AC_MSG_ERROR([
1287 Thread-safety requires POSIX signals, which are not supported by this
1288 operating system.])
1289 fi
1290 fi
1291
1292 if test $ac_cv_func_fseeko = yes; then
1293 AC_SYS_LARGEFILE
1294 fi
1295
1296 # SunOS doesn't handle negative byte comparisons properly with +/- return
1297 AC_FUNC_MEMCMP
1298
1299
1300 # Select semaphore implementation type.
1301 if test "$PORTNAME" != "win32"; then
1302   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1303     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1304     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1305   else
1306     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1307       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1308       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1309     else
1310       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1311       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1312     fi
1313   fi
1314 else
1315   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1316   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1317 fi
1318
1319
1320 # Select shared-memory implementation type.
1321 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1322 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1323
1324
1325 # If not set in template file, set bytes to use libc memset()
1326 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1327   MEMSET_LOOP_LIMIT=1024
1328 fi
1329 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1330
1331
1332 if test "$enable_nls" = yes ; then
1333   PGAC_CHECK_GETTEXT
1334 fi
1335
1336 # Check for Tcl configuration script tclConfig.sh
1337 if test "$with_tcl" = yes; then
1338     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1339     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1340                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1341     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1342     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1343     ac_save_CPPFLAGS=$CPPFLAGS
1344     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1345     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1346     CPPFLAGS=$ac_save_CPPFLAGS
1347 fi
1348
1349 #
1350 # Check for DocBook and tools
1351 #
1352 PGAC_PROG_NSGMLS
1353 PGAC_PROG_JADE
1354 PGAC_CHECK_DOCBOOK(4.2)
1355 PGAC_PATH_DOCBOOK_STYLESHEETS
1356 PGAC_PATH_COLLATEINDEX
1357 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1358
1359 # Thread testing
1360
1361 # We have to run the thread test near the end so we have all our symbols
1362 # defined.  Cross compiling throws a warning.
1363 #
1364 if test "$enable_thread_safety_force" = yes; then
1365 if test x"$template" != x"win32"
1366 then
1367   AC_MSG_WARN([
1368 *** Skipping thread test program.  --enable-thread-safety-force was used.
1369 *** Run the program in src/test/thread on the your machine and add proper
1370 *** locking function calls to your applications to guarantee thread safety.
1371 ])
1372 else
1373 AC_MSG_WARN([*** skipping thread test on Win32])
1374 fi
1375 elif test "$enable_thread_safety" = yes; then
1376 if test x"$template" != x"win32"
1377 then
1378 AC_MSG_CHECKING([thread safety of required library functions])
1379
1380 _CFLAGS="$CFLAGS"
1381 _LIBS="$LIBS"
1382 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1383 LIBS="$LIBS $PTHREAD_LIBS"
1384 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1385   [AC_MSG_RESULT(yes)],
1386   [AC_MSG_RESULT(no)
1387   AC_MSG_ERROR([thread test program failed
1388 This platform is not thread-safe.  Check the file 'config.log'for the
1389 exact reason.
1390
1391 You can use the configure option --enable-thread-safety-force to force
1392 threads to be enabled.  But you must then run the program in
1393 src/test/thread and add locking function calls to your applications to
1394 guarantee thread safety.])],
1395   [AC_MSG_RESULT(maybe)
1396   AC_MSG_WARN([
1397 *** Skipping thread test program because of cross-compile build.
1398 *** Run the program in src/test/thread on the target machine.
1399 ])])
1400 CFLAGS="$_CFLAGS"
1401 LIBS="$_LIBS"
1402 else
1403 AC_MSG_WARN([*** skipping thread test on Win32])
1404 fi
1405 fi
1406
1407 # prepare build tree if outside source tree
1408 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1409 # Note 2: /bin/pwd might be better than shell's built-in at getting
1410 #         a symlink-free name.
1411 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1412   vpath_build=no
1413 else
1414   vpath_build=yes
1415   if test "$no_create" != yes; then
1416     _AS_ECHO_N([preparing build tree... ])
1417     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1418     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1419       || AC_MSG_ERROR(failed)
1420     AC_MSG_RESULT(done)
1421   fi
1422 fi
1423 AC_SUBST(vpath_build)
1424
1425
1426 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1427
1428 AC_CONFIG_LINKS([
1429   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1430   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1431   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1432   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1433   src/include/pg_config_os.h:src/include/port/${template}.h
1434   src/Makefile.port:src/makefiles/Makefile.${template}
1435 ])
1436
1437 if test "$PORTNAME" = "win32"; then
1438 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1439 # Links sometimes fail undetected on Mingw -
1440 # so here we detect it and warn the user
1441 for FILE in $CONFIG_LINKS
1442  do
1443         # test -e works for symlinks in the MinGW console
1444         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1445  done
1446 ])
1447 fi
1448
1449 AC_CONFIG_HEADERS([src/include/pg_config.h],
1450 [
1451 # Update timestamp for pg_config.h (see Makefile.global)
1452 echo >src/include/stamp-h
1453 ])
1454
1455 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1456
1457 AC_OUTPUT
1458
1459 # Warn about unknown options
1460 PGAC_ARG_CHECK