granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.409 2005/05/05 19:15:54 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.1devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.53)
  23 AC_COPYRIGHT([Copyright (c) 1996-2005, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     beos*) template=beos ;;
  53     bsdi*) template=bsdi ;;
  54   cygwin*) template=cygwin ;;
  55   darwin*) template=darwin ;;
  56     dgux*) template=dgux ;;
  57  freebsd*) template=freebsd ;;
  58     hpux*) template=hpux ;;
  59     irix*) template=irix ;;
  60  linux*|gnu*|k*bsd*-gnu)
  61            template=linux ;;
  62    mingw*) template=win32 ;;
  63   netbsd*) template=netbsd ;;
  64 nextstep*) template=nextstep ;;
  65  openbsd*) template=openbsd ;;
  66      osf*) template=osf ;;
  67      qnx*) template=qnx4 ;;
  68      sco*) template=sco ;;
  69  solaris*) template=solaris ;;
  70    sunos*) template=sunos4 ;;
  71  sysv4.2*)
  72         case $host_vendor in
  73           univel) template=univel ;;
  74         esac ;;
  75    sysv4*) template=svr4 ;;
  76    sysv5*) template=unixware ;;
  77   ultrix*) template=ultrix4 ;;
  78 esac
  79
  80   if test x"$template" = x"" ; then
  81     AC_MSG_ERROR([[
  82 *******************************************************************
  83 PostgreSQL has apparently not been ported to your platform yet.
  84 To try a manual configuration, look into the src/template directory
  85 for a similar platform and use the '--with-template=' option.
  86
  87 Please also contact <pgsql-ports@postgresql.org> to see about
  88 rectifying this.  Include the above 'checking host system type...'
  89 line.
  90 *******************************************************************
  91 ]])
  92   fi
  93
  94 ])
  95
  96 AC_MSG_RESULT([$template])
  97
  98 PORTNAME=$template
  99 AC_SUBST(PORTNAME)
 100
 101 # Initialize default assumption that we do not need separate assembly code
 102 # for TAS (test-and-set).  This can be overridden by the template file
 103 # when it's executed.
 104 need_tas=no
 105 tas_file=dummy.s
 106
 107
 108
 109 ##
 110 ## Command line options
 111 ##
 112
 113 #
 114 # Installation directory for documentation
 115 #
 116 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 117   --without-docdir        do not install the documentation],
 118          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 119          [docdir=],
 120          [docdir=$withval],
 121          [docdir='${prefix}/doc'])
 122 AC_SUBST(docdir)
 123
 124
 125 #
 126 # Add non-standard directories to the include path
 127 #
 128 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 129
 130
 131 #
 132 # Add non-standard directories to the library search path
 133 #
 134 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 135              [LIBRARY_DIRS=$withval])
 136
 137 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 138              [LIBRARY_DIRS=$withval])
 139
 140
 141 #
 142 # 64-bit integer date/time storage (--enable-integer-datetimes)
 143 #
 144 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 145 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 146               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 147                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 148 AC_MSG_RESULT([$enable_integer_datetimes])
 149
 150
 151 #
 152 # NLS
 153 #
 154 AC_MSG_CHECKING([whether NLS is wanted])
 155 PGAC_ARG_OPTARG(enable, nls,
 156                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 157                 [],
 158                 [WANTED_LANGUAGES=$enableval],
 159                 [AC_DEFINE(ENABLE_NLS, 1,
 160                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 161 AC_MSG_RESULT([$enable_nls])
 162 AC_SUBST(enable_nls)
 163 AC_SUBST(WANTED_LANGUAGES)
 164
 165 #
 166 # Default port number (--with-pgport), default 5432
 167 #
 168 AC_MSG_CHECKING([for default port number])
 169 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [5432]],
 170              [default_port=$withval],
 171              [default_port=5432])
 172 AC_MSG_RESULT([$default_port])
 173 # Need both of these because some places want an integer and some a string
 174 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 175 [Define to the default TCP port number on which the server listens and
 176 to which clients will try to connect.  This can be overridden at run-time,
 177 but it's convenient if your clients have the right default compiled in.
 178 (--with-pgport=PORTNUM)])
 179 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 180                    [Define to the default TCP port number as a string constant.])
 181 AC_SUBST(default_port)
 182
 183 #
 184 # Option to disable shared libraries
 185 #
 186 PGAC_ARG_BOOL(enable, shared, yes,
 187               [  --disable-shared        do not build shared libraries])
 188 AC_SUBST(enable_shared)
 189
 190 #
 191 # '-rpath'-like feature can be disabled
 192 #
 193 PGAC_ARG_BOOL(enable, rpath, yes,
 194               [  --disable-rpath         do not embed shared library search path in executables])
 195 AC_SUBST(enable_rpath)
 196
 197 #
 198 # Spinlocks
 199 #
 200 PGAC_ARG_BOOL(enable, spinlocks, yes,
 201               [  --disable-spinlocks     do not use spinlocks])
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [  --enable-debug          build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # C compiler
 212 #
 213
 214 # For historical reasons you can also use --with-CC to specify the C compiler
 215 # to use, although the standard way to do this is to set the CC environment
 216 # variable.
 217 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 218
 219 case $template in
 220   aix) pgac_cc_list="gcc xlc";;
 221  irix) pgac_cc_list="cc";; # no gcc
 222     *) pgac_cc_list="gcc cc";;
 223 esac
 224
 225 AC_PROG_CC([$pgac_cc_list])
 226
 227 unset CFLAGS
 228
 229 #
 230 # Read the template
 231 #
 232 . "$srcdir/src/template/$template" || exit
 233
 234 # CFLAGS are selected so:
 235 # If the user specifies something in the environment, that is used.
 236 # else:  If the template file set something, that is used.
 237 # else:  If the compiler is GCC, then we use -O2.
 238 # else:  If the compiler is something else, then we use -0.
 239
 240 if test "$ac_env_CFLAGS_set" = set; then
 241   CFLAGS=$ac_env_CFLAGS_value
 242 elif test "${CFLAGS+set}" = set; then
 243   : # (keep what template set)
 244 elif test "$GCC" = yes; then
 245   CFLAGS="-O2"
 246 else
 247   # if the user selected debug mode, don't use -O
 248   if test "$enable_debug" != yes; then
 249     CFLAGS="-O"
 250   fi
 251 fi
 252
 253 if test "$GCC" = yes; then
 254   CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith"
 255
 256   # Some versions of GCC support some additional useful warning flags.
 257   # Check whether they are supported, and add them to CFLAGS if so.
 258   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 259   PGAC_PROG_CC_CFLAGS_OPT([-Wold-style-definition])
 260   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 261
 262   # Disable strict-aliasing rules; needed for gcc 3.3+
 263   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 264 fi
 265
 266 # supply -g if --enable-debug
 267 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 268   CFLAGS="$CFLAGS -g"
 269 fi
 270
 271 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 272
 273 # We already have this in Makefile.win32, but configure needs it too
 274 if test "$PORTNAME" = "win32"; then
 275   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 276 fi
 277
 278 # Check if the compiler still works with the template settings
 279 AC_MSG_CHECKING([whether the C compiler still works])
 280 AC_TRY_LINK([], [return 0;],
 281   [AC_MSG_RESULT(yes)],
 282   [AC_MSG_RESULT(no)
 283    AC_MSG_ERROR([cannot proceed])])
 284
 285 # Defend against gcc -ffast-math
 286 if test "$GCC" = yes; then
 287 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 288 choke me
 289 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 290 fi
 291
 292 AC_PROG_CPP
 293 AC_SUBST(GCC)
 294
 295 # Create compiler version string
 296 if test x"$GCC" = x"yes" ; then
 297   cc_string="GCC `${CC} --version | sed q`"
 298 else
 299   cc_string=$CC
 300 fi
 301 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 302                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 303                    [A string containing the version number, platform, and C compiler])
 304
 305
 306 #
 307 # Set up TAS assembly code if needed; the template file has now had its
 308 # chance to request this.
 309 #
 310 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 311
 312 if test "$need_tas" = yes ; then
 313   TAS=tas.o
 314 else
 315   TAS=""
 316 fi
 317 AC_SUBST(TAS)
 318
 319
 320 #
 321 # Automatic dependency tracking
 322 #
 323 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 324               [autodepend=yes])
 325 AC_SUBST(autodepend)
 326
 327
 328 #
 329 # Enable assert checks
 330 #
 331 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 332               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 333                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 334
 335
 336 #
 337 # Include directories
 338 #
 339 ac_save_IFS=$IFS
 340 IFS="${IFS}${PATH_SEPARATOR}"
 341 # SRCH_INC comes from the template file
 342 for dir in $with_includes $SRCH_INC; do
 343   if test -d "$dir"; then
 344     INCLUDES="$INCLUDES -I$dir"
 345   else
 346     AC_MSG_WARN([*** Include directory $dir does not exist.])
 347   fi
 348 done
 349 IFS=$ac_save_IFS
 350 AC_SUBST(INCLUDES)
 351
 352
 353 #
 354 # Library directories
 355 #
 356 ac_save_IFS=$IFS
 357 IFS="${IFS}${PATH_SEPARATOR}"
 358 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 359 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 360   if test -d "$dir"; then
 361     LIBDIRS="$LIBDIRS -L$dir"
 362   else
 363     AC_MSG_WARN([*** Library directory $dir does not exist.])
 364   fi
 365 done
 366 IFS=$ac_save_IFS
 367
 368 #
 369 # Enable thread-safe client libraries
 370 #
 371 AC_MSG_CHECKING([allow thread-safe client libraries])
 372 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 373 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 374 if test "$enable_thread_safety" = yes -o \
 375         "$enable_thread_safety_force" = yes; then
 376   enable_thread_safety="yes"    # for 'force'
 377   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 378           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 379 fi
 380 AC_MSG_RESULT([$enable_thread_safety])
 381 AC_SUBST(enable_thread_safety)
 382
 383 #
 384 # Optionally build Tcl modules (PL/Tcl)
 385 #
 386 AC_MSG_CHECKING([whether to build with Tcl])
 387 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 388 AC_MSG_RESULT([$with_tcl])
 389 AC_SUBST([with_tcl])
 390
 391 # We see if the path to the Tcl/Tk configuration scripts is specified.
 392 # This will override the use of tclsh to find the paths to search.
 393
 394 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 395
 396 #
 397 # Optionally build Perl modules (PL/Perl)
 398 #
 399 AC_MSG_CHECKING([whether to build Perl modules])
 400 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 401 AC_MSG_RESULT([$with_perl])
 402 AC_SUBST(with_perl)
 403
 404 #
 405 # Optionally build Python modules (PL/Python)
 406 #
 407 AC_MSG_CHECKING([whether to build Python modules])
 408 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 409 AC_MSG_RESULT([$with_python])
 410 AC_SUBST(with_python)
 411
 412 #
 413 # Kerberos 4
 414 #
 415 AC_MSG_CHECKING([whether to build with Kerberos 4 support])
 416 PGAC_ARG_BOOL(with, krb4, no, [  --with-krb4             build with Kerberos 4 support],
 417 [
 418   AC_DEFINE(KRB4, 1, [Define to build with Kerberos 4 support. (--with-krb4)])
 419   krb_srvtab="/etc/srvtab"
 420 ])
 421 AC_MSG_RESULT([$with_krb4])
 422 AC_SUBST(with_krb4)
 423
 424
 425 #
 426 # Kerberos 5
 427 #
 428 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 429 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 430 [
 431   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 432   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 433 ])
 434 AC_MSG_RESULT([$with_krb5])
 435 AC_SUBST(with_krb5)
 436
 437
 438 # Using both Kerberos 4 and Kerberos 5 at the same time isn't going to work.
 439 if test "$with_krb4" = yes && test "$with_krb5" = yes ; then
 440   AC_MSG_ERROR([Kerberos 4 and Kerberos 5 support cannot be combined])
 441 fi
 442
 443 AC_SUBST(krb_srvtab)
 444
 445
 446 #
 447 # Kerberos configuration parameters
 448 #
 449 PGAC_ARG_REQ(with, krb-srvnam,
 450              [  --with-krb-srvnam=NAME  name of the service principal in Kerberos [[postgres]]],
 451              [],
 452              [with_krb_srvnam="postgres"])
 453 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 454                    [Define to the name of the PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 455
 456
 457 #
 458 # PAM
 459 #
 460 AC_MSG_CHECKING([whether to build with PAM support])
 461 PGAC_ARG_BOOL(with, pam, no,
 462               [  --with-pam              build with PAM support],
 463               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 464 AC_MSG_RESULT([$with_pam])
 465 AC_SUBST(with_pam)
 466
 467
 468 #
 469 # Rendezvous
 470 #
 471 AC_MSG_CHECKING([whether to build with Rendezvous support])
 472 PGAC_ARG_BOOL(with, rendezvous, no,
 473               [  --with-rendezvous       build with Rendezvous support],
 474               [AC_DEFINE([USE_RENDEZVOUS], 1, [Define to 1 to build with Rendezvous support. (--with-rendezvous)])])
 475 AC_MSG_RESULT([$with_rendezvous])
 476 AC_SUBST(with_rendezvous)
 477
 478
 479 #
 480 # OpenSSL
 481 #
 482 AC_MSG_CHECKING([whether to build with OpenSSL support])
 483 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 484               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 485 AC_MSG_RESULT([$with_openssl])
 486 AC_SUBST(with_openssl)
 487
 488
 489 #
 490 # Readline
 491 #
 492 PGAC_ARG_BOOL(with, readline, yes,
 493               [  --without-readline      do not use Readline])
 494 # readline on MinGW has problems with backslashes in psql and other bugs.
 495 # This is particularly a problem with non-US code pages.
 496 # Therefore disable its use until we understand the cause. 2004-07-20
 497 if test "$PORTNAME" = "win32"; then
 498   if test "$with_readline" = yes; then
 499     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 500     with_readline=no
 501   fi
 502 fi
 503
 504
 505 #
 506 # Zlib
 507 #
 508 PGAC_ARG_BOOL(with, zlib, yes,
 509               [  --without-zlib          do not use Zlib])
 510
 511 #
 512 # Elf
 513 #
 514
 515 # Assume system is ELF if it predefines __ELF__ as 1,
 516 # otherwise believe host_os based default.
 517 case $host_os in
 518     freebsd1*|freebsd2*) elf=no;;
 519     freebsd3*|freebsd4*) elf=yes;;
 520 esac
 521
 522 AC_EGREP_CPP(yes,
 523 [#if __ELF__
 524   yes
 525 #endif
 526 ],
 527 [ELF_SYS=true],
 528 [if test "X$elf" = "Xyes" ; then
 529   ELF_SYS=true
 530 else
 531   ELF_SYS=
 532 fi])
 533 AC_SUBST(ELF_SYS)
 534
 535 #
 536 # Assignments
 537 #
 538
 539 CPPFLAGS="$CPPFLAGS $INCLUDES"
 540 LDFLAGS="$LDFLAGS $LIBDIRS"
 541
 542 AC_ARG_VAR(LDFLAGS_SL)
 543
 544 AC_PROG_AWK
 545 PGAC_PATH_FLEX
 546 AC_PROG_LN_S
 547 PGAC_PROG_LD
 548 AC_SUBST(LD)
 549 AC_SUBST(with_gnu_ld)
 550
 551 case $host_os in sysv5*)
 552   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 553   [
 554     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 555     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 556     LDFLAGS=$pgac_save_LDFLAGS
 557   ])
 558   ld_R_works=$pgac_cv_prog_ld_R
 559   AC_SUBST(ld_R_works)
 560 esac
 561
 562 # To simplify the build system, we specify the maximal set of
 563 # libraries to link against when building any executable. The linker
 564 # on some platforms optionally allows unused link arguments to be
 565 # elided from the resulting executable, so enable that capability if
 566 # it exists.
 567 # XXX: currently we only support GNU ld; do any other linkers support
 568 # an equivalent feature?
 569 if test "$with_gnu_ld"; then
 570   AC_CACHE_CHECK([whether ld --as-needed works], [pgac_cv_prog_ld_as_needed],
 571   [
 572     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,--as-needed"
 573     AC_TRY_LINK([], [],
 574                 [pgac_cv_prog_ld_as_needed=yes],
 575                 [pgac_cv_prog_ld_as_needed=no])
 576    if test x"$pgac_cv_prog_ld_as_needed" = x"no"; then
 577      LDFLAGS=$pgac_save_LDFLAGS
 578    fi
 579   ])
 580 fi
 581
 582 AC_PROG_RANLIB
 583 AC_CHECK_PROGS(LORDER, lorder)
 584 AC_PATH_PROG(TAR, tar)
 585 PGAC_CHECK_STRIP
 586
 587 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 588 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 589
 590 AC_CHECK_PROGS(YACC, ['bison -y'])
 591
 592 if test "$YACC"; then
 593   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 594     AC_MSG_WARN([
 595 *** If you are going to modify the grammar files or build from CVS, the installed
 596 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 597   fi
 598 fi
 599
 600 if test -z "$YACC"; then
 601   AC_MSG_WARN([
 602 *** Without Bison you will not be able to build PostgreSQL from CVS or
 603 *** change any of the parser definition files.  You can obtain Bison from
 604 *** a GNU mirror site.  (If you are using the official distribution of
 605 *** PostgreSQL then you do not need to worry about this because the Bison
 606 *** output is pre-generated.)  To use a different yacc program (possible,
 607 *** but not recommended), set the environment variable YACC before running
 608 *** 'configure'.])
 609 fi
 610 AC_SUBST(YFLAGS)
 611
 612 PGAC_PATH_PERL
 613 if test "$with_perl" = yes; then
 614   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 615   PGAC_CHECK_PERL_EMBED_LDFLAGS
 616 fi
 617
 618 if test "$with_python" = yes; then
 619   PGAC_PATH_PYTHON
 620   PGAC_CHECK_PYTHON_EMBED_SETUP
 621 fi
 622
 623
 624 ##
 625 ## Libraries
 626 ##
 627
 628 if test "$PORTNAME" != "aix" -a "$PORTNAME" != "alpha"
 629 then
 630         AC_CHECK_LIB(bsd,      main)
 631 fi
 632 AC_CHECK_LIB(util,     setproctitle)
 633 AC_CHECK_LIB(m,        main)
 634 AC_CHECK_LIB(dl,       main)
 635 AC_CHECK_LIB(nsl,      main)
 636 AC_CHECK_LIB(socket,   main)
 637 AC_CHECK_LIB(ipc,      main)
 638 AC_CHECK_LIB(IPC,      main)
 639 AC_CHECK_LIB(lc,       main)
 640 AC_CHECK_LIB(dld,      main)
 641 AC_CHECK_LIB(ld,       main)
 642 AC_CHECK_LIB(compat,   main)
 643 AC_CHECK_LIB(BSD,      main)
 644 AC_CHECK_LIB(gen,      main)
 645 AC_CHECK_LIB(PW,       main)
 646 AC_CHECK_LIB(resolv,   main)
 647 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 648 # QNX:
 649 AC_CHECK_LIB(unix, main)
 650 AC_SEARCH_LIBS(crypt,  crypt)
 651 # BeOS:
 652 if test "$PORTNAME" = "beos"
 653 then
 654         AC_CHECK_LIB(bind, __inet_ntoa)
 655 fi
 656 # Solaris:
 657 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 658 # Cygwin:
 659 AC_CHECK_LIB(cygipc, shmget)
 660 # WIN32:
 661 if test "$PORTNAME" = "win32"
 662 then
 663         AC_CHECK_LIB(wsock32, main)
 664 fi
 665
 666 if test "$with_readline" = yes; then
 667   PGAC_CHECK_READLINE
 668   if test x"$pgac_cv_check_readline" = x"no"; then
 669     AC_MSG_ERROR([readline library not found
 670 If you have readline already installed, see config.log for details on the
 671 failure.  It is possible the compiler isn't looking in the proper directory.
 672 Use --without-readline to disable readline support.])
 673   fi
 674 fi
 675
 676 if test "$with_zlib" = yes; then
 677   AC_CHECK_LIB(z, inflate, [],
 678                [AC_MSG_ERROR([zlib library not found
 679 If you have zlib already installed, see config.log for details on the
 680 failure.  It is possible the compiler isn't looking in the proper directory.
 681 Use --without-zlib to disable zlib support.])])
 682 fi
 683
 684 if test "$enable_spinlocks" = yes; then
 685   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 686 else
 687   AC_MSG_WARN([
 688 *** Not using spinlocks will cause poor performance.])
 689 fi
 690
 691 if test "$with_krb4" = yes ; then
 692   AC_CHECK_LIB(des, des_encrypt, [], [AC_MSG_ERROR([library 'des' is required for Kerberos 4])])
 693   AC_CHECK_LIB(krb, krb_sendauth, [], [AC_MSG_ERROR([library 'krb' is required for Kerberos 4])])
 694   AC_REPLACE_FUNCS([gethostname])
 695 fi
 696
 697 if test "$with_krb5" = yes ; then
 698   if test "$PORTNAME" != "win32"; then
 699      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 700                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 701      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 702                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 703      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 704                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 705   else
 706      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 707                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 708   fi
 709 fi
 710
 711 if test "$with_openssl" = yes ; then
 712   dnl Order matters!
 713   if test "$PORTNAME" != "win32"; then
 714      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 715      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 716   else
 717      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 718      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 719   fi
 720 fi
 721
 722 if test "$with_pam" = yes ; then
 723   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 724 fi
 725
 726
 727 ##
 728 ## Header files
 729 ##
 730
 731 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 732 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 733
 734 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 735 # netinet/in.h is included first.
 736 AC_CHECK_HEADERS(netinet/in.h)
 737 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 738 [AC_INCLUDES_DEFAULT
 739 #ifdef HAVE_NETINET_IN_H
 740 #include <netinet/in.h>
 741 #endif
 742 ])
 743
 744 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 745   AC_CHECK_HEADERS(readline/readline.h, [],
 746         [AC_CHECK_HEADERS(readline.h, [],
 747                 [AC_MSG_ERROR([readline header not found
 748 If you have readline already installed, see config.log for details on the
 749 failure.  It is possible the compiler isn't looking in the proper directory.
 750 Use --without-readline to disable readline support.])])])
 751   AC_CHECK_HEADERS(readline/history.h, [],
 752         [AC_CHECK_HEADERS(history.h, [],
 753                 [AC_MSG_ERROR([history header not found
 754 If you have readline already installed, see config.log for details on the
 755 failure.  It is possible the compiler isn't looking in the proper directory.
 756 Use --without-readline to disable readline support.])])])
 757 fi
 758
 759 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 760 # Some installations of libedit usurp /usr/include/readline/, which seems
 761 # bad practice, since in combined installations readline will have its headers
 762 # there.  We might have to resort to AC_EGREP checks to make sure we found
 763 # the proper header...
 764   AC_CHECK_HEADERS(editline/readline.h, [],
 765         [AC_CHECK_HEADERS(readline.h, [],
 766                 [AC_CHECK_HEADERS(readline/readline.h, [],
 767                         [AC_MSG_ERROR([readline header not found
 768 If you have libedit already installed, see config.log for details on the
 769 failure.  It is possible the compiler isn't looking in the proper directory.
 770 Use --without-readline to disable libedit support.])])])])
 771   AC_CHECK_HEADERS(editline/history.h, [],
 772         [AC_CHECK_HEADERS(history.h, [],
 773                 [AC_CHECK_HEADERS(readline/history.h, [],
 774                         [AC_MSG_ERROR([history header not found
 775 If you have libedit already installed, see config.log for details on the
 776 failure.  It is possible the compiler isn't looking in the proper directory.
 777 Use --without-readline to disable libedit support.])])])])
 778 fi
 779
 780 if test "$with_zlib" = yes; then
 781   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 782 If you have zlib already installed, see config.log for details on the
 783 failure.  It is possible the compiler isn't looking in the proper directory.
 784 Use --without-zlib to disable zlib support.])])
 785 fi
 786
 787 if test "$with_krb4" = yes ; then
 788   AC_CHECK_HEADER(krb.h, [], [AC_MSG_ERROR([header file <krb.h> is required for Kerberos 4])])
 789 fi
 790
 791 if test "$with_krb5" = yes ; then
 792   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 793 fi
 794
 795 if test "$with_openssl" = yes ; then
 796   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 797   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 798 fi
 799
 800 if test "$with_pam" = yes ; then
 801   AC_CHECK_HEADERS(security/pam_appl.h, [],
 802                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 803                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 804 fi
 805
 806 if test "$with_rendezvous" = yes ; then
 807   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Rendezvous])])
 808 fi
 809
 810
 811 ##
 812 ## Types, structures, compiler characteristics
 813 ##
 814
 815 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 816 AC_C_CONST
 817 AC_C_INLINE
 818 AC_C_STRINGIZE
 819 PGAC_C_SIGNED
 820 AC_C_VOLATILE
 821 PGAC_C_FUNCNAME_SUPPORT
 822 PGAC_STRUCT_TIMEZONE
 823 PGAC_UNION_SEMUN
 824 PGAC_STRUCT_SOCKADDR_UN
 825 PGAC_STRUCT_SOCKADDR_STORAGE
 826 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 827 PGAC_STRUCT_ADDRINFO
 828
 829 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 830 [#include <sys/param.h>
 831 #include <sys/types.h>
 832 #include <sys/socket.h>
 833 #include <sys/ucred.h>])
 834
 835 AC_CHECK_TYPES([struct option], [], [],
 836 [#ifdef HAVE_GETOPT_H
 837 #include <getopt.h>
 838 #endif])
 839
 840 if test "$with_zlib" = yes; then
 841   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 842   # did not).  While we could work around the lack of z_streamp, it
 843   # seems unwise to encourage people to use such old zlib versions...
 844   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 845 Use --without-zlib to disable zlib support.])],
 846                 [#include <zlib.h>])
 847 fi
 848
 849 if test "$with_krb5" = yes; then
 850 # Check for differences between MIT and Heimdal (KTH) releases
 851   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 852                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 853                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 854                                      [#include <krb5.h>])],
 855                    [#include <krb5.h>])
 856   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 857                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 858                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 859                                      [#include <krb5.h>])],
 860                    [#include <krb5.h>])
 861 fi
 862
 863 ##
 864 ## Functions, global variables
 865 ##
 866
 867 PGAC_VAR_INT_TIMEZONE
 868 AC_FUNC_ACCEPT_ARGTYPES
 869 PGAC_FUNC_GETTIMEOFDAY_1ARG
 870
 871 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 872
 873 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 874
 875 HAVE_IPV6=no
 876 AC_CHECK_TYPE([struct sockaddr_in6],
 877               [AC_CHECK_FUNC(inet_ntop,
 878                              [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 879                                                           HAVE_IPV6=yes])],
 880               [],
 881 [$ac_includes_default
 882 #include <netinet/in.h>])
 883 AC_SUBST(HAVE_IPV6)
 884
 885 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 886 [AC_TRY_LINK(
 887 [#include <machine/vmparam.h>
 888 #include <sys/exec.h>
 889 ],
 890 [PS_STRINGS->ps_nargvstr = 1;
 891 PS_STRINGS->ps_argvstr = "foo";],
 892 [pgac_cv_var_PS_STRINGS=yes],
 893 [pgac_cv_var_PS_STRINGS=no])])
 894 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 895   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 896 fi
 897
 898
 899 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 900 # is missing.  Yes, there are machines that have only one.  We may
 901 # also decide to use snprintf.c if snprintf() is present but does not
 902 # have all the features we need --- see below.
 903
 904 pgac_need_repl_snprintf=no
 905 AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 906 AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 907
 908
 909 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 910 # include/c.h will provide declarations.  Note this is a separate test
 911 # from whether the functions exist in the C library --- there are
 912 # systems that have the functions but don't bother to declare them :-(
 913
 914 AC_CHECK_DECLS([snprintf, vsnprintf])
 915
 916
 917 # do this one the hard way in case isinf() is a macro
 918 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 919 [AC_TRY_LINK(
 920 [#include <math.h>
 921 ],
 922 [double x = 0.0; int res = isinf(x);],
 923 [ac_cv_func_isinf=yes],
 924 [ac_cv_func_isinf=no])])
 925
 926 if test $ac_cv_func_isinf = yes ; then
 927   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 928 else
 929   AC_LIBOBJ(isinf)
 930   # Look for a way to implement a substitute for isinf()
 931   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 932 fi
 933
 934 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 935
 936 # system's version of getaddrinfo(), if any, may be used only if we found
 937 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h
 938 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 939   AC_REPLACE_FUNCS([getaddrinfo])
 940 else
 941   AC_LIBOBJ(getaddrinfo)
 942 fi
 943
 944 # similarly, use system's getopt_long() only if system provides struct option.
 945 if test x"$ac_cv_type_struct_option" = xyes ; then
 946   AC_REPLACE_FUNCS([getopt_long])
 947 else
 948   AC_LIBOBJ(getopt_long)
 949 fi
 950
 951 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 952 # We override the previous test that said fseeko/ftello didn't exist
 953 # OS tests are also done in include/c.h and port/fseeko.c
 954 case $host_os in bsdi*|netbsd*)
 955 ac_cv_func_fseeko=yes
 956 esac
 957
 958 # Solaris has a very slow qsort in certain cases, so we replace it.
 959 if test "$PORTNAME" = "solaris"; then
 960 AC_LIBOBJ(qsort)
 961 fi
 962
 963 # Win32 support
 964 if test "$PORTNAME" = "win32"; then
 965 AC_LIBOBJ(copydir)
 966 AC_LIBOBJ(gettimeofday)
 967 AC_LIBOBJ(kill)
 968 AC_LIBOBJ(open)
 969 AC_LIBOBJ(rand)
 970 AC_DEFINE([HAVE_SYMLINK], 1,
 971           [Define to 1 if you have the `symlink' function.])
 972 fi
 973
 974 if test "$with_readline" = yes; then
 975   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
 976   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
 977   AC_CHECK_FUNCS([replace_history_entry])
 978 fi
 979
 980
 981 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
 982 AC_MSG_CHECKING(for finite)
 983 AC_TRY_LINK([#include <math.h>],
 984             [int dummy=finite(1.0);],
 985             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
 986 AC_MSG_RESULT(yes)],
 987             [AC_MSG_RESULT(no)])
 988
 989 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
 990 dnl (especially on GNU libc)
 991 dnl See also comments in c.h.
 992 AC_MSG_CHECKING(for sigsetjmp)
 993 AC_TRY_LINK([#include <setjmp.h>],
 994             [sigjmp_buf x; sigsetjmp(x, 1);],
 995             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
 996 AC_MSG_RESULT(yes)],
 997             [AC_MSG_RESULT(no)])
 998
 999 AC_CHECK_FUNC(syslog,
1000               [AC_CHECK_HEADER(syslog.h,
1001                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1002
1003 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1004 [AC_TRY_LINK([#include <unistd.h>],
1005   [extern int optreset; optreset = 1;],
1006   [pgac_cv_var_int_optreset=yes],
1007   [pgac_cv_var_int_optreset=no])])
1008 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1009   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1010 fi
1011
1012 AC_CHECK_FUNCS([strtoll strtoq], [break])
1013 AC_CHECK_FUNCS([strtoull strtouq], [break])
1014
1015 # Check for one of atexit() or on_exit()
1016 AC_CHECK_FUNCS(atexit, [],
1017                [AC_CHECK_FUNCS(on_exit, [],
1018                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1019
1020 AC_FUNC_FSEEKO
1021
1022 #
1023 # Pthreads
1024 #
1025 # For each platform, we need to know about any special compile and link
1026 # libraries, and whether the normal C function names are thread-safe.
1027 # See the comment at the top of src/port/thread.c for more information.
1028 #
1029 if test "$enable_thread_safety" = yes; then
1030 ACX_PTHREAD     # set thread flags
1031
1032 # Some platforms use these, so just defineed them.  They can't hurt if they
1033 # are not supported.
1034 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1035
1036
1037 # At this point, we don't want to muck with the compiler name for threading.
1038 # Let's see who fails, perhaps AIX.  2004-04-23
1039 if test "$PTHREAD_CC" != "$CC"; then
1040 AC_MSG_ERROR([
1041 PostgreSQL does not support platforms that require a special
1042 compiler binary for thread-safety.
1043 ])
1044 fi
1045
1046 if test "$THREAD_SUPPORT" = no; then
1047 AC_MSG_ERROR([
1048 Cannot enable threads on your platform.
1049 Your platform is known to not support thread-safe programs.
1050 For details, compile and run src/bin/pg_thread_test.
1051 ])
1052 fi
1053
1054 # Check for *_r functions
1055 _CFLAGS="$CFLAGS"
1056 _LIBS="$LIBS"
1057 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1058 LIBS="$LIBS $PTHREAD_LIBS"
1059
1060 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1061
1062 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1063
1064 # Do test here with the proper thread flags
1065 PGAC_FUNC_GETPWUID_R_5ARG
1066 PGAC_FUNC_STRERROR_R_INT
1067
1068 CFLAGS="$_CFLAGS"
1069 LIBS="$_LIBS"
1070
1071 else
1072 # do not use values from template file
1073 PTHREAD_CFLAGS=
1074 PTHREAD_LIBS=
1075 fi
1076
1077 AC_SUBST(PTHREAD_CFLAGS)
1078 AC_SUBST(PTHREAD_LIBS)
1079
1080
1081 # This test makes sure that run tests work at all.  Sometimes a shared
1082 # library is found by the linker, but the runtime linker can't find it.
1083 # This check should come after all modifications of compiler or linker
1084 # variables, and before any other run tests.
1085 AC_MSG_CHECKING([test program])
1086 AC_TRY_RUN([int main() { return 0; }],
1087 [AC_MSG_RESULT(ok)],
1088 [AC_MSG_RESULT(failed)
1089 AC_MSG_ERROR([[
1090 *** Could not execute a simple test program.  This may be a problem
1091 *** related to locating shared libraries.  Check the file 'config.log'
1092 *** for the exact reason.]])],
1093 [AC_MSG_RESULT([cross-compiling])])
1094
1095
1096 # Force use of our snprintf if system's doesn't do arg control
1097 # This feature is used by NLS
1098 if test "$enable_nls" = yes &&
1099    test $pgac_need_repl_snprintf = no &&
1100 # On Win32, libintl replaces snprintf() with its own version that
1101 # understands arg control, so we don't need our own.  In fact, it
1102 # also uses macros that conflict with ours, so we _can't_ use
1103 # our own.
1104    test "$PORTNAME" != "win32"; then
1105   PGAC_FUNC_PRINTF_ARG_CONTROL
1106   if test $pgac_cv_printf_arg_control != yes ; then
1107     pgac_need_repl_snprintf=yes
1108   fi
1109 fi
1110
1111
1112 dnl Check to see if we have a working 64-bit integer type.
1113 dnl This breaks down into two steps:
1114 dnl (1) figure out if the compiler has a 64-bit int type with working
1115 dnl arithmetic, and if so
1116 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1117 dnl snprintf is the only library routine we really need for int8 support.)
1118 dnl It's entirely possible to have a compiler that handles a 64-bit type
1119 dnl when the C library doesn't; this is fairly likely when using gcc on
1120 dnl an older platform, for example.
1121 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1122 dnl we force our own version of snprintf() to be used instead.
1123 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1124
1125 PGAC_TYPE_64BIT_INT([long int])
1126
1127 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1128   PGAC_TYPE_64BIT_INT([long long int])
1129 fi
1130
1131
1132 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1133
1134 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1135   AC_TRY_COMPILE([
1136 #define INT64CONST(x)  x##LL
1137 long long int foo = INT64CONST(0x1234567890123456);
1138 ],
1139         [],
1140         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1141         [])
1142 fi
1143
1144
1145 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1146 # we found we need to use "long long int", better check.  We cope with
1147 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1148 # work, fall back to our own snprintf emulation (which we know uses %lld).
1149
1150 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1151   if test $pgac_need_repl_snprintf = no; then
1152     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1153     if test "$LONG_LONG_INT_FORMAT" = ""; then
1154       # Force usage of our own snprintf, since system snprintf is broken
1155       pgac_need_repl_snprintf=yes
1156       LONG_LONG_INT_FORMAT='%lld'
1157     fi
1158   else
1159     # Here if we previously decided we needed to use our own snprintf
1160     LONG_LONG_INT_FORMAT='%lld'
1161   fi
1162   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1163   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1164   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1165 else
1166   # Here if we are not using 'long long int' at all
1167   INT64_FORMAT='"%ld"'
1168   UINT64_FORMAT='"%lu"'
1169 fi
1170
1171 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1172                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1173
1174 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1175                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1176
1177 # Now we have checked all the reasons to replace snprintf
1178 if test $pgac_need_repl_snprintf = yes; then
1179   AC_DEFINE(USE_SNPRINTF, 1, [Use replacement snprintf() functions.])
1180   AC_LIBOBJ(snprintf)
1181 fi
1182
1183 # Need a #define for the size of Datum (unsigned long)
1184 AC_CHECK_SIZEOF([unsigned long])
1185
1186 # Determine memory alignment requirements for the basic C data types.
1187
1188 PGAC_CHECK_ALIGNOF(short)
1189 PGAC_CHECK_ALIGNOF(int)
1190 PGAC_CHECK_ALIGNOF(long)
1191 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1192   PGAC_CHECK_ALIGNOF(long long int)
1193 fi
1194 PGAC_CHECK_ALIGNOF(double)
1195
1196 # Compute maximum alignment of any basic type.
1197 # We assume long's alignment is at least as strong as char, short, or int;
1198 # but we must check long long (if it exists) and double.
1199
1200 MAX_ALIGNOF=$pgac_cv_alignof_long
1201 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1202   MAX_ALIGNOF=$pgac_cv_alignof_double
1203 fi
1204 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1205   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1206 fi
1207 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1208
1209
1210 # Some platforms predefine the types int8, int16, etc.  Only check
1211 # a (hopefully) representative subset.
1212 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1213 [#include <stdio.h>
1214 #ifdef HAVE_SUPPORTDEFS_H
1215 #include <SupportDefs.h>
1216 #endif])
1217
1218 # We also check for sig_atomic_t, which *should* be defined per ANSI
1219 # C, but is missing on some old platforms.
1220 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1221
1222
1223 PGAC_FUNC_POSIX_SIGNALS
1224 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1225   AC_MSG_ERROR([
1226 *** Thread-safety requires POSIX signals, which are not supported by your
1227 *** operating system.
1228 ])
1229 fi
1230
1231 if test $ac_cv_func_fseeko = yes; then
1232 AC_SYS_LARGEFILE
1233 fi
1234
1235 # SunOS doesn't handle negative byte comparisons properly with +/- return
1236 AC_FUNC_MEMCMP
1237
1238
1239 # Select semaphore implementation type.
1240 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1241   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1242   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1243 else
1244   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1245     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1246     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1247   else
1248     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1249     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1250   fi
1251 fi
1252
1253
1254 # Select shared-memory implementation type.
1255 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1256 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1257
1258
1259 if test "$enable_nls" = yes ; then
1260   PGAC_CHECK_GETTEXT
1261 fi
1262
1263 # Check for Tcl configuration script tclConfig.sh
1264 if test "$with_tcl" = yes; then
1265     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1266     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1267                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1268     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1269     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1270     ac_save_CPPFLAGS=$CPPFLAGS
1271     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1272     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1273     CPPFLAGS=$ac_save_CPPFLAGS
1274 fi
1275
1276 #
1277 # Check for DocBook and tools
1278 #
1279 PGAC_PROG_NSGMLS
1280 PGAC_PROG_JADE
1281 PGAC_CHECK_DOCBOOK(4.2)
1282 PGAC_PATH_DOCBOOK_STYLESHEETS
1283 PGAC_PATH_COLLATEINDEX
1284 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1285
1286 # Thread testing
1287
1288 # We have to run the thread test near the end so we have all our symbols
1289 # defined.  Cross compiling throws a warning.
1290 #
1291 if test "$enable_thread_safety_force" = yes; then
1292   AC_MSG_WARN([
1293 *** Skipping thread test program.  --enable-thread-safety-force was used.
1294 *** Run the program in src/tools/thread on the your machine and add
1295 proper locking function calls to your applications to guarantee thread
1296 safety.
1297 ])
1298 elif test "$enable_thread_safety" = yes; then
1299 AC_MSG_CHECKING([thread safety of required library functions])
1300
1301 _CFLAGS="$CFLAGS"
1302 _LIBS="$LIBS"
1303 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1304 LIBS="$LIBS $PTHREAD_LIBS"
1305 AC_TRY_RUN([#include "$srcdir/src/tools/thread/thread_test.c"],
1306   [AC_MSG_RESULT(yes)],
1307   [AC_MSG_RESULT(no)
1308   AC_MSG_ERROR([
1309 *** Thread test program failed.  Your platform is not thread-safe.
1310 *** Check the file 'config.log'for the exact reason.
1311 ***
1312 *** You can use the configure option --enable-thread-safety-force
1313 *** to force threads to be enabled.  However, you must then run
1314 *** the program in src/tools/thread and add locking function calls
1315 *** to your applications to guarantee thread safety.
1316 ])],
1317   [AC_MSG_RESULT(maybe)
1318   AC_MSG_WARN([
1319 *** Skipping thread test program because of cross-compile build.
1320 *** Run the program in src/tools/thread on the target machine.
1321 ])])
1322 CFLAGS="$_CFLAGS"
1323 LIBS="$_LIBS"
1324 fi
1325
1326 # prepare build tree if outside source tree
1327 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1328 # Note 2: /bin/pwd might be better than shell's built-in at getting
1329 #         a symlink-free name.
1330 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1331   vpath_build=no
1332 else
1333   vpath_build=yes
1334   if test "$no_create" != yes; then
1335     _AS_ECHO_N([preparing build tree... ])
1336     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1337     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1338       || AC_MSG_ERROR(failed)
1339     AC_MSG_RESULT(done)
1340   fi
1341 fi
1342 AC_SUBST(vpath_build)
1343
1344
1345 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1346
1347 AC_CONFIG_LINKS([
1348   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1349   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1350   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1351   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1352   src/include/pg_config_os.h:src/include/port/${template}.h
1353   src/Makefile.port:src/makefiles/Makefile.${template}
1354 ])
1355
1356 if test "$PORTNAME" = "win32"; then
1357 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1358 # Links sometimes fail undetected on Mingw -
1359 # so here we detect it and warn the user
1360 for FILE in $CONFIG_LINKS
1361  do
1362         # test -e works for symlinks in the MinGW console
1363         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1364  done
1365 ])
1366 fi
1367
1368 AC_CONFIG_HEADERS([src/include/pg_config.h],
1369 [
1370 # Update timestamp for pg_config.h (see Makefile.global)
1371 echo >src/include/stamp-h
1372 ])
1373
1374 AC_OUTPUT
1375