granicus.if.org Git - postgresql/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl configure.in
   3 dnl
   4 dnl Developers, please strive to achieve this order:
   5 dnl
   6 dnl 0. Initialization and options processing
   7 dnl 1. Programs
   8 dnl 2. Libraries
   9 dnl 3. Header files
  10 dnl 4. Types
  11 dnl 5. Structures
  12 dnl 6. Compiler characteristics
  13 dnl 7. Functions, global variables
  14 dnl 8. System services
  15 dnl
  16 dnl Read the Autoconf manual for details.
  17 dnl
  18 m4_pattern_forbid(^PGAC_)dnl to catch undefined macros
  19
  20 AC_INIT([PostgreSQL], [12devel], [pgsql-bugs@postgresql.org])
  21
  22 m4_if(m4_defn([m4_PACKAGE_VERSION]), [2.69], [], [m4_fatal([Autoconf version 2.69 is required.
  23 Untested combinations of 'autoconf' and PostgreSQL versions are not
  24 recommended.  You can remove the check from 'configure.in' but it is then
  25 your responsibility whether the result works or not.])])
  26 AC_COPYRIGHT([Copyright (c) 1996-2018, PostgreSQL Global Development Group])
  27 AC_CONFIG_SRCDIR([src/backend/access/common/heaptuple.c])
  28 AC_CONFIG_AUX_DIR(config)
  29 AC_PREFIX_DEFAULT(/usr/local/pgsql)
  30 AC_SUBST(configure_args, [$ac_configure_args])
  31
  32 [PG_MAJORVERSION=`expr "$PACKAGE_VERSION" : '\([0-9][0-9]*\)'`]
  33 AC_SUBST(PG_MAJORVERSION)
  34 AC_DEFINE_UNQUOTED(PG_MAJORVERSION, "$PG_MAJORVERSION", [PostgreSQL major version as a string])
  35
  36 PGAC_ARG_REQ(with, extra-version, [STRING], [append STRING to version],
  37              [PG_VERSION="$PACKAGE_VERSION$withval"],
  38              [PG_VERSION="$PACKAGE_VERSION"])
  39 AC_DEFINE_UNQUOTED(PG_VERSION, "$PG_VERSION", [PostgreSQL version as a string])
  40
  41 AC_CANONICAL_HOST
  42
  43 template=
  44 AC_MSG_CHECKING([which template to use])
  45
  46 PGAC_ARG_REQ(with, template, [NAME], [override operating system template],
  47 [
  48   case $withval in
  49     list)   echo; ls "$srcdir/src/template"; exit;;
  50     *)      if test -f "$srcdir/src/template/$with_template" ; then
  51               template=$withval
  52             else
  53               AC_MSG_ERROR(['$withval' is not a valid template name. Use 'list' for a list.])
  54             fi;;
  55   esac
  56 ],
  57 [
  58 # --with-template not given
  59
  60 case $host_os in
  61      aix*) template=aix ;;
  62   cygwin*) template=cygwin ;;
  63   darwin*) template=darwin ;;
  64 dragonfly*) template=netbsd ;;
  65  freebsd*) template=freebsd ;;
  66     hpux*) template=hpux ;;
  67  linux*|gnu*|k*bsd*-gnu)
  68            template=linux ;;
  69    mingw*) template=win32 ;;
  70   netbsd*) template=netbsd ;;
  71  openbsd*) template=openbsd ;;
  72  solaris*) template=solaris ;;
  73 esac
  74
  75   if test x"$template" = x"" ; then
  76     AC_MSG_ERROR([[
  77 *******************************************************************
  78 PostgreSQL has apparently not been ported to your platform yet.
  79 To try a manual configuration, look into the src/template directory
  80 for a similar platform and use the '--with-template=' option.
  81
  82 Please also contact <pgsql-bugs@postgresql.org> to see about
  83 rectifying this.  Include the above 'checking host system type...'
  84 line.
  85 *******************************************************************
  86 ]])
  87   fi
  88
  89 ])
  90
  91 AC_MSG_RESULT([$template])
  92
  93 PORTNAME=$template
  94 AC_SUBST(PORTNAME)
  95
  96 # Initialize default assumption that we do not need separate assembly code
  97 # for TAS (test-and-set).  This can be overridden by the template file
  98 # when it's executed.
  99 need_tas=no
 100 tas_file=dummy.s
 101
 102
 103
 104 ##
 105 ## Command line options
 106 ##
 107
 108 #
 109 # Add non-standard directories to the include path
 110 #
 111 PGAC_ARG_REQ(with, includes, [DIRS], [look for additional header files in DIRS])
 112
 113
 114 #
 115 # Add non-standard directories to the library search path
 116 #
 117 PGAC_ARG_REQ(with, libraries, [DIRS], [look for additional libraries in DIRS],
 118              [LIBRARY_DIRS=$withval])
 119
 120 PGAC_ARG_REQ(with, libs,      [DIRS], [alternative spelling of --with-libraries],
 121              [LIBRARY_DIRS=$withval])
 122
 123
 124 #
 125 # 64-bit integer date/time storage is now the only option, but to avoid
 126 # unnecessary breakage of build scripts, continue to accept an explicit
 127 # "--enable-integer-datetimes" switch.
 128 #
 129 PGAC_ARG_BOOL(enable, integer-datetimes, yes, [obsolete option, no longer supported],
 130               [],
 131               [AC_MSG_ERROR([--disable-integer-datetimes is no longer supported])])
 132
 133
 134 #
 135 # NLS
 136 #
 137 AC_MSG_CHECKING([whether NLS is wanted])
 138 PGAC_ARG_OPTARG(enable, nls,
 139                 [LANGUAGES], [enable Native Language Support],
 140                 [],
 141                 [WANTED_LANGUAGES=$enableval],
 142                 [AC_DEFINE(ENABLE_NLS, 1,
 143                            [Define to 1 if you want National Language Support. (--enable-nls)])])
 144 AC_MSG_RESULT([$enable_nls])
 145 AC_SUBST(enable_nls)
 146 AC_SUBST(WANTED_LANGUAGES)
 147
 148 #
 149 # Default port number (--with-pgport), default 5432
 150 #
 151 AC_MSG_CHECKING([for default port number])
 152 PGAC_ARG_REQ(with, pgport, [PORTNUM], [set default port number [5432]],
 153              [default_port=$withval],
 154              [default_port=5432])
 155 AC_MSG_RESULT([$default_port])
 156 # Need both of these because some places want an integer and some a string
 157 AC_DEFINE_UNQUOTED(DEF_PGPORT, ${default_port},
 158 [Define to the default TCP port number on which the server listens and
 159 to which clients will try to connect.  This can be overridden at run-time,
 160 but it's convenient if your clients have the right default compiled in.
 161 (--with-pgport=PORTNUM)])
 162 AC_DEFINE_UNQUOTED(DEF_PGPORT_STR, "${default_port}",
 163                    [Define to the default TCP port number as a string constant.])
 164 AC_SUBST(default_port)
 165
 166 # It's worth validating port; you can get very confusing errors otherwise
 167 if test x"$default_port" = x""; then
 168   AC_MSG_ERROR([invalid --with-pgport specification: empty string])
 169 elif test ! x`echo "$default_port" | sed -e 's/[[0-9]]*//'` = x""; then
 170   AC_MSG_ERROR([invalid --with-pgport specification: must be a number])
 171 elif test ! x`echo "$default_port" | sed -e 's/^0.//'` = x"$default_port"; then
 172   AC_MSG_ERROR([invalid --with-pgport specification: must not have leading 0])
 173 elif test "$default_port" -lt "1" -o "$default_port" -gt "65535"; then
 174   AC_MSG_ERROR([invalid --with-pgport specification: must be between 1 and 65535])
 175 fi
 176
 177 #
 178 # '-rpath'-like feature can be disabled
 179 #
 180 PGAC_ARG_BOOL(enable, rpath, yes,
 181               [do not embed shared library search path in executables])
 182 AC_SUBST(enable_rpath)
 183
 184 #
 185 # Spinlocks
 186 #
 187 PGAC_ARG_BOOL(enable, spinlocks, yes,
 188               [do not use spinlocks])
 189
 190 #
 191 # Atomic operations
 192 #
 193 PGAC_ARG_BOOL(enable, atomics, yes,
 194               [do not use atomic operations])
 195
 196 #
 197 # Random number generation
 198 #
 199 PGAC_ARG_BOOL(enable, strong-random, yes,
 200               [do not use a strong random number source])
 201 AC_SUBST(enable_strong_random)
 202
 203 #
 204 # --enable-debug adds -g to compiler flags
 205 #
 206 PGAC_ARG_BOOL(enable, debug, no,
 207               [build with debugging symbols (-g)])
 208 AC_SUBST(enable_debug)
 209
 210 #
 211 # --enable-profiling enables gcc profiling
 212 #
 213 PGAC_ARG_BOOL(enable, profiling, no,
 214               [build with profiling enabled ])
 215
 216 #
 217 # --enable-coverage enables generation of code coverage metrics with gcov
 218 #
 219 PGAC_ARG_BOOL(enable, coverage, no,
 220               [build with coverage testing instrumentation],
 221 [PGAC_PATH_PROGS(GCOV, gcov)
 222 if test -z "$GCOV"; then
 223   AC_MSG_ERROR([gcov not found])
 224 fi
 225 PGAC_PATH_PROGS(LCOV, lcov)
 226 if test -z "$LCOV"; then
 227   AC_MSG_ERROR([lcov not found])
 228 fi
 229 PGAC_PATH_PROGS(GENHTML, genhtml)
 230 if test -z "$GENHTML"; then
 231   AC_MSG_ERROR([genhtml not found])
 232 fi])
 233 AC_SUBST(enable_coverage)
 234
 235 #
 236 # DTrace
 237 #
 238 PGAC_ARG_BOOL(enable, dtrace, no,
 239               [build with DTrace support],
 240 [PGAC_PATH_PROGS(DTRACE, dtrace)
 241 if test -z "$DTRACE"; then
 242   AC_MSG_ERROR([dtrace not found])
 243 fi
 244 AC_SUBST(DTRACEFLAGS)])
 245 AC_SUBST(enable_dtrace)
 246
 247 #
 248 # TAP tests
 249 #
 250 PGAC_ARG_BOOL(enable, tap-tests, no,
 251               [enable TAP tests (requires Perl and IPC::Run)])
 252 AC_SUBST(enable_tap_tests)
 253
 254 #
 255 # Block size
 256 #
 257 AC_MSG_CHECKING([for block size])
 258 PGAC_ARG_REQ(with, blocksize, [BLOCKSIZE], [set table block size in kB [8]],
 259              [blocksize=$withval],
 260              [blocksize=8])
 261 case ${blocksize} in
 262   1) BLCKSZ=1024;;
 263   2) BLCKSZ=2048;;
 264   4) BLCKSZ=4096;;
 265   8) BLCKSZ=8192;;
 266  16) BLCKSZ=16384;;
 267  32) BLCKSZ=32768;;
 268   *) AC_MSG_ERROR([Invalid block size. Allowed values are 1,2,4,8,16,32.])
 269 esac
 270 AC_MSG_RESULT([${blocksize}kB])
 271
 272 AC_DEFINE_UNQUOTED([BLCKSZ], ${BLCKSZ}, [
 273  Size of a disk block --- this also limits the size of a tuple.  You
 274  can set it bigger if you need bigger tuples (although TOAST should
 275  reduce the need to have large tuples, since fields can be spread
 276  across multiple tuples).
 277
 278  BLCKSZ must be a power of 2.  The maximum possible value of BLCKSZ
 279  is currently 2^15 (32768).  This is determined by the 15-bit widths
 280  of the lp_off and lp_len fields in ItemIdData (see
 281  include/storage/itemid.h).
 282
 283  Changing BLCKSZ requires an initdb.
 284 ])
 285
 286 #
 287 # Relation segment size
 288 #
 289 AC_MSG_CHECKING([for segment size])
 290 PGAC_ARG_REQ(with, segsize, [SEGSIZE], [set table segment size in GB [1]],
 291              [segsize=$withval],
 292              [segsize=1])
 293 # this expression is set up to avoid unnecessary integer overflow
 294 # blocksize is already guaranteed to be a factor of 1024
 295 RELSEG_SIZE=`expr '(' 1024 / ${blocksize} ')' '*' ${segsize} '*' 1024`
 296 test $? -eq 0 || exit 1
 297 AC_MSG_RESULT([${segsize}GB])
 298
 299 AC_DEFINE_UNQUOTED([RELSEG_SIZE], ${RELSEG_SIZE}, [
 300  RELSEG_SIZE is the maximum number of blocks allowed in one disk file.
 301  Thus, the maximum size of a single file is RELSEG_SIZE * BLCKSZ;
 302  relations bigger than that are divided into multiple files.
 303
 304  RELSEG_SIZE * BLCKSZ must be less than your OS' limit on file size.
 305  This is often 2 GB or 4GB in a 32-bit operating system, unless you
 306  have large file support enabled.  By default, we make the limit 1 GB
 307  to avoid any possible integer-overflow problems within the OS.
 308  A limit smaller than necessary only means we divide a large
 309  relation into more chunks than necessary, so it seems best to err
 310  in the direction of a small limit.
 311
 312  A power-of-2 value is recommended to save a few cycles in md.c,
 313  but is not absolutely required.
 314
 315  Changing RELSEG_SIZE requires an initdb.
 316 ])
 317
 318 #
 319 # WAL block size
 320 #
 321 AC_MSG_CHECKING([for WAL block size])
 322 PGAC_ARG_REQ(with, wal-blocksize, [BLOCKSIZE], [set WAL block size in kB [8]],
 323              [wal_blocksize=$withval],
 324              [wal_blocksize=8])
 325 case ${wal_blocksize} in
 326   1) XLOG_BLCKSZ=1024;;
 327   2) XLOG_BLCKSZ=2048;;
 328   4) XLOG_BLCKSZ=4096;;
 329   8) XLOG_BLCKSZ=8192;;
 330  16) XLOG_BLCKSZ=16384;;
 331  32) XLOG_BLCKSZ=32768;;
 332  64) XLOG_BLCKSZ=65536;;
 333   *) AC_MSG_ERROR([Invalid WAL block size. Allowed values are 1,2,4,8,16,32,64.])
 334 esac
 335 AC_MSG_RESULT([${wal_blocksize}kB])
 336
 337 AC_DEFINE_UNQUOTED([XLOG_BLCKSZ], ${XLOG_BLCKSZ}, [
 338  Size of a WAL file block.  This need have no particular relation to BLCKSZ.
 339  XLOG_BLCKSZ must be a power of 2, and if your system supports O_DIRECT I/O,
 340  XLOG_BLCKSZ must be a multiple of the alignment requirement for direct-I/O
 341  buffers, else direct I/O may fail.
 342
 343  Changing XLOG_BLCKSZ requires an initdb.
 344 ])
 345
 346 #
 347 # C compiler
 348 #
 349
 350 # For historical reasons you can also use --with-CC to specify the C compiler
 351 # to use, although the standard way to do this is to set the CC environment
 352 # variable.
 353 PGAC_ARG_REQ(with, CC, [CMD], [set compiler (deprecated)], [CC=$with_CC])
 354
 355 case $template in
 356   aix) pgac_cc_list="gcc xlc"; pgac_cxx_list="g++ xlC";;
 357     *) pgac_cc_list="gcc cc"; pgac_cxx_list="g++ c++";;
 358 esac
 359
 360 AC_PROG_CC([$pgac_cc_list])
 361 AC_PROG_CC_C99()
 362
 363 # Error out if the compiler does not support C99, as the codebase
 364 # relies on that.
 365 if test "$ac_cv_prog_cc_c99" = no; then
 366     AC_MSG_ERROR([C compiler "$CC" does not support C99])
 367 fi
 368
 369 AC_PROG_CXX([$pgac_cxx_list])
 370
 371 # Check if it's Intel's compiler, which (usually) pretends to be gcc,
 372 # but has idiosyncrasies of its own.  We assume icc will define
 373 # __INTEL_COMPILER regardless of CFLAGS.
 374 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __INTEL_COMPILER
 375 choke me
 376 @%:@endif])], [ICC=yes], [ICC=no])
 377
 378 # Check if it's Sun Studio compiler. We assume that
 379 # __SUNPRO_C will be defined for Sun Studio compilers
 380 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifndef __SUNPRO_C
 381 choke me
 382 @%:@endif])], [SUN_STUDIO_CC=yes], [SUN_STUDIO_CC=no])
 383
 384 AC_SUBST(SUN_STUDIO_CC)
 385
 386
 387 #
 388 # LLVM
 389 #
 390 # Checked early because subsequent tests depend on it.
 391 PGAC_ARG_BOOL(with, llvm, no, [build with LLVM based JIT support],
 392               [AC_DEFINE([USE_LLVM], 1, [Define to 1 to build with LLVM based JIT support. (--with-llvm)])])
 393 AC_SUBST(with_llvm)
 394 if test "$with_llvm" = yes ; then
 395    PGAC_LLVM_SUPPORT()
 396 fi
 397
 398
 399 unset CFLAGS
 400 unset CXXFLAGS
 401
 402 #
 403 # Read the template
 404 #
 405 . "$srcdir/src/template/$template" || exit
 406
 407 # C[XX]FLAGS are selected so:
 408 # If the user specifies something in the environment, that is used.
 409 # else:  If the template file set something, that is used.
 410 # else:  If coverage was enabled, don't set anything.
 411 # else:  If the compiler is GCC, then we use -O2.
 412 # else:  If the compiler is something else, then we use -O, unless debugging.
 413
 414 if test "$ac_env_CFLAGS_set" = set; then
 415   CFLAGS=$ac_env_CFLAGS_value
 416 elif test "${CFLAGS+set}" = set; then
 417   : # (keep what template set)
 418 elif test "$enable_coverage" = yes; then
 419   : # no optimization by default
 420 elif test "$GCC" = yes; then
 421   CFLAGS="-O2"
 422 else
 423   # if the user selected debug mode, don't use -O
 424   if test "$enable_debug" != yes; then
 425     CFLAGS="-O"
 426   fi
 427 fi
 428
 429 if test "$ac_env_CXXFLAGS_set" = set; then
 430   CXXFLAGS=$ac_env_CXXFLAGS_value
 431 elif test "${CXXFLAGS+set}" = set; then
 432   : # (keep what template set)
 433 elif test "$enable_coverage" = yes; then
 434   : # no optimization by default
 435 elif test "$GCC" = yes; then
 436   CXXFLAGS="-O2"
 437 else
 438   # if the user selected debug mode, don't use -O
 439   if test "$enable_debug" != yes; then
 440     CXXFLAGS="-O"
 441   fi
 442 fi
 443
 444 # When generating bitcode (for inlining) we always want to use -O2
 445 # even when --enable-debug is specified. The bitcode it's not going to
 446 # be used for line-by-line debugging, and JIT inlining doesn't work
 447 # without at least -O1 (otherwise clang will emit 'noinline'
 448 # attributes everywhere), which is bad for testing.  Still allow the
 449 # environment to override if done explicitly.
 450 if test "$ac_env_BITCODE_CFLAGS_set" = set; then
 451   BITCODE_CFLAGS=$ac_env_BITCODE_CFLAGS_value
 452 else
 453   BITCODE_CFLAGS="-O2 $BITCODE_CFLAGS"
 454 fi
 455 if test "$ac_env_BITCODE_CXXFLAGS_set" = set; then
 456   BITCODE_CXXFLAGS=$ac_env_BITCODE_CXXFLAGS_value
 457 else
 458   BITCODE_CXXFLAGS="-O2 $BITCODE_CXXFLAGS"
 459 fi
 460
 461 # C[XX]FLAGS we determined above will be added back at the end
 462 user_CFLAGS=$CFLAGS
 463 CFLAGS=""
 464 user_CXXFLAGS=$CXXFLAGS
 465 CXXFLAGS=""
 466 user_BITCODE_CFLAGS=$BITCODE_CFLAGS
 467 BITCODE_CFLAGS=""
 468 user_BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS
 469 BITCODE_CXXFLAGS=""
 470
 471 # set CFLAGS_VECTOR from the environment, if available
 472 if test "$ac_env_CFLAGS_VECTOR_set" = set; then
 473   CFLAGS_VECTOR=$ac_env_CFLAGS_VECTOR_value
 474 fi
 475
 476 # Some versions of GCC support some additional useful warning flags.
 477 # Check whether they are supported, and add them to CFLAGS if so.
 478 # ICC pretends to be GCC but it's lying; it doesn't support these flags,
 479 # but has its own.  Also check other compiler-specific flags here.
 480
 481 if test "$GCC" = yes -a "$ICC" = no; then
 482   CFLAGS="-Wall -Wmissing-prototypes -Wpointer-arith"
 483   CXXFLAGS="-Wall -Wpointer-arith"
 484   # These work in some but not all gcc versions
 485   PGAC_PROG_CC_CFLAGS_OPT([-Wdeclaration-after-statement])
 486   # -Wdeclaration-after-statement isn't applicable for C++
 487   # Really don't want VLAs to be used in our dialect of C
 488   PGAC_PROG_CC_CFLAGS_OPT([-Werror=vla])
 489   # -Wvla is not applicable for C++
 490   PGAC_PROG_CC_CFLAGS_OPT([-Wendif-labels])
 491   PGAC_PROG_CXX_CFLAGS_OPT([-Wendif-labels])
 492   PGAC_PROG_CC_CFLAGS_OPT([-Wmissing-format-attribute])
 493   PGAC_PROG_CXX_CFLAGS_OPT([-Wmissing-format-attribute])
 494   # This was included in -Wall/-Wformat in older GCC versions
 495   PGAC_PROG_CC_CFLAGS_OPT([-Wformat-security])
 496   PGAC_PROG_CXX_CFLAGS_OPT([-Wformat-security])
 497   # Disable strict-aliasing rules; needed for gcc 3.3+
 498   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 499   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 500   # Disable optimizations that assume no overflow; needed for gcc 4.3+
 501   PGAC_PROG_CC_CFLAGS_OPT([-fwrapv])
 502   PGAC_PROG_CXX_CFLAGS_OPT([-fwrapv])
 503   # Disable FP optimizations that cause various errors on gcc 4.5+ or maybe 4.6+
 504   PGAC_PROG_CC_CFLAGS_OPT([-fexcess-precision=standard])
 505   PGAC_PROG_CXX_CFLAGS_OPT([-fexcess-precision=standard])
 506   # Optimization flags for specific files that benefit from vectorization
 507   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-funroll-loops])
 508   PGAC_PROG_CC_VAR_OPT(CFLAGS_VECTOR, [-ftree-vectorize])
 509   # We want to suppress clang's unhelpful unused-command-line-argument warnings
 510   # but gcc won't complain about unrecognized -Wno-foo switches, so we have to
 511   # test for the positive form and if that works, add the negative form
 512   NOT_THE_CFLAGS=""
 513   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wunused-command-line-argument])
 514   if test -n "$NOT_THE_CFLAGS"; then
 515     CFLAGS="$CFLAGS -Wno-unused-command-line-argument"
 516   fi
 517   # Similarly disable useless truncation warnings from gcc 8+
 518   NOT_THE_CFLAGS=""
 519   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wformat-truncation])
 520   if test -n "$NOT_THE_CFLAGS"; then
 521     CFLAGS="$CFLAGS -Wno-format-truncation"
 522   fi
 523   NOT_THE_CFLAGS=""
 524   PGAC_PROG_CC_VAR_OPT(NOT_THE_CFLAGS, [-Wstringop-truncation])
 525   if test -n "$NOT_THE_CFLAGS"; then
 526     CFLAGS="$CFLAGS -Wno-stringop-truncation"
 527   fi
 528 elif test "$ICC" = yes; then
 529   # Intel's compiler has a bug/misoptimization in checking for
 530   # division by NAN (NaN == 0), -mp1 fixes it, so add it to the CFLAGS.
 531   PGAC_PROG_CC_CFLAGS_OPT([-mp1])
 532   PGAC_PROG_CXX_CFLAGS_OPT([-mp1])
 533   # Make sure strict aliasing is off (though this is said to be the default)
 534   PGAC_PROG_CC_CFLAGS_OPT([-fno-strict-aliasing])
 535   PGAC_PROG_CXX_CFLAGS_OPT([-fno-strict-aliasing])
 536 elif test "$PORTNAME" = "aix"; then
 537   # AIX's xlc has to have strict aliasing turned off too
 538   PGAC_PROG_CC_CFLAGS_OPT([-qnoansialias])
 539   PGAC_PROG_CXX_CFLAGS_OPT([-qnoansialias])
 540   PGAC_PROG_CC_CFLAGS_OPT([-qlonglong])
 541   PGAC_PROG_CXX_CFLAGS_OPT([-qlonglong])
 542 elif test "$PORTNAME" = "hpux"; then
 543   # On some versions of HP-UX, libm functions do not set errno by default.
 544   # Fix that by using +Olibmerrno if the compiler recognizes it.
 545   PGAC_PROG_CC_CFLAGS_OPT([+Olibmerrno])
 546   PGAC_PROG_CXX_CFLAGS_OPT([+Olibmerrno])
 547 fi
 548
 549 AC_SUBST(CFLAGS_VECTOR, $CFLAGS_VECTOR)
 550
 551 # Determine flags used to emit bitcode for JIT inlining. Need to test
 552 # for behaviour changing compiler flags, to keep compatibility with
 553 # compiler used for normal postgres code.
 554 if test "$with_llvm" = yes ; then
 555   CLANGXX="$CLANG -xc++"
 556
 557   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fno-strict-aliasing])
 558   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fno-strict-aliasing])
 559   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fwrapv])
 560   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fwrapv])
 561   PGAC_PROG_VARCC_VARFLAGS_OPT(CLANG, BITCODE_CFLAGS, [-fexcess-precision=standard])
 562   PGAC_PROG_VARCXX_VARFLAGS_OPT(CLANGXX, BITCODE_CXXFLAGS, [-fexcess-precision=standard])
 563 fi
 564
 565 # supply -g if --enable-debug
 566 if test "$enable_debug" = yes && test "$ac_cv_prog_cc_g" = yes; then
 567   CFLAGS="$CFLAGS -g"
 568 fi
 569
 570 if test "$enable_debug" = yes && test "$ac_cv_prog_cxx_g" = yes; then
 571   CXXFLAGS="$CXXFLAGS -g"
 572 fi
 573
 574 # enable code coverage if --enable-coverage
 575 if test "$enable_coverage" = yes; then
 576   if test "$GCC" = yes; then
 577     CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
 578     CXXFLAGS="$CXXFLAGS -fprofile-arcs -ftest-coverage"
 579   else
 580     AC_MSG_ERROR([--enable-coverage is supported only when using GCC])
 581   fi
 582 fi
 583
 584 # enable profiling if --enable-profiling
 585 if test "$enable_profiling" = yes && test "$ac_cv_prog_cc_g" = yes; then
 586   if test "$GCC" = yes; then
 587     AC_DEFINE([PROFILE_PID_DIR], 1,
 588            [Define to 1 to allow profiling output to be saved separately for each process.])
 589     CFLAGS="$CFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 590     CXXFLAGS="$CXXFLAGS -pg $PLATFORM_PROFILE_FLAGS"
 591   else
 592     AC_MSG_ERROR([--enable-profiling is supported only when using GCC])
 593   fi
 594 fi
 595
 596 # We already have this in Makefile.win32, but configure needs it too
 597 if test "$PORTNAME" = "win32"; then
 598   CPPFLAGS="$CPPFLAGS -I$srcdir/src/include/port/win32 -DEXEC_BACKEND"
 599 fi
 600
 601 # Now that we're done automatically adding stuff to C[XX]FLAGS, put back the
 602 # user-specified flags (if any) at the end.  This lets users override
 603 # the automatic additions.
 604 CFLAGS="$CFLAGS $user_CFLAGS"
 605 CXXFLAGS="$CXXFLAGS $user_CXXFLAGS"
 606 BITCODE_CFLAGS="$BITCODE_CFLAGS $user_BITCODE_CFLAGS"
 607 BITCODE_CXXFLAGS="$BITCODE_CXXFLAGS $user_BITCODE_CXXFLAGS"
 608
 609 AC_SUBST(BITCODE_CFLAGS, $BITCODE_CFLAGS)
 610 AC_SUBST(BITCODE_CXXFLAGS, $BITCODE_CXXFLAGS)
 611
 612 # Check if the compiler still works with the final flag settings
 613 # (note, we're not checking that for CXX, which is optional)
 614 AC_MSG_CHECKING([whether the C compiler still works])
 615 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 616   [AC_MSG_RESULT(yes)],
 617   [AC_MSG_RESULT(no)
 618    AC_MSG_ERROR([cannot proceed])])
 619
 620 # Defend against gcc -ffast-math
 621 if test "$GCC" = yes; then
 622 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [@%:@ifdef __FAST_MATH__
 623 choke me
 624 @%:@endif])], [], [AC_MSG_ERROR([do not put -ffast-math in CFLAGS])])
 625 fi
 626
 627 # Defend against clang being used on x86-32 without SSE2 enabled.  As current
 628 # versions of clang do not understand -fexcess-precision=standard, the use of
 629 # x87 floating point operations leads to problems like isinf possibly returning
 630 # false for a value that is infinite when converted from the 80bit register to
 631 # the 8byte memory representation.
 632 #
 633 # Only perform the test if the compiler doesn't understand
 634 # -fexcess-precision=standard, that way a potentially fixed compiler will work
 635 # automatically.
 636 if test "$pgac_cv_prog_CC_cflags__fexcess_precision_standard" = no; then
 637 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
 638 @%:@if defined(__clang__) && defined(__i386__) && !defined(__SSE2_MATH__)
 639 choke me
 640 @%:@endif
 641 ])], [],
 642 [AC_MSG_ERROR([Compiling PostgreSQL with clang, on 32bit x86, requires SSE2 support. Use -msse2 or use gcc.])])
 643 fi
 644
 645 AC_PROG_CPP
 646 AC_SUBST(GCC)
 647
 648
 649 #
 650 # Set up TAS assembly code if needed; the template file has now had its
 651 # chance to request this.
 652 #
 653 AC_CONFIG_LINKS([src/backend/port/tas.s:src/backend/port/tas/${tas_file}])
 654
 655 if test "$need_tas" = yes ; then
 656   TAS=tas.o
 657 else
 658   TAS=""
 659 fi
 660 AC_SUBST(TAS)
 661
 662
 663 #
 664 # Automatic dependency tracking
 665 #
 666 PGAC_ARG_BOOL(enable, depend, no, [turn on automatic dependency tracking],
 667               [autodepend=yes])
 668 AC_SUBST(autodepend)
 669
 670
 671 #
 672 # Enable assert checks
 673 #
 674 PGAC_ARG_BOOL(enable, cassert, no, [enable assertion checks (for debugging)],
 675               [AC_DEFINE([USE_ASSERT_CHECKING], 1,
 676                          [Define to 1 to build with assertion checks. (--enable-cassert)])])
 677
 678
 679 #
 680 # Include directories
 681 #
 682 ac_save_IFS=$IFS
 683 IFS="${IFS}${PATH_SEPARATOR}"
 684 # SRCH_INC comes from the template file
 685 for dir in $with_includes $SRCH_INC; do
 686   if test -d "$dir"; then
 687     INCLUDES="$INCLUDES -I$dir"
 688   else
 689     AC_MSG_WARN([*** Include directory $dir does not exist.])
 690   fi
 691 done
 692 IFS=$ac_save_IFS
 693 AC_SUBST(INCLUDES)
 694
 695
 696 #
 697 # Library directories
 698 #
 699 ac_save_IFS=$IFS
 700 IFS="${IFS}${PATH_SEPARATOR}"
 701 # LIBRARY_DIRS comes from command line, SRCH_LIB from template file.
 702 for dir in $LIBRARY_DIRS $SRCH_LIB; do
 703   if test -d "$dir"; then
 704     LIBDIRS="$LIBDIRS -L$dir"
 705   else
 706     AC_MSG_WARN([*** Library directory $dir does not exist.])
 707   fi
 708 done
 709 IFS=$ac_save_IFS
 710
 711 #
 712 # Enable thread-safe client libraries
 713 #
 714 AC_MSG_CHECKING([allow thread-safe client libraries])
 715 PGAC_ARG_BOOL(enable, thread-safety, yes, [disable thread-safety in client libraries])
 716 if test "$enable_thread_safety" = yes; then
 717   AC_DEFINE([ENABLE_THREAD_SAFETY], 1,
 718           [Define to 1 to build client libraries as thread-safe code. (--enable-thread-safety)])
 719 fi
 720 AC_MSG_RESULT([$enable_thread_safety])
 721 AC_SUBST(enable_thread_safety)
 722
 723 #
 724 # ICU
 725 #
 726 AC_MSG_CHECKING([whether to build with ICU support])
 727 PGAC_ARG_BOOL(with, icu, no, [build with ICU support],
 728               [AC_DEFINE([USE_ICU], 1, [Define to build with ICU support. (--with-icu)])])
 729 AC_MSG_RESULT([$with_icu])
 730 AC_SUBST(with_icu)
 731
 732 if test "$with_icu" = yes; then
 733   PKG_CHECK_MODULES(ICU, icu-uc icu-i18n)
 734 fi
 735
 736 #
 737 # Optionally build Tcl modules (PL/Tcl)
 738 #
 739 AC_MSG_CHECKING([whether to build with Tcl])
 740 PGAC_ARG_BOOL(with, tcl, no, [build Tcl modules (PL/Tcl)])
 741 AC_MSG_RESULT([$with_tcl])
 742 AC_SUBST([with_tcl])
 743
 744 # We see if the path to the Tcl/Tk configuration scripts is specified.
 745 # This will override the use of tclsh to find the paths to search.
 746
 747 PGAC_ARG_REQ(with, tclconfig, [DIR], [tclConfig.sh is in DIR])
 748
 749 #
 750 # Optionally build Perl modules (PL/Perl)
 751 #
 752 AC_MSG_CHECKING([whether to build Perl modules])
 753 PGAC_ARG_BOOL(with, perl, no, [build Perl modules (PL/Perl)])
 754 AC_MSG_RESULT([$with_perl])
 755 AC_SUBST(with_perl)
 756
 757 #
 758 # Optionally build Python modules (PL/Python)
 759 #
 760 AC_MSG_CHECKING([whether to build Python modules])
 761 PGAC_ARG_BOOL(with, python, no, [build Python modules (PL/Python)])
 762 AC_MSG_RESULT([$with_python])
 763 AC_SUBST(with_python)
 764
 765 #
 766 # GSSAPI
 767 #
 768 AC_MSG_CHECKING([whether to build with GSSAPI support])
 769 PGAC_ARG_BOOL(with, gssapi, no, [build with GSSAPI support],
 770 [
 771   AC_DEFINE(ENABLE_GSS, 1, [Define to build with GSSAPI support. (--with-gssapi)])
 772   krb_srvtab="FILE:\$(sysconfdir)/krb5.keytab"
 773 ])
 774 AC_MSG_RESULT([$with_gssapi])
 775 AC_SUBST(with_gssapi)
 776
 777
 778 AC_SUBST(krb_srvtab)
 779
 780
 781 #
 782 # Kerberos configuration parameters
 783 #
 784 PGAC_ARG_REQ(with, krb-srvnam,
 785              [NAME], [default service principal name in Kerberos (GSSAPI) [postgres]],
 786              [],
 787              [with_krb_srvnam="postgres"])
 788 AC_SUBST(with_krb_srvnam)
 789 AC_DEFINE_UNQUOTED([PG_KRB_SRVNAM], ["$with_krb_srvnam"],
 790                    [Define to the name of the default PostgreSQL service principal in Kerberos (GSSAPI). (--with-krb-srvnam=NAME)])
 791
 792
 793 #
 794 # PAM
 795 #
 796 AC_MSG_CHECKING([whether to build with PAM support])
 797 PGAC_ARG_BOOL(with, pam, no,
 798               [build with PAM support],
 799               [AC_DEFINE([USE_PAM], 1, [Define to 1 to build with PAM support. (--with-pam)])])
 800 AC_MSG_RESULT([$with_pam])
 801
 802
 803 #
 804 # BSD AUTH
 805 #
 806 AC_MSG_CHECKING([whether to build with BSD Authentication support])
 807 PGAC_ARG_BOOL(with, bsd-auth, no,
 808               [build with BSD Authentication support],
 809               [AC_DEFINE([USE_BSD_AUTH], 1, [Define to 1 to build with BSD Authentication support. (--with-bsd-auth)])])
 810 AC_MSG_RESULT([$with_bsd_auth])
 811
 812
 813 #
 814 # LDAP
 815 #
 816 AC_MSG_CHECKING([whether to build with LDAP support])
 817 PGAC_ARG_BOOL(with, ldap, no,
 818               [build with LDAP support],
 819               [AC_DEFINE([USE_LDAP], 1, [Define to 1 to build with LDAP support. (--with-ldap)])])
 820 AC_MSG_RESULT([$with_ldap])
 821 AC_SUBST(with_ldap)
 822
 823
 824 #
 825 # Bonjour
 826 #
 827 AC_MSG_CHECKING([whether to build with Bonjour support])
 828 PGAC_ARG_BOOL(with, bonjour, no,
 829               [build with Bonjour support],
 830               [AC_DEFINE([USE_BONJOUR], 1, [Define to 1 to build with Bonjour support. (--with-bonjour)])])
 831 AC_MSG_RESULT([$with_bonjour])
 832
 833
 834 #
 835 # OpenSSL
 836 #
 837 AC_MSG_CHECKING([whether to build with OpenSSL support])
 838 PGAC_ARG_BOOL(with, openssl, no, [build with OpenSSL support],
 839               [AC_DEFINE([USE_OPENSSL], 1, [Define to build with OpenSSL support. (--with-openssl)])])
 840 AC_MSG_RESULT([$with_openssl])
 841 AC_SUBST(with_openssl)
 842
 843 #
 844 # SELinux
 845 #
 846 AC_MSG_CHECKING([whether to build with SELinux support])
 847 PGAC_ARG_BOOL(with, selinux, no, [build with SELinux support])
 848 AC_SUBST(with_selinux)
 849 AC_MSG_RESULT([$with_selinux])
 850
 851 #
 852 # Systemd
 853 #
 854 AC_MSG_CHECKING([whether to build with systemd support])
 855 PGAC_ARG_BOOL(with, systemd, no, [build with systemd support],
 856               [AC_DEFINE([USE_SYSTEMD], 1, [Define to build with systemd support. (--with-systemd)])])
 857 AC_SUBST(with_systemd)
 858 AC_MSG_RESULT([$with_systemd])
 859
 860 #
 861 # Readline
 862 #
 863 PGAC_ARG_BOOL(with, readline, yes,
 864               [do not use GNU Readline nor BSD Libedit for editing])
 865 # readline on MinGW has problems with backslashes in psql and other bugs.
 866 # This is particularly a problem with non-US code pages.
 867 # Therefore disable its use until we understand the cause. 2004-07-20
 868 if test "$PORTNAME" = "win32"; then
 869   if test "$with_readline" = yes; then
 870     AC_MSG_WARN([*** Readline does not work on MinGW --- disabling])
 871     with_readline=no
 872   fi
 873 fi
 874
 875
 876 #
 877 # Prefer libedit
 878 #
 879 PGAC_ARG_BOOL(with, libedit-preferred, no,
 880               [prefer BSD Libedit over GNU Readline])
 881
 882
 883 #
 884 # UUID library
 885 #
 886 # There are at least three UUID libraries in common use: the FreeBSD/NetBSD
 887 # library, the e2fsprogs libuuid (now part of util-linux-ng), and the OSSP
 888 # UUID library.  More than one of these might be present on a given platform,
 889 # so we make the user say which one she wants.
 890 #
 891 PGAC_ARG_REQ(with, uuid, [LIB], [build contrib/uuid-ossp using LIB (bsd,e2fs,ossp)])
 892 if test x"$with_uuid" = x"" ; then
 893   with_uuid=no
 894 fi
 895 PGAC_ARG_BOOL(with, ossp-uuid, no, [obsolete spelling of --with-uuid=ossp])
 896 if test "$with_ossp_uuid" = yes ; then
 897   with_uuid=ossp
 898 fi
 899
 900 if test "$with_uuid" = bsd ; then
 901   AC_DEFINE([HAVE_UUID_BSD], 1, [Define to 1 if you have BSD UUID support.])
 902   UUID_EXTRA_OBJS="md5.o sha1.o"
 903 elif test "$with_uuid" = e2fs ; then
 904   AC_DEFINE([HAVE_UUID_E2FS], 1, [Define to 1 if you have E2FS UUID support.])
 905   UUID_EXTRA_OBJS="md5.o sha1.o"
 906 elif test "$with_uuid" = ossp ; then
 907   AC_DEFINE([HAVE_UUID_OSSP], 1, [Define to 1 if you have OSSP UUID support.])
 908   UUID_EXTRA_OBJS=""
 909 elif test "$with_uuid" = no ; then
 910   UUID_EXTRA_OBJS=""
 911 else
 912   AC_MSG_ERROR([--with-uuid must specify one of bsd, e2fs, or ossp])
 913 fi
 914 AC_SUBST(with_uuid)
 915 AC_SUBST(UUID_EXTRA_OBJS)
 916
 917
 918 #
 919 # XML
 920 #
 921 PGAC_ARG_BOOL(with, libxml, no, [build with XML support],
 922               [AC_DEFINE([USE_LIBXML], 1, [Define to 1 to build with XML support. (--with-libxml)])])
 923
 924 if test "$with_libxml" = yes ; then
 925   PGAC_PATH_PROGS(XML2_CONFIG, xml2-config)
 926   if test -n "$XML2_CONFIG"; then
 927     for pgac_option in `$XML2_CONFIG --cflags`; do
 928       case $pgac_option in
 929         -I*|-D*) CPPFLAGS="$CPPFLAGS $pgac_option";;
 930       esac
 931     done
 932     for pgac_option in `$XML2_CONFIG --libs`; do
 933       case $pgac_option in
 934         -L*) LDFLAGS="$LDFLAGS $pgac_option";;
 935       esac
 936     done
 937   fi
 938 fi
 939
 940 AC_SUBST(with_libxml)
 941
 942 #
 943 # XSLT
 944 #
 945 PGAC_ARG_BOOL(with, libxslt, no, [use XSLT support when building contrib/xml2],
 946               [AC_DEFINE([USE_LIBXSLT], 1, [Define to 1 to use XSLT support when building contrib/xml2. (--with-libxslt)])])
 947
 948
 949 AC_SUBST(with_libxslt)
 950
 951 #
 952 # tzdata
 953 #
 954 PGAC_ARG_REQ(with, system-tzdata,
 955              [DIR], [use system time zone data in DIR])
 956 AC_SUBST(with_system_tzdata)
 957
 958 #
 959 # Zlib
 960 #
 961 PGAC_ARG_BOOL(with, zlib, yes,
 962               [do not use Zlib])
 963 AC_SUBST(with_zlib)
 964
 965 #
 966 # Elf
 967 #
 968
 969 # Assume system is ELF if it predefines __ELF__ as 1,
 970 # otherwise believe host_os based default.
 971 case $host_os in
 972     freebsd1*|freebsd2*) elf=no;;
 973     freebsd3*|freebsd4*) elf=yes;;
 974 esac
 975
 976 AC_EGREP_CPP(yes,
 977 [#if __ELF__
 978   yes
 979 #endif
 980 ],
 981 [ELF_SYS=true],
 982 [if test "X$elf" = "Xyes" ; then
 983   ELF_SYS=true
 984 else
 985   ELF_SYS=
 986 fi])
 987 AC_SUBST(ELF_SYS)
 988
 989 #
 990 # Assignments
 991 #
 992
 993 CPPFLAGS="$CPPFLAGS $INCLUDES"
 994 LDFLAGS="$LDFLAGS $LIBDIRS"
 995
 996 AC_ARG_VAR(LDFLAGS_EX, [extra linker flags for linking executables only])
 997 AC_ARG_VAR(LDFLAGS_SL, [extra linker flags for linking shared libraries only])
 998
 999 PGAC_PROG_LD
