granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $PostgreSQL: pgsql/configure.in,v 1.462 2006/04/29 00:51:41 momjian Exp $
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [8.2devel], [pgsql-bugs@postgresql.org])
  21
  22 AC_PREREQ(2.59)
  23 AC_COPYRIGHT([Copyright (c) 1996-2006, PostgreSQL Global Development Group])
  24 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  25 AC_CONFIG_AUX_DIR(config)
  26 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  27 AC_SUBST(configure_args, [$ac_configure_args])
  28
  29 AC_DEFINE_UNQUOTED(PG_VERSION, "$PACKAGE_VERSION", [PostgreSQL version as a string])
  30
  31 AC_CANONICAL_HOST
  32
  33 template=
  34 AC_MSG_CHECKING([which template to use])
  35
  36 PGAC_ARG_REQ(with, template, [],
  37 [
  38   case $withval in
  39     list)   echo; ls "$srcdir/src/template"; exit;;
  40     *)      if test -f "$srcdir/src/template/$with_template" ; then
  41               template=$withval
  42             else
  43               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  44             fi;;
  45   esac
  46 ],
  47 [
  48 # --with-template not given
  49
  50 case $host_os in
  51      aix*) template=aix ;;
  52     bsdi*) template=bsdi ;;
  53   cygwin*) template=cygwin ;;
  54   darwin*) template=darwin ;;
  55     dgux*) template=dgux ;;
  56  freebsd*) template=freebsd ;;
  57     hpux*) template=hpux ;;
  58     irix*) template=irix ;;
  59  linux*|gnu*|k*bsd*-gnu)
  60            template=linux ;;
  61    mingw*) template=win32 ;;
  62   netbsd*) template=netbsd ;;
  63 nextstep*) template=nextstep ;;
  64  openbsd*) template=openbsd ;;
  65      osf*) template=osf ;;
  66      sco*) template=sco ;;
  67  solaris*) template=solaris ;;
  68    sunos*) template=sunos4 ;;
  69  sysv4.2*)
  70         case $host_vendor in
  71           univel) template=univel ;;
  72         esac ;;
  73    sysv4*) template=svr4 ;;
  74    sysv5*) template=unixware ;;
  75   ultrix*) template=ultrix4 ;;
  76 esac
  77
  78   if test x"$template" = x"" ; then
  79     AC_MSG_ERROR([[
  80 *******************************************************************
  81 PostgreSQL has apparently not been ported to your platform yet.
  82 To try a manual configuration, look into the src/template directory
  83 for a similar platform and use the '--with-template=' option.
  84
  85 Please also contact <pgsql-ports@postgresql.org> to see about
  86 rectifying this.  Include the above 'checking host system type...'
  87 line.
  88 *******************************************************************
  89 ]])
  90   fi
  91
  92 ])
  93
  94 AC_MSG_RESULT([$template])
  95
  96 PORTNAME=$template
  97 AC_SUBST(PORTNAME)
  98
  99 # Initialize default assumption that we do not need separate assembly code
 100 # for TAS (test-and-set).  This can be overridden by the template file
 101 # when it's executed.
 102 need_tas=no
 103 tas_file=dummy.s
 104
 105
 106
 107 ##
 108 ## Command line options
 109 ##
 110
 111 #
 112 # Installation directory for documentation
 113 #
 114 PGAC_ARG(with, docdir, [  --with-docdir=DIR       install the documentation in DIR [[PREFIX/doc]]
 115   --without-docdir        do not install the documentation],
 116          [AC_MSG_ERROR([option --with-docdir requires an argument])],
 117          [docdir=],
 118          [docdir=$withval],
 119          [docdir='${prefix}/doc'])
 120 AC_SUBST(docdir)
 121
 122
 123 #
 124 # Add non-standard directories to the include path
 125 #
 126 PGAC_ARG_REQ(with, includes, [  --with-includes=DIRS    look for additional header files in DIRS])
 127
 128
 129 #
 130 # Add non-standard directories to the library search path
 131 #
 132 PGAC_ARG_REQ(with, libraries, [  --with-libraries=DIRS   look for additional libraries in DIRS],
 133              [LIBRARY_DIRS=$withval])
 134
 135 PGAC_ARG_REQ(with, libs,      [  --with-libs=DIRS        alternative spelling of --with-libraries],
 136              [LIBRARY_DIRS=$withval])
 137
 138
 139 #
 140 # 64-bit integer date/time storage (--enable-integer-datetimes)
 141 #
 142 AC_MSG_CHECKING([whether to build with 64-bit integer date/time support])
 143 PGAC_ARG_BOOL(enable, integer-datetimes, no, [  --enable-integer-datetimes  enable 64-bit integer date/time support],
 144               [AC_DEFINE([USE_INTEGER_DATETIMES], 1,
 145                          [Define to 1 if you want 64-bit integer timestamp and interval support. (--enable-integer-datetimes)])])
 146 AC_MSG_RESULT([$enable_integer_datetimes])
 147
 148
 149 #
 150 # NLS
 151 #
 152 AC_MSG_CHECKING([whether NLS is wanted])
 153 PGAC_ARG_OPTARG(enable, nls,
 154                 [[  --enable-nls[=LANGUAGES]  enable Native Language Support]],
 155                 [],
 156                 [WANTED_LANGUAGES=$enableval],
 157                 [AC_DEFINE(ENABLE_NLS, 1,
 158                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 159 AC_MSG_RESULT([$enable_nls])
 160 AC_SUBST(enable_nls)
 161 AC_SUBST(WANTED_LANGUAGES)
 162
 163 #
 164 # Default port number (--with-pgport), default 5432
 165 #
 166 AC_MSG_CHECKING([for default port number])
 167 PGAC_ARG_REQ(with, pgport, [  --with-pgport=PORTNUM   change default port number [[5432]]],
 168              [default_port=$withval],
 169              [default_port=5432])
 170 AC_MSG_RESULT([$default_port])
 171 # Need both of these because some places want an integer and some a string
 172 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 173 [Define to the default TCP port number on which the server listens and
 174 to which clients will try to connect.  This can be overridden at run-time,
 175 but it's convenient if your clients have the right default compiled in.
 176 (--with-pgport=PORTNUM)])
 177 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 178                    [Define to the default TCP port number as a string constant.])
 179 AC_SUBST(default_port)
 180
 181 #
 182 # Option to disable shared libraries
 183 #
 184 PGAC_ARG_BOOL(enable, shared, yes,
 185               [  --disable-shared        do not build shared libraries])
 186 AC_SUBST(enable_shared)
 187
 188 #
 189 # '-rpath'-like feature can be disabled
 190 #
 191 PGAC_ARG_BOOL(enable, rpath, yes,
 192               [  --disable-rpath         do not embed shared library search path in executables])
 193 AC_SUBST(enable_rpath)
 194
 195 #
 196 # Spinlocks
 197 #
 198 PGAC_ARG_BOOL(enable, spinlocks, yes,
 199               [  --disable-spinlocks     do not use spinlocks])
 200
 201 #
 202 # --enable-debug adds -g to compiler flags
 203 #
 204 PGAC_ARG_BOOL(enable, debug, no,
 205               [  --enable-debug          build with debugging symbols (-g)])
 206 AC_SUBST(enable_debug)
 207
 208 #
 209 # C compiler
 210 #
 211
 212 # For historical reasons you can also use --with-CC to specify the C compiler
 213 # to use, although the standard way to do this is to set the CC environment
 214 # variable.
 215 PGAC_ARG_REQ(with, CC, [], [CC=$with_CC])
 216
 217 case $template in
 218   aix) pgac_cc_list="gcc xlc";;
 219  irix) pgac_cc_list="cc";; # no gcc
 220     *) pgac_cc_list="gcc cc";;
 221 esac
 222
 223 AC_PROG_CC([$pgac_cc_list])
 224
 225 unset CFLAGS
 226
 227 #
 228 # Read the template
 229 #
 230 . "$srcdir/src/template/$template" || exit
 231
 232 # CFLAGS are selected so:
 233 # If the user specifies something in the environment, that is used.
 234 # else:  If the template file set something, that is used.
 235 # else:  If the compiler is GCC, then we use -O2.
 236 # else:  If the compiler is something else, then we use -0.
 237
 238 if test "$ac_env_CFLAGS_set" = set; then
 239   CFLAGS=$ac_env_CFLAGS_value
 240 elif test "${CFLAGS+set}" = set; then
 241   : # (keep what template set)
 242 elif test "$GCC" = yes; then
 243   CFLAGS="-O2"
 244 else
 245   # if the user selected debug mode, don't use -O
 246   if test "$enable_debug" != yes; then
 247     CFLAGS="-O"
 248   fi
 249 fi
 250
 251 # The Intel compiler on Linux supports most gcc options, but not
 252 # all of them, so only add these options if we are really using
 253 # gcc.
 254
 255 if test "$GCC" = yes; then
 256 AC_TRY_COMPILE([], [@%:@ifndef __INTEL_COMPILER
 257 choke me
 258 @%:@endif], [ICC=[yes]], [ICC=[no]])
 259   if test "$ICC" = no; then
 260     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -Wpointer-arith -Winline"
 261
 262     # Some versions of GCC support some additional useful warning flags.
 263     # Check whether they are supported, and add them to CFLAGS if so.
 264     PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 265     PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 266   else
 267     # Intel compiler has a bug/misoptimization in checking for
 268     # division by NAN (NaN == 0), -mp1 fixes it, so add it to the
 269     # CFLAGS.
 270     PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 271   fi
 272
 273   # Disable strict-aliasing rules; needed for gcc 3.3+
 274   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 275 elif test ${CC} = "xlc"; then
 276   # AIX xlc has to have strict aliasing turned off too
 277   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 278 fi
 279
 280 # supply -g if --enable-debug
 281 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 282   CFLAGS="$CFLAGS -g"
 283 fi
 284
 285 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
 286
 287 # We already have this in Makefile.win32, but configure needs it too
 288 if test "$PORTNAME" = "win32"; then
 289   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 290 fi
 291
 292 # Check if the compiler still works with the template settings
 293 AC_MSG_CHECKING([whether the C compiler still works])
 294 AC_TRY_LINK([], [return 0;],
 295   [AC_MSG_RESULT(yes)],
 296   [AC_MSG_RESULT(no)
 297    AC_MSG_ERROR([cannot proceed])])
 298
 299 # Defend against gcc -ffast-math
 300 if test "$GCC" = yes; then
 301 AC_TRY_COMPILE([], [@%:@ifdef __FAST_MATH__
 302 choke me
 303 @%:@endif], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 304 fi
 305
 306 AC_PROG_CPP
 307 AC_SUBST(GCC)
 308
 309 # Create compiler version string
 310 if test x"$GCC" = x"yes" ; then
 311   cc_string="GCC `${CC} --version | sed q`"
 312 else
 313   cc_string=$CC
 314 fi
 315 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
 316                    ["PostgreSQL $PACKAGE_VERSION on $host, compiled by $cc_string"],
 317                    [A string containing the version number, platform, and C compiler])
 318
 319
 320 #
 321 # Set up TAS assembly code if needed; the template file has now had its
 322 # chance to request this.
 323 #
 324 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 325
 326 if test "$need_tas" = yes ; then
 327   TAS=tas.o
 328 else
 329   TAS=""
 330 fi
 331 AC_SUBST(TAS)
 332
 333
 334 #
 335 # Automatic dependency tracking
 336 #
 337 PGAC_ARG_BOOL(enable, depend, no, [  --enable-depend         turn on automatic dependency tracking],
 338               [autodepend=yes])
 339 AC_SUBST(autodepend)
 340
 341
 342 #
 343 # Enable assert checks
 344 #
 345 PGAC_ARG_BOOL(enable, cassert, no, [  --enable-cassert        enable assertion checks (for debugging)],
 346               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 347                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 348
 349
 350 #
 351 # Include directories
 352 #
 353 ac_save_IFS=$IFS
 354 IFS="${IFS}${PATH_SEPARATOR}"
 355 # SRCH_INC comes from the template file
 356 for dir in $with_includes $SRCH_INC; do
 357   if test -d "$dir"; then
 358     INCLUDES="$INCLUDES -I$dir"
 359   else
 360     AC_MSG_WARN([*** Include directory $dir does not exist.])
 361   fi
 362 done
 363 IFS=$ac_save_IFS
 364 AC_SUBST(INCLUDES)
 365
 366
 367 #
 368 # Library directories
 369 #
 370 ac_save_IFS=$IFS
 371 IFS="${IFS}${PATH_SEPARATOR}"
 372 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 373 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 374   if test -d "$dir"; then
 375     LIBDIRS="$LIBDIRS -L$dir"
 376   else
 377     AC_MSG_WARN([*** Library directory $dir does not exist.])
 378   fi
 379 done
 380 IFS=$ac_save_IFS
 381
 382 #
 383 # Enable thread-safe client libraries
 384 #
 385 AC_MSG_CHECKING([allow thread-safe client libraries])
 386 PGAC_ARG_BOOL(enable, thread-safety, no, [  --enable-thread-safety  make client libraries thread-safe])
 387 PGAC_ARG_BOOL(enable, thread-safety-force, no, [  --enable-thread-safety-force  force thread-safety in spite of thread test failure])
 388 if test "$enable_thread_safety" = yes -o \
 389         "$enable_thread_safety_force" = yes; then
 390   enable_thread_safety="yes"    # for 'force'
 391   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 392           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 393 fi
 394 AC_MSG_RESULT([$enable_thread_safety])
 395 AC_SUBST(enable_thread_safety)
 396
 397 #
 398 # Optionally build Tcl modules (PL/Tcl)
 399 #
 400 AC_MSG_CHECKING([whether to build with Tcl])
 401 PGAC_ARG_BOOL(with, tcl, no, [  --with-tcl              build Tcl modules (PL/Tcl)])
 402 AC_MSG_RESULT([$with_tcl])
 403 AC_SUBST([with_tcl])
 404
 405 # We see if the path to the Tcl/Tk configuration scripts is specified.
 406 # This will override the use of tclsh to find the paths to search.
 407
 408 PGAC_ARG_REQ(with, tclconfig, [  --with-tclconfig=DIR    tclConfig.sh is in DIR])
 409
 410 #
 411 # Optionally build Perl modules (PL/Perl)
 412 #
 413 AC_MSG_CHECKING([whether to build Perl modules])
 414 PGAC_ARG_BOOL(with, perl, no, [  --with-perl             build Perl modules (PL/Perl)])
 415 AC_MSG_RESULT([$with_perl])
 416 AC_SUBST(with_perl)
 417
 418 #
 419 # Optionally build Python modules (PL/Python)
 420 #
 421 AC_MSG_CHECKING([whether to build Python modules])
 422 PGAC_ARG_BOOL(with, python, no, [  --with-python           build Python modules (PL/Python)])
 423 AC_MSG_RESULT([$with_python])
 424 AC_SUBST(with_python)
 425
 426 #
 427 # Kerberos 5
 428 #
 429 AC_MSG_CHECKING([whether to build with Kerberos 5 support])
 430 PGAC_ARG_BOOL(with, krb5, no, [  --with-krb5             build with Kerberos 5 support],
 431 [
 432   AC_DEFINE(KRB5, 1, [Define to build with Kerberos 5 support. (--with-krb5)])
 433   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 434 ])
 435 AC_MSG_RESULT([$with_krb5])
 436 AC_SUBST(with_krb5)
 437
 438
 439 AC_SUBST(krb_srvtab)
 440
 441
 442 #
 443 # Kerberos configuration parameters
 444 #
 445 PGAC_ARG_REQ(with, krb-srvnam,
 446              [  --with-krb-srvnam=NAME  name of the default service principal in Kerberos [[postgres]]],
 447              [],
 448              [with_krb_srvnam="postgres"])
 449 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 450                    [Define to the name of the default PostgreSQL service principal in Kerberos. (--with-krb-srvnam=NAME)])
 451
 452
 453 #
 454 # PAM
 455 #
 456 AC_MSG_CHECKING([whether to build with PAM support])
 457 PGAC_ARG_BOOL(with, pam, no,
 458               [  --with-pam              build with PAM support],
 459               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 460 AC_MSG_RESULT([$with_pam])
 461 AC_SUBST(with_pam)
 462
 463
 464 #
 465 # LDAP
 466 #
 467 AC_MSG_CHECKING([whether to build with LDAP support])
 468 PGAC_ARG_BOOL(with, ldap, no,
 469               [  --with-ldap             build with LDAP support],
 470               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 471 AC_MSG_RESULT([$with_ldap])
 472 AC_SUBST(with_ldap)
 473
 474
 475 #
 476 # Bonjour
 477 #
 478 AC_MSG_CHECKING([whether to build with Bonjour support])
 479 PGAC_ARG_BOOL(with, bonjour, no,
 480               [  --with-bonjour          build with Bonjour support],
 481               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 482 AC_MSG_RESULT([$with_bonjour])
 483 AC_SUBST(with_bonjour)
 484
 485
 486 #
 487 # OpenSSL
 488 #
 489 AC_MSG_CHECKING([whether to build with OpenSSL support])
 490 PGAC_ARG_BOOL(with, openssl, no, [  --with-openssl          build with OpenSSL support],
 491               [AC_DEFINE([USE_SSL], 1, [Define to build with (Open)SSL support. (--with-openssl)])])
 492 AC_MSG_RESULT([$with_openssl])
 493 AC_SUBST(with_openssl)
 494
 495
 496 #
 497 # Prefer libedit
 498 #
 499 PGAC_ARG_BOOL(with, libedit-preferred, no,
 500               [  --with-libedit-preferred  prefer BSD Libedit over GNU Readline])
 501
 502
 503 #
 504 # Readline
 505 #
 506 PGAC_ARG_BOOL(with, readline, yes,
 507               [  --without-readline      do not use GNU Readline / BSD Libedit line editing])
 508 # readline on MinGW has problems with backslashes in psql and other bugs.
 509 # This is particularly a problem with non-US code pages.
 510 # Therefore disable its use until we understand the cause. 2004-07-20
 511 if test "$PORTNAME" = "win32"; then
 512   if test "$with_readline" = yes; then
 513     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 514     with_readline=no
 515   fi
 516 fi
 517
 518
 519 #
 520 # Zlib
 521 #
 522 PGAC_ARG_BOOL(with, zlib, yes,
 523               [  --without-zlib          do not use Zlib])
 524 AC_SUBST(with_zlib)
 525
 526 #
 527 # Elf
 528 #
 529
 530 # Assume system is ELF if it predefines __ELF__ as 1,
 531 # otherwise believe host_os based default.
 532 case $host_os in
 533     freebsd1*|freebsd2*) elf=no;;
 534     freebsd3*|freebsd4*) elf=yes;;
 535 esac
 536
 537 AC_EGREP_CPP(yes,
 538 [#if __ELF__
 539   yes
 540 #endif
 541 ],
 542 [ELF_SYS=true],
 543 [if test "X$elf" = "Xyes" ; then
 544   ELF_SYS=true
 545 else
 546   ELF_SYS=
 547 fi])
 548 AC_SUBST(ELF_SYS)
 549
 550 #
 551 # Assignments
 552 #
 553
 554 CPPFLAGS="$CPPFLAGS $INCLUDES"
 555 LDFLAGS="$LDFLAGS $LIBDIRS"
 556
 557 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
 558 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
 559
 560 AC_ARG_VAR(LDFLAGS_SL)
 561
 562 AC_PROG_AWK
 563 PGAC_PATH_FLEX
 564 AC_PROG_LN_S
 565 PGAC_PROG_LD
 566 AC_SUBST(LD)
 567 AC_SUBST(with_gnu_ld)
 568 case $host_os in sysv5*)
 569   AC_CACHE_CHECK([whether ld -R works], [pgac_cv_prog_ld_R],
 570   [
 571     pgac_save_LDFLAGS=$LDFLAGS; LDFLAGS="$LDFLAGS -Wl,-R/usr/lib"
 572     AC_TRY_LINK([], [], [pgac_cv_prog_ld_R=yes], [pgac_cv_prog_ld_R=no])
 573     LDFLAGS=$pgac_save_LDFLAGS
 574   ])
 575   ld_R_works=$pgac_cv_prog_ld_R
 576   AC_SUBST(ld_R_works)
 577 esac
 578 AC_PROG_RANLIB
 579 AC_PATH_PROG(TAR, tar)
 580 PGAC_CHECK_STRIP
 581
 582 AC_CHECK_PROGS(YACC, ['bison -y'])
 583
 584 if test "$YACC"; then
 585   if $YACC --version | sed q | $AWK '{ if ($4 < 1.875) exit 0; else exit 1;}'; then
 586     AC_MSG_WARN([
 587 *** If you are going to modify the grammar files or build from CVS, the installed
 588 *** version of Bison is too old.  Bison version 1.875 or later is required.])
 589   fi
 590 fi
 591
 592 if test -z "$YACC"; then
 593   AC_MSG_WARN([
 594 *** Without Bison you will not be able to build PostgreSQL from CVS or
 595 *** change any of the parser definition files.  You can obtain Bison from
 596 *** a GNU mirror site.  (If you are using the official distribution of
 597 *** PostgreSQL then you do not need to worry about this because the Bison
 598 *** output is pre-generated.)  To use a different yacc program (possible,
 599 *** but not recommended), set the environment variable YACC before running
 600 *** 'configure'.])
 601 fi
 602 AC_SUBST(YFLAGS)
 603
 604 PGAC_PATH_PERL
 605 if test "$with_perl" = yes; then
 606   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
 607   PGAC_CHECK_PERL_EMBED_LDFLAGS
 608 fi
 609
 610 if test "$with_python" = yes; then
 611   PGAC_PATH_PYTHON
 612   PGAC_CHECK_PYTHON_EMBED_SETUP
 613 fi
 614
 615 # Supply a numeric version string for use by 3rd party add-ons
 616 # awk -F is a regex on some platforms, and not on others, so make "." a tab
 617 PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
 618 tr '.' '        ' |
 619 $AWK '{printf \"%d%02d%02d\", $1, $2, (NF >= 3) ? $3 : 0}'`"
 620 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
 621
 622 ##
 623 ## Libraries
 624 ##
 625
 626 AC_SEARCH_LIBS(setproctitle, util)
 627 AC_SEARCH_LIBS(pow, m)
 628 AC_SEARCH_LIBS(dlopen, dl)
 629 AC_SEARCH_LIBS(socket, [socket wsock32])
 630 AC_SEARCH_LIBS(shl_load, dld)
 631 # We only use libld in port/dynloader/aix.c
 632 case $host_os in
 633      aix*)
 634         AC_SEARCH_LIBS(ldopen, ld)
 635         ;;
 636 esac
 637 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
 638 AC_SEARCH_LIBS(crypt, crypt)
 639 # Solaris:
 640 AC_SEARCH_LIBS(fdatasync, [rt posix4])
 641 # Cygwin:
 642 AC_SEARCH_LIBS(shmget, cygipc)
 643
 644 if test "$with_readline" = yes; then
 645   PGAC_CHECK_READLINE
 646   if test x"$pgac_cv_check_readline" = x"no"; then
 647     AC_MSG_ERROR([readline library not found
 648 If you have readline already installed, see config.log for details on the
 649 failure.  It is possible the compiler isn't looking in the proper directory.
 650 Use --without-readline to disable readline support.])
 651   fi
 652 fi
 653
 654 if test "$with_zlib" = yes; then
 655   AC_CHECK_LIB(z, inflate, [],
 656                [AC_MSG_ERROR([zlib library not found
 657 If you have zlib already installed, see config.log for details on the
 658 failure.  It is possible the compiler isn't looking in the proper directory.
 659 Use --without-zlib to disable zlib support.])])
 660 fi
 661
 662 if test "$enable_spinlocks" = yes; then
 663   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
 664 else
 665   AC_MSG_WARN([
 666 *** Not using spinlocks will cause poor performance.])
 667 fi
 668
 669 if test "$with_krb5" = yes ; then
 670   if test "$PORTNAME" != "win32"; then
 671      AC_SEARCH_LIBS(com_err, [krb5 'krb5 -ldes -lasn1 -lroken' com_err], [],
 672                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 673      AC_SEARCH_LIBS(krb5_encrypt, [krb5 'krb5 -ldes -lasn1 -lroken' crypto k5crypto], [],
 674                     [AC_MSG_ERROR([could not find function 'krb5_encrypt' required for Kerberos 5])])
 675      AC_SEARCH_LIBS(krb5_sendauth, [krb5 'krb5 -ldes -lasn1 -lroken'], [],
 676                     [AC_MSG_ERROR([could not find function 'krb5_sendauth' required for Kerberos 5])])
 677   else
 678      AC_SEARCH_LIBS(com_err, 'comerr32 -lkrb5_32', [],
 679                     [AC_MSG_ERROR([could not find function 'com_err' required for Kerberos 5])])
 680   fi
 681 fi
 682
 683 if test "$with_openssl" = yes ; then
 684   dnl Order matters!
 685   if test "$PORTNAME" != "win32"; then
 686      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
 687      AC_CHECK_LIB(ssl,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
 688   else
 689      AC_CHECK_LIB(eay32, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'eay32' is required for OpenSSL])])
 690      AC_CHECK_LIB(ssleay32,    SSL_library_init, [], [AC_MSG_ERROR([library 'ssleay32' is required for OpenSSL])])
 691   fi
 692 fi
 693
 694 if test "$with_pam" = yes ; then
 695   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
 696 fi
 697
 698
 699 if test "$with_ldap" = yes ; then
 700   if test "$PORTNAME" != "win32"; then
 701      AC_CHECK_LIB(ldap,    ldap_bind, [], [AC_MSG_ERROR([library 'ldap' is required for LDAP])])
 702   else
 703      AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
 704   fi
 705 fi
 706
 707 ##
 708 ## Header files
 709 ##
 710
 711 dnl sys/socket.h is required by AC_FUNC_ACCEPT_ARGTYPES
 712 AC_CHECK_HEADERS([crypt.h dld.h endian.h fp_class.h getopt.h ieeefp.h langinfo.h poll.h pwd.h sys/ipc.h sys/poll.h sys/pstat.h sys/select.h sys/sem.h sys/socket.h sys/shm.h sys/time.h sys/un.h termios.h utime.h wchar.h wctype.h kernel/OS.h kernel/image.h SupportDefs.h])
 713
 714 # At least on IRIX, cpp test for netinet/tcp.h will fail unless
 715 # netinet/in.h is included first.
 716 AC_CHECK_HEADERS(netinet/in.h)
 717 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 718 [AC_INCLUDES_DEFAULT
 719 #ifdef HAVE_NETINET_IN_H
 720 #include <netinet/in.h>
 721 #endif
 722 ])
 723
 724 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
 725   AC_CHECK_HEADERS(readline/readline.h, [],
 726         [AC_CHECK_HEADERS(readline.h, [],
 727                 [AC_MSG_ERROR([readline header not found
 728 If you have readline already installed, see config.log for details on the
 729 failure.  It is possible the compiler isn't looking in the proper directory.
 730 Use --without-readline to disable readline support.])])])
 731   AC_CHECK_HEADERS(readline/history.h, [],
 732         [AC_CHECK_HEADERS(history.h, [],
 733                 [AC_MSG_ERROR([history header not found
 734 If you have readline already installed, see config.log for details on the
 735 failure.  It is possible the compiler isn't looking in the proper directory.
 736 Use --without-readline to disable readline support.])])])
 737 fi
 738
 739 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
 740 # Some installations of libedit usurp /usr/include/readline/, which seems
 741 # bad practice, since in combined installations readline will have its headers
 742 # there.  We might have to resort to AC_EGREP checks to make sure we found
 743 # the proper header...
 744   AC_CHECK_HEADERS(editline/readline.h, [],
 745         [AC_CHECK_HEADERS(readline.h, [],
 746                 [AC_CHECK_HEADERS(readline/readline.h, [],
 747                         [AC_MSG_ERROR([readline header not found
 748 If you have libedit already installed, see config.log for details on the
 749 failure.  It is possible the compiler isn't looking in the proper directory.
 750 Use --without-readline to disable libedit support.])])])])
 751   AC_CHECK_HEADERS(editline/history.h, [],
 752         [AC_CHECK_HEADERS(history.h, [],
 753                 [AC_CHECK_HEADERS(readline/history.h, [],
 754                         [AC_MSG_ERROR([history header not found
 755 If you have libedit already installed, see config.log for details on the
 756 failure.  It is possible the compiler isn't looking in the proper directory.
 757 Use --without-readline to disable libedit support.])])])])
 758 fi
 759
 760 if test "$with_zlib" = yes; then
 761   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
 762 If you have zlib already installed, see config.log for details on the
 763 failure.  It is possible the compiler isn't looking in the proper directory.
 764 Use --without-zlib to disable zlib support.])])
 765 fi
 766
 767 if test "$with_krb5" = yes ; then
 768   AC_CHECK_HEADER(krb5.h, [], [AC_MSG_ERROR([header file <krb5.h> is required for Kerberos 5])])
 769 fi
 770
 771 if test "$with_openssl" = yes ; then
 772   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
 773   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
 774 fi
 775
 776 if test "$with_pam" = yes ; then
 777   AC_CHECK_HEADERS(security/pam_appl.h, [],
 778                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
 779                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
 780 fi
 781
 782 if test "$with_ldap" = yes ; then
 783   if test "$PORTNAME" != "win32"; then
 784      AC_CHECK_HEADERS(ldap.h, [],
 785                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
 786   else
 787      AC_CHECK_HEADERS(winldap.h, [],
 788                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
 789                       [AC_INCLUDES_DEFAULT
 790 #include <windows.h>
 791                       ])
 792   fi
 793 fi
 794
 795 if test "$with_bonjour" = yes ; then
 796   AC_CHECK_HEADER(DNSServiceDiscovery/DNSServiceDiscovery.h, [], [AC_MSG_ERROR([header file <DNSServiceDiscovery/DNSServiceDiscovery.h> is required for Bonjour])])
 797 fi
 798
 799
 800 ##
 801 ## Types, structures, compiler characteristics
 802 ##
 803
 804 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
 805 AC_C_CONST
 806 AC_C_INLINE
 807 AC_C_STRINGIZE
 808 PGAC_C_SIGNED
 809 AC_C_VOLATILE
 810 PGAC_C_FUNCNAME_SUPPORT
 811 PGAC_STRUCT_TIMEZONE
 812 PGAC_UNION_SEMUN
 813 PGAC_STRUCT_SOCKADDR_UN
 814 PGAC_STRUCT_SOCKADDR_STORAGE
 815 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
 816 PGAC_STRUCT_ADDRINFO
 817
 818 AC_CHECK_TYPES([struct cmsgcred, struct fcred, struct sockcred], [], [],
 819 [#include <sys/param.h>
 820 #include <sys/types.h>
 821 #include <sys/socket.h>
 822 #include <sys/ucred.h>])
 823
 824 AC_CHECK_TYPES([struct option], [], [],
 825 [#ifdef HAVE_GETOPT_H
 826 #include <getopt.h>
 827 #endif])
 828
 829 if test "$with_zlib" = yes; then
 830   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
 831   # did not).  While we could work around the lack of z_streamp, it
 832   # seems unwise to encourage people to use such old zlib versions...
 833   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
 834 Use --without-zlib to disable zlib support.])],
 835                 [#include <zlib.h>])
 836 fi
 837
 838 if test "$with_krb5" = yes; then
 839 # Check for differences between MIT and Heimdal (KTH) releases
 840   AC_CHECK_MEMBERS(krb5_ticket.enc_part2, [],
 841                    [AC_CHECK_MEMBERS(krb5_ticket.client, [],
 842                                      [AC_MSG_ERROR([could not determine how to get client name from Kerberos 5 ticket])],
 843                                      [#include <krb5.h>])],
 844                    [#include <krb5.h>])
 845   AC_CHECK_MEMBERS(krb5_error.text.data, [],
 846                    [AC_CHECK_MEMBERS(krb5_error.e_data, [],
 847                                      [AC_MSG_ERROR([could not determine how to extract Kerberos 5 error messages])],
 848                                      [#include <krb5.h>])],
 849                    [#include <krb5.h>])
 850 fi
 851
 852 # This is probably only present on Darwin, but may as well check always
 853 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
 854
 855 ##
 856 ## Functions, global variables
 857 ##
 858
 859 PGAC_VAR_INT_TIMEZONE
 860 AC_FUNC_ACCEPT_ARGTYPES
 861 PGAC_FUNC_GETTIMEOFDAY_1ARG
 862
 863 AC_CHECK_FUNCS([cbrt dlopen fcvt fdatasync getpeereid memmove poll pstat readlink setproctitle setsid sigprocmask symlink sysconf towlower utime utimes waitpid wcstombs])
 864
 865 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
 866
 867 HAVE_IPV6=no
 868 AC_CHECK_TYPE([struct sockaddr_in6],
 869         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
 870          HAVE_IPV6=yes],
 871         [],
 872 [$ac_includes_default
 873 #include <netinet/in.h>])
 874 AC_SUBST(HAVE_IPV6)
 875
 876 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
 877 [AC_TRY_LINK(
 878 [#include <machine/vmparam.h>
 879 #include <sys/exec.h>
 880 ],
 881 [PS_STRINGS->ps_nargvstr = 1;
 882 PS_STRINGS->ps_argvstr = "foo";],
 883 [pgac_cv_var_PS_STRINGS=yes],
 884 [pgac_cv_var_PS_STRINGS=no])])
 885 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
 886   AC_DEFINE([HAVE_PS_STRINGS], [], [Define to 1 if the PS_STRINGS thing exists.])
 887 fi
 888
 889
 890 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
 891 # is missing.  Yes, there are machines that have only one.  We may
 892 # also decide to use snprintf.c if snprintf() is present but does not
 893 # have all the features we need --- see below.
 894
 895 if test "$PORTNAME" = "win32"; then
 896   # Win32 gets snprintf.c built unconditionally.
 897   #
 898   # To properly translate all NLS languages strings, we must support the
 899   # *printf() %$ format, which allows *printf() arguments to be selected
 900   # by position in the translated string.
 901   #
 902   # libintl versions < 0.13 use the native *printf() functions, and Win32
 903   # *printf() doesn't understand %$, so we must use our /port versions,
 904   # which do understand %$. libintl versions >= 0.13 include their own
 905   # *printf versions on Win32.  The libintl 0.13 release note text is:
 906   #
 907   #   C format strings with positions, as they arise when a translator
 908   #   needs to reorder a sentence, are now supported on all platforms.
 909   #   On those few platforms (NetBSD and Woe32) for which the native
 910   #   printf()/fprintf()/... functions don't support such format
 911   #   strings, replacements are provided through <libintl.h>.
 912   #
 913   # We could use libintl >= 0.13's *printf() if we were sure that we had
 914   # a litint >= 0.13 at runtime, but seeing that there is no clean way
 915   # to guarantee that, it is best to just use our own, so we are sure to
 916   # get %$ support. In include/port.h we disable the *printf() macros
 917   # that might have been defined by libintl.
 918   #
 919   # We do this unconditionally whether NLS is used or not so we are sure
 920   # that all Win32 libraries and binaries behave the same.
 921   pgac_need_repl_snprintf=yes
 922 else
 923   pgac_need_repl_snprintf=no
 924   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
 925   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
 926 fi
 927
 928
 929 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
 930 # include/c.h will provide declarations.  Note this is a separate test
 931 # from whether the functions exist in the C library --- there are
 932 # systems that have the functions but don't bother to declare them :-(
 933
 934 AC_CHECK_DECLS([snprintf, vsnprintf])
 935
 936
 937 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
 938 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
 939 [AC_TRY_LINK([
 940 #include <math.h>
 941 double glob_double;
 942 ],
 943 [return isinf(glob_double) ? 0 : 1;],
 944 [ac_cv_func_isinf=yes],
 945 [ac_cv_func_isinf=no])])
 946
 947 if test $ac_cv_func_isinf = yes ; then
 948   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
 949 else
 950   AC_LIBOBJ(isinf)
 951   # Look for a way to implement a substitute for isinf()
 952   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
 953 fi
 954
 955 AC_REPLACE_FUNCS([crypt fseeko getopt getrusage inet_aton random rint srandom strdup strerror strtol strtoul unsetenv])
 956
 957 # System's version of getaddrinfo(), if any, may be used only if we found
 958 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
 959 # (Note: the AC_REPLACE_FUNCS probe fails on Windows, where the available
 960 # versions of getaddrinfo don't follow normal C call protocol.  This is OK
 961 # because we want to use our own getaddrinfo.c on Windows anyway.)
 962 if test x"$ac_cv_type_struct_addrinfo" = xyes ; then
 963   AC_REPLACE_FUNCS([getaddrinfo])
 964 else
 965   AC_LIBOBJ(getaddrinfo)
 966 fi
 967
 968 # similarly, use system's getopt_long() only if system provides struct option.
 969 if test x"$ac_cv_type_struct_option" = xyes ; then
 970   AC_REPLACE_FUNCS([getopt_long])
 971 else
 972   AC_LIBOBJ(getopt_long)
 973 fi
 974
 975 # BSD/OS & NetBSD use a custom fseeko/ftello built on fsetpos/fgetpos
 976 # We override the previous test that said fseeko/ftello didn't exist
 977 # OS tests are also done in include/c.h and port/fseeko.c
 978 case $host_os in bsdi*|netbsd*)
 979 ac_cv_func_fseeko=yes
 980 esac
 981
 982 # Solaris has a very slow qsort in certain cases, so we replace it:
 983 #   http://forum.sun.com/thread.jspa?forumID=4&threadID=7231
 984 # Supposedly it is fixed in Solaris, but not sure which version, and
 985 # no confirmed testing.  2005-12-16
 986 if test "$PORTNAME" = "solaris"; then
 987 AC_LIBOBJ(qsort)
 988 fi
 989
 990 # Win32 support
 991 if test "$PORTNAME" = "win32"; then
 992 AC_LIBOBJ(gettimeofday)
 993 AC_LIBOBJ(kill)
 994 AC_LIBOBJ(open)
 995 AC_LIBOBJ(rand)
 996 AC_DEFINE([HAVE_SYMLINK], 1,
 997           [Define to 1 if you have the `symlink' function.])
 998 fi
 999
