granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.308 2003/11/29 19:51:16 pgsql Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [7.5devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright 2003 PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix5 ;;
  60    linux*) template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      qnx*) template=qnx4 ;;
  67      sco*) template=sco ;;
  68  solaris*) template=solaris ;;
  69    sunos*) template=sunos4 ;;
  70  sysv4.2*)
  71         case $host_vendor in
  72           univel) template=univel ;;
  73         esac ;;
  74    sysv4*) template=svr4 ;;
  75    sysv5*) template=unixware ;;
  76   ultrix*) template=ultrix4 ;;
  77 esac
  78
  79   if test x"$template" = x"" ; then
  80     AC_MSG_ERROR([[
  81 *******************************************************************
  82 PostgreSQL has apparently not been ported to your platform yet.
  83 To try a manual configuration, look into the src/template directory
  84 for a similar platform and use the '--with-template=' option.
  85
  86 Please also contact <pgsql-ports@postgresql.org> to see about
  87 rectifying this.  Include the above 'checking host system type...'
  88 line.
  89 *******************************************************************
  90 ]])
  91   fi
  92
  93 ])
  94
  95 AC_MSG_RESULT([$template])
  96
  97 PORTNAME=$template
  98 AC_SUBST(PORTNAME)
  99
 100 # Pick right test-and-set (TAS) code.  Most platforms have inline
 101 # assembler code in src/include/storage/s_lock.h, so we just use
 102 # a dummy file here.
 103 case $host in
 104   hppa*-*-hpux*)        need_tas=yes; tas_file=hpux_hppa.s ;;
 105   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 106   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 107   *)                need_tas=no;  tas_file=dummy.s ;;
 108 esac
 109 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 110
 111 if test "$need_tas" = yes ; then
 112   TAS=tas.o
 113 fi
 114 AC_SUBST(TAS)
 115
 116
 117
 118 ##
 119 ## Command line options
 120 ##
 121
 122 #
 123 # Installation directory for documentation
 124 #
 125 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 126   --without-docdir        do not install the documentation],
 127          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 128          [docdir=],
 129          [docdir=$withval],
 130          [docdir='${prefix}/doc'])
 131 AC_SUBST(docdir)
 132
 133
 134 #
 135 # Add non-standard directories to the include path
 136 #
 137 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 138
 139
 140 #
 141 # Add non-standard directories to the library search path
 142 #
 143 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 144              [LIBRARY_DIRS=$withval])
 145
 146 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 147              [LIBRARY_DIRS=$withval])
 148
 149
 150 #
 151 # 64-bit integer date/time storage (--enable-integer-datetimes)
 152 #
 153 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 154 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 155               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 156                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 157 AC_MSG_RESULT([$enable_integer_datetimes])
 158
 159
 160 #
 161 # NLS
 162 #
 163 AC_MSG_CHECKING([whether NLS is wanted])
 164 PGAC_ARG_OPTARG(enable, nls,
 165                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 166                 [],
 167                 [WANTED_LANGUAGES=$enableval],
 168                 [AC_DEFINE(ENABLE_NLS, 1,
 169                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 170 AC_MSG_RESULT([$enable_nls])
 171 AC_SUBST(enable_nls)
 172 AC_SUBST(WANTED_LANGUAGES)
 173
 174 #
 175 # Default port number (--with-pgport), default 5432
 176 #
 177 AC_MSG_CHECKING([for default port number])
 178 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 179              [default_port=$withval],
 180              [default_port=5432])
 181 AC_MSG_RESULT([$default_port])
 182 # Need both of these because some places want an integer and some a string
 183 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 184 [Define to the default TCP port number on which the server listens and
 185 to which clients will try to connect.  This can be overridden at run-time,
 186 but it's convenient if your clients have the right default compiled in.
 187 (--with-pgport=PORTNUM)])
 188 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 189                    [Define to the default TCP port number as a string constant.])
 190 AC_SUBST(default_port)
 191
 192 #
 193 # Option to disable shared libraries
 194 #
 195 PGAC_ARG_BOOL(enable, shared, yes,
 196               [  --disable-shared        do not build shared libraries])
 197 AC_SUBST(enable_shared)
 198
 199 #
 200 # '-rpath'-like feature can be disabled
 201 #
 202 PGAC_ARG_BOOL(enable, rpath, yes,
 203               [  --disable-rpath         do not embed shared library search path in executables])
 204 AC_SUBST(enable_rpath)
 205
 206 #
 207 # Spinlocks
 208 #
 209 PGAC_ARG_BOOL(enable, spinlocks, yes,
 210               [  --disable-spinlocks     do not use spinlocks])
 211
 212 #
 213 # --enable-debug adds -g to compiler flags
 214 #
 215 PGAC_ARG_BOOL(enable, debug, no,
 216               [  --enable-debug          build with debugging symbols (-g)])
 217 AC_SUBST(enable_debug)
 218
 219 #
 220 # C compiler
 221 #
 222
 223 # For historical reasons you can also use --with-CC to specify the C compiler
 224 # to use, although the standard way to do this is to set the CC environment
 225 # variable.
 226 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 227
 228 case $template in
 229   aix) pgac_cc_list="gcc xlc";;
 230  irix) pgac_cc_list="cc";; # no gcc
 231     *) pgac_cc_list="gcc cc";;
 232 esac
 233
 234 AC_PROG_CC([$pgac_cc_list])
 235
 236 unset CFLAGS
 237
 238 #
 239 # Read the template
 240 #
 241 . "$srcdir/src/template/$template" || exit
 242
 243 # CFLAGS are selected so:
 244 # If the user specifies something in the environment, that is used.
 245 # else:  If the template file set something, that is used.
 246 # else:  If the compiler is GCC, then we use -O2.
 247 # else:  If the compiler is something else, then we use -0.
 248
 249 if test "$ac_env_CFLAGS_set" = set; then
 250   CFLAGS=$ac_env_CFLAGS_value
 251 elif test "${CFLAGS+set}" = set; then
 252   : # (keep what template set)
 253 elif test "$GCC" = yes; then
 254   CFLAGS="-O2"
 255 else
 256   # if the user selected debug mode, don't use -O
 257   if test "$enable_debug" != yes; then
 258     CFLAGS="-O"
 259   fi
 260 fi
 261
 262 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 263 PGAC_PROG_CC_NO_STRICT_ALIASING
 264
 265 # supply -g if --enable-debug
 266 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 267   CFLAGS="$CFLAGS -g"
 268 fi
 269
 270 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 271
 272 # We already have this in Makefile.win32, but configure needs it too
 273 if test "$PORTNAME" = "win32"; then
 274   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32"
 275 fi
 276
 277 # Check if the compiler still works with the template settings
 278 AC_MSG_CHECKING([whether the C compiler still works])
 279 AC_TRY_LINK([], [return 0;],
 280   [AC_MSG_RESULT(yes)],
 281   [AC_MSG_RESULT(no)
 282    AC_MSG_ERROR([cannot proceed])])
 283
 284 # Defend against gcc -ffast-math
 285 if test "$GCC" = yes; then
 286 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 287 choke me
 288 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 289 fi
 290
 291 AC_PROG_CPP
 292 AC_SUBST(GCC)
 293
 294 # Create compiler version string
 295 if test x"$GCC" = x"yes" ; then
 296   cc_string="GCC `${CC} --version | sed q`"
 297 else
 298   cc_string=$CC
 299 fi
 300 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 301                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 302                    [A string containing the version number, platform, and C compiler])
 303
 304
 305 #
 306 # Automatic dependency tracking
 307 #
 308 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 309               [autodepend=yes])
 310 AC_SUBST(autodepend)
 311
 312
 313 #
 314 # Enable assert checks
 315 #
 316 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 317               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 318                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 319
 320
 321 #
 322 # Include directories
 323 #
 324 ac_save_IFS=$IFS
 325 IFS="${IFS}:"
 326 # SRCH_INC comes from the template file
 327 for dir in $with_includes $SRCH_INC; do
 328   if test -d "$dir"; then
 329     INCLUDES="$INCLUDES -I$dir"
 330   else
 331     AC_MSG_WARN([*** Include directory $dir does not exist.])
 332   fi
 333 done
 334 IFS=$ac_save_IFS
 335 AC_SUBST(INCLUDES)
 336
 337
 338 #
 339 # Library directories
 340 #
 341 ac_save_IFS=$IFS
 342 IFS="${IFS}:"
 343 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 344 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 345   if test -d "$dir"; then
 346     LIBDIRS="$LIBDIRS -L$dir"
 347   else
 348     AC_MSG_WARN([*** Library directory $dir does not exist.])
 349   fi
 350 done
 351 IFS=$ac_save_IFS
 352
 353 #
 354 # Enable thread-safe client libraries
 355 #
 356 AC_MSG_CHECKING([allow thread-safe client libraries])
 357 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe],
 358               [AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 359                          [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])])
 360 AC_MSG_RESULT([$enable_thread_safety])
 361 AC_SUBST(enable_thread_safety)
 362
 363 #
 364 # Tcl/Tk
 365 #
 366 AC_MSG_CHECKING([whether to build with Tcl])
 367 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 368 AC_MSG_RESULT([$with_tcl])
 369 AC_SUBST([with_tcl])
 370
 371 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 372 AC_MSG_CHECKING([whether to build with Tk])
 373 if test "$with_tcl" = yes; then
 374   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 375 else
 376   with_tk=no
 377 fi
 378 AC_MSG_RESULT([$with_tk])
 379 AC_SUBST([with_tk])
 380
 381
 382 # We see if the path to the Tcl/Tk configuration scripts is specified.
 383 # This will override the use of tclsh to find the paths to search.
 384
 385 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 386
 387 # We see if the path to the Tk configuration scripts is specified.
 388 # This will override the use of tclsh to find the paths to search.
 389
 390 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 391
 392 #
 393 # Optionally build Perl modules (PL/Perl)
 394 #
 395 AC_MSG_CHECKING([whether to build Perl modules])
 396 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 397 AC_MSG_RESULT([$with_perl])
 398 AC_SUBST(with_perl)
 399
 400 #
 401 # Optionally build Python modules (PL/Python)
 402 #
 403 AC_MSG_CHECKING([whether to build Python modules])
 404 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 405 AC_MSG_RESULT([$with_python])
 406 AC_SUBST(with_python)
 407
 408 #
 409 # Optionally build the Java/JDBC tools
 410 #
 411 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 412 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 413 [AC_MSG_RESULT(yes)
 414 PGAC_PATH_ANT
 415 if test -z "$ANT"; then
 416   AC_MSG_ERROR([Ant is required to build Java components
 417 If you have Ant already installed, see config.log for details on the failure.])
 418 fi
 419 if "$ANT" -version | egrep -i 'ant version' | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 420   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 421 fi],
 422 [AC_MSG_RESULT(no)])
 423 AC_SUBST(with_java)
 424
 425 #
 426 # Kerberos 4
 427 #
 428 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 429 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 430 [
 431   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 432   krb_srvtab="/etc/srvtab"
 433 ])
 434 AC_MSG_RESULT([$with_krb4])
 435 AC_SUBST(with_krb4)
 436
 437
 438 #
 439 # Kerberos 5
 440 #
 441 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 442 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 443 [
 444   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 445   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 446 ])
 447 AC_MSG_RESULT([$with_krb5])
 448 AC_SUBST(with_krb5)
 449
 450
 451 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 452 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 453   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 454 fi
 455
 456 AC_SUBST(krb_srvtab)
 457
 458
 459 #
 460 # Kerberos configuration parameters
 461 #
 462 PGAC_ARG_REQ(with, krb-srvnam,
 463              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 464              [],
 465              [with_krb_srvnam="postgres"])
 466 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 467                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 468
 469
 470 #
 471 # PAM
 472 #
 473 AC_MSG_CHECKING([whether to build with PAM support])
 474 PGAC_ARG_BOOL(with, pam, no,
 475               [  --with-pam              build with PAM support],
 476               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 477 AC_MSG_RESULT([$with_pam])
 478 AC_SUBST(with_pam)
 479
 480
 481 #
 482 # Rendezvous
 483 #
 484 AC_MSG_CHECKING([whether to build with Rendezvous support])
 485 PGAC_ARG_BOOL(with, rendezvous, no,
 486               [  --with-rendezvous       build with Rendezvous support],
 487               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 488 AC_MSG_RESULT([$with_rendezvous])
 489 AC_SUBST(with_rendezvous)
 490
 491
 492 #
 493 # OpenSSL
 494 #
 495 AC_MSG_CHECKING([whether to build with OpenSSL support])
 496 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 497               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 498 AC_MSG_RESULT([$with_openssl])
 499 AC_SUBST(with_openssl)
 500
 501
 502 #
 503 # Readline
 504 #
 505 PGAC_ARG_BOOL(with, readline, yes,
 506               [  --without-readline      do not use Readline])
 507
 508 #
 509 # Zlib
 510 #
 511 PGAC_ARG_BOOL(with, zlib, yes,
 512               [  --without-zlib          do not use Zlib])
 513
 514 #
 515 # Elf
 516 #
 517
 518 # Assume system is ELF if it predefines __ELF__ as 1,
 519 # otherwise believe host_os based default.
 520 case $host_os in
 521     freebsd1*|freebsd2*) elf=no;;
 522     freebsd3*|freebsd4*) elf=yes;;
 523 esac
 524
 525 AC_EGREP_CPP(yes,
 526 [#if __ELF__
 527   yes
 528 #endif
 529 ],
 530 [ELF_SYS=true],
 531 [if test "X$elf" = "Xyes" ; then
 532   ELF_SYS=true
 533 else
 534   ELF_SYS=
 535 fi])
 536 AC_SUBST(ELF_SYS)
 537
 538 #
 539 # Assignments
 540 #
 541
 542 CPPFLAGS="$CPPFLAGS $INCLUDES"
 543 LDFLAGS="$LDFLAGS $LIBDIRS"
 544
 545 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 546 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 547
 548
 549 AC_PROG_AWK
 550 PGAC_PATH_FLEX
 551 AC_PROG_LN_S
 552 AC_PROG_LD
 553 AC_SUBST(LD)
 554 AC_SUBST(with_gnu_ld)
 555 case $host_os in sysv5*)
 556   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 557   [
 558     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 559     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 560     LDFLAGS=$pgac_save_LDFLAGS
 561   ])
 562   ld_R_works=$pgac_cv_prog_ld_R
 563   AC_SUBST(ld_R_works)
 564 esac
 565 AC_PROG_RANLIB
 566 AC_CHECK_PROGS(LORDER, lorder)
 567 AC_PATH_PROG(TAR, tar)
 568 PGAC_CHECK_STRIP
 569
 570 AC_CHECK_PROGS(YACC, ['bison -y'])
 571
 572 if test "$YACC"; then
 573   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 574     AC_MSG_WARN([
 575 *** The installed version of Bison is too old.  PostgreSQL needs
 576 *** Bison version 1.875 or later.])
 577   fi
 578 fi
 579
 580 if test -z "$YACC"; then
 581   AC_MSG_WARN([
 582 *** Without Bison you will not be able to build PostgreSQL from CVS or
 583 *** change any of the parser definition files.  You can obtain Bison from
 584 *** a GNU mirror site.  (If you are using the official distribution of
 585 *** PostgreSQL then you do not need to worry about this because the Bison
 586 *** output is pre-generated.)  To use a different yacc program (possible,
 587 *** but not recommended), set the environment variable YACC before running
 588 *** 'configure'.])
 589 fi
 590 AC_SUBST(YFLAGS)
 591
 592 PGAC_PATH_PERL
 593 if test "$with_perl" = yes; then
 594   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 595   PGAC_CHECK_PERL_EMBED_LDFLAGS
 596 fi
 597
 598 if test "$with_python" = yes; then
 599   PGAC_PATH_PYTHON
 600   PGAC_CHECK_PYTHON_EMBED_SETUP
 601 fi
 602
 603
 604 ##
 605 ## Libraries
 606 ##
 607
 608 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 609 then
 610         AC_CHECK_LIB(bsd,      main)
 611 fi
 612 AC_CHECK_LIB(util,     setproctitle)
 613 AC_CHECK_LIB(m,        main)
 614 AC_CHECK_LIB(dl,       main)
 615 AC_CHECK_LIB(nsl,      main)
 616 AC_CHECK_LIB(socket,   main)
 617 AC_CHECK_LIB(ipc,      main)
 618 AC_CHECK_LIB(IPC,      main)
 619 AC_CHECK_LIB(lc,       main)
 620 AC_CHECK_LIB(dld,      main)
 621 AC_CHECK_LIB(ld,       main)
 622 AC_CHECK_LIB(compat,   main)
 623 AC_CHECK_LIB(BSD,      main)
 624 AC_CHECK_LIB(gen,      main)
 625 AC_CHECK_LIB(PW,       main)
 626 AC_CHECK_LIB(resolv,   main)
 627 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 628 # QNX:
 629 AC_CHECK_LIB(unix, main)
 630 AC_SEARCH_LIBS(crypt,  crypt)
 631 # BeOS:
 632 if test "$PORTNAME" = "beos"
 633 then
 634         AC_CHECK_LIB(bind, __inet_ntoa)
 635 fi
 636 # Solaris:
 637 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 638 # Cygwin:
 639 AC_CHECK_LIB(cygipc, shmget)
 640 # WIN32:
 641 if test "$PORTNAME" = "win32"
 642 then
 643         AC_CHECK_LIB(wsock32, main)
 644 fi
 645
 646 if test "$with_readline" = yes; then
 647   PGAC_CHECK_READLINE
 648   if test x"$pgac_cv_check_readline" = x"no"; then
 649     AC_MSG_ERROR([readline library not found
 650 If you have readline already installed, see config.log for details on the
 651 failure.  It is possible the compiler isn't looking in the proper directory.
 652 Use --without-readline to disable readline support.])
 653   fi
 654 fi
 655
 656 if test "$with_zlib" = yes; then
 657   AC_CHECK_LIB(z, inflate, [],
 658                [AC_MSG_ERROR([zlib library not found
 659 If you have zlib already installed, see config.log for details on the
 660 failure.  It is possible the compiler isn't looking in the proper directory.
 661 Use --without-zlib to disable zlib support.])])
 662 fi
 663
 664 if test "$enable_spinlocks" = yes; then
 665   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 666 else
 667   AC_MSG_WARN([
 668 *** Not using spinlocks will cause poor performance.])
 669 fi
 670
 671 if test "$with_krb4" = yes ; then
 672   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 673   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 674   AC_REPLACE_FUNCS([gethostname])
 675 fi
 676
 677 if test "$with_krb5" = yes ; then
 678   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 679                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 680   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 681                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 682   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 683                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 684 fi
 685
 686 if test "$with_openssl" = yes ; then
 687   dnl Order matters!
 688   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 689   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 690 fi
 691
 692 if test "$with_pam" = yes ; then
 693   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 694 fi
 695
 696
 697 ##
 698 ## Header files
 699 ##
 700
 701 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 702 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h utime.h kernel/OS.h kernel/image.h SupportDefs.h])
 703
 704 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 705 # netinet/in.h is included first.
 706 AC_CHECK_HEADERS(netinet/in.h)
 707 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 708 [AC_INCLUDES_DEFAULT
 709 #ifdef HAVE_NETINET_IN_H
 710 #include <netinet/in.h>
 711 #endif
 712 ])
 713
 714 if test "$with_readline" = yes; then
 715   AC_CHECK_HEADERS(readline/readline.h, [],
 716                    [AC_CHECK_HEADERS(editline/readline.h, [],
 717                          [AC_CHECK_HEADERS(readline.h, [],
 718                                      [AC_MSG_ERROR([readline header not found
 719 If you have readline already installed, see config.log for details on the
 720 failure.  It is possible the compiler isn't looking in the proper directory.
 721 Use --without-readline to disable readline support.])])])])
 722   AC_CHECK_HEADERS(readline/history.h, [],
 723                    [AC_CHECK_HEADERS(editline/history.h, [],
 724                          [AC_CHECK_HEADERS(history.h, [],
 725                                      [AC_MSG_ERROR([history header not found
 726 If you have readline already installed, see config.log for details on the
 727 failure.  It is possible the compiler isn't looking in the proper directory.
 728 Use --without-readline to disable readline support.])])])])
 729 fi
 730
 731 if test "$with_zlib" = yes; then
 732   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 733 If you have zlib already installed, see config.log for details on the
 734 failure.  It is possible the compiler isn't looking in the proper directory.
 735 Use --without-zlib to disable zlib support.])])
 736 fi
 737
 738 if test "$with_krb4" = yes ; then
 739   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 740 fi
 741
 742 if test "$with_krb5" = yes ; then
 743   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 744   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 745 fi
 746
 747 if test "$with_openssl" = yes ; then
 748   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 749   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 750 fi
 751
 752 if test "$with_pam" = yes ; then
 753   AC_CHECK_HEADERS(security/pam_appl.h, [],
 754                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 755                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 756 fi
 757
 758 if test "$with_rendezvous" = yes ; then
 759   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 760 fi
 761
 762
 763 ##
 764 ## Types, structures, compiler characteristics
 765 ##
 766
 767 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 768 AC_C_CONST
 769 AC_C_INLINE
 770 AC_C_STRINGIZE
 771 PGAC_C_SIGNED
 772 AC_C_VOLATILE
 773 PGAC_C_FUNCNAME_SUPPORT
 774 PGAC_STRUCT_TIMEZONE
 775 PGAC_UNION_SEMUN
 776 PGAC_STRUCT_SOCKADDR_UN
 777 PGAC_STRUCT_SOCKADDR_STORAGE
 778 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 779 PGAC_STRUCT_ADDRINFO
 780
 781 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 782 [#include <sys/param.h>
 783 #include <sys/types.h>
 784 #include <sys/socket.h>
 785 #include <sys/ucred.h>])
 786
 787 AC_CHECK_TYPES([struct option], [], [],
 788 [#ifdef HAVE_GETOPT_H
 789 #include <getopt.h>
 790 #endif])
 791
 792 if test "$with_zlib" = yes; then
 793   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 794   # did not).  While we could work around the lack of z_streamp, it
 795   # seems unwise to encourage people to use such old zlib versions...
 796   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 797 Use --without-zlib to disable zlib support.])],
 798                 [#include <zlib.h>])
 799 fi
 800
 801 if test "$with_krb5" = yes; then
 802 # Check for differences between MIT and Heimdal (KTH) releases
 803   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 804                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 805                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 806                                      [#include <krb5.h>])],
 807                    [#include <krb5.h>])
 808   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 809                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 810                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 811                                      [#include <krb5.h>])],
 812                    [#include <krb5.h>])
 813 fi
 814
 815
 816 ##
 817 ## Functions, global variables
 818 ##
 819
 820 PGAC_VAR_INT_TIMEZONE
 821 AC_FUNC_ACCEPT_ARGTYPES
 822 PGAC_FUNC_GETTIMEOFDAY_1ARG
 823
 824 # SunOS doesn't handle negative byte comparisons properly with +/- return
 825 AC_FUNC_MEMCMP
 826
 827 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf utime utimes waitpid])
 828
 829 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 830
 831 HAVE_IPV6=no
 832 AC_CHECK_TYPE([struct sockaddr_in6],
 833               [AC_CHECK_FUNC(inet_ntop,
 834                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 835                                                           HAVE_IPV6=yes])],
 836               [],
 837 [$ac_includes_default
 838 #include <netinet/in.h>])
 839 AC_SUBST(HAVE_IPV6)
 840
 841 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 842 [AC_TRY_LINK(
 843 [#include <machine/vmparam.h>
 844 #include <sys/exec.h>
 845 ],
 846 [PS_STRINGS->ps_nargvstr = 1;
 847 PS_STRINGS->ps_argvstr = "foo";],
 848 [pgac_cv_var_PS_STRINGS=yes],
 849 [pgac_cv_var_PS_STRINGS=no])])
 850 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 851   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 852 fi
 853
 854
 855 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 856 # is missing.  Yes, there are machines that have only one.  We may
 857 # also decide to use snprintf.c if snprintf() is present but does not
 858 # have working "long long int" support -- see below.
 859
 860 pgac_need_repl_snprintf=no
 861 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 862 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 863
 864
 865 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 866 # include/c.h will provide declarations.  Note this is a separate test
 867 # from whether the functions exist in the C library --- there are
 868 # systems that have the functions but don't bother to declare them :-(
 869
 870 AC_CHECK_DECLS([snprintf, vsnprintf])
 871
 872
 873 # do this one the hard way in case isinf() is a macro
 874 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 875 [AC_TRY_LINK(
 876 [#include <math.h>
 877 ],
 878 [double x = 0.0; int res = isinf(x);],
 879 [ac_cv_func_isinf=yes],
 880 [ac_cv_func_isinf=no])])
 881
 882 if test $ac_cv_func_isinf = yes ; then
 883   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 884 else
 885   AC_LIBOBJ(isinf)
 886   # Look for a way to implement a substitute for isinf()
 887   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 888 fi
 889
 890 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strcasecmp strdup strerror strtol strtoul])
 891
 892 # system's version of getaddrinfo(), if any, may be used only if we found
 893 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 894 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 895   AC_REPLACE_FUNCS([getaddrinfo])
 896 else
 897   AC_LIBOBJ(getaddrinfo)
 898 fi
 899
 900 # similarly, use system's getopt_long() only if system provides struct option.
 901 if test x"$ac_cv_type_struct_option" = xyes ; then
 902   AC_REPLACE_FUNCS([getopt_long])
 903 else
 904   AC_LIBOBJ(getopt_long)
 905 fi
 906
 907 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 908 # We override the previous test that said fseeko/ftello didn't exist
 909 # OS tests are also done in include/c.h and port/fseeko.c
 910 case $host_os in bsdi*|netbsd*)
 911 ac_cv_func_fseeko=yes
 912 esac
 913
 914 # Solaris has a very slow qsort in certain cases, so we replace it.
 915 case $host_os in solaris*)
 916 AC_LIBOBJ(qsort) ;;
 917 esac
 918
 919 # Win32 can't to rename or unlink on an open file
 920 case $host_os in mingw*)
 921 AC_LIBOBJ(dirmod)
 922 AC_LIBOBJ(copydir)
 923 AC_LIBOBJ(gettimeofday) ;;
 924 esac
 925
 926 if test "$with_readline" = yes; then
 927   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 928   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 929   AC_CHECK_FUNCS([replace_history_entry])
 930 fi
 931
 932
 933 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 934 AC_MSG_CHECKING(for finite)
 935 AC_TRY_LINK([#include <math.h>],
 936             [int dummy=finite(1.0);],
 937             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 938 AC_MSG_RESULT(yes)],
 939             [AC_MSG_RESULT(no)])
 940
 941 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 942 dnl (especially on GNU libc)
 943 dnl See also comments in c.h.
 944 AC_MSG_CHECKING(for sigsetjmp)
 945 AC_TRY_LINK([#include <setjmp.h>],
 946             [sigjmp_buf x; sigsetjmp(x, 1);],
 947             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 948 AC_MSG_RESULT(yes)],
 949             [AC_MSG_RESULT(no)])
 950
 951 AC_CHECK_FUNC(syslog,
 952               [AC_CHECK_HEADER(syslog.h,
 953                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 954
 955 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 956 [AC_TRY_LINK([#include <unistd.h>],
 957   [extern int optreset; optreset = 1;],
 958   [pgac_cv_var_int_optreset=yes],
 959   [pgac_cv_var_int_optreset=no])])
 960 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 961   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 962 fi
 963
 964 AC_CHECK_FUNCS([strtoll strtoq], [break])
 965 AC_CHECK_FUNCS([strtoull strtouq], [break])
 966
 967 # Check for one of atexit() or on_exit()
 968 AC_CHECK_FUNCS(atexit, [],
 969                [AC_CHECK_FUNCS(on_exit, [],
 970                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 971
 972 AC_FUNC_FSEEKO
 973
 974 #
 975 # Pthreads
 976 #
 977 # For each platform, we need to know about any special compile and link
 978 # libraries, and whether the normal C function names are thread-safe.
 979 # See the comment at the top of src/port/thread.c for more information.
 980 #
 981 if test "$enable_thread_safety" = yes; then
 982 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safetys])])
 983
 984 if test "$THREAD_SUPPORT" != yes; then
 985 AC_MSG_ERROR([
 986 Cannot enable threads on your platform.
 987 Please report your platform threading info to the PostgreSQL mailing lists
 988 so it can be added to the next release.  Report all compile flags, link flags,
 989 functions, or libraries required for threading support.
 990 See the comment at the top of src/port/thread.c for more information.
 991 ])
 992 fi
 993 else
 994 # do not use values from template file
 995 THREAD_CPPFLAGS=
 996 THREAD_LIBS=
 997 fi
 998 AC_SUBST(THREAD_SUPPORT)
 999 AC_SUBST(THREAD_CPPFLAGS)
1000 AC_SUBST(THREAD_LIBS)
1001
1002
1003 #
1004 # Check for re-entrant versions of certain functions
1005 #
1006 # Include special flags if threads are enabled _and_ if required for
1007 # threading on this platform.  Some platforms have *_r functions but
1008 # their natively named funcs are threadsafe, and should be used instead.
1009 #
1010 # One trick here is that if we don't call AC_CHECK_FUNCS, the
1011 # functions are marked "not found", which is perfect.
1012 #
1013 if test "$enable_thread_safety" = yes -a "$NEED_REENTRANT_FUNCS" = yes ; then
1014 _CFLAGS="$CFLAGS"
1015 _LIBS="$LIBS"
1016 CFLAGS="$CFLAGS $THREAD_CPPFLAGS"
1017 LIBS="$LIBS $THREAD_LIBS"
1018 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1019 CFLAGS="$_CFLAGS"
1020 LIBS="$_LIBS"
1021 fi
1022
1023
1024 # This test makes sure that run tests work at all.  Sometimes a shared
1025 # library is found by the linker, but the runtime linker can't find it.
1026 # This check should come after all modifications of compiler or linker
1027 # variables, and before any other run tests.
1028 AC_MSG_CHECKING([test program])
1029 AC_TRY_RUN([int main() { return 0; }],
1030 [AC_MSG_RESULT(ok)],
1031 [AC_MSG_RESULT(failed)
1032 AC_MSG_ERROR([[
1033 *** Could not execute a simple test program.  This may be a problem
1034 *** related to locating shared libraries.  Check the file 'config.log'
1035 *** for the exact reason.]])],
1036 [AC_MSG_RESULT([cross-compiling])])
1037
1038
1039 dnl Check to see if we have a working 64-bit integer type.
1040 dnl This breaks down into two steps:
1041 dnl (1) figure out if the compiler has a 64-bit int type with working
1042 dnl arithmetic, and if so
1043 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1044 dnl snprintf is the only library routine we really need for int8 support.)
1045 dnl It's entirely possible to have a compiler that handles a 64-bit type
1046 dnl when the C library doesn't; this is fairly likely when using gcc on
1047 dnl an older platform, for example.
1048 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1049 dnl we force our own version of snprintf() to be used instead.
1050 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1051
1052 PGAC_TYPE_64BIT_INT([long int])
1053
1054 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1055   PGAC_TYPE_64BIT_INT([long long int])
1056 fi
1057
1058
1059 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1060
1061 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1062   AC_TRY_COMPILE([
1063 #define INT64CONST(x)  x##LL
1064 long long int foo = INT64CONST(0x1234567890123456);
1065 ],
1066         [],
1067         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1068         [])
1069 fi
1070
1071
1072 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1073 # we found we need to use "long long int", better check.  We cope with
1074 # snprintfs that use either %lld, %qd, or %I64d as the format.  If
1075 # neither works, fall back to our own snprintf emulation (which we
1076 # know uses %lld).
1077
1078 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1079   if test $pgac_need_repl_snprintf = no; then
1080     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1081     if test "$LONG_LONG_INT_FORMAT" = ""; then
1082       # Force usage of our own snprintf, since system snprintf is broken
1083       pgac_need_repl_snprintf=yes
1084       LONG_LONG_INT_FORMAT='%lld'
1085     fi
1086   else
1087     # Here if we previously decided we needed to use our own snprintf
1088     LONG_LONG_INT_FORMAT='%lld'
1089   fi
1090   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1091 else
1092   # Here if we are not using 'long long int' at all
1093   INT64_FORMAT='"%ld"'
1094 fi
1095
1096 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1097                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1098
1099 if test $pgac_need_repl_snprintf = yes; then
1100   AC_LIBOBJ(snprintf)
1101 fi
1102
1103 # Need a #define for the size of Datum (unsigned long)
1104 AC_CHECK_SIZEOF([unsigned long])
1105
1106 # Determine memory alignment requirements for the basic C data types.
1107
1108 PGAC_CHECK_ALIGNOF(short)
1109 PGAC_CHECK_ALIGNOF(int)
1110 PGAC_CHECK_ALIGNOF(long)
1111 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1112   PGAC_CHECK_ALIGNOF(long long int)
1113 fi
1114 PGAC_CHECK_ALIGNOF(double)
1115
1116 # Compute maximum alignment of any basic type.
1117 # We assume long's alignment is at least as strong as char, short, or int;
1118 # but we must check long long (if it exists) and double.
1119
1120 MAX_ALIGNOF=$pgac_cv_alignof_long
1121 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1122   MAX_ALIGNOF=$pgac_cv_alignof_double
1123 fi
1124 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1125   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1126 fi
1127 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1128
1129
1130 # Some platforms predefine the types int8, int16, etc.  Only check
1131 # a (hopefully) representative subset.
1132 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1133 [#include <stdio.h>
1134 #ifdef HAVE_SUPPORTDEFS_H
1135 #include <SupportDefs.h>
1136 #endif])
1137
1138 # We also check for sig_atomic_t, which *should* be defined per ANSI
1139 # C, but is missing on some old platforms.
1140 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1141
1142
1143 PGAC_FUNC_POSIX_SIGNALS
1144 if test $ac_cv_func_fseeko = yes; then
1145 AC_SYS_LARGEFILE
1146 fi
1147
1148
1149 # Select semaphore implementation type.
1150 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1151   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1152   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1153 else
1154   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1155     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1156     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1157   else
1158     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1159     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1160   fi
1161 fi
1162
1163
1164 # Select shared-memory implementation type.
1165 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1166 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1167
1168
1169 if test "$enable_nls" = yes ; then
1170   PGAC_CHECK_GETTEXT
1171 fi
1172
1173 # Check for Tcl configuration script tclConfig.sh
1174 if test "$with_tcl" = yes; then
1175     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1176     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1177                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1178     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1179 fi
1180
1181 # Check for Tk configuration script tkConfig.sh
1182 if test "$with_tk" = yes; then
1183     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1184     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1185 fi
1186
1187
1188 #
1189 # Check for DocBook and tools
1190 #
1191 PGAC_PROG_NSGMLS
1192 PGAC_PROG_JADE
1193 PGAC_CHECK_DOCBOOK(4.2)
1194 PGAC_PATH_DOCBOOK_STYLESHEETS
1195 PGAC_PATH_COLLATEINDEX
1196 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1197
1198
1199 # prepare build tree if outside source tree
1200 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1201 # Note 2: /bin/pwd might be better than shell's built-in at getting
1202 #         a symlink-free name.
1203 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1204   vpath_build=no
1205 else
1206   vpath_build=yes
1207   if test "$no_create" != yes; then
1208     _AS_ECHO_N([preparing build tree... ])
1209     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1210     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1211       || AC_MSG_ERROR(failed)
1212     AC_MSG_RESULT(done)
1213   fi
1214 fi
1215 AC_SUBST(vpath_build)
1216
1217
1218 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1219
1220 AC_CONFIG_LINKS([
1221   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1222   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1223   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1224   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1225   src/include/pg_config_os.h:src/include/port/${template}.h
1226   src/Makefile.port:src/makefiles/Makefile.${template}
1227 ])
1228
1229 AC_CONFIG_HEADERS([src/include/pg_config.h],
1230 [
1231 # Update timestamp for pg_config.h (see Makefile.global)
1232 echo >src/include/stamp-h
1233 ])
1234
1235 AC_OUTPUT