granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.378 2004/09/27 02:17:14 pgsql Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.0.0beta3], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright 2004 PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix ;;
  60  linux*|gnu*|k*bsd*-gnu)
  61            template=linux ;;
  62    mingw*) template=win32 ;;
  63   netbsd*) template=netbsd ;;
  64 nextstep*) template=nextstep ;;
  65  openbsd*) template=openbsd ;;
  66      osf*) template=osf ;;
  67      qnx*) template=qnx4 ;;
  68      sco*) template=sco ;;
  69  solaris*) template=solaris ;;
  70    sunos*) template=sunos4 ;;
  71  sysv4.2*)
  72         case $host_vendor in
  73           univel) template=univel ;;
  74         esac ;;
  75    sysv4*) template=svr4 ;;
  76    sysv5*) template=unixware ;;
  77   ultrix*) template=ultrix4 ;;
  78 esac
  79
  80   if test x"$template" = x"" ; then
  81     AC_MSG_ERROR([[
  82 *******************************************************************
  83 PostgreSQL has apparently not been ported to your platform yet.
  84 To try a manual configuration, look into the src/template directory
  85 for a similar platform and use the '--with-template=' option.
  86
  87 Please also contact <pgsql-ports@postgresql.org> to see about
  88 rectifying this.  Include the above 'checking host system type...'
  89 line.
  90 *******************************************************************
  91 ]])
  92   fi
  93
  94 ])
  95
  96 AC_MSG_RESULT([$template])
  97
  98 PORTNAME=$template
  99 AC_SUBST(PORTNAME)
 100
 101 # Initialize default assumption that we do not need separate assembly code
 102 # for TAS (test-and-set).  This can be overridden by the template file
 103 # when it's executed.
 104 need_tas=no
 105 tas_file=dummy.s
 106
 107
 108
 109 ##
 110 ## Command line options
 111 ##
 112
 113 #
 114 # Installation directory for documentation
 115 #
 116 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 117   --without-docdir        do not install the documentation],
 118          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 119          [docdir=],
 120          [docdir=$withval],
 121          [docdir='${prefix}/doc'])
 122 AC_SUBST(docdir)
 123
 124
 125 #
 126 # Add non-standard directories to the include path
 127 #
 128 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 129
 130
 131 #
 132 # Add non-standard directories to the library search path
 133 #
 134 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 135              [LIBRARY_DIRS=$withval])
 136
 137 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 138              [LIBRARY_DIRS=$withval])
 139
 140
 141 #
 142 # 64-bit integer date/time storage (--enable-integer-datetimes)
 143 #
 144 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 145 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 146               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 147                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 148 AC_MSG_RESULT([$enable_integer_datetimes])
 149
 150
 151 #
 152 # NLS
 153 #
 154 AC_MSG_CHECKING([whether NLS is wanted])
 155 PGAC_ARG_OPTARG(enable, nls,
 156                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 157                 [],
 158                 [WANTED_LANGUAGES=$enableval],
 159                 [AC_DEFINE(ENABLE_NLS, 1,
 160                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 161 AC_MSG_RESULT([$enable_nls])
 162 AC_SUBST(enable_nls)
 163 AC_SUBST(WANTED_LANGUAGES)
 164
 165 #
 166 # Default port number (--with-pgport), default 5432
 167 #
 168 AC_MSG_CHECKING([for default port number])
 169 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 170              [default_port=$withval],
 171              [default_port=5432])
 172 AC_MSG_RESULT([$default_port])
 173 # Need both of these because some places want an integer and some a string
 174 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 175 [Define to the default TCP port number on which the server listens and
 176 to which clients will try to connect.  This can be overridden at run-time,
 177 but it's convenient if your clients have the right default compiled in.
 178 (--with-pgport=PORTNUM)])
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 180                    [Define to the default TCP port number as a string constant.])
 181 AC_SUBST(default_port)
 182
 183 #
 184 # Option to disable shared libraries
 185 #
 186 PGAC_ARG_BOOL(enable, shared, yes,
 187               [  --disable-shared        do not build shared libraries])
 188 AC_SUBST(enable_shared)
 189
 190 #
 191 # '-rpath'-like feature can be disabled
 192 #
 193 PGAC_ARG_BOOL(enable, rpath, yes,
 194               [  --disable-rpath         do not embed shared library search path in executables])
 195 AC_SUBST(enable_rpath)
 196
 197 #
 198 # Spinlocks
 199 #
 200 PGAC_ARG_BOOL(enable, spinlocks, yes,
 201               [  --disable-spinlocks     do not use spinlocks])
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226
 227 unset CFLAGS
 228
 229 #
 230 # Read the template
 231 #
 232 . "$srcdir/src/template/$template" || exit
 233
 234 # CFLAGS are selected so:
 235 # If the user specifies something in the environment, that is used.
 236 # else:  If the template file set something, that is used.
 237 # else:  If the compiler is GCC, then we use -O2.
 238 # else:  If the compiler is something else, then we use -0.
 239
 240 if test "$ac_env_CFLAGS_set" = set; then
 241   CFLAGS=$ac_env_CFLAGS_value
 242 elif test "${CFLAGS+set}" = set; then
 243   : # (keep what template set)
 244 elif test "$GCC" = yes; then
 245   CFLAGS="-O2"
 246 else
 247   # if the user selected debug mode, don't use -O
 248   if test "$enable_debug" != yes; then
 249     CFLAGS="-O"
 250   fi
 251 fi
 252
 253 # Need to specify -fno-strict-aliasing too in case it's gcc 3.3 or later.
 254 PGAC_PROG_CC_NO_STRICT_ALIASING
 255
 256 # supply -g if --enable-debug
 257 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 258   CFLAGS="$CFLAGS -g"
 259 fi
 260
 261 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 262
 263 # We already have this in Makefile.win32, but configure needs it too
 264 if test "$PORTNAME" = "win32"; then
 265   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 266 fi
 267
 268 # Check if the compiler still works with the template settings
 269 AC_MSG_CHECKING([whether the C compiler still works])
 270 AC_TRY_LINK([], [return 0;],
 271   [AC_MSG_RESULT(yes)],
 272   [AC_MSG_RESULT(no)
 273    AC_MSG_ERROR([cannot proceed])])
 274
 275 # Defend against gcc -ffast-math
 276 if test "$GCC" = yes; then
 277 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 278 choke me
 279 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 280 fi
 281
 282 AC_PROG_CPP
 283 AC_SUBST(GCC)
 284
 285 # Create compiler version string
 286 if test x"$GCC" = x"yes" ; then
 287   cc_string="GCC `${CC} --version | sed q`"
 288 else
 289   cc_string=$CC
 290 fi
 291 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 292                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 293                    [A string containing the version number, platform, and C compiler])
 294
 295
 296 #
 297 # Set up TAS assembly code if needed; the template file has now had its
 298 # chance to request this.
 299 #
 300 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 301
 302 if test "$need_tas" = yes ; then
 303   TAS=tas.o
 304 else
 305   TAS=""
 306 fi
 307 AC_SUBST(TAS)
 308
 309
 310 #
 311 # Automatic dependency tracking
 312 #
 313 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 314               [autodepend=yes])
 315 AC_SUBST(autodepend)
 316
 317
 318 #
 319 # Enable assert checks
 320 #
 321 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 322               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 323                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 324
 325
 326 #
 327 # Include directories
 328 #
 329 ac_save_IFS=$IFS
 330 IFS="${IFS}${PATH_SEPARATOR}"
 331 # SRCH_INC comes from the template file
 332 for dir in $with_includes $SRCH_INC; do
 333   if test -d "$dir"; then
 334     INCLUDES="$INCLUDES -I$dir"
 335   else
 336     AC_MSG_WARN([*** Include directory $dir does not exist.])
 337   fi
 338 done
 339 IFS=$ac_save_IFS
 340 AC_SUBST(INCLUDES)
 341
 342
 343 #
 344 # Library directories
 345 #
 346 ac_save_IFS=$IFS
 347 IFS="${IFS}${PATH_SEPARATOR}"
 348 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 349 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 350   if test -d "$dir"; then
 351     LIBDIRS="$LIBDIRS -L$dir"
 352   else
 353     AC_MSG_WARN([*** Library directory $dir does not exist.])
 354   fi
 355 done
 356 IFS=$ac_save_IFS
 357
 358 #
 359 # Enable thread-safe client libraries
 360 #
 361 AC_MSG_CHECKING([allow thread-safe client libraries])
 362 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 363 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 364 if test "$enable_thread_safety" = yes -o \
 365         "$enable_thread_safety_force" = yes; then
 366   enable_thread_safety="yes"    # for 'force'
 367   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 368           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 369 fi
 370 AC_MSG_RESULT([$enable_thread_safety])
 371 AC_SUBST(enable_thread_safety)
 372
 373 #
 374 # Tcl/Tk
 375 #
 376 AC_MSG_CHECKING([whether to build with Tcl])
 377 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 378 AC_MSG_RESULT([$with_tcl])
 379 AC_SUBST([with_tcl])
 380
 381 # We see if the path to the Tcl/Tk configuration scripts is specified.
 382 # This will override the use of tclsh to find the paths to search.
 383
 384 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 385
 386 #
 387 # Optionally build Perl modules (PL/Perl)
 388 #
 389 AC_MSG_CHECKING([whether to build Perl modules])
 390 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 391 AC_MSG_RESULT([$with_perl])
 392 AC_SUBST(with_perl)
 393
 394 #
 395 # Optionally build Python modules (PL/Python)
 396 #
 397 AC_MSG_CHECKING([whether to build Python modules])
 398 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 399 AC_MSG_RESULT([$with_python])
 400 AC_SUBST(with_python)
 401
 402 #
 403 # Kerberos 4
 404 #
 405 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 406 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 407 [
 408   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 409   krb_srvtab="/etc/srvtab"
 410 ])
 411 AC_MSG_RESULT([$with_krb4])
 412 AC_SUBST(with_krb4)
 413
 414
 415 #
 416 # Kerberos 5
 417 #
 418 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 419 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 420 [
 421   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 422   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 423 ])
 424 AC_MSG_RESULT([$with_krb5])
 425 AC_SUBST(with_krb5)
 426
 427
 428 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 429 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 430   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 431 fi
 432
 433 AC_SUBST(krb_srvtab)
 434
 435
 436 #
 437 # Kerberos configuration parameters
 438 #
 439 PGAC_ARG_REQ(with, krb-srvnam,
 440              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 441              [],
 442              [with_krb_srvnam="postgres"])
 443 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 444                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 445
 446
 447 #
 448 # PAM
 449 #
 450 AC_MSG_CHECKING([whether to build with PAM support])
 451 PGAC_ARG_BOOL(with, pam, no,
 452               [  --with-pam              build with PAM support],
 453               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 454 AC_MSG_RESULT([$with_pam])
 455 AC_SUBST(with_pam)
 456
 457
 458 #
 459 # Rendezvous
 460 #
 461 AC_MSG_CHECKING([whether to build with Rendezvous support])
 462 PGAC_ARG_BOOL(with, rendezvous, no,
 463               [  --with-rendezvous       build with Rendezvous support],
 464               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 465 AC_MSG_RESULT([$with_rendezvous])
 466 AC_SUBST(with_rendezvous)
 467
 468
 469 #
 470 # OpenSSL
 471 #
 472 AC_MSG_CHECKING([whether to build with OpenSSL support])
 473 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 474               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 475 AC_MSG_RESULT([$with_openssl])
 476 AC_SUBST(with_openssl)
 477
 478
 479 #
 480 # Readline
 481 #
 482 PGAC_ARG_BOOL(with, readline, yes,
 483               [  --without-readline      do not use Readline])
 484 # readline on MinGW has problems with backslashes in psql and other bugs.
 485 # This is particularly a problem with non-US code pages.
 486 # Therefore disable its use until we understand the cause. 2004-07-20
 487 if test "$PORTNAME" = "win32"; then
 488   if test "$with_readline" = yes; then
 489     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 490     with_readline=no
 491   fi
 492 fi
 493
 494
 495 #
 496 # Zlib
 497 #
 498 PGAC_ARG_BOOL(with, zlib, yes,
 499               [  --without-zlib          do not use Zlib])
 500
 501 #
 502 # Elf
 503 #
 504
 505 # Assume system is ELF if it predefines __ELF__ as 1,
 506 # otherwise believe host_os based default.
 507 case $host_os in
 508     freebsd1*|freebsd2*) elf=no;;
 509     freebsd3*|freebsd4*) elf=yes;;
 510 esac
 511
 512 AC_EGREP_CPP(yes,
 513 [#if __ELF__
 514   yes
 515 #endif
 516 ],
 517 [ELF_SYS=true],
 518 [if test "X$elf" = "Xyes" ; then
 519   ELF_SYS=true
 520 else
 521   ELF_SYS=
 522 fi])
 523 AC_SUBST(ELF_SYS)
 524
 525 #
 526 # Assignments
 527 #
 528
 529 CPPFLAGS="$CPPFLAGS $INCLUDES"
 530 LDFLAGS="$LDFLAGS $LIBDIRS"
 531
 532 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 533 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 534
 535
 536 AC_PROG_AWK
 537 PGAC_PATH_FLEX
 538 AC_PROG_LN_S
 539 PGAC_PROG_LD
 540 AC_SUBST(LD)
 541 AC_SUBST(with_gnu_ld)
 542 case $host_os in sysv5*)
 543   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 544   [
 545     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 546     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 547     LDFLAGS=$pgac_save_LDFLAGS
 548   ])
 549   ld_R_works=$pgac_cv_prog_ld_R
 550   AC_SUBST(ld_R_works)
 551 esac
 552 AC_PROG_RANLIB
 553 AC_CHECK_PROGS(LORDER, lorder)
 554 AC_PATH_PROG(TAR, tar)
 555 PGAC_CHECK_STRIP
 556
 557 AC_CHECK_PROGS(YACC, ['bison -y'])
 558
 559 if test "$YACC"; then
 560   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 561     AC_MSG_WARN([
 562 *** If you are going to modify the grammar files or build from CVS, the installed
 563 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 564   fi
 565 fi
 566
 567 if test -z "$YACC"; then
 568   AC_MSG_WARN([
 569 *** Without Bison you will not be able to build PostgreSQL from CVS or
 570 *** change any of the parser definition files.  You can obtain Bison from
 571 *** a GNU mirror site.  (If you are using the official distribution of
 572 *** PostgreSQL then you do not need to worry about this because the Bison
 573 *** output is pre-generated.)  To use a different yacc program (possible,
 574 *** but not recommended), set the environment variable YACC before running
 575 *** 'configure'.])
 576 fi
 577 AC_SUBST(YFLAGS)
 578
 579 PGAC_PATH_PERL
 580 if test "$with_perl" = yes; then
 581   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 582   PGAC_CHECK_PERL_EMBED_LDFLAGS
 583 fi
 584
 585 if test "$with_python" = yes; then
 586   PGAC_PATH_PYTHON
 587   PGAC_CHECK_PYTHON_EMBED_SETUP
 588 fi
 589
 590
 591 ##
 592 ## Libraries
 593 ##
 594
 595 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 596 then
 597         AC_CHECK_LIB(bsd,      main)
 598 fi
 599 AC_CHECK_LIB(util,     setproctitle)
 600 AC_CHECK_LIB(m,        main)
 601 AC_CHECK_LIB(dl,       main)
 602 AC_CHECK_LIB(nsl,      main)
 603 AC_CHECK_LIB(socket,   main)
 604 AC_CHECK_LIB(ipc,      main)
 605 AC_CHECK_LIB(IPC,      main)
 606 AC_CHECK_LIB(lc,       main)
 607 AC_CHECK_LIB(dld,      main)
 608 AC_CHECK_LIB(ld,       main)
 609 AC_CHECK_LIB(compat,   main)
 610 AC_CHECK_LIB(BSD,      main)
 611 AC_CHECK_LIB(gen,      main)
 612 AC_CHECK_LIB(PW,       main)
 613 AC_CHECK_LIB(resolv,   main)
 614 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 615 # QNX:
 616 AC_CHECK_LIB(unix, main)
 617 AC_SEARCH_LIBS(crypt,  crypt)
 618 # BeOS:
 619 if test "$PORTNAME" = "beos"
 620 then
 621         AC_CHECK_LIB(bind, __inet_ntoa)
 622 fi
 623 # Solaris:
 624 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 625 # Cygwin:
 626 AC_CHECK_LIB(cygipc, shmget)
 627 # WIN32:
 628 if test "$PORTNAME" = "win32"
 629 then
 630         AC_CHECK_LIB(wsock32, main)
 631 fi
 632
 633 if test "$with_readline" = yes; then
 634   PGAC_CHECK_READLINE
 635   if test x"$pgac_cv_check_readline" = x"no"; then
 636     AC_MSG_ERROR([readline library not found
 637 If you have readline already installed, see config.log for details on the
 638 failure.  It is possible the compiler isn't looking in the proper directory.
 639 Use --without-readline to disable readline support.])
 640   fi
 641 fi
 642
 643 if test "$with_zlib" = yes; then
 644   AC_CHECK_LIB(z, inflate, [],
 645                [AC_MSG_ERROR([zlib library not found
 646 If you have zlib already installed, see config.log for details on the
 647 failure.  It is possible the compiler isn't looking in the proper directory.
 648 Use --without-zlib to disable zlib support.])])
 649 fi
 650
 651 if test "$enable_spinlocks" = yes; then
 652   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 653 else
 654   AC_MSG_WARN([
 655 *** Not using spinlocks will cause poor performance.])
 656 fi
 657
 658 if test "$with_krb4" = yes ; then
 659   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 660   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 661   AC_REPLACE_FUNCS([gethostname])
 662 fi
 663
 664 if test "$with_krb5" = yes ; then
 665   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 666                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 667   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 668                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 669   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 670                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 671 fi
 672
 673 if test "$with_openssl" = yes ; then
 674   dnl Order matters!
 675   AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 676   AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 677 fi
 678
 679 if test "$with_pam" = yes ; then
 680   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 681 fi
 682
 683
 684 ##
 685 ## Header files
 686 ##
 687
 688 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 689 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 690
 691 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 692 # netinet/in.h is included first.
 693 AC_CHECK_HEADERS(netinet/in.h)
 694 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 695 [AC_INCLUDES_DEFAULT
 696 #ifdef HAVE_NETINET_IN_H
 697 #include <netinet/in.h>
 698 #endif
 699 ])
 700
 701 if test "$with_readline" = yes; then
 702   AC_CHECK_HEADERS(readline/readline.h, [],
 703                    [AC_CHECK_HEADERS(editline/readline.h, [],
 704                          [AC_CHECK_HEADERS(readline.h, [],
 705                                      [AC_MSG_ERROR([readline header not found
 706 If you have readline already installed, see config.log for details on the
 707 failure.  It is possible the compiler isn't looking in the proper directory.
 708 Use --without-readline to disable readline support.])])])])
 709   AC_CHECK_HEADERS(readline/history.h, [],
 710                    [AC_CHECK_HEADERS(editline/history.h, [],
 711                          [AC_CHECK_HEADERS(history.h, [],
 712                                      [AC_MSG_ERROR([history header not found
 713 If you have readline already installed, see config.log for details on the
 714 failure.  It is possible the compiler isn't looking in the proper directory.
 715 Use --without-readline to disable readline support.])])])])
 716 fi
 717
 718 if test "$with_zlib" = yes; then
 719   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 720 If you have zlib already installed, see config.log for details on the
 721 failure.  It is possible the compiler isn't looking in the proper directory.
 722 Use --without-zlib to disable zlib support.])])
 723 fi
 724
 725 if test "$with_krb4" = yes ; then
 726   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 727 fi
 728
 729 if test "$with_krb5" = yes ; then
 730   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 731   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 732 fi
 733
 734 if test "$with_openssl" = yes ; then
 735   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 736   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 737 fi
 738
 739 if test "$with_pam" = yes ; then
 740   AC_CHECK_HEADERS(security/pam_appl.h, [],
 741                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 742                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 743 fi
 744
 745 if test "$with_rendezvous" = yes ; then
 746   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 747 fi
 748
 749
 750 ##
 751 ## Types, structures, compiler characteristics
 752 ##
 753
 754 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 755 AC_C_CONST
 756 AC_C_INLINE
 757 AC_C_STRINGIZE
 758 PGAC_C_SIGNED
 759 AC_C_VOLATILE
 760 PGAC_C_FUNCNAME_SUPPORT
 761 PGAC_STRUCT_TIMEZONE
 762 PGAC_UNION_SEMUN
 763 PGAC_STRUCT_SOCKADDR_UN
 764 PGAC_STRUCT_SOCKADDR_STORAGE
 765 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 766 PGAC_STRUCT_ADDRINFO
 767
 768 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 769 [#include <sys/param.h>
 770 #include <sys/types.h>
 771 #include <sys/socket.h>
 772 #include <sys/ucred.h>])
 773
 774 AC_CHECK_TYPES([struct option], [], [],
 775 [#ifdef HAVE_GETOPT_H
 776 #include <getopt.h>
 777 #endif])
 778
 779 if test "$with_zlib" = yes; then
 780   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 781   # did not).  While we could work around the lack of z_streamp, it
 782   # seems unwise to encourage people to use such old zlib versions...
 783   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 784 Use --without-zlib to disable zlib support.])],
 785                 [#include <zlib.h>])
 786 fi
 787
 788 if test "$with_krb5" = yes; then
 789 # Check for differences between MIT and Heimdal (KTH) releases
 790   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 791                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 792                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 793                                      [#include <krb5.h>])],
 794                    [#include <krb5.h>])
 795   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 796                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 797                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 798                                      [#include <krb5.h>])],
 799                    [#include <krb5.h>])
 800 fi
 801
 802 ##
 803 ## Functions, global variables
 804 ##
 805
 806 PGAC_VAR_INT_TIMEZONE
 807 AC_FUNC_ACCEPT_ARGTYPES
 808 PGAC_FUNC_GETTIMEOFDAY_1ARG
 809
 810 # SunOS doesn't handle negative byte comparisons properly with +/- return
 811 AC_FUNC_MEMCMP
 812
 813 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 814
 815 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 816
 817 HAVE_IPV6=no
 818 AC_CHECK_TYPE([struct sockaddr_in6],
 819               [AC_CHECK_FUNC(inet_ntop,
 820                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 821                                                           HAVE_IPV6=yes])],
 822               [],
 823 [$ac_includes_default
 824 #include <netinet/in.h>])
 825 AC_SUBST(HAVE_IPV6)
 826
 827 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 828 [AC_TRY_LINK(
 829 [#include <machine/vmparam.h>
 830 #include <sys/exec.h>
 831 ],
 832 [PS_STRINGS->ps_nargvstr = 1;
 833 PS_STRINGS->ps_argvstr = "foo";],
 834 [pgac_cv_var_PS_STRINGS=yes],
 835 [pgac_cv_var_PS_STRINGS=no])])
 836 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 837   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 838 fi
 839
 840
 841 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 842 # is missing.  Yes, there are machines that have only one.  We may
 843 # also decide to use snprintf.c if snprintf() is present but does not
 844 # have working "long long int" support -- see below.
 845
 846 pgac_need_repl_snprintf=no
 847 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 848 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 849
 850
 851 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 852 # include/c.h will provide declarations.  Note this is a separate test
 853 # from whether the functions exist in the C library --- there are
 854 # systems that have the functions but don't bother to declare them :-(
 855
 856 AC_CHECK_DECLS([snprintf, vsnprintf])
 857
 858
 859 # do this one the hard way in case isinf() is a macro
 860 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 861 [AC_TRY_LINK(
 862 [#include <math.h>
 863 ],
 864 [double x = 0.0; int res = isinf(x);],
 865 [ac_cv_func_isinf=yes],
 866 [ac_cv_func_isinf=no])])
 867
 868 if test $ac_cv_func_isinf = yes ; then
 869   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 870 else
 871   AC_LIBOBJ(isinf)
 872   # Look for a way to implement a substitute for isinf()
 873   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 874 fi
 875
 876 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 877
 878 # system's version of getaddrinfo(), if any, may be used only if we found
 879 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 880 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 881   AC_REPLACE_FUNCS([getaddrinfo])
 882 else
 883   AC_LIBOBJ(getaddrinfo)
 884 fi
 885
 886 # similarly, use system's getopt_long() only if system provides struct option.
 887 if test x"$ac_cv_type_struct_option" = xyes ; then
 888   AC_REPLACE_FUNCS([getopt_long])
 889 else
 890   AC_LIBOBJ(getopt_long)
 891 fi
 892
 893 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 894 # We override the previous test that said fseeko/ftello didn't exist
 895 # OS tests are also done in include/c.h and port/fseeko.c
 896 case $host_os in bsdi*|netbsd*)
 897 ac_cv_func_fseeko=yes
 898 esac
 899
 900 # Solaris has a very slow qsort in certain cases, so we replace it.
 901 if test "$PORTNAME" = "solaris"; then
 902 AC_LIBOBJ(qsort)
 903 fi
 904
 905 # Win32 support
 906 if test "$PORTNAME" = "win32"; then
 907 AC_LIBOBJ(copydir)
 908 AC_LIBOBJ(gettimeofday)
 909 AC_LIBOBJ(kill)
 910 AC_LIBOBJ(open)
 911 AC_LIBOBJ(rand)
 912 AC_DEFINE([HAVE_SYMLINK], 1,
 913           [Define to 1 if you have the `symlink' function.])
 914 fi
 915
 916 if test "$with_readline" = yes; then
 917   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 918   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 919   AC_CHECK_FUNCS([replace_history_entry])
 920 fi
 921
 922
 923 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 924 AC_MSG_CHECKING(for finite)
 925 AC_TRY_LINK([#include <math.h>],
 926             [int dummy=finite(1.0);],
 927             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 928 AC_MSG_RESULT(yes)],
 929             [AC_MSG_RESULT(no)])
 930
 931 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 932 dnl (especially on GNU libc)
 933 dnl See also comments in c.h.
 934 AC_MSG_CHECKING(for sigsetjmp)
 935 AC_TRY_LINK([#include <setjmp.h>],
 936             [sigjmp_buf x; sigsetjmp(x, 1);],
 937             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 938 AC_MSG_RESULT(yes)],
 939             [AC_MSG_RESULT(no)])
 940
 941 AC_CHECK_FUNC(syslog,
 942               [AC_CHECK_HEADER(syslog.h,
 943                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
 944
 945 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 946 [AC_TRY_LINK([#include <unistd.h>],
 947   [extern int optreset; optreset = 1;],
 948   [pgac_cv_var_int_optreset=yes],
 949   [pgac_cv_var_int_optreset=no])])
 950 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 951   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
 952 fi
 953
 954 AC_CHECK_FUNCS([strtoll strtoq], [break])
 955 AC_CHECK_FUNCS([strtoull strtouq], [break])
 956
 957 # Check for one of atexit() or on_exit()
 958 AC_CHECK_FUNCS(atexit, [],
 959                [AC_CHECK_FUNCS(on_exit, [],
 960                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 961
 962 AC_FUNC_FSEEKO
 963
 964 #
 965 # Pthreads
 966 #
 967 # For each platform, we need to know about any special compile and link
 968 # libraries, and whether the normal C function names are thread-safe.
 969 # See the comment at the top of src/port/thread.c for more information.
 970 #
 971 if test "$enable_thread_safety" = yes; then
 972 ACX_PTHREAD     # set thread flags
 973
 974 # Some platforms use these, so just defineed them.  They can't hurt if they
 975 # are not supported.
 976 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
 977
 978
 979 # At this point, we don't want to muck with the compiler name for threading.
 980 # Let's see who fails, perhaps AIX.  2004-04-23
 981 if test "$PTHREAD_CC" != "$CC"; then
 982 AC_MSG_ERROR([
 983 PostgreSQL does not support platforms that require a special
 984 compiler binary for thread-safety.
 985 ])
 986 fi
 987
 988 if test "$THREAD_SUPPORT" = no; then
 989 AC_MSG_ERROR([
 990 Cannot enable threads on your platform.
 991 Your platform is known to not support thread-safe programs.
 992 For details, compile and run src/bin/pg_thread_test.
 993 ])
 994 fi
 995
 996 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
 997
 998 # Check for *_r functions
 999 _CFLAGS="$CFLAGS"
1000 _LIBS="$LIBS"
1001 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1002 LIBS="$LIBS $PTHREAD_LIBS"
1003 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1004
1005 # Do test here with the proper thread flags
1006 PGAC_FUNC_GETPWUID_R_5ARG
1007 PGAC_FUNC_STRERROR_R_INT
1008
1009 CFLAGS="$_CFLAGS"
1010 LIBS="$_LIBS"
1011
1012 else
1013 # do not use values from template file
1014 PTHREAD_CFLAGS=
1015 PTHREAD_LIBS=
1016 fi
1017
1018 AC_SUBST(PTHREAD_CFLAGS)
1019 AC_SUBST(PTHREAD_LIBS)
1020
1021
1022 # This test makes sure that run tests work at all.  Sometimes a shared
1023 # library is found by the linker, but the runtime linker can't find it.
1024 # This check should come after all modifications of compiler or linker
1025 # variables, and before any other run tests.
1026 AC_MSG_CHECKING([test program])
1027 AC_TRY_RUN([int main() { return 0; }],
1028 [AC_MSG_RESULT(ok)],
1029 [AC_MSG_RESULT(failed)
1030 AC_MSG_ERROR([[
1031 *** Could not execute a simple test program.  This may be a problem
1032 *** related to locating shared libraries.  Check the file 'config.log'
1033 *** for the exact reason.]])],
1034 [AC_MSG_RESULT([cross-compiling])])
1035
1036
1037 dnl Check to see if we have a working 64-bit integer type.
1038 dnl This breaks down into two steps:
1039 dnl (1) figure out if the compiler has a 64-bit int type with working
1040 dnl arithmetic, and if so
1041 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1042 dnl snprintf is the only library routine we really need for int8 support.)
1043 dnl It's entirely possible to have a compiler that handles a 64-bit type
1044 dnl when the C library doesn't; this is fairly likely when using gcc on
1045 dnl an older platform, for example.
1046 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1047 dnl we force our own version of snprintf() to be used instead.
1048 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1049
1050 PGAC_TYPE_64BIT_INT([long int])
1051
1052 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1053   PGAC_TYPE_64BIT_INT([long long int])
1054 fi
1055
1056
1057 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1058
1059 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1060   AC_TRY_COMPILE([
1061 #define INT64CONST(x)  x##LL
1062 long long int foo = INT64CONST(0x1234567890123456);
1063 ],
1064         [],
1065         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1066         [])
1067 fi
1068
1069
1070 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1071 # we found we need to use "long long int", better check.  We cope with
1072 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1073 # work, fall back to our own snprintf emulation (which we know uses %lld).
1074
1075 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1076   if test $pgac_need_repl_snprintf = no; then
1077     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1078     if test "$LONG_LONG_INT_FORMAT" = ""; then
1079       # Force usage of our own snprintf, since system snprintf is broken
1080       pgac_need_repl_snprintf=yes
1081       LONG_LONG_INT_FORMAT='%lld'
1082     fi
1083   else
1084     # Here if we previously decided we needed to use our own snprintf
1085     LONG_LONG_INT_FORMAT='%lld'
1086   fi
1087   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1088   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1089   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1090 else
1091   # Here if we are not using 'long long int' at all
1092   INT64_FORMAT='"%ld"'
1093   UINT64_FORMAT='"%lu"'
1094 fi
1095
1096 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1097                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1098
1099 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1100                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1101
1102 if test $pgac_need_repl_snprintf = yes; then
1103   AC_LIBOBJ(snprintf)
1104 fi
1105
1106 # Need a #define for the size of Datum (unsigned long)
1107 AC_CHECK_SIZEOF([unsigned long])
1108
1109 # Determine memory alignment requirements for the basic C data types.
1110
1111 PGAC_CHECK_ALIGNOF(short)
1112 PGAC_CHECK_ALIGNOF(int)
1113 PGAC_CHECK_ALIGNOF(long)
1114 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1115   PGAC_CHECK_ALIGNOF(long long int)
1116 fi
1117 PGAC_CHECK_ALIGNOF(double)
1118
1119 # Compute maximum alignment of any basic type.
1120 # We assume long's alignment is at least as strong as char, short, or int;
1121 # but we must check long long (if it exists) and double.
1122
1123 MAX_ALIGNOF=$pgac_cv_alignof_long
1124 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1125   MAX_ALIGNOF=$pgac_cv_alignof_double
1126 fi
1127 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1128   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1129 fi
1130 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1131
1132
1133 # Some platforms predefine the types int8, int16, etc.  Only check
1134 # a (hopefully) representative subset.
1135 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1136 [#include <stdio.h>
1137 #ifdef HAVE_SUPPORTDEFS_H
1138 #include <SupportDefs.h>
1139 #endif])
1140
1141 # We also check for sig_atomic_t, which *should* be defined per ANSI
1142 # C, but is missing on some old platforms.
1143 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1144
1145
1146 PGAC_FUNC_POSIX_SIGNALS
1147 if test $ac_cv_func_fseeko = yes; then
1148 AC_SYS_LARGEFILE
1149 fi
1150
1151
1152 # Select semaphore implementation type.
1153 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1154   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1155   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1156 else
1157   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1158     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1159     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1160   else
1161     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1162     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1163   fi
1164 fi
1165
1166
1167 # Select shared-memory implementation type.
1168 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1169 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1170
1171
1172 if test "$enable_nls" = yes ; then
1173   PGAC_CHECK_GETTEXT
1174 fi
1175
1176 # Check for Tcl configuration script tclConfig.sh
1177 if test "$with_tcl" = yes; then
1178     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1179     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1180                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1181     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1182 fi
1183
1184 #
1185 # Check for DocBook and tools
1186 #
1187 PGAC_PROG_NSGMLS
1188 PGAC_PROG_JADE
1189 PGAC_CHECK_DOCBOOK(4.2)
1190 PGAC_PATH_DOCBOOK_STYLESHEETS
1191 PGAC_PATH_COLLATEINDEX
1192 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1193
1194 # Thread testing
1195
1196 # We have to run the thread test near the end so we have all our symbols
1197 # defined.  Cross compiling throws a warning.
1198 #
1199 if test "$enable_thread_safety_force" = yes; then
1200   AC_MSG_WARN([
1201 *** Skipping thread test program.  --enable-thread-safety-force was used.
1202 *** Run the program in src/tools/thread on the your machine and add
1203 proper locking function calls to your applications to guarantee thread
1204 safety.
1205 ])
1206 elif test "$enable_thread_safety" = yes; then
1207 AC_MSG_CHECKING([thread safety of required library functions])
1208
1209 _CFLAGS="$CFLAGS"
1210 _LIBS="$LIBS"
1211 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1212 LIBS="$LIBS $PTHREAD_LIBS"
1213 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1214   [AC_MSG_RESULT(yes)],
1215   [AC_MSG_RESULT(no)
1216   AC_MSG_ERROR([
1217 *** Thread test program failed.  Your platform is not thread-safe.
1218 *** Check the file 'config.log'for the exact reason.
1219 ***
1220 *** You can use the configure option --enable-thread-safety-force
1221 *** to force threads to be enabled.  However, you must then run
1222 *** the program in src/tools/thread and add locking function calls
1223 *** to your applications to guarantee thread safety.
1224 ])],
1225   [AC_MSG_RESULT(maybe)
1226   AC_MSG_WARN([
1227 *** Skipping thread test program because of cross-compile build.
1228 *** Run the program in src/tools/thread on the target machine.
1229 ])])
1230 CFLAGS="$_CFLAGS"
1231 LIBS="$_LIBS"
1232 fi
1233
1234 # prepare build tree if outside source tree
1235 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1236 # Note 2: /bin/pwd might be better than shell's built-in at getting
1237 #         a symlink-free name.
1238 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1239   vpath_build=no
1240 else
1241   vpath_build=yes
1242   if test "$no_create" != yes; then
1243     _AS_ECHO_N([preparing build tree... ])
1244     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1245     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1246       || AC_MSG_ERROR(failed)
1247     AC_MSG_RESULT(done)
1248   fi
1249 fi
1250 AC_SUBST(vpath_build)
1251
1252
1253 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1254
1255 AC_CONFIG_LINKS([
1256   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1257   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1258   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1259   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1260   src/include/pg_config_os.h:src/include/port/${template}.h
1261   src/Makefile.port:src/makefiles/Makefile.${template}
1262 ])
1263
1264 if test "$PORTNAME" = "win32"; then
1265 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1266 # Links sometimes fail undetected on Mingw -
1267 # so here we detect it and warn the user
1268 for FILE in $CONFIG_LINKS
1269  do
1270         # test -e works for symlinks in the MinGW console
1271         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1272  done
1273 ])
1274 fi
1275
1276 AC_CONFIG_HEADERS([src/include/pg_config.h],
1277 [
1278 # Update timestamp for pg_config.h (see Makefile.global)
1279 echo >src/include/stamp-h
1280 ])
1281
1282 AC_OUTPUT
1283