granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Header: /cvsroot/pgsql/configure.in,v 1.201 2002/09/02 16:14:01 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19 dnl
  20 dnl The GNU folks apparently haven't heard that some people don't use
  21 dnl Texinfo. Use this sorcery to use "docdir" instead of "infodir".
  22 m4_define([info], [doc])
  23 m4_define([infodir], [docdir])
  24 AC_INIT([PostgreSQL], [7.3devel], [pgsql-bugs@postgresql.org])
  25 m4_undefine([infodir])
  26 m4_undefine([info])
  27 AC_SUBST(docdir)
  28
  29 AC_PREREQ(2.53)
  30 AC_COPYRIGHT([Copyright 2002 PostgreSQL Global Development Group])
  31 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  32 AC_CONFIG_AUX_DIR(config)
  33 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  34 AC_SUBST(configure_args, [$ac_configure_args])
  35
  36 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  37
  38 AC_CANONICAL_HOST
  39
  40 template=
  41 AC_MSG_CHECKING([which template to use])
  42
  43 PGAC_ARG_REQ(with, template, [],
  44 [
  45   case $withval in
  46     list)   echo; ls "$srcdir/src/template"; exit;;
  47     *)      if test -f "$srcdir/src/template/$with_template" ; then
  48               template=$withval
  49             else
  50               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  51             fi;;
  52   esac
  53 ],
  54 [
  55   # --with-template not given
  56
  57 case $host_os in
  58      aix*) template=aix ;;
  59     beos*) template=beos ;;
  60     bsdi*) template=bsdi ;;
  61   cygwin*) template=win ;;
  62   darwin*) template=darwin ;;
  63     dgux*) template=dgux ;;
  64  freebsd*) template=freebsd ;;
  65     hpux*) template=hpux ;;
  66     irix*) template=irix5 ;;
  67    linux*) template=linux ;;
  68   netbsd*) template=netbsd ;;
  69 nextstep*) template=nextstep ;;
  70  openbsd*) template=openbsd ;;
  71      osf*) template=osf ;;
  72      qnx*) template=qnx4 ;;
  73      sco*) template=sco ;;
  74  solaris*) template=solaris ;;
  75    sunos*) template=sunos4 ;;
  76  sysv4.2*)
  77         case $host_vendor in
  78           univel) template=univel ;;
  79         esac ;;
  80    sysv4*) template=svr4 ;;
  81    sysv5*) template=unixware ;;
  82   ultrix*) template=ultrix4 ;;
  83 esac
  84
  85   if test x"$template" = x"" ; then
  86     AC_MSG_ERROR([[
  87 *******************************************************************
  88 PostgreSQL has apparently not been ported to your platform yet.
  89 To try a manual configuration, look into the src/template directory
  90 for a similar platform and use the '--with-template=' option.
  91
  92 Please also contact <pgsql-ports@postgresql.org> to see about
  93 rectifying this.  Include the above 'checking host system type...'
  94 line.
  95 *******************************************************************
  96 ]])
  97   fi
  98
  99 ])
 100
 101 AC_MSG_RESULT([$template])
 102
 103 PORTNAME=$template
 104 AC_SUBST(PORTNAME)
 105
 106 # Pick right test-and-set (TAS) code.  Most platforms have inline
 107 # assembler code in src/include/storage/s_lock.h, so we just use
 108 # a dummy file here.
 109 case $host in
 110   *-*-hpux*)        need_tas=yes; tas_file=hpux.s ;;
 111   sparc-*-solaris*) need_tas=yes; tas_file=solaris_sparc.s ;;
 112   i?86-*-solaris*)   need_tas=yes; tas_file=solaris_i386.s ;;
 113   *)                need_tas=no;  tas_file=dummy.s ;;
 114 esac
 115 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 116
 117 if test "$need_tas" = yes ; then
 118   TAS=tas.o
 119 fi
 120 AC_SUBST(TAS)
 121
 122
 123
 124 ##
 125 ## Command line options
 126 ##
 127
 128
 129 #
 130 # Add non-standard directories to the include path
 131 #
 132 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 133
 134
 135 #
 136 # Add non-standard directories to the library search path
 137 #
 138 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 139              [LIBRARY_DIRS=$withval])
 140
 141 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 142              [LIBRARY_DIRS=$withval])
 143
 144
 145 #
 146 # 64-bit integer date/time storage (--enable-integer-datetimes)
 147 #
 148 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 149 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 150               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 151                          [Set to 1 if you want integer date/time support (--enable-integer-datetimes)])])
 152 AC_MSG_RESULT([$enable_integer_datetimes])
 153
 154
 155 # Character set recode (--enable-recode)
 156 #
 157 AC_MSG_CHECKING([whether to build with recode support])
 158 PGAC_ARG_BOOL(enable, recode, no, [  --enable-recode         enable character set recode support],
 159               [AC_DEFINE([CYR_RECODE], 1,
 160                          [Set to 1 if you want cyrillic recode support (--enable-recode)])])
 161 AC_MSG_RESULT([$enable_recode])
 162
 163
 164 #
 165 # Multibyte support
 166 #
 167 MULTIBYTE=SQL_ASCII
 168 AC_DEFINE(MULTIBYTE, 1, [Set to 1 if you want to use multibyte characters (--enable-multibyte)])
 169 AC_SUBST(MULTIBYTE)
 170
 171 #
 172 # NLS
 173 #
 174 AC_MSG_CHECKING([whether NLS is wanted])
 175 PGAC_ARG_OPTARG(enable, nls,
 176                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 177                 [],
 178                 [WANTED_LANGUAGES=$enableval],
 179                 [AC_DEFINE(ENABLE_NLS, 1,
 180                            [Define to 1 if you want National Language Support (--enable-nls)])])
 181 AC_MSG_RESULT([$enable_nls])
 182 AC_SUBST(enable_nls)
 183 AC_SUBST(WANTED_LANGUAGES)
 184
 185 #
 186 # Default port number (--with-pgport), default 5432
 187 #
 188 AC_MSG_CHECKING([for default port number])
 189 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 190              [default_port=$withval],
 191              [default_port=5432])
 192 AC_MSG_RESULT([$default_port])
 193 # Need both of these because some places want an integer and some a string
 194 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 195 [The default TCP port number on which the server listens and to which
 196 clients will try to connect to.  This can be overridden at run-time,
 197 but it's convenient if your clients have the right default compiled in.
 198 (--with-pgport=PORTNUM)])
 199 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 200                    [Default TCP port number as string constant])
 201 AC_SUBST(default_port)
 202
 203 #
 204 # Maximum number of allowed connections (--with-maxbackends), default 32
 205 #
 206 AC_MSG_CHECKING([for default soft limit on number of connections])
 207 PGAC_ARG_REQ(with, maxbackends, [  --with-maxbackends=N    set default maximum number of connections [32]],
 208              [],
 209              [with_maxbackends=32])
 210 AC_MSG_RESULT([$with_maxbackends])
 211 AC_DEFINE_UNQUOTED([DEF_MAXBACKENDS], [$with_maxbackends],
 212                    [The default soft limit on the number of concurrent connections, i.e., the default for the postmaster -N switch (--with-maxbackends)])
 213
 214
 215 #
 216 # Option to disable shared libraries
 217 #
 218 PGAC_ARG_BOOL(enable, shared, yes,
 219               [  --disable-shared        do not build shared libraries])
 220 AC_SUBST(enable_shared)
 221
 222 #
 223 # '-rpath'-like feature can be disabled
 224 #
 225 PGAC_ARG_BOOL(enable, rpath, yes,
 226               [  --disable-rpath         do not embed shared library search path in executables])
 227 AC_SUBST(enable_rpath)
 228
 229
 230 #
 231 # --enable-debug adds -g to compiler flags
 232 #
 233 PGAC_ARG_BOOL(enable, debug, no,
 234               [  --enable-debug          build with debugging symbols (-g)])
 235 AC_SUBST(enable_debug)
 236
 237 #
 238 # C compiler
 239 #
 240
 241 # For historical reasons you can also use --with-CC to specify the C compiler
 242 # to use, although the standard way to do this is to set the CC environment
 243 # variable.
 244 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 245
 246 case $template in
 247   aix) pgac_cc_list="gcc xlc";;
 248  irix) pgac_cc_list="cc";; # no gcc
 249     *) pgac_cc_list="gcc cc";;
 250 esac
 251
 252 AC_PROG_CC([$pgac_cc_list])
 253 # Read the template
 254 . "$srcdir/src/template/$template" || exit
 255
 256 if test "$ac_env_CFLAGS_set" = set; then
 257   CFLAGS=$ac_env_CFLAGS_value
 258 fi
 259 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 260   CFLAGS="$CFLAGS -g"
 261 fi
 262 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 263 # Check if the compiler still works with the template settings
 264 AC_MSG_CHECKING([whether the C compiler still works])
 265 AC_TRY_LINK([], [return 0;],
 266   [AC_MSG_RESULT(yes)],
 267   [AC_MSG_RESULT(no)
 268    AC_MSG_ERROR([cannot proceed])])
 269 AC_PROG_CPP
 270 AC_SUBST(GCC)
 271
 272 # Create compiler version string
 273 if test x"$GCC" = x"yes" ; then
 274   cc_string="GCC `${CC} --version | sed q`"
 275 else
 276   cc_string=$CC
 277 fi
 278 AC_DEFINE_UNQUOTED(PG_VERSION_STR, ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"], [A canonical string containing the version number, platform, and C compiler])
 279
 280
 281 #
 282 # Automatic dependency tracking
 283 #
 284 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 285               [autodepend=yes])
 286 AC_SUBST(autodepend)
 287
 288
 289 #
 290 # Enable assert checks
 291 #
 292 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 293               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 294                          [Define to 1 to build with assertion checks])])
 295
 296
 297 #
 298 # Include directories
 299 #
 300 ac_save_IFS=$IFS
 301 IFS="${IFS}:"
 302 # SRCH_INC comes from the template file
 303 for dir in $with_includes $SRCH_INC; do
 304   if test -d "$dir"; then
 305     INCLUDES="$INCLUDES -I$dir"
 306   else
 307     AC_MSG_WARN([*** Include directory $dir does not exist.])
 308   fi
 309 done
 310 IFS=$ac_save_IFS
 311 AC_SUBST(INCLUDES)
 312
 313
 314 #
 315 # Library directories
 316 #
 317 ac_save_IFS=$IFS
 318 IFS="${IFS}:"
 319 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 320 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 321   if test -d "$dir"; then
 322     LIBDIRS="$LIBDIRS -L$dir"
 323   else
 324     AC_MSG_WARN([*** Library directory $dir does not exist.])
 325   fi
 326 done
 327 IFS=$ac_save_IFS
 328
 329
 330 #
 331 # Tcl/Tk
 332 #
 333 AC_MSG_CHECKING([whether to build with Tcl])
 334 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl and Tk interfaces])
 335 AC_MSG_RESULT([$with_tcl])
 336 AC_SUBST([with_tcl])
 337
 338 # If Tcl is enabled (above) then Tk is also, unless the user disables it using --without-tk
 339 AC_MSG_CHECKING([whether to build with Tk])
 340 if test "$with_tcl" = yes; then
 341   PGAC_ARG_BOOL(with, tk, yes, [  --without-tk            do not build Tk interfaces if Tcl is enabled])
 342 else
 343   with_tk=no
 344 fi
 345 AC_MSG_RESULT([$with_tk])
 346 AC_SUBST([with_tk])
 347
 348
 349 # We see if the path to the Tcl/Tk configuration scripts is specified.
 350 # This will override the use of tclsh to find the paths to search.
 351
 352 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh and tkConfig.sh are in DIR])
 353
 354 # We see if the path to the Tk configuration scripts is specified.
 355 # This will override the use of tclsh to find the paths to search.
 356
 357 PGAC_ARG_REQ(with, tkconfig,  [  --with-tkconfig=DIR     tkConfig.sh is in DIR])
 358
 359 #
 360 # Optionally build Perl modules (Pg.pm and PL/Perl)
 361 #
 362 AC_MSG_CHECKING([whether to build Perl modules])
 363 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build PL/Perl])
 364 AC_MSG_RESULT([$with_perl])
 365 AC_SUBST(with_perl)
 366
 367 #
 368 # Optionally build Python interface module
 369 #
 370 AC_MSG_CHECKING([whether to build Python modules])
 371 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python interface module])
 372 AC_MSG_RESULT([$with_python])
 373 AC_SUBST(with_python)
 374
 375 #
 376 # Optionally build the Java/JDBC tools
 377 #
 378 AC_MSG_CHECKING([whether to build Java/JDBC tools])
 379 PGAC_ARG_BOOL(with, java, no, [  --with-java             build JDBC interface and Java tools],
 380 [AC_MSG_RESULT(yes)
 381 PGAC_PATH_ANT
 382 if test -z "$ANT"; then
 383   AC_MSG_ERROR([Ant is required to build Java components])
 384 fi
 385 if "$ANT" -version | sed q | egrep -v ' 1\.[[5-9]]| [[2-9]]\.' >/dev/null ; then
 386   AC_MSG_ERROR([Ant version >= 1.5 is required to build Java components])
 387 fi],
 388 [AC_MSG_RESULT(no)])
 389 AC_SUBST(with_java)
 390
 391 dnl A note on the Kerberos and OpenSSL options:
 392 dnl
 393 dnl The user can give an argument to the option in order the specify
 394 dnl the base path of the respective installation (what he specified
 395 dnl perhaps as --prefix). If no argument is given ($withval is "yes")
 396 dnl then we take the path where the package installs by default. This
 397 dnl way the user doesn't have to use redundant --with-includes and
 398 dnl --with-libraries options, but he can still use them if the layout
 399 dnl is non-standard.
 400
 401 #
 402 # Kerberos 4
 403 #
 404 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 405 PGAC_ARG_OPTARG(with, krb4, [[  --with-krb4[=DIR]       build with Kerberos 4 support [/usr/athena]]],
 406                 [krb4_prefix=/usr/athena],
 407                 [krb4_prefix=$withval],
 408 [
 409   AC_MSG_RESULT(yes)
 410   AC_DEFINE(KRB4, 1, [Define if you are building with Kerberos 4 support.])
 411
 412   if test -d "$krb4_prefix/include"; then
 413     INCLUDES="$INCLUDES -I$krb4_prefix/include"
 414   fi
 415   if test -d "$krb4_prefix/lib"; then
 416     LIBDIRS="$LIBDIRS -L$krb4_prefix/lib"
 417   fi
 418
 419   krb_srvtab="/etc/srvtab"
 420 ],
 421 [AC_MSG_RESULT(no)])
 422
 423 AC_SUBST(with_krb4)
 424
 425
 426 #
 427 # Kerberos 5
 428 #
 429 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 430 PGAC_ARG_OPTARG(with, krb5, [[  --with-krb5[=DIR]       build with Kerberos 5 support [/usr/athena]]],
 431               [krb5_prefix=/usr/athena],
 432               [krb5_prefix=$withval],
 433 [
 434   AC_MSG_RESULT([yes])
 435   AC_DEFINE(KRB5, 1, [Define if you are building with Kerberos 5 support.])
 436
 437   if test -d "$krb5_prefix/include"; then
 438     INCLUDES="$INCLUDES -I$krb5_prefix/include"
 439   fi
 440   if test -d "$krb5_prefix/lib"; then
 441     LIBDIRS="$LIBDIRS -L$krb5_prefix/lib"
 442   fi
 443
 444   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 445 ],
 446 [AC_MSG_RESULT(no)])
 447
 448 AC_SUBST(with_krb5)
 449
 450
 451 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 452 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 453   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 454 fi
 455
 456 AC_SUBST(krb_srvtab)
 457
 458
 459 #
 460 # Kerberos configuration parameters
 461 #
 462 PGAC_ARG_REQ(with, krb-srvnam,
 463              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [postgres]],
 464              [],
 465              [with_krb_srvnam="postgres"])
 466 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 467                    [The name of the PostgreSQL service principal in Kerberos])
 468
 469
 470 #
 471 # PAM
 472 #
 473 AC_MSG_CHECKING([whether to build with PAM support])
 474 PGAC_ARG_BOOL(with, pam, no,
 475               [  --with-pam              build with PAM support],
 476               [AC_DEFINE([USE_PAM], 1, [Define to build with PAM support])])
 477 AC_MSG_RESULT([$with_pam])
 478 AC_SUBST(with_pam)
 479
 480
 481 #
 482 # OpenSSL
 483 #
 484 PGAC_ARG_OPTARG(with, openssl,
 485                 [[  --with-openssl[=DIR]    build with OpenSSL support [/usr/local/ssl]]],
 486                 [openssl_prefix=/usr/local/ssl],
 487                 [openssl_prefix=$withval],
 488 [
 489   AC_MSG_RESULT([building with OpenSSL support])
 490   AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support])
 491
 492   if test -d "${openssl_prefix}/include" ; then
 493     INCLUDES="$INCLUDES -I${openssl_prefix}/include"
 494   fi
 495   if test -d "${openssl_prefix}/lib" ; then
 496     LIBDIRS="$LIBDIRS -L${openssl_prefix}/lib"
 497   fi
 498 ])
 499
 500 AC_SUBST(with_openssl)
 501
 502
 503 #
 504 # Readline
 505 #
 506 PGAC_ARG_BOOL(with, readline, yes,
 507               [  --without-readline      do not use Readline])
 508
 509 #
 510 # Zlib
 511 #
 512 PGAC_ARG_BOOL(with, zlib, yes,
 513               [  --without-zlib          do not use Zlib])
 514
 515
 516
 517 # Assume system is ELF if it predefines __ELF__ as 1,
 518 # otherwise believe host_os based default.
 519 case $host_os in
 520     freebsd1*|freebsd2*) elf=no;;
 521     freebsd3*|freebsd4*) elf=yes;;
 522 esac
 523
 524 AC_EGREP_CPP(yes,
 525 [#if __ELF__
 526   yes
 527 #endif
 528 ],
 529 [ELF_SYS=true],
 530 [if test "X$elf" = "Xyes" ; then
 531   ELF_SYS=true
 532 else
 533   ELF_SYS=
 534 fi])
 535 AC_SUBST(ELF_SYS)
 536
 537
 538
 539 CPPFLAGS="$CPPFLAGS $INCLUDES"
 540 LDFLAGS="$LDFLAGS $LIBDIRS"
 541
 542 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 543 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 544
 545
 546 AC_PROG_AWK
 547 PGAC_PATH_FLEX
 548 AC_PROG_LN_S
 549 AC_PROG_LD
 550 AC_SUBST(LD)
 551 AC_SUBST(with_gnu_ld)
 552 case $host_os in sysv5*)
 553   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 554   [
 555     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 556     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 557     LDFLAGS=$pgac_save_LDFLAGS
 558   ])
 559   ld_R_works=$pgac_cv_prog_ld_R
 560   AC_SUBST(ld_R_works)
 561 esac
 562 AC_PROG_RANLIB
 563 AC_CHECK_PROGS(LORDER, lorder)
 564 AC_PATH_PROG(TAR, tar)
 565 PGAC_CHECK_STRIP
 566
 567 AC_CHECK_PROGS(YACC, ['bison -y'])
 568 if test -z "$YACC"; then
 569   AC_MSG_WARN([
 570 *** Without Bison you will not be able to build PostgreSQL from CVS or
 571 *** change any of the parser definition files.  You can obtain Bison from
 572 *** a GNU mirror site.  (If you are using the official distribution of
 573 *** PostgreSQL then you do not need to worry about this because the Bison
 574 *** output is pre-generated.)  To use a different yacc program (possible,
 575 *** but not recommended), set the environment variable YACC before running
 576 *** 'configure'.])
 577 fi
 578 AC_SUBST(YFLAGS)
 579
 580 if test "$with_tk" = yes; then
 581     AC_PATH_PROG(WISH, wish)
 582     test -z "$WISH" && AC_MSG_ERROR(['wish' is required for Tk support])
 583 fi
 584
 585 PGAC_PATH_PERL
 586 if test "$with_perl" = yes; then
 587   PGAC_CHECK_PERL_CONFIGS([installsitearch,installman3dir,
 588                            archlibexp,privlibexp,useshrplib,man3ext])
 589   PGAC_CHECK_PERL_EMBED_LDFLAGS
 590 fi
 591
 592 if test "$with_python" = yes; then
 593   PGAC_PATH_PYTHON
 594   PGAC_CHECK_PYTHON_MODULE_SETUP
 595   PGAC_CHECK_PYTHON_EMBED_SETUP
 596 fi
 597
 598
 599 ##
 600 ## Libraries
 601 ##
 602
 603 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 604 then
 605         AC_CHECK_LIB(bsd,      main)
 606 fi
 607 AC_CHECK_LIB(util,     setproctitle)
 608 AC_CHECK_LIB(m,        main)
 609 AC_CHECK_LIB(dl,       main)
 610 AC_CHECK_LIB(nsl,      main)
 611 AC_CHECK_LIB(socket,   main)
 612 AC_CHECK_LIB(ipc,      main)
 613 AC_CHECK_LIB(IPC,      main)
 614 AC_CHECK_LIB(lc,       main)
 615 AC_CHECK_LIB(dld,      main)
 616 AC_CHECK_LIB(ld,       main)
 617 AC_CHECK_LIB(compat,   main)
 618 AC_CHECK_LIB(BSD,      main)
 619 AC_CHECK_LIB(gen,      main)
 620 AC_CHECK_LIB(PW,       main)
 621 AC_CHECK_LIB(resolv,   main)
 622 AC_SEARCH_LIBS(getopt_long, [getopt])
 623 # QNX:
 624 AC_CHECK_LIB([[unix]], main)
 625 AC_SEARCH_LIBS(crypt,  crypt)
 626 # BeOS:
 627 AC_CHECK_LIB(bind,     __inet_ntoa)
 628 # Solaris:
 629 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 630
 631 if test "$with_readline" = yes; then
 632   PGAC_CHECK_READLINE
 633   if test x"$pgac_cv_check_readline" = x"no"; then
 634     AC_MSG_ERROR([readline library not found
 635 Use --without-readline to disable readline support.])
 636   fi
 637 fi
 638
 639 if test "$with_zlib" = yes; then
 640   AC_CHECK_LIB(z, inflate, [],
 641                [AC_MSG_ERROR([zlib library not found
 642 Use --without-zlib to disable zlib support.])])
 643 fi
 644
 645 if test "$with_krb4" = yes ; then
 646   AC_CHECK_LIB(des, [des_encrypt], [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 647   AC_CHECK_LIB(krb, [krb_sendauth], [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 648 fi
 649
 650 if test "$with_krb5" = yes ; then
 651   AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 652                  [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 653   AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 654                  [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 655   AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 656                  [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 657 fi
 658
 659 if test "$with_openssl" = yes ; then
 660   dnl Order matters!
 661   AC_CHECK_LIB(crypto, [CRYPTO_new_ex_data], [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 662   AC_CHECK_LIB(ssl,    [SSL_library_init], [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 663 fi
 664
 665 if test "$with_pam" = yes ; then
 666   AC_CHECK_LIB(pam,    [pam_start], [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 667 fi
 668
 669
 670 ##
 671 ## Header files
 672 ##
 673
 674 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 675 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h pwd.h sys/ipc.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/un.h termios.h kernel/OS.h kernel/image.h SupportDefs.h])
 676
 677 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 678 # netinet/in.h is included first.
 679 AC_CHECK_HEADERS([netinet/in.h])
 680 AC_CHECK_HEADERS([netinet/tcp.h], [], [],
 681 [AC_INCLUDES_DEFAULT
 682 #ifdef HAVE_NETINET_IN_H
 683 #include <netinet/in.h>
 684 #endif
 685 ])
 686
 687 if test "$with_readline" = yes; then
 688   AC_CHECK_HEADERS([readline/readline.h], [],
 689                    [AC_CHECK_HEADERS([readline.h], [],
 690                                      [AC_MSG_ERROR([readline header not found
 691 Use --without-readline to disable readline support.])])])
 692   AC_CHECK_HEADERS([readline/history.h], [],
 693                    [AC_CHECK_HEADERS([history.h], [],
 694                                      [AC_MSG_ERROR([history header not found
 695 Use --without-readline to disable readline support.])])])
 696 fi
 697
 698 if test "$with_zlib" = yes; then
 699   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 700 Use --without-zlib to disable zlib support.])])
 701 fi
 702
 703 if test "$with_krb4" = yes ; then
 704   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 705 fi
 706
 707 if test "$with_krb5" = yes ; then
 708   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 709   AC_CHECK_HEADER(com_err.h, [], [AC_MSG_ERROR([header file <com_err.h> is required for Kerberos 5])])
 710 fi
 711
 712 if test "$with_openssl" = yes ; then
 713   AC_CHECK_HEADER([openssl/ssl.h], [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 714   AC_CHECK_HEADER([openssl/err.h], [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 715 fi
 716
 717 if test "$with_pam" = yes ; then
 718   AC_CHECK_HEADER([security/pam_appl.h], [], [AC_MSG_ERROR([header file <security/pam_appl.h> is required for PAM])])
 719 fi
 720
 721
 722 ##
 723 ## Types, structures, compiler characteristics
 724 ##
 725
 726 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 727 AC_C_CONST
 728 AC_C_INLINE
 729 AC_C_STRINGIZE
 730 PGAC_C_SIGNED
 731 AC_C_VOLATILE
 732 AC_STRUCT_TIMEZONE
 733 PGAC_UNION_SEMUN
 734 PGAC_STRUCT_SOCKADDR_UN
 735
 736 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 737 [#include <sys/param.h>
 738 #include <sys/socket.h>
 739 #include <sys/ucred.h>])
 740
 741 if test "$with_zlib" = yes; then
 742   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 743   # did not).  While we could work around the lack of z_streamp, it
 744   # seems unwise to encourage people to use such old zlib versions...
 745   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 746 Use --without-zlib to disable zlib support.])],
 747                 [#include <zlib.h>])
 748 fi
 749
 750 if test "$with_krb5" = yes; then
 751 # Check for differences between MIT and Heimdal (KTH) releases
 752   AC_CHECK_MEMBERS([krb5_ticket.enc_part2], [],
 753                    [AC_CHECK_MEMBERS([krb5_ticket.client], [],
 754                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 755                                      [#include <krb5.h>])],
 756                    [#include <krb5.h>])
 757   AC_CHECK_MEMBERS([krb5_error.text.data], [],
 758                    [AC_CHECK_MEMBER([krb5_error.e_data], [],
 759                                     [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 760                                     [#include <krb5.h>])],
 761                    [#include <krb5.h>])
 762 fi
 763
 764
 765 ##
 766 ## Functions, global variables
 767 ##
 768
 769 PGAC_VAR_INT_TIMEZONE
 770 AC_FUNC_ACCEPT_ARGTYPES
 771 PGAC_FUNC_GETTIMEOFDAY_1ARG
 772
 773 # SunOS doesn't handle negative byte comparisons properly with +/- return
 774 AC_FUNC_MEMCMP
 775
 776 AC_CHECK_FUNCS([cbrt fcvt getopt_long memmove pstat setproctitle setsid sigprocmask sysconf waitpid dlopen fdatasync])
 777
 778 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 779
 780 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 781 [AC_TRY_LINK(
 782 [#include <machine/vmparam.h>
 783 #include <sys/exec.h>
 784 ],
 785 [PS_STRINGS->ps_nargvstr = 1;
 786 PS_STRINGS->ps_argvstr = "foo";],
 787 [pgac_cv_var_PS_STRINGS=yes],
 788 [pgac_cv_var_PS_STRINGS=no])])
 789 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 790   AC_DEFINE([HAVE_PS_STRINGS], [], [Define if the PS_STRINGS thing exists.])
 791 fi
 792
 793
 794 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 795 # is missing.  Yes, there are machines that have only one.  We may
 796 # also decide to use snprintf.c if snprintf() is present but does not
 797 # have working "long long int" support -- see below.
 798
 799 pgac_need_repl_snprintf=no
 800 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 801 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 802
 803
 804 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 805 # include/c.h will provide declarations.  Note this is a separate test
 806 # from whether the functions exist in the C library --- there are
 807 # systems that have the functions but don't bother to declare them :-(
 808
 809 AC_CHECK_DECLS([snprintf, vsnprintf])
 810
 811
 812 # do this one the hard way in case isinf() is a macro
 813 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 814 [AC_TRY_LINK(
 815 [#include <math.h>
 816 ],
 817 [double x = 0.0; int res = isinf(x);],
 818 [ac_cv_func_isinf=yes],
 819 [ac_cv_func_isinf=no])])
 820
 821 if test $ac_cv_func_isinf = yes ; then
 822   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf()])
 823 else
 824   AC_LIBOBJ(isinf)
 825   # Look for a way to implement a substitute for isinf()
 826   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 827 fi
 828
 829 AC_REPLACE_FUNCS([gethostname getrusage inet_aton random srandom strcasecmp strdup strerror strtol strtoul])
 830
 831 # Solaris has a very slow qsort in certain cases.
 832 case $host_os in
 833   solaris*) AC_LIBOBJ(qsort) ;;
 834 esac
 835
 836 # On HPUX 9, rint() is not in regular libm.a but in /lib/pa1.1/libm.a;
 837 # this hackery with HPUXMATHLIB allows us to cope.
 838 HPUXMATHLIB=""
 839 case $host_cpu in
 840   hppa1.1)
 841         if test -r /lib/pa1.1/libm.a ; then
 842             HPUXMATHLIB="-L /lib/pa1.1 -lm"
 843         fi ;;
 844 esac
 845 AC_SUBST(HPUXMATHLIB)
 846
 847 AC_CHECK_FUNCS(rint, [],
 848                [AC_CHECK_LIB(m, rint, AC_DEFINE(HAVE_RINT), , $HPUXMATHLIB)])
 849
 850
 851 if test "$with_readline" = yes; then
 852   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 853   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 854 fi
 855
 856
 857 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 858 AC_MSG_CHECKING(for finite)
 859 AC_TRY_LINK([#include <math.h>],
 860             [int dummy=finite(1.0);],
 861             [AC_DEFINE(HAVE_FINITE, 1, [Set to 1 if you have finite()])
 862 AC_MSG_RESULT(yes)],
 863             [AC_MSG_RESULT(no)])
 864
 865 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 866 dnl (especially on GNU libc)
 867 dnl See also comments in pg_config.h.
 868 AC_MSG_CHECKING(for sigsetjmp)
 869 AC_TRY_LINK([#include <setjmp.h>],
 870             [sigjmp_buf x; sigsetjmp(x, 1);],
 871             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Set to 1 if you have sigsetjmp()])
 872 AC_MSG_RESULT(yes)],
 873             [AC_MSG_RESULT(no)])
 874
 875 AC_CHECK_FUNC(syslog,
 876              [AC_CHECK_HEADER(syslog.h,
 877              [AC_DEFINE(HAVE_SYSLOG, 1, [])],
 878              [])])
 879
 880 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
 881 [AC_TRY_LINK([#include <unistd.h>],
 882   [extern int optreset; optreset = 1;],
 883   [pgac_cv_var_int_optreset=yes],
 884   [pgac_cv_var_int_optreset=no])])
 885 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
 886   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'])
 887 fi
 888
 889 AC_CHECK_FUNCS([strtoll strtoq], [break])
 890 AC_CHECK_FUNCS([strtoull strtouq], [break])
 891
 892 # Check for one of atexit() or on_exit()
 893 AC_CHECK_FUNCS(atexit, [],
 894                [AC_CHECK_FUNCS(on_exit, [],
 895                                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
 896
 897 AC_FUNC_FSEEKO
 898
 899
 900 # This test makes sure that run tests work at all.  Sometimes a shared
 901 # library is found by the linker, but the runtime linker can't find it.
 902 # This check should come after all modifications of compiler or linker
 903 # variables, and before any other run tests.
 904 AC_MSG_CHECKING([test program])
 905 AC_TRY_RUN([int main() { return 0; }],
 906 [AC_MSG_RESULT(ok)],
 907 [AC_MSG_RESULT(failed)
 908 AC_MSG_ERROR([[
 909 *** Could not execute a simple test program.  This may be a problem
 910 *** related to locating shared libraries.  Check the file 'config.log'
 911 *** for the exact reason.]])],
 912 [AC_MSG_RESULT([cross-compiling])])
 913
 914
 915 dnl Check to see if we have a working 64-bit integer type.
 916 dnl This breaks down into two steps:
 917 dnl (1) figure out if the compiler has a 64-bit int type with working
 918 dnl arithmetic, and if so
 919 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
 920 dnl snprintf is the only library routine we really need for int8 support.)
 921 dnl It's entirely possible to have a compiler that handles a 64-bit type
 922 dnl when the C library doesn't; this is fairly likely when using gcc on
 923 dnl an older platform, for example.
 924 dnl If there is no native snprintf() or it does not handle the 64-bit type,
 925 dnl we force our own version of snprintf() to be used instead.
 926 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
 927
 928 PGAC_TYPE_64BIT_INT([long int])
 929
 930 if test x"$HAVE_LONG_INT_64" = x"no" ; then
 931   PGAC_TYPE_64BIT_INT([long long int])
 932 fi
 933
 934
 935 dnl If we need to use "long long int", figure out whether nnnLL notation works.
 936
 937 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
 938   AC_TRY_COMPILE([
 939 #define INT64CONST(x)  x##LL
 940 long long int foo = INT64CONST(0x1234567890123456);
 941 ],
 942         [],
 943         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define if you have LL constants])],
 944         [])
 945 fi
 946
 947
 948 dnl If we found "long int" is 64 bits, assume snprintf handles it.
 949 dnl If we found we need to use "long long int", better check.
 950 dnl We cope with snprintfs that use either %lld or %qd as the format.
 951 dnl If neither works, fall back to our own snprintf emulation (which we
 952 dnl know uses %lld).
 953
 954 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
 955   if test $pgac_need_repl_snprintf = no; then
 956     AC_MSG_CHECKING(whether snprintf handles 'long long int' as %lld)
 957     AC_TRY_RUN([#include <stdio.h>
 958 typedef long long int int64;
 959 #define INT64_FORMAT "%lld"
 960
 961 int64 a = 20000001;
 962 int64 b = 40000005;
 963
 964 int does_int64_snprintf_work()
 965 {
 966   int64 c;
 967   char buf[100];
 968
 969   if (sizeof(int64) != 8)
 970     return 0;                   /* doesn't look like the right size */
 971
 972   c = a * b;
 973   snprintf(buf, 100, INT64_FORMAT, c);
 974   if (strcmp(buf, "800000140000005") != 0)
 975     return 0;                   /* either multiply or snprintf is busted */
 976   return 1;
 977 }
 978 main() {
 979   exit(! does_int64_snprintf_work());
 980 }],
 981         [ AC_MSG_RESULT(yes)
 982           INT64_FORMAT='"%lld"'
 983         ],
 984   [ AC_MSG_RESULT(no)
 985     AC_MSG_CHECKING(whether snprintf handles 'long long int' as %qd)
 986     AC_TRY_RUN([#include <stdio.h>
 987 typedef long long int int64;
 988 #define INT64_FORMAT "%qd"
 989
 990 int64 a = 20000001;
 991 int64 b = 40000005;
 992
 993 int does_int64_snprintf_work()
 994 {
 995   int64 c;
 996   char buf[100];
 997
 998   if (sizeof(int64) != 8)
 999     return 0;     /* doesn't look like the right size */
1000
1001   c = a * b;
1002   snprintf(buf, 100, INT64_FORMAT, c);
1003   if (strcmp(buf, "800000140000005") != 0)
1004     return 0;     /* either multiply or snprintf is busted */
1005   return 1;
1006 }
1007 main() {
1008   exit(! does_int64_snprintf_work());
1009 }],
1010   [ AC_MSG_RESULT(yes)
1011     INT64_FORMAT='"%qd"'
1012   ],
1013   [ AC_MSG_RESULT(no)
1014         # Force usage of our own snprintf, since system snprintf is broken
1015         pgac_need_repl_snprintf=yes
1016         INT64_FORMAT='"%lld"'
1017   ],
1018   [ AC_MSG_RESULT([cannot test (not on host machine)])
1019         # Force usage of our own snprintf, since we cannot test foreign snprintf
1020         pgac_need_repl_snprintf=yes
1021         INT64_FORMAT='"%lld"'
1022   ]) ],
1023   [ AC_MSG_RESULT([cannot test (not on host machine)])
1024         # Force usage of our own snprintf, since we cannot test foreign snprintf
1025         pgac_need_repl_snprintf=yes
1026         INT64_FORMAT='"%lld"'
1027   ])
1028   else
1029     # here if we previously decided we needed to use our own snprintf
1030     INT64_FORMAT='"%lld"'
1031   fi
1032 else
1033   # Here if we are not using 'long long int' at all
1034   INT64_FORMAT='"%ld"'
1035 fi
1036
1037 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1038                    [Define this as the appropriate snprintf format for 64-bit ints, if any])
1039
1040 if test $pgac_need_repl_snprintf = yes; then
1041   AC_LIBOBJ(snprintf)
1042 fi
1043
1044 dnl Need a #define for the size of Datum (unsigned long)
1045
1046 AC_CHECK_SIZEOF([unsigned long])
1047 AC_DEFINE_UNQUOTED(SIZEOF_DATUM, $ac_cv_sizeof_unsigned_long, [sizeof(Datum) -- don't change])
1048
1049 # Determine memory alignment requirements for the basic C data types.
1050
1051 PGAC_CHECK_ALIGNOF(short)
1052 PGAC_CHECK_ALIGNOF(int)
1053 PGAC_CHECK_ALIGNOF(long)
1054 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1055   PGAC_CHECK_ALIGNOF(long long int)
1056 fi
1057 PGAC_CHECK_ALIGNOF(double)
1058
1059 # Compute maximum alignment of any basic type.
1060 # We assume long's alignment is at least as strong as char, short, or int;
1061 # but we must check long long (if it exists) and double.
1062
1063 MAX_ALIGNOF=$pgac_cv_alignof_long
1064 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1065   MAX_ALIGNOF=$pgac_cv_alignof_double
1066 fi
1067 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1068   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1069 fi
1070 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any type])
1071
1072
1073 # Some platforms predefine the types int8, int16, etc.  Only check
1074 # a (hopefully) representative subset.
1075 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1076 [#include <stdio.h>
1077 #ifdef HAVE_SUPPORTDEFS_H
1078 #include <SupportDefs.h>
1079 #endif])
1080
1081 # We also check for sig_atomic_t, which *should* be defined per ANSI
1082 # C, but is missing on some old platforms.
1083 AC_CHECK_TYPES([sig_atomic_t], [], [], [#include <signal.h>])
1084
1085
1086 PGAC_FUNC_POSIX_SIGNALS
1087 if test $ac_cv_func_fseeko = yes; then
1088 AC_SYS_LARGEFILE
1089 fi
1090
1091
1092 # Select semaphore implementation type.
1093 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1094   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores])
1095   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1096 else
1097   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1098     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores])
1099     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1100   else
1101     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores])
1102     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1103   fi
1104 fi
1105
1106
1107 # Select shared-memory implementation type.
1108 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory])
1109 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1110
1111
1112 if test "$enable_nls" = yes ; then
1113   PGAC_CHECK_GETTEXT
1114 fi
1115
1116 # Check for Tcl configuration script tclConfig.sh
1117 if test "$with_tcl" = yes; then
1118     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1119     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1120                           [TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1121     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1122 fi
1123
1124 # Check for Tk configuration script tkConfig.sh
1125 if test "$with_tk" = yes; then
1126     PGAC_PATH_TKCONFIGSH([$with_tkconfig $with_tclconfig])
1127     PGAC_EVAL_TCLCONFIGSH([$TK_CONFIG_SH], [TK_LIBS,TK_LIB_SPEC,TK_XINCLUDES])
1128 fi
1129
1130
1131 #
1132 # Check for DocBook and tools
1133 #
1134 PGAC_PROG_NSGMLS
1135 PGAC_PROG_JADE
1136 PGAC_CHECK_DOCBOOK([3.1])
1137 PGAC_PATH_DOCBOOK_STYLESHEETS
1138 PGAC_PATH_COLLATEINDEX
1139 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1140
1141
1142 # prepare build tree if outside source tree
1143 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1144 # Note 2: /bin/pwd might be better than shell's built-in at getting
1145 #         a symlink-free name.
1146 if test "$no_create" != yes; then
1147   if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1148     :
1149   else
1150     AC_SUBST(vpath_build, yes)
1151     _AS_ECHO_N([preparing build tree... ])
1152     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1153     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1154       || AC_MSG_ERROR(failed)
1155     AC_MSG_RESULT(done)
1156   fi
1157 fi
1158
1159
1160 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1161
1162 AC_CONFIG_LINKS([
1163   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1164   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1165   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1166   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1167   src/include/pg_config_os.h:src/include/port/${template}.h
1168   src/Makefile.port:src/makefiles/Makefile.${template}
1169 ])
1170
1171 AC_CONFIG_HEADERS([src/include/pg_config.h],
1172 [
1173 # Update timestamp for pg_config.h (see Makefile.global)
1174 echo >src/include/stamp-h
1175 ])
1176
1177 AC_OUTPUT