granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.13)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(srclib/apr/build)
  12
  13 dnl #
  14 dnl # Include our own M4 macros along with those for APR and libtool
  15 dnl #
  16 sinclude(srclib/apr/build/apr_common.m4)
  17 sinclude(srclib/apr/build/apr_network.m4)
  18 sinclude(srclib/apr/build/apr_threads.m4)
  19 sinclude(acinclude.m4)
  20
  21 dnl Save user-defined environment settings for later restoration
  22 dnl
  23 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  24 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  25 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  26 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  27 APR_SAVE_THE_ENVIRONMENT(LIBS)
  28 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  29
  30 dnl Generate ./config.nice for reproducing runs of configure
  31 dnl
  32 APR_CONFIG_NICE(config.nice)
  33
  34 nl='
  35 '
  36 dnl ## Run configure for packages Apache uses
  37
  38 echo $ac_n "${nl}Configuring Apache Portable Runtime library ...${nl}"
  39
  40 APR_SUBDIR_CONFIG(srclib/apr, "$apache_apr_flags --disable-shared")
  41
  42 echo $ac_n "${nl}Configuring Apache Portable Runtime Utility library...${nl}"
  43
  44 APR_SUBDIR_CONFIG(srclib/apr-util, "--with-apr=../apr --disable-shared")
  45
  46 echo $ac_n "${nl}Configuring PCRE regular expression library ...${nl}"
  47
  48 APR_SUBDIR_CONFIG(srclib/pcre)
  49
  50 echo $ac_n "${nl}Configuring Apache httpd ...${nl}"
  51
  52 echo $ac_n "obtaining flag settings from the sub-configures...${nl}"
  53 . ./srclib/apr/APRVARS
  54
  55 dnl Now that we have APR's EXTRA_flags in our environment, move them over
  56 dnl to the normal variables to avoid duplications and use them for testing.
  57 dnl We ignore EXTRA_INCLUDES because our own includes will encompass them.
  58 dnl
  59 APR_ADDTO(CFLAGS, $EXTRA_CFLAGS)
  60 APR_ADDTO(CPPFLAGS, $EXTRA_CPPFLAGS)
  61 APR_ADDTO(LDFLAGS, $EXTRA_LDFLAGS)
  62 APR_ADDTO(LIBS, $EXTRA_LIBS)
  63 EXTRA_CFLAGS=
  64 EXTRA_CPPFLAGS=
  65 EXTRA_LDFLAGS=
  66 EXTRA_LIBS=
  67 EXTRA_INCLUDES=
  68
  69 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  70 dnl by configure until it is too late.  Is that how it should be or not?
  71 dnl Something seems broken here.
  72 AC_PREFIX_DEFAULT(/usr/local/apache2)
  73 test "$prefix" = "NONE" && prefix='/usr/local/apache2'
  74 test "$exec_prefix" = "NONE" && exec_prefix='${prefix}'
  75
  76 dnl Absolute source/build directory
  77 abs_srcdir=`(cd $srcdir && pwd)`
  78 abs_builddir=`pwd`
  79
  80 dnl If the source dir is not equal to the build dir,
  81 dnl then we are running in VPATH mode.
  82
  83 if test "$abs_builddir" != "$abs_srcdir"; then
  84   USE_VPATH=1
  85   APR_ADDTO(INCLUDES, [-I. -I\$(srcdir) -I\$(top_builddir)/os/\$(OS_DIR) -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_builddir)/server/mpm/\$(MPM_NAME) -I\$(top_srcdir)/server/mpm/\$(MPM_NAME) -I\$(top_builddir)/modules/http -I\$(top_srcdir)/modules/http -I\$(top_builddir)/include -I\$(top_srcdir)/include -I\$(top_builddir)/srclib/apr/include -I\$(top_srcdir)/srclib/apr/include -I\$(top_builddir)/srclib/apr-util/include -I\$(top_srcdir)/srclib/apr-util/include])
  86 else
  87   APR_ADDTO(INCLUDES, [-I. -I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/server/mpm/\$(MPM_NAME) -I\$(top_srcdir)/modules/http -I\$(top_srcdir)/include -I\$(top_srcdir)/srclib/apr/include -I\$(top_srcdir)/srclib/apr-util/include])
  88 fi
  89
  90 echo $ac_n "${nl}Applying OS-specific hints for httpd ...${nl}"
  91
  92 AC_CANONICAL_SYSTEM
  93
  94 case "$host_alias" in
  95   *os2*)
  96       # Use a custom made libtool replacement
  97       echo "using aplibtool"
  98       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
  99       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 100       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 101       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 102       MK_IMPLIB="emximp"
 103       other_targets="$other_targets os2core"
 104       ;;
 105   *)
 106       if test "x$LTFLAGS" = "x"; then
 107           LTFLAGS='--silent'
 108       fi
 109       LIBTOOL='$(SHELL) $(top_builddir)/srclib/apr/libtool $(LTFLAGS)'
 110       SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 111       ;;
 112 esac
 113
 114 case "$host" in
 115   *-apple-aux3*)
 116       APR_SETVAR(APACHE_MPM, [prefork])
 117       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 118       ;;
 119   *-beos*)
 120       APR_SETVAR(APACHE_MPM, [beos])
 121       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 122       ;;
 123   *os2_emx*)
 124       APR_SETVAR(APACHE_MPM, [spmt_os2])
 125       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 126       ;;
 127   *-linux-*)
 128       case `uname -r` in
 129         2.2* ) APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 130             ;;
 131         * )
 132             ;;
 133       esac
 134       ;;
 135   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 136       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 137       ;;
 138   *-solaris2*)
 139       dnl  This is a hack -- we should be using AC_TRY_RUN instead
 140       ap_platform_runtime_link_flag="-R"
 141       ;;
 142 esac
 143
 144 dnl
 145 dnl Process command line arguments. This is done early in the process so the
 146 dnl user can get feedback quickly in case of an error.
 147 dnl
 148 dnl ### need to move some of the arguments "up here"
 149
 150 dnl ## Check for programs
 151
 152 AC_PATH_PROG(RM, rm)
 153 AC_PROG_AWK
 154 AC_PROG_CC
 155 AC_PROG_CPP
 156 AC_PROG_INSTALL
 157 AC_PROG_LN_S
 158 AC_CHECK_TOOL(RANLIB, ranlib, true)
 159 dnl AC_PATH_PROG(PERL_PATH, perl)
 160
 161 dnl various OS checks that apparently set required flags
 162 AC_AIX
 163 AC_ISC_POSIX
 164 AC_MINIX
 165
 166 dnl ## Check for libraries
 167
 168 dnl ## Check for header files
 169
 170 dnl I think these are just used all over the place, so just check for
 171 dnl them at the base of the tree. If some are specific to a single
 172 dnl directory, they should be moved (Comment #Spoon)
 173
 174 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 175 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 176 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 177
 178 AC_HEADER_STDC
 179 AC_CHECK_HEADERS( \
 180 string.h \
 181 limits.h \
 182 unistd.h \
 183 sys/socket.h \
 184 pwd.h \
 185 grp.h \
 186 strings.h
 187 )
 188 AC_HEADER_SYS_WAIT
 189
 190 dnl ## Check for typedefs, structures, and compiler characteristics.
 191
 192 AC_C_CONST
 193
 194 dnl ## Check for library functions
 195
 196 dnl See Comment #Spoon
 197
 198 AC_CHECK_FUNCS( \
 199 initgroups \
 200 )
 201
 202 AC_CHECK_LIB(nsl, gethostbyname)
 203 AC_CHECK_LIB(nsl, gethostname)
 204 AC_CHECK_LIB(socket, socket)
 205
 206 AC_ARG_WITH(port,[  --with-port=PORT        Port on which to listen (default is 80)],
 207         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 208         [PORT=80])
 209
 210 AC_ARG_ENABLE(maintainer-mode,[  --enable-maintainer-mode  Turn on debugging and compile time warnings],
 211   [APR_ADDTO(CPPFLAGS,-DAP_DEBUG)
 212 ])dnl
 213
 214 APACHE_ENABLE_LAYOUT
 215 APACHE_ENABLE_MODULES
 216
 217 dnl reading config stubs
 218 esyscmd(./build/config-stubs .)
 219
 220 APACHE_SUBST(progname)
 221 APACHE_SUBST(MPM_LIB)
 222 APACHE_SUBST(OS)
 223 APACHE_SUBST(OS_DIR)
 224 APACHE_SUBST(BUILTIN_LIBS)
 225
 226 PRE_SHARED_CMDS='echo ""'
 227 POST_SHARED_CMDS='echo ""'
 228
 229 if test "$apache_need_shared" = "yes"; then
 230   $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 231   case "$host" in
 232     *-ibm-aix*)
 233       HTTPD_LDFLAGS="$HTTPD_LDFLAGS -Wl,-bE:$abs_srcdir/support/httpd.exp"
 234       SH_LDFLAGS="$SH_LDFLAGS -Wl,-bI:$abs_srcdir/support/httpd.exp"
 235       ;;
 236     *beos)
 237       SH_LDFLAGS='$(top_builddir)/_APP_'
 238       PRE_SHARED_CMDS='ln -s $(top_builddir)/httpd $(top_builddir)/_APP_'
 239       POST_SHARED_CMDS='rm $(top_builddir)/_APP_'
 240       ;;
 241     *os390)
 242       APR_ADDTO(CFLAGS, [-Wc,DLL,EXPORTALL])
 243       ;;
 244   esac
 245   shared_build="shared-modules"
 246 fi
 247
 248 APACHE_SUBST(PRE_SHARED_CMDS)
 249 APACHE_SUBST(POST_SHARED_CMDS)
 250 APACHE_SUBST(shared_build)
 251
 252 AC_ARG_WITH(program-name,
 253 [  --with-program-name     alternate executable name],[
 254   progname="$withval" ], [
 255   progname="httpd"] )
 256
 257 # SuExec parameters
 258 AC_ARG_WITH(suexec-caller,
 259 [  --with-suexec-caller    User allowed to call SuExec],[
 260   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 261
 262 AC_ARG_WITH(suexec-userdir,
 263 [  --with-suexec-userdir   User subdirectory],[
 264   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 265
 266 AC_ARG_WITH(suexec-docroot,
 267 [  --with-suexec-docroot   SuExec root directory],[
 268   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 269
 270 AC_ARG_WITH(suexec-uidmin,
 271 [  --with-suexec-uidmin    Minimal allowed UID],[
 272   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 273
 274 AC_ARG_WITH(suexec-gidmin,
 275 [  --with-suexec-gidmin    Minimal allowed GID],[
 276   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 277
 278 AC_ARG_WITH(suexec-logfile,
 279 [  --with-suexec-logfile   Set the logfile],[
 280   AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file] ) ] )
 281
 282 AC_ARG_WITH(suexec-safepath,
 283 [  --with-suexec-safepath  Set the safepath],[
 284   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 285
 286 AC_ARG_WITH(suexec-umask,
 287 [  --with-suexec-umask     umask for suexec'd process],[
 288   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 289
 290 dnl AP_LIB_DIRS specifies the additional libs from srclib/ that we need
 291 dnl AP_LIBS specifies the actual libraries. note we have some required libs.
 292 AP_LIBS="$abs_srcdir/srclib/pcre/libpcre.la $abs_srcdir/srclib/apr-util/libaprutil.la $AP_LIBS"
 293
 294 dnl APR should go after the other libs, so the right symbols can be picked up
 295 AP_LIBS="$AP_LIBS $abs_srcdir/srclib/apr/libapr.la"
 296 APACHE_SUBST(AP_LIB_DIRS)
 297 APACHE_SUBST(AP_LIBS)
 298
 299 AC_DEFINE(AP_USING_AUTOCONF, 1,
 300                 [Using autoconf to configure Apache])
 301
 302 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 303     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 304               [This platform doesn't suffer from the thundering herd problem])
 305 fi
 306
 307 dnl check for endianness
 308 if test "$cross_compiling" = "no"; then
 309   AC_C_BIGENDIAN
 310 else
 311   AC_DEFINE(AP_UNKNOWN_BYTE_ORDER,1,
 312                 [byte order is unknown due to cross-compilation])
 313 fi
 314
 315 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 316 APACHE_FAST_OUTPUT(os/beos/Makefile os/os2/Makefile os/Makefile)
 317 APACHE_FAST_OUTPUT(os/unix/Makefile server/Makefile)
 318 APACHE_FAST_OUTPUT(support/Makefile srclib/pcre/Makefile)
 319 for i in $AP_LIB_DIRS; do
 320   APACHE_FAST_OUTPUT(srclib/$i/Makefile)
 321 done
 322
 323 if test -d ./test; then
 324     APACHE_FAST_OUTPUT(test/Makefile)
 325 fi
 326
 327 dnl get the exported vars from APRUTIL
 328 . ./srclib/apr-util/export_vars.sh
 329 APR_ADDTO(LIBS, $APRUTIL_EXPORT_LIBS)
 330 AP_LIBS="$AP_LIBS $LIBTOOL_LIBS"
 331
 332 dnl ## Finalize the variables
 333 echo $ac_n "${nl}Restore user-defined environment settings...${nl}"
 334
 335 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 336 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 337 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 338 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 339 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 340 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 341
 342 echo $ac_n "${nl}Construct makefiles and header files...${nl}"
 343
 344 APACHE_GEN_CONFIG_VARS
 345
 346 dnl ## Build modules.c
 347 rm -f modules.c
 348 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 349
 350 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "$prefix",
 351         [Root directory of the Apache install area])
 352 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "conf/$progname.conf",
 353         [Location of the config file, relative to the Apache root directory])
 354 AC_DEFINE_UNQUOTED(APACHE_MPM_DIR, "$MPM_DIR",
 355         [Location of the source for the current MPM])
 356
 357 perlbin=`$ac_aux_dir/PrintPath perl`
 358 if test "x$perlbin" = "x"; then
 359     perlbin="/replace/with/path/to/perl/interpreter"
 360 fi
 361 AC_SUBST(perlbin)
 362
 363 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 364
 365 BSD_MAKEFILE=no
 366 case "$host_alias" in
 367 *bsdi*)
 368     # Check whether they've installed GNU make
 369     if make --version > /dev/null 2>&1; then
 370         true
 371     else
 372         BSD_MAKEFILE=yes
 373     fi
 374     ;;
 375 esac
 376
 377 AC_OUTPUT($APACHE_OUTPUT_FILES support/apxs support/apachectl support/dbmmanage support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile,,[
 378   APACHE_GEN_MAKEFILES
 379 ])
 380