granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(build/apr_common.m4)
  17 sinclude(build/find_apr.m4)
  18 sinclude(build/find_apu.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  22 dnl by configure until it is too late.  Is that how it should be or not?
  23 dnl Something seems broken here.
  24 AC_PREFIX_DEFAULT(/usr/local/apache2)
  25
  26 dnl Get the layout here, so we can pass the required variables to apr
  27 APACHE_ENABLE_LAYOUT
  28
  29 dnl reparse the configure arguments.
  30 APR_PARSE_ARGUMENTS
  31
  32 dnl export expanded and relative configure argument variables
  33 APACHE_EXPORT_ARGUMENTS
  34
  35 dnl Save user-defined environment settings for later restoration
  36 dnl
  37 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  38 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  39 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  40 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  41 APR_SAVE_THE_ENVIRONMENT(LIBS)
  42 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  43
  44 dnl Generate ./config.nice for reproducing runs of configure
  45 dnl
  46 APR_CONFIG_NICE(config.nice)
  47
  48 nl='
  49 '
  50 dnl Check that mkdir -p works
  51 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  52
  53 dnl ## Run configure for packages Apache uses
  54
  55 dnl shared library support for these packages doesn't currently
  56 dnl work on some platforms
  57
  58 AC_CANONICAL_SYSTEM
  59
  60 orig_prefix="$prefix"
  61
  62 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  63
  64 APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1)
  65
  66 if test "$apr_found" = "no"; then
  67   AC_MSG_ERROR([APR not found.  Please read the documentation.])
  68 fi
  69
  70 if test "$apr_found" = "reconfig"; then
  71   APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir")
  72   dnl We must be the first to build and the last to be cleaned
  73   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
  74   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
  75 fi
  76
  77 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
  78 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
  79 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
  80 APR_ADDTO(INCLUDES, `$apr_config --includes`)
  81 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
  82 APR_BINDIR=`$apr_config --bindir`
  83 APR_INCLUDEDIR=`$apr_config --includedir`
  84
  85 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  86
  87 APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util", 1)
  88
  89 if test "$apu_found" = "no"; then
  90   AC_MSG_ERROR([APR-util not found.  Please read the documentation.])
  91 fi
  92
  93 if test "$apu_found" = "reconfig"; then
  94   APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
  95   dnl We must be the last to build and the first to be cleaned
  96   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
  97   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
  98 fi
  99
 100 APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 101 APR_ADDTO(INCLUDES, `$apu_config --includes`)
 102 APU_BINDIR=`$apu_config --bindir`
 103 APU_INCLUDEDIR=`$apu_config --includedir`
 104
 105 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
 106
 107 APR_SUBDIR_CONFIG(srclib/pcre, "--prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir")
 108
 109 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
 110
 111 dnl Absolute source/build directory
 112 abs_srcdir=`(cd $srcdir && pwd)`
 113 abs_builddir=`pwd`
 114
 115 dnl If the source dir is not equal to the build dir,
 116 dnl then we are running in VPATH mode.
 117
 118 if test "$abs_builddir" != "$abs_srcdir"; then
 119   USE_VPATH=1
 120   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_builddir)/modules/proxy -I\$(top_srcdir)/modules/proxy -I\$(top_builddir)/modules/filters -I\$(top_srcdir)/modules/filters -I\$(top_builddir)/include -I\$(top_srcdir)/include])
 121 else
 122   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_SUBDIR_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/modules/filters -I\$(top_srcdir)/modules/proxy -I\$(top_srcdir)/include])
 123 fi
 124
 125 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
 126
 127 case $host in
 128   *os2*)
 129       # Use a custom made libtool replacement
 130       echo "using aplibtool"
 131       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 132       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 133       SH_LIBS="\$(ALL_LIBS)"
 134       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 135       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 136       MK_IMPLIB="emximp"
 137       other_targets="$other_targets os2core"
 138       INSTALL_PROG_FLAGS="-e .exe"
 139       SHLTCFLAGS=""
 140       LTCFLAGS=""
 141       ;;
 142   *)
 143       if test "x$LTFLAGS" = "x"; then
 144           LTFLAGS='--silent'
 145       fi
 146       my_libtool=`$apr_config --apr-libtool`
 147       LIBTOOL="$my_libtool \$(LTFLAGS)"
 148       libtoolversion=`$my_libtool --version`
 149       case $libtoolversion in
 150           *1.4*)
 151               SH_LIBTOOL='$(LIBTOOL)'
 152               SHLTCFLAGS="-prefer-pic"
 153               LTCFLAGS="-prefer-non-pic -static"
 154               ;;
 155           *)
 156               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 157               SHLTCFLAGS=""
 158               LTCFLAGS=""
 159               ;;
 160       esac
 161       ;;
 162 esac
 163 APACHE_SUBST(SHLTCFLAGS)
 164 APACHE_SUBST(LTCFLAGS)
 165
 166 AP_SIG_GRACEFUL=USR1
 167
 168 case $host in
 169   *-apple-aux3*)
 170       APR_SETVAR(APACHE_MPM, [prefork])
 171       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 172       ;;
 173   *-beos*)
 174       APR_SETVAR(APACHE_MPM, [beos])
 175       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 176       ;;
 177   *os2_emx*)
 178       APR_SETVAR(APACHE_MPM, [mpmt_os2])
 179       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 180       ;;
 181   *-linux-*)
 182       case `uname -r` in
 183         2.0* )
 184             AP_SIG_GRACEFUL=WINCH
 185             ;;
 186         2.[[2-9]]* )
 187             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 188             ;;
 189         * )
 190             ;;
 191       esac
 192       ;;
 193   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 194       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 195       ;;
 196   *-solaris2*)
 197       dnl This is a hack -- we should be using AC_TRY_RUN instead
 198       ap_platform_runtime_link_flag="-R"
 199       dnl solaris 8 and above don't have a thundering herd
 200       dnl not sure about rev's before this one.
 201       case `uname -r` in
 202         5.[567]*)
 203             ;;
 204         * )
 205             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 206             ;;
 207       esac
 208       ;;
 209   *cygwin*)
 210       APR_SETVAR(APACHE_MPM, [prefork])
 211       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 212       ;;
 213   *aix*)
 214       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 215       if test $aixver -ge 4320; then
 216         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 217       fi
 218       ;;
 219   *os390*)
 220       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 221       ;;
 222 esac
 223
 224 dnl
 225 dnl Process command line arguments. This is done early in the process so the
 226 dnl user can get feedback quickly in case of an error.
 227 dnl
 228 dnl ### need to move some of the arguments "up here"
 229
 230 dnl ## Check for programs
 231
 232 AC_PATH_PROG(RM, rm)
 233 AC_PROG_AWK
 234 AC_PROG_CC
 235 AC_PROG_CPP
 236 AC_PROG_INSTALL
 237 AC_PROG_LN_S
 238 AC_CHECK_TOOL(RANLIB, ranlib, true)
 239 dnl AC_PATH_PROG(PERL_PATH, perl)
 240 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 241
 242 dnl various OS checks that apparently set required flags
 243 AC_AIX
 244 AC_ISC_POSIX
 245 AC_MINIX
 246
 247 dnl Check for what we can generate dependency files with
 248 APR_CHECK_DEPEND
 249
 250 dnl ## Check for libraries
 251
 252 dnl ## Check for header files
 253
 254 dnl I think these are just used all over the place, so just check for
 255 dnl them at the base of the tree. If some are specific to a single
 256 dnl directory, they should be moved (Comment #Spoon)
 257
 258 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 259 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 260 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 261
 262 AC_HEADER_STDC
 263 AC_CHECK_HEADERS( \
 264 string.h \
 265 limits.h \
 266 unistd.h \
 267 sys/socket.h \
 268 pwd.h \
 269 grp.h \
 270 strings.h \
 271 sys/processor.h \
 272 sys/sem.h
 273 )
 274 AC_HEADER_SYS_WAIT
 275
 276 dnl ## Check for typedefs, structures, and compiler characteristics.
 277
 278 AC_C_CONST
 279 if test "$ac_cv_prog_gcc" = "yes"; then
 280   APR_ADDTO(NOTEST_CPPFLAGS,-DAP_HAVE_DESIGNATED_INITIALIZER)
 281 fi
 282
 283 dnl ## Check for library functions
 284
 285 dnl See Comment #Spoon
 286
 287 AC_CHECK_FUNCS( \
 288 getpwnam \
 289 getgrnam \
 290 initgroups \
 291 bindprocessor \
 292 timegm \
 293 )
 294
 295 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 296 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 297 [AC_TRY_COMPILE([#include <sys/types.h>
 298 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 299   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 300 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 301     AC_DEFINE(HAVE_GMTOFF)
 302 fi
 303
 304 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 305
 306 case $host in
 307     *aix*)
 308         # for 32-bit builds, increase MAXDATA to allow lots of threads
 309         if test x$OBJECT_MODE != x64; then
 310             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 311         fi
 312         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 313         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 314         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 315         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 316         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 317         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 318         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 319         ;;
 320     *os390*)
 321         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 322         ;;
 323     *)
 324         OS_SPECIFIC_VARS=""
 325 esac
 326
 327 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 328         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 329         [PORT=80])
 330
 331 dnl ## See if APR has IPv6 support
 332 ap_old_cppflags=$CPPFLAGS
 333 CPPFLAGS="$CPPFLAGS $INCLUDES"
 334 AC_TRY_COMPILE([#include <apr.h>], [
 335 #if !APR_HAVE_IPV6
 336 #error APR does not have IPv6 support
 337 #endif], apr_have_ipv6=yes, apr_have_ipv6=no)
 338 CPPFLAGS=$ap_old_cppflags
 339
 340 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 341 [
 342   v4mapped=$enableval
 343 ],
 344 [
 345     case $host in
 346     *freebsd5*|*netbsd*|*openbsd*)
 347         v4mapped=no
 348         ;;
 349     *)
 350         v4mapped=yes
 351         ;;
 352 esac
 353 ])
 354
 355 if test $v4mapped = "yes" -o $apr_have_ipv6 = "no"; then
 356     nonssl_listen_stmt_1=""
 357     nonssl_listen_stmt_2="Listen @@Port@@"
 358     if test $apr_have_ipv6 = "yes"; then
 359         AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 360                   [Allow IPv4 connections on IPv6 listening sockets])
 361     fi
 362 else
 363     nonssl_listen_stmt_1="Listen 0.0.0.0:@@Port@@"
 364     nonssl_listen_stmt_2="Listen [[::]]:@@Port@@"
 365 fi
 366
 367 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings),
 368 [
 369   APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 370 ])dnl
 371
 372 prefix="$orig_prefix"
 373 APACHE_ENABLE_MODULES
 374
 375 dnl reading config stubs
 376 esyscmd(./build/config-stubs .)
 377
 378 APACHE_SUBST(progname)
 379 APACHE_SUBST(MPM_LIB)
 380 APACHE_SUBST(OS)
 381 APACHE_SUBST(OS_DIR)
 382 APACHE_SUBST(BUILTIN_LIBS)
 383 APACHE_SUBST(SHLIBPATH_VAR)
 384 APACHE_SUBST(OS_SPECIFIC_VARS)
 385
 386 PRE_SHARED_CMDS='echo ""'
 387 POST_SHARED_CMDS='echo ""'
 388
 389 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 390
 391 if test "$apache_need_shared" = "yes"; then
 392   if test -f $ac_aux_dir/ltconfig; then
 393     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 394   fi
 395   shared_build="shared-build"
 396 fi
 397
 398 dnl enable_so tells us if *any* modules can be built as DSOs
 399
 400 if test "$enable_so" = "yes"; then
 401   case $host in
 402     *-ibm-aix*)
 403       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp"
 404       SH_LDFLAGS="$SH_LDFLAGS \$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)"
 405       UTIL_LDFLAGS="$UTIL_LDFLAGS -Wl,-uXML_Parse"
 406       ;;
 407     *beos)
 408       SH_LDFLAGS='$(top_builddir)/_APP_'
 409       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 410       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 411       ;;
 412     *os390)
 413       HTTPD_LDFLAGS="$HTTPD_LDFLAGS --main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll"
 414       SH_LDFLAGS="$SH_LDFLAGS --core-dll=$abs_srcdir/apachecore.dll"
 415   esac
 416 fi
 417
 418 APACHE_SUBST(PRE_SHARED_CMDS)
 419 APACHE_SUBST(POST_SHARED_CMDS)
 420 APACHE_SUBST(shared_build)
 421
 422 AC_ARG_WITH(program-name,
 423 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 424   progname="$withval" ], [
 425   progname="httpd"] )
 426
 427 # SuExec parameters
 428 AC_ARG_WITH(suexec-bin,
 429 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 430   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 431 ] )
 432
 433 AC_ARG_WITH(suexec-caller,
 434 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 435   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 436
 437 AC_ARG_WITH(suexec-userdir,
 438 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 439   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 440
 441 AC_ARG_WITH(suexec-docroot,
 442 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 443   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 444
 445 AC_ARG_WITH(suexec-uidmin,
 446 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 447   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 448
 449 AC_ARG_WITH(suexec-gidmin,
 450 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 451   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 452
 453 AC_ARG_WITH(suexec-logfile,
 454 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 455   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 456
 457 AC_ARG_WITH(suexec-safepath,
 458 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 459   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 460
 461 AC_ARG_WITH(suexec-umask,
 462 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 463   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 464
 465 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 466 AP_LIBS="$abs_builddir/srclib/pcre/libpcre.la $AP_LIBS"
 467
 468 dnl APR should go after the other libs, so the right symbols can be picked up
 469 AP_LIBS="$AP_LIBS `$apu_config --link-libtool --libs` `$apr_config --link-libtool --libs`"
 470 APACHE_SUBST(AP_LIBS)
 471 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 472 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 473
 474 AC_DEFINE(AP_USING_AUTOCONF, 1,
 475                 [Using autoconf to configure Apache])
 476
 477 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 478     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 479               [This platform doesn't suffer from the thundering herd problem])
 480 fi
 481
 482 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL, SIG$AP_SIG_GRACEFUL, [Signal used to gracefully restart])
 483 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_STRING, "SIG$AP_SIG_GRACEFUL", [Signal used to gracefully restart (as a quoted string)])
 484 AC_DEFINE_UNQUOTED(AP_SIG_GRACEFUL_SHORT, $AP_SIG_GRACEFUL, [Signal used to gracefully restart (without SIG prefix)])
 485 AP_SIG_GRACEFUL_SHORT=$AP_SIG_GRACEFUL
 486 AP_SIG_GRACEFUL=SIG$AP_SIG_GRACEFUL_SHORT
 487 AC_SUBST(AP_SIG_GRACEFUL)
 488 AC_SUBST(AP_SIG_GRACEFUL_STRING)
 489 AC_SUBST(AP_SIG_GRACEFUL_SHORT)
 490
 491 dnl check for endianness
 492 if test "$cross_compiling" = "no"; then
 493   AC_C_BIGENDIAN
 494 else
 495   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 496                 [byte order is unknown due to cross-compilation])
 497 fi
 498
 499 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 500 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 501 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 502 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 503
 504 if test -d ./test; then
 505     APACHE_FAST_OUTPUT(test/Makefile)
 506 fi
 507
 508 dnl ## Finalize the variables
 509 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 510
 511 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 512 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 513 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 514 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 515 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 516 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 517
 518 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 519
 520 APACHE_GEN_CONFIG_VARS
 521
 522 dnl ## Build modules.c
 523 rm -f modules.c
 524 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 525
 526 APR_EXPAND_VAR(ap_prefix, $prefix)
 527 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 528         [Root directory of the Apache install area])
 529 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 530         [Location of the config file, relative to the Apache root directory])
 531 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 532         [Location of the MIME types config file, relative to the Apache root directory])
 533 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 534         [Location of the source for the current MPM])
 535
 536 perlbin=`$ac_aux_dir/PrintPath perl`
 537 if test "x$perlbin" = "x"; then
 538     perlbin="/replace/with/path/to/perl/interpreter"
 539 fi
 540 AC_SUBST(perlbin)
 541
 542 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 543
 544 BSD_MAKEFILE=no
 545 ap_make_include=include
 546 ap_make_delimiter=' '
 547 case $host in
 548 *bsdi*)
 549     # Check whether they've installed GNU make
 550     if make --version > /dev/null 2>&1; then
 551         true
 552     else
 553         BSD_MAKEFILE=yes
 554         ap_make_include=.include
 555         ap_make_delimiter='"'
 556     fi
 557     ;;
 558 esac
 559 AC_SUBST(ap_make_include)
 560 AC_SUBST(ap_make_delimiter)
 561
 562 dnl Ensure that docs/conf is created.
 563 test -d docs/conf||$mkdir_p docs/conf
 564
 565 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd-std.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk,[true],[
 566   APACHE_GEN_MAKEFILES
 567 ])
 568