granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.175 2002/04/03 05:39:27 petere Exp $
   3
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17
  18 dnl The GNU folks apparently haven't heard that some people don't use
  19 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  20 m4_define([info], [doc])
  21 m4_define([infodir], [docdir])
  22 AC_INIT([PostgreSQL], [7.3devel], [pgsql-bugs@postgresql.org])
  23 m4_undefine([infodir])
  24 m4_undefine([info])
  25 AC_SUBST(docdir)
  26
  27 AC_PREREQ(2.53)
  28 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  29 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  30 AC_CONFIG_AUX_DIR(config)
  31 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  32 AC_SUBST(configure_args, [$ac_configure_args])
  33
  34 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  35
  36 AC_CANONICAL_HOST
  37
  38 template=
  39 AC_MSG_CHECKING([which template to use])
  40
  41 PGAC_ARG_REQ(with, template, [],
  42 [
  43   case $withval in
  44     list)   echo; ls "$srcdir/src/template"; exit;;
  45     *)      if test -f "$srcdir/src/template/$with_template" ; then
  46               template=$withval
  47             else
  48               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  49             fi;;
  50   esac
  51 ],
  52 [
  53   # --with-template not given
  54
  55 case $host_os in
  56      aix*) template=aix ;;
  57     beos*) template=beos ;;
  58     bsdi*) template=bsdi ;;
  59   cygwin*) template=win ;;
  60   darwin*) template=darwin ;;
  61     dgux*) template=dgux ;;
  62  freebsd*) template=freebsd ;;
  63     hpux*) template=hpux ;;
  64     irix*) template=irix5 ;;
  65    linux*) template=linux ;;
  66   netbsd*) template=netbsd ;;
  67 nextstep*) template=nextstep ;;
  68  openbsd*) template=openbsd ;;
  69      osf*) template=osf ;;
  70      qnx*) template=qnx4 ;;
  71      sco*) template=sco ;;
  72  solaris*) template=solaris ;;
  73    sunos*) template=sunos4 ;;
  74  sysv4.2*)
  75         case $host_vendor in
  76           univel) template=univel ;;
  77         esac ;;
  78    sysv4*) template=svr4 ;;
  79    sysv5*) template=unixware ;;
  80   ultrix*) template=ultrix4 ;;
  81 esac
  82
  83   if test x"$template" = x"" ; then
  84     AC_MSG_ERROR([[
  85 *******************************************************************
  86 PostgreSQL has apparently not been ported to your platform yet.
  87 To try a manual configuration, look into the src/template directory
  88 for a similar platform and use the '--with-template=' option.
  89
  90 Please also contact <pgsql-ports@postgresql.org> to see about
  91 rectifying this.  Include the above 'checking host system type...'
  92 line.
  93 *******************************************************************
  94 ]])
  95   fi
  96
  97 ])
  98
  99 AC_MSG_RESULT([$template])
 100
 101 PORTNAME=$template
 102 AC_SUBST(PORTNAME)
 103
 104 # Pick right test-and-set (TAS) code.  Most platforms have inline
 105 # assembler code in src/include/storage/s_lock.h, so we just use
 106 # a dummy file here.
 107 case $host in
 108   *-*-hpux*)        need_tas=yes; tas_file=hpux.s ;;
 109   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 110   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 111   *)                need_tas=no;  tas_file=dummy.s ;;
 112 esac
 113 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 114
 115 if test "$need_tas" = yes ; then
 116   TAS=tas.o
 117 fi
 118 AC_SUBST(TAS)
 119
 120
 121
 122 ##
 123 ## Command line options
 124 ##
 125
 126
 127 #
 128 # Add non-standard directories to the include path
 129 #
 130 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 131
 132
 133 #
 134 # Add non-standard directories to the library search path
 135 #
 136 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 137              [LIBRARY_DIRS=$withval])
 138
 139 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 140              [LIBRARY_DIRS=$withval])
 141
 142
 143 #
 144 # Character set recode (--enable-recode)
 145 #
 146 AC_MSG_CHECKING([whether to build with recode support])
 147 PGAC_ARG_BOOL(enable, recode, no, [  --enable-recode         enable character set recode support],
 148               [AC_DEFINE([CYR_RECODE], 1,
 149                          [Set to 1 if you want cyrillic recode support (--enable-recode)])])
 150 AC_MSG_RESULT([$enable_recode])
 151
 152
 153 #
 154 # Multibyte support
 155 #
 156 MULTIBYTE=
 157 AC_MSG_CHECKING([whether to build with multibyte character support])
 158
 159 PGAC_ARG_OPTARG(enable, multibyte, [  --enable-multibyte      enable multibyte character support],
 160 [MULTIBYTE=SQL_ASCII],
 161 [
 162   case $enableval in
 163     SQL_ASCII|EUC_JP|EUC_CN|EUC_KR|EUC_TW|JOHAB|UNICODE|MULE_INTERNAL|LATIN1|LATIN2|LATIN3|LATIN4|LATIN5|LATIN6|LATIN7|LATIN8|LATIN9|LATIN10|WIN1256|TCVN|WIN874|KOI8|WIN|ALT|ISO_8859_5|ISO_8859_6|ISO_8859_7|ISO_8859_8)
 164       MULTIBYTE=$enableval;;
 165     *)
 166       AC_MSG_ERROR(
 167 [argument to --enable-multibyte must be one of:
 168   SQL_ASCII, EUC_JP, EUC_CN, EUC_KR, EUC_TW, JOHAB,
 169   UNICODE, MULE_INTERNAL,
 170   LATIN1, LATIN2, LATIN3, LATIN4, LATIN5,
 171   LATIN6, LATIN7, LATIN8, LATIN9, LATIN10,
 172   WIN1256, TCVN, WIN874, KOI8, WIN, ALT,
 173   ISO_8859_5, ISO_8859_6, ISO_8859_7, ISO_8859_8
 174 Or do not specify an argument to the option to use the default.]);;
 175   esac
 176 ],
 177 [
 178   AC_DEFINE(MULTIBYTE, 1, [Set to 1 if you want to use multibyte characters (--enable-multibyte)])
 179   AC_MSG_RESULT([yes, default $MULTIBYTE])
 180 ],
 181 [AC_MSG_RESULT(no)])
 182
 183 AC_SUBST(MULTIBYTE)
 184
 185 #
 186 # NLS
 187 #
 188 AC_MSG_CHECKING([whether NLS is wanted])
 189 PGAC_ARG_OPTARG(enable, nls,
 190                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 191                 [],
 192                 [WANTED_LANGUAGES=$enableval],
 193                 [AC_DEFINE(ENABLE_NLS, 1,
 194                            [Define to 1 if you want National Language Support (--enable-nls)])])
 195 AC_MSG_RESULT([$enable_nls])
 196 AC_SUBST(enable_nls)
 197 AC_SUBST(WANTED_LANGUAGES)
 198
 199 #
 200 # Default port number (--with-pgport), default 5432
 201 #
 202 AC_MSG_CHECKING([for default port number])
 203 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 204              [default_port=$withval],
 205              [default_port=5432])
 206 AC_MSG_RESULT([$default_port])
 207 # Need both of these because some places want an integer and some a string
 208 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 209 [The default TCP port number on which the server listens and to which
 210 clients will try to connect to.  This can be overridden at run-time,
 211 but it's convenient if your clients have the right default compiled in.
 212 (--with-pgport=PORTNUM)])
 213 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 214                    [Default TCP port number as string constant])
 215 AC_SUBST(default_port)
 216
 217 #
 218 # Maximum number of allowed connections (--with-maxbackends), default 32
 219 #
 220 AC_MSG_CHECKING([for default soft limit on number of connections])
 221 PGAC_ARG_REQ(with, maxbackends, [  --with-maxbackends=N    set default maximum number of connections [32]],
 222              [],
 223              [with_maxbackends=32])
 224 AC_MSG_RESULT([$with_maxbackends])
 225 AC_DEFINE_UNQUOTED([DEF_MAXBACKENDS], [$with_maxbackends],
 226                    [The default soft limit on the number of concurrent connections, i.e., the default for the postmaster -N switch (--with-maxbackends)])
 227
 228
 229 #
 230 # Option to disable shared libraries
 231 #
 232 PGAC_ARG_BOOL(enable, shared, yes,
 233               [  --disable-shared        do not build shared libraries])
 234 AC_SUBST(enable_shared)
 235
 236 #
 237 # '-rpath'-like feature can be disabled
 238 #
 239 PGAC_ARG_BOOL(enable, rpath, yes,
 240               [  --disable-rpath         do not embed shared library search path in executables])
 241 AC_SUBST(enable_rpath)
 242
 243
 244 #
 245 # --enable-debug adds -g to compiler flags
 246 #
 247 PGAC_ARG_BOOL(enable, debug, no,
 248               [  --enable-debug          build with debugging symbols (-g)])
 249 AC_SUBST(enable_debug)
 250
 251 #
 252 # C compiler
 253 #
 254
 255 # For historical reasons you can also use --with-CC to specify the C compiler
 256 # to use, although the standard way to do this is to set the CC environment
 257 # variable.
 258 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 259
 260 case $template in
 261   aix) pgac_cc_list="gcc xlc";;
 262  irix) pgac_cc_list="cc";; # no gcc
 263     *) pgac_cc_list="gcc cc";;
 264 esac
 265
 266 AC_PROG_CC([$pgac_cc_list])
 267 # Read the template
 268 . "$srcdir/src/template/$template" || exit
 269
 270 if test "$ac_env_CFLAGS_set" = set; then
 271   CFLAGS=$ac_env_CFLAGS_value
 272 fi
 273 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 274   CFLAGS="$CFLAGS -g"
 275 fi
 276 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 277 # Check if the compiler still works with the template settings
 278 AC_MSG_CHECKING([whether the C compiler still works])
 279 AC_TRY_LINK([], [return 0;],
 280   [AC_MSG_RESULT(yes)],
 281   [AC_MSG_RESULT(no)
 282    AC_MSG_ERROR([cannot proceed])])
 283 AC_PROG_CPP
 284 AC_SUBST(GCC)
 285
 286 # Create compiler version string
 287 if test x"$GCC" = x"yes" ; then
 288   cc_string="GCC `${CC} --version | sed q`"
 289 else
 290   cc_string=$CC
 291 fi
 292 AC_DEFINE_UNQUOTED(PG_VERSION_STR, ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"], [A canonical string containing the version number, platform, and C compiler])
 293
 294
 295 #
 296 # Automatic dependency tracking
 297 #
 298 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 299               [autodepend=yes])
 300 AC_SUBST(autodepend)
 301
 302
 303 #
 304 # Enable assert checks
 305 #
 306 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 307               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 308                          [Define to 1 to build with assertion checks])])
 309
 310
 311 #
 312 # Include directories
 313 #
 314 ac_save_IFS=$IFS
 315 IFS="${IFS}:"
 316 # SRCH_INC comes from the template file
 317 for dir in $with_includes $SRCH_INC; do
 318   if test -d "$dir"; then
 319     INCLUDES="$INCLUDES -I$dir"
 320   else
 321     AC_MSG_WARN([*** Include directory $dir does not exist.])
 322   fi
 323 done
 324 IFS=$ac_save_IFS
 325 AC_SUBST(INCLUDES)
 326
 327
 328 #
 329 # Library directories
 330 #
 331 ac_save_IFS=$IFS
 332 IFS="${IFS}:"
 333 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 334 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 335   if test -d "$dir"; then
 336     LIBDIRS="$LIBDIRS -L$dir"
 337   else
 338     AC_MSG_WARN([*** Library directory $dir does not exist.])
 339   fi
 340 done
 341 IFS=$ac_save_IFS
 342
 343
 344 #
 345 # Tcl/Tk
 346 #
 347 AC_MSG_CHECKING([whether to build with Tcl])
 348 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 349 AC_MSG_RESULT([$with_tcl])
 350 AC_SUBST([with_tcl])
 351
 352 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 353 AC_MSG_CHECKING([whether to build with Tk])
 354 if test "$with_tcl" = yes; then
 355   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 356 else
 357   with_tk=no
 358 fi
 359 AC_MSG_RESULT([$with_tk])
 360 AC_SUBST([with_tk])
 361
 362
 363 # We see if the path to the Tcl/Tk configuration scripts is specified.
 364 # This will override the use of tclsh to find the paths to search.
 365
 366 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 367
 368 # We see if the path to the Tk configuration scripts is specified.
 369 # This will override the use of tclsh to find the paths to search.
 370
 371 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 372
 373 #
 374 # Optionally build Perl modules (Pg.pm and PL/Perl)
 375 #
 376 AC_MSG_CHECKING([whether to build Perl modules])
 377 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl interface and PL/Perl])
 378 AC_MSG_RESULT([$with_perl])
 379 AC_SUBST(with_perl)
 380
 381 #
 382 # Optionally build Python interface module
 383 #
 384 AC_MSG_CHECKING([whether to build Python modules])
 385 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 386 AC_MSG_RESULT([$with_python])
 387 AC_SUBST(with_python)
 388
 389 #
 390 # Optionally build the Java/JDBC tools
 391 #
 392 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 393 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 394 [AC_MSG_RESULT(yes)
 395 PGAC_PATH_ANT
 396 if test -z "$ANT"; then
 397   AC_MSG_ERROR([Ant is required to build Java components])
 398 fi],
 399 [AC_MSG_RESULT(no)])
 400 AC_SUBST(with_java)
 401
 402 dnl A note on the Kerberos and OpenSSL options:
 403 dnl
 404 dnl The user can give an argument to the option in order the specify
 405 dnl the base path of the respective installation (what he specified
 406 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 407 dnl then we take the path where the package installs by default. This
 408 dnl way the user doesn't have to use redundant --with-includes and
 409 dnl --with-libraries options, but he can still use them if the layout
 410 dnl is non-standard.
 411
 412 #
 413 # Kerberos 4
 414 #
 415 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 416 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 417                 [krb4_prefix=/usr/athena],
 418                 [krb4_prefix=$withval],
 419 [
 420   AC_MSG_RESULT(yes)
 421   AC_DEFINE(KRB4, 1, [Define if you are building with Kerberos 4 support.])
 422
 423   if test -d "$krb4_prefix/include"; then
 424     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 425   fi
 426   if test -d "$krb4_prefix/lib"; then
 427     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 428   fi
 429
 430   krb_srvtab="/etc/srvtab"
 431 ],
 432 [AC_MSG_RESULT(no)])
 433
 434 AC_SUBST(with_krb4)
 435
 436
 437 #
 438 # Kerberos 5
 439 #
 440 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 441 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 442               [krb5_prefix=/usr/athena],
 443               [krb5_prefix=$withval],
 444 [
 445   AC_MSG_RESULT([yes])
 446   AC_DEFINE(KRB5, 1, [Define if you are building with Kerberos 5 support.])
 447
 448   if test -d "$krb5_prefix/include"; then
 449     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 450   fi
 451   if test -d "$krb5_prefix/lib"; then
 452     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 453   fi
 454
 455   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 456 ],
 457 [AC_MSG_RESULT(no)])
 458
 459 AC_SUBST(with_krb5)
 460
 461
 462 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 463 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 464   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 465 fi
 466
 467 AC_SUBST(krb_srvtab)
 468
 469
 470 #
 471 # Kerberos configuration parameters
 472 #
 473 PGAC_ARG_REQ(with, krb-srvnam,
 474              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 475              [],
 476              [with_krb_srvnam="postgres"])
 477 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 478                    [The name of the PostgreSQL service principal in Kerberos])
 479
 480
 481 #
 482 # PAM
 483 #
 484 AC_MSG_CHECKING([whether to build with PAM support])
 485 PGAC_ARG_BOOL(with, pam, no,
 486               [  --with-pam              build with PAM support],
 487               [AC_DEFINE([USE_PAM], 1, [Define to build with PAM support])])
 488 AC_MSG_RESULT([$with_pam])
 489 AC_SUBST(with_pam)
 490
 491
 492 #
 493 # OpenSSL
 494 #
 495 PGAC_ARG_OPTARG(with, openssl,
 496                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 497                 [openssl_prefix=/usr/local/ssl],
 498                 [openssl_prefix=$withval],
 499 [
 500   AC_MSG_RESULT([building with OpenSSL support])
 501   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support])
 502
 503   if test -d "${openssl_prefix}/include" ; then
 504     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 505   fi
 506   if test -d "${openssl_prefix}/lib" ; then
 507     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 508   fi
 509 ])
 510
 511 AC_SUBST(with_openssl)
 512
 513
 514
 515 #
 516 # Optionally enable the building of the ODBC driver
 517 #
 518
 519 # Old option name
 520 if test "${with_odbc+set}" = set && test "${enable_odbc+set}" != set; then
 521   enable_odbc=$with_odbc
 522 fi
 523
 524 AC_MSG_CHECKING([whether to build the ODBC driver])
 525 PGAC_ARG_BOOL(enable, odbc, no, [  --enable-odbc           build the ODBC driver package])
 526 PGAC_ARG_BOOL(with, unixodbc, no, [  --with-unixodbc         build ODBC driver for unixODBC])
 527 PGAC_ARG_BOOL(with, iodbc, no, [  --with-iodbc            build ODBC driver for iODBC])
 528 if test "$with_unixodbc" = yes && test "$with_iodbc" = yes; then
 529   AC_MSG_ERROR([ODBC driver cannot be built for both unixODBC and iODBC])
 530 fi
 531 if test "$with_unixodbc" = yes || test "$with_iodbc" = yes; then
 532   enable_odbc=yes
 533 fi
 534 case $enable_odbc:$with_unixodbc:$with_iodbc in
 535   yes:no:no)    AC_MSG_RESULT([yes (stand-alone)]);;
 536   yes:yes:no)   AC_MSG_RESULT([yes (unixODBC)])
 537                 AC_DEFINE(WITH_UNIXODBC, 1, [Define to 1 to build with unixODBC support (--with-unixodbc)])
 538                 ;;
 539   yes:no:yes)   AC_MSG_RESULT([yes (iODBC)])
 540                 AC_DEFINE(WITH_IODBC, 1, [Define to 1 to build with iODBC support (--with-iodbc)])
 541                 ;;
 542   no:*)         AC_MSG_RESULT(no);;
 543 esac
 544 AC_SUBST([enable_odbc])
 545 AC_SUBST([with_unixodbc])
 546 AC_SUBST([with_iodbc])
 547
 548
 549 # Allow for overriding the default location of the odbcinst.ini
 550 # file which is normally ${sysconfdir} (i.e., ${prefix}/etc).
 551 PGAC_ARG_REQ(with, odbcinst,
 552              [  --with-odbcinst=DIR     default directory for odbcinst.ini [sysconfdir]],
 553              [odbcinst_ini_dir=$withval],
 554              [odbcinst_ini_dir="\${sysconfdir}"])
 555 AC_SUBST([odbcinst_ini_dir])
 556
 557
 558
 559 # Assume system is ELF if it predefines __ELF__ as 1,
 560 # otherwise believe host_os based default.
 561 case $host_os in
 562     freebsd1*|freebsd2*) elf=no;;
 563     freebsd3*|freebsd4*) elf=yes;;
 564 esac
 565
 566 AC_EGREP_CPP(yes,
 567 [#if __ELF__
 568   yes
 569 #endif
 570 ],
 571 [ELF_SYS=true],
 572 [if test "X$elf" = "Xyes" ; then
 573   ELF_SYS=true
 574 else
 575   ELF_SYS=
 576 fi])
 577 AC_SUBST(ELF_SYS)
 578
 579
 580
 581 #
 582 # Optionally build C++ code (i.e., libpq++)
 583 #
 584 AC_MSG_CHECKING([whether to build C++ modules])
 585 PGAC_ARG_OPTARG(with, CXX, [  --with-CXX              build C++ modules (libpq++)],
 586                 [],
 587                 [CXX=$withval],
 588 [
 589   AC_MSG_RESULT(yes)
 590
 591   # If the user has specified CXXFLAGS in the environment, leave it
 592   # alone, else use a default.
 593
 594   AC_PROG_CXX
 595   if test "$ac_env_CXXFLAGS" != set; then
 596     if test "$GXX" = yes; then
 597       CXXFLAGS=-O2
 598     else
 599       case $template in
 600         osf)            CXXFLAGS='-O4 -Olimit 2000' ;;
 601         unixware)       CXXFLAGS='-O' ;;
 602         *)              CXXFLAGS= ;;
 603       esac
 604     fi
 605   fi
 606   if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 607     CXXFLAGS="$CXXFLAGS -g"
 608   fi
 609   AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
 610
 611   AC_PROG_CXXCPP
 612 ],
 613 [AC_MSG_RESULT(no)])
 614 AC_SUBST(with_CXX)
 615 AC_SUBST(GXX)
 616
 617 CPPFLAGS="$CPPFLAGS $INCLUDES"
 618 LDFLAGS="$LDFLAGS $LIBDIRS"
 619
 620 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 621 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 622
 623
 624 AC_PROG_AWK
 625 PGAC_PATH_FLEX
 626 AC_PROG_LN_S
 627 AC_PROG_LD
 628 AC_SUBST(LD)
 629 AC_SUBST(with_gnu_ld)
 630 case $host_os in sysv5*)
 631   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 632   [
 633     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 634     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 635     LDFLAGS=$pgac_save_LDFLAGS
 636   ])
 637   ld_R_works=$pgac_cv_prog_ld_R
 638   AC_SUBST(ld_R_works)
 639 esac
 640 AC_PROG_RANLIB
 641 AC_CHECK_PROGS(LORDER, lorder)
 642 AC_PATH_PROG(TAR, tar)
 643
 644 AC_CHECK_PROGS(YACC, ['bison -y'])
 645 if test -z "$YACC"; then
 646   AC_MSG_WARN([
 647 *** Without Bison you will not be able to build PostgreSQL from CVS or
 648 *** change any of the parser definition files.  You can obtain Bison from
 649 *** a GNU mirror site.  (If you are using the official distribution of
 650 *** PostgreSQL then you do not need to worry about this because the Bison
 651 *** output is pre-generated.)  To use a different yacc program (possible,
 652 *** but not recommended), set the environment variable YACC before running
 653 *** 'configure'.])
 654 fi
 655 AC_SUBST(YFLAGS)
 656
 657 if test "$with_tk" = yes; then
 658     AC_PATH_PROG(WISH, wish)
 659     test -z "$WISH" && AC_MSG_ERROR(['wish' is required for Tk support])
 660 fi
 661
 662 PGAC_PATH_PERL
 663 if test "$with_perl" = yes; then
 664   PGAC_CHECK_PERL_DIRS
 665 fi
 666
 667 if test "$with_python" = yes; then
 668   PGAC_PATH_PYTHON
 669   PGAC_CHECK_PYTHON_MODULE_SETUP
 670   PGAC_CHECK_PYTHON_EMBED_SETUP
 671 fi
 672
 673
 674 ##
 675 ## Libraries
 676 ##
 677
 678 PGAC_CHECK_READLINE
 679 AC_SEARCH_LIBS(using_history, history,
 680                [AC_DEFINE(HAVE_HISTORY_FUNCTIONS, 1,
 681                           [Define if you have the history functions])])
 682
 683 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 684 then
 685         AC_CHECK_LIB(bsd,      main)
 686 fi
 687 AC_CHECK_LIB(util,     setproctitle)
 688 AC_CHECK_LIB(m,        main)
 689 AC_CHECK_LIB(dl,       main)
 690 AC_CHECK_LIB(socket,   main)
 691 AC_CHECK_LIB(nsl,      main)
 692 AC_CHECK_LIB(ipc,      main)
 693 AC_CHECK_LIB(IPC,      main)
 694 AC_CHECK_LIB(lc,       main)
 695 AC_CHECK_LIB(dld,      main)
 696 AC_CHECK_LIB(ld,       main)
 697 AC_CHECK_LIB(compat,   main)
 698 AC_CHECK_LIB(BSD,      main)
 699 AC_CHECK_LIB(gen,      main)
 700 AC_CHECK_LIB(PW,       main)
 701 AC_CHECK_LIB(resolv,   main)
 702 # QNX:
 703 AC_CHECK_LIB([[unix]], main)
 704 AC_SEARCH_LIBS(crypt,  crypt)
 705 # BeOS:
 706 AC_CHECK_LIB(bind,     __inet_ntoa)
 707 # Only consider libz to be present if we find <zlib.h> as well;
 708 # furthermore, check that <zlib.h> defines z_streamp (versions before
 709 # about 1.0.4 did not).  While we could work around the lack of z_streamp,
 710 # it seems unwise to encourage people to use such old zlib versions...
 711 AC_EGREP_HEADER(z_streamp, zlib.h, [
 712 AC_CHECK_LIB(z,        inflate)
 713 ])
 714 # Solaris:
 715 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 716
 717 if test "$with_krb4" = yes ; then
 718   AC_CHECK_LIB(des, [des_encrypt], [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 719   AC_CHECK_LIB(krb, [krb_sendauth], [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 720 fi
 721
 722 if test "$with_krb5" = yes ; then
 723   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 724                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 725   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 726                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 727   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 728                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 729 fi
 730
 731 if test "$with_openssl" = yes ; then
 732   dnl Order matters!
 733   AC_CHECK_LIB(crypto, [CRYPTO_new_ex_data], [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 734   AC_CHECK_LIB(ssl,    [SSL_library_init], [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 735 fi
 736
 737 if test "$with_pam" = yes ; then
 738   AC_CHECK_LIB(pam,    [pam_start], [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 739 fi
 740
 741
 742 ##
 743 ## Header files
 744 ##
 745 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 746 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h pwd.h sys/ipc.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h kernel/OS.h kernel/image.h SupportDefs.h])
 747
 748 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 749 # netinet/in.h is included first.
 750 AC_CHECK_HEADERS([netinet/in.h])
 751 AC_CHECK_HEADERS([netinet/tcp.h], [], [],
 752 [AC_INCLUDES_DEFAULT
 753 #ifdef HAVE_NETINET_IN_H
 754 #include <netinet/in.h>
 755 #endif
 756 ])
 757
 758 AC_CHECK_HEADERS([readline/readline.h readline.h], [break])
 759 AC_CHECK_HEADERS([readline/history.h history.h], [break])
 760
 761 if test "$with_krb4" = yes ; then
 762   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 763 fi
 764
 765 if test "$with_krb5" = yes ; then
 766   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 767   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 768 fi
 769
 770 if test "$with_openssl" = yes ; then
 771   AC_CHECK_HEADER([openssl/ssl.h], [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 772   AC_CHECK_HEADER([openssl/err.h], [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 773 fi
 774
 775 if test "$with_pam" = yes ; then
 776   AC_CHECK_HEADER([security/pam_appl.h], [], [AC_MSG_ERROR([header file <security/pam_appl.h> is required for PAM])])
 777 fi
 778
 779
 780 ##
 781 ## Types, structures, compiler characteristics
 782 ##
 783 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 784 AC_C_CONST
 785 AC_C_INLINE
 786 AC_C_STRINGIZE
 787 PGAC_C_SIGNED
 788 AC_C_VOLATILE
 789 AC_STRUCT_TIMEZONE
 790 PGAC_UNION_SEMUN
 791 PGAC_STRUCT_SOCKADDR_UN
 792
 793 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 794 [#include <sys/param.h>
 795 #include <sys/socket.h>
 796 #include <sys/ucred.h>])
 797
 798 if test "$with_krb5" = yes; then
 799 # Check for differences between MIT and Heimdal (KTH) releases
 800   AC_CHECK_MEMBERS([krb5_ticket.enc_part2], [],
 801                    [AC_CHECK_MEMBERS([krb5_ticket.client], [],
 802                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 803                                      [#include <krb5.h>])],
 804                    [#include <krb5.h>])
 805   AC_CHECK_MEMBERS([krb5_error.text.data], [],
 806                    [AC_CHECK_MEMBER([krb5_error.e_data], [],
 807                                     [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 808                                     [#include <krb5.h>])],
 809                    [#include <krb5.h>])
 810 fi
 811
 812
 813 ##
 814 ## Functions, global variables
 815 ##
 816 PGAC_VAR_INT_TIMEZONE
 817 AC_FUNC_ACCEPT_ARGTYPES
 818 PGAC_FUNC_GETTIMEOFDAY_1ARG
 819
 820 # SunOS doesn't handle negative byte comparisons properly with +/- return
 821 PGAC_FUNC_MEMCMP
 822
 823 AC_CHECK_FUNCS([cbrt fcvt getopt_long memmove pstat setproctitle setsid sigprocmask sysconf waitpid dlopen fdatasync])
 824
 825 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 826
 827 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 828 [AC_TRY_LINK(
 829 [#include <machine/vmparam.h>
 830 #include <sys/exec.h>
 831 ],
 832 [PS_STRINGS->ps_nargvstr = 1;
 833 PS_STRINGS->ps_argvstr = "foo";],
 834 [pgac_cv_var_PS_STRINGS=yes],
 835 [pgac_cv_var_PS_STRINGS=no])])
 836 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 837   AC_DEFINE([HAVE_PS_STRINGS], [], [Define if the PS_STRINGS thing exists.])
 838 fi
 839
 840
 841 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 842 # is missing.  Yes, there are machines that have only one.  We may
 843 # also decide to use snprintf.c if snprintf() is present but does not
 844 # have working "long long int" support -- see below.
 845
 846 SNPRINTF=''
 847 AC_CHECK_FUNCS(snprintf, [], SNPRINTF='snprintf.o')
 848 AC_CHECK_FUNCS(vsnprintf, [], SNPRINTF='snprintf.o')
 849 AC_SUBST(SNPRINTF)
 850
 851
 852 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 853 # include/c.h will provide declarations.  Note this is a separate test
 854 # from whether the functions exist in the C library --- there are
 855 # systems that have the functions but don't bother to declare them :-(
 856
 857 AC_CHECK_DECLS([snprintf, vsnprintf])
 858
 859
 860 # do this one the hard way in case isinf() is a macro
 861 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 862 [AC_TRY_LINK(
 863 [#include <math.h>
 864 ],
 865 [double x = 0.0; int res = isinf(x);],
 866 [ac_cv_func_isinf=yes],
 867 [ac_cv_func_isinf=no])])
 868
 869 if test $ac_cv_func_isinf = yes ; then
 870   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf()])
 871   ISINF=
 872 else
 873   ISINF='isinf.o'
 874   # Look for a way to implement a substitute for isinf()
 875   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 876 fi
 877 AC_SUBST(ISINF)
 878
 879
 880 AC_CHECK_FUNCS(getrusage, [], GETRUSAGE='getrusage.o')
 881 AC_SUBST(GETRUSAGE)
 882 AC_CHECK_FUNCS(srandom, [], SRANDOM='srandom.o')
 883 AC_SUBST(SRANDOM)
 884 AC_CHECK_FUNCS(gethostname, [], GETHOSTNAME='gethostname.o')
 885 AC_SUBST(GETHOSTNAME)
 886 AC_CHECK_FUNCS(random, [], MISSING_RANDOM='random.o')
 887 AC_SUBST(MISSING_RANDOM)
 888 AC_CHECK_FUNCS(inet_aton, [], INET_ATON='inet_aton.o')
 889 AC_SUBST(INET_ATON)
 890 AC_CHECK_FUNCS(strerror, [], STRERROR='strerror.o')
 891 AC_SUBST(STRERROR)
 892 AC_CHECK_FUNCS(strdup, [], STRDUP='../../utils/strdup.o')
 893 AC_SUBST(STRDUP)
 894 AC_CHECK_FUNCS(strtol, [], STRTOL='strtol.o')
 895 AC_SUBST(STRTOL)
 896 AC_CHECK_FUNCS(strtoul, [], STRTOUL='strtoul.o')
 897 AC_SUBST(STRTOUL)
 898 AC_CHECK_FUNCS(strcasecmp, [], STRCASECMP='strcasecmp.o')
 899 AC_SUBST(STRCASECMP)
 900
 901 # On HPUX 9, rint() is not in regular libm.a but in /lib/pa1.1/libm.a;
 902 # this hackery with HPUXMATHLIB allows us to cope.
 903 HPUXMATHLIB=""
 904 case $host_cpu in
 905   hppa1.1)
 906         if [[ -r /lib/pa1.1/libm.a ]] ; then
 907             HPUXMATHLIB="-L /lib/pa1.1 -lm"
 908         fi ;;
 909 esac
 910 AC_SUBST(HPUXMATHLIB)
 911
 912 AC_CHECK_FUNCS(rint, [],
 913                [AC_CHECK_LIB(m, rint, AC_DEFINE(HAVE_RINT), , $HPUXMATHLIB)])
 914
 915
 916 # Readline versions < 2.1 don't have rl_completion_append_character
 917 AC_MSG_CHECKING([for rl_completion_append_character])
 918 AC_TRY_LINK([#include <stdio.h>
 919 #ifdef HAVE_READLINE_READLINE_H
 920 # include <readline/readline.h>
 921 #elif defined(HAVE_READLINE_H)
 922 # include <readline.h>
 923 #endif
 924 ],
 925 [rl_completion_append_character = 'x';],
 926 [AC_MSG_RESULT(yes)
 927 AC_DEFINE(HAVE_RL_COMPLETION_APPEND_CHARACTER, 1,
 928           [Define if you have rl_completion_append_character])],
 929 [AC_MSG_RESULT(no)])
 930
 931 AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 932
 933
 934 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 935 AC_MSG_CHECKING(for finite)
 936 AC_TRY_LINK([#include <math.h>],
 937             [int dummy=finite(1.0);],
 938             [AC_DEFINE(HAVE_FINITE, 1, [Set to 1 if you have finite()])
 939 AC_MSG_RESULT(yes)],
 940             [AC_MSG_RESULT(no)])
 941
 942 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 943 dnl (especially on GNU libc)
 944 dnl See also comments in pg_config.h.
 945 AC_MSG_CHECKING(for sigsetjmp)
 946 AC_TRY_LINK([#include <setjmp.h>],
 947             [sigjmp_buf x; sigsetjmp(x, 1);],
 948             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Set to 1 if you have sigsetjmp()])
 949 AC_MSG_RESULT(yes)],
 950             [AC_MSG_RESULT(no)])
 951
 952
 953 PGAC_ARG_BOOL(enable, syslog, no, [  --enable-syslog         enable logging to syslog],
 954               [AC_CHECK_FUNC(syslog,
 955                              [AC_DEFINE([ENABLE_SYSLOG], 1,
 956                                         [Define to 1 if to enable the syslogging code])],
 957                              [AC_MSG_ERROR([no syslog interface found])])])
 958
 959
 960 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 961 [AC_TRY_LINK([#include <unistd.h>],
 962   [extern int optreset; optreset = 1;],
 963   [pgac_cv_var_int_optreset=yes],
 964   [pgac_cv_var_int_optreset=no])])
 965 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 966   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'])
 967 fi
 968
 969
 970 # This test makes sure that run tests work at all.  Sometimes a shared
 971 # library is found by the linker, but the runtime linker can't find it.
 972 # This check should come after all modifications of compiler or linker
 973 # variables, and before any other run tests.
 974 AC_MSG_CHECKING([test program])
 975 AC_TRY_RUN([int main() { return 0; }],
 976 [AC_MSG_RESULT(ok)],
 977 [AC_MSG_RESULT(failed)
 978 AC_MSG_ERROR([[
 979 *** Could not execute a simple test program.  This may be a problem
 980 *** related to locating shared libraries.  Check the file 'config.log'
 981 *** for the exact reason.]])],
 982 [AC_MSG_RESULT([cross-compiling])])
 983
 984
 985 dnl Check to see if we have a working 64-bit integer type.
 986 dnl This breaks down into two steps:
 987 dnl (1) figure out if the compiler has a 64-bit int type with working
 988 dnl arithmetic, and if so
 989 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
 990 dnl snprintf is the only library routine we really need for int8 support.)
 991 dnl It's entirely possible to have a compiler that handles a 64-bit type
 992 dnl when the C library doesn't; this is fairly likely when using gcc on
 993 dnl an older platform, for example.
 994 dnl If there is no native snprintf() or it does not handle the 64-bit type,
 995 dnl we force our own version of snprintf() to be used instead.
 996 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
 997
 998 PGAC_TYPE_64BIT_INT([long int])
 999
1000 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1001   PGAC_TYPE_64BIT_INT([long long int])
1002 fi
1003
1004
1005 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1006
1007 if [[ x"$HAVE_LONG_LONG_INT_64" = xyes ]] ; then
1008   AC_TRY_COMPILE([
1009 #define INT64CONST(x)  x##LL
1010 long long int foo = INT64CONST(0x1234567890123456);
1011 ],
1012         [],
1013         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define if you have LL constants])],
1014         [])
1015 fi
1016
1017
1018 dnl If we found "long int" is 64 bits, assume snprintf handles it.
1019 dnl If we found we need to use "long long int", better check.
1020 dnl We cope with snprintfs that use either %lld or %qd as the format.
1021 dnl If neither works, fall back to our own snprintf emulation (which we
1022 dnl know uses %lld).
1023
1024 if [[ x"$HAVE_LONG_LONG_INT_64" = xyes ]] ; then
1025   if [[ x$SNPRINTF = x ]] ; then
1026     AC_MSG_CHECKING(whether snprintf handles 'long long int' as %lld)
1027     AC_TRY_RUN([#include <stdio.h>
1028 typedef long long int int64;
1029 #define INT64_FORMAT "%lld"
1030
1031 int64 a = 20000001;
1032 int64 b = 40000005;
1033
1034 int does_int64_snprintf_work()
1035 {
1036   int64 c;
1037   char buf[100];
1038
1039   if (sizeof(int64) != 8)
1040     return 0;                   /* doesn't look like the right size */
1041
1042   c = a * b;
1043   snprintf(buf, 100, INT64_FORMAT, c);
1044   if (strcmp(buf, "800000140000005") != 0)
1045     return 0;                   /* either multiply or snprintf is busted */
1046   return 1;
1047 }
1048 main() {
1049   exit(! does_int64_snprintf_work());
1050 }],
1051         [ AC_MSG_RESULT(yes)
1052           INT64_FORMAT='"%lld"'
1053         ],
1054   [ AC_MSG_RESULT(no)
1055     AC_MSG_CHECKING(whether snprintf handles 'long long int' as %qd)
1056     AC_TRY_RUN([#include <stdio.h>
1057 typedef long long int int64;
1058 #define INT64_FORMAT "%qd"
1059
1060 int64 a = 20000001;
1061 int64 b = 40000005;
1062
1063 int does_int64_snprintf_work()
1064 {
1065   int64 c;
1066   char buf[100];
1067
1068   if (sizeof(int64) != 8)
1069     return 0;     /* doesn't look like the right size */
1070
1071   c = a * b;
1072   snprintf(buf, 100, INT64_FORMAT, c);
1073   if (strcmp(buf, "800000140000005") != 0)
1074     return 0;     /* either multiply or snprintf is busted */
1075   return 1;
1076 }
1077 main() {
1078   exit(! does_int64_snprintf_work());
1079 }],
1080   [ AC_MSG_RESULT(yes)
1081     INT64_FORMAT='"%qd"'
1082   ],
1083   [ AC_MSG_RESULT(no)
1084         # Force usage of our own snprintf, since system snprintf is broken
1085         SNPRINTF='snprintf.o'
1086         INT64_FORMAT='"%lld"'
1087   ],
1088   [ AC_MSG_RESULT(assuming not on target machine)
1089         # Force usage of our own snprintf, since we cannot test foreign snprintf
1090         SNPRINTF='snprintf.o'
1091         INT64_FORMAT='"%lld"'
1092   ]) ],
1093   [ AC_MSG_RESULT(assuming not on target machine)
1094         # Force usage of our own snprintf, since we cannot test foreign snprintf
1095         SNPRINTF='snprintf.o'
1096         INT64_FORMAT='"%lld"'
1097   ])
1098   else
1099     # here if we previously decided we needed to use our own snprintf
1100     INT64_FORMAT='"%lld"'
1101   fi
1102 else
1103   # Here if we are not using 'long long int' at all
1104   INT64_FORMAT='"%ld"'
1105 fi
1106
1107 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1108                    [Define this as the appropriate snprintf format for 64-bit ints, if any])
1109
1110
1111 AC_CHECK_FUNCS([strtoll strtoq], [break])
1112 AC_CHECK_FUNCS([strtoull strtouq], [break])
1113
1114 # Check for one of atexit() or on_exit()
1115 AC_CHECK_FUNCS(atexit, [],
1116                [AC_CHECK_FUNCS(on_exit, [],
1117                                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1118
1119 dnl Need a #define for the size of Datum (unsigned long)
1120
1121 AC_CHECK_SIZEOF([unsigned long])
1122 AC_DEFINE_UNQUOTED(SIZEOF_DATUM, $ac_cv_sizeof_unsigned_long, [sizeof(Datum) -- don't change])
1123
1124 # Determine memory alignment requirements for the basic C data types.
1125
1126 PGAC_CHECK_ALIGNOF(short)
1127 PGAC_CHECK_ALIGNOF(int)
1128 PGAC_CHECK_ALIGNOF(long)
1129 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1130   PGAC_CHECK_ALIGNOF(long long int)
1131 fi
1132 PGAC_CHECK_ALIGNOF(double)
1133
1134 # Compute maximum alignment of any basic type.
1135 # We assume long's alignment is at least as strong as char, short, or int;
1136 # but we must check long long (if it exists) and double.
1137
1138 MAX_ALIGNOF=$pgac_cv_alignof_long
1139 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1140   MAX_ALIGNOF=$pgac_cv_alignof_double
1141 fi
1142 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1143   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1144 fi
1145 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any type])
1146
1147
1148 # Some platforms predefine the types int8, int16, etc.  Only check
1149 # a (hopefully) representative subset.
1150 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1151 [#include <stdio.h>
1152 #ifdef HAVE_SUPPORTDEFS_H
1153 #include <SupportDefs.h>
1154 #endif])
1155
1156 # We also check for sig_atomic_t, which *should* be defined per ANSI
1157 # C, but is missing on some old platforms.
1158 AC_CHECK_TYPES([sig_atomic_t], [], [], [#include <signal.h>])
1159
1160
1161 PGAC_FUNC_POSIX_SIGNALS
1162
1163
1164 if test "$enable_nls" = yes ; then
1165   PGAC_CHECK_GETTEXT
1166 fi
1167
1168 if test "$with_CXX" = yes; then
1169   PGAC_CLASS_STRING
1170   PGAC_CXX_NAMESPACE_STD
1171 fi
1172
1173
1174 # Check for Tcl configuration script tclConfig.sh
1175 if test "$with_tcl" = yes; then
1176     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1177 fi
1178
1179 # Check for Tk configuration script tkConfig.sh
1180 if test "$with_tk" = yes; then
1181     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1182 fi
1183
1184
1185 #
1186 # Check for DocBook and tools
1187 #
1188 PGAC_PROG_NSGMLS
1189 # If you don't have nsgmls you won't get very far, so save the cycles.
1190 if test -n "$NSGMLS"; then
1191   PGAC_PROG_JADE
1192   PGAC_CHECK_DOCBOOK([3.1])
1193   PGAC_PATH_DOCBOOK_STYLESHEETS
1194   AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1195 fi
1196
1197
1198 # prepare build tree if outside source tree
1199 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1200 # Note 2: /bin/pwd might be better than shell's built-in at getting
1201 #         a symlink-free name.
1202 if test "$no_create" != yes; then
1203   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1204     :
1205   else
1206     AC_SUBST(vpath_build, yes)
1207     _AS_ECHO_N([preparing build tree... ])
1208     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1209     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1210       || AC_MSG_ERROR(failed)
1211     AC_MSG_RESULT(done)
1212   fi
1213 fi
1214
1215
1216 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1217
1218 AC_CONFIG_LINKS([
1219   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1220   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1221   src/include/pg_config_os.h:src/include/port/${template}.h
1222   src/Makefile.port:src/makefiles/Makefile.${template}
1223 ])
1224
1225 AC_CONFIG_HEADERS([src/include/pg_config.h],
1226 [
1227 # Update timestamp for pg_config.h (see Makefile.global)
1228 echo >src/include/stamp-h
1229 ])
1230
1231 AC_OUTPUT