granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.276 2003/08/04 21:26:26 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.4devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55   # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=cygwin ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68    mingw*) template=win32 ;;
  69   netbsd*) template=netbsd ;;
  70 nextstep*) template=nextstep ;;
  71  openbsd*) template=openbsd ;;
  72      osf*) template=osf ;;
  73      qnx*) template=qnx4 ;;
  74      sco*) template=sco ;;
  75  solaris*) template=solaris ;;
  76    sunos*) template=sunos4 ;;
  77  sysv4.2*)
  78         case $host_vendor in
  79           univel) template=univel ;;
  80         esac ;;
  81    sysv4*) template=svr4 ;;
  82    sysv5*) template=unixware ;;
  83   ultrix*) template=ultrix4 ;;
  84 esac
  85
  86   if test x"$template" = x"" ; then
  87     AC_MSG_ERROR([[
  88 *******************************************************************
  89 PostgreSQL has apparently not been ported to your platform yet.
  90 To try a manual configuration, look into the src/template directory
  91 for a similar platform and use the '--with-template=' option.
  92
  93 Please also contact <pgsql-ports@postgresql.org> to see about
  94 rectifying this.  Include the above 'checking host system type...'
  95 line.
  96 *******************************************************************
  97 ]])
  98   fi
  99
 100 ])
 101
 102 AC_MSG_RESULT([$template])
 103
 104 PORTNAME=$template
 105 AC_SUBST(PORTNAME)
 106
 107 # Pick right test-and-set (TAS) code.  Most platforms have inline
 108 # assembler code in src/include/storage/s_lock.h, so we just use
 109 # a dummy file here.
 110 case $host in
 111   hppa*-*-hpux*)        need_tas=yes; tas_file=hpux_hppa.s ;;
 112   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 113   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 114   *)                need_tas=no;  tas_file=dummy.s ;;
 115 esac
 116 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 117
 118 if test "$need_tas" = yes ; then
 119   TAS=tas.o
 120 fi
 121 AC_SUBST(TAS)
 122
 123
 124
 125 ##
 126 ## Command line options
 127 ##
 128
 129
 130 #
 131 # Add non-standard directories to the include path
 132 #
 133 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 134
 135
 136 #
 137 # Add non-standard directories to the library search path
 138 #
 139 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 140              [LIBRARY_DIRS=$withval])
 141
 142 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 143              [LIBRARY_DIRS=$withval])
 144
 145
 146 #
 147 # 64-bit integer date/time storage (--enable-integer-datetimes)
 148 #
 149 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 150 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 151               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 152                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 153 AC_MSG_RESULT([$enable_integer_datetimes])
 154
 155
 156 #
 157 # NLS
 158 #
 159 AC_MSG_CHECKING([whether NLS is wanted])
 160 PGAC_ARG_OPTARG(enable, nls,
 161                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 162                 [],
 163                 [WANTED_LANGUAGES=$enableval],
 164                 [AC_DEFINE(ENABLE_NLS, 1,
 165                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 166 AC_MSG_RESULT([$enable_nls])
 167 AC_SUBST(enable_nls)
 168 AC_SUBST(WANTED_LANGUAGES)
 169
 170 #
 171 # Default port number (--with-pgport), default 5432
 172 #
 173 AC_MSG_CHECKING([for default port number])
 174 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 175              [default_port=$withval],
 176              [default_port=5432])
 177 AC_MSG_RESULT([$default_port])
 178 # Need both of these because some places want an integer and some a string
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 180 [Define to the default TCP port number on which the server listens and
 181 to which clients will try to connect to.  This can be overridden at
 182 run-time, but it's convenient if your clients have the right default
 183 compiled in.  (--with-pgport=PORTNUM)])
 184 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 185                    [Define to the default TCP port number as string constant.])
 186 AC_SUBST(default_port)
 187
 188 #
 189 # Option to disable shared libraries
 190 #
 191 PGAC_ARG_BOOL(enable, shared, yes,
 192               [  --disable-shared        do not build shared libraries])
 193 AC_SUBST(enable_shared)
 194
 195 #
 196 # '-rpath'-like feature can be disabled
 197 #
 198 PGAC_ARG_BOOL(enable, rpath, yes,
 199               [  --disable-rpath         do not embed shared library search path in executables])
 200 AC_SUBST(enable_rpath)
 201
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226 # Read the template
 227 . "$srcdir/src/template/$template" || exit
 228
 229 if test "$ac_env_CFLAGS_set" = set; then
 230   CFLAGS=$ac_env_CFLAGS_value
 231 fi
 232 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 233   CFLAGS="$CFLAGS -g"
 234 fi
 235 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 236
 237 # Check if the compiler still works with the template settings
 238 AC_MSG_CHECKING([whether the C compiler still works])
 239 AC_TRY_LINK([], [return 0;],
 240   [AC_MSG_RESULT(yes)],
 241   [AC_MSG_RESULT(no)
 242    AC_MSG_ERROR([cannot proceed])])
 243
 244 # Defend against gcc -ffastmath
 245 if test "$GCC" = yes; then
 246 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 247 choke me
 248 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 249 fi
 250
 251 AC_PROG_CPP
 252 AC_SUBST(GCC)
 253
 254 # Create compiler version string
 255 if test x"$GCC" = x"yes" ; then
 256   cc_string="GCC `${CC} --version | sed q`"
 257 else
 258   cc_string=$CC
 259 fi
 260 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 261                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 262                    [A string containing the version number, platform, and C compiler])
 263
 264
 265 #
 266 # Automatic dependency tracking
 267 #
 268 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 269               [autodepend=yes])
 270 AC_SUBST(autodepend)
 271
 272
 273 #
 274 # Enable assert checks
 275 #
 276 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 277               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 278                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 279
 280
 281 #
 282 # Include directories
 283 #
 284 ac_save_IFS=$IFS
 285 IFS="${IFS}:"
 286 # SRCH_INC comes from the template file
 287 for dir in $with_includes $SRCH_INC; do
 288   if test -d "$dir"; then
 289     INCLUDES="$INCLUDES -I$dir"
 290   else
 291     AC_MSG_WARN([*** Include directory $dir does not exist.])
 292   fi
 293 done
 294 IFS=$ac_save_IFS
 295 AC_SUBST(INCLUDES)
 296
 297
 298 #
 299 # Library directories
 300 #
 301 ac_save_IFS=$IFS
 302 IFS="${IFS}:"
 303 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 304 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 305   if test -d "$dir"; then
 306     LIBDIRS="$LIBDIRS -L$dir"
 307   else
 308     AC_MSG_WARN([*** Library directory $dir does not exist.])
 309   fi
 310 done
 311 IFS=$ac_save_IFS
 312
 313 #
 314 # Enable libpq to be thread-safety
 315 #
 316 AC_MSG_CHECKING([allow thread-safe libpq and ecpg])
 317 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety allow libpq and ecpg to be thread-safe],
 318               [AC_DEFINE([USE_THREADS], 1, [Define to 1 to build libpq and ecpg to be thread-safe. (--enable-thread-safety)])])
 319 AC_MSG_RESULT([$enable_thread_safety])
 320 AC_SUBST(enable_thread_safety)
 321
 322 #
 323 # Tcl/Tk
 324 #
 325 AC_MSG_CHECKING([whether to build with Tcl])
 326 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 327 AC_MSG_RESULT([$with_tcl])
 328 AC_SUBST([with_tcl])
 329
 330 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 331 AC_MSG_CHECKING([whether to build with Tk])
 332 if test "$with_tcl" = yes; then
 333   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 334 else
 335   with_tk=no
 336 fi
 337 AC_MSG_RESULT([$with_tk])
 338 AC_SUBST([with_tk])
 339
 340
 341 # We see if the path to the Tcl/Tk configuration scripts is specified.
 342 # This will override the use of tclsh to find the paths to search.
 343
 344 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 345
 346 # We see if the path to the Tk configuration scripts is specified.
 347 # This will override the use of tclsh to find the paths to search.
 348
 349 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 350
 351 #
 352 # Optionally build Perl modules (PL/Perl)
 353 #
 354 AC_MSG_CHECKING([whether to build Perl modules])
 355 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 356 AC_MSG_RESULT([$with_perl])
 357 AC_SUBST(with_perl)
 358
 359 #
 360 # Optionally build Python interface module
 361 #
 362 AC_MSG_CHECKING([whether to build Python modules])
 363 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 364 AC_MSG_RESULT([$with_python])
 365 AC_SUBST(with_python)
 366
 367 #
 368 # Optionally build the Java/JDBC tools
 369 #
 370 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 371 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 372 [AC_MSG_RESULT(yes)
 373 PGAC_PATH_ANT
 374 if test -z "$ANT"; then
 375   AC_MSG_ERROR([Ant is required to build Java components
 376 If you have Ant already installed, see config.log for details on the failure.])
 377 fi
 378 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 379   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 380 fi],
 381 [AC_MSG_RESULT(no)])
 382 AC_SUBST(with_java)
 383
 384 dnl A note on the Kerberos and OpenSSL options:
 385 dnl
 386 dnl The user can give an argument to the option in order the specify
 387 dnl the base path of the respective installation (what he specified
 388 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 389 dnl then we take the path where the package installs by default. This
 390 dnl way the user doesn't have to use redundant --with-includes and
 391 dnl --with-libraries options, but he can still use them if the layout
 392 dnl is non-standard.
 393
 394 #
 395 # Kerberos 4
 396 #
 397 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 398 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 399                 [krb4_prefix=/usr/athena],
 400                 [krb4_prefix=$withval],
 401 [
 402   AC_MSG_RESULT(yes)
 403   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 404
 405   if test -d "$krb4_prefix/include"; then
 406     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 407   fi
 408   if test -d "$krb4_prefix/lib"; then
 409     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 410   fi
 411
 412   krb_srvtab="/etc/srvtab"
 413 ],
 414 [AC_MSG_RESULT(no)])
 415
 416 AC_SUBST(with_krb4)
 417
 418
 419 #
 420 # Kerberos 5
 421 #
 422 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 423 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 424               [krb5_prefix=/usr/athena],
 425               [krb5_prefix=$withval],
 426 [
 427   AC_MSG_RESULT([yes])
 428   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 429
 430   if test -d "$krb5_prefix/include"; then
 431     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 432   fi
 433   if test -d "$krb5_prefix/lib"; then
 434     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 435   fi
 436
 437   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 438 ],
 439 [AC_MSG_RESULT(no)])
 440
 441 AC_SUBST(with_krb5)
 442
 443
 444 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 445 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 446   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 447 fi
 448
 449 AC_SUBST(krb_srvtab)
 450
 451
 452 #
 453 # Kerberos configuration parameters
 454 #
 455 PGAC_ARG_REQ(with, krb-srvnam,
 456              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 457              [],
 458              [with_krb_srvnam="postgres"])
 459 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 460                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 461
 462
 463 #
 464 # PAM
 465 #
 466 AC_MSG_CHECKING([whether to build with PAM support])
 467 PGAC_ARG_BOOL(with, pam, no,
 468               [  --with-pam              build with PAM support],
 469               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 470 AC_MSG_RESULT([$with_pam])
 471 AC_SUBST(with_pam)
 472
 473
 474 #
 475 # Rendezvous
 476 #
 477 AC_MSG_CHECKING([whether to build with Rendezvous support])
 478 PGAC_ARG_BOOL(with, rendezvous, no,
 479               [  --with-rendezvous       build with Rendezvous support],
 480               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 481 AC_MSG_RESULT([$with_rendezvous])
 482 AC_SUBST(with_rendezvous)
 483
 484
 485 #
 486 # OpenSSL
 487 #
 488 PGAC_ARG_OPTARG(with, openssl,
 489                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 490                 [openssl_prefix=/usr/local/ssl],
 491                 [openssl_prefix=$withval],
 492 [
 493   AC_MSG_RESULT([building with OpenSSL support])
 494   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])
 495
 496   if test -d "${openssl_prefix}/include" ; then
 497     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 498   fi
 499   if test -d "${openssl_prefix}/lib" ; then
 500     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 501   fi
 502 ])
 503
 504 AC_SUBST(with_openssl)
 505
 506
 507 #
 508 # Readline
 509 #
 510 PGAC_ARG_BOOL(with, readline, yes,
 511               [  --without-readline      do not use Readline])
 512
 513 #
 514 # Zlib
 515 #
 516 PGAC_ARG_BOOL(with, zlib, yes,
 517               [  --without-zlib          do not use Zlib])
 518
 519
 520 #
 521 # Elf
 522 #
 523
 524 # Assume system is ELF if it predefines __ELF__ as 1,
 525 # otherwise believe host_os based default.
 526 case $host_os in
 527     freebsd1*|freebsd2*) elf=no;;
 528     freebsd3*|freebsd4*) elf=yes;;
 529 esac
 530
 531 AC_EGREP_CPP(yes,
 532 [#if __ELF__
 533   yes
 534 #endif
 535 ],
 536 [ELF_SYS=true],
 537 [if test "X$elf" = "Xyes" ; then
 538   ELF_SYS=true
 539 else
 540   ELF_SYS=
 541 fi])
 542 AC_SUBST(ELF_SYS)
 543
 544 #
 545 # Assignments
 546 #
 547
 548 CPPFLAGS="$CPPFLAGS $INCLUDES"
 549 LDFLAGS="$LDFLAGS $LIBDIRS"
 550
 551 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 552 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 553
 554
 555 AC_PROG_AWK
 556 PGAC_PATH_FLEX
 557 AC_PROG_LN_S
 558 AC_PROG_LD
 559 AC_SUBST(LD)
 560 AC_SUBST(with_gnu_ld)
 561 case $host_os in sysv5*)
 562   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 563   [
 564     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 565     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 566     LDFLAGS=$pgac_save_LDFLAGS
 567   ])
 568   ld_R_works=$pgac_cv_prog_ld_R
 569   AC_SUBST(ld_R_works)
 570 esac
 571 AC_PROG_RANLIB
 572 AC_CHECK_PROGS(LORDER, lorder)
 573 AC_PATH_PROG(TAR, tar)
 574 PGAC_CHECK_STRIP
 575
 576 AC_CHECK_PROGS(YACC, ['bison -y'])
 577
 578 if test "$YACC"; then
 579   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 580     AC_MSG_WARN([
 581 *** The installed version of Bison is too old.  PostgreSQL needs
 582 *** Bison version 1.875 or later.])
 583   fi
 584 fi
 585
 586 if test -z "$YACC"; then
 587   AC_MSG_WARN([
 588 *** Without Bison you will not be able to build PostgreSQL from CVS or
 589 *** change any of the parser definition files.  You can obtain Bison from
 590 *** a GNU mirror site.  (If you are using the official distribution of
 591 *** PostgreSQL then you do not need to worry about this because the Bison
 592 *** output is pre-generated.)  To use a different yacc program (possible,
 593 *** but not recommended), set the environment variable YACC before running
 594 *** 'configure'.])
 595 fi
 596 AC_SUBST(YFLAGS)
 597
 598 PGAC_PATH_PERL
 599 if test "$with_perl" = yes; then
 600   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 601   PGAC_CHECK_PERL_EMBED_LDFLAGS
 602 fi
 603
 604 if test "$with_python" = yes; then
 605   PGAC_PATH_PYTHON
 606   PGAC_CHECK_PYTHON_MODULE_SETUP
 607   PGAC_CHECK_PYTHON_EMBED_SETUP
 608 fi
 609
 610
 611 ##
 612 ## Libraries
 613 ##
 614
 615 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 616 then
 617         AC_CHECK_LIB(bsd,      main)
 618 fi
 619 AC_CHECK_LIB(util,     setproctitle)
 620 AC_CHECK_LIB(m,        main)
 621 AC_CHECK_LIB(dl,       main)
 622 AC_CHECK_LIB(nsl,      main)
 623 AC_CHECK_LIB(socket,   main)
 624 AC_CHECK_LIB(ipc,      main)
 625 AC_CHECK_LIB(IPC,      main)
 626 AC_CHECK_LIB(lc,       main)
 627 AC_CHECK_LIB(dld,      main)
 628 AC_CHECK_LIB(ld,       main)
 629 AC_CHECK_LIB(compat,   main)
 630 AC_CHECK_LIB(BSD,      main)
 631 AC_CHECK_LIB(gen,      main)
 632 AC_CHECK_LIB(PW,       main)
 633 AC_CHECK_LIB(resolv,   main)
 634 AC_CHECK_LIB(wsock32,   main)
 635 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 636 # QNX:
 637 AC_CHECK_LIB(unix, main)
 638 AC_SEARCH_LIBS(crypt,  crypt)
 639 # BeOS:
 640 if test "$PORTNAME" = "beos"
 641 then
 642         AC_CHECK_LIB(bind, __inet_ntoa)
 643 fi
 644 # Solaris:
 645 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 646 # Cygwin:
 647 AC_CHECK_LIB(cygipc, shmget)
 648
 649 if test "$with_readline" = yes; then
 650   PGAC_CHECK_READLINE
 651   if test x"$pgac_cv_check_readline" = x"no"; then
 652     AC_MSG_ERROR([readline library not found
 653 If you have readline already installed, see config.log for details on the
 654 failure.  It is possible the compiler isn't looking in the proper directory.
 655 Use --without-readline to disable readline support.])
 656   fi
 657 fi
 658
 659 if test "$with_zlib" = yes; then
 660   AC_CHECK_LIB(z, inflate, [],
 661                [AC_MSG_ERROR([zlib library not found
 662 If you have zlib already installed, see config.log for details on the
 663 failure.  It is possible the compiler isn't looking in the proper directory.
 664 Use --without-zlib to disable zlib support.])])
 665 fi
 666
 667 if test "$with_krb4" = yes ; then
 668   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 669   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 670   AC_REPLACE_FUNCS([gethostname])
 671 fi
 672
 673 if test "$with_krb5" = yes ; then
 674   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 675                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 676   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 677                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 678   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 679                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 680 fi
 681
 682 if test "$with_openssl" = yes ; then
 683   dnl Order matters!
 684   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 685   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 686 fi
 687
 688 if test "$with_pam" = yes ; then
 689   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 690 fi
 691
 692
 693 ##
 694 ## Header files
 695 ##
 696
 697 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 698 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 699
 700 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 701 # netinet/in.h is included first.
 702 AC_CHECK_HEADERS(netinet/in.h)
 703 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 704 [AC_INCLUDES_DEFAULT
 705 #ifdef HAVE_NETINET_IN_H
 706 #include <netinet/in.h>
 707 #endif
 708 ])
 709
 710 if test "$with_readline" = yes; then
 711   AC_CHECK_HEADERS(readline/readline.h, [],
 712                    [AC_CHECK_HEADERS(editline/readline.h, [],
 713                          [AC_CHECK_HEADERS(readline.h, [],
 714                                      [AC_MSG_ERROR([readline header not found
 715 If you have readline already installed, see config.log for details on the
 716 failure.  It is possible the compiler isn't looking in the proper directory.
 717 Use --without-readline to disable readline support.])])])])
 718   AC_CHECK_HEADERS(readline/history.h, [],
 719                    [AC_CHECK_HEADERS(editline/history.h, [],
 720                          [AC_CHECK_HEADERS(history.h, [],
 721                                      [AC_MSG_ERROR([history header not found
 722 If you have readline already installed, see config.log for details on the
 723 failure.  It is possible the compiler isn't looking in the proper directory.
 724 Use --without-readline to disable readline support.])])])])
 725 fi
 726
 727 if test "$with_zlib" = yes; then
 728   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 729 If you have zlib already installed, see config.log for details on the
 730 failure.  It is possible the compiler isn't looking in the proper directory.
 731 Use --without-zlib to disable zlib support.])])
 732 fi
 733
 734 if test "$with_krb4" = yes ; then
 735   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 736 fi
 737
 738 if test "$with_krb5" = yes ; then
 739   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 740   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 741 fi
 742
 743 if test "$with_openssl" = yes ; then
 744   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 745   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 746 fi
 747
 748 if test "$with_pam" = yes ; then
 749   AC_CHECK_HEADERS(security/pam_appl.h, [],
 750                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 751                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 752 fi
 753
 754 if test "$with_rendezvous" = yes ; then
 755   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 756 fi
 757
 758
 759 ##
 760 ## Types, structures, compiler characteristics
 761 ##
 762
 763 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 764 AC_C_CONST
 765 AC_C_INLINE
 766 AC_C_STRINGIZE
 767 PGAC_C_SIGNED
 768 AC_C_VOLATILE
 769 PGAC_C_FUNCNAME_SUPPORT
 770 PGAC_STRUCT_TIMEZONE
 771 PGAC_UNION_SEMUN
 772 PGAC_STRUCT_SOCKADDR_UN
 773 PGAC_STRUCT_SOCKADDR_STORAGE
 774 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 775 PGAC_STRUCT_ADDRINFO
 776
 777 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 778 [#include <sys/param.h>
 779 #include <sys/types.h>
 780 #include <sys/socket.h>
 781 #include <sys/ucred.h>])
 782
 783 if test "$with_zlib" = yes; then
 784   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 785   # did not).  While we could work around the lack of z_streamp, it
 786   # seems unwise to encourage people to use such old zlib versions...
 787   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 788 Use --without-zlib to disable zlib support.])],
 789                 [#include <zlib.h>])
 790 fi
 791
 792 if test "$with_krb5" = yes; then
 793 # Check for differences between MIT and Heimdal (KTH) releases
 794   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 795                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 796                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 797                                      [#include <krb5.h>])],
 798                    [#include <krb5.h>])
 799   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 800                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 801                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 802                                      [#include <krb5.h>])],
 803                    [#include <krb5.h>])
 804 fi
 805
 806
 807 ##
 808 ## Functions, global variables
 809 ##
 810
 811 PGAC_VAR_INT_TIMEZONE
 812 AC_FUNC_ACCEPT_ARGTYPES
 813 PGAC_FUNC_GETTIMEOFDAY_1ARG
 814
 815 # SunOS doesn't handle negative byte comparisons properly with +/- return
 816 AC_FUNC_MEMCMP
 817
 818 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 819
 820 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 821
 822 AC_CHECK_TYPE([struct sockaddr_in6],
 823               [AC_CHECK_FUNC(inet_ntop,
 824                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])])],
 825               [],
 826 [$ac_includes_default
 827 #include <netinet/in.h>])
 828
 829 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 830 [AC_TRY_LINK(
 831 [#include <machine/vmparam.h>
 832 #include <sys/exec.h>
 833 ],
 834 [PS_STRINGS->ps_nargvstr = 1;
 835 PS_STRINGS->ps_argvstr = "foo";],
 836 [pgac_cv_var_PS_STRINGS=yes],
 837 [pgac_cv_var_PS_STRINGS=no])])
 838 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 839   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 840 fi
 841
 842
 843 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 844 # is missing.  Yes, there are machines that have only one.  We may
 845 # also decide to use snprintf.c if snprintf() is present but does not
 846 # have working "long long int" support -- see below.
 847
 848 pgac_need_repl_snprintf=no
 849 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 850 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 851
 852
 853 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 854 # include/c.h will provide declarations.  Note this is a separate test
 855 # from whether the functions exist in the C library --- there are
 856 # systems that have the functions but don't bother to declare them :-(
 857
 858 AC_CHECK_DECLS([snprintf, vsnprintf])
 859
 860
 861 # do this one the hard way in case isinf() is a macro
 862 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 863 [AC_TRY_LINK(
 864 [#include <math.h>
 865 ],
 866 [double x = 0.0; int res = isinf(x);],
 867 [ac_cv_func_isinf=yes],
 868 [ac_cv_func_isinf=no])])
 869
 870 if test $ac_cv_func_isinf = yes ; then
 871   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 872 else
 873   AC_LIBOBJ(isinf)
 874   # Look for a way to implement a substitute for isinf()
 875   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 876 fi
 877
 878 AC_REPLACE_FUNCS([crypt fseeko getopt getopt_long getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 879
 880 # system's version of getaddrinfo(), if any, may be used only if we found
 881 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 882 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 883   AC_REPLACE_FUNCS([getaddrinfo])
 884 else
 885   AC_LIBOBJ(getaddrinfo)
 886 fi
 887
 888 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 889 # We override the previous test that said fseeko/ftello didn't exist
 890 # OS tests are also done in include/c.h and port/fseeko.c
 891 case $host_os in bsdi*|netbsd*)
 892 ac_cv_func_fseeko=yes
 893 esac
 894
 895 # Solaris has a very slow qsort in certain cases, so we replace it.
 896 case $host_os in solaris*)
 897 AC_LIBOBJ(qsort) ;;
 898 esac
 899
 900 # Win32 can't to rename or unlink on an open file
 901 case $host_os in mingw*)
 902 AC_LIBOBJ(dirmod)
 903 AC_LIBOBJ(copydir)
 904 AC_LIBOBJ(gettimeofday) ;;
 905 esac
 906
 907 if test "$with_readline" = yes; then
 908   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 909   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 910   AC_CHECK_FUNCS([replace_history_entry])
 911 fi
 912
 913
 914 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 915 AC_MSG_CHECKING(for finite)
 916 AC_TRY_LINK([#include <math.h>],
 917             [int dummy=finite(1.0);],
 918             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 919 AC_MSG_RESULT(yes)],
 920             [AC_MSG_RESULT(no)])
 921
 922 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 923 dnl (especially on GNU libc)
 924 dnl See also comments in c.h.
 925 AC_MSG_CHECKING(for sigsetjmp)
 926 AC_TRY_LINK([#include <setjmp.h>],
 927             [sigjmp_buf x; sigsetjmp(x, 1);],
 928             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 929 AC_MSG_RESULT(yes)],
 930             [AC_MSG_RESULT(no)])
 931
 932 AC_CHECK_FUNC(syslog,
 933               [AC_CHECK_HEADER(syslog.h,
 934                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 935
 936 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 937 [AC_TRY_LINK([#include <unistd.h>],
 938   [extern int optreset; optreset = 1;],
 939   [pgac_cv_var_int_optreset=yes],
 940   [pgac_cv_var_int_optreset=no])])
 941 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 942   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 943 fi
 944
 945 AC_CHECK_FUNCS([strtoll strtoq], [break])
 946 AC_CHECK_FUNCS([strtoull strtouq], [break])
 947
 948 # Check for one of atexit() or on_exit()
 949 AC_CHECK_FUNCS(atexit, [],
 950                [AC_CHECK_FUNCS(on_exit, [],
 951                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 952
 953 AC_FUNC_FSEEKO
 954
 955 #
 956 # Pthreads
 957 #
 958 # For each platform, we need to know about any special compile and link
 959 # libraries, and whether the normal C function names are thread-safe.
 960 #
 961 if test "$enable_thread_safety" = yes; then
 962 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --with-threads])])
 963
 964 if test "$SUPPORTS_THREADS" != yes; then
 965 AC_MSG_ERROR([
 966 Cannot enable threads on your platform.
 967 Please report your platform threading info to the PostgreSQL mailing lists
 968 so it can be added to the next release.  Report all compile flags, link flags,
 969 functions, or libraries required for threading support.
 970 ])
 971 fi
 972 else
 973 # do not use values from template file
 974 THREAD_CFLAGS=
 975 THREAD_LIBS=
 976 fi
 977 AC_SUBST(THREAD_CFLAGS)
 978 AC_SUBST(THREAD_LIBS)
 979
 980
 981 #
 982 # Check for re-entrant versions of certain functions
 983 #
 984 # Include special flags if threads are enabled _and_ if required for
 985 # threading on this platform.  Some platforms have *_r functions but
 986 # their natively named funcs are threadsafe, and should be used instead.
 987 #
 988 # One trick here is that if we don't call AC_CHECK_FUNCS, the
 989 # functions are marked "not found", which is perfect.
 990 #
 991 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNC_NAMES" = yes ; then
 992 _CFLAGS="$CFLAGS"
 993 _LIBS="$LIBS"
 994 CFLAGS="$CFLAGS $THREAD_CFLAGS"
 995 LIBS="$LIBS $THREAD_LIBS"
 996 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
 997 CFLAGS="$_CFLAGS"
 998 LIBS="$_LIBS"
 999 fi
1000
1001
1002 # This test makes sure that run tests work at all.  Sometimes a shared
1003 # library is found by the linker, but the runtime linker can't find it.
1004 # This check should come after all modifications of compiler or linker
1005 # variables, and before any other run tests.
1006 AC_MSG_CHECKING([test program])
1007 AC_TRY_RUN([int main() { return 0; }],
1008 [AC_MSG_RESULT(ok)],
1009 [AC_MSG_RESULT(failed)
1010 AC_MSG_ERROR([[
1011 *** Could not execute a simple test program.  This may be a problem
1012 *** related to locating shared libraries.  Check the file 'config.log'
1013 *** for the exact reason.]])],
1014 [AC_MSG_RESULT([cross-compiling])])
1015
1016
1017 dnl Check to see if we have a working 64-bit integer type.
1018 dnl This breaks down into two steps:
1019 dnl (1) figure out if the compiler has a 64-bit int type with working
1020 dnl arithmetic, and if so
1021 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1022 dnl snprintf is the only library routine we really need for int8 support.)
1023 dnl It's entirely possible to have a compiler that handles a 64-bit type
1024 dnl when the C library doesn't; this is fairly likely when using gcc on
1025 dnl an older platform, for example.
1026 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1027 dnl we force our own version of snprintf() to be used instead.
1028 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1029
1030 PGAC_TYPE_64BIT_INT([long int])
1031
1032 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1033   PGAC_TYPE_64BIT_INT([long long int])
1034 fi
1035
1036
1037 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1038
1039 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1040   AC_TRY_COMPILE([
1041 #define INT64CONST(x)  x##LL
1042 long long int foo = INT64CONST(0x1234567890123456);
1043 ],
1044         [],
1045         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1046         [])
1047 fi
1048
1049
1050 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1051 # we found we need to use "long long int", better check.  We cope with
1052 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1053 # neither works, fall back to our own snprintf emulation (which we
1054 # know uses %lld).
1055
1056 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1057   if test $pgac_need_repl_snprintf = no; then
1058     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1059     if test "$LONG_LONG_INT_FORMAT" = ""; then
1060       # Force usage of our own snprintf, since system snprintf is broken
1061       pgac_need_repl_snprintf=yes
1062       LONG_LONG_INT_FORMAT='%lld'
1063     fi
1064   else
1065     # Here if we previously decided we needed to use our own snprintf
1066     LONG_LONG_INT_FORMAT='%lld'
1067   fi
1068   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1069 else
1070   # Here if we are not using 'long long int' at all
1071   INT64_FORMAT='"%ld"'
1072 fi
1073
1074 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1075                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1076
1077 if test $pgac_need_repl_snprintf = yes; then
1078   AC_LIBOBJ(snprintf)
1079 fi
1080
1081 # Need a #define for the size of Datum (unsigned long)
1082 AC_CHECK_SIZEOF([unsigned long])
1083
1084 # Determine memory alignment requirements for the basic C data types.
1085
1086 PGAC_CHECK_ALIGNOF(short)
1087 PGAC_CHECK_ALIGNOF(int)
1088 PGAC_CHECK_ALIGNOF(long)
1089 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1090   PGAC_CHECK_ALIGNOF(long long int)
1091 fi
1092 PGAC_CHECK_ALIGNOF(double)
1093
1094 # Compute maximum alignment of any basic type.
1095 # We assume long's alignment is at least as strong as char, short, or int;
1096 # but we must check long long (if it exists) and double.
1097
1098 MAX_ALIGNOF=$pgac_cv_alignof_long
1099 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1100   MAX_ALIGNOF=$pgac_cv_alignof_double
1101 fi
1102 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1103   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1104 fi
1105 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1106
1107
1108 # Some platforms predefine the types int8, int16, etc.  Only check
1109 # a (hopefully) representative subset.
1110 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1111 [#include <stdio.h>
1112 #ifdef HAVE_SUPPORTDEFS_H
1113 #include <SupportDefs.h>
1114 #endif])
1115
1116 # We also check for sig_atomic_t, which *should* be defined per ANSI
1117 # C, but is missing on some old platforms.
1118 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1119
1120
1121 PGAC_FUNC_POSIX_SIGNALS
1122 if test $ac_cv_func_fseeko = yes; then
1123 AC_SYS_LARGEFILE
1124 fi
1125
1126
1127 # Select semaphore implementation type.
1128 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1129   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1130   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1131 else
1132   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1133     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1134     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1135   else
1136     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1137     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1138   fi
1139 fi
1140
1141
1142 # Select shared-memory implementation type.
1143 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1144 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1145
1146
1147 if test "$enable_nls" = yes ; then
1148   PGAC_CHECK_GETTEXT
1149 fi
1150
1151 # Check for Tcl configuration script tclConfig.sh
1152 if test "$with_tcl" = yes; then
1153     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1154     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1155                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1156     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1157 fi
1158
1159 # Check for Tk configuration script tkConfig.sh
1160 if test "$with_tk" = yes; then
1161     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1162     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1163 fi
1164
1165
1166 #
1167 # Check for DocBook and tools
1168 #
1169 PGAC_PROG_NSGMLS
1170 PGAC_PROG_JADE
1171 PGAC_CHECK_DOCBOOK(3.1)
1172 PGAC_PATH_DOCBOOK_STYLESHEETS
1173 PGAC_PATH_COLLATEINDEX
1174 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1175
1176
1177 # prepare build tree if outside source tree
1178 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1179 # Note 2: /bin/pwd might be better than shell's built-in at getting
1180 #         a symlink-free name.
1181 if test "$no_create" != yes; then
1182   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1183     :
1184   else
1185     AC_SUBST(vpath_build, yes)
1186     _AS_ECHO_N([preparing build tree... ])
1187     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1188     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1189       || AC_MSG_ERROR(failed)
1190     AC_MSG_RESULT(done)
1191   fi
1192 fi
1193
1194
1195 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1196
1197 AC_CONFIG_LINKS([
1198   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1199   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1200   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1201   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1202   src/include/pg_config_os.h:src/include/port/${template}.h
1203   src/Makefile.port:src/makefiles/Makefile.${template}
1204 ])
1205
1206 AC_CONFIG_HEADERS([src/include/pg_config.h],
1207 [
1208 # Update timestamp for pg_config.h (see Makefile.global)
1209 echo >src/include/stamp-h
1210 ])
1211
1212 AC_OUTPUT