granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.507 2007/03/29 15:30:51 mha Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.3devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2007, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # --enable-profiling enables gcc profiling
 210 #
 211 PGAC_ARG_BOOL(enable, profiling, no,
 212               [  --enable-profiling      build with profiling enabled ])
 213 AC_SUBST(enable_profiling)
 214
 215 #
 216 # DTrace
 217 #
 218 PGAC_ARG_BOOL(enable, dtrace, no,
 219               [  --enable-dtrace         build with DTrace support],
 220 [AC_DEFINE([ENABLE_DTRACE], 1,
 221            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 222 AC_CHECK_PROGS(DTRACE, dtrace)
 223 if test -z "$DTRACE"; then
 224   AC_MSG_ERROR([dtrace not found])
 225 fi
 226 AC_SUBST(DTRACEFLAGS)])
 227 AC_SUBST(enable_dtrace)
 228
 229 #
 230 # C compiler
 231 #
 232
 233 # For historical reasons you can also use --with-CC to specify the C compiler
 234 # to use, although the standard way to do this is to set the CC environment
 235 # variable.
 236 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 237
 238 case $template in
 239   aix) pgac_cc_list="gcc xlc";;
 240  irix) pgac_cc_list="cc";; # no gcc
 241     *) pgac_cc_list="gcc cc";;
 242 esac
 243
 244 AC_PROG_CC([$pgac_cc_list])
 245
 246 unset CFLAGS
 247
 248 #
 249 # Read the template
 250 #
 251 . "$srcdir/src/template/$template" || exit
 252
 253 # CFLAGS are selected so:
 254 # If the user specifies something in the environment, that is used.
 255 # else:  If the template file set something, that is used.
 256 # else:  If the compiler is GCC, then we use -O2.
 257 # else:  If the compiler is something else, then we use -0.
 258
 259 if test "$ac_env_CFLAGS_set" = set; then
 260   CFLAGS=$ac_env_CFLAGS_value
 261 elif test "${CFLAGS+set}" = set; then
 262   : # (keep what template set)
 263 elif test "$GCC" = yes; then
 264   CFLAGS="-O2"
 265 else
 266   # if the user selected debug mode, don't use -O
 267   if test "$enable_debug" != yes; then
 268     CFLAGS="-O"
 269   fi
 270 fi
 271
 272 # Some versions of GCC support some additional useful warning flags.
 273 # Check whether they are supported, and add them to CFLAGS if so.
 274
 275 if test "$GCC" = yes; then
 276
 277 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 278 # So we have to check if "GCC" is really ICC.
 279 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 280 choke me
 281 @%:@endif], [ICC=[yes]], [ICC=[no]])
 282
 283   if test "$ICC" = no; then
 284     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 285
 286     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 287     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 288   else
 289     # Intel compiler has a bug/misoptimization in checking for
 290     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 291     # CFLAGS.
 292     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 293   fi
 294
 295   # Disable strict-aliasing rules; needed for gcc 3.3+
 296   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 297 elif test x"${CC}" = x"xlc"; then
 298   # AIX xlc has to have strict aliasing turned off too
 299   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 300 fi
 301
 302 # supply -g if --enable-debug
 303 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 304   CFLAGS="$CFLAGS -g"
 305 fi
 306
 307 # enable profiling if --enable-profiling
 308 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 309   if test "$GCC" = yes; then
 310     AC_DEFINE([PROFILE_PID_DIR], 1,
 311            [Define to 1 to enable profiling. (--enable-profiling)])
 312     CFLAGS="$CFLAGS -pg"
 313   else
 314     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 315   fi
 316 fi
 317
 318 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 319
 320 # We already have this in Makefile.win32, but configure needs it too
 321 if test "$PORTNAME" = "win32"; then
 322   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 323 fi
 324
 325 # Check if the compiler still works with the template settings
 326 AC_MSG_CHECKING([whether the C compiler still works])
 327 AC_TRY_LINK([], [return 0;],
 328   [AC_MSG_RESULT(yes)],
 329   [AC_MSG_RESULT(no)
 330    AC_MSG_ERROR([cannot proceed])])
 331
 332 # Defend against gcc -ffast-math
 333 if test "$GCC" = yes; then
 334 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 335 choke me
 336 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 337 fi
 338
 339 AC_PROG_CPP
 340 AC_SUBST(GCC)
 341
 342 # Create compiler version string
 343 if test x"$GCC" = x"yes" ; then
 344   cc_string="GCC `${CC} --version | sed q`"
 345 else
 346   cc_string=$CC
 347 fi
 348 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 349                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 350                    [A string containing the version number, platform, and C compiler])
 351
 352
 353 #
 354 # Set up TAS assembly code if needed; the template file has now had its
 355 # chance to request this.
 356 #
 357 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 358
 359 if test "$need_tas" = yes ; then
 360   TAS=tas.o
 361 else
 362   TAS=""
 363 fi
 364 AC_SUBST(TAS)
 365
 366
 367 #
 368 # Automatic dependency tracking
 369 #
 370 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 371               [autodepend=yes])
 372 AC_SUBST(autodepend)
 373
 374
 375 #
 376 # Enable assert checks
 377 #
 378 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 379               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 380                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 381
 382
 383 #
 384 # Include directories
 385 #
 386 ac_save_IFS=$IFS
 387 IFS="${IFS}${PATH_SEPARATOR}"
 388 # SRCH_INC comes from the template file
 389 for dir in $with_includes $SRCH_INC; do
 390   if test -d "$dir"; then
 391     INCLUDES="$INCLUDES -I$dir"
 392   else
 393     AC_MSG_WARN([*** Include directory $dir does not exist.])
 394   fi
 395 done
 396 IFS=$ac_save_IFS
 397 AC_SUBST(INCLUDES)
 398
 399
 400 #
 401 # Library directories
 402 #
 403 ac_save_IFS=$IFS
 404 IFS="${IFS}${PATH_SEPARATOR}"
 405 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 406 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 407   if test -d "$dir"; then
 408     LIBDIRS="$LIBDIRS -L$dir"
 409   else
 410     AC_MSG_WARN([*** Library directory $dir does not exist.])
 411   fi
 412 done
 413 IFS=$ac_save_IFS
 414
 415 #
 416 # Enable thread-safe client libraries
 417 #
 418 AC_MSG_CHECKING([allow thread-safe client libraries])
 419 if test "$PORTNAME" != "win32"; then
 420 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 421 else
 422 # Win32 should always use threads
 423 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 424 fi
 425
 426 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 427 if test "$enable_thread_safety" = yes -o \
 428         "$enable_thread_safety_force" = yes; then
 429   enable_thread_safety="yes"    # for 'force'
 430   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 431           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 432 fi
 433 AC_MSG_RESULT([$enable_thread_safety])
 434 AC_SUBST(enable_thread_safety)
 435
 436 #
 437 # Optionally build Tcl modules (PL/Tcl)
 438 #
 439 AC_MSG_CHECKING([whether to build with Tcl])
 440 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 441 AC_MSG_RESULT([$with_tcl])
 442 AC_SUBST([with_tcl])
 443
 444 # We see if the path to the Tcl/Tk configuration scripts is specified.
 445 # This will override the use of tclsh to find the paths to search.
 446
 447 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 448
 449 #
 450 # Optionally build Perl modules (PL/Perl)
 451 #
 452 AC_MSG_CHECKING([whether to build Perl modules])
 453 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 454 AC_MSG_RESULT([$with_perl])
 455 AC_SUBST(with_perl)
 456
 457 #
 458 # Optionally build Python modules (PL/Python)
 459 #
 460 AC_MSG_CHECKING([whether to build Python modules])
 461 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 462 AC_MSG_RESULT([$with_python])
 463 AC_SUBST(with_python)
 464
 465 #
 466 # Kerberos 5
 467 #
 468 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 469 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 470 [
 471   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 472   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 473 ])
 474 AC_MSG_RESULT([$with_krb5])
 475 AC_SUBST(with_krb5)
 476
 477
 478 AC_SUBST(krb_srvtab)
 479
 480
 481 #
 482 # Kerberos configuration parameters
 483 #
 484 PGAC_ARG_REQ(with, krb-srvnam,
 485              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 486              [],
 487              [with_krb_srvnam="postgres"])
 488 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 489                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 490
 491
 492 #
 493 # PAM
 494 #
 495 AC_MSG_CHECKING([whether to build with PAM support])
 496 PGAC_ARG_BOOL(with, pam, no,
 497               [  --with-pam              build with PAM support],
 498               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 499 AC_MSG_RESULT([$with_pam])
 500 AC_SUBST(with_pam)
 501
 502
 503 #
 504 # LDAP
 505 #
 506 AC_MSG_CHECKING([whether to build with LDAP support])
 507 PGAC_ARG_BOOL(with, ldap, no,
 508               [  --with-ldap             build with LDAP support],
 509               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 510 AC_MSG_RESULT([$with_ldap])
 511 AC_SUBST(with_ldap)
 512
 513
 514 #
 515 # Bonjour
 516 #
 517 AC_MSG_CHECKING([whether to build with Bonjour support])
 518 PGAC_ARG_BOOL(with, bonjour, no,
 519               [  --with-bonjour          build with Bonjour support],
 520               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 521 AC_MSG_RESULT([$with_bonjour])
 522 AC_SUBST(with_bonjour)
 523
 524
 525 #
 526 # OpenSSL
 527 #
 528 AC_MSG_CHECKING([whether to build with OpenSSL support])
 529 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 530               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 531 AC_MSG_RESULT([$with_openssl])
 532 AC_SUBST(with_openssl)
 533
 534
 535 #
 536 # Readline
 537 #
 538 PGAC_ARG_BOOL(with, readline, yes,
 539               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 540 # readline on MinGW has problems with backslashes in psql and other bugs.
 541 # This is particularly a problem with non-US code pages.
 542 # Therefore disable its use until we understand the cause. 2004-07-20
 543 if test "$PORTNAME" = "win32"; then
 544   if test "$with_readline" = yes; then
 545     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 546     with_readline=no
 547   fi
 548 fi
 549
 550
 551 #
 552 # Prefer libedit
 553 #
 554 PGAC_ARG_BOOL(with, libedit-preferred, no,
 555               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 556
 557
 558 #
 559 # XML
 560 #
 561 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 562               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 563
 564 if test "$with_libxml" = yes ; then
 565   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 566   if test -n "$XML2_CONFIG"; then
 567     for pgac_option in `$XML2_CONFIG --cflags`; do
 568       case $pgac_option in
 569         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 570       esac
 571     done
 572     for pgac_option in `$XML2_CONFIG --libs`; do
 573       case $pgac_option in
 574         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 575       esac
 576     done
 577   fi
 578 fi
 579
 580
 581 #
 582 # Zlib
 583 #
 584 PGAC_ARG_BOOL(with, zlib, yes,
 585               [  --without-zlib          do not use Zlib])
 586 AC_SUBST(with_zlib)
 587
 588 #
 589 # Elf
 590 #
 591
 592 # Assume system is ELF if it predefines __ELF__ as 1,
 593 # otherwise believe host_os based default.
 594 case $host_os in
 595     freebsd1*|freebsd2*) elf=no;;
 596     freebsd3*|freebsd4*) elf=yes;;
 597 esac
 598
 599 AC_EGREP_CPP(yes,
 600 [#if __ELF__
 601   yes
 602 #endif
 603 ],
 604 [ELF_SYS=true],
 605 [if test "X$elf" = "Xyes" ; then
 606   ELF_SYS=true
 607 else
 608   ELF_SYS=
 609 fi])
 610 AC_SUBST(ELF_SYS)
 611
 612 #
 613 # Assignments
 614 #
 615
 616 CPPFLAGS="$CPPFLAGS $INCLUDES"
 617 LDFLAGS="$LDFLAGS $LIBDIRS"
 618
 619 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 620 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 621
 622 AC_ARG_VAR(LDFLAGS_SL)
 623
 624 AC_PROG_AWK
 625 PGAC_PATH_FLEX
 626 AC_PROG_LN_S
 627 PGAC_PROG_LD
 628 AC_SUBST(LD)
 629 AC_SUBST(with_gnu_ld)
 630 case $host_os in sysv5*)
 631   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 632   [
 633     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 634     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 635     LDFLAGS=$pgac_save_LDFLAGS
 636   ])
 637   ld_R_works=$pgac_cv_prog_ld_R
 638   AC_SUBST(ld_R_works)
 639 esac
 640 AC_PROG_RANLIB
 641 AC_PATH_PROG(TAR, tar)
 642 PGAC_CHECK_STRIP
 643
 644 if test -z "$YACC"; then
 645   AC_CHECK_PROGS(YACC, ['bison -y'])
 646
 647   if test "$YACC"; then
 648     if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 649       AC_MSG_WARN([
 650 *** The installed version of Bison is too old to use with PostgreSQL.
 651 *** Bison version 1.875 or later is required.])
 652       YACC=""
 653     fi
 654   fi
 655
 656   if test -z "$YACC"; then
 657     AC_MSG_WARN([
 658 *** Without Bison you will not be able to build PostgreSQL from CVS nor
 659 *** change any of the parser definition files.  You can obtain Bison from
 660 *** a GNU mirror site.  (If you are using the official distribution of
 661 *** PostgreSQL then you do not need to worry about this, because the Bison
 662 *** output is pre-generated.)  To use a different yacc program (possible,
 663 *** but not recommended), set the environment variable YACC before running
 664 *** 'configure'.])
 665   fi
 666 fi
 667 AC_SUBST(YFLAGS)
 668
 669 PGAC_PATH_PERL
 670 if test "$with_perl" = yes; then
 671   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 672   PGAC_CHECK_PERL_EMBED_LDFLAGS
 673 fi
 674
 675 if test "$with_python" = yes; then
 676   PGAC_PATH_PYTHON
 677   PGAC_CHECK_PYTHON_EMBED_SETUP
 678 fi
 679
 680 # Supply a numeric version string for use by 3rd party add-ons
 681 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 682 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 683 tr '.' '        ' |
 684 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 685 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 686
 687 ##
 688 ## Libraries
 689 ##
 690 ## Most libraries are included only if they demonstrably provide a function
 691 ## we need, but libm is an exception: always include it, because there are
 692 ## too many compilers that play cute optimization games that will break
 693 ## probes for standard functions such as pow().
 694 ##
 695
 696 AC_CHECK_LIB(m, main)
 697 AC_SEARCH_LIBS(setproctitle, util)
 698 AC_SEARCH_LIBS(dlopen, dl)
 699 AC_SEARCH_LIBS(socket, [socket wsock32])
 700 AC_SEARCH_LIBS(shl_load, dld)
 701 # We only use libld in port/dynloader/aix.c
 702 case $host_os in
 703      aix*)
 704         AC_SEARCH_LIBS(ldopen, ld)
 705         ;;
 706 esac
 707 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 708 AC_SEARCH_LIBS(crypt, crypt)
 709 # Solaris:
 710 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 711 # Cygwin:
 712 AC_SEARCH_LIBS(shmget, cygipc)
 713
 714 if test "$with_readline" = yes; then
 715   PGAC_CHECK_READLINE
 716   if test x"$pgac_cv_check_readline" = x"no"; then
 717     AC_MSG_ERROR([readline library not found
 718 If you have readline already installed, see config.log for details on the
 719 failure.  It is possible the compiler isn't looking in the proper directory.
 720 Use --without-readline to disable readline support.])
 721   fi
 722 fi
 723
 724 if test "$with_zlib" = yes; then
 725   AC_CHECK_LIB(z, inflate, [],
 726                [AC_MSG_ERROR([zlib library not found
 727 If you have zlib already installed, see config.log for details on the
 728 failure.  It is possible the compiler isn't looking in the proper directory.
 729 Use --without-zlib to disable zlib support.])])
 730 fi
 731
 732 if test "$enable_spinlocks" = yes; then
 733   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 734 else
 735   AC_MSG_WARN([
 736 *** Not using spinlocks will cause poor performance.])
 737 fi
 738
 739 if test "$with_krb5" = yes ; then
 740   if test "$PORTNAME" != "win32"; then
 741      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 742                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 743      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 744                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 745   else
 746      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 747                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 748   fi
 749 fi
 750
 751 if test "$with_openssl" = yes ; then
 752   dnl Order matters!
 753   if test "$PORTNAME" != "win32"; then
 754      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 755      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 756   else
 757      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 758      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 759   fi
 760 fi
 761
 762 if test "$with_pam" = yes ; then
 763   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 764 fi
 765
 766 if test "$with_libxml" = yes ; then
 767   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 768 fi
 769
 770
 771 ##
 772 ## Header files
 773 ##
 774
 775 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 776 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 777
 778 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 779 # netinet/in.h is included first.
 780 AC_CHECK_HEADERS(netinet/in.h)
 781 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 782 [AC_INCLUDES_DEFAULT
 783 #ifdef HAVE_NETINET_IN_H
 784 #include <netinet/in.h>
 785 #endif
 786 ])
 787
 788 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 789   AC_CHECK_HEADERS(readline/readline.h, [],
 790         [AC_CHECK_HEADERS(readline.h, [],
 791                 [AC_MSG_ERROR([readline header not found
 792 If you have readline already installed, see config.log for details on the
 793 failure.  It is possible the compiler isn't looking in the proper directory.
 794 Use --without-readline to disable readline support.])])])
 795   AC_CHECK_HEADERS(readline/history.h, [],
 796         [AC_CHECK_HEADERS(history.h, [],
 797                 [AC_MSG_ERROR([history header not found
 798 If you have readline already installed, see config.log for details on the
 799 failure.  It is possible the compiler isn't looking in the proper directory.
 800 Use --without-readline to disable readline support.])])])
 801 fi
 802
 803 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 804 # Some installations of libedit usurp /usr/include/readline/, which seems
 805 # bad practice, since in combined installations readline will have its headers
 806 # there.  We might have to resort to AC_EGREP checks to make sure we found
 807 # the proper header...
 808   AC_CHECK_HEADERS(editline/readline.h, [],
 809         [AC_CHECK_HEADERS(readline.h, [],
 810                 [AC_CHECK_HEADERS(readline/readline.h, [],
 811                         [AC_MSG_ERROR([readline header not found
 812 If you have libedit already installed, see config.log for details on the
 813 failure.  It is possible the compiler isn't looking in the proper directory.
 814 Use --without-readline to disable libedit support.])])])])
 815 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 816 # not be there at all.  Hence, don't complain if not found.  We must check
 817 # though, since in yet other versions it is an independent header.
 818   AC_CHECK_HEADERS(editline/history.h, [],
 819         [AC_CHECK_HEADERS(history.h, [],
 820                 [AC_CHECK_HEADERS(readline/history.h)])])
 821 fi
 822
 823 if test "$with_zlib" = yes; then
 824   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 825 If you have zlib already installed, see config.log for details on the
 826 failure.  It is possible the compiler isn't looking in the proper directory.
 827 Use --without-zlib to disable zlib support.])])
 828 fi
 829
 830 if test "$with_krb5" = yes ; then
 831   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 832 fi
 833
 834 if test "$with_openssl" = yes ; then
 835   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 836   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 837 fi
 838
 839 if test "$with_pam" = yes ; then
 840   AC_CHECK_HEADERS(security/pam_appl.h, [],
 841                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 842                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 843 fi
 844
 845 if test "$with_libxml" = yes ; then
 846   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 847 fi
 848
 849 if test "$with_ldap" = yes ; then
 850   if test "$PORTNAME" != "win32"; then
 851      AC_CHECK_HEADERS(ldap.h, [],
 852                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 853   else
 854      AC_CHECK_HEADERS(winldap.h, [],
 855                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 856                       [AC_INCLUDES_DEFAULT
 857 #include <windows.h>
 858                       ])
 859   fi
 860 fi
 861
 862 if test "$with_bonjour" = yes ; then
 863   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 864 fi
 865
 866
 867 ##
 868 ## Types, structures, compiler characteristics
 869 ##
 870
 871 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 872 AC_C_CONST
 873 AC_C_INLINE
 874 AC_C_STRINGIZE
 875 PGAC_C_SIGNED
 876 AC_C_VOLATILE
 877 PGAC_C_FUNCNAME_SUPPORT
 878 PGAC_STRUCT_TIMEZONE
 879 PGAC_UNION_SEMUN
 880 PGAC_STRUCT_SOCKADDR_UN
 881 PGAC_STRUCT_SOCKADDR_STORAGE
 882 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 883 PGAC_STRUCT_ADDRINFO
 884
 885 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 886 [#include <sys/param.h>
 887 #include <sys/types.h>
 888 #include <sys/socket.h>
 889 #include <sys/ucred.h>])
 890
 891 AC_CHECK_TYPES([struct option], [], [],
 892 [#ifdef HAVE_GETOPT_H
 893 #include <getopt.h>
 894 #endif])
 895
 896 if test "$with_zlib" = yes; then
 897   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 898   # did not).  While we could work around the lack of z_streamp, it
 899   # seems unwise to encourage people to use such old zlib versions...
 900   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 901 Use --without-zlib to disable zlib support.])],
 902                 [#include <zlib.h>])
 903 fi
 904
 905 if test "$with_krb5" = yes; then
 906 # Check for differences between MIT and Heimdal (KTH) releases
 907   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 908                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 909                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 910                                      [#include <krb5.h>])],
 911                    [#include <krb5.h>])
 912   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 913                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 914                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 915                                      [#include <krb5.h>])],
 916                    [#include <krb5.h>])
 917 fi
 918
 919
 920 ##
 921 ## Functions, global variables
 922 ##
 923
 924 PGAC_VAR_INT_TIMEZONE
 925 AC_FUNC_ACCEPT_ARGTYPES
 926 PGAC_FUNC_GETTIMEOFDAY_1ARG
 927
 928 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 929
 930 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 931 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 932 AC_CHECK_DECLS([strlcat, strlcpy])
 933 # This is probably only present on Darwin, but may as well check always
 934 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 935
 936 HAVE_IPV6=no
 937 AC_CHECK_TYPE([struct sockaddr_in6],
 938         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 939          HAVE_IPV6=yes],
 940         [],
 941 [$ac_includes_default
 942 #include <netinet/in.h>])
 943 AC_SUBST(HAVE_IPV6)
 944
 945 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 946 [AC_TRY_LINK(
 947 [#include <machine/vmparam.h>
 948 #include <sys/exec.h>
 949 ],
 950 [PS_STRINGS->ps_nargvstr = 1;
 951 PS_STRINGS->ps_argvstr = "foo";],
 952 [pgac_cv_var_PS_STRINGS=yes],
 953 [pgac_cv_var_PS_STRINGS=no])])
 954 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 955   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 956 fi
 957
 958
 959 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 960 # is missing.  Yes, there are machines that have only one.  We may
 961 # also decide to use snprintf.c if snprintf() is present but does not
 962 # have all the features we need --- see below.
 963
 964 if test "$PORTNAME" = "win32"; then
 965   # Win32 gets snprintf.c built unconditionally.
 966   #
 967   # To properly translate all NLS languages strings, we must support the
 968   # *printf() %$ format, which allows *printf() arguments to be selected
 969   # by position in the translated string.
 970   #
 971   # libintl versions < 0.13 use the native *printf() functions, and Win32
 972   # *printf() doesn't understand %$, so we must use our /port versions,
 973   # which do understand %$. libintl versions >= 0.13 include their own
 974   # *printf versions on Win32.  The libintl 0.13 release note text is:
 975   #
 976   #   C format strings with positions, as they arise when a translator
 977   #   needs to reorder a sentence, are now supported on all platforms.
 978   #   On those few platforms (NetBSD and Woe32) for which the native
 979   #   printf()/fprintf()/... functions don't support such format
 980   #   strings, replacements are provided through <libintl.h>.
 981   #
 982   # We could use libintl >= 0.13's *printf() if we were sure that we had
 983   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 984   # to guarantee that, it is best to just use our own, so we are sure to
 985   # get %$ support. In include/port.h we disable the *printf() macros
 986   # that might have been defined by libintl.
 987   #
 988   # We do this unconditionally whether NLS is used or not so we are sure
 989   # that all Win32 libraries and binaries behave the same.
 990   pgac_need_repl_snprintf=yes
 991 else
 992   pgac_need_repl_snprintf=no
 993   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 994   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 995 fi
 996
 997
 998 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 999 # include/c.h will provide declarations.  Note this is a separate test
1000 # from whether the functions exist in the C library --- there are
1001 # systems that have the functions but don't bother to declare them :-(
1002
1003 AC_CHECK_DECLS([snprintf, vsnprintf])
1004
1005
1006 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1007 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1008 [AC_TRY_LINK([
1009 #include <math.h>
1010 double glob_double;
1011 ],
1012 [return isinf(glob_double) ? 0 : 1;],
1013 [ac_cv_func_isinf=yes],
1014 [ac_cv_func_isinf=no])])
1015
1016 if test $ac_cv_func_isinf = yes ; then
1017   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1018 else
1019   AC_LIBOBJ(isinf)
1020   # Look for a way to implement a substitute for isinf()
1021   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1022 fi
1023
1024 # Some versions of libedit contain strlcpy(); so disregard that library while
1025 # checking for these standard libc functions.
1026 pgac_save_LIBS="$LIBS"
1027 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1028
1029 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1030
1031 LIBS="$pgac_save_LIBS"
1032
1033 # System's version of getaddrinfo(), if any, may be used only if we found
1034 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1035 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1036 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1037 # because we want to use our own getaddrinfo.c on Windows anyway.)
1038 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1039   AC_REPLACE_FUNCS([getaddrinfo])
1040 else
1041   AC_LIBOBJ(getaddrinfo)
1042 fi
1043
1044 # similarly, use system's getopt_long() only if system provides struct option.
1045 if test x"$ac_cv_type_struct_option" = xyes ; then
1046   AC_REPLACE_FUNCS([getopt_long])
1047 else
1048   AC_LIBOBJ(getopt_long)
1049 fi
1050
1051 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1052 # We override the previous test that said fseeko/ftello didn't exist
1053 # OS tests are also done in include/c.h and port/fseeko.c
1054 case $host_os in bsdi*|netbsd*)
1055 ac_cv_func_fseeko=yes
1056 esac
1057
1058 # Win32 support
1059 if test "$PORTNAME" = "win32"; then
1060 AC_LIBOBJ(gettimeofday)
1061 AC_LIBOBJ(kill)
1062 AC_LIBOBJ(open)
1063 AC_LIBOBJ(rand)
1064 AC_LIBOBJ(win32error)
1065 AC_DEFINE([HAVE_SYMLINK], 1,
1066           [Define to 1 if you have the `symlink' function.])
1067 fi
1068
1069 if test "$with_readline" = yes; then
1070   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1071   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1072   AC_CHECK_FUNCS([replace_history_entry])
1073 fi
1074
1075
1076 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1077 dnl (especially on GNU libc)
1078 dnl See also comments in c.h.
1079 AC_MSG_CHECKING(for sigsetjmp)
1080 AC_TRY_LINK([#include <setjmp.h>],
1081             [sigjmp_buf x; sigsetjmp(x, 1);],
1082             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1083 AC_MSG_RESULT(yes)],
1084             [AC_MSG_RESULT(no)])
1085
1086 AC_DECL_SYS_SIGLIST
1087
1088 AC_CHECK_FUNC(syslog,
1089               [AC_CHECK_HEADER(syslog.h,
1090                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1091
1092 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1093 [AC_TRY_LINK([#include <unistd.h>],
1094   [extern int optreset; optreset = 1;],
1095   [pgac_cv_var_int_optreset=yes],
1096   [pgac_cv_var_int_optreset=no])])
1097 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1098   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1099 fi
1100
1101 AC_CHECK_FUNCS([strtoll strtoq], [break])
1102 AC_CHECK_FUNCS([strtoull strtouq], [break])
1103
1104 # Check for one of atexit() or on_exit()
1105 AC_CHECK_FUNCS(atexit, [],
1106                [AC_CHECK_FUNCS(on_exit, [],
1107                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1108
1109 AC_FUNC_FSEEKO
1110
1111 #
1112 # Pthreads
1113 #
1114 # For each platform, we need to know about any special compile and link
1115 # libraries, and whether the normal C function names are thread-safe.
1116 # See the comment at the top of src/port/thread.c for more information.
1117 # WIN32 doesn't need the pthread tests;  it always uses threads
1118 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1119 ACX_PTHREAD     # set thread flags
1120
1121 # Some platforms use these, so just defineed them.  They can't hurt if they
1122 # are not supported.
1123 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1124
1125
1126 # At this point, we don't want to muck with the compiler name for threading.
1127 # Let's see who fails, perhaps AIX.  2004-04-23
1128 if test "$PTHREAD_CC" != "$CC"; then
1129 AC_MSG_ERROR([
1130 PostgreSQL does not support platforms that require a special compiler
1131 for thread safety.])
1132 fi
1133
1134 if test "$THREAD_SUPPORT" = no; then
1135 AC_MSG_ERROR([cannot enable threads on this platform
1136 This platform is known to not support thread-safe programs.  For details,
1137 compile and run src/bin/pg_thread_test.])
1138 fi
1139
1140 # Check for *_r functions
1141 _CFLAGS="$CFLAGS"
1142 _LIBS="$LIBS"
1143 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1144 LIBS="$LIBS $PTHREAD_LIBS"
1145
1146 if test "$PORTNAME" != "win32"; then
1147 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1148 fi
1149
1150 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1151
1152 # Do test here with the proper thread flags
1153 PGAC_FUNC_GETPWUID_R_5ARG
1154 PGAC_FUNC_STRERROR_R_INT
1155
1156 CFLAGS="$_CFLAGS"
1157 LIBS="$_LIBS"
1158
1159 else
1160 # do not use values from template file
1161 PTHREAD_CFLAGS=
1162 PTHREAD_LIBS=
1163 fi
1164
1165 AC_SUBST(PTHREAD_CFLAGS)
1166 AC_SUBST(PTHREAD_LIBS)
1167
1168
1169 # We can test for libldap_r only after we know PTHREAD_LIBS
1170 if test "$with_ldap" = yes ; then
1171   _LIBS="$LIBS"
1172   if test "$PORTNAME" != "win32"; then
1173     AC_CHECK_LIB(ldap, ldap_bind, [],
1174                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1175                  [$EXTRA_LDAP_LIBS])
1176     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1177     if test "$enable_thread_safety" = yes; then
1178       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1179       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1180                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1181                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1182       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1183     else
1184       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1185     fi
1186   else
1187     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1188     LDAP_LIBS_FE="-lwldap32"
1189     LDAP_LIBS_BE="-lwldap32"
1190   fi
1191   LIBS="$_LIBS"
1192 fi
1193 AC_SUBST(LDAP_LIBS_FE)
1194 AC_SUBST(LDAP_LIBS_BE)
1195
1196
1197 # This test makes sure that run tests work at all.  Sometimes a shared
1198 # library is found by the linker, but the runtime linker can't find it.
1199 # This check should come after all modifications of compiler or linker
1200 # variables, and before any other run tests.
1201 AC_MSG_CHECKING([test program])
1202 AC_TRY_RUN([int main() { return 0; }],
1203 [AC_MSG_RESULT(ok)],
1204 [AC_MSG_RESULT(failed)
1205 AC_MSG_ERROR([[
1206 Could not execute a simple test program.  This may be a problem
1207 related to locating shared libraries.  Check the file 'config.log'
1208 for the exact reason.]])],
1209 [AC_MSG_RESULT([cross-compiling])])
1210
1211 # --------------------
1212 # Run tests below here
1213 # --------------------
1214
1215 # Force use of our snprintf if system's doesn't do arg control
1216 # See comment above at snprintf test for details.
1217 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1218   PGAC_FUNC_PRINTF_ARG_CONTROL
1219   if test $pgac_cv_printf_arg_control != yes ; then
1220     pgac_need_repl_snprintf=yes
1221   fi
1222 fi
1223
1224
1225 dnl Check to see if we have a working 64-bit integer type.
1226 dnl This breaks down into two steps:
1227 dnl (1) figure out if the compiler has a 64-bit int type with working
1228 dnl arithmetic, and if so
1229 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1230 dnl snprintf is the only library routine we really need for int8 support.)
1231 dnl It's entirely possible to have a compiler that handles a 64-bit type
1232 dnl when the C library doesn't; this is fairly likely when using gcc on
1233 dnl an older platform, for example.
1234 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1235 dnl we force our own version of snprintf() to be used instead.
1236 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1237
1238 PGAC_TYPE_64BIT_INT([long int])
1239
1240 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1241   PGAC_TYPE_64BIT_INT([long long int])
1242 fi
1243
1244
1245 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1246
1247 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1248   AC_TRY_COMPILE([
1249 #define INT64CONST(x)  x##LL
1250 long long int foo = INT64CONST(0x1234567890123456);
1251 ],
1252         [],
1253         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1254         [])
1255 fi
1256
1257
1258 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1259 # we found we need to use "long long int", better check.  We cope with
1260 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1261 # work, fall back to our own snprintf emulation (which we know uses %lld).
1262
1263 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1264   if test $pgac_need_repl_snprintf = no; then
1265     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1266     if test "$LONG_LONG_INT_FORMAT" = ""; then
1267       # Force usage of our own snprintf, since system snprintf is broken
1268       pgac_need_repl_snprintf=yes
1269       LONG_LONG_INT_FORMAT='%lld'
1270     fi
1271   else
1272     # Here if we previously decided we needed to use our own snprintf
1273     LONG_LONG_INT_FORMAT='%lld'
1274   fi
1275   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1276   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1277   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1278 else
1279   # Here if we are not using 'long long int' at all
1280   INT64_FORMAT='"%ld"'
1281   UINT64_FORMAT='"%lu"'
1282 fi
1283
1284 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1285                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1286
1287 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1288                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1289
1290 # Now we have checked all the reasons to replace snprintf
1291 if test $pgac_need_repl_snprintf = yes; then
1292   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1293   AC_LIBOBJ(snprintf)
1294 fi
1295
1296 # Need a #define for the size of Datum (unsigned long)
1297 AC_CHECK_SIZEOF([unsigned long])
1298
1299 # And one for the size of size_t (enables tweaks for > 32bit address space)
1300 AC_CHECK_SIZEOF([size_t])
1301
1302 # Determine memory alignment requirements for the basic C data types.
1303
1304 PGAC_CHECK_ALIGNOF(short)
1305 PGAC_CHECK_ALIGNOF(int)
1306 PGAC_CHECK_ALIGNOF(long)
1307 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1308   PGAC_CHECK_ALIGNOF(long long int)
1309 fi
1310 PGAC_CHECK_ALIGNOF(double)
1311
1312 # Compute maximum alignment of any basic type.
1313 # We assume long's alignment is at least as strong as char, short, or int;
1314 # but we must check long long (if it exists) and double.
1315
1316 MAX_ALIGNOF=$pgac_cv_alignof_long
1317 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1318   MAX_ALIGNOF=$pgac_cv_alignof_double
1319 fi
1320 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1321   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1322 fi
1323 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1324
1325
1326 # Some platforms predefine the types int8, int16, etc.  Only check
1327 # a (hopefully) representative subset.
1328 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1329 [#include <stdio.h>
1330 #ifdef HAVE_SUPPORTDEFS_H
1331 #include <SupportDefs.h>
1332 #endif])
1333
1334 # We also check for sig_atomic_t, which *should* be defined per ANSI
1335 # C, but is missing on some old platforms.
1336 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1337
1338
1339 if test "$PORTNAME" != "win32"
1340 then
1341 PGAC_FUNC_POSIX_SIGNALS
1342 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1343   AC_MSG_ERROR([
1344 Thread-safety requires POSIX signals, which are not supported by this
1345 operating system.])
1346 fi
1347 fi
1348
1349 if test $ac_cv_func_fseeko = yes; then
1350 AC_SYS_LARGEFILE
1351 fi
1352
1353 # SunOS doesn't handle negative byte comparisons properly with +/- return
1354 AC_FUNC_MEMCMP
1355
1356
1357 # Select semaphore implementation type.
1358 if test "$PORTNAME" != "win32"; then
1359   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1360     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1361     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1362   else
1363     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1364       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1365       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1366     else
1367       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1368       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1369     fi
1370   fi
1371 else
1372   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1373   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1374 fi
1375
1376
1377 # Select shared-memory implementation type.
1378 if test "$PORTNAME" != "win32"; then
1379   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1380   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1381 else
1382   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1383   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1384 fi
1385
1386 # If not set in template file, set bytes to use libc memset()
1387 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1388   MEMSET_LOOP_LIMIT=1024
1389 fi
1390 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1391
1392
1393 if test "$enable_nls" = yes ; then
1394   PGAC_CHECK_GETTEXT
1395 fi
1396
1397 # Check for Tcl configuration script tclConfig.sh
1398 if test "$with_tcl" = yes; then
1399     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1400     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1401                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1402     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1403     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1404     ac_save_CPPFLAGS=$CPPFLAGS
1405     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1406     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1407     CPPFLAGS=$ac_save_CPPFLAGS
1408 fi
1409
1410 #
1411 # Check for DocBook and tools
1412 #
1413 PGAC_PROG_NSGMLS
1414 PGAC_PROG_JADE
1415 PGAC_CHECK_DOCBOOK(4.2)
1416 PGAC_PATH_DOCBOOK_STYLESHEETS
1417 PGAC_PATH_COLLATEINDEX
1418 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1419
1420 # Thread testing
1421
1422 # We have to run the thread test near the end so we have all our symbols
1423 # defined.  Cross compiling throws a warning.
1424 #
1425 if test "$enable_thread_safety_force" = yes; then
1426 if test "$PORTNAME" != "win32"
1427 then
1428   AC_MSG_WARN([
1429 *** Skipping thread test program.  --enable-thread-safety-force was used.
1430 *** Run the program in src/test/thread on the your machine and add proper
1431 *** locking function calls to your applications to guarantee thread safety.
1432 ])
1433 else
1434 AC_MSG_WARN([*** skipping thread test on Win32])
1435 fi
1436 elif test "$enable_thread_safety" = yes; then
1437 if test "$PORTNAME" != "win32"
1438 then
1439 AC_MSG_CHECKING([thread safety of required library functions])
1440
1441 _CFLAGS="$CFLAGS"
1442 _LIBS="$LIBS"
1443 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1444 LIBS="$LIBS $PTHREAD_LIBS"
1445 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1446   [AC_MSG_RESULT(yes)],
1447   [AC_MSG_RESULT(no)
1448   AC_MSG_ERROR([thread test program failed
1449 This platform is not thread-safe.  Check the file 'config.log'for the
1450 exact reason.
1451
1452 You can use the configure option --enable-thread-safety-force to force
1453 threads to be enabled.  But you must then run the program in
1454 src/test/thread and add locking function calls to your applications to
1455 guarantee thread safety.])],
1456   [AC_MSG_RESULT(maybe)
1457   AC_MSG_WARN([
1458 *** Skipping thread test program because of cross-compile build.
1459 *** Run the program in src/test/thread on the target machine.
1460 ])])
1461 CFLAGS="$_CFLAGS"
1462 LIBS="$_LIBS"
1463 else
1464 AC_MSG_WARN([*** skipping thread test on Win32])
1465 fi
1466 fi
1467
1468 # prepare build tree if outside source tree
1469 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1470 # Note 2: /bin/pwd might be better than shell's built-in at getting
1471 #         a symlink-free name.
1472 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1473   vpath_build=no
1474 else
1475   vpath_build=yes
1476   if test "$no_create" != yes; then
1477     _AS_ECHO_N([preparing build tree... ])
1478     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1479     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1480       || AC_MSG_ERROR(failed)
1481     AC_MSG_RESULT(done)
1482   fi
1483 fi
1484 AC_SUBST(vpath_build)
1485
1486
1487 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1488
1489 AC_CONFIG_LINKS([
1490   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1491   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1492   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1493   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1494   src/include/pg_config_os.h:src/include/port/${template}.h
1495   src/Makefile.port:src/makefiles/Makefile.${template}
1496 ])
1497
1498 if test "$PORTNAME" = "win32"; then
1499 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1500 # Links sometimes fail undetected on Mingw -
1501 # so here we detect it and warn the user
1502 for FILE in $CONFIG_LINKS
1503  do
1504         # test -e works for symlinks in the MinGW console
1505         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1506  done
1507 ])
1508 fi
1509
1510 AC_CONFIG_HEADERS([src/include/pg_config.h],
1511 [
1512 # Update timestamp for pg_config.h (see Makefile.global)
1513 echo >src/include/stamp-h
1514 ])
1515
1516 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1517
1518 AC_OUTPUT
1519
1520 # Warn about unknown options
1521 PGAC_ARG_CHECK