granicus.if.org Git - apache/blob - configure.in

   1 dnl
   2 dnl Autoconf configuration for Apache httpd
   3 dnl
   4 dnl     Use ./buildconf to produce a configure script
   5 dnl
   6
   7 AC_PREREQ(2.50)
   8 AC_INIT(ABOUT_APACHE)
   9
  10 AC_CONFIG_HEADER(include/ap_config_auto.h)
  11 AC_CONFIG_AUX_DIR(build)
  12
  13 dnl Absolute source/build directory
  14 abs_srcdir=`(cd $srcdir && pwd)`
  15 abs_builddir=`pwd`
  16
  17 dnl Ensure that the httpd version is included
  18 HTTPD_VERSION=`$abs_srcdir/build/get-version.sh all $abs_srcdir/include/ap_release.h AP_SERVER`
  19 AC_SUBST(HTTPD_VERSION)
  20
  21 dnl #
  22 dnl # Include our own M4 macros along with those for APR and libtool
  23 dnl #
  24 sinclude(build/apr_common.m4)
  25 sinclude(build/find_apr.m4)
  26 sinclude(build/find_apu.m4)
  27 sinclude(acinclude.m4)
  28
  29 dnl Later versions of autoconf (>= 2.62) by default cause the produced
  30 dnl configure script to emit at least warnings when it comes across unknown
  31 dnl command line options. These versions also have the macro
  32 dnl AC_DISABLE_OPTION_CHECKING defined which turns this off by default.
  33 dnl We want to have this turned off here since our configure calls can
  34 dnl contain options for APR / APR-UTIL configure that are unknown to us.
  35 dnl So avoid confusing the user by turning this off. See also PR 45221.
  36 ifdef([AC_DISABLE_OPTION_CHECKING], [AC_DISABLE_OPTION_CHECKING])
  37
  38 dnl XXX we can't just use AC_PREFIX_DEFAULT because that isn't subbed in
  39 dnl by configure until it is too late.  Is that how it should be or not?
  40 dnl Something seems broken here.
  41 AC_PREFIX_DEFAULT(/usr/local/apache2)
  42
  43 dnl Get the layout here, so we can pass the required variables to apr
  44 APR_ENABLE_LAYOUT(Apache, [errordir iconsdir htdocsdir cgidir])
  45
  46 dnl reparse the configure arguments.
  47 APR_PARSE_ARGUMENTS
  48
  49 dnl export expanded and relative configure argument variables
  50 APACHE_EXPORT_ARGUMENTS
  51
  52 dnl Save user-defined environment settings for later restoration
  53 dnl
  54 APR_SAVE_THE_ENVIRONMENT(CPPFLAGS)
  55 APR_SAVE_THE_ENVIRONMENT(CFLAGS)
  56 APR_SAVE_THE_ENVIRONMENT(CXXFLAGS)
  57 APR_SAVE_THE_ENVIRONMENT(LDFLAGS)
  58 APR_SAVE_THE_ENVIRONMENT(LIBS)
  59 APR_SAVE_THE_ENVIRONMENT(INCLUDES)
  60
  61 dnl Generate ./config.nice for reproducing runs of configure
  62 dnl
  63 APR_CONFIG_NICE(config.nice)
  64
  65 nl='
  66 '
  67 dnl Check that mkdir -p works
  68 APR_MKDIR_P_CHECK($top_srcdir/build/mkdir.sh)
  69
  70 dnl get an EGREP to use in the Makefiles
  71 AC_PROG_EGREP
  72 APACHE_SUBST(EGREP)
  73
  74 dnl ## Run configure for packages Apache uses
  75
  76 dnl shared library support for these packages doesn't currently
  77 dnl work on some platforms
  78
  79 AC_CANONICAL_SYSTEM
  80
  81 orig_prefix="$prefix"
  82
  83 AC_MSG_NOTICE([])
  84 AC_MSG_NOTICE([Configuring Apache Portable Runtime library...])
  85 AC_MSG_NOTICE([])
  86
  87 AC_ARG_WITH(included-apr,
  88 APACHE_HELP_STRING(--with-included-apr,Use bundled copies of APR/APR-Util))
  89
  90 if test "x$with_included_apr" = "xyes"; then
  91   apr_found=reconfig
  92   if test ! -d srclib/apr && test ! -d $srcdir/srclib/apr; then
  93     AC_MSG_ERROR([Bundled APR requested but not found at ./srclib/. Please refer to the documentation on APR in the httpd INSTALL file.])
  94   fi
  95 else
  96   APR_FIND_APR("$srcdir/srclib/apr", "./srclib/apr", 1, 1 2, [
  97     version=`$apr_config --version`
  98     case x${version} in
  99     x1.[[0-3]].*)
 100       AC_MSG_WARN([APR version 1.4.0 or later is required, found $version])
 101       apr_acceptable=no
 102       ;;
 103     esac
 104     unset version
 105    ])
 106 fi
 107
 108 if test "$apr_found" = "no"; then
 109   AC_MSG_ERROR([APR not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 110 fi
 111
 112 if test "$apr_found" = "reconfig"; then
 113   APR_SUBDIR_CONFIG(srclib/apr,
 114                     [$apache_apr_flags --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir --datadir=$datadir --with-installbuilddir=$installbuilddir],
 115                     [--enable-layout=*|\'--enable-layout=*])
 116   dnl We must be the first to build and the last to be cleaned
 117   AP_BUILD_SRCLIB_DIRS="apr $AP_BUILD_SRCLIB_DIRS"
 118   AP_CLEAN_SRCLIB_DIRS="$AP_CLEAN_SRCLIB_DIRS apr"
 119
 120   dnl We have to find apr-N-config when we reconfigure APR.
 121   for majorver in 1 2; do
 122     test_apr_config="./srclib/apr/apr-${majorver}-config"
 123     if test -f "$test_apr_config"; then
 124       apr_config="$test_apr_config"
 125     fi
 126   done
 127 fi
 128
 129 APR_SETIFNULL(CC, `$apr_config --cc`)
 130 APR_SETIFNULL(CPP, `$apr_config --cpp`)
 131 APR_ADDTO(CFLAGS, `$apr_config --cflags`)
 132 APR_ADDTO(CPPFLAGS, `$apr_config --cppflags`)
 133 dnl internal-only CPPFLAGS (shouldn't affect third-party module builds)
 134 INTERNAL_CPPFLAGS=""
 135 APR_ADDTO(LDFLAGS, `$apr_config --ldflags`)
 136 SHLIBPATH_VAR=`$apr_config --shlib-path-var`
 137 APR_BINDIR=`$apr_config --bindir`
 138 APR_INCLUDEDIR=`$apr_config --includedir`
 139 APR_INCLUDES=`$apr_config --includes`
 140 APR_VERSION=`$apr_config --version`
 141 apr_major_version=`echo ${APR_VERSION} | sed 's,\..*,,'`
 142 APR_CONFIG="$APR_BINDIR/apr-${apr_major_version}-config"
 143
 144 AC_MSG_NOTICE([])
 145 AC_MSG_NOTICE([Configuring Apache Portable Runtime Utility library...])
 146 AC_MSG_NOTICE([])
 147
 148 if test "x${apr_major_version}" = "x2"; then
 149   apu_found=obsolete
 150 elif test "x$with_included_apr" = "xyes"; then
 151   apu_found=reconfig
 152   if test ! -d srclib/apr-util && test ! -d $srcdir/srclib/apr-util; then
 153     AC_MSG_ERROR([Bundled APR-Util requested but not found at ./srclib/.  Please refer to the documentation on APR in the httpd INSTALL file.])
 154   fi
 155 else
 156    dnl If httpd is buildconf'ed against an apr 2.x tree, then 1.x
 157    dnl isn't supported.
 158    ifdef([APR_FIND_APU], [
 159      APR_FIND_APU("$srcdir/srclib/apr-util", "./srclib/apr-util",
 160                   1, ${apr_major_version})
 161    ], [apu_found=no])
 162 fi
 163
 164 if test "$apu_found" = "no"; then
 165   AC_MSG_ERROR([APR-util not found.  Please refer to the documentation on APR in the httpd INSTALL file.])
 166 fi
 167
 168 # Catch some misconfigurations:
 169 case ${apr_found}.${apu_found} in
 170 reconfig.yes)
 171   AC_MSG_ERROR([Cannot use an external APR-util with the bundled APR])
 172   ;;
 173 yes.reconfig)
 174   AC_MSG_ERROR([Cannot use an external APR with the bundled APR-util])
 175   ;;
 176 esac
 177
 178 if test "$apu_found" = "reconfig"; then
 179   APR_SUBDIR_CONFIG(srclib/apr-util,
 180                     [--with-apr=../apr --prefix=$prefix --exec-prefix=$exec_prefix --libdir=$libdir --includedir=$includedir --bindir=$bindir],
 181                     [--enable-layout=*|\'--enable-layout=*])
 182   dnl We must be the last to build and the first to be cleaned
 183   AP_BUILD_SRCLIB_DIRS="$AP_BUILD_SRCLIB_DIRS apr-util"
 184   AP_CLEAN_SRCLIB_DIRS="apr-util $AP_CLEAN_SRCLIB_DIRS"
 185   dnl APR and APR-Util major versions must match
 186   apu_config="./srclib/apr-util/apu-${apr_major_version}-config"
 187 fi
 188
 189 if test "$apu_found" = "obsolete"; then
 190   AC_MSG_NOTICE([APR-util obsoleted, woohoo])
 191 else
 192   APR_ADDTO(LDFLAGS, `$apu_config --ldflags`)
 193   APU_BINDIR=`$apu_config --bindir`
 194   APU_INCLUDEDIR=`$apu_config --includedir`
 195   APU_INCLUDES=`$apu_config --includes`
 196   APU_VERSION=`$apu_config --version`
 197   APU_CONFIG="$APU_BINDIR/apu-`echo ${APU_VERSION} | sed 's,\..*,,'`-config"
 198 fi
 199
 200 dnl In case we picked up CC and CPP from APR, get that info into the
 201 dnl config cache so that PCRE uses it.  Otherwise, CC and CPP used for
 202 dnl PCRE and for our config tests will be whatever PCRE determines.
 203 AC_PROG_CC
 204 AC_PROG_CPP
 205
 206 dnl Try to get c99 support for variadic macros
 207 ifdef([AC_PROG_CC_C99], [AC_PROG_CC_C99])
 208
 209 dnl In case of cross compilation we set CC_FOR_BUILD to cc unless
 210 dnl we got already CC_FOR_BUILD from environment.
 211 if test "x${build_alias}" != "x${host_alias}"; then
 212   if test "x${CC_FOR_BUILD}" = "x"; then
 213     CC_FOR_BUILD=cc
 214   fi
 215 fi
 216
 217 if test "x${cache_file}" = "x/dev/null"; then
 218   # Likewise, ensure that CC and CPP are passed through to the pcre
 219   # configure script iff caching is disabled (the autoconf 2.5x default).
 220   export CC; export CPP
 221 fi
 222
 223 AC_ARG_WITH(pcre,
 224 APACHE_HELP_STRING(--with-pcre=PATH,Use external PCRE library))
 225
 226 AC_PATH_PROG(PCRE_CONFIG, pcre-config, false)
 227 if test -d "$with_pcre" && test -x "$with_pcre/bin/pcre-config"; then
 228    PCRE_CONFIG=$with_pcre/bin/pcre-config
 229 elif test -x "$with_pcre"; then
 230    PCRE_CONFIG=$with_pcre
 231 fi
 232
 233 if test "$PCRE_CONFIG" != "false"; then
 234   if $PCRE_CONFIG --version >/dev/null 2>&1; then :; else
 235     AC_MSG_ERROR([Did not find pcre-config script at $PCRE_CONFIG])
 236   fi
 237   case `$PCRE_CONFIG --version` in
 238   [[1-5].*])
 239     AC_MSG_ERROR([Need at least pcre version 6.0])
 240     ;;
 241   esac
 242   AC_MSG_NOTICE([Using external PCRE library from $PCRE_CONFIG])
 243   APR_ADDTO(PCRE_INCLUDES, [`$PCRE_CONFIG --cflags`])
 244   APR_ADDTO(PCRE_LIBS, [`$PCRE_CONFIG --libs`])
 245 else
 246   AC_MSG_ERROR([pcre-config for libpcre not found. PCRE is required and available from http://pcre.org/])
 247 fi
 248 APACHE_SUBST(PCRE_LIBS)
 249
 250 AC_MSG_NOTICE([])
 251 AC_MSG_NOTICE([Configuring Apache httpd...])
 252 AC_MSG_NOTICE([])
 253
 254 dnl If the source dir is not equal to the build dir,
 255 dnl then we are running in VPATH mode.
 256
 257 APR_ADDTO(INCLUDES, [-I.])
 258
 259 if test "$abs_builddir" != "$abs_srcdir"; then
 260   APR_ADDTO(INCLUDES, [-I\$(top_builddir)/include])
 261 fi
 262
 263 APR_ADDTO(INCLUDES, [-I\$(top_srcdir)/os/\$(OS_DIR) -I\$(top_srcdir)/include])
 264
 265 # apr/apr-util --includes may pick up system paths for dependent
 266 # libraries, so ensure these are later in INCLUDES than local source
 267 # directories.
 268 APR_ADDTO(INCLUDES, $APR_INCLUDES)
 269 APR_ADDTO(INCLUDES, $APU_INCLUDES)
 270
 271 dnl Add in path to PCRE includes
 272 APR_ADDTO(INCLUDES, $PCRE_INCLUDES)
 273
 274 AC_MSG_NOTICE([])
 275 AC_MSG_NOTICE([Applying OS-specific hints for httpd...])
 276 AC_MSG_NOTICE([])
 277
 278 case $host in
 279   *os2*)
 280       # Use a custom made libtool replacement
 281       echo "using aplibtool"
 282       LIBTOOL="$abs_srcdir/srclib/apr/build/aplibtool"
 283       SH_LIBTOOL="$LIBTOOL --shared --export-all"
 284       SH_LIBS="\$(ALL_LIBS)"
 285       CORE_IMPLIB_FILE="ApacheCoreOS2.la"
 286       CORE_IMPLIB="$abs_srcdir/server/$CORE_IMPLIB_FILE"
 287       MK_IMPLIB="emximp"
 288       other_targets="$other_targets os2core"
 289       INSTALL_PROG_FLAGS="-e .exe"
 290       SHLTCFLAGS=""
 291       LTCFLAGS=""
 292       ;;
 293   *)
 294       if test "x$LTFLAGS" = "x"; then
 295           LTFLAGS='--silent'
 296       fi
 297       my_libtool=`$apr_config --apr-libtool`
 298       LIBTOOL="$my_libtool \$(LTFLAGS)"
 299       libtoolversion=`$my_libtool --version`
 300       case $libtoolversion in
 301           *1.[[45]]* | *[[2-9]].[[0-9]]*)
 302               SH_LIBTOOL='$(LIBTOOL)'
 303               SHLTCFLAGS="-prefer-pic"
 304               LTCFLAGS="-prefer-non-pic -static"
 305               ;;
 306           *)
 307               SH_LIBTOOL='$(SHELL) $(top_builddir)/shlibtool $(LTFLAGS)'
 308               SHLTCFLAGS=""
 309               LTCFLAGS=""
 310               ;;
 311       esac
 312       ;;
 313 esac
 314 APACHE_SUBST(SHLTCFLAGS)
 315 APACHE_SUBST(LTCFLAGS)
 316
 317 case $host in
 318   *-apple-aux3*)
 319       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 320       ;;
 321   *os2-emx*)
 322       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 323       ;;
 324   *-linux-*)
 325       case `uname -r` in
 326         2.[[2-9]]* )
 327             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 328             ;;
 329         * )
 330             ;;
 331       esac
 332       ;;
 333   *486-*-bsdi* | *-netbsd* | *-freebsd* | *-apple-darwin* | *-dec-osf* | *-qnx)
 334       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 335       ;;
 336   *-solaris2*)
 337       dnl This is a hack -- we should be using AC_TRY_RUN instead
 338       ap_platform_runtime_link_flag="-R"
 339       dnl solaris 8 and above don't have a thundering herd
 340       dnl not sure about rev's before this one.
 341       case `uname -r` in
 342         5.[567]*)
 343             ;;
 344         * )
 345             APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 346             ;;
 347       esac
 348       ;;
 349   *cygwin*)
 350       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 351       ;;
 352   *mingw32*)
 353       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAP_DECLARE_EXPORT])
 354       APR_ADDTO(INTERNAL_CPPFLAGS, [-DAPREQ_DECLARE_EXPORT])
 355       APR_SETIFNULL(ac_cv_func_times, [no])
 356       APR_SETIFNULL(ac_cv_func_getpwnam, [no])
 357       APR_SETIFNULL(ac_cv_func_getgrnam, [no])
 358       ;;
 359   *aix*)
 360       aixver=`echo $host | sed 's/^[[^0-9]]*//' | sed 's/\.//g'`
 361       if test $aixver -ge 4320; then
 362         APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 363       fi
 364       ;;
 365   *os390*)
 366       APR_SETVAR(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, [1])
 367       ;;
 368 esac
 369
 370 APR_SETVAR(AP_NONBLOCK_WHEN_MULTI_LISTEN, [1])
 371
 372 dnl
 373 dnl Process command line arguments. This is done early in the process so the
 374 dnl user can get feedback quickly in case of an error.
 375 dnl
 376 dnl ### need to move some of the arguments "up here"
 377
 378 dnl ## Check for programs
 379
 380 AC_PATH_PROG(RM, rm)
 381 AC_PATH_PROG(PKGCONFIG, pkg-config)
 382 AC_PATH_PROG(RSYNC, rsync)
 383 AC_PROG_AWK
 384 AC_PROG_LN_S
 385 AC_CHECK_TOOL(RANLIB, ranlib, true)
 386 dnl AC_PATH_PROG(PERL_PATH, perl)
 387 AC_CHECK_PROGS(LYNX_PATH,[lynx links elinks], [lynx])
 388
 389 # Hard-coded install programs
 390 MKINSTALLDIRS="\$(abs_srcdir)/build/mkdir.sh"
 391 INSTALL="\$(LIBTOOL) --mode=install \$(abs_srcdir)/build/install.sh -c"
 392 APACHE_SUBST(MKINSTALLDIRS)
 393 APACHE_SUBST(INSTALL)
 394
 395 dnl Various OS checks that apparently set required flags
 396 ifdef([AC_USE_SYSTEM_EXTENSIONS], [
 397 AC_USE_SYSTEM_EXTENSIONS
 398 ], [
 399 AC_AIX
 400 AC_MINIX
 401 ])
 402
 403 AC_ISC_POSIX
 404
 405 # Ensure that satisfactory versions of apr and apr-util are
 406 # found if external copies are configured.
 407 if test "${apr_found}" = "yes"; then
 408   # Require at least APR 1.3.x otherwise fail
 409   APACHE_CHECK_APxVER([apr], 1, 3)
 410 fi
 411
 412 if test "${apu_found}" = "yes"; then
 413   # Require at least APR-util 1.3.x otherwise fail
 414   if test "${apr_found}" = "yes"; then
 415     # we need to add the APR includes to CPPFLAGS
 416     apu_ckver_CPPFLAGS="$CPPFLAGS"
 417     CPPFLAGS="$CPPFLAGS `$apr_config --includes`"
 418     APACHE_CHECK_APxVER([apu], 1, 3)
 419     CPPFLAGS="$apu_ckver_CPPFLAGS"
 420   else
 421     APACHE_CHECK_APxVER([apu], 1, 3)
 422   fi
 423 fi
 424
 425 dnl Check for what we can generate dependency files with
 426 APR_CHECK_DEPEND
 427
 428 dnl ## Check for libraries
 429
 430 dnl ## Check for header files
 431
 432 dnl I think these are just used all over the place, so just check for
 433 dnl them at the base of the tree. If some are specific to a single
 434 dnl directory, they should be moved (Comment #Spoon)
 435
 436 dnl Regarding standard header files: AC_HEADER_STDC doesn't set symbols
 437 dnl HAVE_STRING_H, HAVE_STDLIB_H, etc., so those are checked for
 438 dnl explicitly so that the normal HAVE_xxx_H symbol is defined.
 439
 440 AC_HEADER_STDC
 441 AC_CHECK_HEADERS( \
 442 string.h \
 443 limits.h \
 444 unistd.h \
 445 sys/socket.h \
 446 pwd.h \
 447 grp.h \
 448 strings.h \
 449 sys/prctl.h \
 450 sys/processor.h \
 451 sys/sem.h \
 452 sys/sdt.h
 453 )
 454 AC_HEADER_SYS_WAIT
 455
 456 dnl ## Check for typedefs, structures, and compiler characteristics.
 457
 458 AC_C_CONST
 459
 460 dnl ## Check for library functions
 461 dnl ## sqrt() only needed in support/ab.c
 462 saved_LIBS="$LIBS"
 463 LIBS=""
 464 AC_SEARCH_LIBS(sqrt, m)
 465 MATH_LIBS="$LIBS"
 466 APACHE_SUBST(MATH_LIBS)
 467 LIBS="$saved_LIBS"
 468
 469 saved_LIBS="$LIBS"
 470 LIBS=""
 471 AC_SEARCH_LIBS(crypt, crypt)
 472 CRYPT_LIBS="$LIBS"
 473 APACHE_SUBST(CRYPT_LIBS)
 474 LIBS="$saved_LIBS"
 475
 476 dnl See Comment #Spoon
 477
 478 AC_CHECK_FUNCS( \
 479 getpwnam \
 480 getgrnam \
 481 initgroups \
 482 bindprocessor \
 483 prctl \
 484 timegm \
 485 getpgid \
 486 fopen64 \
 487 getloadavg
 488 )
 489
 490 dnl confirm that a void pointer is large enough to store a long integer
 491 APACHE_CHECK_VOID_PTR_LEN
 492
 493 AC_CACHE_CHECK([for gettid()], ac_cv_gettid,
 494 [AC_TRY_RUN(#define _GNU_SOURCE
 495 #include <unistd.h>
 496 #include <sys/syscall.h>
 497 #include <sys/types.h>
 498 int main(int argc, char **argv) {
 499 pid_t t = syscall(SYS_gettid); return t == -1 ? 1 : 0; },
 500 [ac_cv_gettid=yes], [ac_cv_gettid=no], [ac_cv_gettid=no])])
 501 if test "$ac_cv_gettid" = "yes"; then
 502     AC_DEFINE(HAVE_GETTID, 1, [Define if you have gettid()])
 503 fi
 504
 505 dnl ## Check for the tm_gmtoff field in struct tm to get the timezone diffs
 506 AC_CACHE_CHECK([for tm_gmtoff in struct tm], ac_cv_struct_tm_gmtoff,
 507 [AC_TRY_COMPILE([#include <sys/types.h>
 508 #include <time.h>], [struct tm tm; tm.tm_gmtoff;],
 509   ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no)])
 510 if test "$ac_cv_struct_tm_gmtoff" = "yes"; then
 511     AC_DEFINE(HAVE_GMTOFF, 1, [Define if struct tm has a tm_gmtoff field])
 512 fi
 513
 514 dnl ## Set up any appropriate OS-specific environment variables for apachectl
 515
 516 case $host in
 517     *aix*)
 518         # for 32-bit builds, increase MAXDATA to allow lots of threads
 519         if test x$OBJECT_MODE != x64; then
 520             OS_SPECIFIC_VARS="LDR_CNTRL=\"MAXDATA=0x80000000\" ; export LDR_CNTRL ;"
 521         fi
 522         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS AIXTHREAD_SCOPE=S ; export AIXTHREAD_SCOPE"
 523         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_MUTEX_DEBUG=OFF ; export AIXTHREAD_MUTEX_DEBUG"
 524         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_RWLOCK_DEBUG=OFF ; export AIXTHREAD_RWLOCK_DEBUG"
 525         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; AIXTHREAD_COND_DEBUG=OFF ; export AIXTHREAD_COND_DEBUG"
 526         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; SPINLOOPTIME=1000 ; export SPINLOOPTIME"
 527         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; YIELDLOOPTIME=8 ; export YIELDLOOPTIME"
 528         OS_SPECIFIC_VARS="$OS_SPECIFIC_VARS ; MALLOCMULTIHEAP=considersize,heaps:8 ; export MALLOCMULTIHEAP"
 529         ;;
 530     *os390*)
 531         OS_SPECIFIC_VARS="export _CEE_RUNOPTS=\"STACK(,,ANY)\" ; export _EDC_ADD_ERRNO2=1"
 532         ;;
 533     *)
 534         OS_SPECIFIC_VARS=""
 535 esac
 536
 537 AC_ARG_WITH(port,APACHE_HELP_STRING(--with-port=PORT,Port on which to listen (default is 80)),
 538         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-port requires a value (the TCP port number)'); else PORT="$withval"; fi],
 539         [PORT=80])
 540
 541 AC_ARG_WITH(sslport,APACHE_HELP_STRING(--with-sslport=SSLPORT,Port on which to securelisten (default is 443)),
 542         [if test "$withval" = "yes"; then AC_MSG_ERROR('option --with-sslport requires a value (the SSL TCP port number)'); else SSLPORT="$withval"; fi],
 543         [SSLPORT=443])
 544
 545 DTRACE=true
 546 AC_ARG_ENABLE(dtrace,APACHE_HELP_STRING(--enable-dtrace,Enable DTrace probes),
 547 [
 548   enable_dtrace=$enableval
 549   if test "$enableval" = "yes"; then
 550     APR_ADDTO(CPPFLAGS, -DAPR_DTRACE_PROVIDER)
 551     AC_MSG_ERROR('DTrace Support in the build system is not complete. Patches Welcome!')
 552   fi
 553 ],
 554 [
 555   enable_dtrace=no
 556 ])
 557
 558 dnl Disabled dtrace build for now.
 559 enable_dtrace=no
 560
 561 case $host in
 562   *-solaris2*)
 563     if test $enable_dtrace = "yes" -a "$ac_cv_header_sys_sdt_h" = "yes"; then
 564         AC_DEFINE(AP_ENABLE_DTRACE, 1,
 565                   [Enable DTrace probes])
 566         DTRACE="/usr/sbin/dtrace $DTRACEFLAGS"
 567         test -f include/apache_probes.h || $DTRACE -h -s apache_probes.d -o include/apache_probes.h
 568     fi
 569     ;;
 570 esac
 571
 572 APACHE_SUBST(DTRACE)
 573
 574 AC_ARG_ENABLE(hook-probes,APACHE_HELP_STRING(--enable-hook-probes,Enable APR hook probes),
 575 [
 576     if test "$enableval" = "yes"; then
 577         AC_DEFINE(AP_HOOK_PROBES_ENABLED, 1,
 578                   [Enable the APR hook probes capability, reading from ap_hook_probes.h])
 579         APR_ADDTO(INTERNAL_CPPFLAGS, -DAP_HOOK_PROBES_ENABLED)
 580     fi
 581 ])dnl
 582
 583 AC_ARG_ENABLE(exception-hook,APACHE_HELP_STRING(--enable-exception-hook,Enable fatal exception hook),
 584 [
 585     if test "$enableval" = "yes"; then
 586         AC_DEFINE(AP_ENABLE_EXCEPTION_HOOK, 1,
 587                   [Allow modules to run hook after a fatal exception])
 588     fi
 589 ])dnl
 590
 591 AC_ARG_ENABLE(load-all-modules,APACHE_HELP_STRING(--enable-load-all-modules,Load all modules),
 592 [
 593   LOAD_ALL_MODULES=$enableval
 594   AC_MSG_NOTICE([Setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 595 ],
 596 [
 597   LOAD_ALL_MODULES="no"
 598 ])
 599
 600 AC_ARG_ENABLE(maintainer-mode,APACHE_HELP_STRING(--enable-maintainer-mode,Turn on debugging and compile time warnings and load all compiled modules),
 601 [
 602   if test "$enableval" = "yes"; then
 603     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 604     if test "$GCC" = "yes"; then
 605       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith])
 606       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 607       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 608       APACHE_ADD_GCC_CFLAG([-Wformat])
 609       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 610       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 611     elif test "$AIX_XLC" = "yes"; then
 612       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 613     fi
 614     if test "x$enable_load_all_modules" = "x"; then
 615       LOAD_ALL_MODULES=yes
 616       AC_MSG_NOTICE([Maintainer mode setting "LOAD_ALL_MODULES" to $LOAD_ALL_MODULES])
 617     fi
 618   fi
 619 ])dnl
 620
 621 AC_ARG_ENABLE(debugger-mode,APACHE_HELP_STRING(--enable-debugger-mode,Turn on debugging and compile time warnings and turn off optimization),
 622 [
 623   if test "$enableval" = "yes"; then
 624     APR_ADDTO(CPPFLAGS, -DAP_DEBUG)
 625     if test "$GCC" = "yes"; then
 626       APR_ADDTO(CFLAGS,[-Wall -Wmissing-prototypes -Wstrict-prototypes -Wmissing-declarations -Wpointer-arith -O0])
 627       APACHE_ADD_GCC_CFLAG([-Wdeclaration-after-statement])
 628       APACHE_ADD_GCC_CFLAG([-Werror=declaration-after-statement])
 629       APACHE_ADD_GCC_CFLAG([-Wformat])
 630       APACHE_ADD_GCC_CFLAG([-Wformat-security])
 631       APACHE_ADD_GCC_CFLAG([-Werror=format-security])
 632     elif test "$AIX_XLC" = "yes"; then
 633       APR_ADDTO(CFLAGS,-qfullpath -qinitauto=FE -qcheck=all -qinfo=pro)
 634     fi
 635   fi
 636 ])dnl
 637
 638 dnl Conditionally enable PIE support for GNU toolchains.
 639 AC_ARG_ENABLE(pie,APACHE_HELP_STRING(--enable-pie,Build httpd as a Position Independent Executable))
 640 if test "$enable_pie" = "yes"; then
 641    AC_CACHE_CHECK([whether $CC accepts PIE flags], [ap_cv_cc_pie], [
 642      save_CFLAGS=$CFLAGS
 643      save_LDFLAGS=$LDFLAGS
 644      CFLAGS="$CFLAGS -fPIE"
 645      LDFLAGS="$LDFLAGS -pie"
 646      AC_TRY_RUN([static int foo[30000]; int main () { return 0; }],
 647       [ap_cv_cc_pie=yes], [ap_cv_cc_pie=no], [ap_cv_cc_pie=yes])
 648      CFLAGS=$save_CFLAGS
 649      LDFLAGS=$save_LDFLAGS
 650    ])
 651    if test "$ap_cv_cc_pie" = "yes"; then
 652      PICFLAGS="-fPIE"
 653      PILDFLAGS="-pie"
 654    else
 655      AC_ERROR([--enable-pie requested but $CC failed using PIE flags])
 656    fi
 657 fi
 658 APACHE_SUBST(PICFLAGS)
 659 APACHE_SUBST(PILDFLAGS)
 660
 661 prefix="$orig_prefix"
 662 APACHE_ENABLE_MODULES
 663
 664 dnl reading config stubs
 665 esyscmd(./build/config-stubs .)
 666
 667 APACHE_SUBST(progname)
 668 APACHE_SUBST(OS)
 669 APACHE_SUBST(OS_DIR)
 670 APACHE_SUBST(BUILTIN_LIBS)
 671 APACHE_SUBST(SHLIBPATH_VAR)
 672 APACHE_SUBST(OS_SPECIFIC_VARS)
 673
 674 PRE_SHARED_CMDS='echo ""'
 675 POST_SHARED_CMDS='echo ""'
 676
 677 dnl apache_need_shared tells us if Apache modules are being built as DSOs
 678
 679 if test "$apache_need_shared" = "yes"; then
 680   if test -f $ac_aux_dir/ltconfig; then
 681     $SHELL $ac_aux_dir/ltconfig --output=shlibtool --disable-static --srcdir=$ac_aux_dir --cache-file=./config.cache $ac_aux_dir/ltmain.sh
 682   fi
 683   shared_build="shared-build"
 684 fi
 685
 686 dnl enable_so tells us if *any* modules can be built as DSOs
 687
 688 if test "$enable_so" = "yes" -o "$enable_so" = "static"; then
 689   case $host in
 690     *-ibm-aix*)
 691       APR_ADDTO(HTTPD_LDFLAGS, [-Wl,-uXML_Parse -Wl,-bE:$abs_builddir/server/httpd.exp])
 692       APR_ADDTO(SH_LDFLAGS, [\$(EXTRA_LDFLAGS) \$(EXTRA_LIBS)])
 693       APR_ADDTO(UTIL_LDFLAGS, [-Wl,-uXML_Parse])
 694       ;;
 695     *os390)
 696       APR_ADDTO(HTTPD_LDFLAGS, [--main=$abs_srcdir/server/main.o --core-dll=$abs_srcdir/apachecore.dll])
 697       APR_ADDTO(SH_LDFLAGS, [--core-dll=$abs_srcdir/apachecore.dll])
 698   esac
 699   MOD_SO_ENABLED=yes
 700 fi
 701 AC_SUBST(MOD_SO_ENABLED)
 702
 703 APACHE_SUBST(PRE_SHARED_CMDS)
 704 APACHE_SUBST(POST_SHARED_CMDS)
 705 APACHE_SUBST(shared_build)
 706
 707 AC_ARG_WITH(program-name,
 708 APACHE_HELP_STRING(--with-program-name,alternate executable name),[
 709   progname="$withval" ], [
 710   progname="httpd"] )
 711
 712 # SuExec parameters
 713 AC_ARG_WITH(suexec-bin,
 714 APACHE_HELP_STRING(--with-suexec-bin,Path to suexec binary),[
 715   AC_DEFINE_UNQUOTED(SUEXEC_BIN, "$withval", [Path to suexec binary] )
 716 ] )
 717
 718 AC_ARG_WITH(suexec-caller,
 719 APACHE_HELP_STRING(--with-suexec-caller,User allowed to call SuExec),[
 720   AC_DEFINE_UNQUOTED(AP_HTTPD_USER, "$withval", [User allowed to call SuExec] ) ] )
 721
 722 AC_ARG_WITH(suexec-userdir,
 723 APACHE_HELP_STRING(--with-suexec-userdir,User subdirectory),[
 724   AC_DEFINE_UNQUOTED(AP_USERDIR_SUFFIX, "$withval", [User subdirectory] ) ] )
 725
 726 AC_ARG_WITH(suexec-docroot,
 727 APACHE_HELP_STRING(--with-suexec-docroot,SuExec root directory),[
 728   AC_DEFINE_UNQUOTED(AP_DOC_ROOT, "$withval", [SuExec root directory] ) ] )
 729
 730 AC_ARG_WITH(suexec-uidmin,
 731 APACHE_HELP_STRING(--with-suexec-uidmin,Minimal allowed UID),[
 732   AC_DEFINE_UNQUOTED(AP_UID_MIN, $withval, [Minimum allowed UID] ) ] )
 733
 734 AC_ARG_WITH(suexec-gidmin,
 735 APACHE_HELP_STRING(--with-suexec-gidmin,Minimal allowed GID),[
 736   AC_DEFINE_UNQUOTED(AP_GID_MIN, $withval, [Minimum allowed GID] ) ] )
 737
 738 AC_ARG_WITH(suexec-logfile,
 739 APACHE_HELP_STRING(--with-suexec-logfile,Set the logfile),[
 740   if test "x$withval" = "xyes"; then
 741     AC_MSG_ERROR([log filename required for --with-suexec-logfile option])
 742   elif test "x$withval" != "xno"; then
 743     AC_DEFINE_UNQUOTED(AP_LOG_EXEC, "$withval", [SuExec log file])
 744   fi
 745 ])
 746
 747 AC_ARG_WITH(suexec-syslog,
 748 APACHE_HELP_STRING(--with-suexec-syslog,Set the logfile),[
 749   if test $withval = "yes"; then
 750     if test "x${with_suexec_logfile}" != "xno"; then
 751       AC_MSG_NOTICE([hint: use "--without-suexec-logfile --with-suexec-syslog"])
 752       AC_MSG_ERROR([suexec does not support both logging to file and syslog])
 753     fi
 754     AC_CHECK_FUNCS([vsyslog], [], [
 755        AC_MSG_ERROR([cannot support syslog from suexec without vsyslog()])])
 756     AC_DEFINE(AP_LOG_SYSLOG, 1, [SuExec log to syslog])
 757   fi
 758 ])
 759
 760
 761 AC_ARG_WITH(suexec-safepath,
 762 APACHE_HELP_STRING(--with-suexec-safepath,Set the safepath),[
 763   AC_DEFINE_UNQUOTED(AP_SAFE_PATH, "$withval", [safe shell path for SuExec] ) ] )
 764
 765 AC_ARG_WITH(suexec-umask,
 766 APACHE_HELP_STRING(--with-suexec-umask,umask for suexec'd process),[
 767   AC_DEFINE_UNQUOTED(AP_SUEXEC_UMASK, 0$withval, [umask for suexec'd process] ) ] )
 768
 769 INSTALL_SUEXEC=setuid
 770 AC_ARG_ENABLE([suexec-capabilities],
 771 APACHE_HELP_STRING(--enable-suexec-capabilities,Use Linux capability bits not setuid root suexec), [
 772   if test "$enableval" = "yes"; then
 773     INSTALL_SUEXEC=caps
 774     AC_DEFINE(AP_SUEXEC_CAPABILITIES, 1,
 775               [Enable if suexec is installed with Linux capabilities, not setuid])
 776   fi
 777 ])
 778 APACHE_SUBST(INSTALL_SUEXEC)
 779
 780 dnl APR should go after the other libs, so the right symbols can be picked up
 781 if test x${apu_found} != xobsolete; then
 782   AP_LIBS="$AP_LIBS `$apu_config --avoid-ldap --link-libtool --libs`"
 783 fi
 784 AP_LIBS="$AP_LIBS `$apr_config --link-libtool --libs`"
 785 APACHE_SUBST(AP_LIBS)
 786 APACHE_SUBST(AP_BUILD_SRCLIB_DIRS)
 787 APACHE_SUBST(AP_CLEAN_SRCLIB_DIRS)
 788
 789 AC_DEFINE(AP_USING_AUTOCONF, 1,
 790                 [Using autoconf to configure Apache])
 791
 792 if test "$SINGLE_LISTEN_UNSERIALIZED_ACCEPT" = "1"; then
 793     AC_DEFINE(SINGLE_LISTEN_UNSERIALIZED_ACCEPT, 1,
 794               [This platform doesn't suffer from the thundering herd problem])
 795 fi
 796
 797 if test "$AP_NONBLOCK_WHEN_MULTI_LISTEN" = "1"; then
 798     AC_DEFINE(AP_NONBLOCK_WHEN_MULTI_LISTEN, 1,
 799               [Listening sockets are non-blocking when there are more than 1])
 800 fi
 801
 802 APR_CHECK_APR_DEFINE(APR_HAVE_IPV6)
 803
 804 AC_ARG_ENABLE(v4-mapped,APACHE_HELP_STRING(--enable-v4-mapped,Allow IPv6 sockets to handle IPv4 connections),
 805 [
 806   v4mapped=$enableval
 807 ],
 808 [
 809     case $host in
 810     *freebsd5*|*netbsd*|*openbsd*)
 811         v4mapped=no
 812         ;;
 813     *)
 814         v4mapped=yes
 815         ;;
 816     esac
 817     if ap_mpm_is_enabled winnt; then
 818         dnl WinNT MPM doesn't support this.
 819         v4mapped=no
 820     fi
 821 ])
 822
 823 if test $v4mapped = "yes" -a $ac_cv_define_APR_HAVE_IPV6 = "yes"; then
 824     AC_DEFINE(AP_ENABLE_V4_MAPPED, 1,
 825               [Allow IPv4 connections on IPv6 listening sockets])
 826 fi
 827
 828 APACHE_FAST_OUTPUT(Makefile modules/Makefile srclib/Makefile)
 829 APACHE_FAST_OUTPUT(os/Makefile server/Makefile)
 830 APACHE_FAST_OUTPUT(support/Makefile)
 831
 832 if test -d ./test; then
 833     APACHE_FAST_OUTPUT(test/Makefile)
 834 fi
 835
 836 dnl ## Finalize the variables
 837 AC_MSG_NOTICE([])
 838 AC_MSG_NOTICE([Restore user-defined environment settings...])
 839 AC_MSG_NOTICE([])
 840
 841 APR_RESTORE_THE_ENVIRONMENT(CPPFLAGS, EXTRA_)
 842 APR_RESTORE_THE_ENVIRONMENT(CFLAGS, EXTRA_)
 843 APR_RESTORE_THE_ENVIRONMENT(CXXFLAGS, EXTRA_)
 844 APR_RESTORE_THE_ENVIRONMENT(LDFLAGS, EXTRA_)
 845 APR_RESTORE_THE_ENVIRONMENT(LIBS, EXTRA_)
 846 APR_RESTORE_THE_ENVIRONMENT(INCLUDES, EXTRA_)
 847
 848 AC_MSG_NOTICE([])
 849 AC_MSG_NOTICE([Construct makefiles and header files...])
 850 AC_MSG_NOTICE([])
 851
 852 APACHE_GEN_CONFIG_VARS
 853
 854 dnl ## Build modules.c
 855 rm -f modules.c
 856 echo $MODLIST | $AWK -f $srcdir/build/build-modules-c.awk > modules.c
 857
 858 APR_EXPAND_VAR(ap_prefix, $prefix)
 859 AC_DEFINE_UNQUOTED(HTTPD_ROOT, "${ap_prefix}",
 860         [Root directory of the Apache install area])
 861 AC_DEFINE_UNQUOTED(SERVER_CONFIG_FILE, "${rel_sysconfdir}/${progname}.conf",
 862         [Location of the config file, relative to the Apache root directory])
 863 AC_DEFINE_UNQUOTED(AP_TYPES_CONFIG_FILE, "${rel_sysconfdir}/mime.types",
 864         [Location of the MIME types config file, relative to the Apache root directory])
 865
 866 perlbin=`$ac_aux_dir/PrintPath perl`
 867 if test "x$perlbin" = "x"; then
 868     perlbin="/replace/with/path/to/perl/interpreter"
 869 fi
 870 AC_SUBST(perlbin)
 871
 872 dnl If we are running on BSD/OS, we need to use the BSD .include syntax.
 873
 874 BSD_MAKEFILE=no
 875 ap_make_include=include
 876 ap_make_delimiter=' '
 877 case $host in
 878 *bsdi*)
 879     # Check whether they've installed GNU make
 880     if make --version > /dev/null 2>&1; then
 881         true
 882     else
 883         BSD_MAKEFILE=yes
 884         ap_make_include=.include
 885         ap_make_delimiter='"'
 886     fi
 887     ;;
 888 esac
 889 AC_SUBST(ap_make_include)
 890 AC_SUBST(ap_make_delimiter)
 891
 892 dnl Ensure that docs/conf is created.
 893 test -d docs/conf||$mkdir_p docs/conf
 894
 895 AC_OUTPUT($APACHE_OUTPUT_FILES docs/conf/httpd.conf docs/conf/extra/httpd-autoindex.conf docs/conf/extra/httpd-dav.conf docs/conf/extra/httpd-default.conf docs/conf/extra/httpd-info.conf docs/conf/extra/httpd-languages.conf docs/conf/extra/httpd-manual.conf docs/conf/extra/httpd-mpm.conf docs/conf/extra/httpd-multilang-errordoc.conf docs/conf/extra/httpd-policy.conf docs/conf/extra/httpd-ssl.conf docs/conf/extra/httpd-userdir.conf docs/conf/extra/httpd-vhosts.conf docs/conf/extra/proxy-html.conf include/ap_config_layout.h support/apxs support/apachectl support/dbmmanage support/envvars-std support/log_server_status support/logresolve.pl support/phf_abuse_log.cgi support/split-logfile build/rules.mk build/pkg/pkginfo build/config_vars.sh,[true],[
 896   APACHE_GEN_MAKEFILES
 897 ])