1000 AC_SUBST(LD)
1001 AC_SUBST(with_gnu_ld)
1002 AC_PROG_RANLIB
1003 PGAC_CHECK_STRIP
1004 AC_CHECK_TOOL(AR, ar, ar)
1005 if test "$PORTNAME" = "win32"; then
1006   AC_CHECK_TOOL(DLLTOOL, dlltool, dlltool)
1007   AC_CHECK_TOOL(DLLWRAP, dllwrap, dllwrap)
1008   AC_CHECK_TOOL(WINDRES, windres, windres)
1009 fi
1010
1011 AC_PROG_INSTALL
1012 # When Autoconf chooses install-sh as install program it tries to generate
1013 # a relative path to it in each makefile where it substitutes it. This clashes
1014 # with our Makefile.global concept. This workaround helps.
1015 case $INSTALL in
1016   *install-sh*) install_bin='';;
1017   *) install_bin=$INSTALL;;
1018 esac
1019 AC_SUBST(install_bin)
1020
1021 PGAC_PATH_PROGS(TAR, tar)
1022 AC_PROG_LN_S
1023 AC_PROG_AWK
1024 AC_PROG_MKDIR_P
1025 # When Autoconf chooses install-sh as mkdir -p program it tries to generate
1026 # a relative path to it in each makefile where it substitutes it. This clashes
1027 # with our Makefile.global concept. This workaround helps.
1028 case $MKDIR_P in
1029   *install-sh*) MKDIR_P='\${SHELL} \${top_srcdir}/config/install-sh -c -d';;
1030 esac
1031
1032 PGAC_PATH_BISON
1033 PGAC_PATH_FLEX
1034
1035 PGAC_PATH_PERL
1036 if test "$with_perl" = yes; then
1037   if test -z "$PERL"; then
1038     AC_MSG_ERROR([Perl not found])
1039   fi
1040   PGAC_CHECK_PERL_CONFIGS([archlibexp,privlibexp,useshrplib])
1041   if test "$perl_useshrplib" != yes && test "$perl_useshrplib" != true; then
1042     AC_MSG_ERROR([cannot build PL/Perl because libperl is not a shared library
1043 You might have to rebuild your Perl installation.  Refer to the
1044 documentation for details.  Use --without-perl to disable building
1045 PL/Perl.])
1046   fi
1047   PGAC_CHECK_PERL_EMBED_CCFLAGS
1048   PGAC_CHECK_PERL_EMBED_LDFLAGS
1049 fi
1050
1051 if test "$with_python" = yes; then
1052   PGAC_PATH_PYTHON
1053   PGAC_CHECK_PYTHON_EMBED_SETUP
1054 fi
1055
1056 if test "$cross_compiling" = yes && test -z "$with_system_tzdata"; then
1057   PGAC_PATH_PROGS(ZIC, zic)
1058   if test -z "$ZIC"; then
1059     AC_MSG_ERROR([
1060 When cross-compiling, either use the option --with-system-tzdata to use
1061 existing time-zone data, or set the environment variable ZIC to a zic
1062 program to use during the build.])
1063   fi
1064 fi
1065
1066 #
1067 # Pthreads
1068 #
1069 # For each platform, we need to know about any special compile and link
1070 # libraries, and whether the normal C function names are thread-safe.
1071 # See the comment at the top of src/port/thread.c for more information.
1072 # WIN32 doesn't need the pthread tests;  it always uses threads
1073 #
1074 # These tests are run before the library-tests, because linking with the
1075 # other libraries can pull in the pthread functions as a side-effect.  We
1076 # want to use the -pthread or similar flags directly, and not rely on
1077 # the side-effects of linking with some other library.
1078 #
1079 # note: We have to use AS_IF here rather than plain if. The AC_CHECK_HEADER
1080 # invocation below is the first one in the script, and autoconf generates
1081 # additional code for that, which must not be inside the if-block. AS_IF
1082 # knows how to do that.
1083 AS_IF([test "$enable_thread_safety" = yes -a "$PORTNAME" != "win32"],
1084 [ # then
1085 AX_PTHREAD      # set thread flags
1086
1087 # Some platforms use these, so just define them.  They can't hurt if they
1088 # are not supported.  For example, on Solaris -D_POSIX_PTHREAD_SEMANTICS
1089 # enables 5-arg getpwuid_r, among other things.
1090 PTHREAD_CFLAGS="$PTHREAD_CFLAGS -D_REENTRANT -D_THREAD_SAFE -D_POSIX_PTHREAD_SEMANTICS"
1091
1092 # Check for *_r functions
1093 _CFLAGS="$CFLAGS"
1094 _LIBS="$LIBS"
1095 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
1096 LIBS="$LIBS $PTHREAD_LIBS"
1097
1098 AC_CHECK_HEADER(pthread.h, [], [AC_MSG_ERROR([
1099 pthread.h not found;  use --disable-thread-safety to disable thread safety])])
1100
1101 AC_CHECK_FUNCS([strerror_r getpwuid_r gethostbyname_r])
1102
1103 # Do test here with the proper thread flags
1104 PGAC_FUNC_STRERROR_R_INT
1105
1106 CFLAGS="$_CFLAGS"
1107 LIBS="$_LIBS"
1108
1109 ], [ # else
1110 # do not use values from template file
1111 PTHREAD_CFLAGS=
1112 PTHREAD_LIBS=
1113 ]) # fi
1114
1115 AC_SUBST(PTHREAD_CFLAGS)
1116 AC_SUBST(PTHREAD_LIBS)
1117
1118
1119 ##
1120 ## Libraries
1121 ##
1122 ## Most libraries are included only if they demonstrably provide a function
1123 ## we need, but libm is an exception: always include it, because there are
1124 ## too many compilers that play cute optimization games that will break
1125 ## probes for standard functions such as pow().
1126 ##
1127
1128 AC_CHECK_LIB(m, main)
1129 AC_SEARCH_LIBS(setproctitle, util)
1130 AC_SEARCH_LIBS(dlopen, dl)
1131 AC_SEARCH_LIBS(socket, [socket ws2_32])
1132 AC_SEARCH_LIBS(shl_load, dld)
1133 AC_SEARCH_LIBS(getopt_long, [getopt gnugetopt])
1134 AC_SEARCH_LIBS(crypt, crypt)
1135 AC_SEARCH_LIBS(shm_open, rt)
1136 AC_SEARCH_LIBS(shm_unlink, rt)
1137 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1138 # Solaris:
1139 AC_SEARCH_LIBS(fdatasync, [rt posix4])
1140 # Required for thread_test.c on Solaris
1141 AC_SEARCH_LIBS(sched_yield, rt)
1142 # Required for thread_test.c on Solaris 2.5:
1143 # Other ports use it too (HP-UX) so test unconditionally
1144 AC_SEARCH_LIBS(gethostbyname_r, nsl)
1145 # Cygwin:
1146 AC_SEARCH_LIBS(shmget, cygipc)
1147
1148 if test "$with_readline" = yes; then
1149   PGAC_CHECK_READLINE
1150   if test x"$pgac_cv_check_readline" = x"no"; then
1151     AC_MSG_ERROR([readline library not found
1152 If you have readline already installed, see config.log for details on the
1153 failure.  It is possible the compiler isn't looking in the proper directory.
1154 Use --without-readline to disable readline support.])
1155   fi
1156 fi
1157
1158 if test "$with_zlib" = yes; then
1159   AC_CHECK_LIB(z, inflate, [],
1160                [AC_MSG_ERROR([zlib library not found
1161 If you have zlib already installed, see config.log for details on the
1162 failure.  It is possible the compiler isn't looking in the proper directory.
1163 Use --without-zlib to disable zlib support.])])
1164 fi
1165
1166 if test "$enable_spinlocks" = yes; then
1167   AC_DEFINE(HAVE_SPINLOCKS, 1, [Define to 1 if you have spinlocks.])
1168 else
1169   AC_MSG_WARN([
1170 *** Not using spinlocks will cause poor performance.])
1171 fi
1172
1173 if test "$enable_atomics" = yes; then
1174   AC_DEFINE(HAVE_ATOMICS, 1, [Define to 1 if you want to use atomics if available.])
1175 else
1176   AC_MSG_WARN([
1177 *** Not using atomic operations will cause poor performance.])
1178 fi
1179
1180 if test "$with_gssapi" = yes ; then
1181   if test "$PORTNAME" != "win32"; then
1182     AC_SEARCH_LIBS(gss_init_sec_context, [gssapi_krb5 gss 'gssapi -lkrb5 -lcrypto'], [],
1183                    [AC_MSG_ERROR([could not find function 'gss_init_sec_context' required for GSSAPI])])
1184   else
1185     LIBS="$LIBS -lgssapi32"
1186   fi
1187 fi
1188
1189 if test "$with_openssl" = yes ; then
1190   dnl Order matters!
1191   if test "$PORTNAME" != "win32"; then
1192      AC_CHECK_LIB(crypto, CRYPTO_new_ex_data, [], [AC_MSG_ERROR([library 'crypto' is required for OpenSSL])])
1193      AC_CHECK_LIB(ssl,    SSL_new, [], [AC_MSG_ERROR([library 'ssl' is required for OpenSSL])])
1194   else
1195      AC_SEARCH_LIBS(CRYPTO_new_ex_data, [eay32 crypto], [], [AC_MSG_ERROR([library 'eay32' or 'crypto' is required for OpenSSL])])
1196      AC_SEARCH_LIBS(SSL_new, [ssleay32 ssl], [], [AC_MSG_ERROR([library 'ssleay32' or 'ssl' is required for OpenSSL])])
1197   fi
1198   AC_CHECK_FUNCS([SSL_clear_options SSL_get_current_compression X509_get_signature_nid])
1199   # Functions introduced in OpenSSL 1.1.0. We used to check for
1200   # OPENSSL_VERSION_NUMBER, but that didn't work with 1.1.0, because LibreSSL
1201   # defines OPENSSL_VERSION_NUMBER to claim version 2.0.0, even though it
1202   # doesn't have these OpenSSL 1.1.0 functions. So check for individual
1203   # functions.
1204   AC_CHECK_FUNCS([OPENSSL_init_ssl BIO_get_data BIO_meth_new ASN1_STRING_get0_data RAND_OpenSSL])
1205   # OpenSSL versions before 1.1.0 required setting callback functions, for
1206   # thread-safety. In 1.1.0, it's no longer required, and CRYPTO_lock()
1207   # function was removed.
1208   AC_CHECK_FUNCS([CRYPTO_lock])
1209 fi
1210
1211 if test "$with_pam" = yes ; then
1212   AC_CHECK_LIB(pam,    pam_start, [], [AC_MSG_ERROR([library 'pam' is required for PAM])])
1213 fi
1214
1215 if test "$with_libxml" = yes ; then
1216   AC_CHECK_LIB(xml2, xmlSaveToBuffer, [], [AC_MSG_ERROR([library 'xml2' (version >= 2.6.23) is required for XML support])])
1217 fi
1218
1219 if test "$with_libxslt" = yes ; then
1220   AC_CHECK_LIB(xslt, xsltCleanupGlobals, [], [AC_MSG_ERROR([library 'xslt' is required for XSLT support])])
1221 fi
1222
1223 # Note: We can test for libldap_r only after we know PTHREAD_LIBS
1224 if test "$with_ldap" = yes ; then
1225   _LIBS="$LIBS"
1226   if test "$PORTNAME" != "win32"; then
1227     AC_CHECK_LIB(ldap, ldap_bind, [],
1228                  [AC_MSG_ERROR([library 'ldap' is required for LDAP])],
1229                  [$EXTRA_LDAP_LIBS])
1230     LDAP_LIBS_BE="-lldap $EXTRA_LDAP_LIBS"
1231     if test "$enable_thread_safety" = yes; then
1232       # on some platforms ldap_r fails to link without PTHREAD_LIBS
1233       AC_CHECK_LIB(ldap_r, ldap_simple_bind, [],
1234                    [AC_MSG_ERROR([library 'ldap_r' is required for LDAP])],
1235                    [$PTHREAD_CFLAGS $PTHREAD_LIBS $EXTRA_LDAP_LIBS])
1236       LDAP_LIBS_FE="-lldap_r $EXTRA_LDAP_LIBS"
1237     else
1238       LDAP_LIBS_FE="-lldap $EXTRA_LDAP_LIBS"
1239     fi
1240     AC_CHECK_FUNCS([ldap_initialize])
1241   else
1242     AC_CHECK_LIB(wldap32, ldap_bind, [], [AC_MSG_ERROR([library 'wldap32' is required for LDAP])])
1243     LDAP_LIBS_FE="-lwldap32"
1244     LDAP_LIBS_BE="-lwldap32"
1245   fi
1246   LIBS="$_LIBS"
1247 fi
1248 AC_SUBST(LDAP_LIBS_FE)
1249 AC_SUBST(LDAP_LIBS_BE)
1250
1251 # for contrib/sepgsql
1252 if test "$with_selinux" = yes; then
1253   AC_CHECK_LIB(selinux, security_compute_create_name, [],
1254                [AC_MSG_ERROR([library 'libselinux', version 2.1.10 or newer, is required for SELinux support])])
1255 fi
1256
1257 # for contrib/uuid-ossp
1258 if test "$with_uuid" = bsd ; then
1259   # On BSD, the UUID functions are in libc
1260   AC_CHECK_FUNC(uuid_to_string,
1261     [UUID_LIBS=""],
1262     [AC_MSG_ERROR([BSD UUID functions are not present])])
1263 elif test "$with_uuid" = e2fs ; then
1264   # On macOS, the UUID functions are in libc
1265   AC_CHECK_FUNC(uuid_generate,
1266     [UUID_LIBS=""],
1267     [AC_CHECK_LIB(uuid, uuid_generate,
1268       [UUID_LIBS="-luuid"],
1269       [AC_MSG_ERROR([library 'uuid' is required for E2FS UUID])])])
1270 elif test "$with_uuid" = ossp ; then
1271   AC_CHECK_LIB(ossp-uuid, uuid_export,
1272     [UUID_LIBS="-lossp-uuid"],
1273     [AC_CHECK_LIB(uuid, uuid_export,
1274       [UUID_LIBS="-luuid"],
1275       [AC_MSG_ERROR([library 'ossp-uuid' or 'uuid' is required for OSSP UUID])])])
1276 fi
1277 AC_SUBST(UUID_LIBS)
1278
1279
1280 ##
1281 ## Header files
1282 ##
1283
1284 AC_HEADER_STDBOOL
1285
1286 AC_CHECK_HEADERS([atomic.h crypt.h fp_class.h getopt.h ieeefp.h ifaddrs.h langinfo.h mbarrier.h poll.h sys/epoll.h sys/ipc.h sys/prctl.h sys/procctl.h sys/pstat.h sys/resource.h sys/select.h sys/sem.h sys/shm.h sys/sockio.h sys/tas.h sys/un.h termios.h ucred.h utime.h wchar.h wctype.h])
1287
1288 # On BSD, test for net/if.h will fail unless sys/socket.h
1289 # is included first.
1290 AC_CHECK_HEADERS(net/if.h, [], [],
1291 [AC_INCLUDES_DEFAULT
1292 #include <sys/socket.h>
1293 ])
1294
1295 # On OpenBSD, test for sys/ucred.h will fail unless sys/param.h
1296 # is included first.
1297 AC_CHECK_HEADERS(sys/ucred.h, [], [],
1298 [AC_INCLUDES_DEFAULT
1299 #include <sys/param.h>
1300 ])
1301
1302 # At least on IRIX, test for netinet/tcp.h will fail unless
1303 # netinet/in.h is included first.
1304 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
1305 [AC_INCLUDES_DEFAULT
1306 #include <netinet/in.h>
1307 ])
1308
1309 if expr x"$pgac_cv_check_readline" : 'x-lreadline' >/dev/null ; then
1310   AC_CHECK_HEADERS(readline/readline.h, [],
1311         [AC_CHECK_HEADERS(readline.h, [],
1312                 [AC_MSG_ERROR([readline header not found
1313 If you have readline already installed, see config.log for details on the
1314 failure.  It is possible the compiler isn't looking in the proper directory.
1315 Use --without-readline to disable readline support.])])])
1316   AC_CHECK_HEADERS(readline/history.h, [],
1317         [AC_CHECK_HEADERS(history.h, [],
1318                 [AC_MSG_ERROR([history header not found
1319 If you have readline already installed, see config.log for details on the
1320 failure.  It is possible the compiler isn't looking in the proper directory.
1321 Use --without-readline to disable readline support.])])])
1322 fi
1323
1324 if expr x"$pgac_cv_check_readline" : 'x-ledit' >/dev/null ; then
1325 # Some installations of libedit usurp /usr/include/readline/, which seems
1326 # bad practice, since in combined installations readline will have its headers
1327 # there.  We might have to resort to AC_EGREP checks to make sure we found
1328 # the proper header...
1329   AC_CHECK_HEADERS(editline/readline.h, [],
1330         [AC_CHECK_HEADERS(readline.h, [],
1331                 [AC_CHECK_HEADERS(readline/readline.h, [],
1332                         [AC_MSG_ERROR([readline header not found
1333 If you have libedit already installed, see config.log for details on the
1334 failure.  It is possible the compiler isn't looking in the proper directory.
1335 Use --without-readline to disable libedit support.])])])])
1336 # Note: in a libedit installation, history.h is sometimes a dummy, and may
1337 # not be there at all.  Hence, don't complain if not found.  We must check
1338 # though, since in yet other versions it is an independent header.
1339   AC_CHECK_HEADERS(editline/history.h, [],
1340         [AC_CHECK_HEADERS(history.h, [],
1341                 [AC_CHECK_HEADERS(readline/history.h)])])
1342 fi
1343
1344 if test "$with_zlib" = yes; then
1345   AC_CHECK_HEADER(zlib.h, [], [AC_MSG_ERROR([zlib header not found
1346 If you have zlib already installed, see config.log for details on the
1347 failure.  It is possible the compiler isn't looking in the proper directory.
1348 Use --without-zlib to disable zlib support.])])
1349 fi
1350
1351 if test "$with_gssapi" = yes ; then
1352   AC_CHECK_HEADERS(gssapi/gssapi.h, [],
1353         [AC_CHECK_HEADERS(gssapi.h, [], [AC_MSG_ERROR([gssapi.h header file is required for GSSAPI])])])
1354 fi
1355
1356 if test "$with_openssl" = yes ; then
1357   AC_CHECK_HEADER(openssl/ssl.h, [], [AC_MSG_ERROR([header file <openssl/ssl.h> is required for OpenSSL])])
1358   AC_CHECK_HEADER(openssl/err.h, [], [AC_MSG_ERROR([header file <openssl/err.h> is required for OpenSSL])])
1359 fi
1360
1361 if test "$with_pam" = yes ; then
1362   AC_CHECK_HEADERS(security/pam_appl.h, [],
1363                    [AC_CHECK_HEADERS(pam/pam_appl.h, [],
1364                                      [AC_MSG_ERROR([header file <security/pam_appl.h> or <pam/pam_appl.h> is required for PAM.])])])
1365 fi
1366
1367 if test "$with_bsd_auth" = yes ; then
1368   AC_CHECK_HEADER(bsd_auth.h, [], [AC_MSG_ERROR([header file <bsd_auth.h> is required for BSD Authentication support])])
1369 fi
1370
1371 if test "$with_systemd" = yes ; then
1372   AC_CHECK_HEADER(systemd/sd-daemon.h, [], [AC_MSG_ERROR([header file <systemd/sd-daemon.h> is required for systemd support])])
1373 fi
1374
1375 if test "$with_libxml" = yes ; then
1376   AC_CHECK_HEADER(libxml/parser.h, [], [AC_MSG_ERROR([header file <libxml/parser.h> is required for XML support])])
1377 fi
1378
1379 if test "$with_libxslt" = yes ; then
1380   AC_CHECK_HEADER(libxslt/xslt.h, [], [AC_MSG_ERROR([header file <libxslt/xslt.h> is required for XSLT support])])
1381 fi
1382
1383 if test "$with_ldap" = yes ; then
1384   if test "$PORTNAME" != "win32"; then
1385      AC_CHECK_HEADERS(ldap.h, [],
1386                       [AC_MSG_ERROR([header file <ldap.h> is required for LDAP])])
1387      PGAC_LDAP_SAFE
1388   else
1389      AC_CHECK_HEADERS(winldap.h, [],
1390                       [AC_MSG_ERROR([header file <winldap.h> is required for LDAP])],
1391                       [AC_INCLUDES_DEFAULT
1392 #include <windows.h>
1393                       ])
1394   fi
1395 fi
1396
1397 if test "$with_bonjour" = yes ; then
1398   AC_CHECK_HEADER(dns_sd.h, [], [AC_MSG_ERROR([header file <dns_sd.h> is required for Bonjour])])
1399 dnl At some point we might add something like
1400 dnl AC_SEARCH_LIBS(DNSServiceRegister, dns_sd)
1401 dnl but right now, what that would mainly accomplish is to encourage
1402 dnl people to try to use the avahi implementation, which does not work.
1403 dnl If you want to use Apple's own Bonjour code on another platform,
1404 dnl just add -ldns_sd to LIBS manually.
1405 fi
1406
1407 # for contrib/uuid-ossp
1408 if test "$with_uuid" = bsd ; then
1409   AC_CHECK_HEADERS(uuid.h,
1410     [AC_EGREP_HEADER([uuid_to_string], uuid.h, [],
1411       [AC_MSG_ERROR([header file <uuid.h> does not match BSD UUID library])])],
1412     [AC_MSG_ERROR([header file <uuid.h> is required for BSD UUID])])
1413 elif test "$with_uuid" = e2fs ; then
1414   AC_CHECK_HEADERS(uuid/uuid.h,
1415     [AC_EGREP_HEADER([uuid_generate], uuid/uuid.h, [],
1416       [AC_MSG_ERROR([header file <uuid/uuid.h> does not match E2FS UUID library])])],
1417     [AC_CHECK_HEADERS(uuid.h,
1418       [AC_EGREP_HEADER([uuid_generate], uuid.h, [],
1419         [AC_MSG_ERROR([header file <uuid.h> does not match E2FS UUID library])])],
1420       [AC_MSG_ERROR([header file <uuid/uuid.h> or <uuid.h> is required for E2FS UUID])])])
1421 elif test "$with_uuid" = ossp ; then
1422   AC_CHECK_HEADERS(ossp/uuid.h,
1423     [AC_EGREP_HEADER([uuid_export], ossp/uuid.h, [],
1424       [AC_MSG_ERROR([header file <ossp/uuid.h> does not match OSSP UUID library])])],
1425     [AC_CHECK_HEADERS(uuid.h,
1426       [AC_EGREP_HEADER([uuid_export], uuid.h, [],
1427         [AC_MSG_ERROR([header file <uuid.h> does not match OSSP UUID library])])],
1428       [AC_MSG_ERROR([header file <ossp/uuid.h> or <uuid.h> is required for OSSP UUID])])])
1429 fi
1430
1431 if test "$PORTNAME" = "win32" ; then
1432    AC_CHECK_HEADERS(crtdefs.h)
1433 fi
1434
1435 ##
1436 ## Types, structures, compiler characteristics
1437 ##
1438
1439 m4_defun([AC_PROG_CC_STDC], []) dnl We don't want that.
1440 AC_C_BIGENDIAN
1441 AC_C_INLINE
1442 PGAC_PRINTF_ARCHETYPE
1443 AC_C_FLEXIBLE_ARRAY_MEMBER
1444 PGAC_C_SIGNED
1445 PGAC_C_FUNCNAME_SUPPORT
1446 PGAC_C_STATIC_ASSERT
1447 PGAC_C_TYPEOF
1448 PGAC_C_TYPES_COMPATIBLE
1449 PGAC_C_BUILTIN_BSWAP16
1450 PGAC_C_BUILTIN_BSWAP32
1451 PGAC_C_BUILTIN_BSWAP64
1452 PGAC_C_BUILTIN_CONSTANT_P
1453 PGAC_C_BUILTIN_UNREACHABLE
1454 PGAC_C_COMPUTED_GOTO
1455 PGAC_STRUCT_TIMEZONE
1456 PGAC_UNION_SEMUN
1457 PGAC_STRUCT_SOCKADDR_UN
1458 PGAC_STRUCT_SOCKADDR_STORAGE
1459 PGAC_STRUCT_SOCKADDR_STORAGE_MEMBERS
1460 PGAC_STRUCT_ADDRINFO
1461 AC_TYPE_INTPTR_T
1462 AC_TYPE_UINTPTR_T
1463 AC_TYPE_LONG_LONG_INT
1464
1465 PGAC_TYPE_LOCALE_T
1466
1467 # MSVC doesn't cope well with defining restrict to __restrict, the
1468 # spelling it understands, because it conflicts with
1469 # __declspec(restrict). Therefore we define pg_restrict to the
1470 # appropriate definition, which presumably won't conflict.
1471 #
1472 # Allow platforms with buggy compilers to force restrict to not be
1473 # used by setting $FORCE_DISABLE_RESTRICT=yes in the relevant
1474 # template.
1475 AC_C_RESTRICT
1476 if test "$ac_cv_c_restrict" = "no" -o "x$FORCE_DISABLE_RESTRICT" = "xyes"; then
1477   pg_restrict=""
1478 else
1479   pg_restrict="$ac_cv_c_restrict"
1480 fi
1481 AC_DEFINE_UNQUOTED([pg_restrict], [$pg_restrict],
1482 [Define to keyword to use for C99 restrict support, or to nothing if not
1483 supported])
1484
1485 AC_CHECK_TYPES([struct cmsgcred], [], [],
1486 [#include <sys/socket.h>
1487 #include <sys/param.h>
1488 #ifdef HAVE_SYS_UCRED_H
1489 #include <sys/ucred.h>
1490 #endif])
1491
1492 AC_CHECK_TYPES([struct option], [], [],
1493 [#ifdef HAVE_GETOPT_H
1494 #include <getopt.h>
1495 #endif])
1496
1497 if test "$with_zlib" = yes; then
1498   # Check that <zlib.h> defines z_streamp (versions before about 1.0.4
1499   # did not).  While we could work around the lack of z_streamp, it
1500   # seems unwise to encourage people to use such old zlib versions...
1501   AC_CHECK_TYPE(z_streamp, [], [AC_MSG_ERROR([zlib version is too old
1502 Use --without-zlib to disable zlib support.])],
1503                 [#include <zlib.h>])
1504 fi
1505
1506 # On PPC, check if assembler supports LWARX instruction's mutex hint bit
1507 case $host_cpu in
1508   ppc*|powerpc*)
1509     AC_MSG_CHECKING([whether assembler supports lwarx hint bit])
1510     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([],
1511         [int a = 0; int *p = &a; int r;
1512          __asm__ __volatile__ (" lwarx %0,0,%1,1\n" : "=&r"(r) : "r"(p));])],
1513         [pgac_cv_have_ppc_mutex_hint=yes],
1514         [pgac_cv_have_ppc_mutex_hint=no])
1515     AC_MSG_RESULT([$pgac_cv_have_ppc_mutex_hint])
1516     if test x"$pgac_cv_have_ppc_mutex_hint" = xyes ; then
1517         AC_DEFINE(HAVE_PPC_LWARX_MUTEX_HINT, 1, [Define to 1 if the assembler supports PPC's LWARX mutex hint bit.])
1518     fi
1519   ;;
1520 esac
1521
1522 # Check largefile support.  You might think this is a system service not a
1523 # compiler characteristic, but you'd be wrong.  We must check this before
1524 # probing existence of related functions such as fseeko, since the largefile
1525 # defines can affect what is generated for that.
1526 if test "$PORTNAME" != "win32"; then
1527    AC_SYS_LARGEFILE
1528    dnl Autoconf 2.69's AC_SYS_LARGEFILE believes it's a good idea to #define
1529    dnl _DARWIN_USE_64_BIT_INODE, but it isn't: on macOS 10.5 that activates a
1530    dnl bug that causes readdir() to sometimes return EINVAL.  On later macOS
1531    dnl versions where the feature actually works, it's on by default anyway.
1532    AH_VERBATIM([_DARWIN_USE_64_BIT_INODE],[])
1533 fi
1534
1535 # Check for largefile support (must be after AC_SYS_LARGEFILE)
1536 AC_CHECK_SIZEOF([off_t])
1537
1538 # If we don't have largefile support, can't handle segsize >= 2GB.
1539 if test "$ac_cv_sizeof_off_t" -lt 8 -a "$segsize" != "1"; then
1540    AC_MSG_ERROR([Large file support is not enabled. Segment size cannot be larger than 1GB.])
1541 fi
1542
1543 AC_CHECK_SIZEOF([bool], [],
1544 [#ifdef HAVE_STDBOOL_H
1545 #include <stdbool.h>
1546 #endif])
1547
1548
1549 ##
1550 ## Functions, global variables
1551 ##
1552
1553 PGAC_VAR_INT_TIMEZONE
1554 AC_FUNC_ACCEPT_ARGTYPES
1555 PGAC_FUNC_GETTIMEOFDAY_1ARG
1556 PGAC_FUNC_WCSTOMBS_L
1557
1558 # Some versions of libedit contain strlcpy(), setproctitle(), and other
1559 # symbols that that library has no business exposing to the world.  Pending
1560 # acquisition of a clue by those developers, ignore libedit (including its
1561 # possible alias of libreadline) while checking for everything else.
1562 LIBS_including_readline="$LIBS"
1563 LIBS=`echo "$LIBS" | sed -e 's/-ledit//g' -e 's/-lreadline//g'`
1564
1565 AC_CHECK_FUNCS([cbrt clock_gettime fdatasync getifaddrs getpeerucred getrlimit mbstowcs_l memmove poll posix_fallocate ppoll pstat pthread_is_threaded_np readlink setproctitle setproctitle_fast setsid shm_open symlink sync_file_range utime utimes wcstombs_l])
1566
1567 AC_REPLACE_FUNCS(fseeko)
1568 case $host_os in
1569         # NetBSD uses a custom fseeko/ftello built on fsetpos/fgetpos
1570         # Mingw uses macros to access Win32 API calls
1571         netbsd*|mingw*)
1572                 AC_DEFINE(HAVE_FSEEKO, 1, [Define to 1 because replacement version used.])
1573                 ac_cv_func_fseeko=yes;;
1574         *)
1575                 AC_FUNC_FSEEKO;;
1576 esac
1577
1578 # posix_fadvise() is a no-op on Solaris, so don't incur function overhead
1579 # by calling it, 2009-04-02
1580 # http://src.opensolaris.org/source/xref/onnv/onnv-gate/usr/src/lib/libc/port/gen/posix_fadvise.c
1581 if test "$PORTNAME" != "solaris"; then
1582 AC_CHECK_FUNCS(posix_fadvise)
1583 AC_CHECK_DECLS(posix_fadvise, [], [], [#include <fcntl.h>])
1584 fi
1585
1586 AC_CHECK_DECLS(fdatasync, [], [], [#include <unistd.h>])
1587 AC_CHECK_DECLS([strlcat, strlcpy, strnlen])
1588 # This is probably only present on macOS, but may as well check always
1589 AC_CHECK_DECLS(F_FULLFSYNC, [], [], [#include <fcntl.h>])
1590
1591 AC_CHECK_DECLS([RTLD_GLOBAL, RTLD_NOW], [], [], [#include <dlfcn.h>])
1592
1593 HAVE_IPV6=no
1594 AC_CHECK_TYPE([struct sockaddr_in6],
1595         [AC_DEFINE(HAVE_IPV6, 1, [Define to 1 if you have support for IPv6.])
1596          HAVE_IPV6=yes],
1597         [],
1598 [$ac_includes_default
1599 #include <netinet/in.h>])
1600 AC_SUBST(HAVE_IPV6)
1601
1602 AC_CACHE_CHECK([for PS_STRINGS], [pgac_cv_var_PS_STRINGS],
1603 [AC_LINK_IFELSE([AC_LANG_PROGRAM(
1604 [#include <machine/vmparam.h>
1605 #include <sys/exec.h>
1606 ],
1607 [PS_STRINGS->ps_nargvstr = 1;
1608 PS_STRINGS->ps_argvstr = "foo";])],
1609 [pgac_cv_var_PS_STRINGS=yes],
1610 [pgac_cv_var_PS_STRINGS=no])])
1611 if test "$pgac_cv_var_PS_STRINGS" = yes ; then
1612   AC_DEFINE([HAVE_PS_STRINGS], 1, [Define to 1 if the PS_STRINGS thing exists.])
1613 fi
1614
1615
1616 # We use our snprintf.c emulation if either snprintf() or vsnprintf()
1617 # is missing.  Yes, there are machines that have only one.  We may
1618 # also decide to use snprintf.c if snprintf() is present but does not
1619 # have all the features we need --- see below.
1620
1621 if test "$PORTNAME" = "win32"; then
1622   # Win32 gets snprintf.c built unconditionally.
1623   #
1624   # To properly translate all NLS languages strings, we must support the
1625   # *printf() %$ format, which allows *printf() arguments to be selected
1626   # by position in the translated string.
1627   #
1628   # libintl versions < 0.13 use the native *printf() functions, and Win32
1629   # *printf() doesn't understand %$, so we must use our /port versions,
1630   # which do understand %$. libintl versions >= 0.13 include their own
1631   # *printf versions on Win32.  The libintl 0.13 release note text is:
1632   #
1633   #   C format strings with positions, as they arise when a translator
1634   #   needs to reorder a sentence, are now supported on all platforms.
1635   #   On those few platforms (NetBSD and Woe32) for which the native
1636   #   printf()/fprintf()/... functions don't support such format
1637   #   strings, replacements are provided through <libintl.h>.
1638   #
1639   # We could use libintl >= 0.13's *printf() if we were sure that we had
1640   # a libintl >= 0.13 at runtime, but seeing that there is no clean way
1641   # to guarantee that, it is best to just use our own, so we are sure to
1642   # get %$ support. In include/port.h we disable the *printf() macros
1643   # that might have been defined by libintl.
1644   #
1645   # We do this unconditionally whether NLS is used or not so we are sure
1646   # that all Win32 libraries and binaries behave the same.
1647   pgac_need_repl_snprintf=yes
1648 else
1649   pgac_need_repl_snprintf=no
1650   AC_CHECK_FUNCS(snprintf, [], pgac_need_repl_snprintf=yes)
1651   AC_CHECK_FUNCS(vsnprintf, [], pgac_need_repl_snprintf=yes)
1652 fi
1653
1654
1655 # Check whether <stdio.h> declares snprintf() and vsnprintf(); if not,
1656 # include/c.h will provide declarations.  Note this is a separate test
1657 # from whether the functions exist in the C library --- there are
1658 # systems that have the functions but don't bother to declare them :-(
1659
1660 AC_CHECK_DECLS([snprintf, vsnprintf])
1661
1662
1663 dnl Cannot use AC_CHECK_FUNC because isinf may be a macro
1664 AC_CACHE_CHECK([for isinf], ac_cv_func_isinf,
1665 [AC_LINK_IFELSE([AC_LANG_PROGRAM([
1666 #include <math.h>
1667 double glob_double;
1668 ],
1669 [return isinf(glob_double) ? 0 : 1;])],
1670 [ac_cv_func_isinf=yes],
1671 [ac_cv_func_isinf=no])])
1672
1673 if test $ac_cv_func_isinf = yes ; then
1674   AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have isinf().])
1675 else
1676   AC_LIBOBJ(isinf)
1677   # Look for a way to implement a substitute for isinf()
1678   AC_CHECK_FUNCS([fpclass fp_class fp_class_d class], [break])
1679 fi
1680
1681 AC_REPLACE_FUNCS([crypt dlopen fls getopt getrusage inet_aton mkdtemp random rint srandom strerror strlcat strlcpy strnlen])
1682
1683 case $host_os in
1684
1685         # Windows uses a specialised env handler
1686         # and doesn't need a replacement getpeereid because it doesn't use
1687         # Unix sockets.
1688         mingw*)
1689                 AC_DEFINE(HAVE_UNSETENV, 1, [Define to 1 because replacement version used.])
1690                 AC_DEFINE(HAVE_GETPEEREID, 1, [Define to 1 because function not required.])
1691                 ac_cv_func_unsetenv=yes
1692                 ac_cv_func_getpeereid=yes;;
1693         *)
1694                 AC_REPLACE_FUNCS([unsetenv getpeereid])
1695                 ;;
1696 esac
1697
1698 # System's version of getaddrinfo(), if any, may be used only if we found
1699 # a definition for struct addrinfo; see notes in src/include/getaddrinfo.h.
1700 # We use only our own getaddrinfo.c on Windows, but it's time to revisit that.
1701 if test x"$ac_cv_type_struct_addrinfo" = xyes && \
1702    test "$PORTNAME" != "win32"; then
1703   AC_REPLACE_FUNCS([getaddrinfo])
1704 else
1705   AC_LIBOBJ(getaddrinfo)
1706 fi
1707
1708 # Similarly, use system's getopt_long() only if system provides struct option.
1709 if test x"$ac_cv_type_struct_option" = xyes ; then
1710   AC_REPLACE_FUNCS([getopt_long])
1711 else
1712   AC_LIBOBJ(getopt_long)
1713 fi
1714
1715 # Solaris' getopt() doesn't do what we want for long options, so always use
1716 # our version on that platform.
1717 if test "$PORTNAME" = "solaris"; then
1718   AC_LIBOBJ(getopt)
1719 fi
1720
1721 # mingw has adopted a GNU-centric interpretation of optind/optreset,
1722 # so always use our version on Windows.
1723 if test "$PORTNAME" = "win32"; then
1724   AC_LIBOBJ(getopt)
1725   AC_LIBOBJ(getopt_long)
1726 fi
1727
1728 # Win32 (really MinGW) support
1729 if test "$PORTNAME" = "win32"; then
1730   AC_REPLACE_FUNCS(gettimeofday)
1731   AC_LIBOBJ(dirmod)
1732   AC_LIBOBJ(kill)
1733   AC_LIBOBJ(open)
1734   AC_LIBOBJ(system)
1735   AC_LIBOBJ(win32env)
1736   AC_LIBOBJ(win32error)
1737   AC_LIBOBJ(win32security)
1738   AC_LIBOBJ(win32setlocale)
1739   AC_DEFINE([HAVE_SYMLINK], 1,
1740             [Define to 1 if you have the `symlink' function.])
1741   AC_CHECK_TYPES(MINIDUMP_TYPE, [pgac_minidump_type=yes], [pgac_minidump_type=no], [
1742 #define WIN32_LEAN_AND_MEAN
1743 #include <windows.h>
1744 #include <string.h>
1745 #include <dbghelp.h>])
1746 fi
1747 if test x"$pgac_minidump_type" = x"yes" ; then
1748   AC_SUBST(have_win32_dbghelp,yes)
1749 else
1750   AC_SUBST(have_win32_dbghelp,no)
1751 fi
1752
1753 # Cygwin needs only a bit of that
1754 if test "$PORTNAME" = "cygwin"; then
1755   AC_LIBOBJ(dirmod)
1756 fi
1757
1758 AC_CHECK_DECLS([sys_siglist], [], [],
1759 [#include <signal.h>
1760 /* NetBSD declares sys_siglist in unistd.h.  */
1761 #ifdef HAVE_UNISTD_H
1762 # include <unistd.h>
1763 #endif
1764 ])
1765
1766 AC_CHECK_FUNC(syslog,
1767               [AC_CHECK_HEADER(syslog.h,
1768                                [AC_DEFINE(HAVE_SYSLOG, 1, [Define to 1 if you have the syslog interface.])])])
1769
1770 AC_CACHE_CHECK([for opterr], pgac_cv_var_int_opterr,
1771 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1772   [extern int opterr; opterr = 1;])],
1773   [pgac_cv_var_int_opterr=yes],
1774   [pgac_cv_var_int_opterr=no])])
1775 if test x"$pgac_cv_var_int_opterr" = x"yes"; then
1776   AC_DEFINE(HAVE_INT_OPTERR, 1, [Define to 1 if you have the global variable 'int opterr'.])
1777 fi
1778
1779 AC_CACHE_CHECK([for optreset], pgac_cv_var_int_optreset,
1780 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>],
1781   [extern int optreset; optreset = 1;])],
1782   [pgac_cv_var_int_optreset=yes],
1783   [pgac_cv_var_int_optreset=no])])
1784 if test x"$pgac_cv_var_int_optreset" = x"yes"; then
1785   AC_DEFINE(HAVE_INT_OPTRESET, 1, [Define to 1 if you have the global variable 'int optreset'.])
1786 fi
1787
1788 AC_CHECK_FUNCS([strtoll __strtoll strtoq], [break])
1789 AC_CHECK_FUNCS([strtoull __strtoull strtouq], [break])
1790 # strto[u]ll may exist but not be declared
1791 AC_CHECK_DECLS([strtoll, strtoull])
1792
1793 if test "$with_icu" = yes; then
1794   ac_save_CPPFLAGS=$CPPFLAGS
1795   CPPFLAGS="$ICU_CFLAGS $CPPFLAGS"
1796
1797   # Verify we have ICU's header files
1798   AC_CHECK_HEADER(unicode/ucol.h, [],
1799         [AC_MSG_ERROR([header file <unicode/ucol.h> is required for ICU])])
1800
1801   CPPFLAGS=$ac_save_CPPFLAGS
1802 fi
1803
1804 # Lastly, restore full LIBS list and check for readline/libedit symbols
1805 LIBS="$LIBS_including_readline"
1806
1807 if test "$with_readline" = yes; then
1808   PGAC_VAR_RL_COMPLETION_APPEND_CHARACTER
1809   AC_CHECK_FUNCS([rl_completion_matches rl_filename_completion_function rl_reset_screen_size])
1810   AC_CHECK_FUNCS([append_history history_truncate_file])
1811 fi
1812
1813
1814 # This test makes sure that run tests work at all.  Sometimes a shared
1815 # library is found by the linker, but the runtime linker can't find it.
1816 # This check should come after all modifications of compiler or linker
1817 # variables, and before any other run tests.
1818 AC_MSG_CHECKING([test program])
1819 AC_RUN_IFELSE([AC_LANG_SOURCE([int main() { return 0; }])],
1820 [AC_MSG_RESULT(ok)],
1821 [AC_MSG_RESULT(failed)
1822 AC_MSG_ERROR([[
1823 Could not execute a simple test program.  This may be a problem
1824 related to locating shared libraries.  Check the file 'config.log'
1825 for the exact reason.]])],
1826 [AC_MSG_RESULT([cross-compiling])])
1827
1828 # --------------------
1829 # Run tests below here
1830 # --------------------
1831
1832 # For NLS, force use of our snprintf if system's doesn't do arg control.
1833 # See comment above at snprintf test for details.
1834 if test "$enable_nls" = yes -a "$pgac_need_repl_snprintf" = no; then
1835   PGAC_FUNC_SNPRINTF_ARG_CONTROL
1836   if test $pgac_cv_snprintf_arg_control != yes ; then
1837     pgac_need_repl_snprintf=yes
1838   fi
1839 fi
1840
1841
1842 dnl Check to see if we have a working 64-bit integer type.
1843 dnl Since Postgres 8.4, we no longer support compilers without a working
1844 dnl 64-bit type; but we have to determine whether that type is called
1845 dnl "long int" or "long long int".
1846
1847 PGAC_TYPE_64BIT_INT([long int])
1848
1849 if test x"$HAVE_LONG_INT_64" = x"yes" ; then
1850   pg_int64_type="long int"
1851 else
1852   PGAC_TYPE_64BIT_INT([long long int])
1853   if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1854     pg_int64_type="long long int"
1855   else
1856     AC_MSG_ERROR([Cannot find a working 64-bit integer type.])
1857   fi
1858 fi
1859
1860 AC_DEFINE_UNQUOTED(PG_INT64_TYPE, $pg_int64_type,
1861   [Define to the name of a signed 64-bit integer type.])
1862
1863 # Select the printf length modifier that goes with that, too.
1864 # (This used to be bound up with replacement-snprintf selection, but now
1865 # we assume that the native *printf functions use standard length modifiers.)
1866 if test x"$pg_int64_type" = x"long long int" ; then
1867   INT64_MODIFIER='"ll"'
1868 else
1869   INT64_MODIFIER='"l"'
1870 fi
1871
1872 AC_DEFINE_UNQUOTED(INT64_MODIFIER, $INT64_MODIFIER,
1873                    [Define to the appropriate printf length modifier for 64-bit ints.])
1874
1875 # Force use of our snprintf if the system's doesn't support the %z flag.
1876 # (Note this test uses PG_INT64_TYPE and INT64_MODIFIER.)
1877 if test "$pgac_need_repl_snprintf" = no; then
1878   PGAC_FUNC_SNPRINTF_SIZE_T_SUPPORT
1879   if test "$pgac_cv_snprintf_size_t_support" != yes; then
1880     pgac_need_repl_snprintf=yes
1881   fi
1882 fi
1883
1884 # Force use of our snprintf if the system's doesn't handle buffer overrun
1885 # as specified by C99.
1886 if test "$pgac_need_repl_snprintf" = no; then
1887   PGAC_FUNC_SNPRINTF_C99_RESULT
1888   if test "$pgac_cv_snprintf_c99_result" != yes; then
1889     pgac_need_repl_snprintf=yes
1890   fi
1891 fi
1892
1893 # Now we have checked all the reasons to replace snprintf
1894 if test $pgac_need_repl_snprintf = yes; then
1895   AC_DEFINE(USE_REPL_SNPRINTF, 1, [Use replacement snprintf() functions.])
1896   AC_LIBOBJ(snprintf)
1897 fi
1898
1899 # has to be down here, rather than with the other builtins, because
1900 # the test uses PG_INT64_TYPE.
1901 PGAC_C_BUILTIN_OP_OVERFLOW
1902
1903 # Check size of void *, size_t (enables tweaks for > 32bit address space)
1904 AC_CHECK_SIZEOF([void *])
1905 AC_CHECK_SIZEOF([size_t])
1906 AC_CHECK_SIZEOF([long])
1907
1908 # Decide whether float4 is passed by value: user-selectable, enabled by default
1909 AC_MSG_CHECKING([whether to build with float4 passed by value])
1910 PGAC_ARG_BOOL(enable, float4-byval, yes, [disable float4 passed by value],
1911               [AC_DEFINE([USE_FLOAT4_BYVAL], 1,
1912                          [Define to 1 if you want float4 values to be passed by value. (--enable-float4-byval)])
1913                float4passbyval=true],
1914               [float4passbyval=false])
1915 AC_MSG_RESULT([$enable_float4_byval])
1916 AC_DEFINE_UNQUOTED([FLOAT4PASSBYVAL], [$float4passbyval], [float4 values are passed by value if 'true', by reference if 'false'])
1917
1918 # Decide whether float8 is passed by value.
1919 # Note: this setting also controls int8 and related types such as timestamp.
1920 # If sizeof(Datum) >= 8, this is user-selectable, enabled by default.
1921 # If not, trying to select it is an error.
1922 AC_MSG_CHECKING([whether to build with float8 passed by value])
1923 if test $ac_cv_sizeof_void_p -ge 8 ; then
1924   PGAC_ARG_BOOL(enable, float8-byval, yes, [disable float8 passed by value])
1925 else
1926   PGAC_ARG_BOOL(enable, float8-byval, no, [disable float8 passed by value])
1927   if test "$enable_float8_byval" = yes ; then
1928     AC_MSG_ERROR([--enable-float8-byval is not supported on 32-bit platforms.])
1929   fi
1930 fi
1931 if test "$enable_float8_byval" = yes ; then
1932   AC_DEFINE([USE_FLOAT8_BYVAL], 1,
1933             [Define to 1 if you want float8, int8, etc values to be passed by value. (--enable-float8-byval)])
1934   float8passbyval=true
1935 else
1936   float8passbyval=false
1937 fi
1938 AC_MSG_RESULT([$enable_float8_byval])
1939 AC_DEFINE_UNQUOTED([FLOAT8PASSBYVAL], [$float8passbyval], [float8, int8, and related values are passed by value if 'true', by reference if 'false'])
1940
1941 # Determine memory alignment requirements for the basic C data types.
1942
1943 AC_CHECK_ALIGNOF(short)
1944 AC_CHECK_ALIGNOF(int)
1945 AC_CHECK_ALIGNOF(long)
1946 if test x"$HAVE_LONG_LONG_INT_64" = x"yes" ; then
1947   AC_CHECK_ALIGNOF(long long int)
1948 fi
1949 AC_CHECK_ALIGNOF(double)
1950
1951 # Compute maximum alignment of any basic type.
1952 # We assume long's alignment is at least as strong as char, short, or int;
1953 # but we must check long long (if it is being used for int64) and double.
1954 # Note that we intentionally do not consider any types wider than 64 bits,
1955 # as allowing MAXIMUM_ALIGNOF to exceed 8 would be too much of a penalty
1956 # for disk and memory space.
1957
1958 MAX_ALIGNOF=$ac_cv_alignof_long
1959 if test $MAX_ALIGNOF -lt $ac_cv_alignof_double ; then
1960   MAX_ALIGNOF=$ac_cv_alignof_double
1961 fi
1962 if test x"$HAVE_LONG_LONG_INT_64" = xyes && test $MAX_ALIGNOF -lt $ac_cv_alignof_long_long_int ; then
1963   MAX_ALIGNOF="$ac_cv_alignof_long_long_int"
1964 fi
1965 AC_DEFINE_UNQUOTED(MAXIMUM_ALIGNOF, $MAX_ALIGNOF, [Define as the maximum alignment requirement of any C data type.])
1966
1967
1968 # Some platforms predefine the types int8, int16, etc.  Only check
1969 # a (hopefully) representative subset.
1970 AC_CHECK_TYPES([int8, uint8, int64, uint64], [], [],
1971 [#include <stdio.h>])
1972
1973 # Some compilers offer a 128-bit integer scalar type.
1974 PGAC_TYPE_128BIT_INT
1975
1976 # Check for various atomic operations now that we have checked how to declare
1977 # 64bit integers.
1978 PGAC_HAVE_GCC__SYNC_CHAR_TAS
1979 PGAC_HAVE_GCC__SYNC_INT32_TAS
1980 PGAC_HAVE_GCC__SYNC_INT32_CAS
1981 PGAC_HAVE_GCC__SYNC_INT64_CAS
1982 PGAC_HAVE_GCC__ATOMIC_INT32_CAS
1983 PGAC_HAVE_GCC__ATOMIC_INT64_CAS
1984
1985
1986 # Check for x86 cpuid instruction
1987 AC_CACHE_CHECK([for __get_cpuid], [pgac_cv__get_cpuid],
1988 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <cpuid.h>],
1989   [[unsigned int exx[4] = {0, 0, 0, 0};
1990   __get_cpuid(1, &exx[0], &exx[1], &exx[2], &exx[3]);
1991   ]])],
1992   [pgac_cv__get_cpuid="yes"],
1993   [pgac_cv__get_cpuid="no"])])
1994 if test x"$pgac_cv__get_cpuid" = x"yes"; then
1995   AC_DEFINE(HAVE__GET_CPUID, 1, [Define to 1 if you have __get_cpuid.])
1996 fi
1997
1998 AC_CACHE_CHECK([for __cpuid], [pgac_cv__cpuid],
1999 [AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <intrin.h>],
2000   [[unsigned int exx[4] = {0, 0, 0, 0};
2001   __get_cpuid(exx[0], 1);
2002   ]])],
2003   [pgac_cv__cpuid="yes"],
2004   [pgac_cv__cpuid="no"])])
2005 if test x"$pgac_cv__cpuid" = x"yes"; then
2006   AC_DEFINE(HAVE__CPUID, 1, [Define to 1 if you have __cpuid.])
2007 fi
2008
2009 # Check for Intel SSE 4.2 intrinsics to do CRC calculations.
2010 #
2011 # First check if the _mm_crc32_u8 and _mm_crc32_u64 intrinsics can be used
2012 # with the default compiler flags. If not, check if adding the -msse4.2
2013 # flag helps. CFLAGS_SSE42 is set to -msse4.2 if that's required.
2014 PGAC_SSE42_CRC32_INTRINSICS([])
2015 if test x"$pgac_sse42_crc32_intrinsics" != x"yes"; then
2016   PGAC_SSE42_CRC32_INTRINSICS([-msse4.2])
2017 fi
2018 AC_SUBST(CFLAGS_SSE42)
2019
2020 # Are we targeting a processor that supports SSE 4.2? gcc, clang and icc all
2021 # define __SSE4_2__ in that case.
2022 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [
2023 #ifndef __SSE4_2__
2024 #error __SSE4_2__ not defined
2025 #endif
2026 ])], [SSE4_2_TARGETED=1])
2027
2028 # Check for ARMv8 CRC Extension intrinsics to do CRC calculations.
2029 #
2030 # First check if __crc32c* intrinsics can be used with the default compiler
2031 # flags. If not, check if adding -march=armv8-a+crc flag helps.
2032 # CFLAGS_ARMV8_CRC32C is set if the extra flag is required.
2033 PGAC_ARMV8_CRC32C_INTRINSICS([])
2034 if test x"$pgac_armv8_crc32c_intrinsics" != x"yes"; then
2035   PGAC_ARMV8_CRC32C_INTRINSICS([-march=armv8-a+crc])
2036 fi
2037 AC_SUBST(CFLAGS_ARMV8_CRC32C)
2038
2039 # Select CRC-32C implementation.
2040 #
2041 # If we are targeting a processor that has Intel SSE 4.2 instructions, we can
2042 # use the special CRC instructions for calculating CRC-32C. If we're not
2043 # targeting such a processor, but we can nevertheless produce code that uses
2044 # the SSE intrinsics, perhaps with some extra CFLAGS, compile both
2045 # implementations and select which one to use at runtime, depending on whether
2046 # SSE 4.2 is supported by the processor we're running on.
2047 #
2048 # Similarly, if we are targeting an ARM processor that has the CRC
2049 # instructions that are part of the ARMv8 CRC Extension, use them. And if
2050 # we're not targeting such a processor, but can nevertheless produce code that
2051 # uses the CRC instructions, compile both, and select at runtime.
2052 #
2053 # You can override this logic by setting the appropriate USE_*_CRC32 flag to 1
2054 # in the template or configure command line.
2055 if test x"$USE_SLICING_BY_8_CRC32C" = x"" && test x"$USE_SSE42_CRC32C" = x"" && test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"" && test x"$USE_ARMV8_CRC32C" = x"" && test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x""; then
2056   # Use Intel SSE 4.2 if available.
2057   if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && test x"$SSE4_2_TARGETED" = x"1" ; then
2058     USE_SSE42_CRC32C=1
2059   else
2060     # Intel SSE 4.2, with runtime check? The CPUID instruction is needed for
2061     # the runtime check.
2062     if test x"$pgac_sse42_crc32_intrinsics" = x"yes" && (test x"$pgac_cv__get_cpuid" = x"yes" || test x"$pgac_cv__cpuid" = x"yes"); then
2063       USE_SSE42_CRC32C_WITH_RUNTIME_CHECK=1
2064     else
2065       # Use ARM CRC Extension if available.
2066       if test x"$pgac_armv8_crc32c_intrinsics" = x"yes" && test x"$CFLAGS_ARMV8_CRC32C" = x""; then
2067         USE_ARMV8_CRC32C=1
2068       else
2069         # ARM CRC Extension, with runtime check?
2070         if test x"$pgac_armv8_crc32c_intrinsics" = x"yes"; then
2071           USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK=1
2072         else
2073           # fall back to slicing-by-8 algorithm, which doesn't require any
2074           # special CPU support.
2075           USE_SLICING_BY_8_CRC32C=1
2076         fi
2077       fi
2078     fi
2079   fi
2080 fi
2081
2082 # Set PG_CRC32C_OBJS appropriately depending on the selected implementation.
2083 AC_MSG_CHECKING([which CRC-32C implementation to use])
2084 if test x"$USE_SSE42_CRC32C" = x"1"; then
2085   AC_DEFINE(USE_SSE42_CRC32C, 1, [Define to 1 use Intel SSE 4.2 CRC instructions.])
2086   PG_CRC32C_OBJS="pg_crc32c_sse42.o"
2087   AC_MSG_RESULT(SSE 4.2)
2088 else
2089   if test x"$USE_SSE42_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2090     AC_DEFINE(USE_SSE42_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use Intel SSE 4.2 CRC instructions with a runtime check.])
2091     PG_CRC32C_OBJS="pg_crc32c_sse42.o pg_crc32c_sb8.o pg_crc32c_sse42_choose.o"
2092     AC_MSG_RESULT(SSE 4.2 with runtime check)
2093   else
2094     if test x"$USE_ARMV8_CRC32C" = x"1"; then
2095       AC_DEFINE(USE_ARMV8_CRC32C, 1, [Define to 1 to use ARMv8 CRC Extension.])
2096       PG_CRC32C_OBJS="pg_crc32c_armv8.o"
2097       AC_MSG_RESULT(ARMv8 CRC instructions)
2098     else
2099       if test x"$USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK" = x"1"; then
2100         AC_DEFINE(USE_ARMV8_CRC32C_WITH_RUNTIME_CHECK, 1, [Define to 1 to use ARMv8 CRC Extension with a runtime check.])
2101         PG_CRC32C_OBJS="pg_crc32c_armv8.o pg_crc32c_sb8.o pg_crc32c_armv8_choose.o"
2102         AC_MSG_RESULT(ARMv8 CRC instructions with runtime check)
2103       else
2104         AC_DEFINE(USE_SLICING_BY_8_CRC32C, 1, [Define to 1 to use software CRC-32C implementation (slicing-by-8).])
2105         PG_CRC32C_OBJS="pg_crc32c_sb8.o"
2106         AC_MSG_RESULT(slicing-by-8)
2107       fi
2108     fi
2109   fi
2110 fi
2111 AC_SUBST(PG_CRC32C_OBJS)
2112
2113
2114 # Select semaphore implementation type.
2115 if test "$PORTNAME" != "win32"; then
2116   if test x"$PREFERRED_SEMAPHORES" = x"NAMED_POSIX" ; then
2117     # Need sem_open for this
2118     AC_SEARCH_LIBS(sem_open, [rt pthread], [USE_NAMED_POSIX_SEMAPHORES=1])
2119   fi
2120   if test x"$PREFERRED_SEMAPHORES" = x"UNNAMED_POSIX" ; then
2121     # Need sem_init for this
2122     AC_SEARCH_LIBS(sem_init, [rt pthread], [USE_UNNAMED_POSIX_SEMAPHORES=1])
2123   fi
2124   AC_MSG_CHECKING([which semaphore API to use])
2125   if test x"$USE_NAMED_POSIX_SEMAPHORES" = x"1" ; then
2126     AC_DEFINE(USE_NAMED_POSIX_SEMAPHORES, 1, [Define to select named POSIX semaphores.])
2127     SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2128     sematype="named POSIX"
2129   else
2130     if test x"$USE_UNNAMED_POSIX_SEMAPHORES" = x"1" ; then
2131       AC_DEFINE(USE_UNNAMED_POSIX_SEMAPHORES, 1, [Define to select unnamed POSIX semaphores.])
2132       SEMA_IMPLEMENTATION="src/backend/port/posix_sema.c"
2133       sematype="unnamed POSIX"
2134     else
2135       AC_DEFINE(USE_SYSV_SEMAPHORES, 1, [Define to select SysV-style semaphores.])
2136       SEMA_IMPLEMENTATION="src/backend/port/sysv_sema.c"
2137       sematype="System V"
2138     fi
2139   fi
2140   AC_MSG_RESULT([$sematype])
2141 else
2142   AC_DEFINE(USE_WIN32_SEMAPHORES, 1, [Define to select Win32-style semaphores.])
2143   SEMA_IMPLEMENTATION="src/backend/port/win32_sema.c"
2144 fi
2145
2146
2147 # Select shared-memory implementation type.
2148 if test "$PORTNAME" != "win32"; then
2149   AC_DEFINE(USE_SYSV_SHARED_MEMORY, 1, [Define to select SysV-style shared memory.])
2150   SHMEM_IMPLEMENTATION="src/backend/port/sysv_shmem.c"
2151 else
2152   AC_DEFINE(USE_WIN32_SHARED_MEMORY, 1, [Define to select Win32-style shared memory.])
2153   SHMEM_IMPLEMENTATION="src/backend/port/win32_shmem.c"
2154 fi
2155
2156 # Select random number source
2157 #
2158 # You can override this logic by setting the appropriate USE_*RANDOM flag to 1
2159 # in the template or configure command line.
2160
2161 # If not selected manually, try to select a source automatically.
2162 if test "$enable_strong_random" = "yes" && test x"$USE_OPENSSL_RANDOM" = x"" && test x"$USE_WIN32_RANDOM" = x"" && test x"$USE_DEV_URANDOM" = x"" ; then
2163   if test x"$with_openssl" = x"yes" ; then
2164     USE_OPENSSL_RANDOM=1
2165   elif test "$PORTNAME" = "win32" ; then
2166     USE_WIN32_RANDOM=1
2167   else
2168     AC_CHECK_FILE([/dev/urandom], [], [])
2169
2170     if test x"$ac_cv_file__dev_urandom" = x"yes" ; then
2171       USE_DEV_URANDOM=1
2172     fi
2173   fi
2174 fi
2175
2176 AC_MSG_CHECKING([which random number source to use])
2177 if test "$enable_strong_random" = yes ; then
2178   if test x"$USE_OPENSSL_RANDOM" = x"1" ; then
2179     AC_DEFINE(USE_OPENSSL_RANDOM, 1, [Define to use OpenSSL for random number generation])
2180     AC_MSG_RESULT([OpenSSL])
2181   elif test x"$USE_WIN32_RANDOM" = x"1" ; then
2182     AC_DEFINE(USE_WIN32_RANDOM, 1, [Define to use native Windows API for random number generation])
2183     AC_MSG_RESULT([Windows native])
2184   elif test x"$USE_DEV_URANDOM" = x"1" ; then
2185     AC_DEFINE(USE_DEV_URANDOM, 1, [Define to use /dev/urandom for random number generation])
2186     AC_MSG_RESULT([/dev/urandom])
2187   else
2188     AC_MSG_ERROR([
2189 no source of strong random numbers was found
2190 PostgreSQL can use OpenSSL or /dev/urandom as a source of random numbers,
2191 for authentication protocols. You can use --disable-strong-random to use a
2192 built-in pseudo random number generator, but that may be insecure.])
2193   fi
2194   AC_DEFINE(HAVE_STRONG_RANDOM, 1, [Define to use have a strong random number source])
2195 else
2196     AC_MSG_RESULT([weak builtin PRNG])
2197     AC_MSG_WARN([
2198 *** Not using a strong random number source may be insecure.])
2199 fi
2200
2201 # If not set in template file, set bytes to use libc memset()
2202 if test x"$MEMSET_LOOP_LIMIT" = x"" ; then
2203   MEMSET_LOOP_LIMIT=1024
2204 fi
2205 AC_DEFINE_UNQUOTED(MEMSET_LOOP_LIMIT, ${MEMSET_LOOP_LIMIT}, [Define bytes to use libc memset().])
2206
2207
2208 if test "$enable_nls" = yes ; then
2209   PGAC_CHECK_GETTEXT
2210 fi
2211
2212 # Check for Tcl configuration script tclConfig.sh
2213 if test "$with_tcl" = yes; then
2214     PGAC_PATH_TCLCONFIGSH([$with_tclconfig])
2215     PGAC_EVAL_TCLCONFIGSH([$TCL_CONFIG_SH],
2216                           [TCL_INCLUDE_SPEC,TCL_LIBS,TCL_LIB_SPEC,TCL_SHARED_BUILD])
2217     AC_SUBST(TCL_SHLIB_LD_LIBS)dnl don't want to double-evaluate that one
2218     if test "$TCL_SHARED_BUILD" != 1; then
2219       AC_MSG_ERROR([cannot build PL/Tcl because Tcl is not a shared library
2220 Use --without-tcl to disable building PL/Tcl.])
2221     fi
2222     # now that we have TCL_INCLUDE_SPEC, we can check for <tcl.h>
2223     ac_save_CPPFLAGS=$CPPFLAGS
2224     CPPFLAGS="$TCL_INCLUDE_SPEC $CPPFLAGS"
2225     AC_CHECK_HEADER(tcl.h, [], [AC_MSG_ERROR([header file <tcl.h> is required for Tcl])])
2226     CPPFLAGS=$ac_save_CPPFLAGS
2227 fi
2228
2229 # check for <perl.h>
2230 if test "$with_perl" = yes; then
2231   ac_save_CPPFLAGS=$CPPFLAGS
2232   CPPFLAGS="$CPPFLAGS -I$perl_archlibexp/CORE"
2233   AC_CHECK_HEADER(perl.h, [], [AC_MSG_ERROR([header file <perl.h> is required for Perl])],
2234                   [#include <EXTERN.h>])
2235   # While we're at it, check that we can link to libperl.
2236   # On most platforms, if perl.h is there then libperl.so will be too, but at
2237   # this writing Debian packages them separately.  There is no known reason to
2238   # waste cycles on separate probes for the Tcl or Python libraries, though.
2239   pgac_save_LIBS=$LIBS
2240   LIBS="$perl_embed_ldflags"
2241   AC_MSG_CHECKING([for libperl])
2242   AC_LINK_IFELSE([AC_LANG_PROGRAM([
2243 #include <EXTERN.h>
2244 #include <perl.h>
2245 ],  [perl_alloc();])],
2246     [AC_MSG_RESULT(yes)],
2247     [AC_MSG_RESULT(no)
2248      AC_MSG_ERROR([libperl library is required for Perl])])
2249   LIBS=$pgac_save_LIBS
2250   CPPFLAGS=$ac_save_CPPFLAGS
2251 fi
2252
2253 # check for <Python.h>
2254 if test "$with_python" = yes; then
2255   ac_save_CPPFLAGS=$CPPFLAGS
2256   CPPFLAGS="$python_includespec $CPPFLAGS"
2257   AC_CHECK_HEADER(Python.h, [], [AC_MSG_ERROR([header file <Python.h> is required for Python])])
2258   CPPFLAGS=$ac_save_CPPFLAGS
2259 fi
2260
2261 #
2262 # Check for DocBook and tools
2263 #
2264 PGAC_PATH_XMLLINT
2265 PGAC_CHECK_DOCBOOK(4.2)
2266 PGAC_PATH_PROGS(DBTOEPUB, dbtoepub)
2267 PGAC_PATH_PROGS(XSLTPROC, xsltproc)
2268 PGAC_PATH_PROGS(FOP, fop)
2269
2270 #
2271 # Check for test tools
2272 #
2273 if test "$enable_tap_tests" = yes; then
2274   # Check for necessary modules, unless user has specified the "prove" to use;
2275   # in that case it's her responsibility to have a working configuration.
2276   # (prove might be part of a different Perl installation than perl, eg on
2277   # MSys, so the result of AX_PROG_PERL_MODULES could be irrelevant anyway.)
2278   if test -z "$PROVE"; then
2279     # Test::More and Time::HiRes are supposed to be part of core Perl,
2280     # but some distros omit them in a minimal installation.
2281     AX_PROG_PERL_MODULES([IPC::Run Test::More=0.87 Time::HiRes], ,
2282       [AC_MSG_ERROR([Additional Perl modules are required to run TAP tests])])
2283   fi
2284   # Now make sure we know where prove is
2285   PGAC_PATH_PROGS(PROVE, prove)
2286   if test -z "$PROVE"; then
2287     AC_MSG_ERROR([prove not found])
2288   fi
2289 fi
2290
2291 # Thread testing
2292
2293 # We have to run the thread test near the end so we have all our symbols
2294 # defined.  Cross compiling throws a warning.
2295 #
2296 if test "$enable_thread_safety" = yes; then
2297 if test "$PORTNAME" != "win32"
2298 then
2299 AC_MSG_CHECKING([thread safety of required library functions])
2300
2301 _CFLAGS="$CFLAGS"
2302 _LIBS="$LIBS"
2303 CFLAGS="$CFLAGS $PTHREAD_CFLAGS -DIN_CONFIGURE"
2304 LIBS="$LIBS $PTHREAD_LIBS"
2305 AC_RUN_IFELSE(
2306   [AC_LANG_SOURCE([[#include "$srcdir/src/test/thread/thread_test.c"]])],
2307   [AC_MSG_RESULT(yes)],
2308   [AC_MSG_RESULT(no)
2309   AC_MSG_ERROR([thread test program failed
2310 This platform is not thread-safe.  Check the file 'config.log' or compile
2311 and run src/test/thread/thread_test for the exact reason.
2312 Use --disable-thread-safety to disable thread safety.])],
2313   [AC_MSG_RESULT(maybe)
2314   AC_MSG_WARN([
2315 *** Skipping thread test program because of cross-compile build.
2316 *** Run the program in src/test/thread on the target machine.
2317 ])])
2318 CFLAGS="$_CFLAGS"
2319 LIBS="$_LIBS"
2320 else
2321 AC_MSG_WARN([*** skipping thread test on Win32])
2322 fi
2323 fi
2324
2325 # If compiler will take -Wl,--as-needed (or various platform-specific
2326 # spellings thereof) then add that to LDFLAGS.  This is much easier than
2327 # trying to filter LIBS to the minimum for each executable.
2328 # On (at least) some Red-Hat-derived systems, this switch breaks linking to
2329 # libreadline; therefore we postpone testing it until we know what library
2330 # dependencies readline has.  The test code will try to link with $LIBS.
2331 if test "$with_readline" = yes; then
2332   link_test_func=readline
2333 else
2334   link_test_func=exit
2335 fi
2336
2337 if test "$PORTNAME" = "darwin"; then
2338   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-dead_strip_dylibs], $link_test_func)
2339 elif test "$PORTNAME" = "openbsd"; then
2340   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,-Bdynamic], $link_test_func)
2341 else
2342   PGAC_PROG_CC_LDFLAGS_OPT([-Wl,--as-needed], $link_test_func)
2343 fi
2344
2345 # Create compiler version string
2346 if test x"$GCC" = x"yes" ; then
2347   cc_string=`${CC} --version | sed q`
2348   case $cc_string in [[A-Za-z]]*) ;; *) cc_string="GCC $cc_string";; esac
2349 elif test x"$SUN_STUDIO_CC" = x"yes" ; then
2350   cc_string=`${CC} -V 2>&1 | sed q`
2351 else
2352   cc_string=$CC
2353 fi
2354
2355 AC_DEFINE_UNQUOTED(PG_VERSION_STR,
2356                    ["PostgreSQL $PG_VERSION on $host, compiled by $cc_string, `expr $ac_cv_sizeof_void_p \* 8`-bit"],
2357                    [A string containing the version number, platform, and C compiler])
2358
2359 # Supply a numeric version string for use by 3rd party add-ons
2360 # awk -F is a regex on some platforms, and not on others, so make "." a tab
2361 [PG_VERSION_NUM="`echo "$PACKAGE_VERSION" | sed 's/[A-Za-z].*$//' |
2362 tr '.' '        ' |
2363 $AWK '{printf "%d%04d", $1, $2}'`"]
2364 AC_DEFINE_UNQUOTED(PG_VERSION_NUM, $PG_VERSION_NUM, [PostgreSQL version as a number])
2365 AC_SUBST(PG_VERSION_NUM)
2366
2367
2368 # Begin output steps
2369
2370 AC_MSG_NOTICE([using compiler=$cc_string])
2371 AC_MSG_NOTICE([using CFLAGS=$CFLAGS])
2372 AC_MSG_NOTICE([using CPPFLAGS=$CPPFLAGS])
2373 AC_MSG_NOTICE([using LDFLAGS=$LDFLAGS])
2374 # Currently only used when LLVM is used
2375 if test "$with_llvm" = yes ; then
2376    AC_MSG_NOTICE([using CXX=$CXX])
2377    AC_MSG_NOTICE([using CXXFLAGS=$CXXFLAGS])
2378    AC_MSG_NOTICE([using CLANG=$CLANG])
2379    AC_MSG_NOTICE([using BITCODE_CFLAGS=$BITCODE_CFLAGS])
2380    AC_MSG_NOTICE([using BITCODE_CXXFLAGS=$BITCODE_CXXFLAGS])
2381 fi
2382
2383 # prepare build tree if outside source tree
2384 # Note 1: test -ef might not exist, but it's more reliable than `pwd`.
2385 # Note 2: /bin/pwd might be better than shell's built-in at getting
2386 #         a symlink-free name.
2387 if ( test "$srcdir" -ef . ) >/dev/null 2>&1 || test "`cd $srcdir && /bin/pwd`" = "`/bin/pwd`"; then
2388   vpath_build=no
2389 else
2390   vpath_build=yes
2391   if test "$no_create" != yes; then
2392     _AS_ECHO_N([preparing build tree... ])
2393     pgac_abs_top_srcdir=`cd "$srcdir" && pwd`
2394     $SHELL "$ac_aux_dir/prep_buildtree" "$pgac_abs_top_srcdir" "." \
2395       || AC_MSG_ERROR(failed)
2396     AC_MSG_RESULT(done)
2397   fi
2398 fi
2399 AC_SUBST(vpath_build)
2400
2401
2402 AC_CONFIG_FILES([GNUmakefile src/Makefile.global])
2403
2404 AC_CONFIG_LINKS([
2405   src/backend/port/pg_sema.c:${SEMA_IMPLEMENTATION}
2406   src/backend/port/pg_shmem.c:${SHMEM_IMPLEMENTATION}
2407   src/include/pg_config_os.h:src/include/port/${template}.h
2408   src/Makefile.port:src/makefiles/Makefile.${template}
2409 ])
2410
2411 if test "$PORTNAME" = "win32"; then
2412 AC_CONFIG_COMMANDS([check_win32_symlinks],[
2413 # Links sometimes fail undetected on Mingw -
2414 # so here we detect it and warn the user
2415 for FILE in $CONFIG_LINKS
2416  do
2417         # test -e works for symlinks in the MinGW console
2418         test -e `expr "$FILE" : '\([[^:]]*\)'` || AC_MSG_WARN([*** link for $FILE -- please fix by hand])
2419  done
2420 ])
2421 fi
2422
2423 AC_CONFIG_HEADERS([src/include/pg_config.h],
2424 [
2425 # Update timestamp for pg_config.h (see Makefile.global)
2426 echo >src/include/stamp-h
2427 ])
2428
2429 AC_CONFIG_HEADERS([src/include/pg_config_ext.h],
2430 [
2431 # Update timestamp for pg_config_ext.h (see Makefile.global)
2432 echo >src/include/stamp-ext-h
2433 ])
2434
2435 AC_CONFIG_HEADERS([src/interfaces/ecpg/include/ecpg_config.h],
2436                   [echo >src/interfaces/ecpg/include/stamp-h])
2437
2438 AC_OUTPUT