1000 if test "$with_readline" = yes; then
1001   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1002   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function])
1003   AC_CHECK_FUNCS([replace_history_entry])
1004 fi
1005
1006
1007 dnl Cannot use AC_CHECK_FUNC because finite may be a macro
1008 AC_MSG_CHECKING(for finite)
1009 AC_TRY_LINK([
1010 #include <math.h>
1011 double glob_double;
1012 ],
1013             [return finite(glob_double) ? 0 : 1;],
1014             [AC_DEFINE(HAVE_FINITE, 1, [Define to 1 if you have finite().])
1015 AC_MSG_RESULT(yes)],
1016             [AC_MSG_RESULT(no)])
1017
1018 dnl Cannot use AC_CHECK_FUNC because sigsetjmp may be a macro
1019 dnl (especially on GNU libc)
1020 dnl See also comments in c.h.
1021 AC_MSG_CHECKING(for sigsetjmp)
1022 AC_TRY_LINK([#include <setjmp.h>],
1023             [sigjmp_buf x; sigsetjmp(x, 1);],
1024             [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have sigsetjmp().])
1025 AC_MSG_RESULT(yes)],
1026             [AC_MSG_RESULT(no)])
1027
1028 AC_CHECK_FUNC(syslog,
1029               [AC_CHECK_HEADER(syslog.h,
1030                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1031
1032 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1033 [AC_TRY_LINK([#include <unistd.h>],
1034   [extern int optreset; optreset = 1;],
1035   [pgac_cv_var_int_optreset=yes],
1036   [pgac_cv_var_int_optreset=no])])
1037 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1038   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1039 fi
1040
1041 AC_CHECK_FUNCS([strtoll strtoq], [break])
1042 AC_CHECK_FUNCS([strtoull strtouq], [break])
1043
1044 # Check for one of atexit() or on_exit()
1045 AC_CHECK_FUNCS(atexit, [],
1046                [AC_CHECK_FUNCS(on_exit, [],
1047                [AC_MSG_ERROR([neither atexit() nor on_exit() found])])])
1048
1049 AC_FUNC_FSEEKO
1050
1051 #
1052 # Pthreads
1053 #
1054 # For each platform, we need to know about any special compile and link
1055 # libraries, and whether the normal C function names are thread-safe.
1056 # See the comment at the top of src/port/thread.c for more information.
1057 #
1058 if test "$enable_thread_safety" = yes; then
1059 ACX_PTHREAD     # set thread flags
1060
1061 # Some platforms use these, so just defineed them.  They can't hurt if they
1062 # are not supported.
1063 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1064
1065
1066 # At this point, we don't want to muck with the compiler name for threading.
1067 # Let's see who fails, perhaps AIX.  2004-04-23
1068 if test "$PTHREAD_CC" != "$CC"; then
1069 AC_MSG_ERROR([
1070 PostgreSQL does not support platforms that require a special
1071 compiler binary for thread-safety.
1072 ])
1073 fi
1074
1075 if test "$THREAD_SUPPORT" = no; then
1076 AC_MSG_ERROR([
1077 Cannot enable threads on your platform.
1078 Your platform is known to not support thread-safe programs.
1079 For details, compile and run src/bin/pg_thread_test.
1080 ])
1081 fi
1082
1083 # Check for *_r functions
1084 _CFLAGS="$CFLAGS"
1085 _LIBS="$LIBS"
1086 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1087 LIBS="$LIBS $PTHREAD_LIBS"
1088
1089 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([pthread.h not found, required for --enable-thread-safety])])
1090
1091 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1092
1093 # Do test here with the proper thread flags
1094 PGAC_FUNC_GETPWUID_R_5ARG
1095 PGAC_FUNC_STRERROR_R_INT
1096
1097 CFLAGS="$_CFLAGS"
1098 LIBS="$_LIBS"
1099
1100 else
1101 # do not use values from template file
1102 PTHREAD_CFLAGS=
1103 PTHREAD_LIBS=
1104 fi
1105
1106 AC_SUBST(PTHREAD_CFLAGS)
1107 AC_SUBST(PTHREAD_LIBS)
1108
1109
1110 # This test makes sure that run tests work at all.  Sometimes a shared
1111 # library is found by the linker, but the runtime linker can't find it.
1112 # This check should come after all modifications of compiler or linker
1113 # variables, and before any other run tests.
1114 AC_MSG_CHECKING([test program])
1115 AC_TRY_RUN([int main() { return 0; }],
1116 [AC_MSG_RESULT(ok)],
1117 [AC_MSG_RESULT(failed)
1118 AC_MSG_ERROR([[
1119 *** Could not execute a simple test program.  This may be a problem
1120 *** related to locating shared libraries.  Check the file 'config.log'
1121 *** for the exact reason.]])],
1122 [AC_MSG_RESULT([cross-compiling])])
1123
1124 # --------------------
1125 # Run tests below here
1126 # --------------------
1127
1128 # Force use of our snprintf if system's doesn't do arg control
1129 # See comment above at snprintf test for details.
1130 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1131   PGAC_FUNC_PRINTF_ARG_CONTROL
1132   if test $pgac_cv_printf_arg_control != yes ; then
1133     pgac_need_repl_snprintf=yes
1134   fi
1135 fi
1136
1137
1138 dnl Check to see if we have a working 64-bit integer type.
1139 dnl This breaks down into two steps:
1140 dnl (1) figure out if the compiler has a 64-bit int type with working
1141 dnl arithmetic, and if so
1142 dnl (2) see whether snprintf() can format the type correctly.  (Currently,
1143 dnl snprintf is the only library routine we really need for int8 support.)
1144 dnl It's entirely possible to have a compiler that handles a 64-bit type
1145 dnl when the C library doesn't; this is fairly likely when using gcc on
1146 dnl an older platform, for example.
1147 dnl If there is no native snprintf() or it does not handle the 64-bit type,
1148 dnl we force our own version of snprintf() to be used instead.
1149 dnl Note this test must be run after our initial check for snprintf/vsnprintf.
1150
1151 PGAC_TYPE_64BIT_INT([long int])
1152
1153 if test x"$HAVE_LONG_INT_64" = x"no" ; then
1154   PGAC_TYPE_64BIT_INT([long long int])
1155 fi
1156
1157
1158 dnl If we need to use "long long int", figure out whether nnnLL notation works.
1159
1160 if test x"$HAVE_LONG_LONG_INT_64" = xyes ; then
1161   AC_TRY_COMPILE([
1162 #define INT64CONST(x)  x##LL
1163 long long int foo = INT64CONST(0x1234567890123456);
1164 ],
1165         [],
1166         [AC_DEFINE(HAVE_LL_CONSTANTS, 1, [Define to 1 if constants of type 'long long int' should have the suffix LL.])],
1167         [])
1168 fi
1169
1170
1171 # If we found "long int" is 64 bits, assume snprintf handles it.  If
1172 # we found we need to use "long long int", better check.  We cope with
1173 # snprintfs that use %lld, %qd, or %I64d as the format.  If none of these
1174 # work, fall back to our own snprintf emulation (which we know uses %lld).
1175
1176 if test "$HAVE_LONG_LONG_INT_64" = yes ; then
1177   if test $pgac_need_repl_snprintf = no; then
1178     PGAC_FUNC_SNPRINTF_LONG_LONG_INT_FORMAT
1179     if test "$LONG_LONG_INT_FORMAT" = ""; then
1180       # Force usage of our own snprintf, since system snprintf is broken
1181       pgac_need_repl_snprintf=yes
1182       LONG_LONG_INT_FORMAT='%lld'
1183     fi
1184   else
1185     # Here if we previously decided we needed to use our own snprintf
1186     LONG_LONG_INT_FORMAT='%lld'
1187   fi
1188   LONG_LONG_UINT_FORMAT=`echo "$LONG_LONG_INT_FORMAT" | sed 's/d$/u/'`
1189   INT64_FORMAT="\"$LONG_LONG_INT_FORMAT\""
1190   UINT64_FORMAT="\"$LONG_LONG_UINT_FORMAT\""
1191 else
1192   # Here if we are not using 'long long int' at all
1193   INT64_FORMAT='"%ld"'
1194   UINT64_FORMAT='"%lu"'
1195 fi
1196
1197 AC_DEFINE_UNQUOTED(INT64_FORMAT, $INT64_FORMAT,
1198                    [Define to the appropriate snprintf format for 64-bit ints, if any.])
1199
1200 AC_DEFINE_UNQUOTED(UINT64_FORMAT, $UINT64_FORMAT,
1201                    [Define to the appropriate snprintf format for unsigned 64-bit ints, if any.])
1202
1203 # Now we have checked all the reasons to replace snprintf
1204 if test $pgac_need_repl_snprintf = yes; then
1205   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1206   AC_LIBOBJ(snprintf)
1207 fi
1208
1209 # Need a #define for the size of Datum (unsigned long)
1210 AC_CHECK_SIZEOF([unsigned long])
1211
1212 # And one for the size of size_t (enables tweaks for > 32bit address space)
1213 AC_CHECK_SIZEOF([size_t])
1214
1215 # Determine memory alignment requirements for the basic C data types.
1216
1217 PGAC_CHECK_ALIGNOF(short)
1218 PGAC_CHECK_ALIGNOF(int)
1219 PGAC_CHECK_ALIGNOF(long)
1220 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1221   PGAC_CHECK_ALIGNOF(long long int)
1222 fi
1223 PGAC_CHECK_ALIGNOF(double)
1224
1225 # Compute maximum alignment of any basic type.
1226 # We assume long's alignment is at least as strong as char, short, or int;
1227 # but we must check long long (if it exists) and double.
1228
1229 MAX_ALIGNOF=$pgac_cv_alignof_long
1230 if test $MAX_ALIGNOF -lt $pgac_cv_alignof_double ; then
1231   MAX_ALIGNOF=$pgac_cv_alignof_double
1232 fi
1233 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $pgac_cv_alignof_long_long_int ; then
1234   MAX_ALIGNOF="$pgac_cv_alignof_long_long_int"
1235 fi
1236 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1237
1238
1239 # Some platforms predefine the types int8, int16, etc.  Only check
1240 # a (hopefully) representative subset.
1241 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1242 [#include <stdio.h>
1243 #ifdef HAVE_SUPPORTDEFS_H
1244 #include <SupportDefs.h>
1245 #endif])
1246
1247 # We also check for sig_atomic_t, which *should* be defined per ANSI
1248 # C, but is missing on some old platforms.
1249 AC_CHECK_TYPES(sig_atomic_t, [], [], [#include <signal.h>])
1250
1251
1252 if test x"$template" != x"win32"
1253 then
1254 PGAC_FUNC_POSIX_SIGNALS
1255 if test "$pgac_cv_func_posix_signals" != yes -a "$enable_thread_safety" = yes; then
1256   AC_MSG_ERROR([
1257 *** Thread-safety requires POSIX signals, which are not supported by your
1258 *** operating system.
1259 ])
1260 fi
1261 fi
1262
1263 if test $ac_cv_func_fseeko = yes; then
1264 AC_SYS_LARGEFILE
1265 fi
1266
1267 # SunOS doesn't handle negative byte comparisons properly with +/- return
1268 AC_FUNC_MEMCMP
1269
1270
1271 # Select semaphore implementation type.
1272 if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
1273   AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
1274   SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1275 else
1276   if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
1277     AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
1278     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
1279   else
1280     AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
1281     SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
1282   fi
1283 fi
1284
1285
1286 # Select shared-memory implementation type.
1287 AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
1288 SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
1289
1290
1291 # If not set in template file, set bytes to use libc memset()
1292 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
1293   MEMSET_LOOP_LIMIT=1024
1294 fi
1295 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
1296
1297
1298 if test "$enable_nls" = yes ; then
1299   PGAC_CHECK_GETTEXT
1300 fi
1301
1302 # Check for Tcl configuration script tclConfig.sh
1303 if test "$with_tcl" = yes; then
1304     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
1305     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
1306                           [TCL_INCLUDE_SPEC,TCL_LIB_FILE,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
1307     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
1308     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
1309     ac_save_CPPFLAGS=$CPPFLAGS
1310     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
1311     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
1312     CPPFLAGS=$ac_save_CPPFLAGS
1313 fi
1314
1315 #
1316 # Check for DocBook and tools
1317 #
1318 PGAC_PROG_NSGMLS
1319 PGAC_PROG_JADE
1320 PGAC_CHECK_DOCBOOK(4.2)
1321 PGAC_PATH_DOCBOOK_STYLESHEETS
1322 PGAC_PATH_COLLATEINDEX
1323 AC_CHECK_PROGS(SGMLSPL, sgmlspl)
1324
1325 # Thread testing
1326
1327 # We have to run the thread test near the end so we have all our symbols
1328 # defined.  Cross compiling throws a warning.
1329 #
1330 if test "$enable_thread_safety_force" = yes; then
1331 if test x"$template" != x"win32"
1332 then
1333   AC_MSG_WARN([
1334 *** Skipping thread test program.  --enable-thread-safety-force was used.
1335 *** Run the program in src/test/thread on the your machine and add
1336 proper locking function calls to your applications to guarantee thread
1337 safety.
1338 ])
1339 else
1340 AC_MSG_WARN([*** Skipping thread test on Win32])
1341 fi
1342 elif test "$enable_thread_safety" = yes; then
1343 if test x"$template" != x"win32"
1344 then
1345 AC_MSG_CHECKING([thread safety of required library functions])
1346
1347 _CFLAGS="$CFLAGS"
1348 _LIBS="$LIBS"
1349 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
1350 LIBS="$LIBS $PTHREAD_LIBS"
1351 AC_TRY_RUN([#include "$srcdir/src/test/thread/thread_test.c"],
1352   [AC_MSG_RESULT(yes)],
1353   [AC_MSG_RESULT(no)
1354   AC_MSG_ERROR([
1355 *** Thread test program failed.  Your platform is not thread-safe.
1356 *** Check the file 'config.log'for the exact reason.
1357 ***
1358 *** You can use the configure option --enable-thread-safety-force
1359 *** to force threads to be enabled.  However, you must then run
1360 *** the program in src/test/thread and add locking function calls
1361 *** to your applications to guarantee thread safety.
1362 ])],
1363   [AC_MSG_RESULT(maybe)
1364   AC_MSG_WARN([
1365 *** Skipping thread test program because of cross-compile build.
1366 *** Run the program in src/test/thread on the target machine.
1367 ])])
1368 CFLAGS="$_CFLAGS"
1369 LIBS="$_LIBS"
1370 else
1371 AC_MSG_WARN([*** Skipping thread test on Win32])
1372 fi
1373 fi
1374
1375 # prepare build tree if outside source tree
1376 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
1377 # Note 2: /bin/pwd might be better than shell's built-in at getting
1378 #         a symlink-free name.
1379 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
1380   vpath_build=no
1381 else
1382   vpath_build=yes
1383   if test "$no_create" != yes; then
1384     _AS_ECHO_N([preparing build tree... ])
1385     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
1386     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
1387       || AC_MSG_ERROR(failed)
1388     AC_MSG_RESULT(done)
1389   fi
1390 fi
1391 AC_SUBST(vpath_build)
1392
1393
1394 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
1395
1396 AC_CONFIG_LINKS([
1397   src/backend/port/dynloader.c:src/backend/port/dynloader/${template}.c
1398   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
1399   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
1400   src/include/dynloader.h:src/backend/port/dynloader/${template}.h
1401   src/include/pg_config_os.h:src/include/port/${template}.h
1402   src/Makefile.port:src/makefiles/Makefile.${template}
1403 ])
1404
1405 if test "$PORTNAME" = "win32"; then
1406 AC_CONFIG_COMMANDS([check_win32_symlinks],[
1407 # Links sometimes fail undetected on Mingw -
1408 # so here we detect it and warn the user
1409 for FILE in $CONFIG_LINKS
1410  do
1411         # test -e works for symlinks in the MinGW console
1412         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE - please fix by hand])
1413  done
1414 ])
1415 fi
1416
1417 AC_CONFIG_HEADERS([src/include/pg_config.h],
1418 [
1419 # Update timestamp for pg_config.h (see Makefile.global)
1420 echo >src/include/stamp-h
1421 ])
1422
1423 AC_OUTPUT
1424