granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.520 2007/07/12 14:36:52 mha Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.3devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2007, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # --enable-profiling enables gcc profiling
 210 #
 211 PGAC_ARG_BOOL(enable, profiling, no,
 212               [  --enable-profiling      build with profiling enabled ])
 213 AC_SUBST(enable_profiling)
 214
 215 #
 216 # DTrace
 217 #
 218 PGAC_ARG_BOOL(enable, dtrace, no,
 219               [  --enable-dtrace         build with DTrace support],
 220 [AC_DEFINE([ENABLE_DTRACE], 1,
 221            [Define to 1 to enable DTrace support. (--enable-dtrace)])
 222 AC_CHECK_PROGS(DTRACE, dtrace)
 223 if test -z "$DTRACE"; then
 224   AC_MSG_ERROR([dtrace not found])
 225 fi
 226 AC_SUBST(DTRACEFLAGS)])
 227 AC_SUBST(enable_dtrace)
 228
 229 #
 230 # C compiler
 231 #
 232
 233 # For historical reasons you can also use --with-CC to specify the C compiler
 234 # to use, although the standard way to do this is to set the CC environment
 235 # variable.
 236 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 237
 238 case $template in
 239   aix) pgac_cc_list="gcc xlc";;
 240  irix) pgac_cc_list="cc";; # no gcc
 241     *) pgac_cc_list="gcc cc";;
 242 esac
 243
 244 AC_PROG_CC([$pgac_cc_list])
 245
 246 unset CFLAGS
 247
 248 #
 249 # Read the template
 250 #
 251 . "$srcdir/src/template/$template" || exit
 252
 253 # CFLAGS are selected so:
 254 # If the user specifies something in the environment, that is used.
 255 # else:  If the template file set something, that is used.
 256 # else:  If the compiler is GCC, then we use -O2.
 257 # else:  If the compiler is something else, then we use -0.
 258
 259 if test "$ac_env_CFLAGS_set" = set; then
 260   CFLAGS=$ac_env_CFLAGS_value
 261 elif test "${CFLAGS+set}" = set; then
 262   : # (keep what template set)
 263 elif test "$GCC" = yes; then
 264   CFLAGS="-O2"
 265 else
 266   # if the user selected debug mode, don't use -O
 267   if test "$enable_debug" != yes; then
 268     CFLAGS="-O"
 269   fi
 270 fi
 271
 272 # Some versions of GCC support some additional useful warning flags.
 273 # Check whether they are supported, and add them to CFLAGS if so.
 274
 275 if test "$GCC" = yes; then
 276
 277 # ICC pretends to be GCC but it's lying; it doesn't support these options.
 278 # So we have to check if "GCC" is really ICC.
 279 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 280 choke me
 281 @%:@endif], [ICC=[yes]], [ICC=[no]])
 282
 283   if test "$ICC" = no; then
 284     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 285
 286     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 287     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 288   else
 289     # Intel compiler has a bug/misoptimization in checking for
 290     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 291     # CFLAGS.
 292     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 293   fi
 294
 295   # Disable strict-aliasing rules; needed for gcc 3.3+
 296   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 297 elif test x"${CC}" = x"xlc"; then
 298   # AIX xlc has to have strict aliasing turned off too
 299   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 300 fi
 301
 302 # supply -g if --enable-debug
 303 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 304   CFLAGS="$CFLAGS -g"
 305 fi
 306
 307 # enable profiling if --enable-profiling
 308 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 309   if test "$GCC" = yes; then
 310     AC_DEFINE([PROFILE_PID_DIR], 1,
 311            [Define to 1 to enable profiling. (--enable-profiling)])
 312     CFLAGS="$CFLAGS -pg"
 313   else
 314     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 315   fi
 316 fi
 317
 318 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 319
 320 # We already have this in Makefile.win32, but configure needs it too
 321 if test "$PORTNAME" = "win32"; then
 322   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 323 fi
 324
 325 # Check if the compiler still works with the template settings
 326 AC_MSG_CHECKING([whether the C compiler still works])
 327 AC_TRY_LINK([], [return 0;],
 328   [AC_MSG_RESULT(yes)],
 329   [AC_MSG_RESULT(no)
 330    AC_MSG_ERROR([cannot proceed])])
 331
 332 # Defend against gcc -ffast-math
 333 if test "$GCC" = yes; then
 334 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 335 choke me
 336 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 337 fi
 338
 339 AC_PROG_CPP
 340 AC_SUBST(GCC)
 341
 342 # Create compiler version string
 343 if test x"$GCC" = x"yes" ; then
 344   cc_string="GCC `${CC} --version | sed q`"
 345 else
 346   cc_string=$CC
 347 fi
 348 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 349                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 350                    [A string containing the version number, platform, and C compiler])
 351
 352
 353 #
 354 # Set up TAS assembly code if needed; the template file has now had its
 355 # chance to request this.
 356 #
 357 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 358
 359 if test "$need_tas" = yes ; then
 360   TAS=tas.o
 361 else
 362   TAS=""
 363 fi
 364 AC_SUBST(TAS)
 365
 366
 367 #
 368 # Automatic dependency tracking
 369 #
 370 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 371               [autodepend=yes])
 372 AC_SUBST(autodepend)
 373
 374
 375 #
 376 # Enable assert checks
 377 #
 378 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 379               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 380                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 381
 382
 383 #
 384 # Include directories
 385 #
 386 ac_save_IFS=$IFS
 387 IFS="${IFS}${PATH_SEPARATOR}"
 388 # SRCH_INC comes from the template file
 389 for dir in $with_includes $SRCH_INC; do
 390   if test -d "$dir"; then
 391     INCLUDES="$INCLUDES -I$dir"
 392   else
 393     AC_MSG_WARN([*** Include directory $dir does not exist.])
 394   fi
 395 done
 396 IFS=$ac_save_IFS
 397 AC_SUBST(INCLUDES)
 398
 399
 400 #
 401 # Library directories
 402 #
 403 ac_save_IFS=$IFS
 404 IFS="${IFS}${PATH_SEPARATOR}"
 405 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 406 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 407   if test -d "$dir"; then
 408     LIBDIRS="$LIBDIRS -L$dir"
 409   else
 410     AC_MSG_WARN([*** Library directory $dir does not exist.])
 411   fi
 412 done
 413 IFS=$ac_save_IFS
 414
 415 #
 416 # Enable thread-safe client libraries
 417 #
 418 AC_MSG_CHECKING([allow thread-safe client libraries])
 419 if test "$PORTNAME" != "win32"; then
 420 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 421 else
 422 # Win32 should always use threads
 423 PGAC_ARG_BOOL(enable, thread-safety, yes, [  --enable-thread-safety  make client libraries thread-safe])
 424 fi
 425
 426 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety despite thread test failure])
 427 if test "$enable_thread_safety" = yes -o \
 428         "$enable_thread_safety_force" = yes; then
 429   enable_thread_safety="yes"    # for 'force'
 430   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 431           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 432 fi
 433 AC_MSG_RESULT([$enable_thread_safety])
 434 AC_SUBST(enable_thread_safety)
 435
 436 #
 437 # Optionally build Tcl modules (PL/Tcl)
 438 #
 439 AC_MSG_CHECKING([whether to build with Tcl])
 440 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 441 AC_MSG_RESULT([$with_tcl])
 442 AC_SUBST([with_tcl])
 443
 444 # We see if the path to the Tcl/Tk configuration scripts is specified.
 445 # This will override the use of tclsh to find the paths to search.
 446
 447 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 448
 449 #
 450 # Optionally build Perl modules (PL/Perl)
 451 #
 452 AC_MSG_CHECKING([whether to build Perl modules])
 453 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 454 AC_MSG_RESULT([$with_perl])
 455 AC_SUBST(with_perl)
 456
 457 #
 458 # Optionally build Python modules (PL/Python)
 459 #
 460 AC_MSG_CHECKING([whether to build Python modules])
 461 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 462 AC_MSG_RESULT([$with_python])
 463 AC_SUBST(with_python)
 464
 465 #
 466 # GSSAPI
 467 #
 468 AC_MSG_CHECKING([whether to build with GSSAPI support])
 469 PGAC_ARG_BOOL(with, gssapi, no, [  --with-gssapi           build with GSSAPI support],
 470 [
 471   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 472   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 473 ])
 474 AC_MSG_RESULT([$with_gssapi])
 475 AC_SUBST(with_gssapi)
 476
 477 #
 478 # Kerberos 5
 479 #
 480 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 481 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 482 [
 483   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 484   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 485 ])
 486 AC_MSG_RESULT([$with_krb5])
 487 AC_SUBST(with_krb5)
 488
 489
 490 AC_SUBST(krb_srvtab)
 491
 492
 493 #
 494 # Kerberos configuration parameters
 495 #
 496 PGAC_ARG_REQ(with, krb-srvnam,
 497              [  --with-krb-srvnam=NAME  default service principal name in Kerberos [[postgres]]],
 498              [],
 499              [with_krb_srvnam="postgres"])
 500 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 501                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 502
 503
 504 #
 505 # PAM
 506 #
 507 AC_MSG_CHECKING([whether to build with PAM support])
 508 PGAC_ARG_BOOL(with, pam, no,
 509               [  --with-pam              build with PAM support],
 510               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 511 AC_MSG_RESULT([$with_pam])
 512 AC_SUBST(with_pam)
 513
 514
 515 #
 516 # LDAP
 517 #
 518 AC_MSG_CHECKING([whether to build with LDAP support])
 519 PGAC_ARG_BOOL(with, ldap, no,
 520               [  --with-ldap             build with LDAP support],
 521               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 522 AC_MSG_RESULT([$with_ldap])
 523 AC_SUBST(with_ldap)
 524
 525
 526 #
 527 # Bonjour
 528 #
 529 AC_MSG_CHECKING([whether to build with Bonjour support])
 530 PGAC_ARG_BOOL(with, bonjour, no,
 531               [  --with-bonjour          build with Bonjour support],
 532               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 533 AC_MSG_RESULT([$with_bonjour])
 534 AC_SUBST(with_bonjour)
 535
 536
 537 #
 538 # OpenSSL
 539 #
 540 AC_MSG_CHECKING([whether to build with OpenSSL support])
 541 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 542               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 543 AC_MSG_RESULT([$with_openssl])
 544 AC_SUBST(with_openssl)
 545
 546
 547 #
 548 # Readline
 549 #
 550 PGAC_ARG_BOOL(with, readline, yes,
 551               [  --without-readline      do not use GNU Readline nor BSD Libedit for editing])
 552 # readline on MinGW has problems with backslashes in psql and other bugs.
 553 # This is particularly a problem with non-US code pages.
 554 # Therefore disable its use until we understand the cause. 2004-07-20
 555 if test "$PORTNAME" = "win32"; then
 556   if test "$with_readline" = yes; then
 557     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 558     with_readline=no
 559   fi
 560 fi
 561
 562
 563 #
 564 # Prefer libedit
 565 #
 566 PGAC_ARG_BOOL(with, libedit-preferred, no,
 567               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 568
 569
 570 #
 571 # OSSP UUID library
 572 #
 573 PGAC_ARG_BOOL(with, ossp-uuid, no, [  --with-ossp-uuid        build with OSSP UUID library for UUID generation])
 574 AC_SUBST(with_ossp_uuid)
 575
 576
 577 #
 578 # XML
 579 #
 580 PGAC_ARG_BOOL(with, libxml, no, [  --with-libxml           build with XML support],
 581               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 582
 583 if test "$with_libxml" = yes ; then
 584   AC_CHECK_PROGS(XML2_CONFIG, xml2-config)
 585   if test -n "$XML2_CONFIG"; then
 586     for pgac_option in `$XML2_CONFIG --cflags`; do
 587       case $pgac_option in
 588         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 589       esac
 590     done
 591     for pgac_option in `$XML2_CONFIG --libs`; do
 592       case $pgac_option in
 593         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 594       esac
 595     done
 596   fi
 597 fi
 598
 599 AC_SUBST(with_libxml)
 600
 601 #
 602 # XSLT
 603 #
 604 PGAC_ARG_BOOL(with, libxslt, no, [  --with-libxslt          build with XSLT support],
 605               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to build with XSLT support. (--with-libxslt)])])
 606
 607
 608 AC_SUBST(with_libxslt)
 609
 610 #
 611 # Zlib
 612 #
 613 PGAC_ARG_BOOL(with, zlib, yes,
 614               [  --without-zlib          do not use Zlib])
 615 AC_SUBST(with_zlib)
 616
 617 #
 618 # Elf
 619 #
 620
 621 # Assume system is ELF if it predefines __ELF__ as 1,
 622 # otherwise believe host_os based default.
 623 case $host_os in
 624     freebsd1*|freebsd2*) elf=no;;
 625     freebsd3*|freebsd4*) elf=yes;;
 626 esac
 627
 628 AC_EGREP_CPP(yes,
 629 [#if __ELF__
 630   yes
 631 #endif
 632 ],
 633 [ELF_SYS=true],
 634 [if test "X$elf" = "Xyes" ; then
 635   ELF_SYS=true
 636 else
 637   ELF_SYS=
 638 fi])
 639 AC_SUBST(ELF_SYS)
 640
 641 #
 642 # Assignments
 643 #
 644
 645 CPPFLAGS="$CPPFLAGS $INCLUDES"
 646 LDFLAGS="$LDFLAGS $LIBDIRS"
 647
 648 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 649 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 650
 651 AC_ARG_VAR(LDFLAGS_SL)
 652
 653 AC_PROG_AWK
 654 PGAC_PATH_FLEX
 655 AC_PROG_LN_S
 656 PGAC_PROG_LD
 657 AC_SUBST(LD)
 658 AC_SUBST(with_gnu_ld)
 659 case $host_os in sysv5*)
 660   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 661   [
 662     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 663     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 664     LDFLAGS=$pgac_save_LDFLAGS
 665   ])
 666   ld_R_works=$pgac_cv_prog_ld_R
 667   AC_SUBST(ld_R_works)
 668 esac
 669 AC_PROG_RANLIB
 670 AC_PATH_PROG(TAR, tar)
 671 PGAC_CHECK_STRIP
 672
 673 if test -z "$YACC"; then
 674   AC_CHECK_PROGS(YACC, ['bison -y'])
 675
 676   if test "$YACC"; then
 677     if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 678       AC_MSG_WARN([
 679 *** The installed version of Bison is too old to use with PostgreSQL.
 680 *** Bison version 1.875 or later is required.])
 681       YACC=""
 682     fi
 683   fi
 684
 685   if test -z "$YACC"; then
 686     AC_MSG_WARN([
 687 *** Without Bison you will not be able to build PostgreSQL from CVS nor
 688 *** change any of the parser definition files.  You can obtain Bison from
 689 *** a GNU mirror site.  (If you are using the official distribution of
 690 *** PostgreSQL then you do not need to worry about this, because the Bison
 691 *** output is pre-generated.)  To use a different yacc program (possible,
 692 *** but not recommended), set the environment variable YACC before running
 693 *** 'configure'.])
 694   fi
 695 fi
 696 AC_SUBST(YFLAGS)
 697
 698 PGAC_PATH_PERL
 699 if test "$with_perl" = yes; then
 700   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 701   PGAC_CHECK_PERL_EMBED_LDFLAGS
 702 fi
 703
 704 if test "$with_python" = yes; then
 705   PGAC_PATH_PYTHON
 706   PGAC_CHECK_PYTHON_EMBED_SETUP
 707 fi
 708
 709 # Supply a numeric version string for use by 3rd party add-ons
 710 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 711 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 712 tr '.' '        ' |
 713 $AWK '{printf "%d%02d%02d", $1, $2, (NF >= 3) ? $3 : 0}'`"]
 714 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 715
 716 ##
 717 ## Libraries
 718 ##
 719 ## Most libraries are included only if they demonstrably provide a function
 720 ## we need, but libm is an exception: always include it, because there are
 721 ## too many compilers that play cute optimization games that will break
 722 ## probes for standard functions such as pow().
 723 ##
 724
 725 AC_CHECK_LIB(m, main)
 726 AC_SEARCH_LIBS(setproctitle, util)
 727 AC_SEARCH_LIBS(dlopen, dl)
 728 AC_SEARCH_LIBS(socket, [socket wsock32])
 729 AC_SEARCH_LIBS(shl_load, dld)
 730 # We only use libld in port/dynloader/aix.c
 731 case $host_os in
 732      aix*)
 733         AC_SEARCH_LIBS(ldopen, ld)
 734         ;;
 735 esac
 736 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 737 AC_SEARCH_LIBS(crypt, crypt)
 738 # Solaris:
 739 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 740 # Cygwin:
 741 AC_SEARCH_LIBS(shmget, cygipc)
 742
 743 if test "$with_readline" = yes; then
 744   PGAC_CHECK_READLINE
 745   if test x"$pgac_cv_check_readline" = x"no"; then
 746     AC_MSG_ERROR([readline library not found
 747 If you have readline already installed, see config.log for details on the
 748 failure.  It is possible the compiler isn't looking in the proper directory.
 749 Use --without-readline to disable readline support.])
 750   fi
 751 fi
 752
 753 if test "$with_zlib" = yes; then
 754   AC_CHECK_LIB(z, inflate, [],
 755                [AC_MSG_ERROR([zlib library not found
 756 If you have zlib already installed, see config.log for details on the
 757 failure.  It is possible the compiler isn't looking in the proper directory.
 758 Use --without-zlib to disable zlib support.])])
 759 fi
 760
 761 if test "$enable_spinlocks" = yes; then
 762   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 763 else
 764   AC_MSG_WARN([
 765 *** Not using spinlocks will cause poor performance.])
 766 fi
 767
 768 if test "$with_gssapi" = yes ; then
 769   if test "$PORTNAME" != "win32"; then
 770     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 'gssapi -lkrb5 -lcrypto'], [],
 771                                   [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
 772   else
 773     LIBS="$LIBS -lgssapi32"
 774   fi
 775 fi
 776
 777 if test "$with_krb5" = yes ; then
 778   if test "$PORTNAME" != "win32"; then
 779      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken' com_err], [],
 780                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 781      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -lcrypto -ldes -lasn1 -lroken'], [],
 782                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 783   else
 784      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 785                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 786   fi
 787 fi
 788
 789 if test "$with_openssl" = yes ; then
 790   dnl Order matters!
 791   if test "$PORTNAME" != "win32"; then
 792      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 793      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 794   else
 795      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 796      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 797   fi
 798 fi
 799
 800 if test "$with_pam" = yes ; then
 801   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 802 fi
 803
 804 if test "$with_libxml" = yes ; then
 805   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
 806 fi
 807
 808 if test "$with_libxslt" = yes ; then
 809   AC_CHECK_LIB(xslt, xsltLibxmlVersion, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
 810 fi
 811
 812
 813 ##
 814 ## Header files
 815 ##
 816
 817 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 818 AC_CHECK_HEADERS([crypt.h dld.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/tas.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 819
 820 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 821 # netinet/in.h is included first.
 822 AC_CHECK_HEADERS(netinet/in.h)
 823 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 824 [AC_INCLUDES_DEFAULT
 825 #ifdef HAVE_NETINET_IN_H
 826 #include <netinet/in.h>
 827 #endif
 828 ])
 829
 830 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 831   AC_CHECK_HEADERS(readline/readline.h, [],
 832         [AC_CHECK_HEADERS(readline.h, [],
 833                 [AC_MSG_ERROR([readline header not found
 834 If you have readline already installed, see config.log for details on the
 835 failure.  It is possible the compiler isn't looking in the proper directory.
 836 Use --without-readline to disable readline support.])])])
 837   AC_CHECK_HEADERS(readline/history.h, [],
 838         [AC_CHECK_HEADERS(history.h, [],
 839                 [AC_MSG_ERROR([history header not found
 840 If you have readline already installed, see config.log for details on the
 841 failure.  It is possible the compiler isn't looking in the proper directory.
 842 Use --without-readline to disable readline support.])])])
 843 fi
 844
 845 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 846 # Some installations of libedit usurp /usr/include/readline/, which seems
 847 # bad practice, since in combined installations readline will have its headers
 848 # there.  We might have to resort to AC_EGREP checks to make sure we found
 849 # the proper header...
 850   AC_CHECK_HEADERS(editline/readline.h, [],
 851         [AC_CHECK_HEADERS(readline.h, [],
 852                 [AC_CHECK_HEADERS(readline/readline.h, [],
 853                         [AC_MSG_ERROR([readline header not found
 854 If you have libedit already installed, see config.log for details on the
 855 failure.  It is possible the compiler isn't looking in the proper directory.
 856 Use --without-readline to disable libedit support.])])])])
 857 # Note: in a libedit installation, history.h is sometimes a dummy, and may
 858 # not be there at all.  Hence, don't complain if not found.  We must check
 859 # though, since in yet other versions it is an independent header.
 860   AC_CHECK_HEADERS(editline/history.h, [],
 861         [AC_CHECK_HEADERS(history.h, [],
 862                 [AC_CHECK_HEADERS(readline/history.h)])])
 863 fi
 864
 865 if test "$with_zlib" = yes; then
 866   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 867 If you have zlib already installed, see config.log for details on the
 868 failure.  It is possible the compiler isn't looking in the proper directory.
 869 Use --without-zlib to disable zlib support.])])
 870 fi
 871
 872 if test "$with_gssapi" = yes ; then
 873   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
 874         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
 875 fi
 876
 877 if test "$with_krb5" = yes ; then
 878   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 879 fi
 880
 881 if test "$with_openssl" = yes ; then
 882   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 883   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 884 fi
 885
 886 if test "$with_pam" = yes ; then
 887   AC_CHECK_HEADERS(security/pam_appl.h, [],
 888                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 889                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 890 fi
 891
 892 if test "$with_libxml" = yes ; then
 893   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
 894 fi
 895
 896 if test "$with_libxslt" = yes ; then
 897   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
 898 fi
 899
 900 if test "$with_ldap" = yes ; then
 901   if test "$PORTNAME" != "win32"; then
 902      AC_CHECK_HEADERS(ldap.h, [],
 903                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 904   else
 905      AC_CHECK_HEADERS(winldap.h, [],
 906                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 907                       [AC_INCLUDES_DEFAULT
 908 #include <windows.h>
 909                       ])
 910   fi
 911 fi
 912
 913 if test "$with_bonjour" = yes ; then
 914   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 915 fi
 916
 917
 918 ##
 919 ## Types, structures, compiler characteristics
 920 ##
 921
 922 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 923 AC_C_BIGENDIAN
 924 AC_C_CONST
 925 AC_C_INLINE
 926 AC_C_STRINGIZE
 927 PGAC_C_SIGNED
 928 AC_C_VOLATILE
 929 PGAC_C_FUNCNAME_SUPPORT
 930 PGAC_STRUCT_TIMEZONE
 931 PGAC_UNION_SEMUN
 932 PGAC_STRUCT_SOCKADDR_UN
 933 PGAC_STRUCT_SOCKADDR_STORAGE
 934 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 935 PGAC_STRUCT_ADDRINFO
 936
 937 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 938 [#include <sys/param.h>
 939 #include <sys/types.h>
 940 #include <sys/socket.h>
 941 #include <sys/ucred.h>])
 942
 943 AC_CHECK_TYPES([struct option], [], [],
 944 [#ifdef HAVE_GETOPT_H
 945 #include <getopt.h>
 946 #endif])
 947
 948 if test "$with_zlib" = yes; then
 949   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 950   # did not).  While we could work around the lack of z_streamp, it
 951   # seems unwise to encourage people to use such old zlib versions...
 952   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 953 Use --without-zlib to disable zlib support.])],
 954                 [#include <zlib.h>])
 955 fi
 956
 957 if test "$with_krb5" = yes; then
 958 # Check for differences between MIT and Heimdal (KTH) releases
 959   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 960                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 961                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 962                                      [#include <krb5.h>])],
 963                    [#include <krb5.h>])
 964   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 965                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 966                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 967                                      [#include <krb5.h>])],
 968                    [#include <krb5.h>])
 969
 970 # Win32 requires headers to be loaded for __stdcall, so can't use
 971 # AC_CHECK_FUNCS here.
 972   AC_MSG_CHECKING(for krb5_free_unparsed_name)
 973   AC_TRY_LINK([#include <krb5.h>],
 974               [krb5_free_unparsed_name(NULL,NULL);],
 975               [AC_DEFINE(HAVE_KRB5_FREE_UNPARSED_NAME, 1, [Define to 1 if you have krb5_free_unparsed_name])
 976 AC_MSG_RESULT(yes)],
 977               [AC_MSG_RESULT(no)])
 978 fi
 979
 980
 981 ##
 982 ## Functions, global variables
 983 ##
 984
 985 PGAC_VAR_INT_TIMEZONE
 986 AC_FUNC_ACCEPT_ARGTYPES
 987 PGAC_FUNC_GETTIMEOFDAY_1ARG
 988
 989 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid getrlimit memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 990
 991 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 992 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
 993 AC_CHECK_DECLS([strlcat, strlcpy])
 994 # This is probably only present on Darwin, but may as well check always
 995 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 996
 997 HAVE_IPV6=no
 998 AC_CHECK_TYPE([struct sockaddr_in6],
 999         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1000          HAVE_IPV6=yes],
1001         [],
1002 [$ac_includes_default
1003 #include <netinet/in.h>])
1004 AC_SUBST(HAVE_IPV6)
1005
1006 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1007 [AC_TRY_LINK(
1008 [#include <machine/vmparam.h>
1009 #include <sys/exec.h>
1010 ],
1011 [PS_STRINGS->ps_nargvstr = 1;
1012 PS_STRINGS->ps_argvstr = "foo";],
1013 [pgac_cv_var_PS_STRINGS=yes],
1014 [pgac_cv_var_PS_STRINGS=no])])
1015 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1016   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
1017 fi
1018
1019
1020 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1021 # is missing.  Yes, there are machines that have only one.  We may
1022 # also decide to use snprintf.c if snprintf() is present but does not
1023 # have all the features we need --- see below.
1024
1025 if test "$PORTNAME" = "win32"; then
1026   # Win32 gets snprintf.c built unconditionally.
1027   #
1028   # To properly translate all NLS languages strings, we must support the
1029   # *printf() %$ format, which allows *printf() arguments to be selected
1030   # by position in the translated string.
1031   #
1032   # libintl versions < 0.13 use the native *printf() functions, and Win32
1033   # *printf() doesn't understand %$, so we must use our /port versions,
1034   # which do understand %$. libintl versions >= 0.13 include their own
1035   # *printf versions on Win32.  The libintl 0.13 release note text is:
1036   #
1037   #   C format strings with positions, as they arise when a translator
1038   #   needs to reorder a sentence, are now supported on all platforms.
1039   #   On those few platforms (NetBSD and Woe32) for which the native
1040   #   printf()/fprintf()/... functions don't support such format
1041   #   strings, replacements are provided through <libintl.h>.
1042   #
1043   # We could use libintl >= 0.13's *printf() if we were sure that we had
1044   # a litint >= 0.13 at runtime, but seeing that there is no clean way
1045   # to guarantee that, it is best to just use our own, so we are sure to
1046   # get %$ support. In include/port.h we disable the *printf() macros
1047   # that might have been defined by libintl.
1048   #
1049   # We do this unconditionally whether NLS is used or not so we are sure
1050   # that all Win32 libraries and binaries behave the same.
1051   pgac_need_repl_snprintf=yes
1052 else
1053   pgac_need_repl_snprintf=no
1054   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1055   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1056 fi
1057
1058
1059 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1060 # include/c.h will provide declarations.  Note this is a separate test
1061 # from whether the functions exist in the C library --- there are
1062 # systems that have the functions but don't bother to declare them :-(
1063
1064 AC_CHECK_DECLS([snprintf, vsnprintf])
1065
1066
1067 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1068 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1069 [AC_TRY_LINK([
1070 #include <math.h>
1071 double glob_double;
1072 ],
1073 [return isinf(glob_double) ? 0 : 1;],
1074 [ac_cv_func_isinf=yes],
1075 [ac_cv_func_isinf=no])])
1076
1077 if test $ac_cv_func_isinf = yes ; then
1078   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1079 else
1080   AC_LIBOBJ(isinf)
1081   # Look for a way to implement a substitute for isinf()
1082   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1083 fi
1084
1085 # Some versions of libedit contain strlcpy(); so disregard that library while
1086 # checking for these standard libc functions.
1087 pgac_save_LIBS="$LIBS"
1088 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1089
1090 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strlcat strlcpy strtol strtoul unsetenv])
1091
1092 LIBS="$pgac_save_LIBS"
1093
1094 # System's version of getaddrinfo(), if any, may be used only if we found
1095 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1096 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
1097 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
1098 # because we want to use our own getaddrinfo.c on Windows anyway.)
1099 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
1100   AC_REPLACE_FUNCS([getaddrinfo])
1101 else
1102   AC_LIBOBJ(getaddrinfo)
1103 fi
1104
1105 # similarly, use system's getopt_long() only if system provides struct option.
1106 if test x"$ac_cv_type_struct_option" = xyes ; then
1107   AC_REPLACE_FUNCS([getopt_long])
1108 else
1109   AC_LIBOBJ(getopt_long)
1110 fi
1111
1112 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
1113 # We override the previous test that said fseeko/ftello didn't exist
1114 # OS tests are also done in include/c.h and port/fseeko.c
1115 case $host_os in bsdi*|netbsd*)
1116 ac_cv_func_fseeko=yes
1117 esac
1118
1119 # Win32 support
1120 if test "$PORTNAME" = "win32"; then
1121 AC_LIBOBJ(gettimeofday)
1122 AC_LIBOBJ(kill)
1123 AC_LIBOBJ(open)
1124 AC_LIBOBJ(rand)
1125 AC_LIBOBJ(win32error)
1126 AC_DEFINE([HAVE_SYMLINK], 1,
1127           [Define to 1 if you have the `symlink' function.])
1128 fi
1129
1130 if test "$with_readline" = yes; then
1131   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1132   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1133   AC_CHECK_FUNCS([replace_history_entry])
1134 fi
1135
1136
1137 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1138 dnl (especially on GNU libc)
1139 dnl See also comments in c.h.
1140 AC_MSG_CHECKING(for sigsetjmp)
1141 AC_TRY_LINK([#include <setjmp.h>],
1142             [sigjmp_buf x; sigsetjmp(x, 1);],
1143             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1144 AC_MSG_RESULT(yes)],
1145             [AC_MSG_RESULT(no)])
1146
1147 AC_DECL_SYS_SIGLIST
1148
1149 AC_CHECK_FUNC(syslog,
1150               [AC_CHECK_HEADER(syslog.h,
1151                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1152
1153 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1154 [AC_TRY_LINK([#include <unistd.h>],
1155   [extern int optreset; optreset = 1;],
1156   [pgac_cv_var_int_optreset=yes],
1157   [pgac_cv_var_int_optreset=no])])
1158 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1159   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1160 fi
1161
1162 AC_CHECK_FUNCS([strtoll strtoq], [break])
1163 AC_CHECK_FUNCS([strtoull strtouq], [break])
1164
1165 # Check for one of atexit() or on_exit()
1166 AC_CHECK_FUNCS(atexit, [],
1167                [AC_CHECK_FUNCS(on_exit, [],
1168                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1169
1170 AC_FUNC_FSEEKO
1171
1172 #
1173 # Pthreads
1174 #
1175 # For each platform, we need to know about any special compile and link
1176 # libraries, and whether the normal C function names are thread-safe.
1177 # See the comment at the top of src/port/thread.c for more information.
1178 # WIN32 doesn't need the pthread tests;  it always uses threads
1179 if test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"; then
1180 ACX_PTHREAD     # set thread flags
1181
1182 # Some platforms use these, so just defineed them.  They can't hurt if they
1183 # are not supported.
1184 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1185
1186
1187 # At this point, we don't want to muck with the compiler name for threading.
1188 # Let's see who fails, perhaps AIX.  2004-04-23
1189 if test "$PTHREAD_CC" != "$CC"; then
1190 AC_MSG_ERROR([
1191 PostgreSQL does not support platforms that require a special compiler
1192 for thread safety.])
1193 fi
1194
1195 if test "$THREAD_SUPPORT" = no; then
1196 AC_MSG_ERROR([cannot enable threads on this platform
1197 This platform is known to not support thread-safe programs.  For details,
1198 compile and run src/bin/pg_thread_test.])
1199 fi
1200
1201 # Check for *_r functions
1202 _CFLAGS="$CFLAGS"
1203 _LIBS="$LIBS"
1204 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1205 LIBS="$LIBS $PTHREAD_LIBS"
1206
1207 if test "$PORTNAME" != "win32"; then
1208 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1209 fi
1210
1211 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1212
1213 # Do test here with the proper thread flags
1214 PGAC_FUNC_GETPWUID_R_5ARG
1215 PGAC_FUNC_STRERROR_R_INT
1216
1217 CFLAGS="$_CFLAGS"
1218 LIBS="$_LIBS"
1219
1220 else
1221 # do not use values from template file
1222 PTHREAD_CFLAGS=
1223 PTHREAD_LIBS=
1224 fi
1225
1226 AC_SUBST(PTHREAD_CFLAGS)
1227 AC_SUBST(PTHREAD_LIBS)
1228
1229
1230 # We can test for libldap_r only after we know PTHREAD_LIBS
1231 if test "$with_ldap" = yes ; then
1232   _LIBS="$LIBS"
1233   if test "$PORTNAME" != "win32"; then
1234     AC_CHECK_LIB(ldap, ldap_bind, [],
1235                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1236                  [$EXTRA_LDAP_LIBS])
1237     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1238     if test "$enable_thread_safety" = yes; then
1239       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1240       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1241                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1242                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1243       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1244     else
1245       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1246     fi
1247   else
1248     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1249     LDAP_LIBS_FE="-lwldap32"
1250     LDAP_LIBS_BE="-lwldap32"
1251   fi
1252   LIBS="$_LIBS"
1253 fi
1254 AC_SUBST(LDAP_LIBS_FE)
1255 AC_SUBST(LDAP_LIBS_BE)
1256
1257
1258 # This test makes sure that run tests work at all.  Sometimes a shared
1259 # library is found by the linker, but the runtime linker can't find it.
1260 # This check should come after all modifications of compiler or linker
1261 # variables, and before any other run tests.
1262 AC_MSG_CHECKING([test program])
1263 AC_TRY_RUN([int main() { return 0; }],
1264 [AC_MSG_RESULT(ok)],
1265 [AC_MSG_RESULT(failed)
1266 AC_MSG_ERROR([[
1267 Could not execute a simple test program.  This may be a problem
1268 related to locating shared libraries.  Check the file 'config.log'
1269 for the exact reason.]])],
1270 [AC_MSG_RESULT([cross-compiling])])
1271
1272 # --------------------
1273 # Run tests below here
1274 # --------------------
1275
1276 # Force use of our snprintf if system's doesn't do arg control
1277 # See comment above at snprintf test for details.
1278 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1279   PGAC_FUNC_PRINTF_ARG_CONTROL
1280   if test $pgac_cv_printf_arg_control != yes ; then
1281     pgac_need_repl_snprintf=yes
1282   fi
1283 fi
1284
1285
1286 dnl Check to see if we have a working 64-bit integer type.
1287 dnl This breaks down into two steps:
1288 dnl (1) figure out if the compiler has a 64-bit int type with working
1289 dnl arithmetic, and if so
1290 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1291 dnl snprintf is the only library routine we really need for int8 support.)
1292 dnl It's entirely possible to have a compiler that handles a 64-bit type
1293 dnl when the C library doesn't; this is fairly likely when using gcc on
1294 dnl an older platform, for example.
1295 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1296 dnl we force our own version of snprintf() to be used instead.
1297 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1298
1299 PGAC_TYPE_64BIT_INT([long int])
1300
1301 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1302   PGAC_TYPE_64BIT_INT([long long int])
1303 fi
1304
1305
1306 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1307
1308 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1309   AC_TRY_COMPILE([
1310 #define INT64CONST(x)  x##LL
1311 long long int foo = INT64CONST(0x1234567890123456);
1312 ],
1313         [],
1314         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1315         [])
1316 fi
1317
1318
1319 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1320 # we found we need to use "long long int", better check.  We cope with
1321 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1322 # work, fall back to our own snprintf emulation (which we know uses %lld).
1323
1324 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1325   if test $pgac_need_repl_snprintf = no; then
1326     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1327     if test "$LONG_LONG_INT_FORMAT" = ""; then
1328       # Force usage of our own snprintf, since system snprintf is broken
1329       pgac_need_repl_snprintf=yes
1330       LONG_LONG_INT_FORMAT='%lld'
1331     fi
1332   else
1333     # Here if we previously decided we needed to use our own snprintf
1334     LONG_LONG_INT_FORMAT='%lld'
1335   fi
1336   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1337   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1338   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1339 else
1340   # Here if we are not using 'long long int' at all
1341   INT64_FORMAT='"%ld"'
1342   UINT64_FORMAT='"%lu"'
1343 fi
1344
1345 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1346                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1347
1348 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1349                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1350
1351 # Now we have checked all the reasons to replace snprintf
1352 if test $pgac_need_repl_snprintf = yes; then
1353   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1354   AC_LIBOBJ(snprintf)
1355 fi
1356
1357 # Need a #define for the size of Datum (unsigned long)
1358 AC_CHECK_SIZEOF([unsigned long])
1359
1360 # And one for the size of size_t (enables tweaks for > 32bit address space)
1361 AC_CHECK_SIZEOF([size_t])
1362
1363 # Determine memory alignment requirements for the basic C data types.
1364
1365 PGAC_CHECK_ALIGNOF(short)
1366 PGAC_CHECK_ALIGNOF(int)
1367 PGAC_CHECK_ALIGNOF(long)
1368 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1369   PGAC_CHECK_ALIGNOF(long long int)
1370 fi
1371 PGAC_CHECK_ALIGNOF(double)
1372
1373 # Compute maximum alignment of any basic type.
1374 # We assume long's alignment is at least as strong as char, short, or int;
1375 # but we must check long long (if it exists) and double.
1376
1377 MAX_ALIGNOF=$pgac_cv_alignof_long
1378 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1379   MAX_ALIGNOF=$pgac_cv_alignof_double
1380 fi
1381 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1382   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1383 fi
1384 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1385
1386
1387 # Some platforms predefine the types int8, int16, etc.  Only check
1388 # a (hopefully) representative subset.
1389 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1390 [#include <stdio.h>
1391 #ifdef HAVE_SUPPORTDEFS_H
1392 #include <SupportDefs.h>
1393 #endif])
1394
1395 # We also check for sig_atomic_t, which *should* be defined per ANSI
1396 # C, but is missing on some old platforms.
1397 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1398
1399
1400 if test "$PORTNAME" != "win32"
1401 then
1402 PGAC_FUNC_POSIX_SIGNALS
1403 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1404   AC_MSG_ERROR([
1405 Thread-safety requires POSIX signals, which are not supported by this
1406 operating system.])
1407 fi
1408 fi
1409
1410 if test $ac_cv_func_fseeko = yes; then
1411 AC_SYS_LARGEFILE
1412 fi
1413
1414 # SunOS doesn't handle negative byte comparisons properly with +/- return
1415 AC_FUNC_MEMCMP
1416
1417
1418 # Select semaphore implementation type.
1419 if test "$PORTNAME" != "win32"; then
1420   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1421     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1422     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1423   else
1424     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1425       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1426       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1427     else
1428       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1429       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1430     fi
1431   fi
1432 else
1433   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
1434   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
1435 fi
1436
1437
1438 # Select shared-memory implementation type.
1439 if test "$PORTNAME" != "win32"; then
1440   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1441   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1442 else
1443   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
1444   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
1445 fi
1446
1447 # If not set in template file, set bytes to use libc memset()
1448 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1449   MEMSET_LOOP_LIMIT=1024
1450 fi
1451 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1452
1453
1454 if test "$enable_nls" = yes ; then
1455   PGAC_CHECK_GETTEXT
1456 fi
1457
1458 # Check for Tcl configuration script tclConfig.sh
1459 if test "$with_tcl" = yes; then
1460     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1461     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1462                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1463     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1464     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1465     ac_save_CPPFLAGS=$CPPFLAGS
1466     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1467     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1468     CPPFLAGS=$ac_save_CPPFLAGS
1469 fi
1470
1471 #
1472 # Check for DocBook and tools
1473 #
1474 PGAC_PROG_NSGMLS
1475 PGAC_PROG_JADE
1476 PGAC_CHECK_DOCBOOK(4.2)
1477 PGAC_PATH_DOCBOOK_STYLESHEETS
1478 PGAC_PATH_COLLATEINDEX
1479 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1480
1481 # Thread testing
1482
1483 # We have to run the thread test near the end so we have all our symbols
1484 # defined.  Cross compiling throws a warning.
1485 #
1486 if test "$enable_thread_safety_force" = yes; then
1487 if test "$PORTNAME" != "win32"
1488 then
1489   AC_MSG_WARN([
1490 *** Skipping thread test program.  --enable-thread-safety-force was used.
1491 *** Run the program in src/test/thread on the your machine and add proper
1492 *** locking function calls to your applications to guarantee thread safety.
1493 ])
1494 else
1495 AC_MSG_WARN([*** skipping thread test on Win32])
1496 fi
1497 elif test "$enable_thread_safety" = yes; then
1498 if test "$PORTNAME" != "win32"
1499 then
1500 AC_MSG_CHECKING([thread safety of required library functions])
1501
1502 _CFLAGS="$CFLAGS"
1503 _LIBS="$LIBS"
1504 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1505 LIBS="$LIBS $PTHREAD_LIBS"
1506 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1507   [AC_MSG_RESULT(yes)],
1508   [AC_MSG_RESULT(no)
1509   AC_MSG_ERROR([thread test program failed
1510 This platform is not thread-safe.  Check the file 'config.log'for the
1511 exact reason.
1512
1513 You can use the configure option --enable-thread-safety-force to force
1514 threads to be enabled.  But you must then run the program in
1515 src/test/thread and add locking function calls to your applications to
1516 guarantee thread safety.])],
1517   [AC_MSG_RESULT(maybe)
1518   AC_MSG_WARN([
1519 *** Skipping thread test program because of cross-compile build.
1520 *** Run the program in src/test/thread on the target machine.
1521 ])])
1522 CFLAGS="$_CFLAGS"
1523 LIBS="$_LIBS"
1524 else
1525 AC_MSG_WARN([*** skipping thread test on Win32])
1526 fi
1527 fi
1528
1529 # prepare build tree if outside source tree
1530 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1531 # Note 2: /bin/pwd might be better than shell's built-in at getting
1532 #         a symlink-free name.
1533 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1534   vpath_build=no
1535 else
1536   vpath_build=yes
1537   if test "$no_create" != yes; then
1538     _AS_ECHO_N([preparing build tree... ])
1539     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1540     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1541       || AC_MSG_ERROR(failed)
1542     AC_MSG_RESULT(done)
1543   fi
1544 fi
1545 AC_SUBST(vpath_build)
1546
1547
1548 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1549
1550 AC_CONFIG_LINKS([
1551   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1552   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1553   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1554   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1555   src/include/pg_config_os.h:src/include/port/${template}.h
1556   src/Makefile.port:src/makefiles/Makefile.${template}
1557 ])
1558
1559 if test "$PORTNAME" = "win32"; then
1560 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1561 # Links sometimes fail undetected on Mingw -
1562 # so here we detect it and warn the user
1563 for FILE in $CONFIG_LINKS
1564  do
1565         # test -e works for symlinks in the MinGW console
1566         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
1567  done
1568 ])
1569 fi
1570
1571 AC_CONFIG_HEADERS([src/include/pg_config.h],
1572 [
1573 # Update timestamp for pg_config.h (see Makefile.global)
1574 echo >src/include/stamp-h
1575 ])
1576
1577 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h])
1578
1579 AC_OUTPUT
1580
1581 # Warn about unknown options
1582 PGAC_ARG_CHECK